qcsrc/server/command/common.qc

   1 // ====================================================
   2 //  Shared code for server commands, written by Samual
   3 //  Last updated: December 27th, 2011
   4 // ====================================================
   5
   6 // select the proper prefix for usage and other messages
   7 string GetCommandPrefix(entity caller)
   8 {
   9         if(caller)
  10                 return "cmd";
  11         else
  12                 return "sv_cmd";
  13 }
  14
  15 // if client return player nickname, or if server return admin nickname
  16 string GetCallerName(entity caller)
  17 {
  18         if(caller)
  19                 return caller.netname;
  20         else
  21                 return admin_name(); //((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  22 }
  23
  24 // verify that the client provided is acceptable for use
  25 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  26 {
  27         if not(client.flags & FL_CLIENT)
  28                 return CLIENT_DOESNT_EXIST;
  29         else if(must_be_real && (clienttype(client) != CLIENTTYPE_REAL))
  30                 return CLIENT_NOT_REAL;
  31         else if(must_be_bots && (clienttype(client) != CLIENTTYPE_BOT))
  32                 return CLIENT_NOT_BOT;
  33
  34         return CLIENT_ACCEPTABLE;
  35 }
  36
  37 // if the client is not acceptable, return a string to be used for error messages
  38 string GetClientErrorString(float clienterror, string original_input)
  39 {
  40         switch(clienterror)
  41         {
  42                 case CLIENT_DOESNT_EXIST: { return strcat("Client '", original_input, "' doesn't exist"); }
  43                 case CLIENT_NOT_REAL: { return strcat("Client '", original_input, "' is not real"); }
  44                 case CLIENT_NOT_BOT: { return strcat("Client '", original_input, "' is not a bot"); }
  45                 default: { return "Incorrect usage of GetClientErrorString"; }
  46         }
  47 }
  48
  49 // is this entity number even in the possible range of entities?
  50 float VerifyClientNumber(float tmp_number)
  51 {
  52         if((tmp_number < 1) || (tmp_number > maxclients))
  53                 return FALSE;
  54         else
  55                 return TRUE;
  56 }
  57
  58 entity GetIndexedEntity(float argc, float start_index)
  59 {
  60         entity tmp_player, selection;
  61         float tmp_number, index;
  62         string tmp_string;
  63
  64         next_token = -1;
  65         index = start_index;
  66         selection = world;
  67
  68         if(argc > start_index)
  69         {
  70                 if(substring(argv(index), 0, 1) == "#")
  71                 {
  72                         tmp_string = substring(argv(index), 1, -1);
  73                         ++index;
  74
  75                         if(tmp_string != "") // is it all one token? like #1
  76                         {
  77                                 tmp_number = stof(tmp_string);
  78                         }
  79                         else if(argc > index) // no, it's two tokens? # 1
  80                         {
  81                                 tmp_number = stof(argv(index));
  82                                 ++index;
  83                         }
  84                         else
  85                                 tmp_number = 0;
  86                 }
  87                 else // maybe it's ONLY a number?
  88                 {
  89                         tmp_number = stof(argv(index));
  90                         ++index;
  91                 }
  92
  93                 if(VerifyClientNumber(tmp_number))
  94                 {
  95                         selection = edict_num(tmp_number); // yes, it was a number
  96                 }
  97                 else // no, maybe it's a name?
  98                 {
  99                         FOR_EACH_CLIENT(tmp_player)
 100                                 if (strdecolorize(tmp_player.netname) == strdecolorize(argv(start_index)))
 101                                         selection = tmp_player;
 102
 103                         index = (start_index + 1);
 104                 }
 105         }
 106
 107         next_token = index;
 108         //print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 109         return selection;
 110 }
 111
 112 // find a player which matches the input string, and return their entity
 113 entity GetFilteredEntity(string input)
 114 {
 115         entity tmp_player, selection;
 116         float tmp_number;
 117
 118         if(substring(input, 0, 1) == "#")
 119                 tmp_number = stof(substring(input, 1, -1));
 120         else
 121                 tmp_number = stof(input);
 122
 123         if(VerifyClientNumber(tmp_number))
 124         {
 125                 selection = edict_num(tmp_number);
 126         }
 127         else
 128         {
 129                 selection = world;
 130                 FOR_EACH_CLIENT(tmp_player)
 131                         if (strdecolorize(tmp_player.netname) == strdecolorize(input))
 132                                 selection = tmp_player;
 133         }
 134
 135         return selection;
 136 }
 137
 138 // same thing, but instead return their edict number
 139 float GetFilteredNumber(string input)
 140 {
 141         entity selection = GetFilteredEntity(input);
 142         float output;
 143
 144         output = num_for_edict(selection);
 145
 146         return output;
 147 }
 148
 149 // switch between sprint and print depending on whether the receiver is the server or a player
 150 void print_to(entity to, string input)
 151 {
 152     if(to)
 153         sprint(to, strcat(input, "\n"));
 154     else
 155         print(input, "\n");
 156 }
 157
 158 // ==========================================
 159 //  Supporting functions for common commands
 160 // ==========================================
 161
 162 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 163 void timeout_handler_reset()
 164 {
 165         timeout_caller = world;
 166         timeout_time = 0;
 167         timeout_leadtime = 0;
 168
 169         remove(self);
 170 }
 171
 172 void timeout_handler_think()
 173 {
 174         entity tmp_player;
 175
 176         switch(timeout_status)
 177         {
 178                 case TIMEOUT_ACTIVE:
 179                 {
 180                         if(timeout_time > 0) // countdown is still going
 181                         {
 182                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 183
 184                                 if(timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 185                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 186
 187                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE; // think again in one second
 188                                 timeout_time -= 1; // decrease the time counter
 189                         }
 190                         else // time to end the timeout
 191                         {
 192                                 timeout_status = TIMEOUT_INACTIVE;
 193
 194                                 // reset the slowmo value back to normal
 195                                 cvar_set("slowmo", ftos(orig_slowmo));
 196
 197                                 // unlock the view for players so they can move around again
 198                                 FOR_EACH_REALPLAYER(tmp_player)
 199                                         tmp_player.fixangle = FALSE;
 200
 201                                 timeout_handler_reset();
 202                         }
 203
 204                         return;
 205                 }
 206
 207                 case TIMEOUT_LEADTIME:
 208                 {
 209                         if(timeout_leadtime > 0) // countdown is still going
 210                         {
 211                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 212
 213                                 self.nextthink = time + 1; // think again in one second
 214                                 timeout_leadtime -= 1; // decrease the time counter
 215                         }
 216                         else // time to begin the timeout
 217                         {
 218                                 timeout_status = TIMEOUT_ACTIVE;
 219
 220                                 // set the slowmo value to the timeout default slowmo value
 221                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 222
 223                                 // reset all the flood variables
 224                                 FOR_EACH_CLIENT(tmp_player)
 225                                         tmp_player.nickspamcount = tmp_player.nickspamtime = tmp_player.floodcontrol_chat =
 226                                         tmp_player.floodcontrol_chatteam = tmp_player.floodcontrol_chattell =
 227                                         tmp_player.floodcontrol_voice = tmp_player.floodcontrol_voiceteam = 0;
 228
 229                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 230                                 FOR_EACH_REALPLAYER(tmp_player)
 231                                         tmp_player.lastV_angle = tmp_player.v_angle;
 232
 233                                 self.nextthink = time; // think again next frame to handle it under TIMEOUT_ACTIVE code
 234                         }
 235
 236                         return;
 237                 }
 238
 239
 240                 case TIMEOUT_INACTIVE:
 241                 default:
 242                 {
 243                         timeout_handler_reset();
 244                         return;
 245                 }
 246         }
 247 }
 248
 249
 250
 251 // ===================================================
 252 //  Common commands used in both sv_cmd.qc and cmd.qc
 253 // ===================================================
 254
 255 void CommonCommand_cvar_changes(float request, entity caller)
 256 {
 257         switch(request)
 258         {
 259                 case CMD_REQUEST_COMMAND:
 260                 {
 261                         print_to(caller, cvar_changes);
 262                         return; // never fall through to usage
 263                 }
 264
 265                 default:
 266                 case CMD_REQUEST_USAGE:
 267                 {
 268                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 269                         print_to(caller, "  No arguments required.");
 270                         print_to(caller, "See also: ^2cvar_purechanges^7");
 271                         return;
 272                 }
 273         }
 274 }
 275
 276 void CommonCommand_cvar_purechanges(float request, entity caller)
 277 {
 278         switch(request)
 279         {
 280                 case CMD_REQUEST_COMMAND:
 281                 {
 282                         print_to(caller, cvar_purechanges);
 283                         return; // never fall through to usage
 284                 }
 285
 286                 default:
 287                 case CMD_REQUEST_USAGE:
 288                 {
 289                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 290                         print_to(caller, "  No arguments required.");
 291                         print_to(caller, "See also: ^2cvar_changes^7");
 292                         return;
 293                 }
 294         }
 295 }
 296
 297 void CommonCommand_info(float request, entity caller, float argc)
 298 {
 299         switch(request)
 300         {
 301                 case CMD_REQUEST_COMMAND:
 302                 {
 303                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 304
 305                         if(command)
 306                                 wordwrap_sprint(command, 1000);
 307                         else
 308                                 print_to(caller, "ERROR: unsupported info command");
 309
 310                         return; // never fall through to usage
 311                 }
 312
 313                 default:
 314                 case CMD_REQUEST_USAGE:
 315                 {
 316                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 317                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 318                         return;
 319                 }
 320         }
 321 }
 322
 323 void CommonCommand_ladder(float request, entity caller)
 324 {
 325         switch(request)
 326         {
 327                 case CMD_REQUEST_COMMAND:
 328                 {
 329                         print_to(caller, ladder_reply);
 330                         return; // never fall through to usage
 331                 }
 332
 333                 default:
 334                 case CMD_REQUEST_USAGE:
 335                 {
 336                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 337                         print_to(caller, "  No arguments required.");
 338                         return;
 339                 }
 340         }
 341 }
 342
 343 void CommonCommand_lsmaps(float request, entity caller)
 344 {
 345         switch(request)
 346         {
 347                 case CMD_REQUEST_COMMAND:
 348                 {
 349                         print_to(caller, lsmaps_reply);
 350                         return; // never fall through to usage
 351                 }
 352
 353                 default:
 354                 case CMD_REQUEST_USAGE:
 355                 {
 356                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 357                         print_to(caller, "  No arguments required.");
 358                         return;
 359                 }
 360         }
 361 }
 362
 363 void CommonCommand_lsnewmaps(float request, entity caller)
 364 {
 365         switch(request)
 366         {
 367                 case CMD_REQUEST_COMMAND:
 368                 {
 369                         print_to(caller, lsnewmaps_reply);
 370                         return; // never fall through to usage
 371                 }
 372
 373                 default:
 374                 case CMD_REQUEST_USAGE:
 375                 {
 376                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsnewmaps"));
 377                         print_to(caller, "  No arguments required.");
 378                         return;
 379                 }
 380         }
 381 }
 382
 383 void CommonCommand_printmaplist(float request, entity caller)
 384 {
 385         switch(request)
 386         {
 387                 case CMD_REQUEST_COMMAND:
 388                 {
 389                         print_to(caller, maplist_reply);
 390                         return; // never fall through to usage
 391                 }
 392
 393                 default:
 394                 case CMD_REQUEST_USAGE:
 395                 {
 396                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 397                         print_to(caller, "  No arguments required.");
 398                         return;
 399                 }
 400         }
 401 }
 402
 403 void CommonCommand_rankings(float request, entity caller)
 404 {
 405         switch(request)
 406         {
 407                 case CMD_REQUEST_COMMAND:
 408                 {
 409                         print_to(caller, rankings_reply);
 410                         return; // never fall through to usage
 411                 }
 412
 413                 default:
 414                 case CMD_REQUEST_USAGE:
 415                 {
 416                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 417                         print_to(caller, "  No arguments required.");
 418                         return;
 419                 }
 420         }
 421 }
 422
 423 void CommonCommand_records(float request, entity caller)
 424 {
 425         switch(request)
 426         {
 427                 case CMD_REQUEST_COMMAND:
 428                 {
 429                         float i;
 430
 431                         for(i = 0; i < 10; ++i)
 432                                 if(records_reply[i] != "")
 433                                         print_to(caller, records_reply[i]);
 434
 435                         return; // never fall through to usage
 436                 }
 437
 438                 default:
 439                 case CMD_REQUEST_USAGE:
 440                 {
 441                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 442                         print_to(caller, "  No arguments required.");
 443                         return;
 444                 }
 445         }
 446 }
 447
 448 void CommonCommand_teamstatus(float request, entity caller)
 449 {
 450         switch(request)
 451         {
 452                 case CMD_REQUEST_COMMAND:
 453                 {
 454                         Score_NicePrint(caller);
 455                         return; // never fall through to usage
 456                 }
 457
 458                 default:
 459                 case CMD_REQUEST_USAGE:
 460                 {
 461                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 462                         print_to(caller, "  No arguments required.");
 463                         return;
 464                 }
 465         }
 466 }
 467
 468 void CommonCommand_time(float request, entity caller)
 469 {
 470         switch(request)
 471         {
 472                 case CMD_REQUEST_COMMAND:
 473                 {
 474                         print_to(caller, strcat("time = ", ftos(time)));
 475                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 476                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 477                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 478                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 479                         print_to(caller, strcat("localtime = ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y")));
 480                         print_to(caller, strcat("gmtime = ", strftime(FALSE, "%a %b %e %H:%M:%S %Z %Y")));
 481                         return;
 482                 }
 483
 484                 default:
 485                 case CMD_REQUEST_USAGE:
 486                 {
 487                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 488                         print_to(caller, "  No arguments required.");
 489                         return;
 490                 }
 491         }
 492 }
 493
 494 void CommonCommand_timein(float request, entity caller)
 495 {
 496         switch(request)
 497         {
 498                 case CMD_REQUEST_COMMAND:
 499                 {
 500                         if(!caller || autocvar_sv_timeout)
 501                         {
 502                                 if not(timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 503                                 else if(caller && (caller != timeout_caller)) { print_to(caller, "^7Error: You are not allowed to stop the active timeout."); }
 504
 505                                 else // everything should be okay, continue aborting timeout
 506                                 {
 507                                         switch(timeout_status)
 508                                         {
 509                                                 case TIMEOUT_LEADTIME:
 510                                                 {
 511                                                         timeout_status = TIMEOUT_INACTIVE;
 512                                                         timeout_time = 0;
 513                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 514                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 515                                                         return;
 516                                                 }
 517
 518                                                 case TIMEOUT_ACTIVE:
 519                                                 {
 520                                                         timeout_time = autocvar_sv_timeout_resumetime;
 521                                                         timeout_handler.nextthink = time; // timeout_handler has to take care of it immediately
 522                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 523                                                         return;
 524                                                 }
 525
 526                                                 default: dprint("timeout status was inactive, but this code was executed anyway?"); return;
 527                                         }
 528                                 }
 529                         }
 530                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 531
 532                         return; // never fall through to usage
 533                 }
 534
 535                 default:
 536                 case CMD_REQUEST_USAGE:
 537                 {
 538                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 539                         print_to(caller, "  No arguments required.");
 540                         return;
 541                 }
 542         }
 543 }
 544
 545 void CommonCommand_timeout(float request, entity caller) // DEAR GOD THIS COMMAND IS TERRIBLE.
 546 {
 547         switch(request)
 548         {
 549                 case CMD_REQUEST_COMMAND:
 550                 {
 551                         if(!caller || autocvar_sv_timeout)
 552                         {
 553                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 554
 555                                 if(timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 556                                 else if(vote_called) { print_to(caller, "^7Error: You can not call a timeout while a vote is active."); }
 557                                 else if(inWarmupStage && !g_warmup_allow_timeout) { print_to(caller, "^7Error: You can not call a timeout in warmup-stage."); }
 558                                 else if(time < game_starttime) { print_to(caller, "^7Error: You can not call a timeout while the map is being restarted."); }
 559                                 else if(caller && (caller.allowed_timeouts < 1)) { print_to(caller, "^7Error: You already used all your timeout calls for this map."); }
 560                                 else if(caller && (caller.classname != "player")) { print_to(caller, "^7Error: You must be a player to call a timeout."); }
 561                                 else if((autocvar_timelimit) && (last_possible_timeout < time - game_starttime)) { print_to(caller, "^7Error: It is too late to call a timeout now!"); }
 562
 563                                 else // everything should be okay, proceed with starting the timeout
 564                                 {
 565                                         if(caller) { caller.allowed_timeouts -= 1; }
 566
 567                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n"); // write a bprint who started the timeout (and how many they have left)
 568
 569                                         timeout_status = TIMEOUT_LEADTIME;
 570                                         timeout_caller = caller;
 571                                         timeout_time = autocvar_sv_timeout_length;
 572                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 573
 574                                         timeout_handler = spawn();
 575                                         timeout_handler.think = timeout_handler_think;
 576                                         timeout_handler.nextthink = time; // always let the entity think asap
 577
 578                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 579                                 }
 580                         }
 581                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 582
 583                         return; // never fall through to usage
 584                 }
 585
 586                 default:
 587                 case CMD_REQUEST_USAGE:
 588                 {
 589                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 590                         print_to(caller, "  No arguments required.");
 591                         return;
 592                 }
 593         }
 594 }
 595
 596 void CommonCommand_who(float request, entity caller, float argc)
 597 {
 598         switch(request)
 599         {
 600                 case CMD_REQUEST_COMMAND:
 601                 {
 602                         float total_listed_players, is_bot;
 603                         entity tmp_player;
 604
 605                         float privacy = (caller && autocvar_sv_status_privacy);
 606                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 607                         string tmp_netaddress, tmp_crypto_idfp;
 608
 609                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 610                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 611                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 612
 613                         total_listed_players = 0;
 614                         FOR_EACH_CLIENT(tmp_player)
 615                         {
 616                                 is_bot = (clienttype(tmp_player) == CLIENTTYPE_BOT);
 617
 618                                 if(is_bot)
 619                                 {
 620                                         tmp_netaddress = "null/botclient";
 621                                         tmp_crypto_idfp = "null/botclient";
 622                                 }
 623                                 else if(privacy)
 624                                 {
 625                                         tmp_netaddress = "hidden";
 626                                         tmp_crypto_idfp = "hidden";
 627                                 }
 628                                 else
 629                                 {
 630                                         tmp_netaddress = tmp_player.netaddress;
 631                                         tmp_crypto_idfp = tmp_player.crypto_idfp;
 632                                 }
 633
 634                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 635                                         num_for_edict(tmp_player),
 636                                         tmp_player.netname,
 637                                         tmp_player.ping,
 638                                         tmp_player.ping_packetloss,
 639                                         process_time(1, time - tmp_player.jointime),
 640                                         tmp_netaddress,
 641                                         tmp_crypto_idfp));
 642
 643                                 ++total_listed_players;
 644                         }
 645
 646                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 647
 648                         return; // never fall through to usage
 649                 }
 650
 651                 default:
 652                 case CMD_REQUEST_USAGE:
 653                 {
 654                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 655                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 656                         return;
 657                 }
 658         }
 659 }
 660
 661 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 662 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 663 void CommonCommand_(float request, entity caller)
 664 {
 665         switch(request)
 666         {
 667                 case CMD_REQUEST_COMMAND:
 668                 {
 669
 670                         return; // never fall through to usage
 671                 }
 672
 673                 default:
 674                 case CMD_REQUEST_USAGE:
 675                 {
 676                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 677                         print_to(caller, "  No arguments required.");
 678                         return;
 679                 }
 680         }
 681 }
 682 */
 683
 684
 685 // ==================================
 686 //  Macro system for common commands
 687 // ==================================
 688
 689 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 690 #define COMMON_COMMANDS(request,caller,arguments,command) \
 691         COMMON_COMMAND("cvar_changes", CommonCommand_cvar_changes(request, caller), "Prints a list of all changed server cvars") \
 692         COMMON_COMMAND("cvar_purechanges", CommonCommand_cvar_purechanges(request, caller), "Prints a list of all changed gameplay cvars") \
 693         COMMON_COMMAND("info", CommonCommand_info(request, caller, arguments), "Request for unique server information set up by admin") \
 694         COMMON_COMMAND("ladder", CommonCommand_ladder(request, caller), "Get information about top players if supported") \
 695         COMMON_COMMAND("lsmaps", CommonCommand_lsmaps(request, caller), "List maps which can be used with the current game mode") \
 696         COMMON_COMMAND("lsnewmaps", CommonCommand_lsnewmaps(request, caller), "List maps which have no records or are seemingly unplayed yet") \
 697         COMMON_COMMAND("printmaplist", CommonCommand_printmaplist(request, caller), "Display full server maplist reply") \
 698         COMMON_COMMAND("rankings", CommonCommand_rankings(request, caller), "Print information about rankings") \
 699         COMMON_COMMAND("records", CommonCommand_records(request, caller), "List top 10 records for the current map") \
 700         COMMON_COMMAND("teamstatus", CommonCommand_teamstatus(request, caller), "Show information about player and team scores") \
 701         COMMON_COMMAND("time", CommonCommand_time(request, caller), "Print different formats/readouts of time") \
 702         COMMON_COMMAND("timein", CommonCommand_timein(request, caller), "Resume the game from being paused with a timeout") \
 703         COMMON_COMMAND("timeout", CommonCommand_timeout(request, caller), "Call a timeout which pauses the game for certain amount of time unless unpaused") \
 704         COMMON_COMMAND("vote", VoteCommand(request, caller, arguments, command), "Request an action to be voted upon by players") \
 705         COMMON_COMMAND("who", CommonCommand_who(request, caller, arguments), "Display detailed client information about all players") \
 706         /* nothing */
 707
 708 void CommonCommand_macro_help(entity caller)
 709 {
 710         #define COMMON_COMMAND(name,function,description) \
 711                 { print_to(caller, strcat("  ^2", name, "^7: ", description)); }
 712
 713         COMMON_COMMANDS(0, caller, 0, "")
 714         #undef COMMON_COMMAND
 715
 716         return;
 717 }
 718
 719 float CommonCommand_macro_command(float argc, entity caller, string command)
 720 {
 721         #define COMMON_COMMAND(name,function,description) \
 722                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 723
 724         COMMON_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, command)
 725         #undef COMMON_COMMAND
 726
 727         return FALSE;
 728 }
 729
 730 float CommonCommand_macro_usage(float argc, entity caller)
 731 {
 732         #define COMMON_COMMAND(name,function,description) \
 733                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 734
 735         COMMON_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
 736         #undef COMMON_COMMAND
 737
 738         return FALSE;
 739 }
 740
 741 void CommonCommand_macro_write_aliases(float fh)
 742 {
 743         #define COMMON_COMMAND(name,function,description) \
 744                 { CMD_Write_Alias("qc_cmd_svcmd", name, description); }
 745
 746         COMMON_COMMANDS(0, world, 0, "")
 747         #undef COMMON_COMMAND
 748
 749         return;
 750 }