qcsrc/server/command/common.qc

   1 #include "common.qh"
   2 #include <common/command/_mod.qh>
   3 #include "common.qh"
   4
   5 #include "../scores.qh"
   6
   7 #include <common/monsters/_mod.qh>
   8 #include <common/notifications/all.qh>
   9 #include <lib/warpzone/common.qh>
  10
  11
  12 // ====================================================
  13 //  Shared code for server commands, written by Samual
  14 //  Last updated: December 27th, 2011
  15 // ====================================================
  16
  17 // select the proper prefix for usage and other messages
  18 string GetCommandPrefix(entity caller)
  19 {
  20         if (caller) return "cmd";
  21         else return "sv_cmd";
  22 }
  23
  24 // if client return player nickname, or if server return admin nickname
  25 string GetCallerName(entity caller)
  26 {
  27         if (caller) return caller.netname;
  28         else return admin_name();  // ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  29 }
  30
  31 // verify that the client provided is acceptable for kicking
  32 float VerifyKickableEntity(entity client)
  33 {
  34         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  35         return CLIENT_ACCEPTABLE;
  36 }
  37
  38 // verify that the client provided is acceptable for use
  39 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  40 {
  41         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  42         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  43         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  44
  45         return CLIENT_ACCEPTABLE;
  46 }
  47
  48 // if the client is not acceptable, return a string to be used for error messages
  49 string GetClientErrorString_color(float clienterror, string original_input, string col)
  50 {
  51         switch (clienterror)
  52         {
  53                 case CLIENT_DOESNT_EXIST:
  54                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  55                 }
  56                 case CLIENT_NOT_REAL:
  57                 { return strcat(col, "Client '", original_input, col, "' is not real");
  58                 }
  59                 case CLIENT_NOT_BOT:
  60                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  61                 }
  62                 default:
  63                 { return "Incorrect usage of GetClientErrorString";
  64                 }
  65         }
  66 }
  67
  68 // is this entity number even in the possible range of entities?
  69 float VerifyClientNumber(float tmp_number)
  70 {
  71         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  72         else return true;
  73 }
  74
  75 entity GetIndexedEntity(float argc, float start_index)
  76 {
  77         entity selection;
  78         float tmp_number, index;
  79         string tmp_string;
  80
  81         next_token = -1;
  82         index = start_index;
  83         selection = NULL;
  84
  85         if (argc > start_index)
  86         {
  87                 if (substring(argv(index), 0, 1) == "#")
  88                 {
  89                         tmp_string = substring(argv(index), 1, -1);
  90                         ++index;
  91
  92                         if (tmp_string != "")  // is it all one token? like #1
  93                         {
  94                                 tmp_number = stof(tmp_string);
  95                         }
  96                         else if (argc > index)  // no, it's two tokens? # 1
  97                         {
  98                                 tmp_number = stof(argv(index));
  99                                 ++index;
 100                         }
 101                         else
 102                         {
 103                                 tmp_number = 0;
 104                         }
 105                 }
 106                 else  // maybe it's ONLY a number?
 107                 {
 108                         tmp_number = stof(argv(index));
 109                         ++index;
 110                 }
 111
 112                 if (VerifyClientNumber(tmp_number))
 113                 {
 114                         selection = edict_num(tmp_number);  // yes, it was a number
 115                 }
 116                 else  // no, maybe it's a name?
 117                 {
 118                         FOREACH_CLIENT(true, LAMBDA(
 119                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 120                                 {
 121                                         selection = it;
 122                                         break; // no reason to keep looking
 123                                 }
 124                         ));
 125
 126                         index = (start_index + 1);
 127                 }
 128         }
 129
 130         next_token = index;
 131         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 132         return selection;
 133 }
 134
 135 // find a player which matches the input string, and return their entity
 136 entity GetFilteredEntity(string input)
 137 {
 138         entity selection;
 139         float tmp_number;
 140
 141         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 142         else tmp_number = stof(input);
 143
 144         if (VerifyClientNumber(tmp_number))
 145         {
 146                 selection = edict_num(tmp_number);
 147         }
 148         else
 149         {
 150                 selection = NULL;
 151                 FOREACH_CLIENT(true, LAMBDA(
 152                         if(strdecolorize(it.netname) == strdecolorize(input))
 153                         {
 154                                 selection = it;
 155                                 break; // no reason to keep looking
 156                         }
 157                 ));
 158         }
 159
 160         return selection;
 161 }
 162
 163 // same thing, but instead return their edict number
 164 float GetFilteredNumber(string input)
 165 {
 166         entity selection = GetFilteredEntity(input);
 167         float output;
 168
 169         output = etof(selection);
 170
 171         return output;
 172 }
 173
 174 // switch between sprint and print depending on whether the receiver is the server or a player
 175 void print_to(entity to, string input)
 176 {
 177         if (to) sprint(to, strcat(input, "\n"));
 178         else LOG_INFO(input, "\n");
 179 }
 180
 181 // ==========================================
 182 //  Supporting functions for common commands
 183 // ==========================================
 184
 185 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 186 void timeout_handler_reset(entity this)
 187 {
 188         timeout_caller = NULL;
 189         timeout_time = 0;
 190         timeout_leadtime = 0;
 191
 192         delete(this);
 193 }
 194
 195 void timeout_handler_think(entity this)
 196 {
 197         switch (timeout_status)
 198         {
 199                 case TIMEOUT_ACTIVE:
 200                 {
 201                         if (timeout_time > 0)  // countdown is still going
 202                         {
 203                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 204
 205                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 206                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_PREPARE);
 207
 208                                 this.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 209                                 timeout_time -= 1;                                  // decrease the time counter
 210                         }
 211                         else  // time to end the timeout
 212                         {
 213                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_TIMEIN);
 214                                 timeout_status = TIMEOUT_INACTIVE;
 215
 216                                 // reset the slowmo value back to normal
 217                                 cvar_set("slowmo", ftos(orig_slowmo));
 218
 219                                 // unlock the view for players so they can move around again
 220                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 221                                         it.fixangle = false;
 222                                 ));
 223
 224                                 timeout_handler_reset(this);
 225                         }
 226
 227                         return;
 228                 }
 229
 230                 case TIMEOUT_LEADTIME:
 231                 {
 232                         if (timeout_leadtime > 0)  // countdown is still going
 233                         {
 234                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 235
 236                                 this.nextthink = time + 1; // think again in one second
 237                                 timeout_leadtime -= 1;     // decrease the time counter
 238                         }
 239                         else  // time to begin the timeout
 240                         {
 241                                 timeout_status = TIMEOUT_ACTIVE;
 242
 243                                 // set the slowmo value to the timeout default slowmo value
 244                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 245
 246                                 // reset all the flood variables
 247                                 FOREACH_CLIENT(true, LAMBDA(
 248                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 249                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 250                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 251                                 ));
 252
 253                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 254                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 255                                         it.lastV_angle = it.v_angle;
 256                                 ));
 257
 258                                 this.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 259                         }
 260
 261                         return;
 262                 }
 263
 264
 265                 case TIMEOUT_INACTIVE:
 266                 default:
 267                 {
 268                         timeout_handler_reset(this);
 269                         return;
 270                 }
 271         }
 272 }
 273
 274
 275 // ===================================================
 276 //  Common commands used in both sv_cmd.qc and cmd.qc
 277 // ===================================================
 278
 279 void CommonCommand_cvar_changes(float request, entity caller)
 280 {
 281         switch (request)
 282         {
 283                 case CMD_REQUEST_COMMAND:
 284                 {
 285                         print_to(caller, cvar_changes);
 286                         return;  // never fall through to usage
 287                 }
 288
 289                 default:
 290                 case CMD_REQUEST_USAGE:
 291                 {
 292                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 293                         print_to(caller, "  No arguments required.");
 294                         print_to(caller, "See also: ^2cvar_purechanges^7");
 295                         return;
 296                 }
 297         }
 298 }
 299
 300 void CommonCommand_cvar_purechanges(float request, entity caller)
 301 {
 302         switch (request)
 303         {
 304                 case CMD_REQUEST_COMMAND:
 305                 {
 306                         print_to(caller, cvar_purechanges);
 307                         return;  // never fall through to usage
 308                 }
 309
 310                 default:
 311                 case CMD_REQUEST_USAGE:
 312                 {
 313                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 314                         print_to(caller, "  No arguments required.");
 315                         print_to(caller, "See also: ^2cvar_changes^7");
 316                         return;
 317                 }
 318         }
 319 }
 320
 321 void CommonCommand_editmob(int request, entity caller, int argc)
 322 {
 323         switch (request)
 324         {
 325                 case CMD_REQUEST_COMMAND:
 326                 {
 327                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 328                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 329
 330                         if (caller)
 331                         {
 332                                 makevectors(caller.v_angle);
 333                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 334                         }
 335
 336                         entity mon = trace_ent;
 337                         bool is_visible = IS_MONSTER(mon);
 338                         string argument = argv(2);
 339
 340                         switch (argv(1))
 341                         {
 342                                 case "name":
 343                                 {
 344                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 345                                         if (!argument)   break;  // escape to usage
 346                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 347                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 348                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 349
 350                                         string mon_oldname = mon.monster_name;
 351
 352                                         mon.monster_name = argument;
 353                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 354                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 355                                         return;
 356                                 }
 357                                 case "spawn":
 358                                 {
 359                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 360                                         if (!argv(2))   break;  // escape to usage
 361
 362                                         int moveflag, tmp_moncount = 0;
 363                                         string arg_lower = strtolower(argument);
 364                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 365
 366                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 367
 368                                         IL_EACH(g_monsters, it.realowner == caller,
 369                                         {
 370                                                 ++tmp_moncount;
 371                                         });
 372
 373                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 374                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 375                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 376                                         if (MUTATOR_CALLHOOK(AllowMobSpawning, caller)) { print_to(caller, M_ARGV(1, string)); return; }
 377                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 378                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 379                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 380                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 381                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 382
 383                                         bool found = false;
 384                                         FOREACH(Monsters, it != MON_Null && it.netname == arg_lower,
 385                                         {
 386                                                 found = true;
 387                                                 break;
 388                                         });
 389
 390                                         if (!found && arg_lower != "random") { print_to(caller, "Invalid monster"); return; }
 391
 392                                         totalspawned += 1;
 393                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 394                                         mon = spawnmonster(spawn(), arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 395                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 396                                         return;
 397                                 }
 398                                 case "kill":
 399                                 {
 400                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 401                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 402                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 403
 404                                         Damage(mon, NULL, NULL, mon.health + mon.max_health + 200, DEATH_KILL.m_id, mon.origin, '0 0 0');
 405                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 406                                         return;
 407                                 }
 408                                 case "skin":
 409                                 {
 410                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 411                                         if (!argument)   break;  // escape to usage
 412                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 413                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 414                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 415                                         if (mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 416
 417                                         mon.skin = stof(argument);
 418                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 419                                         return;
 420                                 }
 421                                 case "movetarget":
 422                                 {
 423                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 424                                         if (!argument)   break;  // escape to usage
 425                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 426                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 427                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 428
 429                                         mon.monster_moveflags = stof(argument);
 430                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 431                                         return;
 432                                 }
 433                                 case "butcher":
 434                                 {
 435                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 436                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(M_ARGV(0, string), "\n"); return; }
 437
 438                                         int tmp_remcount = 0;
 439
 440                                         IL_EACH(g_monsters, true,
 441                                         {
 442                                                 Monster_Remove(it);
 443                                                 ++tmp_remcount;
 444                                         });
 445                                         IL_CLEAR(g_monsters);
 446
 447                                         monsters_total = monsters_killed = totalspawned = 0;
 448
 449                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 450                                         return;
 451                                 }
 452                         }
 453                 }
 454
 455                 default:
 456                 case CMD_REQUEST_USAGE:
 457                 {
 458                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 459                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 460                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 461                         print_to(caller, "  spawn also takes arguments list and random");
 462                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 463                         return;
 464                 }
 465         }
 466 }
 467
 468 void CommonCommand_info(float request, entity caller, float argc)
 469 {
 470         switch (request)
 471         {
 472                 case CMD_REQUEST_COMMAND:
 473                 {
 474                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 475
 476                         if (command) wordwrap_sprint(caller, command, 1000);
 477                         else print_to(caller, "ERROR: unsupported info command");
 478
 479                         return;  // never fall through to usage
 480                 }
 481
 482                 default:
 483                 case CMD_REQUEST_USAGE:
 484                 {
 485                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 486                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 487                         return;
 488                 }
 489         }
 490 }
 491
 492 void CommonCommand_ladder(float request, entity caller)
 493 {
 494         switch (request)
 495         {
 496                 case CMD_REQUEST_COMMAND:
 497                 {
 498                         print_to(caller, ladder_reply);
 499                         return;  // never fall through to usage
 500                 }
 501
 502                 default:
 503                 case CMD_REQUEST_USAGE:
 504                 {
 505                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 506                         print_to(caller, "  No arguments required.");
 507                         return;
 508                 }
 509         }
 510 }
 511
 512 void CommonCommand_lsmaps(float request, entity caller)
 513 {
 514         switch (request)
 515         {
 516                 case CMD_REQUEST_COMMAND:
 517                 {
 518                         print_to(caller, lsmaps_reply);
 519                         return;  // never fall through to usage
 520                 }
 521
 522                 default:
 523                 case CMD_REQUEST_USAGE:
 524                 {
 525                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 526                         print_to(caller, "  No arguments required.");
 527                         return;
 528                 }
 529         }
 530 }
 531
 532 void CommonCommand_printmaplist(float request, entity caller)
 533 {
 534         switch (request)
 535         {
 536                 case CMD_REQUEST_COMMAND:
 537                 {
 538                         print_to(caller, maplist_reply);
 539                         return;  // never fall through to usage
 540                 }
 541
 542                 default:
 543                 case CMD_REQUEST_USAGE:
 544                 {
 545                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 546                         print_to(caller, "  No arguments required.");
 547                         return;
 548                 }
 549         }
 550 }
 551
 552 void CommonCommand_rankings(float request, entity caller)
 553 {
 554         switch (request)
 555         {
 556                 case CMD_REQUEST_COMMAND:
 557                 {
 558                         print_to(caller, rankings_reply);
 559                         return;  // never fall through to usage
 560                 }
 561
 562                 default:
 563                 case CMD_REQUEST_USAGE:
 564                 {
 565                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 566                         print_to(caller, "  No arguments required.");
 567                         return;
 568                 }
 569         }
 570 }
 571
 572 void CommonCommand_records(float request, entity caller)
 573 {
 574         switch (request)
 575         {
 576                 case CMD_REQUEST_COMMAND:
 577                 {
 578                         int num = stoi(argv(1));
 579                         if(num > 0 && num <= 10 && records_reply[num - 1] != "")
 580                                 print_to(caller, records_reply[num - 1]);
 581                         else
 582                         {
 583                                 for (int i = 0; i < 10; ++i)
 584                                         if (records_reply[i] != "") print_to(caller, records_reply[i]);
 585                         }
 586
 587                         return;  // never fall through to usage
 588                 }
 589
 590                 default:
 591                 case CMD_REQUEST_USAGE:
 592                 {
 593                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 594                         print_to(caller, "  No arguments required.");
 595                         return;
 596                 }
 597         }
 598 }
 599
 600 void CommonCommand_teamstatus(float request, entity caller)
 601 {
 602         switch (request)
 603         {
 604                 case CMD_REQUEST_COMMAND:
 605                 {
 606                         Score_NicePrint(caller);
 607                         return;  // never fall through to usage
 608                 }
 609
 610                 default:
 611                 case CMD_REQUEST_USAGE:
 612                 {
 613                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 614                         print_to(caller, "  No arguments required.");
 615                         return;
 616                 }
 617         }
 618 }
 619
 620 void CommonCommand_time(float request, entity caller)
 621 {
 622         switch (request)
 623         {
 624                 case CMD_REQUEST_COMMAND:
 625                 {
 626                         print_to(caller, strcat("time = ", ftos(time)));
 627                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 628                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 629                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 630                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 631                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 632                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 633                         return;
 634                 }
 635
 636                 default:
 637                 case CMD_REQUEST_USAGE:
 638                 {
 639                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 640                         print_to(caller, "  No arguments required.");
 641                         return;
 642                 }
 643         }
 644 }
 645
 646 void CommonCommand_timein(float request, entity caller)
 647 {
 648         switch (request)
 649         {
 650                 case CMD_REQUEST_COMMAND:
 651                 {
 652                         if (!caller || autocvar_sv_timeout)
 653                         {
 654                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 655                                 else if (caller && (caller != timeout_caller))
 656                                 {
 657                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 658                                 }
 659
 660                                 else  // everything should be okay, continue aborting timeout
 661                                 {
 662                                         switch (timeout_status)
 663                                         {
 664                                                 case TIMEOUT_LEADTIME:
 665                                                 {
 666                                                         timeout_status = TIMEOUT_INACTIVE;
 667                                                         timeout_time = 0;
 668                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 669                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 670                                                         return;
 671                                                 }
 672
 673                                                 case TIMEOUT_ACTIVE:
 674                                                 {
 675                                                         timeout_time = autocvar_sv_timeout_resumetime;
 676                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 677                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 678                                                         return;
 679                                                 }
 680
 681                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 682                                                         return;
 683                                         }
 684                                 }
 685                         }
 686                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 687
 688                         return;  // never fall through to usage
 689                 }
 690
 691                 default:
 692                 case CMD_REQUEST_USAGE:
 693                 {
 694                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 695                         print_to(caller, "  No arguments required.");
 696                         return;
 697                 }
 698         }
 699 }
 700
 701 void CommonCommand_timeout(float request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 702 {
 703         switch (request)
 704         {
 705                 case CMD_REQUEST_COMMAND:
 706                 {
 707                         if (!caller || autocvar_sv_timeout)
 708                         {
 709                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 710
 711                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 712                                 else if (vote_called)
 713                                 {
 714                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 715                                 }
 716                                 else if (warmup_stage && !g_warmup_allow_timeout)
 717                                 {
 718                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 719                                 }
 720                                 else if (time < game_starttime)
 721                                 {
 722                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 723                                 }
 724                                 else if (caller && (caller.allowed_timeouts < 1))
 725                                 {
 726                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 727                                 }
 728                                 else if (caller && !IS_PLAYER(caller))
 729                                 {
 730                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 731                                 }
 732                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 733                                 {
 734                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 735                                 }
 736
 737                                 else  // everything should be okay, proceed with starting the timeout
 738                                 {
 739                                         if (caller)   caller.allowed_timeouts -= 1;
 740                                         // write a bprint who started the timeout (and how many they have left)
 741                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 742
 743                                         timeout_status = TIMEOUT_LEADTIME;
 744                                         timeout_caller = caller;
 745                                         timeout_time = autocvar_sv_timeout_length;
 746                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 747
 748                                         timeout_handler = spawn();
 749                                         setthink(timeout_handler, timeout_handler_think);
 750                                         timeout_handler.nextthink = time;  // always let the entity think asap
 751
 752                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_TIMEOUT);
 753                                 }
 754                         }
 755                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 756
 757                         return;  // never fall through to usage
 758                 }
 759
 760                 default:
 761                 case CMD_REQUEST_USAGE:
 762                 {
 763                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 764                         print_to(caller, "  No arguments required.");
 765                         return;
 766                 }
 767         }
 768 }
 769
 770 void CommonCommand_who(float request, entity caller, float argc)
 771 {
 772         switch (request)
 773         {
 774                 case CMD_REQUEST_COMMAND:
 775                 {
 776                         float total_listed_players, is_bot;
 777
 778                         float privacy = (caller && autocvar_sv_status_privacy);
 779                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 780                         string tmp_netaddress, tmp_crypto_idfp;
 781
 782                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 783                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 784                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 785
 786                         total_listed_players = 0;
 787                         FOREACH_CLIENT(true, LAMBDA(
 788                                 is_bot = (IS_BOT_CLIENT(it));
 789
 790                                 if (is_bot)
 791                                 {
 792                                         tmp_netaddress = "null/botclient";
 793                                         tmp_crypto_idfp = "null/botclient";
 794                                 }
 795                                 else if (privacy)
 796                                 {
 797                                         tmp_netaddress = "hidden";
 798                                         tmp_crypto_idfp = "hidden";
 799                                 }
 800                                 else
 801                                 {
 802                                         tmp_netaddress = it.netaddress;
 803                                         tmp_crypto_idfp = it.crypto_idfp;
 804                                 }
 805
 806                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 807                                         etof(it),
 808                                         it.netname,
 809                                         it.ping,
 810                                         it.ping_packetloss,
 811                                         process_time(1, time - it.jointime),
 812                                         tmp_netaddress,
 813                                         tmp_crypto_idfp));
 814
 815                                 ++total_listed_players;
 816                         ));
 817
 818                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 819
 820                         return;  // never fall through to usage
 821                 }
 822
 823                 default:
 824                 case CMD_REQUEST_USAGE:
 825                 {
 826                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 827                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 828                         return;
 829                 }
 830         }
 831 }
 832
 833 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 834 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 835 void CommonCommand_(float request, entity caller)
 836 {
 837     switch(request)
 838     {
 839         case CMD_REQUEST_COMMAND:
 840         {
 841
 842             return; // never fall through to usage
 843         }
 844
 845         default:
 846         case CMD_REQUEST_USAGE:
 847         {
 848             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 849             print_to(caller, "  No arguments required.");
 850             return;
 851         }
 852     }
 853 }
 854 */