qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2 #include "_mod.qh"
   3
   4 #include <common/effects/all.qh>
   5
   6 #include "banning.qh"
   7 #include "cmd.qh"
   8 #include "common.qh"
   9 #include "getreplies.qh"
  10 #include "radarmap.qh"
  11
  12 #include "../anticheat.qh"
  13 #include "../campaign.qh"
  14 #include "../client.qh"
  15 #include "../player.qh"
  16 #include "../g_world.qh"
  17 #include "../ipban.qh"
  18 #include "../playerdemo.qh"
  19 #include "../teamplay.qh"
  20
  21 #include "../bot/api.qh"
  22
  23 #include <server/mutators/_mod.qh>
  24 #include <common/gamemodes/_mod.qh>
  25
  26 #include <common/constants.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/mapinfo.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/teams.qh>
  31 #include <common/util.qh>
  32
  33 #include <common/monsters/sv_monsters.qh>
  34
  35
  36 void PutObserverInServer(entity this);
  37
  38 // =====================================================
  39 //  Server side game commands code, reworked by Samual
  40 // =====================================================
  41
  42 //  used by GameCommand_make_mapinfo()
  43 void make_mapinfo_Think(entity this)
  44 {
  45         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  46         {
  47                 LOG_INFO("Done rebuiling mapinfos.");
  48                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  49                 delete(this);
  50         }
  51         else
  52         {
  53                 setthink(this, make_mapinfo_Think);
  54                 this.nextthink = time;
  55         }
  56 }
  57
  58 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  59 void changematchtime(float delta, float mi, float ma)
  60 {
  61         float cur;
  62         float update;
  63         float lim;
  64
  65         if (delta == 0) return;
  66         if (autocvar_timelimit < 0) return;
  67
  68         if (mi <= 10) mi = 10;  // at least ten sec in the future
  69         cur = time - game_starttime;
  70         if (cur > 0) mi += cur; // from current time!
  71
  72         lim = autocvar_timelimit * 60;
  73
  74         if (delta > 0)
  75         {
  76                 if (lim == 0) return; // cannot increase any further
  77                 else if (lim < ma) update = min(ma, lim + delta);
  78                 else                  // already above maximum: FAIL
  79                         return;
  80         }
  81         else
  82         {
  83                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  84                         update = max(mi, ma);
  85                 else if (lim > mi) // above minimum: decrease
  86                         update = max(mi, lim + delta);
  87                 else               // already below minimum: FAIL
  88                         return;
  89         }
  90
  91         cvar_set("timelimit", ftos(update / 60));
  92 }
  93
  94
  95 // =======================
  96 //  Command Sub-Functions
  97 // =======================
  98
  99 void GameCommand_adminmsg(float request, float argc)
 100 {
 101         switch (request)
 102         {
 103                 case CMD_REQUEST_COMMAND:
 104                 {
 105                         entity client;
 106                         float accepted;
 107
 108                         string targets = strreplace(",", " ", argv(1));
 109                         string original_targets = strreplace(" ", ", ", targets);
 110                         string admin_message = argv(2);
 111                         float infobartime = stof(argv(3));
 112
 113                         string successful, t;
 114                         successful = string_null;
 115
 116                         if ((targets) && (admin_message))
 117                         {
 118                                 for ( ; targets; )
 119                                 {
 120                                         t = car(targets);
 121                                         targets = cdr(targets);
 122
 123                                         // Check to see if the player is a valid target
 124                                         client = GetFilteredEntity(t);
 125                                         accepted = VerifyClientEntity(client, true, false);
 126
 127                                         if (accepted <= 0)
 128                                         {
 129                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 130                                                 continue;
 131                                         }
 132
 133                                         // send the centerprint/console print or infomessage
 134                                         if (infobartime)
 135                                         {
 136                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 137                                         }
 138                                         else
 139                                         {
 140                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 141                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 142                                         }
 143
 144                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
 145                                         LOG_TRACE("Message sent to ", playername(client, false));
 146                                         continue;
 147                                 }
 148
 149                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 150                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 151
 152                                 return;
 153                         }
 154                 }
 155
 156                 default:
 157                         LOG_INFO("Incorrect parameters for ^2adminmsg^7");
 158                 case CMD_REQUEST_USAGE:
 159                 {
 160                         LOG_INFO("Usage:^3 sv_cmd adminmsg clients \"message\" [infobartime]");
 161                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
 162                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.");
 163                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.");
 164                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 165                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"");
 166                         return;
 167                 }
 168         }
 169 }
 170
 171 void GameCommand_allready(float request)
 172 {
 173         switch (request)
 174         {
 175                 case CMD_REQUEST_COMMAND:
 176                 {
 177                         ReadyRestart();
 178                         return;
 179                 }
 180
 181                 default:
 182                 case CMD_REQUEST_USAGE:
 183                 {
 184                         LOG_INFO("Usage:^3 sv_cmd allready");
 185                         LOG_INFO("  No arguments required.");
 186                         return;
 187                 }
 188         }
 189 }
 190
 191 void GameCommand_allspec(float request, float argc)
 192 {
 193         switch (request)
 194         {
 195                 case CMD_REQUEST_COMMAND:
 196                 {
 197                         string reason = argv(1);
 198                         int n = 0;
 199                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 200                                 if (it.caplayer) it.caplayer = 0;
 201                                 PutObserverInServer(it);
 202                                 ++n;
 203                         });
 204                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 205                         else   LOG_INFO("No players found to spectate.");
 206                         return;
 207                 }
 208
 209                 default:
 210                 case CMD_REQUEST_USAGE:
 211                 {
 212                         LOG_INFO("Usage:^3 sv_cmd allspec [reason]");
 213                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.");
 214                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7");
 215                         return;
 216                 }
 217         }
 218 }
 219
 220 void GameCommand_anticheat(float request, float argc)
 221 {
 222         switch (request)
 223         {
 224                 case CMD_REQUEST_COMMAND:
 225                 {
 226                         entity client = GetIndexedEntity(argc, 1);
 227                         float accepted = VerifyClientEntity(client, false, false);
 228
 229                         if (accepted > 0)
 230                         {
 231                                 anticheat_report_to_eventlog(client);
 232                                 return;
 233                         }
 234                         else
 235                         {
 236                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 237                         }
 238                 }
 239
 240                 default:
 241                         LOG_INFO("Incorrect parameters for ^2anticheat^7");
 242                 case CMD_REQUEST_USAGE:
 243                 {
 244                         LOG_INFO("Usage:^3 sv_cmd anticheat client");
 245                         LOG_INFO("  'client' is the entity number or name of the player.");
 246                         return;
 247                 }
 248         }
 249 }
 250
 251 void GameCommand_bbox(float request)
 252 {
 253         switch (request)
 254         {
 255                 case CMD_REQUEST_COMMAND:
 256                 {
 257                         vector size_min = '0 0 0';
 258                         vector size_max = '0 0 0';
 259                         tracebox('1 0 0' * world.absmin.x,
 260                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 261                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 262                                 '1 0 0' * world.absmax.x,
 263                                 MOVE_WORLDONLY,
 264                                 NULL);
 265                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 266
 267                         tracebox('0 1 0' * world.absmin.y,
 268                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 269                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 270                                 '0 1 0' * world.absmax.y,
 271                                 MOVE_WORLDONLY,
 272                                 NULL);
 273                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 274
 275                         tracebox('0 0 1' * world.absmin.z,
 276                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 277                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 278                                 '0 0 1' * world.absmax.z,
 279                                 MOVE_WORLDONLY,
 280                                 NULL);
 281                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 282
 283                         tracebox('1 0 0' * world.absmax.x,
 284                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 285                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 286                                 '1 0 0' * world.absmin.x,
 287                                 MOVE_WORLDONLY,
 288                                 NULL);
 289                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 290
 291                         tracebox('0 1 0' * world.absmax.y,
 292                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 293                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 294                                 '0 1 0' * world.absmin.y,
 295                                 MOVE_WORLDONLY,
 296                                 NULL);
 297                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 298
 299                         tracebox('0 0 1' * world.absmax.z,
 300                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 301                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 302                                 '0 0 1' * world.absmin.z,
 303                                 MOVE_WORLDONLY,
 304                                 NULL);
 305                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 306
 307                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 308                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 309                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 310                         return;
 311                 }
 312
 313                 default:
 314                 case CMD_REQUEST_USAGE:
 315                 {
 316                         LOG_INFO("Usage:^3 sv_cmd bbox");
 317                         LOG_INFO("  No arguments required.");
 318                         LOG_INFO("See also: ^2gettaginfo, trace^7");
 319                         return;
 320                 }
 321         }
 322 }
 323
 324 void GameCommand_bot_cmd(float request, float argc, string command)
 325 {
 326         switch (request)
 327         {
 328                 case CMD_REQUEST_COMMAND:
 329                 {
 330                         entity bot;
 331
 332                         if (argv(1) == "reset")
 333                         {
 334                                 bot_resetqueues();
 335                                 return;
 336                         }
 337                         else if (argv(1) == "setbots")
 338                         {
 339                                 cvar_settemp("bot_vs_human", "0");
 340                                 cvar_settemp("minplayers", "0");
 341                                 cvar_settemp("bot_number", "0");
 342                                 bot_fixcount();
 343                                 cvar_settemp("bot_number", argv(2));
 344                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 345                                 return;
 346                         }
 347                         else if (argv(1) == "load" && argc == 3)
 348                         {
 349                                 float fh, i;
 350                                 string s;
 351                                 fh = fopen(argv(2), FILE_READ);
 352                                 if (fh < 0)
 353                                 {
 354                                         LOG_INFO("cannot open the file");
 355                                         return;
 356                                 }
 357
 358                                 i = 0;
 359                                 while ((s = fgets(fh)))
 360                                 {
 361                                         argc = tokenize_console(s);
 362
 363                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 364                                         {
 365                                                 if (argv(2) == "reset")
 366                                                 {
 367                                                         bot_resetqueues();
 368                                                 }
 369                                                 else if (argv(2) == "setbots")
 370                                                 {
 371                                                         cvar_settemp("bot_vs_human", "0");
 372                                                         cvar_settemp("minplayers", "0");
 373                                                         cvar_settemp("bot_number", "0");
 374                                                         bot_fixcount();
 375                                                         cvar_settemp("bot_number", argv(3));
 376                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 377                                                 }
 378                                                 else
 379                                                 {
 380                                                         if(argv(2) == "*" || argv(2) == "all")
 381                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 382                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 383                                                                 });
 384                                                         else
 385                                                         {
 386                                                                 bot = find_bot_by_number(stof(argv(2)));
 387                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 388                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 389                                                         }
 390                                                 }
 391                                         }
 392                                         else
 393                                         {
 394                                                 localcmd(strcat(s, "\n"));
 395                                         }
 396
 397                                         ++i;
 398                                 }
 399                                 LOG_INFO(ftos(i), " commands read");
 400                                 fclose(fh);
 401                                 return;
 402                         }
 403                         else if (argv(1) == "help")
 404                         {
 405                                 if (argv(2)) bot_cmdhelp(argv(2));
 406                                 else bot_list_commands();
 407                                 return;
 408                         }
 409                         else if (argc >= 3)  // this comes last
 410                         {
 411                                 if(argv(1) == "*" || argv(1) == "all")
 412                                 {
 413                                         int bot_num = 0;
 414                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 415                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 416                                                 bot_num++;
 417                                         });
 418                                         if(bot_num)
 419                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 420                                         return;
 421                                 }
 422                                 else
 423                                 {
 424                                         bot = find_bot_by_number(stof(argv(1)));
 425                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 426                                         if (bot)
 427                                         {
 428                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 429                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 430                                                 return;
 431                                         }
 432                                         else
 433                                         {
 434                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 435                                         }
 436                                 }
 437                         }
 438                 }
 439
 440                 default:
 441                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7");
 442                 case CMD_REQUEST_USAGE:
 443                 {
 444                         LOG_INFO("Usage:^3 sv_cmd bot_cmd client command [argument]");
 445                         LOG_INFO("  'client' can be either the name of the bot or a progressive number (not the entity number!)");
 446                         LOG_INFO("           can also be '*' or 'all' to allow sending the command to all the bots");
 447                         LOG_INFO("  For full list of commands, see bot_cmd help [command].");
 448                         LOG_INFO("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 449                         LOG_INFO("          sv_cmd bot_cmd 1 presskey jump");
 450                         LOG_INFO("          sv_cmd bot_cmd * pause");
 451                         return;
 452                 }
 453         }
 454 }
 455
 456 void GameCommand_cointoss(float request, float argc)
 457 {
 458         switch (request)
 459         {
 460                 case CMD_REQUEST_COMMAND:
 461                 {
 462                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 463                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 464                         string choice = ((random() > 0.5) ? result1 : result2);
 465
 466                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 467                         return;
 468                 }
 469
 470                 default:
 471                 case CMD_REQUEST_USAGE:
 472                 {
 473                         LOG_INFO("Usage:^3 sv_cmd cointoss [result1 result2]");
 474                         LOG_INFO("  Where 'result1' and 'result2' are user created options.");
 475                         return;
 476                 }
 477         }
 478 }
 479
 480 void GameCommand_database(float request, float argc)
 481 {
 482         switch (request)
 483         {
 484                 case CMD_REQUEST_COMMAND:
 485                 {
 486                         if (argc == 3)
 487                         {
 488                                 if (argv(1) == "save")
 489                                 {
 490                                         db_save(ServerProgsDB, argv(2));
 491                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 492                                         return;
 493                                 }
 494                                 else if (argv(1) == "dump")
 495                                 {
 496                                         db_dump(ServerProgsDB, argv(2));
 497                                         LOG_INFO("DB dumped.");  // wtf does this do?
 498                                         return;
 499                                 }
 500                                 else if (argv(1) == "load")
 501                                 {
 502                                         db_close(ServerProgsDB);
 503                                         ServerProgsDB = db_load(argv(2));
 504                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 505                                         return;
 506                                 }
 507                         }
 508                 }
 509
 510                 default:
 511                         LOG_INFO("Incorrect parameters for ^2database^7");
 512                 case CMD_REQUEST_USAGE:
 513                 {
 514                         LOG_INFO("Usage:^3 sv_cmd database action filename");
 515                         LOG_INFO("  Where 'action' is the command to complete,");
 516                         LOG_INFO("  and 'filename' is what it acts upon.");
 517                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"");
 518                         return;
 519                 }
 520         }
 521 }
 522
 523 void GameCommand_defer_clear(float request, float argc)
 524 {
 525         switch (request)
 526         {
 527                 case CMD_REQUEST_COMMAND:
 528                 {
 529                         entity client;
 530                         float accepted;
 531
 532                         if (argc >= 2)
 533                         {
 534                                 client = GetIndexedEntity(argc, 1);
 535                                 accepted = VerifyClientEntity(client, true, false);
 536
 537                                 if (accepted > 0)
 538                                 {
 539                                         stuffcmd(client, "defer clear\n");
 540                                         LOG_INFO("defer clear stuffed to ", playername(client, false));
 541                                 }
 542                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 543
 544                                 return;
 545                         }
 546                 }
 547
 548                 default:
 549                         LOG_INFO("Incorrect parameters for ^2defer_clear^7");
 550                 case CMD_REQUEST_USAGE:
 551                 {
 552                         LOG_INFO("Usage:^3 sv_cmd defer_clear client");
 553                         LOG_INFO("  'client' is the entity number or name of the player.");
 554                         LOG_INFO("See also: ^2defer_clear_all^7");
 555                         return;
 556                 }
 557         }
 558 }
 559
 560 void GameCommand_defer_clear_all(float request)
 561 {
 562         switch (request)
 563         {
 564                 case CMD_REQUEST_COMMAND:
 565                 {
 566                         int n = 0;
 567                         float argc;
 568
 569                         FOREACH_CLIENT(true, {
 570                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 571                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 572                                 ++n;
 573                         });
 574                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 575                         return;
 576                 }
 577
 578                 default:
 579                 case CMD_REQUEST_USAGE:
 580                 {
 581                         LOG_INFO("Usage:^3 sv_cmd defer_clear_all");
 582                         LOG_INFO("  No arguments required.");
 583                         LOG_INFO("See also: ^2defer_clear^7");
 584                         return;
 585                 }
 586         }
 587 }
 588
 589 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 590 {
 591         switch (request)
 592         {
 593                 case CMD_REQUEST_COMMAND:
 594                 {
 595                         if (argv(1))
 596                         {
 597                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 598                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 599                                 return;
 600                         }
 601                 }
 602
 603                 default:
 604                         LOG_INFO("Incorrect parameters for ^2delrec^7");
 605                 case CMD_REQUEST_USAGE:
 606                 {
 607                         LOG_INFO("Usage:^3 sv_cmd delrec ranking [map]");
 608                         LOG_INFO("  'ranking' is which ranking level to clear up to, ");
 609                         LOG_INFO("  it will clear all records up to nth place.");
 610                         LOG_INFO("  if 'map' is not provided it will use current map.");
 611                         return;
 612                 }
 613         }
 614 }
 615
 616 void GameCommand_effectindexdump(float request)
 617 {
 618         switch (request)
 619         {
 620                 case CMD_REQUEST_COMMAND:
 621                 {
 622                         float fh, d;
 623                         string s;
 624
 625                         d = db_create();
 626                         LOG_INFO("begin of effects list");
 627                         db_put(d, "TE_GUNSHOT", "1");
 628                         LOG_INFO("effect TE_GUNSHOT is ", ftos(_particleeffectnum("TE_GUNSHOT")));
 629                         db_put(d, "TE_GUNSHOTQUAD", "1");
 630                         LOG_INFO("effect TE_GUNSHOTQUAD is ", ftos(_particleeffectnum("TE_GUNSHOTQUAD")));
 631                         db_put(d, "TE_SPIKE", "1");
 632                         LOG_INFO("effect TE_SPIKE is ", ftos(_particleeffectnum("TE_SPIKE")));
 633                         db_put(d, "TE_SPIKEQUAD", "1");
 634                         LOG_INFO("effect TE_SPIKEQUAD is ", ftos(_particleeffectnum("TE_SPIKEQUAD")));
 635                         db_put(d, "TE_SUPERSPIKE", "1");
 636                         LOG_INFO("effect TE_SUPERSPIKE is ", ftos(_particleeffectnum("TE_SUPERSPIKE")));
 637                         db_put(d, "TE_SUPERSPIKEQUAD", "1");
 638                         LOG_INFO("effect TE_SUPERSPIKEQUAD is ", ftos(_particleeffectnum("TE_SUPERSPIKEQUAD")));
 639                         db_put(d, "TE_WIZSPIKE", "1");
 640                         LOG_INFO("effect TE_WIZSPIKE is ", ftos(_particleeffectnum("TE_WIZSPIKE")));
 641                         db_put(d, "TE_KNIGHTSPIKE", "1");
 642                         LOG_INFO("effect TE_KNIGHTSPIKE is ", ftos(_particleeffectnum("TE_KNIGHTSPIKE")));
 643                         db_put(d, "TE_EXPLOSION", "1");
 644                         LOG_INFO("effect TE_EXPLOSION is ", ftos(_particleeffectnum("TE_EXPLOSION")));
 645                         db_put(d, "TE_EXPLOSIONQUAD", "1");
 646                         LOG_INFO("effect TE_EXPLOSIONQUAD is ", ftos(_particleeffectnum("TE_EXPLOSIONQUAD")));
 647                         db_put(d, "TE_TAREXPLOSION", "1");
 648                         LOG_INFO("effect TE_TAREXPLOSION is ", ftos(_particleeffectnum("TE_TAREXPLOSION")));
 649                         db_put(d, "TE_TELEPORT", "1");
 650                         LOG_INFO("effect TE_TELEPORT is ", ftos(_particleeffectnum("TE_TELEPORT")));
 651                         db_put(d, "TE_LAVASPLASH", "1");
 652                         LOG_INFO("effect TE_LAVASPLASH is ", ftos(_particleeffectnum("TE_LAVASPLASH")));
 653                         db_put(d, "TE_SMALLFLASH", "1");
 654                         LOG_INFO("effect TE_SMALLFLASH is ", ftos(_particleeffectnum("TE_SMALLFLASH")));
 655                         db_put(d, "TE_FLAMEJET", "1");
 656                         LOG_INFO("effect TE_FLAMEJET is ", ftos(_particleeffectnum("TE_FLAMEJET")));
 657                         db_put(d, "EF_FLAME", "1");
 658                         LOG_INFO("effect EF_FLAME is ", ftos(_particleeffectnum("EF_FLAME")));
 659                         db_put(d, "TE_BLOOD", "1");
 660                         LOG_INFO("effect TE_BLOOD is ", ftos(_particleeffectnum("TE_BLOOD")));
 661                         db_put(d, "TE_SPARK", "1");
 662                         LOG_INFO("effect TE_SPARK is ", ftos(_particleeffectnum("TE_SPARK")));
 663                         db_put(d, "TE_PLASMABURN", "1");
 664                         LOG_INFO("effect TE_PLASMABURN is ", ftos(_particleeffectnum("TE_PLASMABURN")));
 665                         db_put(d, "TE_TEI_G3", "1");
 666                         LOG_INFO("effect TE_TEI_G3 is ", ftos(_particleeffectnum("TE_TEI_G3")));
 667                         db_put(d, "TE_TEI_SMOKE", "1");
 668                         LOG_INFO("effect TE_TEI_SMOKE is ", ftos(_particleeffectnum("TE_TEI_SMOKE")));
 669                         db_put(d, "TE_TEI_BIGEXPLOSION", "1");
 670                         LOG_INFO("effect TE_TEI_BIGEXPLOSION is ", ftos(_particleeffectnum("TE_TEI_BIGEXPLOSION")));
 671                         db_put(d, "TE_TEI_PLASMAHIT", "1");
 672                         LOG_INFO("effect TE_TEI_PLASMAHIT is ", ftos(_particleeffectnum("TE_TEI_PLASMAHIT")));
 673                         db_put(d, "EF_STARDUST", "1");
 674                         LOG_INFO("effect EF_STARDUST is ", ftos(_particleeffectnum("EF_STARDUST")));
 675                         db_put(d, "TR_ROCKET", "1");
 676                         LOG_INFO("effect TR_ROCKET is ", ftos(_particleeffectnum("TR_ROCKET")));
 677                         db_put(d, "TR_GRENADE", "1");
 678                         LOG_INFO("effect TR_GRENADE is ", ftos(_particleeffectnum("TR_GRENADE")));
 679                         db_put(d, "TR_BLOOD", "1");
 680                         LOG_INFO("effect TR_BLOOD is ", ftos(_particleeffectnum("TR_BLOOD")));
 681                         db_put(d, "TR_WIZSPIKE", "1");
 682                         LOG_INFO("effect TR_WIZSPIKE is ", ftos(_particleeffectnum("TR_WIZSPIKE")));
 683                         db_put(d, "TR_SLIGHTBLOOD", "1");
 684                         LOG_INFO("effect TR_SLIGHTBLOOD is ", ftos(_particleeffectnum("TR_SLIGHTBLOOD")));
 685                         db_put(d, "TR_KNIGHTSPIKE", "1");
 686                         LOG_INFO("effect TR_KNIGHTSPIKE is ", ftos(_particleeffectnum("TR_KNIGHTSPIKE")));
 687                         db_put(d, "TR_VORESPIKE", "1");
 688                         LOG_INFO("effect TR_VORESPIKE is ", ftos(_particleeffectnum("TR_VORESPIKE")));
 689                         db_put(d, "TR_NEHAHRASMOKE", "1");
 690                         LOG_INFO("effect TR_NEHAHRASMOKE is ", ftos(_particleeffectnum("TR_NEHAHRASMOKE")));
 691                         db_put(d, "TR_NEXUIZPLASMA", "1");
 692                         LOG_INFO("effect TR_NEXUIZPLASMA is ", ftos(_particleeffectnum("TR_NEXUIZPLASMA")));
 693                         db_put(d, "TR_GLOWTRAIL", "1");
 694                         LOG_INFO("effect TR_GLOWTRAIL is ", ftos(_particleeffectnum("TR_GLOWTRAIL")));
 695                         db_put(d, "TR_SEEKER", "1");
 696                         LOG_INFO("effect TR_SEEKER is ", ftos(_particleeffectnum("TR_SEEKER")));
 697                         db_put(d, "SVC_PARTICLE", "1");
 698                         LOG_INFO("effect SVC_PARTICLE is ", ftos(_particleeffectnum("SVC_PARTICLE")));
 699
 700                         fh = fopen("effectinfo.txt", FILE_READ);
 701                         while ((s = fgets(fh)))
 702                         {
 703                                 tokenize_console(s);
 704                                 if (argv(0) == "effect")
 705                                 {
 706                                         if (db_get(d, argv(1)) != "1")
 707                                         {
 708                                                 int i = _particleeffectnum(argv(1));
 709                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 710                                                 db_put(d, argv(1), "1");
 711                                         }
 712                                 }
 713                         }
 714                         LOG_INFO("end of effects list");
 715
 716                         db_close(d);
 717                         return;
 718                 }
 719
 720                 default:
 721                 case CMD_REQUEST_USAGE:
 722                 {
 723                         LOG_INFO("Usage:^3 sv_cmd effectindexdump");
 724                         LOG_INFO("  No arguments required.");
 725                         return;
 726                 }
 727         }
 728 }
 729
 730 void GameCommand_extendmatchtime(float request)
 731 {
 732         switch (request)
 733         {
 734                 case CMD_REQUEST_COMMAND:
 735                 {
 736                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 737                         return;
 738                 }
 739
 740                 default:
 741                 case CMD_REQUEST_USAGE:
 742                 {
 743                         LOG_INFO("Usage:^3 sv_cmd extendmatchtime");
 744                         LOG_INFO("  No arguments required.");
 745                         LOG_INFO("See also: ^2reducematchtime^7");
 746                         return;
 747                 }
 748         }
 749 }
 750
 751 void GameCommand_gametype(float request, float argc)
 752 {
 753         switch (request)
 754         {
 755                 case CMD_REQUEST_COMMAND:
 756                 {
 757                         if (argv(1) != "")
 758                         {
 759                                 string s = argv(1);
 760                                 Gametype t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 761
 762                                 if (t)
 763                                 {
 764                                         MapInfo_SwitchGameType(t);
 765                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 766                                         if (MapInfo_count > 0)
 767                                         {
 768                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 769                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 770                                                 lsmaps_reply = strzone(getlsmaps());
 771                                                 bprint("Game type successfully switched to ", s, "\n");
 772                                         }
 773                                         else
 774                                         {
 775                                                 bprint("Cannot use this game type: no map for it found\n");
 776                                                 MapInfo_SwitchGameType(tsave);
 777                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 778                                         }
 779                                 }
 780                                 else
 781                                 {
 782                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 783                                 }
 784
 785                                 return;
 786                         }
 787                 }
 788
 789                 default:
 790                         LOG_INFO("Incorrect parameters for ^2gametype^7");
 791                 case CMD_REQUEST_USAGE:
 792                 {
 793                         LOG_INFO("Usage:^3 sv_cmd gametype mode");
 794                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.");
 795                         LOG_INFO("See also: ^2gotomap^7");
 796                         return;
 797                 }
 798         }
 799 }
 800
 801 void GameCommand_gettaginfo(float request, float argc)
 802 {
 803         switch (request)
 804         {
 805                 case CMD_REQUEST_COMMAND:
 806                 {
 807                         entity tmp_entity;
 808                         float i;
 809                         vector v;
 810
 811                         if (argc >= 4)
 812                         {
 813                                 tmp_entity = spawn();
 814                                 if (argv(1) == "w")
 815                                 {
 816                                         .entity weaponentity = weaponentities[0];
 817                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 818                                 }
 819                                 else
 820                                 {
 821                                         precache_model(argv(1));
 822                                         _setmodel(tmp_entity, argv(1));
 823                                 }
 824                                 tmp_entity.frame = stof(argv(2));
 825                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 826                                 else i = gettagindex(tmp_entity, argv(3));
 827                                 if (i)
 828                                 {
 829                                         v = gettaginfo(tmp_entity, i);
 830                                         LOG_INFOF(
 831                                             "model %s frame %s tag %s index %s parent %s",
 832                                             tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 833                                         );
 834                                         LOG_INFOF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 835                                         LOG_INFOF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 836                                         LOG_INFOF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 837                                         LOG_INFOF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 838                                         LOG_INFOF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 839                                         if (argc >= 6)
 840                                         {
 841                                                 v.y = -v.y;
 842                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 843                                         }
 844                                 }
 845                                 else
 846                                 {
 847                                         LOG_INFO("bone not found");
 848                                 }
 849
 850                                 delete(tmp_entity);
 851                                 return;
 852                         }
 853                 }
 854
 855                 default:
 856                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 857                 case CMD_REQUEST_USAGE:
 858                 {
 859                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 860                         LOG_INFO("See also: ^2bbox, trace^7");
 861                         return;
 862                 }
 863         }
 864 }
 865
 866 void GameCommand_animbench(float request, float argc)
 867 {
 868         switch (request)
 869         {
 870                 case CMD_REQUEST_COMMAND:
 871                 {
 872                         entity tmp_entity;
 873
 874                         if (argc >= 4)
 875                         {
 876                                 tmp_entity = spawn();
 877                                 if (argv(1) == "w")
 878                                 {
 879                                         .entity weaponentity = weaponentities[0];
 880                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 881                                 }
 882                                 else
 883                                 {
 884                                         precache_model(argv(1));
 885                                         _setmodel(tmp_entity, argv(1));
 886                                 }
 887                                 float f1 = stof(argv(2));
 888                                 float f2 = stof(argv(3));
 889                                 float t0;
 890                                 float t1 = 0;
 891                                 float t2 = 0;
 892                                 float n = 0;
 893
 894                                 while (t1 + t2 < 1)
 895                                 {
 896                                         tmp_entity.frame = f1;
 897                                         t0 = gettime(GETTIME_HIRES);
 898                                         getsurfacepoint(tmp_entity, 0, 0);
 899                                         t1 += gettime(GETTIME_HIRES) - t0;
 900                                         tmp_entity.frame = f2;
 901                                         t0 = gettime(GETTIME_HIRES);
 902                                         getsurfacepoint(tmp_entity, 0, 0);
 903                                         t2 += gettime(GETTIME_HIRES) - t0;
 904                                         n += 1;
 905                                 }
 906                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 907                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 908
 909                                 delete(tmp_entity);
 910                                 return;
 911                         }
 912                 }
 913
 914                 default:
 915                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 916                 case CMD_REQUEST_USAGE:
 917                 {
 918                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 919                         LOG_INFO("See also: ^2bbox, trace^7");
 920                         return;
 921                 }
 922         }
 923 }
 924
 925 void GameCommand_gotomap(float request, float argc)
 926 {
 927         switch (request)
 928         {
 929                 case CMD_REQUEST_COMMAND:
 930                 {
 931                         if (argv(1))
 932                         {
 933                                 LOG_INFO(GotoMap(argv(1)));
 934                                 return;
 935                         }
 936                 }
 937
 938                 default:
 939                         LOG_INFO("Incorrect parameters for ^2gotomap^7");
 940                 case CMD_REQUEST_USAGE:
 941                 {
 942                         LOG_INFO("Usage:^3 sv_cmd gotomap map");
 943                         LOG_INFO("  Where 'map' is the *.bsp file to change to.");
 944                         LOG_INFO("See also: ^2gametype^7");
 945                         return;
 946                 }
 947         }
 948 }
 949
 950 void GameCommand_lockteams(float request)
 951 {
 952         switch (request)
 953         {
 954                 case CMD_REQUEST_COMMAND:
 955                 {
 956                         if (teamplay)
 957                         {
 958                                 lockteams = 1;
 959                                 bprint("^1The teams are now locked.\n");
 960                         }
 961                         else
 962                         {
 963                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 964                         }
 965                         return;
 966                 }
 967
 968                 default:
 969                 case CMD_REQUEST_USAGE:
 970                 {
 971                         LOG_INFO("Usage:^3 sv_cmd lockteams");
 972                         LOG_INFO("  No arguments required.");
 973                         LOG_INFO("See also: ^2unlockteams^7");
 974                         return;
 975                 }
 976         }
 977 }
 978
 979 void GameCommand_make_mapinfo(float request)
 980 {
 981         switch (request)
 982         {
 983                 case CMD_REQUEST_COMMAND:
 984                 {
 985                         entity tmp_entity;
 986
 987                         tmp_entity = new(make_mapinfo);
 988                         setthink(tmp_entity, make_mapinfo_Think);
 989                         tmp_entity.nextthink = time;
 990                         MapInfo_Enumerate();
 991                         return;
 992                 }
 993
 994                 default:
 995                 case CMD_REQUEST_USAGE:
 996                 {
 997                         LOG_INFO("Usage:^3 sv_cmd make_mapinfo");
 998                         LOG_INFO("  No arguments required.");
 999                         LOG_INFO("See also: ^2radarmap^7");
1000                         return;
1001                 }
1002         }
1003 }
1004
1005 void GameCommand_moveplayer(float request, float argc)
1006 {
1007         switch (request)
1008         {
1009                 case CMD_REQUEST_COMMAND:
1010                 {
1011                         float accepted;
1012                         entity client;
1013
1014                         string targets = strreplace(",", " ", argv(1));
1015                         string original_targets = strreplace(" ", ", ", targets);
1016                         string destination = argv(2);
1017
1018                         string successful, t;
1019                         successful = string_null;
1020
1021                         // lets see if the target(s) even actually exist.
1022                         if ((targets) && (destination))
1023                         {
1024                                 for ( ; targets; )
1025                                 {
1026                                         t = car(targets);
1027                                         targets = cdr(targets);
1028
1029                                         // Check to see if the player is a valid target
1030                                         client = GetFilteredEntity(t);
1031                                         accepted = VerifyClientEntity(client, false, false);
1032
1033                                         if (accepted <= 0)
1034                                         {
1035                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
1036                                                 continue;
1037                                         }
1038
1039                                         // Where are we putting this player?
1040                                         if (destination == "spec" || destination == "spectator")
1041                                         {
1042                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1043                                                 {
1044                                                         if (client.caplayer) client.caplayer = 0;
1045                                                         PutObserverInServer(client);
1046
1047                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1048                                                 }
1049                                                 else
1050                                                 {
1051                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already spectating.");
1052                                                 }
1053                                                 continue;
1054                                         }
1055                                         else
1056                                         {
1057                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1058                                                 {
1059                                                         if (teamplay)
1060                                                         {
1061                                                                 // set up
1062                                                                 float team_id;
1063                                                                 float save = client.team_forced;
1064                                                                 client.team_forced = 0;
1065
1066                                                                 // find the team to move the player to
1067                                                                 team_id = Team_ColorToTeam(destination);
1068                                                                 if (team_id == client.team)  // already on the destination team
1069                                                                 {
1070                                                                         // keep the forcing undone
1071                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7."));
1072                                                                         continue;
1073                                                                 }
1074                                                                 else if (team_id == 0)  // auto team
1075                                                                 {
1076                                                                         CheckAllowedTeams(client);
1077                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1078                                                                 }
1079                                                                 else
1080                                                                 {
1081                                                                         CheckAllowedTeams(client);
1082                                                                 }
1083                                                                 client.team_forced = save;
1084
1085                                                                 // Check to see if the destination team is even available
1086                                                                 switch (team_id)
1087                                                                 {
1088                                                                         case NUM_TEAM_1: if (c1 == -1) { LOG_INFO("Sorry, can't move player to red team if it doesn't exist."); return; } break;
1089                                                                         case NUM_TEAM_2: if (c2 == -1) { LOG_INFO("Sorry, can't move player to blue team if it doesn't exist."); return; } break;
1090                                                                         case NUM_TEAM_3: if (c3 == -1) { LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist."); return; } break;
1091                                                                         case NUM_TEAM_4: if (c4 == -1) { LOG_INFO("Sorry, can't move player to pink team if it doesn't exist."); return; } break;
1092
1093                                                                         default: LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.");
1094                                                                                 return;
1095                                                                 }
1096
1097                                                                 // If so, lets continue and finally move the player
1098                                                                 client.team_forced = 0;
1099                                                                 if (MoveToTeam(client, team_id, 6))
1100                                                                 {
1101                                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1102                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") has been moved to the ", Team_ColoredFullName(team_id), "^7.");
1103                                                                 }
1104                                                                 else
1105                                                                 {
1106                                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ")");
1107                                                                 }
1108                                                                 continue;
1109                                                         }
1110                                                         else
1111                                                         {
1112                                                                 LOG_INFO("Can't change teams when currently not playing a team game.");
1113                                                                 return;
1114                                                         }
1115                                                 }
1116                                                 else
1117                                                 {
1118                                                         LOG_INFO("Can't change teams if the player isn't in the game.");  // well technically we could, but should we allow that? :P
1119                                                         return;
1120                                                 }
1121                                         }
1122                                 }
1123
1124                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1125                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1126
1127                                 return;  // still correct parameters so return to avoid usage print
1128                         }
1129                 }
1130
1131                 default:
1132                         LOG_INFO("Incorrect parameters for ^2moveplayer^7");
1133                 case CMD_REQUEST_USAGE:
1134                 {
1135                         LOG_INFO("Usage:^3 sv_cmd moveplayer clients destination");
1136                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
1137                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating");
1138                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"");
1139                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3");
1140                         LOG_INFO("          sv_cmd moveplayer 2 spec ");
1141                         LOG_INFO("See also: ^2allspec, shuffleteams^7");
1142                         return;
1143                 }
1144         }
1145 }
1146
1147 void GameCommand_nospectators(float request)
1148 {
1149         switch (request)
1150         {
1151                 case CMD_REQUEST_COMMAND:
1152                 {
1153                         blockSpectators = 1;
1154                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1155                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1156                                 if(!it.caplayer)
1157                                 {
1158                                         CS(it).spectatortime = time;
1159                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1160                                 }
1161                         });
1162                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1163                         return;
1164                 }
1165
1166                 default:
1167                 case CMD_REQUEST_USAGE:
1168                 {
1169                         LOG_INFO("Usage:^3 sv_cmd nospectators");
1170                         LOG_INFO("  No arguments required.");
1171                         return;
1172                 }
1173         }
1174 }
1175
1176 void GameCommand_playerdemo(float request, float argc)
1177 {
1178         switch (request)
1179         {
1180                 case CMD_REQUEST_COMMAND:
1181                 {
1182                         if (argv(2) && argv(3))
1183                         {
1184                                 entity client;
1185                                 float i, n, accepted;
1186
1187                                 switch (argv(1))
1188                                 {
1189                                         case "read":
1190                                         {
1191                                                 client = GetIndexedEntity(argc, 2);
1192                                                 accepted = VerifyClientEntity(client, false, true);
1193
1194                                                 if (accepted <= 0)
1195                                                 {
1196                                                         LOG_INFO("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".");
1197                                                         return;
1198                                                 }
1199
1200                                                 playerdemo_open_read(client, argv(next_token));
1201                                                 return;
1202                                         }
1203
1204                                         case "write":
1205                                         {
1206                                                 client = GetIndexedEntity(argc, 2);
1207                                                 accepted = VerifyClientEntity(client, false, false);
1208
1209                                                 if (accepted <= 0)
1210                                                 {
1211                                                         LOG_INFO("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".");
1212                                                         return;
1213                                                 }
1214
1215                                                 playerdemo_open_write(client, argv(next_token));
1216                                                 return;
1217                                         }
1218
1219                                         case "auto_read_and_write":
1220                                         {
1221                                                 n = GetFilteredNumber(argv(3));
1222                                                 cvar_set("bot_number", ftos(n));
1223
1224                                                 localcmd("wait; wait; wait\n");
1225                                                 for (i = 0; i < n; ++i)
1226                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1227                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n + 1), "\n");
1228                                                 return;
1229                                         }
1230
1231                                         case "auto_read":
1232                                         {
1233                                                 n = GetFilteredNumber(argv(3));
1234                                                 cvar_set("bot_number", ftos(n));
1235
1236                                                 localcmd("wait; wait; wait\n");
1237                                                 for (i = 0; i < n; ++i)
1238                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1239                                                 return;
1240                                         }
1241                                 }
1242                         }
1243                 }
1244
1245                 default:
1246                         LOG_INFO("Incorrect parameters for ^2playerdemo^7");
1247                 case CMD_REQUEST_USAGE:
1248                 {
1249                         LOG_INFO("Usage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)");
1250                         LOG_INFO("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"");
1251                         return;
1252                 }
1253         }
1254 }
1255
1256 void GameCommand_printstats(float request)
1257 {
1258         switch (request)
1259         {
1260                 case CMD_REQUEST_COMMAND:
1261                 {
1262                         DumpStats(false);
1263                         LOG_INFO("stats dumped.");
1264                         return;
1265                 }
1266
1267                 default:
1268                 case CMD_REQUEST_USAGE:
1269                 {
1270                         LOG_INFO("Usage:^3 sv_cmd printstats");
1271                         LOG_INFO("  No arguments required.");
1272                         return;
1273                 }
1274         }
1275 }
1276
1277 void GameCommand_radarmap(float request, float argc)
1278 {
1279         switch (request)
1280         {
1281                 case CMD_REQUEST_COMMAND:
1282                 {
1283                         if (RadarMap_Make(argc)) return;
1284                 }
1285
1286                 default:
1287                         LOG_INFO("Incorrect parameters for ^2radarmap^7");
1288                 case CMD_REQUEST_USAGE:
1289                 {
1290                         LOG_INFO("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1291                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.");
1292                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1293                         LOG_INFO("See also: ^2make_mapinfo^7");
1294                         return;
1295                 }
1296         }
1297 }
1298
1299 void GameCommand_reducematchtime(float request)
1300 {
1301         switch (request)
1302         {
1303                 case CMD_REQUEST_COMMAND:
1304                 {
1305                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1306                         return;
1307                 }
1308
1309                 default:
1310                 case CMD_REQUEST_USAGE:
1311                 {
1312                         LOG_INFO("Usage:^3 sv_cmd reducematchtime");
1313                         LOG_INFO("  No arguments required.");
1314                         LOG_INFO("See also: ^2extendmatchtime^7");
1315                         return;
1316                 }
1317         }
1318 }
1319
1320 void GameCommand_setbots(float request, float argc)
1321 {
1322         switch (request)
1323         {
1324                 case CMD_REQUEST_COMMAND:
1325                 {
1326                         if (argc >= 2)
1327                         {
1328                                 cvar_settemp("minplayers", "0");
1329                                 cvar_settemp("bot_number", argv(1));
1330                                 bot_fixcount();
1331                                 return;
1332                         }
1333                 }
1334
1335                 default:
1336                         LOG_INFO("Incorrect parameters for ^2setbots^7");
1337                 case CMD_REQUEST_USAGE:
1338                 {
1339                         LOG_INFO("Usage:^3 sv_cmd setbots botnumber");
1340                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.");
1341                         LOG_INFO("See also: ^2bot_cmd^7");
1342                         return;
1343                 }
1344         }
1345 }
1346
1347 void GameCommand_shuffleteams(float request)
1348 {
1349         switch (request)
1350         {
1351                 case CMD_REQUEST_COMMAND:
1352                 {
1353                         if (!teamplay)
1354                         {
1355                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1356                                 return;
1357                         }
1358
1359                         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1360                                 if (it.team_forced) {
1361                                         // we could theoretically assign forced players to their teams
1362                                         // and shuffle the rest to fill the empty spots but in practise
1363                                         // either all players or none are gonna have forced teams
1364                                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1365                                         return;
1366                                 }
1367                         });
1368
1369                         int number_of_teams = 0;
1370                         CheckAllowedTeams(NULL);
1371                         if (c1 >= 0) number_of_teams = max(1, number_of_teams);
1372                         if (c2 >= 0) number_of_teams = max(2, number_of_teams);
1373                         if (c3 >= 0) number_of_teams = max(3, number_of_teams);
1374                         if (c4 >= 0) number_of_teams = max(4, number_of_teams);
1375
1376                         int team_index = 0;
1377                         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1378                                 int target_team_number = Team_NumberToTeam(team_index + 1);
1379                                 if (it.team != target_team_number) MoveToTeam(it, target_team_number, 6);
1380                                 team_index = (team_index + 1) % number_of_teams;
1381                         });
1382
1383                         bprint("Successfully shuffled the players around randomly.\n");
1384                         return;
1385                 }
1386
1387                 default:
1388                 case CMD_REQUEST_USAGE:
1389                 {
1390                         LOG_INFO("Usage:^3 sv_cmd shuffleteams");
1391                         LOG_INFO("  No arguments required.");
1392                         LOG_INFO("See also: ^2moveplayer, allspec^7");
1393                         return;
1394                 }
1395         }
1396 }
1397
1398 void GameCommand_stuffto(float request, float argc)
1399 {
1400         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1401         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1402         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1403
1404 #ifdef STUFFTO_ENABLED
1405                 switch (request)
1406                 {
1407                         case CMD_REQUEST_COMMAND:
1408                         {
1409                                 if (argv(2))
1410                                 {
1411                                         entity client = GetIndexedEntity(argc, 1);
1412                                         float accepted = VerifyClientEntity(client, true, false);
1413
1414                                         if (accepted > 0)
1415                                         {
1416                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1417                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1418                                         }
1419                                         else
1420                                         {
1421                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1422                                         }
1423
1424                                         return;
1425                                 }
1426                         }
1427
1428                         default:
1429                                 LOG_INFO("Incorrect parameters for ^2stuffto^7");
1430                         case CMD_REQUEST_USAGE:
1431                         {
1432                                 LOG_INFO("Usage:^3 sv_cmd stuffto client \"command\"");
1433                                 LOG_INFO("  'client' is the entity number or name of the player,");
1434                                 LOG_INFO("  and 'command' is the command to be sent to that player.");
1435                                 return;
1436                         }
1437                 }
1438 #else
1439                 if (request)
1440                 {
1441                         LOG_INFO("stuffto command is not enabled on this server.");
1442                         return;
1443                 }
1444 #endif
1445 }
1446
1447 void GameCommand_trace(float request, float argc)
1448 {
1449         switch (request)
1450         {
1451                 case CMD_REQUEST_COMMAND:
1452                 {
1453                         entity e;
1454                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1455                         float i, f, safe, unsafe, dq, dqf;
1456
1457                         switch (argv(1))
1458                         {
1459                                 case "debug":
1460                                 {
1461                                         float hitcount = 0;
1462                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1463                                         float worst_endpos_bug = 0;
1464                                         for ( ; ; )
1465                                         {
1466                                                 org = world.mins;
1467                                                 delta = world.maxs - world.mins;
1468
1469                                                 start.x = org.x + random() * delta.x;
1470                                                 start.y = org.y + random() * delta.y;
1471                                                 start.z = org.z + random() * delta.z;
1472
1473                                                 end.x = org.x + random() * delta.x;
1474                                                 end.y = org.y + random() * delta.y;
1475                                                 end.z = org.z + random() * delta.z;
1476
1477                                                 start = stov(vtos(start));
1478                                                 end = stov(vtos(end));
1479
1480                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1481                                                 if (!trace_startsolid && trace_fraction < 1)
1482                                                 {
1483                                                         p = trace_endpos;
1484                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1485                                                         if (trace_startsolid)
1486                                                         {
1487                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1488                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1489
1490                                                                 // how much do we need to back off?
1491                                                                 safe = 1;
1492                                                                 unsafe = 0;
1493                                                                 for ( ; ; )
1494                                                                 {
1495                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1496                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1497                                                                         if (trace_startsolid)
1498                                                                         {
1499                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1500                                                                                 unsafe = (safe + unsafe) * 0.5;
1501                                                                         }
1502                                                                         else
1503                                                                         {
1504                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1505                                                                                 safe = (safe + unsafe) * 0.5;
1506                                                                         }
1507                                                                 }
1508
1509                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1510                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1511
1512                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1513                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1514                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1515                                                                 if (++hitcount >= 10) break;
1516                                                         }
1517                                                         else
1518                                                         {
1519                                                                 q0 = p;
1520                                                                 dq = 0;
1521                                                                 dqf = 1;
1522                                                                 for ( ; ; )
1523                                                                 {
1524                                                                         q = p + normalize(end - p) * (dq + dqf);
1525                                                                         if (q == q0) break;
1526                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1527                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1528                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1529                                                                         dqf *= 0.5;
1530                                                                         q0 = q;
1531                                                                 }
1532                                                                 if (dq > worst_endpos_bug)
1533                                                                 {
1534                                                                         worst_endpos_bug = dq;
1535                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1536                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1537                                                                         if (++hitcount >= 10) break;
1538                                                                 }
1539                                                         }
1540                                                 }
1541                                         }
1542                                         return;
1543                                 }
1544
1545                                 case "debug2":
1546                                 {
1547                                         e = nextent(NULL);
1548                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1549                                         vv = trace_endpos;
1550                                         if (trace_fraction == 1)
1551                                         {
1552                                                 LOG_INFO("not above ground, aborting");
1553                                                 return;
1554                                         }
1555                                         f = 0;
1556                                         for (i = 0; i < 100000; ++i)
1557                                         {
1558                                                 dv = randomvec();
1559                                                 if (dv.z > 0) dv = -1 * dv;
1560                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1561                                                 if (trace_startsolid) LOG_INFO("bug 1");
1562                                                 if (trace_fraction == 1)
1563                                                 {
1564                                                         if (dv.z < f)
1565                                                         {
1566                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1567                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1568                                                                 f = dv.z;
1569                                                         }
1570                                                 }
1571                                         }
1572                                         LOG_INFO("highest possible dist: ", ftos(f));
1573                                         return;
1574                                 }
1575
1576                                 case "walk":
1577                                 {
1578                                         if (argc == 4 || argc == 5)
1579                                         {
1580                                                 e = nextent(NULL);
1581                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1582                                                         LOG_INFO("can walk");
1583                                                 else
1584                                                         LOG_INFO("cannot walk");
1585                                                 return;
1586                                         }
1587                                 }
1588
1589                                 case "showline":
1590                                 {
1591                                         if (argc == 4)
1592                                         {
1593                                                 vv = stov(argv(2));
1594                                                 dv = stov(argv(3));
1595                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1596                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1597                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1598                                                 return;
1599                                         }
1600                                 }
1601
1602                                         // no default case, just go straight to invalid
1603                         }
1604                 }
1605
1606                 default:
1607                         LOG_INFO("Incorrect parameters for ^2trace^7");
1608                 case CMD_REQUEST_USAGE:
1609                 {
1610                         LOG_INFO("Usage:^3 sv_cmd trace command [startpos endpos] [endpos_height]");
1611                         LOG_INFO("  Where startpos and endpos are parameters for 'walk' and 'showline' commands,");
1612                         LOG_INFO("  'endpos_height' is an optional parameter for 'walk' command,");
1613                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"");
1614                         LOG_INFO("See also: ^2bbox, gettaginfo^7");
1615                         return;
1616                 }
1617         }
1618 }
1619
1620 void GameCommand_unlockteams(float request)
1621 {
1622         switch (request)
1623         {
1624                 case CMD_REQUEST_COMMAND:
1625                 {
1626                         if (teamplay)
1627                         {
1628                                 lockteams = 0;
1629                                 bprint("^1The teams are now unlocked.\n");
1630                         }
1631                         else
1632                         {
1633                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1634                         }
1635                         return;
1636                 }
1637
1638                 default:
1639                 case CMD_REQUEST_USAGE:
1640                 {
1641                         LOG_INFO("Usage:^3 sv_cmd unlockteams");
1642                         LOG_INFO("  No arguments required.");
1643                         LOG_INFO("See also: ^2lockteams^7");
1644                         return;
1645                 }
1646         }
1647 }
1648
1649 void GameCommand_warp(float request, float argc)
1650 {
1651         switch (request)
1652         {
1653                 case CMD_REQUEST_COMMAND:
1654                 {
1655                         if (autocvar_g_campaign)
1656                         {
1657                                 if (argc >= 2)
1658                                 {
1659                                         CampaignLevelWarp(stof(argv(1)));
1660                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1661                                 }
1662                                 else
1663                                 {
1664                                         CampaignLevelWarp(-1);
1665                                         LOG_INFO("Successfully warped to next campaign level.");
1666                                 }
1667                         }
1668                         else
1669                         {
1670                                 LOG_INFO("Not in campaign, can't level warp");
1671                         }
1672                         return;
1673                 }
1674
1675                 default:
1676                 case CMD_REQUEST_USAGE:
1677                 {
1678                         LOG_INFO("Usage:^3 sv_cmd warp [level]");
1679                         LOG_INFO("  'level' is the level to change campaign mode to.");
1680                         LOG_INFO("  if 'level' is not provided it will change to the next level.");
1681                         return;
1682                 }
1683         }
1684 }
1685
1686 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1687 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1688 void GameCommand_(float request)
1689 {
1690     switch(request)
1691     {
1692         case CMD_REQUEST_COMMAND:
1693         {
1694
1695             return;
1696         }
1697
1698         default:
1699         case CMD_REQUEST_USAGE:
1700         {
1701             print("\nUsage:^3 sv_cmd \n");
1702             print("  No arguments required.\n");
1703             return;
1704         }
1705     }
1706 }
1707 */
1708
1709
1710 // ==================================
1711 //  Macro system for server commands
1712 // ==================================
1713
1714 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1715 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1716 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1717 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1718 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1719 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1720 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1721 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1722 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1723 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1724 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1725 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1726 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1727 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1728 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1729 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1730 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1731 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1732 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1733 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1734 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1735 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1736 SERVER_COMMAND(playerdemo, "Control the ability to save demos of players") { GameCommand_playerdemo(request, arguments); }
1737 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1738 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1739 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1740 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1741 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1742 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1743 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1744 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1745 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1746
1747 void GameCommand_macro_help()
1748 {
1749         FOREACH(SERVER_COMMANDS, true, { LOG_INFOF("  ^2%s^7: %s", it.m_name, it.m_description); });
1750 }
1751
1752 float GameCommand_macro_command(float argc, string command)
1753 {
1754         string c = strtolower(argv(0));
1755         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1756                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1757                 return true;
1758         });
1759         return false;
1760 }
1761
1762 float GameCommand_macro_usage(float argc)
1763 {
1764         string c = strtolower(argv(1));
1765         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1766                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1767                 return true;
1768         });
1769         return false;
1770 }
1771
1772 void GameCommand_macro_write_aliases(float fh)
1773 {
1774         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1775 }
1776
1777
1778 // =========================================
1779 //  Main Function Called By Engine (sv_cmd)
1780 // =========================================
1781 // If this function exists, game code handles gamecommand instead of the engine code.
1782
1783 void GameCommand(string command)
1784 {
1785         float argc = tokenize_console(command);
1786
1787         // Guide for working with argc arguments by example:
1788         // argc:   1    - 2      - 3     - 4
1789         // argv:   0    - 1      - 2     - 3
1790         // cmd     vote - master - login - password
1791
1792         if (strtolower(argv(0)) == "help")
1793         {
1794                 if (argc == 1)
1795                 {
1796                         LOG_INFO("Server console commands:");
1797                         GameCommand_macro_help();
1798
1799                         LOG_INFO("\nBanning commands:");
1800                         BanCommand_macro_help();
1801
1802                         LOG_INFO("\nCommon networked commands:");
1803                         CommonCommand_macro_help(NULL);
1804
1805                         LOG_INFO("\nGeneric commands shared by all programs:");
1806                         GenericCommand_macro_help();
1807
1808                         LOG_INFO(
1809                             "\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n"
1810                 "For help about a specific command, type sv_cmd help COMMAND"
1811             );
1812
1813                         return;
1814                 }
1815                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1816                 {
1817                         return;
1818                 }
1819                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1820                 {
1821                         return;
1822                 }
1823                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1824                 {
1825                         return;
1826                 }
1827                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1828                 {
1829                         return;
1830                 }
1831         }
1832         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1833         {
1834                 return;  // handled by a mutator
1835         }
1836         else if (BanCommand(command))
1837         {
1838                 return;  // handled by server/command/ipban.qc
1839         }
1840         else if (CommonCommand_macro_command(argc, NULL, command))
1841         {
1842                 return;  // handled by server/command/common.qc
1843         }
1844         else if (GenericCommand(command))
1845         {
1846                 return;                                        // handled by common/command/generic.qc
1847         }
1848         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1849         {
1850                 return;                                        // handled by one of the above GameCommand_* functions
1851         }
1852
1853         // nothing above caught the command, must be invalid
1854         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1855 }