qcsrc/server/command/common.qc

   1 // ====================================================
   2 //  Shared code for server commands, written by Samual
   3 //  Last updated: December 27th, 2011
   4 // ====================================================
   5
   6 // select the proper prefix for usage and other messages
   7 string GetCommandPrefix(entity caller)
   8 {
   9         if(caller)
  10                 return "cmd";
  11         else
  12                 return "sv_cmd";
  13 }
  14
  15 // if client return player nickname, or if server return admin nickname
  16 string GetCallerName(entity caller)
  17 {
  18         if(caller)
  19                 return caller.netname;
  20         else
  21                 return admin_name(); //((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  22 }
  23
  24 // verify that the client provided is acceptable for use
  25 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  26 {
  27         if (!IS_CLIENT(client))
  28                 return CLIENT_DOESNT_EXIST;
  29         else if(must_be_real && !IS_REAL_CLIENT(client))
  30                 return CLIENT_NOT_REAL;
  31         else if(must_be_bots && !IS_BOT_CLIENT(client))
  32                 return CLIENT_NOT_BOT;
  33
  34         return CLIENT_ACCEPTABLE;
  35 }
  36
  37 // if the client is not acceptable, return a string to be used for error messages
  38 string GetClientErrorString(float clienterror, string original_input)
  39 {
  40         switch(clienterror)
  41         {
  42                 case CLIENT_DOESNT_EXIST: { return strcat("Client '", original_input, "' doesn't exist"); }
  43                 case CLIENT_NOT_REAL: { return strcat("Client '", original_input, "' is not real"); }
  44                 case CLIENT_NOT_BOT: { return strcat("Client '", original_input, "' is not a bot"); }
  45                 default: { return "Incorrect usage of GetClientErrorString"; }
  46         }
  47 }
  48
  49 // is this entity number even in the possible range of entities?
  50 float VerifyClientNumber(float tmp_number)
  51 {
  52         if((tmp_number < 1) || (tmp_number > maxclients))
  53                 return FALSE;
  54         else
  55                 return TRUE;
  56 }
  57
  58 entity GetIndexedEntity(float argc, float start_index)
  59 {
  60         entity tmp_player, selection;
  61         float tmp_number, index;
  62         string tmp_string;
  63
  64         next_token = -1;
  65         index = start_index;
  66         selection = world;
  67
  68         if(argc > start_index)
  69         {
  70                 if(substring(argv(index), 0, 1) == "#")
  71                 {
  72                         tmp_string = substring(argv(index), 1, -1);
  73                         ++index;
  74
  75                         if(tmp_string != "") // is it all one token? like #1
  76                         {
  77                                 tmp_number = stof(tmp_string);
  78                         }
  79                         else if(argc > index) // no, it's two tokens? # 1
  80                         {
  81                                 tmp_number = stof(argv(index));
  82                                 ++index;
  83                         }
  84                         else
  85                                 tmp_number = 0;
  86                 }
  87                 else // maybe it's ONLY a number?
  88                 {
  89                         tmp_number = stof(argv(index));
  90                         ++index;
  91                 }
  92
  93                 if(VerifyClientNumber(tmp_number))
  94                 {
  95                         selection = edict_num(tmp_number); // yes, it was a number
  96                 }
  97                 else // no, maybe it's a name?
  98                 {
  99                         FOR_EACH_CLIENT(tmp_player)
 100                                 if (strdecolorize(tmp_player.netname) == strdecolorize(argv(start_index)))
 101                                         selection = tmp_player;
 102
 103                         index = (start_index + 1);
 104                 }
 105         }
 106
 107         next_token = index;
 108         //print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 109         return selection;
 110 }
 111
 112 // find a player which matches the input string, and return their entity
 113 entity GetFilteredEntity(string input)
 114 {
 115         entity tmp_player, selection;
 116         float tmp_number;
 117
 118         if(substring(input, 0, 1) == "#")
 119                 tmp_number = stof(substring(input, 1, -1));
 120         else
 121                 tmp_number = stof(input);
 122
 123         if(VerifyClientNumber(tmp_number))
 124         {
 125                 selection = edict_num(tmp_number);
 126         }
 127         else
 128         {
 129                 selection = world;
 130                 FOR_EACH_CLIENT(tmp_player)
 131                         if (strdecolorize(tmp_player.netname) == strdecolorize(input))
 132                                 selection = tmp_player;
 133         }
 134
 135         return selection;
 136 }
 137
 138 // same thing, but instead return their edict number
 139 float GetFilteredNumber(string input)
 140 {
 141         entity selection = GetFilteredEntity(input);
 142         float output;
 143
 144         output = num_for_edict(selection);
 145
 146         return output;
 147 }
 148
 149 // switch between sprint and print depending on whether the receiver is the server or a player
 150 void print_to(entity to, string input)
 151 {
 152     if(to)
 153         sprint(to, strcat(input, "\n"));
 154     else
 155         print(input, "\n");
 156 }
 157
 158 // ==========================================
 159 //  Supporting functions for common commands
 160 // ==========================================
 161
 162 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 163 void timeout_handler_reset()
 164 {
 165         timeout_caller = world;
 166         timeout_time = 0;
 167         timeout_leadtime = 0;
 168
 169         remove(self);
 170 }
 171
 172 void timeout_handler_think()
 173 {
 174         entity tmp_player;
 175
 176         switch(timeout_status)
 177         {
 178                 case TIMEOUT_ACTIVE:
 179                 {
 180                         if(timeout_time > 0) // countdown is still going
 181                         {
 182                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 183
 184                                 if(timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 185                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 186
 187                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE; // think again in one second
 188                                 timeout_time -= 1; // decrease the time counter
 189                         }
 190                         else // time to end the timeout
 191                         {
 192                                 timeout_status = TIMEOUT_INACTIVE;
 193
 194                                 // reset the slowmo value back to normal
 195                                 cvar_set("slowmo", ftos(orig_slowmo));
 196
 197                                 // unlock the view for players so they can move around again
 198                                 FOR_EACH_REALPLAYER(tmp_player)
 199                                         tmp_player.fixangle = FALSE;
 200
 201                                 timeout_handler_reset();
 202                         }
 203
 204                         return;
 205                 }
 206
 207                 case TIMEOUT_LEADTIME:
 208                 {
 209                         if(timeout_leadtime > 0) // countdown is still going
 210                         {
 211                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 212
 213                                 self.nextthink = time + 1; // think again in one second
 214                                 timeout_leadtime -= 1; // decrease the time counter
 215                         }
 216                         else // time to begin the timeout
 217                         {
 218                                 timeout_status = TIMEOUT_ACTIVE;
 219
 220                                 // set the slowmo value to the timeout default slowmo value
 221                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 222
 223                                 // reset all the flood variables
 224                                 FOR_EACH_CLIENT(tmp_player)
 225                                         tmp_player.nickspamcount = tmp_player.nickspamtime = tmp_player.floodcontrol_chat =
 226                                         tmp_player.floodcontrol_chatteam = tmp_player.floodcontrol_chattell =
 227                                         tmp_player.floodcontrol_voice = tmp_player.floodcontrol_voiceteam = 0;
 228
 229                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 230                                 FOR_EACH_REALPLAYER(tmp_player)
 231                                         tmp_player.lastV_angle = tmp_player.v_angle;
 232
 233                                 self.nextthink = time; // think again next frame to handle it under TIMEOUT_ACTIVE code
 234                         }
 235
 236                         return;
 237                 }
 238
 239
 240                 case TIMEOUT_INACTIVE:
 241                 default:
 242                 {
 243                         timeout_handler_reset();
 244                         return;
 245                 }
 246         }
 247 }
 248
 249
 250
 251 // ===================================================
 252 //  Common commands used in both sv_cmd.qc and cmd.qc
 253 // ===================================================
 254
 255 void CommonCommand_cvar_changes(float request, entity caller)
 256 {
 257         switch(request)
 258         {
 259                 case CMD_REQUEST_COMMAND:
 260                 {
 261                         print_to(caller, cvar_changes);
 262                         return; // never fall through to usage
 263                 }
 264
 265                 default:
 266                 case CMD_REQUEST_USAGE:
 267                 {
 268                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 269                         print_to(caller, "  No arguments required.");
 270                         print_to(caller, "See also: ^2cvar_purechanges^7");
 271                         return;
 272                 }
 273         }
 274 }
 275
 276 void CommonCommand_cvar_purechanges(float request, entity caller)
 277 {
 278         switch(request)
 279         {
 280                 case CMD_REQUEST_COMMAND:
 281                 {
 282                         print_to(caller, cvar_purechanges);
 283                         return; // never fall through to usage
 284                 }
 285
 286                 default:
 287                 case CMD_REQUEST_USAGE:
 288                 {
 289                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 290                         print_to(caller, "  No arguments required.");
 291                         print_to(caller, "See also: ^2cvar_changes^7");
 292                         return;
 293                 }
 294         }
 295 }
 296
 297 void CommonCommand_info(float request, entity caller, float argc)
 298 {
 299         switch(request)
 300         {
 301                 case CMD_REQUEST_COMMAND:
 302                 {
 303                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 304
 305                         if(command)
 306                                 wordwrap_sprint(command, 1000);
 307                         else
 308                                 print_to(caller, "ERROR: unsupported info command");
 309
 310                         return; // never fall through to usage
 311                 }
 312
 313                 default:
 314                 case CMD_REQUEST_USAGE:
 315                 {
 316                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 317                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 318                         return;
 319                 }
 320         }
 321 }
 322
 323 void CommonCommand_ladder(float request, entity caller)
 324 {
 325         switch(request)
 326         {
 327                 case CMD_REQUEST_COMMAND:
 328                 {
 329                         print_to(caller, ladder_reply);
 330                         return; // never fall through to usage
 331                 }
 332
 333                 default:
 334                 case CMD_REQUEST_USAGE:
 335                 {
 336                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 337                         print_to(caller, "  No arguments required.");
 338                         return;
 339                 }
 340         }
 341 }
 342
 343 void CommonCommand_lsmaps(float request, entity caller)
 344 {
 345         switch(request)
 346         {
 347                 case CMD_REQUEST_COMMAND:
 348                 {
 349                         print_to(caller, lsmaps_reply);
 350                         return; // never fall through to usage
 351                 }
 352
 353                 default:
 354                 case CMD_REQUEST_USAGE:
 355                 {
 356                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 357                         print_to(caller, "  No arguments required.");
 358                         return;
 359                 }
 360         }
 361 }
 362
 363 void CommonCommand_printmaplist(float request, entity caller)
 364 {
 365         switch(request)
 366         {
 367                 case CMD_REQUEST_COMMAND:
 368                 {
 369                         print_to(caller, maplist_reply);
 370                         return; // never fall through to usage
 371                 }
 372
 373                 default:
 374                 case CMD_REQUEST_USAGE:
 375                 {
 376                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 377                         print_to(caller, "  No arguments required.");
 378                         return;
 379                 }
 380         }
 381 }
 382
 383 void CommonCommand_rankings(float request, entity caller)
 384 {
 385         switch(request)
 386         {
 387                 case CMD_REQUEST_COMMAND:
 388                 {
 389                         print_to(caller, rankings_reply);
 390                         return; // never fall through to usage
 391                 }
 392
 393                 default:
 394                 case CMD_REQUEST_USAGE:
 395                 {
 396                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 397                         print_to(caller, "  No arguments required.");
 398                         return;
 399                 }
 400         }
 401 }
 402
 403 void CommonCommand_records(float request, entity caller)
 404 {
 405         switch(request)
 406         {
 407                 case CMD_REQUEST_COMMAND:
 408                 {
 409                         float i;
 410
 411                         for(i = 0; i < 10; ++i)
 412                                 if(records_reply[i] != "")
 413                                         print_to(caller, records_reply[i]);
 414
 415                         return; // never fall through to usage
 416                 }
 417
 418                 default:
 419                 case CMD_REQUEST_USAGE:
 420                 {
 421                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 422                         print_to(caller, "  No arguments required.");
 423                         return;
 424                 }
 425         }
 426 }
 427
 428 void CommonCommand_teamstatus(float request, entity caller)
 429 {
 430         switch(request)
 431         {
 432                 case CMD_REQUEST_COMMAND:
 433                 {
 434                         Score_NicePrint(caller);
 435                         return; // never fall through to usage
 436                 }
 437
 438                 default:
 439                 case CMD_REQUEST_USAGE:
 440                 {
 441                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 442                         print_to(caller, "  No arguments required.");
 443                         return;
 444                 }
 445         }
 446 }
 447
 448 void CommonCommand_time(float request, entity caller)
 449 {
 450         switch(request)
 451         {
 452                 case CMD_REQUEST_COMMAND:
 453                 {
 454                         print_to(caller, strcat("time = ", ftos(time)));
 455                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 456                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 457                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 458                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 459                         print_to(caller, strcat("localtime = ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y")));
 460                         print_to(caller, strcat("gmtime = ", strftime(FALSE, "%a %b %e %H:%M:%S %Z %Y")));
 461                         return;
 462                 }
 463
 464                 default:
 465                 case CMD_REQUEST_USAGE:
 466                 {
 467                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 468                         print_to(caller, "  No arguments required.");
 469                         return;
 470                 }
 471         }
 472 }
 473
 474 void CommonCommand_timein(float request, entity caller)
 475 {
 476         switch(request)
 477         {
 478                 case CMD_REQUEST_COMMAND:
 479                 {
 480                         if(!caller || autocvar_sv_timeout)
 481                         {
 482                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 483                                 else if(caller && (caller != timeout_caller)) { print_to(caller, "^7Error: You are not allowed to stop the active timeout."); }
 484
 485                                 else // everything should be okay, continue aborting timeout
 486                                 {
 487                                         switch(timeout_status)
 488                                         {
 489                                                 case TIMEOUT_LEADTIME:
 490                                                 {
 491                                                         timeout_status = TIMEOUT_INACTIVE;
 492                                                         timeout_time = 0;
 493                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 494                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 495                                                         return;
 496                                                 }
 497
 498                                                 case TIMEOUT_ACTIVE:
 499                                                 {
 500                                                         timeout_time = autocvar_sv_timeout_resumetime;
 501                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 502                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 503                                                         return;
 504                                                 }
 505
 506                                                 default: dprint("timeout status was inactive, but this code was executed anyway?"); return;
 507                                         }
 508                                 }
 509                         }
 510                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 511
 512                         return; // never fall through to usage
 513                 }
 514
 515                 default:
 516                 case CMD_REQUEST_USAGE:
 517                 {
 518                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 519                         print_to(caller, "  No arguments required.");
 520                         return;
 521                 }
 522         }
 523 }
 524
 525 void CommonCommand_timeout(float request, entity caller) // DEAR GOD THIS COMMAND IS TERRIBLE.
 526 {
 527         switch(request)
 528         {
 529                 case CMD_REQUEST_COMMAND:
 530                 {
 531                         if(!caller || autocvar_sv_timeout)
 532                         {
 533                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 534
 535                                 if(timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 536                                 else if(vote_called) { print_to(caller, "^7Error: You can not call a timeout while a vote is active."); }
 537                                 else if(warmup_stage && !g_warmup_allow_timeout) { print_to(caller, "^7Error: You can not call a timeout in warmup-stage."); }
 538                                 else if(time < game_starttime) { print_to(caller, "^7Error: You can not call a timeout while the map is being restarted."); }
 539                                 else if(caller && (caller.allowed_timeouts < 1)) { print_to(caller, "^7Error: You already used all your timeout calls for this map."); }
 540                                 else if(caller && !IS_PLAYER(caller)) { print_to(caller, "^7Error: You must be a player to call a timeout."); }
 541                                 else if((autocvar_timelimit) && (last_possible_timeout < time - game_starttime)) { print_to(caller, "^7Error: It is too late to call a timeout now!"); }
 542
 543                                 else // everything should be okay, proceed with starting the timeout
 544                                 {
 545                                         if(caller) { caller.allowed_timeouts -= 1; }
 546
 547                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n"); // write a bprint who started the timeout (and how many they have left)
 548
 549                                         timeout_status = TIMEOUT_LEADTIME;
 550                                         timeout_caller = caller;
 551                                         timeout_time = autocvar_sv_timeout_length;
 552                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 553
 554                                         timeout_handler = spawn();
 555                                         timeout_handler.think = timeout_handler_think;
 556                                         timeout_handler.nextthink = time; // always let the entity think asap
 557
 558                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 559                                 }
 560                         }
 561                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 562
 563                         return; // never fall through to usage
 564                 }
 565
 566                 default:
 567                 case CMD_REQUEST_USAGE:
 568                 {
 569                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 570                         print_to(caller, "  No arguments required.");
 571                         return;
 572                 }
 573         }
 574 }
 575
 576 void CommonCommand_who(float request, entity caller, float argc)
 577 {
 578         switch(request)
 579         {
 580                 case CMD_REQUEST_COMMAND:
 581                 {
 582                         float total_listed_players, is_bot;
 583                         entity tmp_player;
 584
 585                         float privacy = (caller && autocvar_sv_status_privacy);
 586                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 587                         string tmp_netaddress, tmp_crypto_idfp;
 588
 589                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 590                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 591                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 592
 593                         total_listed_players = 0;
 594                         FOR_EACH_CLIENT(tmp_player)
 595                         {
 596                                 is_bot = (IS_BOT_CLIENT(tmp_player));
 597
 598                                 if(is_bot)
 599                                 {
 600                                         tmp_netaddress = "null/botclient";
 601                                         tmp_crypto_idfp = "null/botclient";
 602                                 }
 603                                 else if(privacy)
 604                                 {
 605                                         tmp_netaddress = "hidden";
 606                                         tmp_crypto_idfp = "hidden";
 607                                 }
 608                                 else
 609                                 {
 610                                         tmp_netaddress = tmp_player.netaddress;
 611                                         tmp_crypto_idfp = tmp_player.crypto_idfp;
 612                                 }
 613
 614                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 615                                         num_for_edict(tmp_player),
 616                                         tmp_player.netname,
 617                                         tmp_player.ping,
 618                                         tmp_player.ping_packetloss,
 619                                         process_time(1, time - tmp_player.jointime),
 620                                         tmp_netaddress,
 621                                         tmp_crypto_idfp));
 622
 623                                 ++total_listed_players;
 624                         }
 625
 626                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 627
 628                         return; // never fall through to usage
 629                 }
 630
 631                 default:
 632                 case CMD_REQUEST_USAGE:
 633                 {
 634                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 635                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 636                         return;
 637                 }
 638         }
 639 }
 640
 641 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 642 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 643 void CommonCommand_(float request, entity caller)
 644 {
 645         switch(request)
 646         {
 647                 case CMD_REQUEST_COMMAND:
 648                 {
 649
 650                         return; // never fall through to usage
 651                 }
 652
 653                 default:
 654                 case CMD_REQUEST_USAGE:
 655                 {
 656                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 657                         print_to(caller, "  No arguments required.");
 658                         return;
 659                 }
 660         }
 661 }
 662 */
 663
 664
 665 // ==================================
 666 //  Macro system for common commands
 667 // ==================================
 668
 669 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 670 #define COMMON_COMMANDS(request,caller,arguments,command) \
 671         COMMON_COMMAND("cvar_changes", CommonCommand_cvar_changes(request, caller), "Prints a list of all changed server cvars") \
 672         COMMON_COMMAND("cvar_purechanges", CommonCommand_cvar_purechanges(request, caller), "Prints a list of all changed gameplay cvars") \
 673         COMMON_COMMAND("info", CommonCommand_info(request, caller, arguments), "Request for unique server information set up by admin") \
 674         COMMON_COMMAND("ladder", CommonCommand_ladder(request, caller), "Get information about top players if supported") \
 675         COMMON_COMMAND("lsmaps", CommonCommand_lsmaps(request, caller), "List maps which can be used with the current game mode") \
 676         COMMON_COMMAND("printmaplist", CommonCommand_printmaplist(request, caller), "Display full server maplist reply") \
 677         COMMON_COMMAND("rankings", CommonCommand_rankings(request, caller), "Print information about rankings") \
 678         COMMON_COMMAND("records", CommonCommand_records(request, caller), "List top 10 records for the current map") \
 679         COMMON_COMMAND("teamstatus", CommonCommand_teamstatus(request, caller), "Show information about player and team scores") \
 680         COMMON_COMMAND("time", CommonCommand_time(request, caller), "Print different formats/readouts of time") \
 681         COMMON_COMMAND("timein", CommonCommand_timein(request, caller), "Resume the game from being paused with a timeout") \
 682         COMMON_COMMAND("timeout", CommonCommand_timeout(request, caller), "Call a timeout which pauses the game for certain amount of time unless unpaused") \
 683         COMMON_COMMAND("vote", VoteCommand(request, caller, arguments, command), "Request an action to be voted upon by players") \
 684         COMMON_COMMAND("who", CommonCommand_who(request, caller, arguments), "Display detailed client information about all players") \
 685         /* nothing */
 686
 687 void CommonCommand_macro_help(entity caller)
 688 {
 689         #define COMMON_COMMAND(name,function,description) \
 690                 { print_to(caller, strcat("  ^2", name, "^7: ", description)); }
 691
 692         COMMON_COMMANDS(0, caller, 0, "")
 693         #undef COMMON_COMMAND
 694
 695         return;
 696 }
 697
 698 float CommonCommand_macro_command(float argc, entity caller, string command)
 699 {
 700         #define COMMON_COMMAND(name,function,description) \
 701                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 702
 703         COMMON_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, command)
 704         #undef COMMON_COMMAND
 705
 706         return FALSE;
 707 }
 708
 709 float CommonCommand_macro_usage(float argc, entity caller)
 710 {
 711         #define COMMON_COMMAND(name,function,description) \
 712                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 713
 714         COMMON_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
 715         #undef COMMON_COMMAND
 716
 717         return FALSE;
 718 }
 719
 720 void CommonCommand_macro_write_aliases(float fh)
 721 {
 722         #define COMMON_COMMAND(name,function,description) \
 723                 { CMD_Write_Alias("qc_cmd_svcmd", name, description); }
 724
 725         COMMON_COMMANDS(0, world, 0, "")
 726         #undef COMMON_COMMAND
 727
 728         return;
 729 }