qcsrc/server/command/common.qc

   1 #include "common.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7 #include "common.qh"
   8
   9 #include "../scores.qh"
  10
  11 #include <common/monsters/_mod.qh>
  12 #include <common/notifications/all.qh>
  13 #include <lib/warpzone/common.qh>
  14
  15
  16 // ====================================================
  17 //  Shared code for server commands, written by Samual
  18 //  Last updated: December 27th, 2011
  19 // ====================================================
  20
  21 // select the proper prefix for usage and other messages
  22 string GetCommandPrefix(entity caller)
  23 {
  24         if (caller) return "cmd";
  25         else return "sv_cmd";
  26 }
  27
  28 // if client return player nickname, or if server return admin nickname
  29 string GetCallerName(entity caller)
  30 {
  31         if (caller) return playername(caller, false);
  32         else return ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : "SERVER ADMIN"); // autocvar_hostname
  33 }
  34
  35 // verify that the client provided is acceptable for kicking
  36 float VerifyKickableEntity(entity client)
  37 {
  38         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  39         return CLIENT_ACCEPTABLE;
  40 }
  41
  42 // verify that the client provided is acceptable for use
  43 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  44 {
  45         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  46         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  47         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  48
  49         return CLIENT_ACCEPTABLE;
  50 }
  51
  52 // if the client is not acceptable, return a string to be used for error messages
  53 string GetClientErrorString_color(float clienterror, string original_input, string col)
  54 {
  55         switch (clienterror)
  56         {
  57                 case CLIENT_DOESNT_EXIST:
  58                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  59                 }
  60                 case CLIENT_NOT_REAL:
  61                 { return strcat(col, "Client '", original_input, col, "' is not real");
  62                 }
  63                 case CLIENT_NOT_BOT:
  64                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  65                 }
  66                 default:
  67                 { return "Incorrect usage of GetClientErrorString";
  68                 }
  69         }
  70 }
  71
  72 // is this entity number even in the possible range of entities?
  73 float VerifyClientNumber(float tmp_number)
  74 {
  75         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  76         else return true;
  77 }
  78
  79 entity GetIndexedEntity(int argc, float start_index)
  80 {
  81         entity selection;
  82         float tmp_number, index;
  83         string tmp_string;
  84
  85         next_token = -1;
  86         index = start_index;
  87         selection = NULL;
  88
  89         if (argc > start_index)
  90         {
  91                 if (substring(argv(index), 0, 1) == "#")
  92                 {
  93                         tmp_string = substring(argv(index), 1, -1);
  94                         ++index;
  95
  96                         if (tmp_string != "")  // is it all one token? like #1
  97                         {
  98                                 tmp_number = stof(tmp_string);
  99                         }
 100                         else if (argc > index)  // no, it's two tokens? # 1
 101                         {
 102                                 tmp_number = stof(argv(index));
 103                                 ++index;
 104                         }
 105                         else
 106                         {
 107                                 tmp_number = 0;
 108                         }
 109                 }
 110                 else  // maybe it's ONLY a number?
 111                 {
 112                         tmp_number = stof(argv(index));
 113                         ++index;
 114                 }
 115
 116                 if (VerifyClientNumber(tmp_number))
 117                 {
 118                         selection = edict_num(tmp_number);  // yes, it was a number
 119                 }
 120                 else  // no, maybe it's a name?
 121                 {
 122                         FOREACH_CLIENT(true, {
 123                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 124                                 {
 125                                         selection = it;
 126                                         break; // no reason to keep looking
 127                                 }
 128                         });
 129
 130                         index = (start_index + 1);
 131                 }
 132         }
 133
 134         next_token = index;
 135         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 136         return selection;
 137 }
 138
 139 // find a player which matches the input string, and return their entity
 140 entity GetFilteredEntity(string input)
 141 {
 142         entity selection;
 143         float tmp_number;
 144
 145         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 146         else tmp_number = stof(input);
 147
 148         if (VerifyClientNumber(tmp_number))
 149         {
 150                 selection = edict_num(tmp_number);
 151         }
 152         else
 153         {
 154                 selection = NULL;
 155                 FOREACH_CLIENT(true, {
 156                         if(strdecolorize(it.netname) == strdecolorize(input))
 157                         {
 158                                 selection = it;
 159                                 break; // no reason to keep looking
 160                         }
 161                 });
 162         }
 163
 164         return selection;
 165 }
 166
 167 // same thing, but instead return their edict number
 168 float GetFilteredNumber(string input)
 169 {
 170         entity selection = GetFilteredEntity(input);
 171         float output;
 172
 173         output = etof(selection);
 174
 175         return output;
 176 }
 177
 178 // switch between sprint and print depending on whether the receiver is the server or a player
 179 void print_to(entity to, string input)
 180 {
 181         if (to) sprint(to, strcat(input, "\n"));
 182         else print(input, "\n");
 183 }
 184
 185 // ==========================================
 186 //  Supporting functions for common commands
 187 // ==========================================
 188
 189 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 190 void timeout_handler_reset(entity this)
 191 {
 192         timeout_caller = NULL;
 193         timeout_time = 0;
 194         timeout_leadtime = 0;
 195
 196         delete(this);
 197 }
 198
 199 void timeout_handler_think(entity this)
 200 {
 201         switch (timeout_status)
 202         {
 203                 case TIMEOUT_ACTIVE:
 204                 {
 205                         if (timeout_time > 0)  // countdown is still going
 206                         {
 207                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 208
 209                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 210                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_PREPARE);
 211
 212                                 this.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 213                                 timeout_time -= 1;                                  // decrease the time counter
 214                         }
 215                         else  // time to end the timeout
 216                         {
 217                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_TIMEIN);
 218                                 timeout_status = TIMEOUT_INACTIVE;
 219
 220                                 // reset the slowmo value back to normal
 221                                 cvar_set("slowmo", ftos(orig_slowmo));
 222
 223                                 // unlock the view for players so they can move around again
 224                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 225                                         it.fixangle = false;
 226                                 });
 227
 228                                 timeout_handler_reset(this);
 229                         }
 230
 231                         return;
 232                 }
 233
 234                 case TIMEOUT_LEADTIME:
 235                 {
 236                         if (timeout_leadtime > 0)  // countdown is still going
 237                         {
 238                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 239
 240                                 this.nextthink = time + 1; // think again in one second
 241                                 timeout_leadtime -= 1;     // decrease the time counter
 242                         }
 243                         else  // time to begin the timeout
 244                         {
 245                                 timeout_status = TIMEOUT_ACTIVE;
 246
 247                                 // set the slowmo value to the timeout default slowmo value
 248                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 249
 250                                 // reset all the flood variables
 251                                 FOREACH_CLIENT(true, {
 252                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 253                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 254                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 255                                 });
 256
 257                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 258                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 259                                         it.lastV_angle = it.v_angle;
 260                                 });
 261
 262                                 this.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 263                         }
 264
 265                         return;
 266                 }
 267
 268
 269                 case TIMEOUT_INACTIVE:
 270                 default:
 271                 {
 272                         timeout_handler_reset(this);
 273                         return;
 274                 }
 275         }
 276 }
 277
 278
 279 // ===================================================
 280 //  Common commands used in both sv_cmd.qc and cmd.qc
 281 // ===================================================
 282
 283 void CommonCommand_cvar_changes(int request, entity caller)
 284 {
 285         switch (request)
 286         {
 287                 case CMD_REQUEST_COMMAND:
 288                 {
 289                         print_to(caller, cvar_changes);
 290                         return;  // never fall through to usage
 291                 }
 292
 293                 default:
 294                 case CMD_REQUEST_USAGE:
 295                 {
 296                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 297                         print_to(caller, "  No arguments required.");
 298                         print_to(caller, "See also: ^2cvar_purechanges^7");
 299                         return;
 300                 }
 301         }
 302 }
 303
 304 void CommonCommand_cvar_purechanges(int request, entity caller)
 305 {
 306         switch (request)
 307         {
 308                 case CMD_REQUEST_COMMAND:
 309                 {
 310                         print_to(caller, cvar_purechanges);
 311                         return;  // never fall through to usage
 312                 }
 313
 314                 default:
 315                 case CMD_REQUEST_USAGE:
 316                 {
 317                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 318                         print_to(caller, "  No arguments required.");
 319                         print_to(caller, "See also: ^2cvar_changes^7");
 320                         return;
 321                 }
 322         }
 323 }
 324
 325 void CommonCommand_editmob(int request, entity caller, int argc)
 326 {
 327         switch (request)
 328         {
 329                 case CMD_REQUEST_COMMAND:
 330                 {
 331                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 332                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 333
 334                         if (caller)
 335                         {
 336                                 makevectors(caller.v_angle);
 337                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 338                         }
 339
 340                         entity mon = trace_ent;
 341                         bool is_visible = IS_MONSTER(mon);
 342                         string argument = argv(2);
 343
 344                         switch (argv(1))
 345                         {
 346                                 case "name":
 347                                 {
 348                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 349                                         if (!argument)   break;  // escape to usage
 350                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 351                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 352                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 353
 354                                         string mon_oldname = mon.monster_name;
 355
 356                                         mon.monster_name = argument;
 357                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 358                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 359                                         return;
 360                                 }
 361                                 case "spawn":
 362                                 {
 363                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 364                                         if (!argv(2))   break;  // escape to usage
 365
 366                                         int moveflag, tmp_moncount = 0;
 367                                         string arg_lower = strtolower(argument);
 368                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 369
 370                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 371
 372                                         IL_EACH(g_monsters, it.realowner == caller,
 373                                         {
 374                                                 ++tmp_moncount;
 375                                         });
 376
 377                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 378                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 379                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 380                                         if (MUTATOR_CALLHOOK(AllowMobSpawning, caller)) { print_to(caller, M_ARGV(1, string)); return; }
 381                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 382                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 383                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 384                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 385                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 386
 387                                         bool found = false;
 388                                         FOREACH(Monsters, it != MON_Null && it.netname == arg_lower,
 389                                         {
 390                                                 found = true;
 391                                                 break;
 392                                         });
 393
 394                                         if (!found && arg_lower != "random" && arg_lower != "anyrandom") { print_to(caller, "Invalid monster"); return; }
 395
 396                                         totalspawned += 1;
 397                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 398                                         mon = spawnmonster(spawn(), arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 399                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 400                                         return;
 401                                 }
 402                                 case "kill":
 403                                 {
 404                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 405                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 406                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 407
 408                                         Damage(mon, NULL, NULL, GetResourceAmount(mon, RESOURCE_HEALTH) + mon.max_health + 200, DEATH_KILL.m_id, DMG_NOWEP, mon.origin, '0 0 0');
 409                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 410                                         return;
 411                                 }
 412                                 case "skin":
 413                                 {
 414                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 415                                         if (!argument)   break;  // escape to usage
 416                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 417                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 418                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 419                                         if (mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 420
 421                                         mon.skin = stof(argument);
 422                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 423                                         return;
 424                                 }
 425                                 case "movetarget":
 426                                 {
 427                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 428                                         if (!argument)   break;  // escape to usage
 429                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 430                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 431                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 432
 433                                         mon.monster_moveflags = stof(argument);
 434                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 435                                         return;
 436                                 }
 437                                 case "butcher":
 438                                 {
 439                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 440                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFOF("%s", M_ARGV(0, string)); return; }
 441
 442                                         int tmp_remcount = 0;
 443
 444                                         IL_EACH(g_monsters, true,
 445                                         {
 446                                                 Monster_Remove(it);
 447                                                 ++tmp_remcount;
 448                                         });
 449                                         IL_CLEAR(g_monsters);
 450
 451                                         monsters_total = monsters_killed = totalspawned = 0;
 452
 453                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 454                                         return;
 455                                 }
 456                         }
 457                 }
 458
 459                 default:
 460                 case CMD_REQUEST_USAGE:
 461                 {
 462                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 463                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 464                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 465                         print_to(caller, "  spawn also takes arguments list and random");
 466                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 467                         return;
 468                 }
 469         }
 470 }
 471
 472 void CommonCommand_info(int request, entity caller, int argc)
 473 {
 474         switch (request)
 475         {
 476                 case CMD_REQUEST_COMMAND:
 477                 {
 478                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 479
 480                         if (command) wordwrap_sprint(caller, command, 1000);
 481                         else print_to(caller, "ERROR: unsupported info command");
 482
 483                         return;  // never fall through to usage
 484                 }
 485
 486                 default:
 487                 case CMD_REQUEST_USAGE:
 488                 {
 489                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 490                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 491                         return;
 492                 }
 493         }
 494 }
 495
 496 void CommonCommand_ladder(int request, entity caller)
 497 {
 498         switch (request)
 499         {
 500                 case CMD_REQUEST_COMMAND:
 501                 {
 502                         print_to(caller, ladder_reply);
 503                         return;  // never fall through to usage
 504                 }
 505
 506                 default:
 507                 case CMD_REQUEST_USAGE:
 508                 {
 509                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 510                         print_to(caller, "  No arguments required.");
 511                         return;
 512                 }
 513         }
 514 }
 515
 516 void CommonCommand_lsmaps(int request, entity caller)
 517 {
 518         switch (request)
 519         {
 520                 case CMD_REQUEST_COMMAND:
 521                 {
 522                         print_to(caller, lsmaps_reply);
 523                         return;  // never fall through to usage
 524                 }
 525
 526                 default:
 527                 case CMD_REQUEST_USAGE:
 528                 {
 529                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 530                         print_to(caller, "  No arguments required.");
 531                         return;
 532                 }
 533         }
 534 }
 535
 536 void CommonCommand_printmaplist(int request, entity caller)
 537 {
 538         switch (request)
 539         {
 540                 case CMD_REQUEST_COMMAND:
 541                 {
 542                         print_to(caller, maplist_reply);
 543                         return;  // never fall through to usage
 544                 }
 545
 546                 default:
 547                 case CMD_REQUEST_USAGE:
 548                 {
 549                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 550                         print_to(caller, "  No arguments required.");
 551                         return;
 552                 }
 553         }
 554 }
 555
 556 void CommonCommand_rankings(int request, entity caller)
 557 {
 558         switch (request)
 559         {
 560                 case CMD_REQUEST_COMMAND:
 561                 {
 562                         print_to(caller, rankings_reply);
 563                         return;  // never fall through to usage
 564                 }
 565
 566                 default:
 567                 case CMD_REQUEST_USAGE:
 568                 {
 569                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 570                         print_to(caller, "  No arguments required.");
 571                         return;
 572                 }
 573         }
 574 }
 575
 576 void CommonCommand_records(int request, entity caller)
 577 {
 578         switch (request)
 579         {
 580                 case CMD_REQUEST_COMMAND:
 581                 {
 582                         int num = stoi(argv(1));
 583                         if(num > 0 && num <= 10 && records_reply[num - 1] != "")
 584                                 print_to(caller, records_reply[num - 1]);
 585                         else
 586                         {
 587                                 for (int i = 0; i < 10; ++i)
 588                                         if (records_reply[i] != "") print_to(caller, records_reply[i]);
 589                         }
 590
 591                         return;  // never fall through to usage
 592                 }
 593
 594                 default:
 595                 case CMD_REQUEST_USAGE:
 596                 {
 597                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 598                         print_to(caller, "  No arguments required.");
 599                         return;
 600                 }
 601         }
 602 }
 603
 604 void CommonCommand_teamstatus(int request, entity caller)
 605 {
 606         switch (request)
 607         {
 608                 case CMD_REQUEST_COMMAND:
 609                 {
 610                         Score_NicePrint(caller);
 611                         return;  // never fall through to usage
 612                 }
 613
 614                 default:
 615                 case CMD_REQUEST_USAGE:
 616                 {
 617                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 618                         print_to(caller, "  No arguments required.");
 619                         return;
 620                 }
 621         }
 622 }
 623
 624 void CommonCommand_time(int request, entity caller)
 625 {
 626         switch (request)
 627         {
 628                 case CMD_REQUEST_COMMAND:
 629                 {
 630                         print_to(caller, strcat("time = ", ftos(time)));
 631                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 632                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 633                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 634                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 635                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %d %H:%M:%S %Z %Y")));
 636                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %d %H:%M:%S %Z %Y")));
 637                         return;
 638                 }
 639
 640                 default:
 641                 case CMD_REQUEST_USAGE:
 642                 {
 643                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 644                         print_to(caller, "  No arguments required.");
 645                         return;
 646                 }
 647         }
 648 }
 649
 650 void CommonCommand_timein(int request, entity caller)
 651 {
 652         switch (request)
 653         {
 654                 case CMD_REQUEST_COMMAND:
 655                 {
 656                         if (!caller || autocvar_sv_timeout)
 657                         {
 658                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 659                                 else if (caller && (caller != timeout_caller))
 660                                 {
 661                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 662                                 }
 663
 664                                 else  // everything should be okay, continue aborting timeout
 665                                 {
 666                                         switch (timeout_status)
 667                                         {
 668                                                 case TIMEOUT_LEADTIME:
 669                                                 {
 670                                                         timeout_status = TIMEOUT_INACTIVE;
 671                                                         timeout_time = 0;
 672                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 673                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 674                                                         return;
 675                                                 }
 676
 677                                                 case TIMEOUT_ACTIVE:
 678                                                 {
 679                                                         timeout_time = autocvar_sv_timeout_resumetime;
 680                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 681                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 682                                                         return;
 683                                                 }
 684
 685                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 686                                                         return;
 687                                         }
 688                                 }
 689                         }
 690                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 691
 692                         return;  // never fall through to usage
 693                 }
 694
 695                 default:
 696                 case CMD_REQUEST_USAGE:
 697                 {
 698                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 699                         print_to(caller, "  No arguments required.");
 700                         return;
 701                 }
 702         }
 703 }
 704
 705 void CommonCommand_timeout(int request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 706 {
 707         switch (request)
 708         {
 709                 case CMD_REQUEST_COMMAND:
 710                 {
 711                         if (!caller || autocvar_sv_timeout)
 712                         {
 713                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 714
 715                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 716                                 else if (vote_called)
 717                                 {
 718                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 719                                 }
 720                                 else if (warmup_stage && !g_warmup_allow_timeout)
 721                                 {
 722                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 723                                 }
 724                                 else if (time < game_starttime)
 725                                 {
 726                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 727                                 }
 728                                 else if (caller && (CS(caller).allowed_timeouts < 1))
 729                                 {
 730                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 731                                 }
 732                                 else if (caller && !IS_PLAYER(caller))
 733                                 {
 734                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 735                                 }
 736                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 737                                 {
 738                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 739                                 }
 740
 741                                 else  // everything should be okay, proceed with starting the timeout
 742                                 {
 743                                         if (caller)   CS(caller).allowed_timeouts -= 1;
 744                                         // write a bprint who started the timeout (and how many they have left)
 745                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(CS(caller).allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 746
 747                                         timeout_status = TIMEOUT_LEADTIME;
 748                                         timeout_caller = caller;
 749                                         timeout_time = autocvar_sv_timeout_length;
 750                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 751
 752                                         timeout_handler = spawn();
 753                                         setthink(timeout_handler, timeout_handler_think);
 754                                         timeout_handler.nextthink = time;  // always let the entity think asap
 755
 756                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_TIMEOUT);
 757                                 }
 758                         }
 759                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 760
 761                         return;  // never fall through to usage
 762                 }
 763
 764                 default:
 765                 case CMD_REQUEST_USAGE:
 766                 {
 767                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 768                         print_to(caller, "  No arguments required.");
 769                         return;
 770                 }
 771         }
 772 }
 773
 774 void CommonCommand_who(int request, entity caller, int argc)
 775 {
 776         switch (request)
 777         {
 778                 case CMD_REQUEST_COMMAND:
 779                 {
 780                         float total_listed_players, is_bot;
 781
 782                         float privacy = (caller && autocvar_sv_status_privacy);
 783                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 784                         string tmp_netaddress, tmp_crypto_idfp;
 785
 786                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 787                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 788                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 789
 790                         total_listed_players = 0;
 791                         FOREACH_CLIENT(true, {
 792                                 is_bot = (IS_BOT_CLIENT(it));
 793
 794                                 if (is_bot)
 795                                 {
 796                                         tmp_netaddress = "null/botclient";
 797                                         tmp_crypto_idfp = "null/botclient";
 798                                 }
 799                                 else if (privacy)
 800                                 {
 801                                         tmp_netaddress = "hidden";
 802                                         tmp_crypto_idfp = "hidden";
 803                                 }
 804                                 else
 805                                 {
 806                                         tmp_netaddress = it.netaddress;
 807                                         tmp_crypto_idfp = it.crypto_idfp;
 808                                 }
 809
 810                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 811                                         etof(it),
 812                                         it.netname,
 813                                         CS(it).ping,
 814                                         CS(it).ping_packetloss,
 815                                         process_time(1, time - CS(it).jointime),
 816                                         tmp_netaddress,
 817                                         tmp_crypto_idfp));
 818
 819                                 ++total_listed_players;
 820                         });
 821
 822                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 823
 824                         return;  // never fall through to usage
 825                 }
 826
 827                 default:
 828                 case CMD_REQUEST_USAGE:
 829                 {
 830                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 831                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 832                         return;
 833                 }
 834         }
 835 }
 836
 837 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 838 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 839 void CommonCommand_(int request, entity caller)
 840 {
 841     switch(request)
 842     {
 843         case CMD_REQUEST_COMMAND:
 844         {
 845
 846             return; // never fall through to usage
 847         }
 848
 849         default:
 850         case CMD_REQUEST_USAGE:
 851         {
 852             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 853             print_to(caller, "  No arguments required.");
 854             return;
 855         }
 856     }
 857 }
 858 */