qcsrc/server/command/common.qc

   1 #include "../../common/command/command.qh"
   2 #include "common.qh"
   3 #include "../_all.qh"
   4
   5 #include "../scores.qh"
   6
   7 #include "../../common/notifications.qh"
   8 #include "../../common/counting.qh"
   9
  10
  11 // ====================================================
  12 //  Shared code for server commands, written by Samual
  13 //  Last updated: December 27th, 2011
  14 // ====================================================
  15
  16 // select the proper prefix for usage and other messages
  17 string GetCommandPrefix(entity caller)
  18 {
  19         if(caller)
  20                 return "cmd";
  21         else
  22                 return "sv_cmd";
  23 }
  24
  25 // if client return player nickname, or if server return admin nickname
  26 string GetCallerName(entity caller)
  27 {
  28         if(caller)
  29                 return caller.netname;
  30         else
  31                 return admin_name(); //((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  32 }
  33
  34 // verify that the client provided is acceptable for kicking
  35 float VerifyKickableEntity(entity client)
  36 {
  37         if (!IS_REAL_CLIENT(client))
  38                 return CLIENT_NOT_REAL;
  39         return CLIENT_ACCEPTABLE;
  40 }
  41
  42 // verify that the client provided is acceptable for use
  43 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  44 {
  45         if (!IS_CLIENT(client))
  46                 return CLIENT_DOESNT_EXIST;
  47         else if(must_be_real && !IS_REAL_CLIENT(client))
  48                 return CLIENT_NOT_REAL;
  49         else if(must_be_bots && !IS_BOT_CLIENT(client))
  50                 return CLIENT_NOT_BOT;
  51
  52         return CLIENT_ACCEPTABLE;
  53 }
  54
  55 // if the client is not acceptable, return a string to be used for error messages
  56 string GetClientErrorString_color(float clienterror, string original_input, string col)
  57 {
  58         switch(clienterror)
  59         {
  60                 case CLIENT_DOESNT_EXIST: { return strcat(col, "Client '", original_input, col, "' doesn't exist"); }
  61                 case CLIENT_NOT_REAL: { return strcat(col, "Client '", original_input, col, "' is not real"); }
  62                 case CLIENT_NOT_BOT: { return strcat(col, "Client '", original_input, col, "' is not a bot"); }
  63                 default: { return "Incorrect usage of GetClientErrorString"; }
  64         }
  65 }
  66
  67 // is this entity number even in the possible range of entities?
  68 float VerifyClientNumber(float tmp_number)
  69 {
  70         if((tmp_number < 1) || (tmp_number > maxclients))
  71                 return false;
  72         else
  73                 return true;
  74 }
  75
  76 entity GetIndexedEntity(float argc, float start_index)
  77 {
  78         entity tmp_player, selection;
  79         float tmp_number, index;
  80         string tmp_string;
  81
  82         next_token = -1;
  83         index = start_index;
  84         selection = world;
  85
  86         if(argc > start_index)
  87         {
  88                 if(substring(argv(index), 0, 1) == "#")
  89                 {
  90                         tmp_string = substring(argv(index), 1, -1);
  91                         ++index;
  92
  93                         if(tmp_string != "") // is it all one token? like #1
  94                         {
  95                                 tmp_number = stof(tmp_string);
  96                         }
  97                         else if(argc > index) // no, it's two tokens? # 1
  98                         {
  99                                 tmp_number = stof(argv(index));
 100                                 ++index;
 101                         }
 102                         else
 103                                 tmp_number = 0;
 104                 }
 105                 else // maybe it's ONLY a number?
 106                 {
 107                         tmp_number = stof(argv(index));
 108                         ++index;
 109                 }
 110
 111                 if(VerifyClientNumber(tmp_number))
 112                 {
 113                         selection = edict_num(tmp_number); // yes, it was a number
 114                 }
 115                 else // no, maybe it's a name?
 116                 {
 117                         FOR_EACH_CLIENT(tmp_player)
 118                                 if (strdecolorize(tmp_player.netname) == strdecolorize(argv(start_index)))
 119                                         selection = tmp_player;
 120
 121                         index = (start_index + 1);
 122                 }
 123         }
 124
 125         next_token = index;
 126         //print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 127         return selection;
 128 }
 129
 130 // find a player which matches the input string, and return their entity
 131 entity GetFilteredEntity(string input)
 132 {
 133         entity tmp_player, selection;
 134         float tmp_number;
 135
 136         if(substring(input, 0, 1) == "#")
 137                 tmp_number = stof(substring(input, 1, -1));
 138         else
 139                 tmp_number = stof(input);
 140
 141         if(VerifyClientNumber(tmp_number))
 142         {
 143                 selection = edict_num(tmp_number);
 144         }
 145         else
 146         {
 147                 selection = world;
 148                 FOR_EACH_CLIENT(tmp_player)
 149                         if (strdecolorize(tmp_player.netname) == strdecolorize(input))
 150                                 selection = tmp_player;
 151         }
 152
 153         return selection;
 154 }
 155
 156 // same thing, but instead return their edict number
 157 float GetFilteredNumber(string input)
 158 {
 159         entity selection = GetFilteredEntity(input);
 160         float output;
 161
 162         output = num_for_edict(selection);
 163
 164         return output;
 165 }
 166
 167 // switch between sprint and print depending on whether the receiver is the server or a player
 168 void print_to(entity to, string input)
 169 {
 170     if(to)
 171         sprint(to, strcat(input, "\n"));
 172     else
 173         print(input, "\n");
 174 }
 175
 176 // ==========================================
 177 //  Supporting functions for common commands
 178 // ==========================================
 179
 180 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 181 void timeout_handler_reset()
 182 {
 183         timeout_caller = world;
 184         timeout_time = 0;
 185         timeout_leadtime = 0;
 186
 187         remove(self);
 188 }
 189
 190 void timeout_handler_think()
 191 {
 192         entity tmp_player;
 193
 194         switch(timeout_status)
 195         {
 196                 case TIMEOUT_ACTIVE:
 197                 {
 198                         if(timeout_time > 0) // countdown is still going
 199                         {
 200                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 201
 202                                 if(timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 203                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 204
 205                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE; // think again in one second
 206                                 timeout_time -= 1; // decrease the time counter
 207                         }
 208                         else // time to end the timeout
 209                         {
 210                                 timeout_status = TIMEOUT_INACTIVE;
 211
 212                                 // reset the slowmo value back to normal
 213                                 cvar_set("slowmo", ftos(orig_slowmo));
 214
 215                                 // unlock the view for players so they can move around again
 216                                 FOR_EACH_REALPLAYER(tmp_player)
 217                                         tmp_player.fixangle = false;
 218
 219                                 timeout_handler_reset();
 220                         }
 221
 222                         return;
 223                 }
 224
 225                 case TIMEOUT_LEADTIME:
 226                 {
 227                         if(timeout_leadtime > 0) // countdown is still going
 228                         {
 229                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 230
 231                                 self.nextthink = time + 1; // think again in one second
 232                                 timeout_leadtime -= 1; // decrease the time counter
 233                         }
 234                         else // time to begin the timeout
 235                         {
 236                                 timeout_status = TIMEOUT_ACTIVE;
 237
 238                                 // set the slowmo value to the timeout default slowmo value
 239                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 240
 241                                 // reset all the flood variables
 242                                 FOR_EACH_CLIENT(tmp_player)
 243                                         tmp_player.nickspamcount = tmp_player.nickspamtime = tmp_player.floodcontrol_chat =
 244                                         tmp_player.floodcontrol_chatteam = tmp_player.floodcontrol_chattell =
 245                                         tmp_player.floodcontrol_voice = tmp_player.floodcontrol_voiceteam = 0;
 246
 247                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 248                                 FOR_EACH_REALPLAYER(tmp_player)
 249                                         tmp_player.lastV_angle = tmp_player.v_angle;
 250
 251                                 self.nextthink = time; // think again next frame to handle it under TIMEOUT_ACTIVE code
 252                         }
 253
 254                         return;
 255                 }
 256
 257
 258                 case TIMEOUT_INACTIVE:
 259                 default:
 260                 {
 261                         timeout_handler_reset();
 262                         return;
 263                 }
 264         }
 265 }
 266
 267
 268
 269 // ===================================================
 270 //  Common commands used in both sv_cmd.qc and cmd.qc
 271 // ===================================================
 272
 273 void CommonCommand_cvar_changes(float request, entity caller)
 274 {
 275         switch(request)
 276         {
 277                 case CMD_REQUEST_COMMAND:
 278                 {
 279                         print_to(caller, cvar_changes);
 280                         return; // never fall through to usage
 281                 }
 282
 283                 default:
 284                 case CMD_REQUEST_USAGE:
 285                 {
 286                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 287                         print_to(caller, "  No arguments required.");
 288                         print_to(caller, "See also: ^2cvar_purechanges^7");
 289                         return;
 290                 }
 291         }
 292 }
 293
 294 void CommonCommand_cvar_purechanges(float request, entity caller)
 295 {
 296         switch(request)
 297         {
 298                 case CMD_REQUEST_COMMAND:
 299                 {
 300                         print_to(caller, cvar_purechanges);
 301                         return; // never fall through to usage
 302                 }
 303
 304                 default:
 305                 case CMD_REQUEST_USAGE:
 306                 {
 307                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 308                         print_to(caller, "  No arguments required.");
 309                         print_to(caller, "See also: ^2cvar_changes^7");
 310                         return;
 311                 }
 312         }
 313 }
 314
 315 void CommonCommand_editmob(float request, entity caller, float argc)
 316 {
 317         switch(request)
 318         {
 319                 case CMD_REQUEST_COMMAND:
 320                 {
 321                         if(autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 322                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 323
 324                         if(caller)
 325                         {
 326                                 makevectors(self.v_angle);
 327                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 328                         }
 329
 330                         entity mon = trace_ent;
 331                         float is_visible = (mon.flags & FL_MONSTER);
 332                         string argument = argv(2);
 333
 334                         switch(argv(1))
 335                         {
 336                                 case "name":
 337                                 {
 338                                         if(!caller) { print_to(caller, "Only players can edit monsters"); return; }
 339                                         if(!argument) { break; } // escape to usage
 340                                         if(!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 341                                         if(mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 342                                         if(!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 343
 344                                         string mon_oldname = mon.monster_name;
 345
 346                                         mon.monster_name = argument;
 347                                         if(mon.sprite) { WaypointSprite_UpdateSprites(mon.sprite, strzone(mon.monster_name), string_null, string_null); }
 348                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 349                                         return;
 350                                 }
 351                                 case "spawn":
 352                                 {
 353                                         if(!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 354                                         if(!argv(2)) { break; } // escape to usage
 355
 356                                         float moveflag, tmp_moncount = 0;
 357                                         string arg_lower = strtolower(argument);
 358                                         moveflag = (argv(3)) ? stof(argv(3)) : 1; // follow owner if not defined
 359                                         ret_string = "Monster spawning is currently disabled by a mutator";
 360
 361                                         if(arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 362
 363                                         FOR_EACH_MONSTER(mon) { if(mon.realowner == caller) ++tmp_moncount; }
 364
 365                                         if(!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 366                                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 367                                         if(!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 368                                         if(MUTATOR_CALLHOOK(AllowMobSpawning)) { print_to(caller, ret_string); return; }
 369                                         if(caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 370                                         if(caller.frozen) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 371                                         if(caller.deadflag != DEAD_NO) { print_to(caller, "You can't spawn monsters while dead"); return; }
 372                                         if(tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 373                                         if(tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 374
 375                                         float i = 0, found = false;
 376                                         for(i = MON_FIRST; i <= MON_LAST; ++i)
 377                                         {
 378                                                 mon = get_monsterinfo(i);
 379                                                 if(mon.netname == arg_lower) { found = true; break; }
 380                                         }
 381
 382                                         if(!found && arg_lower != "random") { print_to(caller, "Invalid monster"); return; }
 383
 384                                         totalspawned += 1;
 385                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 386                                         mon = spawnmonster(arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 387                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 388                                         return;
 389                                 }
 390                                 case "kill":
 391                                 {
 392                                         if(!caller) { print_to(caller, "Only players can kill monsters"); return; }
 393                                         if(mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 394                                         if(!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 395
 396                                         Damage (mon, world, world, mon.health + mon.max_health + 200, DEATH_KILL, mon.origin, '0 0 0');
 397                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 398                                         return;
 399                                 }
 400                                 case "skin":
 401                                 {
 402                                         if(!caller) { print_to(caller, "Only players can edit monsters"); return; }
 403                                         if(!argument) { break; } // escape to usage
 404                                         if(!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 405                                         if(!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 406                                         if(mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 407                                         if(mon.monsterid == MON_MAGE) { print_to(caller, "Mage skins can't be changed"); return; } // TODO
 408
 409                                         mon.skin = stof(argument);
 410                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 411                                         return;
 412                                 }
 413                                 case "movetarget":
 414                                 {
 415                                         if(!caller) { print_to(caller, "Only players can edit monsters"); return; }
 416                                         if(!argument) { break; } // escape to usage
 417                                         if(!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 418                                         if(!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 419                                         if(mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 420
 421                                         mon.monster_moveflags = stof(argument);
 422                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 423                                         return;
 424                                 }
 425                                 case "butcher":
 426                                 {
 427                                         if(caller) { print_to(caller, "This command is not available to players"); return; }
 428                                         if(g_invasion) { print_to(caller, "This command does not work during an invasion!"); return; }
 429
 430                                         float tmp_remcount = 0;
 431                                         entity tmp_entity;
 432
 433                                         FOR_EACH_MONSTER(tmp_entity) { Monster_Remove(tmp_entity); ++tmp_remcount; }
 434
 435                                         monsters_total = monsters_killed = totalspawned = 0;
 436
 437                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 438                                         return;
 439                                 }
 440                         }
 441                 }
 442
 443                 default:
 444                 case CMD_REQUEST_USAGE:
 445                 {
 446                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 447                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 448                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 449                         print_to(caller, "  spawn also takes arguments list and random");
 450                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 451                         return;
 452                 }
 453         }
 454 }
 455
 456 void CommonCommand_info(float request, entity caller, float argc)
 457 {
 458         switch(request)
 459         {
 460                 case CMD_REQUEST_COMMAND:
 461                 {
 462                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 463
 464                         if(command)
 465                                 wordwrap_sprint(command, 1000);
 466                         else
 467                                 print_to(caller, "ERROR: unsupported info command");
 468
 469                         return; // never fall through to usage
 470                 }
 471
 472                 default:
 473                 case CMD_REQUEST_USAGE:
 474                 {
 475                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 476                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 477                         return;
 478                 }
 479         }
 480 }
 481
 482 void CommonCommand_ladder(float request, entity caller)
 483 {
 484         switch(request)
 485         {
 486                 case CMD_REQUEST_COMMAND:
 487                 {
 488                         print_to(caller, ladder_reply);
 489                         return; // never fall through to usage
 490                 }
 491
 492                 default:
 493                 case CMD_REQUEST_USAGE:
 494                 {
 495                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 496                         print_to(caller, "  No arguments required.");
 497                         return;
 498                 }
 499         }
 500 }
 501
 502 void CommonCommand_lsmaps(float request, entity caller)
 503 {
 504         switch(request)
 505         {
 506                 case CMD_REQUEST_COMMAND:
 507                 {
 508                         print_to(caller, lsmaps_reply);
 509                         return; // never fall through to usage
 510                 }
 511
 512                 default:
 513                 case CMD_REQUEST_USAGE:
 514                 {
 515                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 516                         print_to(caller, "  No arguments required.");
 517                         return;
 518                 }
 519         }
 520 }
 521
 522 void CommonCommand_printmaplist(float request, entity caller)
 523 {
 524         switch(request)
 525         {
 526                 case CMD_REQUEST_COMMAND:
 527                 {
 528                         print_to(caller, maplist_reply);
 529                         return; // never fall through to usage
 530                 }
 531
 532                 default:
 533                 case CMD_REQUEST_USAGE:
 534                 {
 535                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 536                         print_to(caller, "  No arguments required.");
 537                         return;
 538                 }
 539         }
 540 }
 541
 542 void CommonCommand_rankings(float request, entity caller)
 543 {
 544         switch(request)
 545         {
 546                 case CMD_REQUEST_COMMAND:
 547                 {
 548                         print_to(caller, rankings_reply);
 549                         return; // never fall through to usage
 550                 }
 551
 552                 default:
 553                 case CMD_REQUEST_USAGE:
 554                 {
 555                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 556                         print_to(caller, "  No arguments required.");
 557                         return;
 558                 }
 559         }
 560 }
 561
 562 void CommonCommand_records(float request, entity caller)
 563 {
 564         switch(request)
 565         {
 566                 case CMD_REQUEST_COMMAND:
 567                 {
 568                         for(int i = 0; i < 10; ++i)
 569                                 if(records_reply[i] != "")
 570                                         print_to(caller, records_reply[i]);
 571
 572                         return; // never fall through to usage
 573                 }
 574
 575                 default:
 576                 case CMD_REQUEST_USAGE:
 577                 {
 578                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 579                         print_to(caller, "  No arguments required.");
 580                         return;
 581                 }
 582         }
 583 }
 584
 585 void CommonCommand_teamstatus(float request, entity caller)
 586 {
 587         switch(request)
 588         {
 589                 case CMD_REQUEST_COMMAND:
 590                 {
 591                         Score_NicePrint(caller);
 592                         return; // never fall through to usage
 593                 }
 594
 595                 default:
 596                 case CMD_REQUEST_USAGE:
 597                 {
 598                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 599                         print_to(caller, "  No arguments required.");
 600                         return;
 601                 }
 602         }
 603 }
 604
 605 void CommonCommand_time(float request, entity caller)
 606 {
 607         switch(request)
 608         {
 609                 case CMD_REQUEST_COMMAND:
 610                 {
 611                         print_to(caller, strcat("time = ", ftos(time)));
 612                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 613                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 614                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 615                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 616                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 617                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 618                         return;
 619                 }
 620
 621                 default:
 622                 case CMD_REQUEST_USAGE:
 623                 {
 624                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 625                         print_to(caller, "  No arguments required.");
 626                         return;
 627                 }
 628         }
 629 }
 630
 631 void CommonCommand_timein(float request, entity caller)
 632 {
 633         switch(request)
 634         {
 635                 case CMD_REQUEST_COMMAND:
 636                 {
 637                         if(!caller || autocvar_sv_timeout)
 638                         {
 639                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 640                                 else if(caller && (caller != timeout_caller)) { print_to(caller, "^7Error: You are not allowed to stop the active timeout."); }
 641
 642                                 else // everything should be okay, continue aborting timeout
 643                                 {
 644                                         switch(timeout_status)
 645                                         {
 646                                                 case TIMEOUT_LEADTIME:
 647                                                 {
 648                                                         timeout_status = TIMEOUT_INACTIVE;
 649                                                         timeout_time = 0;
 650                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 651                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 652                                                         return;
 653                                                 }
 654
 655                                                 case TIMEOUT_ACTIVE:
 656                                                 {
 657                                                         timeout_time = autocvar_sv_timeout_resumetime;
 658                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 659                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 660                                                         return;
 661                                                 }
 662
 663                                                 default: dprint("timeout status was inactive, but this code was executed anyway?"); return;
 664                                         }
 665                                 }
 666                         }
 667                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 668
 669                         return; // never fall through to usage
 670                 }
 671
 672                 default:
 673                 case CMD_REQUEST_USAGE:
 674                 {
 675                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 676                         print_to(caller, "  No arguments required.");
 677                         return;
 678                 }
 679         }
 680 }
 681
 682 void CommonCommand_timeout(float request, entity caller) // DEAR GOD THIS COMMAND IS TERRIBLE.
 683 {
 684         switch(request)
 685         {
 686                 case CMD_REQUEST_COMMAND:
 687                 {
 688                         if(!caller || autocvar_sv_timeout)
 689                         {
 690                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 691
 692                                 if(timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 693                                 else if(vote_called) { print_to(caller, "^7Error: You can not call a timeout while a vote is active."); }
 694                                 else if(warmup_stage && !g_warmup_allow_timeout) { print_to(caller, "^7Error: You can not call a timeout in warmup-stage."); }
 695                                 else if(time < game_starttime) { print_to(caller, "^7Error: You can not call a timeout while the map is being restarted."); }
 696                                 else if(caller && (caller.allowed_timeouts < 1)) { print_to(caller, "^7Error: You already used all your timeout calls for this map."); }
 697                                 else if(caller && !IS_PLAYER(caller)) { print_to(caller, "^7Error: You must be a player to call a timeout."); }
 698                                 else if((autocvar_timelimit) && (last_possible_timeout < time - game_starttime)) { print_to(caller, "^7Error: It is too late to call a timeout now!"); }
 699
 700                                 else // everything should be okay, proceed with starting the timeout
 701                                 {
 702                                         if(caller) { caller.allowed_timeouts -= 1; }
 703
 704                                         // write a bprint who started the timeout (and how many they have left)
 705                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 706
 707                                         timeout_status = TIMEOUT_LEADTIME;
 708                                         timeout_caller = caller;
 709                                         timeout_time = autocvar_sv_timeout_length;
 710                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 711
 712                                         timeout_handler = spawn();
 713                                         timeout_handler.think = timeout_handler_think;
 714                                         timeout_handler.nextthink = time; // always let the entity think asap
 715
 716                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 717                                 }
 718                         }
 719                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 720
 721                         return; // never fall through to usage
 722                 }
 723
 724                 default:
 725                 case CMD_REQUEST_USAGE:
 726                 {
 727                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 728                         print_to(caller, "  No arguments required.");
 729                         return;
 730                 }
 731         }
 732 }
 733
 734 void CommonCommand_who(float request, entity caller, float argc)
 735 {
 736         switch(request)
 737         {
 738                 case CMD_REQUEST_COMMAND:
 739                 {
 740                         float total_listed_players, is_bot;
 741                         entity tmp_player;
 742
 743                         float privacy = (caller && autocvar_sv_status_privacy);
 744                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 745                         string tmp_netaddress, tmp_crypto_idfp;
 746
 747                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 748                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 749                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 750
 751                         total_listed_players = 0;
 752                         FOR_EACH_CLIENT(tmp_player)
 753                         {
 754                                 is_bot = (IS_BOT_CLIENT(tmp_player));
 755
 756                                 if(is_bot)
 757                                 {
 758                                         tmp_netaddress = "null/botclient";
 759                                         tmp_crypto_idfp = "null/botclient";
 760                                 }
 761                                 else if(privacy)
 762                                 {
 763                                         tmp_netaddress = "hidden";
 764                                         tmp_crypto_idfp = "hidden";
 765                                 }
 766                                 else
 767                                 {
 768                                         tmp_netaddress = tmp_player.netaddress;
 769                                         tmp_crypto_idfp = tmp_player.crypto_idfp;
 770                                 }
 771
 772                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 773                                         num_for_edict(tmp_player),
 774                                         tmp_player.netname,
 775                                         tmp_player.ping,
 776                                         tmp_player.ping_packetloss,
 777                                         process_time(1, time - tmp_player.jointime),
 778                                         tmp_netaddress,
 779                                         tmp_crypto_idfp));
 780
 781                                 ++total_listed_players;
 782                         }
 783
 784                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 785
 786                         return; // never fall through to usage
 787                 }
 788
 789                 default:
 790                 case CMD_REQUEST_USAGE:
 791                 {
 792                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 793                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 794                         return;
 795                 }
 796         }
 797 }
 798
 799 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 800 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 801 void CommonCommand_(float request, entity caller)
 802 {
 803         switch(request)
 804         {
 805                 case CMD_REQUEST_COMMAND:
 806                 {
 807
 808                         return; // never fall through to usage
 809                 }
 810
 811                 default:
 812                 case CMD_REQUEST_USAGE:
 813                 {
 814                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 815                         print_to(caller, "  No arguments required.");
 816                         return;
 817                 }
 818         }
 819 }
 820 */