qcsrc/server/command/getreplies.qc

   1 // =========================================================
   2 //  Reply messages for common commands, re-worked by Samual
   3 //  Last updated: December 30th, 2011
   4 // =========================================================
   5
   6 // These strings are set usually during init in g_world.qc,
   7 // or also by some game modes or other functions manually,
   8 // and their purpose is to output information to clients
   9 // without using any extra processing time.
  10
  11 // See common.qc for their proper commands
  12
  13 string getrecords(float page) // 50 records per page
  14 {
  15         float rec = 0, r, i;
  16         string h, s;
  17
  18         s = "";
  19
  20         if (g_ctf)
  21         {
  22                 for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
  23                 {
  24                         if (MapInfo_Get_ByID(i))
  25                         {
  26                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
  27
  28                                 if (!r)
  29                                         continue;
  30
  31                                 // TODO: uid2name
  32                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
  33                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
  34                                 ++rec;
  35                         }
  36                 }
  37         }
  38
  39         if (g_race)
  40         {
  41                 for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
  42                 {
  43                         if (MapInfo_Get_ByID(i))
  44                         {
  45                                 r = race_readTime(MapInfo_Map_bspname, 1);
  46
  47                                 if (!r)
  48                                         continue;
  49
  50                                 h = race_readName(MapInfo_Map_bspname, 1);
  51                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
  52                                 ++rec;
  53                         }
  54                 }
  55         }
  56
  57         if (g_cts)
  58         {
  59                 for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
  60                 {
  61                         if (MapInfo_Get_ByID(i))
  62                         {
  63                                 r = race_readTime(MapInfo_Map_bspname, 1);
  64
  65                                 if (!r)
  66                                         continue;
  67
  68                                 h = race_readName(MapInfo_Map_bspname, 1);
  69                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
  70                                 ++rec;
  71                         }
  72                 }
  73         }
  74
  75         MapInfo_ClearTemps();
  76
  77         if(s == "" && page == 0)
  78                 return "No records are available on this server.\n";
  79         else
  80                 return s;
  81 }
  82
  83 string getrankings()
  84 {
  85         float t, i;
  86         string n, s, p, map;
  87
  88         map = GetMapname();
  89
  90         s = "";
  91         for (i = 1; i <= RANKINGS_CNT; ++i)
  92         {
  93                 t = race_readTime(map, i);
  94
  95                 if (t == 0)
  96                         continue;
  97
  98                 n = race_readName(map, i);
  99                 p = count_ordinal(i);
 100                 s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
 101         }
 102
 103         MapInfo_ClearTemps();
 104
 105         if (s == "")
 106                 return strcat("No records are available for the map: ", map, "\n");
 107         else
 108                 return strcat("Records for ", map, ":\n", s);
 109 }
 110
 111 string getladder()
 112 {
 113         float i, j, k, uidcnt = 0, thiscnt;
 114         string s, temp_s, rr, myuid, thisuid;
 115
 116         rr = (g_cts) ? CTS_RECORD : RACE_RECORD;
 117
 118         for(k = 0; k < MapInfo_count; ++k)
 119         {
 120                 if(MapInfo_Get_ByID(k))
 121                 {
 122                         for(i = 0; i <= LADDER_CNT; ++i) // i = 0 because it is the speed award
 123                         {
 124                                 if(i == 0) // speed award
 125                                 {
 126                                         if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
 127                                                 continue;
 128
 129                                         myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
 130                                 }
 131                                 else // normal record, if it exists (else break)
 132                                 {
 133                                         if(race_readTime(MapInfo_Map_bspname, i) == 0)
 134                                                 continue;
 135
 136                                         myuid = race_readUID(MapInfo_Map_bspname, i);
 137                                 }
 138
 139                                 // string s contains:
 140                                 // arg 0 = # of speed recs
 141                                 // arg 1 = # of 1st place recs
 142                                 // arg 2 = # of 2nd place recs
 143                                 // ... etc
 144                                 // LADDER_CNT+1 = total points
 145
 146                                 temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
 147
 148                                 if(temp_s == "")
 149                                 {
 150                                         db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
 151                                         ++uidcnt;
 152
 153                                         for(j = 0; j <= LADDER_CNT + 1; ++j)
 154                                         {
 155                                                 if(j != LADDER_CNT + 1)
 156                                                         temp_s = strcat(temp_s, "0 ");
 157                                                 else
 158                                                         temp_s = strcat(temp_s, "0");
 159                                         }
 160                                 }
 161
 162                                 tokenize_console(temp_s);
 163                                 s = "";
 164
 165                                 if(i == 0) // speed award
 166                                 {
 167                                         for(j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
 168                                         {
 169                                                 if(j == 0) // speed award
 170                                                         s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
 171                                                 else
 172                                                         s = strcat(s, " ", argv(j)); // just copy over everything else
 173                                         }
 174                                 }
 175                                 else // record
 176                                 {
 177                                         for(j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
 178                                         {
 179                                                 if(j == 0)
 180                                                         s = strcat(s, argv(j)); // speed award, dont prefix with " "
 181                                                 else if(j == i) // wanted rec!
 182                                                         s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
 183                                                 else
 184                                                         s = strcat(s, " ", argv(j)); // just copy over everything else
 185                                         }
 186                                 }
 187
 188                                 // total points are (by default) calculated like this:
 189                                 // speedrec = floor(100 / 10) = 10 points
 190                                 // 1st place = floor(100 / 1) = 100 points
 191                                 // 2nd place = floor(100 / 2) = 50 points
 192                                 // 3rd place = floor(100 / 3) = 33 points
 193                                 // 4th place = floor(100 / 4) = 25 points
 194                                 // 5th place = floor(100 / 5) = 20 points
 195                                 // ... etc
 196
 197                                 if(i == 0)
 198                                         s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
 199                                 else
 200                                         s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
 201
 202                                 db_put(TemporaryDB, strcat("ladder", myuid), s);
 203                         }
 204                 }
 205         }
 206
 207         for(i = 0; i <= uidcnt; ++i) // for each known uid
 208         {
 209                 thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
 210                 temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
 211                 tokenize_console(temp_s);
 212                 thiscnt = stof(argv(LADDER_CNT+1));
 213
 214                 if(thiscnt > top_scores[LADDER_SIZE-1])
 215                 {
 216                         for(j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
 217                         {
 218                                 if(thiscnt > top_scores[j])
 219                                 {
 220                                         for(k = LADDER_SIZE-1; k >= j; --k)
 221                                         {
 222                                                 top_uids[k] = top_uids[k-1];
 223                                                 top_scores[k] = top_scores[k-1];
 224                                         }
 225
 226                                         top_uids[j] = thisuid;
 227                                         top_scores[j] = thiscnt;
 228                                         break;
 229                                 }
 230                         }
 231                 }
 232         }
 233
 234         s = "^3-----------------------\n\n";
 235
 236         s = strcat(s, "Pos ^3|");
 237         s = strcat(s, " ^7Total  ^3|");
 238
 239         for(i = 1; i <= LADDER_CNT; ++i)
 240                 { s = strcat(s, " ^7", count_ordinal(i), " ^3|"); }
 241
 242         s = strcat(s, " ^7Speed awards ^3| ^7Name");
 243         s = strcat(s, "\n^3----+--------");
 244
 245         for(i = 1; i <= min(9, LADDER_CNT); ++i)
 246                 { s = strcat(s, "+-----"); }
 247
 248         #if LADDER_CNT > 9
 249         for(i = 1; i <= LADDER_CNT - 9; ++i)
 250                 { s = strcat(s, "+------"); }
 251         #endif
 252
 253         s = strcat(s, "+--------------+--------------------\n");
 254
 255         for(i = 0; i < LADDER_SIZE; ++i)
 256         {
 257                 temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
 258                 tokenize_console(temp_s);
 259
 260                 if(argv(LADDER_CNT+1) == "") // total is 0, skip
 261                         continue;
 262
 263                 s = strcat(s, strpad(4, count_ordinal(i+1)), "^3| ^7"); // pos
 264                 s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
 265
 266                 for(j = 1; j <= min(9, LADDER_CNT); ++j)
 267                         { s = strcat(s, strpad(4, argv(j)), "^3| ^7"); } // 1st, 2nd, 3rd etc cnt
 268
 269                 #if LADDER_CNT > 9
 270                 for(j = 10; j <= LADDER_CNT; ++j)
 271                         { s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); } // 1st, 2nd, 3rd etc cnt
 272                 #endif
 273
 274                 s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
 275                 s = strcat(s, uid2name(top_uids[i]), "\n"); // name
 276         }
 277
 278         MapInfo_ClearTemps();
 279
 280         if(s == "")
 281                 return "No ladder on this server!\n";
 282         else
 283                 return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
 284 }
 285
 286 string getmaplist()
 287 {
 288         string maplist = "", col;
 289         float i, argc;
 290
 291         argc = tokenize_console(autocvar_g_maplist);
 292         for(i = 0; i < argc; ++i)
 293         {
 294                 if(MapInfo_CheckMap(argv(i)))
 295                 {
 296                         if(mod(i, 2)) { col = "^2"; }
 297                         else { col = "^3"; }
 298                         maplist = sprintf("%s%s%s ", maplist, col, argv(i));
 299                 }
 300         }
 301
 302         MapInfo_ClearTemps();
 303         return sprintf("^7Maps in list: %s\n", maplist);
 304 }
 305
 306
 307 string getlsmaps()
 308 {
 309         string lsmaps = "", col;
 310         float i, newmaps = 0;
 311
 312         for(i = 0; i < MapInfo_count; ++i)
 313         {
 314                 if((MapInfo_Get_ByID(i)) && !(MapInfo_Map_flags & MapInfo_ForbiddenFlags()))
 315                 {
 316                         // todo: Check by play count of maps for other game types?
 317                         if(
 318                                 (g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 319                                 ||
 320                                 (g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 321                         )
 322                         {
 323                                 newmaps = TRUE;
 324                                 if(mod(i, 2)) { col = "^4*"; }
 325                                 else { col = "^5*"; }
 326                         }
 327                         else
 328                         {
 329                                 if(mod(i, 2)) { col = "^2"; }
 330                                 else { col = "^3"; }
 331                         }
 332
 333                         lsmaps = sprintf("%s%s%s ", lsmaps, col, MapInfo_Map_bspname);
 334                 }
 335         }
 336
 337         MapInfo_ClearTemps();
 338         return sprintf("^7Maps available (%d)%s: %s\n", tokenize_console(lsmaps), (newmaps ? " (New maps have asterisks marked in blue)" : ""), lsmaps);
 339 }
 340
 341 string getmonsterlist()
 342 {
 343         string monsterlist = "", col;
 344         float i;
 345
 346         for(i = MON_FIRST; i <= MON_LAST; ++i)
 347         {
 348                 if(mod(i, 2)) { col = "^2"; }
 349                 else { col = "^3"; }
 350                 monsterlist = sprintf("%s%s%s ", monsterlist, col, (get_monsterinfo(i)).netname);
 351         }
 352
 353         return sprintf("^7Monsters available: %s\n", monsterlist);
 354 }