qcsrc/server/command/common.qc

   1 // ====================================================
   2 //  Shared code for server commands, written by Samual
   3 //  Last updated: December 27th, 2011
   4 // ====================================================
   5
   6 // select the proper prefix for usage and other messages
   7 string GetCommandPrefix(entity caller)
   8 {
   9         if(caller)
  10                 return "cmd";
  11         else
  12                 return "sv_cmd";
  13 }
  14
  15 // if client return player nickname, or if server return admin nickname
  16 string GetCallerName(entity caller)
  17 {
  18         if(caller)
  19                 return caller.netname;
  20         else
  21                 return admin_name(); //((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  22 }
  23
  24 // verify that the client provided is acceptable for kicking
  25 float VerifyKickableEntity(entity client)
  26 {
  27         if (!IS_REAL_CLIENT(client))
  28                 return CLIENT_NOT_REAL;
  29         return CLIENT_ACCEPTABLE;
  30 }
  31
  32 // verify that the client provided is acceptable for use
  33 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  34 {
  35         if (!IS_CLIENT(client))
  36                 return CLIENT_DOESNT_EXIST;
  37         else if(must_be_real && !IS_REAL_CLIENT(client))
  38                 return CLIENT_NOT_REAL;
  39         else if(must_be_bots && !IS_BOT_CLIENT(client))
  40                 return CLIENT_NOT_BOT;
  41
  42         return CLIENT_ACCEPTABLE;
  43 }
  44
  45 // if the client is not acceptable, return a string to be used for error messages
  46 string GetClientErrorString(float clienterror, string original_input)
  47 {
  48         switch(clienterror)
  49         {
  50                 case CLIENT_DOESNT_EXIST: { return strcat("Client '", original_input, "' doesn't exist"); }
  51                 case CLIENT_NOT_REAL: { return strcat("Client '", original_input, "' is not real"); }
  52                 case CLIENT_NOT_BOT: { return strcat("Client '", original_input, "' is not a bot"); }
  53                 default: { return "Incorrect usage of GetClientErrorString"; }
  54         }
  55 }
  56
  57 // is this entity number even in the possible range of entities?
  58 float VerifyClientNumber(float tmp_number)
  59 {
  60         if((tmp_number < 1) || (tmp_number > maxclients))
  61                 return FALSE;
  62         else
  63                 return TRUE;
  64 }
  65
  66 entity GetIndexedEntity(float argc, float start_index)
  67 {
  68         entity tmp_player, selection;
  69         float tmp_number, index;
  70         string tmp_string;
  71
  72         next_token = -1;
  73         index = start_index;
  74         selection = world;
  75
  76         if(argc > start_index)
  77         {
  78                 if(substring(argv(index), 0, 1) == "#")
  79                 {
  80                         tmp_string = substring(argv(index), 1, -1);
  81                         ++index;
  82
  83                         if(tmp_string != "") // is it all one token? like #1
  84                         {
  85                                 tmp_number = stof(tmp_string);
  86                         }
  87                         else if(argc > index) // no, it's two tokens? # 1
  88                         {
  89                                 tmp_number = stof(argv(index));
  90                                 ++index;
  91                         }
  92                         else
  93                                 tmp_number = 0;
  94                 }
  95                 else // maybe it's ONLY a number?
  96                 {
  97                         tmp_number = stof(argv(index));
  98                         ++index;
  99                 }
 100
 101                 if(VerifyClientNumber(tmp_number))
 102                 {
 103                         selection = edict_num(tmp_number); // yes, it was a number
 104                 }
 105                 else // no, maybe it's a name?
 106                 {
 107                         FOR_EACH_CLIENT(tmp_player)
 108                                 if (strdecolorize(tmp_player.netname) == strdecolorize(argv(start_index)))
 109                                         selection = tmp_player;
 110
 111                         index = (start_index + 1);
 112                 }
 113         }
 114
 115         next_token = index;
 116         //print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 117         return selection;
 118 }
 119
 120 // find a player which matches the input string, and return their entity
 121 entity GetFilteredEntity(string input)
 122 {
 123         entity tmp_player, selection;
 124         float tmp_number;
 125
 126         if(substring(input, 0, 1) == "#")
 127                 tmp_number = stof(substring(input, 1, -1));
 128         else
 129                 tmp_number = stof(input);
 130
 131         if(VerifyClientNumber(tmp_number))
 132         {
 133                 selection = edict_num(tmp_number);
 134         }
 135         else
 136         {
 137                 selection = world;
 138                 FOR_EACH_CLIENT(tmp_player)
 139                         if (strdecolorize(tmp_player.netname) == strdecolorize(input))
 140                                 selection = tmp_player;
 141         }
 142
 143         return selection;
 144 }
 145
 146 // same thing, but instead return their edict number
 147 float GetFilteredNumber(string input)
 148 {
 149         entity selection = GetFilteredEntity(input);
 150         float output;
 151
 152         output = num_for_edict(selection);
 153
 154         return output;
 155 }
 156
 157 // switch between sprint and print depending on whether the receiver is the server or a player
 158 void print_to(entity to, string input)
 159 {
 160     if(to)
 161         sprint(to, strcat(input, "\n"));
 162     else
 163         print(input, "\n");
 164 }
 165
 166 // ==========================================
 167 //  Supporting functions for common commands
 168 // ==========================================
 169
 170 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 171 void timeout_handler_reset()
 172 {
 173         timeout_caller = world;
 174         timeout_time = 0;
 175         timeout_leadtime = 0;
 176
 177         remove(self);
 178 }
 179
 180 void timeout_handler_think()
 181 {
 182         entity tmp_player;
 183
 184         switch(timeout_status)
 185         {
 186                 case TIMEOUT_ACTIVE:
 187                 {
 188                         if(timeout_time > 0) // countdown is still going
 189                         {
 190                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 191
 192                                 if(timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 193                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 194
 195                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE; // think again in one second
 196                                 timeout_time -= 1; // decrease the time counter
 197                         }
 198                         else // time to end the timeout
 199                         {
 200                                 timeout_status = TIMEOUT_INACTIVE;
 201
 202                                 // reset the slowmo value back to normal
 203                                 cvar_set("slowmo", ftos(orig_slowmo));
 204
 205                                 // unlock the view for players so they can move around again
 206                                 FOR_EACH_REALPLAYER(tmp_player)
 207                                         tmp_player.fixangle = FALSE;
 208
 209                                 timeout_handler_reset();
 210                         }
 211
 212                         return;
 213                 }
 214
 215                 case TIMEOUT_LEADTIME:
 216                 {
 217                         if(timeout_leadtime > 0) // countdown is still going
 218                         {
 219                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 220
 221                                 self.nextthink = time + 1; // think again in one second
 222                                 timeout_leadtime -= 1; // decrease the time counter
 223                         }
 224                         else // time to begin the timeout
 225                         {
 226                                 timeout_status = TIMEOUT_ACTIVE;
 227
 228                                 // set the slowmo value to the timeout default slowmo value
 229                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 230
 231                                 // reset all the flood variables
 232                                 FOR_EACH_CLIENT(tmp_player)
 233                                         tmp_player.nickspamcount = tmp_player.nickspamtime = tmp_player.floodcontrol_chat =
 234                                         tmp_player.floodcontrol_chatteam = tmp_player.floodcontrol_chattell =
 235                                         tmp_player.floodcontrol_voice = tmp_player.floodcontrol_voiceteam = 0;
 236
 237                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 238                                 FOR_EACH_REALPLAYER(tmp_player)
 239                                         tmp_player.lastV_angle = tmp_player.v_angle;
 240
 241                                 self.nextthink = time; // think again next frame to handle it under TIMEOUT_ACTIVE code
 242                         }
 243
 244                         return;
 245                 }
 246
 247
 248                 case TIMEOUT_INACTIVE:
 249                 default:
 250                 {
 251                         timeout_handler_reset();
 252                         return;
 253                 }
 254         }
 255 }
 256
 257
 258
 259 // ===================================================
 260 //  Common commands used in both sv_cmd.qc and cmd.qc
 261 // ===================================================
 262
 263 void CommonCommand_cvar_changes(float request, entity caller)
 264 {
 265         switch(request)
 266         {
 267                 case CMD_REQUEST_COMMAND:
 268                 {
 269                         print_to(caller, cvar_changes);
 270                         return; // never fall through to usage
 271                 }
 272
 273                 default:
 274                 case CMD_REQUEST_USAGE:
 275                 {
 276                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 277                         print_to(caller, "  No arguments required.");
 278                         print_to(caller, "See also: ^2cvar_purechanges^7");
 279                         return;
 280                 }
 281         }
 282 }
 283
 284 void CommonCommand_cvar_purechanges(float request, entity caller)
 285 {
 286         switch(request)
 287         {
 288                 case CMD_REQUEST_COMMAND:
 289                 {
 290                         print_to(caller, cvar_purechanges);
 291                         return; // never fall through to usage
 292                 }
 293
 294                 default:
 295                 case CMD_REQUEST_USAGE:
 296                 {
 297                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 298                         print_to(caller, "  No arguments required.");
 299                         print_to(caller, "See also: ^2cvar_changes^7");
 300                         return;
 301                 }
 302         }
 303 }
 304
 305 void CommonCommand_info(float request, entity caller, float argc)
 306 {
 307         switch(request)
 308         {
 309                 case CMD_REQUEST_COMMAND:
 310                 {
 311                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 312
 313                         if(command)
 314                                 wordwrap_sprint(command, 1000);
 315                         else
 316                                 print_to(caller, "ERROR: unsupported info command");
 317
 318                         return; // never fall through to usage
 319                 }
 320
 321                 default:
 322                 case CMD_REQUEST_USAGE:
 323                 {
 324                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 325                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 326                         return;
 327                 }
 328         }
 329 }
 330
 331 void CommonCommand_ladder(float request, entity caller)
 332 {
 333         switch(request)
 334         {
 335                 case CMD_REQUEST_COMMAND:
 336                 {
 337                         print_to(caller, ladder_reply);
 338                         return; // never fall through to usage
 339                 }
 340
 341                 default:
 342                 case CMD_REQUEST_USAGE:
 343                 {
 344                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 345                         print_to(caller, "  No arguments required.");
 346                         return;
 347                 }
 348         }
 349 }
 350
 351 void CommonCommand_lsmaps(float request, entity caller)
 352 {
 353         switch(request)
 354         {
 355                 case CMD_REQUEST_COMMAND:
 356                 {
 357                         print_to(caller, lsmaps_reply);
 358                         return; // never fall through to usage
 359                 }
 360
 361                 default:
 362                 case CMD_REQUEST_USAGE:
 363                 {
 364                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 365                         print_to(caller, "  No arguments required.");
 366                         return;
 367                 }
 368         }
 369 }
 370
 371 void CommonCommand_printmaplist(float request, entity caller)
 372 {
 373         switch(request)
 374         {
 375                 case CMD_REQUEST_COMMAND:
 376                 {
 377                         print_to(caller, maplist_reply);
 378                         return; // never fall through to usage
 379                 }
 380
 381                 default:
 382                 case CMD_REQUEST_USAGE:
 383                 {
 384                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 385                         print_to(caller, "  No arguments required.");
 386                         return;
 387                 }
 388         }
 389 }
 390
 391 void CommonCommand_rankings(float request, entity caller)
 392 {
 393         switch(request)
 394         {
 395                 case CMD_REQUEST_COMMAND:
 396                 {
 397                         print_to(caller, rankings_reply);
 398                         return; // never fall through to usage
 399                 }
 400
 401                 default:
 402                 case CMD_REQUEST_USAGE:
 403                 {
 404                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 405                         print_to(caller, "  No arguments required.");
 406                         return;
 407                 }
 408         }
 409 }
 410
 411 void CommonCommand_records(float request, entity caller)
 412 {
 413         switch(request)
 414         {
 415                 case CMD_REQUEST_COMMAND:
 416                 {
 417                         float i;
 418
 419                         for(i = 0; i < 10; ++i)
 420                                 if(records_reply[i] != "")
 421                                         print_to(caller, records_reply[i]);
 422
 423                         return; // never fall through to usage
 424                 }
 425
 426                 default:
 427                 case CMD_REQUEST_USAGE:
 428                 {
 429                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 430                         print_to(caller, "  No arguments required.");
 431                         return;
 432                 }
 433         }
 434 }
 435
 436 void CommonCommand_teamstatus(float request, entity caller)
 437 {
 438         switch(request)
 439         {
 440                 case CMD_REQUEST_COMMAND:
 441                 {
 442                         Score_NicePrint(caller);
 443                         return; // never fall through to usage
 444                 }
 445
 446                 default:
 447                 case CMD_REQUEST_USAGE:
 448                 {
 449                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 450                         print_to(caller, "  No arguments required.");
 451                         return;
 452                 }
 453         }
 454 }
 455
 456 void CommonCommand_time(float request, entity caller)
 457 {
 458         switch(request)
 459         {
 460                 case CMD_REQUEST_COMMAND:
 461                 {
 462                         print_to(caller, strcat("time = ", ftos(time)));
 463                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 464                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 465                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 466                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 467                         print_to(caller, strcat("localtime = ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y")));
 468                         print_to(caller, strcat("gmtime = ", strftime(FALSE, "%a %b %e %H:%M:%S %Z %Y")));
 469                         return;
 470                 }
 471
 472                 default:
 473                 case CMD_REQUEST_USAGE:
 474                 {
 475                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 476                         print_to(caller, "  No arguments required.");
 477                         return;
 478                 }
 479         }
 480 }
 481
 482 void CommonCommand_timein(float request, entity caller)
 483 {
 484         switch(request)
 485         {
 486                 case CMD_REQUEST_COMMAND:
 487                 {
 488                         if(!caller || autocvar_sv_timeout)
 489                         {
 490                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 491                                 else if(caller && (caller != timeout_caller)) { print_to(caller, "^7Error: You are not allowed to stop the active timeout."); }
 492
 493                                 else // everything should be okay, continue aborting timeout
 494                                 {
 495                                         switch(timeout_status)
 496                                         {
 497                                                 case TIMEOUT_LEADTIME:
 498                                                 {
 499                                                         timeout_status = TIMEOUT_INACTIVE;
 500                                                         timeout_time = 0;
 501                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 502                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 503                                                         return;
 504                                                 }
 505
 506                                                 case TIMEOUT_ACTIVE:
 507                                                 {
 508                                                         timeout_time = autocvar_sv_timeout_resumetime;
 509                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 510                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 511                                                         return;
 512                                                 }
 513
 514                                                 default: dprint("timeout status was inactive, but this code was executed anyway?"); return;
 515                                         }
 516                                 }
 517                         }
 518                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 519
 520                         return; // never fall through to usage
 521                 }
 522
 523                 default:
 524                 case CMD_REQUEST_USAGE:
 525                 {
 526                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 527                         print_to(caller, "  No arguments required.");
 528                         return;
 529                 }
 530         }
 531 }
 532
 533 void CommonCommand_timeout(float request, entity caller) // DEAR GOD THIS COMMAND IS TERRIBLE.
 534 {
 535         switch(request)
 536         {
 537                 case CMD_REQUEST_COMMAND:
 538                 {
 539                         if(!caller || autocvar_sv_timeout)
 540                         {
 541                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 542
 543                                 if(timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 544                                 else if(vote_called) { print_to(caller, "^7Error: You can not call a timeout while a vote is active."); }
 545                                 else if(warmup_stage && !g_warmup_allow_timeout) { print_to(caller, "^7Error: You can not call a timeout in warmup-stage."); }
 546                                 else if(time < game_starttime) { print_to(caller, "^7Error: You can not call a timeout while the map is being restarted."); }
 547                                 else if(caller && (caller.allowed_timeouts < 1)) { print_to(caller, "^7Error: You already used all your timeout calls for this map."); }
 548                                 else if(caller && !IS_PLAYER(caller)) { print_to(caller, "^7Error: You must be a player to call a timeout."); }
 549                                 else if((autocvar_timelimit) && (last_possible_timeout < time - game_starttime)) { print_to(caller, "^7Error: It is too late to call a timeout now!"); }
 550
 551                                 else // everything should be okay, proceed with starting the timeout
 552                                 {
 553                                         if(caller) { caller.allowed_timeouts -= 1; }
 554
 555                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n"); // write a bprint who started the timeout (and how many they have left)
 556
 557                                         timeout_status = TIMEOUT_LEADTIME;
 558                                         timeout_caller = caller;
 559                                         timeout_time = autocvar_sv_timeout_length;
 560                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 561
 562                                         timeout_handler = spawn();
 563                                         timeout_handler.think = timeout_handler_think;
 564                                         timeout_handler.nextthink = time; // always let the entity think asap
 565
 566                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 567                                 }
 568                         }
 569                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 570
 571                         return; // never fall through to usage
 572                 }
 573
 574                 default:
 575                 case CMD_REQUEST_USAGE:
 576                 {
 577                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 578                         print_to(caller, "  No arguments required.");
 579                         return;
 580                 }
 581         }
 582 }
 583
 584 void CommonCommand_who(float request, entity caller, float argc)
 585 {
 586         switch(request)
 587         {
 588                 case CMD_REQUEST_COMMAND:
 589                 {
 590                         float total_listed_players, is_bot;
 591                         entity tmp_player;
 592
 593                         float privacy = (caller && autocvar_sv_status_privacy);
 594                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 595                         string tmp_netaddress, tmp_crypto_idfp;
 596
 597                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 598                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 599                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 600
 601                         total_listed_players = 0;
 602                         FOR_EACH_CLIENT(tmp_player)
 603                         {
 604                                 is_bot = (IS_BOT_CLIENT(tmp_player));
 605
 606                                 if(is_bot)
 607                                 {
 608                                         tmp_netaddress = "null/botclient";
 609                                         tmp_crypto_idfp = "null/botclient";
 610                                 }
 611                                 else if(privacy)
 612                                 {
 613                                         tmp_netaddress = "hidden";
 614                                         tmp_crypto_idfp = "hidden";
 615                                 }
 616                                 else
 617                                 {
 618                                         tmp_netaddress = tmp_player.netaddress;
 619                                         tmp_crypto_idfp = tmp_player.crypto_idfp;
 620                                 }
 621
 622                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 623                                         num_for_edict(tmp_player),
 624                                         tmp_player.netname,
 625                                         tmp_player.ping,
 626                                         tmp_player.ping_packetloss,
 627                                         process_time(1, time - tmp_player.jointime),
 628                                         tmp_netaddress,
 629                                         tmp_crypto_idfp));
 630
 631                                 ++total_listed_players;
 632                         }
 633
 634                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 635
 636                         return; // never fall through to usage
 637                 }
 638
 639                 default:
 640                 case CMD_REQUEST_USAGE:
 641                 {
 642                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 643                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 644                         return;
 645                 }
 646         }
 647 }
 648
 649 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 650 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 651 void CommonCommand_(float request, entity caller)
 652 {
 653         switch(request)
 654         {
 655                 case CMD_REQUEST_COMMAND:
 656                 {
 657
 658                         return; // never fall through to usage
 659                 }
 660
 661                 default:
 662                 case CMD_REQUEST_USAGE:
 663                 {
 664                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 665                         print_to(caller, "  No arguments required.");
 666                         return;
 667                 }
 668         }
 669 }
 670 */
 671
 672
 673 // ==================================
 674 //  Macro system for common commands
 675 // ==================================
 676
 677 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 678 #define COMMON_COMMANDS(request,caller,arguments,command) \
 679         COMMON_COMMAND("cvar_changes", CommonCommand_cvar_changes(request, caller), "Prints a list of all changed server cvars") \
 680         COMMON_COMMAND("cvar_purechanges", CommonCommand_cvar_purechanges(request, caller), "Prints a list of all changed gameplay cvars") \
 681         COMMON_COMMAND("info", CommonCommand_info(request, caller, arguments), "Request for unique server information set up by admin") \
 682         COMMON_COMMAND("ladder", CommonCommand_ladder(request, caller), "Get information about top players if supported") \
 683         COMMON_COMMAND("lsmaps", CommonCommand_lsmaps(request, caller), "List maps which can be used with the current game mode") \
 684         COMMON_COMMAND("printmaplist", CommonCommand_printmaplist(request, caller), "Display full server maplist reply") \
 685         COMMON_COMMAND("rankings", CommonCommand_rankings(request, caller), "Print information about rankings") \
 686         COMMON_COMMAND("records", CommonCommand_records(request, caller), "List top 10 records for the current map") \
 687         COMMON_COMMAND("teamstatus", CommonCommand_teamstatus(request, caller), "Show information about player and team scores") \
 688         COMMON_COMMAND("time", CommonCommand_time(request, caller), "Print different formats/readouts of time") \
 689         COMMON_COMMAND("timein", CommonCommand_timein(request, caller), "Resume the game from being paused with a timeout") \
 690         COMMON_COMMAND("timeout", CommonCommand_timeout(request, caller), "Call a timeout which pauses the game for certain amount of time unless unpaused") \
 691         COMMON_COMMAND("vote", VoteCommand(request, caller, arguments, command), "Request an action to be voted upon by players") \
 692         COMMON_COMMAND("who", CommonCommand_who(request, caller, arguments), "Display detailed client information about all players") \
 693         /* nothing */
 694
 695 void CommonCommand_macro_help(entity caller)
 696 {
 697         #define COMMON_COMMAND(name,function,description) \
 698                 { print_to(caller, strcat("  ^2", name, "^7: ", description)); }
 699
 700         COMMON_COMMANDS(0, caller, 0, "")
 701         #undef COMMON_COMMAND
 702
 703         return;
 704 }
 705
 706 float CommonCommand_macro_command(float argc, entity caller, string command)
 707 {
 708         #define COMMON_COMMAND(name,function,description) \
 709                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 710
 711         COMMON_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, command)
 712         #undef COMMON_COMMAND
 713
 714         return FALSE;
 715 }
 716
 717 float CommonCommand_macro_usage(float argc, entity caller)
 718 {
 719         #define COMMON_COMMAND(name,function,description) \
 720                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 721
 722         COMMON_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
 723         #undef COMMON_COMMAND
 724
 725         return FALSE;
 726 }
 727
 728 void CommonCommand_macro_write_aliases(float fh)
 729 {
 730         #define COMMON_COMMAND(name,function,description) \
 731                 { CMD_Write_Alias("qc_cmd_svcmd", name, description); }
 732
 733         COMMON_COMMANDS(0, world, 0, "")
 734         #undef COMMON_COMMAND
 735
 736         return;
 737 }