qcsrc/server/command/common.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../../dpdefs/progsdefs.qh"
   5     #include "../../dpdefs/dpextensions.qh"
   6     #include "../sys-post.qh"
   7     #include "../../common/util.qh"
   8     #include "../../common/counting.qh"
   9     #include "../../common/command/shared_defs.qh"
  10     #include "../autocvars.qh"
  11     #include "../defs.qh"
  12     #include "../../common/notifications.qh"
  13     #include "common.qh"
  14     #include "vote.qh"
  15     #include "../scores.qh"
  16 #endif
  17
  18 // ====================================================
  19 //  Shared code for server commands, written by Samual
  20 //  Last updated: December 27th, 2011
  21 // ====================================================
  22
  23 // select the proper prefix for usage and other messages
  24 string GetCommandPrefix(entity caller)
  25 {
  26         if(caller)
  27                 return "cmd";
  28         else
  29                 return "sv_cmd";
  30 }
  31
  32 // if client return player nickname, or if server return admin nickname
  33 string GetCallerName(entity caller)
  34 {
  35         if(caller)
  36                 return caller.netname;
  37         else
  38                 return admin_name(); //((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  39 }
  40
  41 // verify that the client provided is acceptable for use
  42 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  43 {
  44         if (!IS_CLIENT(client))
  45                 return CLIENT_DOESNT_EXIST;
  46         else if(must_be_real && !IS_REAL_CLIENT(client))
  47                 return CLIENT_NOT_REAL;
  48         else if(must_be_bots && !IS_BOT_CLIENT(client))
  49                 return CLIENT_NOT_BOT;
  50
  51         return CLIENT_ACCEPTABLE;
  52 }
  53
  54 // if the client is not acceptable, return a string to be used for error messages
  55 string GetClientErrorString(float clienterror, string original_input)
  56 {
  57         switch(clienterror)
  58         {
  59                 case CLIENT_DOESNT_EXIST: { return strcat("Client '", original_input, "' doesn't exist"); }
  60                 case CLIENT_NOT_REAL: { return strcat("Client '", original_input, "' is not real"); }
  61                 case CLIENT_NOT_BOT: { return strcat("Client '", original_input, "' is not a bot"); }
  62                 default: { return "Incorrect usage of GetClientErrorString"; }
  63         }
  64 }
  65
  66 // is this entity number even in the possible range of entities?
  67 float VerifyClientNumber(float tmp_number)
  68 {
  69         if((tmp_number < 1) || (tmp_number > maxclients))
  70                 return false;
  71         else
  72                 return true;
  73 }
  74
  75 entity GetIndexedEntity(float argc, float start_index)
  76 {
  77         entity tmp_player, selection;
  78         float tmp_number, index;
  79         string tmp_string;
  80
  81         next_token = -1;
  82         index = start_index;
  83         selection = world;
  84
  85         if(argc > start_index)
  86         {
  87                 if(substring(argv(index), 0, 1) == "#")
  88                 {
  89                         tmp_string = substring(argv(index), 1, -1);
  90                         ++index;
  91
  92                         if(tmp_string != "") // is it all one token? like #1
  93                         {
  94                                 tmp_number = stof(tmp_string);
  95                         }
  96                         else if(argc > index) // no, it's two tokens? # 1
  97                         {
  98                                 tmp_number = stof(argv(index));
  99                                 ++index;
 100                         }
 101                         else
 102                                 tmp_number = 0;
 103                 }
 104                 else // maybe it's ONLY a number?
 105                 {
 106                         tmp_number = stof(argv(index));
 107                         ++index;
 108                 }
 109
 110                 if(VerifyClientNumber(tmp_number))
 111                 {
 112                         selection = edict_num(tmp_number); // yes, it was a number
 113                 }
 114                 else // no, maybe it's a name?
 115                 {
 116                         FOR_EACH_CLIENT(tmp_player)
 117                                 if (strdecolorize(tmp_player.netname) == strdecolorize(argv(start_index)))
 118                                         selection = tmp_player;
 119
 120                         index = (start_index + 1);
 121                 }
 122         }
 123
 124         next_token = index;
 125         //print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 126         return selection;
 127 }
 128
 129 // find a player which matches the input string, and return their entity
 130 entity GetFilteredEntity(string input)
 131 {
 132         entity tmp_player, selection;
 133         float tmp_number;
 134
 135         if(substring(input, 0, 1) == "#")
 136                 tmp_number = stof(substring(input, 1, -1));
 137         else
 138                 tmp_number = stof(input);
 139
 140         if(VerifyClientNumber(tmp_number))
 141         {
 142                 selection = edict_num(tmp_number);
 143         }
 144         else
 145         {
 146                 selection = world;
 147                 FOR_EACH_CLIENT(tmp_player)
 148                         if (strdecolorize(tmp_player.netname) == strdecolorize(input))
 149                                 selection = tmp_player;
 150         }
 151
 152         return selection;
 153 }
 154
 155 // same thing, but instead return their edict number
 156 float GetFilteredNumber(string input)
 157 {
 158         entity selection = GetFilteredEntity(input);
 159         float output;
 160
 161         output = num_for_edict(selection);
 162
 163         return output;
 164 }
 165
 166 // switch between sprint and print depending on whether the receiver is the server or a player
 167 void print_to(entity to, string input)
 168 {
 169     if(to)
 170         sprint(to, strcat(input, "\n"));
 171     else
 172         print(input, "\n");
 173 }
 174
 175 // ==========================================
 176 //  Supporting functions for common commands
 177 // ==========================================
 178
 179 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 180 void timeout_handler_reset()
 181 {
 182         timeout_caller = world;
 183         timeout_time = 0;
 184         timeout_leadtime = 0;
 185
 186         remove(self);
 187 }
 188
 189 void timeout_handler_think()
 190 {
 191         entity tmp_player;
 192
 193         switch(timeout_status)
 194         {
 195                 case TIMEOUT_ACTIVE:
 196                 {
 197                         if(timeout_time > 0) // countdown is still going
 198                         {
 199                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 200
 201                                 if(timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 202                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 203
 204                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE; // think again in one second
 205                                 timeout_time -= 1; // decrease the time counter
 206                         }
 207                         else // time to end the timeout
 208                         {
 209                                 timeout_status = TIMEOUT_INACTIVE;
 210
 211                                 // reset the slowmo value back to normal
 212                                 cvar_set("slowmo", ftos(orig_slowmo));
 213
 214                                 // unlock the view for players so they can move around again
 215                                 FOR_EACH_REALPLAYER(tmp_player)
 216                                         tmp_player.fixangle = false;
 217
 218                                 timeout_handler_reset();
 219                         }
 220
 221                         return;
 222                 }
 223
 224                 case TIMEOUT_LEADTIME:
 225                 {
 226                         if(timeout_leadtime > 0) // countdown is still going
 227                         {
 228                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 229
 230                                 self.nextthink = time + 1; // think again in one second
 231                                 timeout_leadtime -= 1; // decrease the time counter
 232                         }
 233                         else // time to begin the timeout
 234                         {
 235                                 timeout_status = TIMEOUT_ACTIVE;
 236
 237                                 // set the slowmo value to the timeout default slowmo value
 238                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 239
 240                                 // reset all the flood variables
 241                                 FOR_EACH_CLIENT(tmp_player)
 242                                         tmp_player.nickspamcount = tmp_player.nickspamtime = tmp_player.floodcontrol_chat =
 243                                         tmp_player.floodcontrol_chatteam = tmp_player.floodcontrol_chattell =
 244                                         tmp_player.floodcontrol_voice = tmp_player.floodcontrol_voiceteam = 0;
 245
 246                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 247                                 FOR_EACH_REALPLAYER(tmp_player)
 248                                         tmp_player.lastV_angle = tmp_player.v_angle;
 249
 250                                 self.nextthink = time; // think again next frame to handle it under TIMEOUT_ACTIVE code
 251                         }
 252
 253                         return;
 254                 }
 255
 256
 257                 case TIMEOUT_INACTIVE:
 258                 default:
 259                 {
 260                         timeout_handler_reset();
 261                         return;
 262                 }
 263         }
 264 }
 265
 266
 267
 268 // ===================================================
 269 //  Common commands used in both sv_cmd.qc and cmd.qc
 270 // ===================================================
 271
 272 void CommonCommand_cvar_changes(float request, entity caller)
 273 {
 274         switch(request)
 275         {
 276                 case CMD_REQUEST_COMMAND:
 277                 {
 278                         print_to(caller, cvar_changes);
 279                         return; // never fall through to usage
 280                 }
 281
 282                 default:
 283                 case CMD_REQUEST_USAGE:
 284                 {
 285                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 286                         print_to(caller, "  No arguments required.");
 287                         print_to(caller, "See also: ^2cvar_purechanges^7");
 288                         return;
 289                 }
 290         }
 291 }
 292
 293 void CommonCommand_cvar_purechanges(float request, entity caller)
 294 {
 295         switch(request)
 296         {
 297                 case CMD_REQUEST_COMMAND:
 298                 {
 299                         print_to(caller, cvar_purechanges);
 300                         return; // never fall through to usage
 301                 }
 302
 303                 default:
 304                 case CMD_REQUEST_USAGE:
 305                 {
 306                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 307                         print_to(caller, "  No arguments required.");
 308                         print_to(caller, "See also: ^2cvar_changes^7");
 309                         return;
 310                 }
 311         }
 312 }
 313
 314 void CommonCommand_info(float request, entity caller, float argc)
 315 {
 316         switch(request)
 317         {
 318                 case CMD_REQUEST_COMMAND:
 319                 {
 320                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 321
 322                         if(command)
 323                                 wordwrap_sprint(command, 1000);
 324                         else
 325                                 print_to(caller, "ERROR: unsupported info command");
 326
 327                         return; // never fall through to usage
 328                 }
 329
 330                 default:
 331                 case CMD_REQUEST_USAGE:
 332                 {
 333                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 334                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 335                         return;
 336                 }
 337         }
 338 }
 339
 340 void CommonCommand_ladder(float request, entity caller)
 341 {
 342         switch(request)
 343         {
 344                 case CMD_REQUEST_COMMAND:
 345                 {
 346                         print_to(caller, ladder_reply);
 347                         return; // never fall through to usage
 348                 }
 349
 350                 default:
 351                 case CMD_REQUEST_USAGE:
 352                 {
 353                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 354                         print_to(caller, "  No arguments required.");
 355                         return;
 356                 }
 357         }
 358 }
 359
 360 void CommonCommand_lsmaps(float request, entity caller)
 361 {
 362         switch(request)
 363         {
 364                 case CMD_REQUEST_COMMAND:
 365                 {
 366                         print_to(caller, lsmaps_reply);
 367                         return; // never fall through to usage
 368                 }
 369
 370                 default:
 371                 case CMD_REQUEST_USAGE:
 372                 {
 373                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 374                         print_to(caller, "  No arguments required.");
 375                         return;
 376                 }
 377         }
 378 }
 379
 380 void CommonCommand_printmaplist(float request, entity caller)
 381 {
 382         switch(request)
 383         {
 384                 case CMD_REQUEST_COMMAND:
 385                 {
 386                         print_to(caller, maplist_reply);
 387                         return; // never fall through to usage
 388                 }
 389
 390                 default:
 391                 case CMD_REQUEST_USAGE:
 392                 {
 393                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 394                         print_to(caller, "  No arguments required.");
 395                         return;
 396                 }
 397         }
 398 }
 399
 400 void CommonCommand_rankings(float request, entity caller)
 401 {
 402         switch(request)
 403         {
 404                 case CMD_REQUEST_COMMAND:
 405                 {
 406                         print_to(caller, rankings_reply);
 407                         return; // never fall through to usage
 408                 }
 409
 410                 default:
 411                 case CMD_REQUEST_USAGE:
 412                 {
 413                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 414                         print_to(caller, "  No arguments required.");
 415                         return;
 416                 }
 417         }
 418 }
 419
 420 void CommonCommand_records(float request, entity caller)
 421 {
 422         switch(request)
 423         {
 424                 case CMD_REQUEST_COMMAND:
 425                 {
 426                         float i;
 427
 428                         for(i = 0; i < 10; ++i)
 429                                 if(records_reply[i] != "")
 430                                         print_to(caller, records_reply[i]);
 431
 432                         return; // never fall through to usage
 433                 }
 434
 435                 default:
 436                 case CMD_REQUEST_USAGE:
 437                 {
 438                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 439                         print_to(caller, "  No arguments required.");
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 void CommonCommand_teamstatus(float request, entity caller)
 446 {
 447         switch(request)
 448         {
 449                 case CMD_REQUEST_COMMAND:
 450                 {
 451                         Score_NicePrint(caller);
 452                         return; // never fall through to usage
 453                 }
 454
 455                 default:
 456                 case CMD_REQUEST_USAGE:
 457                 {
 458                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 459                         print_to(caller, "  No arguments required.");
 460                         return;
 461                 }
 462         }
 463 }
 464
 465 void CommonCommand_time(float request, entity caller)
 466 {
 467         switch(request)
 468         {
 469                 case CMD_REQUEST_COMMAND:
 470                 {
 471                         print_to(caller, strcat("time = ", ftos(time)));
 472                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 473                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 474                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 475                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 476                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 477                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 478                         return;
 479                 }
 480
 481                 default:
 482                 case CMD_REQUEST_USAGE:
 483                 {
 484                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 485                         print_to(caller, "  No arguments required.");
 486                         return;
 487                 }
 488         }
 489 }
 490
 491 void CommonCommand_timein(float request, entity caller)
 492 {
 493         switch(request)
 494         {
 495                 case CMD_REQUEST_COMMAND:
 496                 {
 497                         if(!caller || autocvar_sv_timeout)
 498                         {
 499                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 500                                 else if(caller && (caller != timeout_caller)) { print_to(caller, "^7Error: You are not allowed to stop the active timeout."); }
 501
 502                                 else // everything should be okay, continue aborting timeout
 503                                 {
 504                                         switch(timeout_status)
 505                                         {
 506                                                 case TIMEOUT_LEADTIME:
 507                                                 {
 508                                                         timeout_status = TIMEOUT_INACTIVE;
 509                                                         timeout_time = 0;
 510                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 511                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 512                                                         return;
 513                                                 }
 514
 515                                                 case TIMEOUT_ACTIVE:
 516                                                 {
 517                                                         timeout_time = autocvar_sv_timeout_resumetime;
 518                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 519                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 520                                                         return;
 521                                                 }
 522
 523                                                 default: dprint("timeout status was inactive, but this code was executed anyway?"); return;
 524                                         }
 525                                 }
 526                         }
 527                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 528
 529                         return; // never fall through to usage
 530                 }
 531
 532                 default:
 533                 case CMD_REQUEST_USAGE:
 534                 {
 535                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 536                         print_to(caller, "  No arguments required.");
 537                         return;
 538                 }
 539         }
 540 }
 541
 542 void CommonCommand_timeout(float request, entity caller) // DEAR GOD THIS COMMAND IS TERRIBLE.
 543 {
 544         switch(request)
 545         {
 546                 case CMD_REQUEST_COMMAND:
 547                 {
 548                         if(!caller || autocvar_sv_timeout)
 549                         {
 550                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 551
 552                                 if(timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 553                                 else if(vote_called) { print_to(caller, "^7Error: You can not call a timeout while a vote is active."); }
 554                                 else if(warmup_stage && !g_warmup_allow_timeout) { print_to(caller, "^7Error: You can not call a timeout in warmup-stage."); }
 555                                 else if(time < game_starttime) { print_to(caller, "^7Error: You can not call a timeout while the map is being restarted."); }
 556                                 else if(caller && (caller.allowed_timeouts < 1)) { print_to(caller, "^7Error: You already used all your timeout calls for this map."); }
 557                                 else if(caller && !IS_PLAYER(caller)) { print_to(caller, "^7Error: You must be a player to call a timeout."); }
 558                                 else if((autocvar_timelimit) && (last_possible_timeout < time - game_starttime)) { print_to(caller, "^7Error: It is too late to call a timeout now!"); }
 559
 560                                 else // everything should be okay, proceed with starting the timeout
 561                                 {
 562                                         if(caller) { caller.allowed_timeouts -= 1; }
 563
 564                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n"); // write a bprint who started the timeout (and how many they have left)
 565
 566                                         timeout_status = TIMEOUT_LEADTIME;
 567                                         timeout_caller = caller;
 568                                         timeout_time = autocvar_sv_timeout_length;
 569                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 570
 571                                         timeout_handler = spawn();
 572                                         timeout_handler.think = timeout_handler_think;
 573                                         timeout_handler.nextthink = time; // always let the entity think asap
 574
 575                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 576                                 }
 577                         }
 578                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 579
 580                         return; // never fall through to usage
 581                 }
 582
 583                 default:
 584                 case CMD_REQUEST_USAGE:
 585                 {
 586                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 587                         print_to(caller, "  No arguments required.");
 588                         return;
 589                 }
 590         }
 591 }
 592
 593 void CommonCommand_who(float request, entity caller, float argc)
 594 {
 595         switch(request)
 596         {
 597                 case CMD_REQUEST_COMMAND:
 598                 {
 599                         float total_listed_players, is_bot;
 600                         entity tmp_player;
 601
 602                         float privacy = (caller && autocvar_sv_status_privacy);
 603                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 604                         string tmp_netaddress, tmp_crypto_idfp;
 605
 606                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 607                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 608                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 609
 610                         total_listed_players = 0;
 611                         FOR_EACH_CLIENT(tmp_player)
 612                         {
 613                                 is_bot = (IS_BOT_CLIENT(tmp_player));
 614
 615                                 if(is_bot)
 616                                 {
 617                                         tmp_netaddress = "null/botclient";
 618                                         tmp_crypto_idfp = "null/botclient";
 619                                 }
 620                                 else if(privacy)
 621                                 {
 622                                         tmp_netaddress = "hidden";
 623                                         tmp_crypto_idfp = "hidden";
 624                                 }
 625                                 else
 626                                 {
 627                                         tmp_netaddress = tmp_player.netaddress;
 628                                         tmp_crypto_idfp = tmp_player.crypto_idfp;
 629                                 }
 630
 631                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 632                                         num_for_edict(tmp_player),
 633                                         tmp_player.netname,
 634                                         tmp_player.ping,
 635                                         tmp_player.ping_packetloss,
 636                                         process_time(1, time - tmp_player.jointime),
 637                                         tmp_netaddress,
 638                                         tmp_crypto_idfp));
 639
 640                                 ++total_listed_players;
 641                         }
 642
 643                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 644
 645                         return; // never fall through to usage
 646                 }
 647
 648                 default:
 649                 case CMD_REQUEST_USAGE:
 650                 {
 651                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 652                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 653                         return;
 654                 }
 655         }
 656 }
 657
 658 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 659 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 660 void CommonCommand_(float request, entity caller)
 661 {
 662         switch(request)
 663         {
 664                 case CMD_REQUEST_COMMAND:
 665                 {
 666
 667                         return; // never fall through to usage
 668                 }
 669
 670                 default:
 671                 case CMD_REQUEST_USAGE:
 672                 {
 673                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 674                         print_to(caller, "  No arguments required.");
 675                         return;
 676                 }
 677         }
 678 }
 679 */
 680
 681
 682 // ==================================
 683 //  Macro system for common commands
 684 // ==================================
 685
 686 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 687 #define COMMON_COMMANDS(request,caller,arguments,command) \
 688         COMMON_COMMAND("cvar_changes", CommonCommand_cvar_changes(request, caller), "Prints a list of all changed server cvars") \
 689         COMMON_COMMAND("cvar_purechanges", CommonCommand_cvar_purechanges(request, caller), "Prints a list of all changed gameplay cvars") \
 690         COMMON_COMMAND("info", CommonCommand_info(request, caller, arguments), "Request for unique server information set up by admin") \
 691         COMMON_COMMAND("ladder", CommonCommand_ladder(request, caller), "Get information about top players if supported") \
 692         COMMON_COMMAND("lsmaps", CommonCommand_lsmaps(request, caller), "List maps which can be used with the current game mode") \
 693         COMMON_COMMAND("printmaplist", CommonCommand_printmaplist(request, caller), "Display full server maplist reply") \
 694         COMMON_COMMAND("rankings", CommonCommand_rankings(request, caller), "Print information about rankings") \
 695         COMMON_COMMAND("records", CommonCommand_records(request, caller), "List top 10 records for the current map") \
 696         COMMON_COMMAND("teamstatus", CommonCommand_teamstatus(request, caller), "Show information about player and team scores") \
 697         COMMON_COMMAND("time", CommonCommand_time(request, caller), "Print different formats/readouts of time") \
 698         COMMON_COMMAND("timein", CommonCommand_timein(request, caller), "Resume the game from being paused with a timeout") \
 699         COMMON_COMMAND("timeout", CommonCommand_timeout(request, caller), "Call a timeout which pauses the game for certain amount of time unless unpaused") \
 700         COMMON_COMMAND("vote", VoteCommand(request, caller, arguments, command), "Request an action to be voted upon by players") \
 701         COMMON_COMMAND("who", CommonCommand_who(request, caller, arguments), "Display detailed client information about all players") \
 702         /* nothing */
 703
 704 void CommonCommand_macro_help(entity caller)
 705 {
 706         #define COMMON_COMMAND(name,function,description) \
 707                 { print_to(caller, strcat("  ^2", name, "^7: ", description)); }
 708
 709         COMMON_COMMANDS(0, caller, 0, "");
 710         #undef COMMON_COMMAND
 711
 712         return;
 713 }
 714
 715 float CommonCommand_macro_command(float argc, entity caller, string command)
 716 {
 717         #define COMMON_COMMAND(name,function,description) \
 718                 { if(name == strtolower(argv(0))) { function; return true; } }
 719
 720         COMMON_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, command);
 721         #undef COMMON_COMMAND
 722
 723         return false;
 724 }
 725
 726 float CommonCommand_macro_usage(float argc, entity caller)
 727 {
 728         #define COMMON_COMMAND(name,function,description) \
 729                 { if(name == strtolower(argv(1))) { function; return true; } }
 730
 731         COMMON_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
 732         #undef COMMON_COMMAND
 733
 734         return false;
 735 }
 736
 737 void CommonCommand_macro_write_aliases(float fh)
 738 {
 739         #define COMMON_COMMAND(name,function,description) \
 740                 { CMD_Write_Alias("qc_cmd_svcmd", name, description); }
 741
 742         COMMON_COMMANDS(0, world, 0, "");
 743         #undef COMMON_COMMAND
 744
 745         return;
 746 }