Rename a few parameters and locals named x, y, z
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / sv_cmd.qc
1 #include "sv_cmd.qh"
2 #include "_mod.qh"
3
4 #include "banning.qh"
5 #include "cmd.qh"
6 #include "common.qh"
7 #include "getreplies.qh"
8 #include "radarmap.qh"
9
10 #include "../anticheat.qh"
11 #include "../campaign.qh"
12 #include "../client.qh"
13 #include "../player.qh"
14 #include "../g_world.qh"
15 #include "../ipban.qh"
16 #include "../playerdemo.qh"
17 #include "../teamplay.qh"
18
19 #include "../bot/api.qh"
20
21 #include "../mutators/_mod.qh"
22
23 #include <common/constants.qh>
24 #include <common/net_linked.qh>
25 #include <common/mapinfo.qh>
26 #include <common/notifications/all.qh>
27 #include <common/teams.qh>
28 #include <common/util.qh>
29
30 #include <common/monsters/sv_monsters.qh>
31
32
33 void PutObserverInServer(entity this);
34
35 // =====================================================
36 //  Server side game commands code, reworked by Samual
37 //  Last updated: December 29th, 2011
38 // =====================================================
39
40 //  used by GameCommand_make_mapinfo()
41 void make_mapinfo_Think(entity this)
42 {
43         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
44         {
45                 LOG_INFO("Done rebuiling mapinfos.\n");
46                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
47                 delete(this);
48         }
49         else
50         {
51                 setthink(this, make_mapinfo_Think);
52                 this.nextthink = time;
53         }
54 }
55
56 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
57 void changematchtime(float delta, float mi, float ma)
58 {
59         float cur;
60         float update;
61         float lim;
62
63         if (delta == 0) return;
64         if (autocvar_timelimit < 0) return;
65
66         if (mi <= 10) mi = 10;  // at least ten sec in the future
67         cur = time - game_starttime;
68         if (cur > 0) mi += cur; // from current time!
69
70         lim = autocvar_timelimit * 60;
71
72         if (delta > 0)
73         {
74                 if (lim == 0) return; // cannot increase any further
75                 else if (lim < ma) update = min(ma, lim + delta);
76                 else                  // already above maximum: FAIL
77                         return;
78         }
79         else
80         {
81                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
82                         update = max(mi, ma);
83                 else if (lim > mi) // above minimum: decrease
84                         update = max(mi, lim + delta);
85                 else               // already below minimum: FAIL
86                         return;
87         }
88
89         cvar_set("timelimit", ftos(update / 60));
90 }
91
92
93 // =======================
94 //  Command Sub-Functions
95 // =======================
96
97 void GameCommand_adminmsg(float request, float argc)
98 {
99         switch (request)
100         {
101                 case CMD_REQUEST_COMMAND:
102                 {
103                         entity client;
104                         float accepted;
105
106                         string targets = strreplace(",", " ", argv(1));
107                         string original_targets = strreplace(" ", ", ", targets);
108                         string admin_message = argv(2);
109                         float infobartime = stof(argv(3));
110
111                         string successful, t;
112                         successful = string_null;
113
114                         if ((targets) && (admin_message))
115                         {
116                                 for ( ; targets; )
117                                 {
118                                         t = car(targets);
119                                         targets = cdr(targets);
120
121                                         // Check to see if the player is a valid target
122                                         client = GetFilteredEntity(t);
123                                         accepted = VerifyClientEntity(client, true, false);
124
125                                         if (accepted <= 0)
126                                         {
127                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
128                                                 continue;
129                                         }
130
131                                         // send the centerprint/console print or infomessage
132                                         if (infobartime)
133                                         {
134                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
135                                         }
136                                         else
137                                         {
138                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
139                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
140                                         }
141
142                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
143                                         LOG_TRACE("Message sent to ", client.netname);
144                                         continue;
145                                 }
146
147                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
148                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.\n");
149
150                                 return;
151                         }
152                 }
153
154                 default:
155                         LOG_INFO("Incorrect parameters for ^2adminmsg^7\n");
156                 case CMD_REQUEST_USAGE:
157                 {
158                         LOG_INFO("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
159                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
160                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.\n");
161                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.\n");
162                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
163                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"\n");
164                         return;
165                 }
166         }
167 }
168
169 void GameCommand_allready(float request)
170 {
171         switch (request)
172         {
173                 case CMD_REQUEST_COMMAND:
174                 {
175                         ReadyRestart();
176                         return;
177                 }
178
179                 default:
180                 case CMD_REQUEST_USAGE:
181                 {
182                         LOG_INFO("\nUsage:^3 sv_cmd allready\n");
183                         LOG_INFO("  No arguments required.\n");
184                         return;
185                 }
186         }
187 }
188
189 void GameCommand_allspec(float request, float argc)
190 {
191         switch (request)
192         {
193                 case CMD_REQUEST_COMMAND:
194                 {
195                         string reason = argv(1);
196                         int n = 0;
197                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
198                                 if (it.caplayer) it.caplayer = 0;
199                                 PutObserverInServer(it);
200                                 ++n;
201                         ));
202                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
203                         else   LOG_INFO("No players found to spectate.\n");
204                         return;
205                 }
206
207                 default:
208                 case CMD_REQUEST_USAGE:
209                 {
210                         LOG_INFO("\nUsage:^3 sv_cmd allspec [reason]\n");
211                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.\n");
212                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7\n");
213                         return;
214                 }
215         }
216 }
217
218 void GameCommand_anticheat(float request, float argc)
219 {
220         switch (request)
221         {
222                 case CMD_REQUEST_COMMAND:
223                 {
224                         entity client = GetIndexedEntity(argc, 1);
225                         float accepted = VerifyClientEntity(client, false, false);
226
227                         if (accepted > 0)
228                         {
229                                 anticheat_report_to_eventlog(client);
230                                 return;
231                         }
232                         else
233                         {
234                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
235                         }
236                 }
237
238                 default:
239                         LOG_INFO("Incorrect parameters for ^2anticheat^7\n");
240                 case CMD_REQUEST_USAGE:
241                 {
242                         LOG_INFO("\nUsage:^3 sv_cmd anticheat client\n");
243                         LOG_INFO("  'client' is the entity number or name of the player.\n");
244                         return;
245                 }
246         }
247 }
248
249 void GameCommand_bbox(float request)
250 {
251         switch (request)
252         {
253                 case CMD_REQUEST_COMMAND:
254                 {
255                         LOG_INFO("Original size: ", ftos(world.absmin.x), " ", ftos(world.absmin.y), " ", ftos(world.absmin.z));
256                         LOG_INFO(" ", ftos(world.absmax.x), " ", ftos(world.absmax.y), " ", ftos(world.absmax.z), "\n");
257                         LOG_INFO("Currently set size: ", ftos(world.mins.x), " ", ftos(world.mins.y), " ", ftos(world.mins.z));
258                         LOG_INFO(" ", ftos(world.maxs.x), " ", ftos(world.maxs.y), " ", ftos(world.maxs.z), "\n");
259                         LOG_INFO("Solid bounding box size:");
260
261                         tracebox('1 0 0' * world.absmin.x,
262                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
263                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
264                                 '1 0 0' * world.absmax.x,
265                                 MOVE_WORLDONLY,
266                                 NULL);
267                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmin.x));
268                         else LOG_INFO(" ", ftos(trace_endpos.x));
269
270                         tracebox('0 1 0' * world.absmin.y,
271                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
272                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
273                                 '0 1 0' * world.absmax.y,
274                                 MOVE_WORLDONLY,
275                                 NULL);
276                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmin.y));
277                         else LOG_INFO(" ", ftos(trace_endpos.y));
278
279                         tracebox('0 0 1' * world.absmin.z,
280                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
281                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
282                                 '0 0 1' * world.absmax.z,
283                                 MOVE_WORLDONLY,
284                                 NULL);
285                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmin.z));
286                         else LOG_INFO(" ", ftos(trace_endpos.z));
287
288                         tracebox('1 0 0' * world.absmax.x,
289                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
290                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
291                                 '1 0 0' * world.absmin.x,
292                                 MOVE_WORLDONLY,
293                                 NULL);
294                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmax.x));
295                         else LOG_INFO(" ", ftos(trace_endpos.x));
296
297                         tracebox('0 1 0' * world.absmax.y,
298                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
299                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
300                                 '0 1 0' * world.absmin.y,
301                                 MOVE_WORLDONLY,
302                                 NULL);
303                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmax.y));
304                         else LOG_INFO(" ", ftos(trace_endpos.y));
305
306                         tracebox('0 0 1' * world.absmax.z,
307                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
308                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
309                                 '0 0 1' * world.absmin.z,
310                                 MOVE_WORLDONLY,
311                                 NULL);
312                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmax.z));
313                         else LOG_INFO(" ", ftos(trace_endpos.z));
314
315                         LOG_INFO("\n");
316                         return;
317                 }
318
319                 default:
320                 case CMD_REQUEST_USAGE:
321                 {
322                         LOG_INFO("\nUsage:^3 sv_cmd bbox\n");
323                         LOG_INFO("  No arguments required.\n");
324                         LOG_INFO("See also: ^2gettaginfo, trace^7\n");
325                         return;
326                 }
327         }
328 }
329
330 void GameCommand_bot_cmd(float request, float argc, string command)
331 {
332         switch (request)
333         {
334                 case CMD_REQUEST_COMMAND:
335                 {
336                         entity bot;
337
338                         if (argv(1) == "reset")
339                         {
340                                 bot_resetqueues();
341                                 return;
342                         }
343                         else if (argv(1) == "setbots")
344                         {
345                                 cvar_settemp("bot_vs_human", "0");
346                                 cvar_settemp("minplayers", "0");
347                                 cvar_settemp("bot_number", "0");
348                                 bot_fixcount();
349                                 cvar_settemp("bot_number", argv(2));
350                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count\n");
351                                 return;
352                         }
353                         else if (argv(1) == "load" && argc == 3)
354                         {
355                                 float fh, i;
356                                 string s;
357                                 fh = fopen(argv(2), FILE_READ);
358                                 if (fh < 0)
359                                 {
360                                         LOG_INFO("cannot open the file\n");
361                                         return;
362                                 }
363
364                                 i = 0;
365                                 while ((s = fgets(fh)))
366                                 {
367                                         argc = tokenize_console(s);
368
369                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
370                                         {
371                                                 if (argv(2) == "reset")
372                                                 {
373                                                         bot_resetqueues();
374                                                 }
375                                                 else if (argv(2) == "setbots")
376                                                 {
377                                                         cvar_settemp("bot_vs_human", "0");
378                                                         cvar_settemp("minplayers", "0");
379                                                         cvar_settemp("bot_number", "0");
380                                                         bot_fixcount();
381                                                         cvar_settemp("bot_number", argv(3));
382                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count\n");
383                                                 }
384                                                 else
385                                                 {
386                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
387                                                         bot = find_bot_by_number(stof(argv(2)));
388                                                         if (bot == NULL) bot = find_bot_by_name(argv(2));
389                                                         if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
390                                                 }
391                                         }
392                                         else
393                                         {
394                                                 localcmd(strcat(s, "\n"));
395                                         }
396
397                                         ++i;
398                                 }
399                                 LOG_INFO(ftos(i), " commands read\n");
400                                 fclose(fh);
401                                 return;
402                         }
403                         else if (argv(1) == "help")
404                         {
405                                 if (argv(2)) bot_cmdhelp(argv(2));
406                                 else bot_list_commands();
407                                 return;
408                         }
409                         else if (argc >= 3)  // this comes last
410                         {
411                                 bot = find_bot_by_number(stof(argv(1)));
412                                 if (bot == NULL) bot = find_bot_by_name(argv(1));
413                                 if (bot)
414                                 {
415                                         LOG_INFO(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
416                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
417                                         return;
418                                 }
419                                 else
420                                 {
421                                         LOG_INFO(strcat("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?\n"));  // don't return so that usage is shown
422                                 }
423                         }
424                 }
425
426                 default:
427                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7\n");
428                 case CMD_REQUEST_USAGE:
429                 {
430                         LOG_INFO("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
431                         LOG_INFO("  'client' can be either the name or entity id of the bot\n");
432                         LOG_INFO("  For full list of commands, see bot_cmd help [command].\n");
433                         LOG_INFO("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
434                         LOG_INFO("          sv_cmd bot_cmd client presskey jump\n");
435                         return;
436                 }
437         }
438 }
439
440 void GameCommand_cointoss(float request, float argc)
441 {
442         switch (request)
443         {
444                 case CMD_REQUEST_COMMAND:
445                 {
446                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
447                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
448                         string choice = ((random() > 0.5) ? result1 : result2);
449
450                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
451                         return;
452                 }
453
454                 default:
455                 case CMD_REQUEST_USAGE:
456                 {
457                         LOG_INFO("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
458                         LOG_INFO("  Where 'result1' and 'result2' are user created options.\n");
459                         return;
460                 }
461         }
462 }
463
464 void GameCommand_database(float request, float argc)
465 {
466         switch (request)
467         {
468                 case CMD_REQUEST_COMMAND:
469                 {
470                         if (argc == 3)
471                         {
472                                 if (argv(1) == "save")
473                                 {
474                                         db_save(ServerProgsDB, argv(2));
475                                         LOG_INFO(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
476                                         return;
477                                 }
478                                 else if (argv(1) == "dump")
479                                 {
480                                         db_dump(ServerProgsDB, argv(2));
481                                         LOG_INFO("DB dumped.\n");  // wtf does this do?
482                                         return;
483                                 }
484                                 else if (argv(1) == "load")
485                                 {
486                                         db_close(ServerProgsDB);
487                                         ServerProgsDB = db_load(argv(2));
488                                         LOG_INFO(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
489                                         return;
490                                 }
491                         }
492                 }
493
494                 default:
495                         LOG_INFO("Incorrect parameters for ^2database^7\n");
496                 case CMD_REQUEST_USAGE:
497                 {
498                         LOG_INFO("\nUsage:^3 sv_cmd database action filename\n");
499                         LOG_INFO("  Where 'action' is the command to complete,\n");
500                         LOG_INFO("  and 'filename' is what it acts upon.\n");
501                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"\n");
502                         return;
503                 }
504         }
505 }
506
507 void GameCommand_defer_clear(float request, float argc)
508 {
509         switch (request)
510         {
511                 case CMD_REQUEST_COMMAND:
512                 {
513                         entity client;
514                         float accepted;
515
516                         if (argc >= 2)
517                         {
518                                 client = GetIndexedEntity(argc, 1);
519                                 accepted = VerifyClientEntity(client, true, false);
520
521                                 if (accepted > 0)
522                                 {
523                                         stuffcmd(client, "defer clear\n");
524                                         LOG_INFO("defer clear stuffed to ", client.netname, "\n");
525                                 }
526                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
527
528                                 return;
529                         }
530                 }
531
532                 default:
533                         LOG_INFO("Incorrect parameters for ^2defer_clear^7\n");
534                 case CMD_REQUEST_USAGE:
535                 {
536                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear client\n");
537                         LOG_INFO("  'client' is the entity number or name of the player.\n");
538                         LOG_INFO("See also: ^2defer_clear_all^7\n");
539                         return;
540                 }
541         }
542 }
543
544 void GameCommand_defer_clear_all(float request)
545 {
546         switch (request)
547         {
548                 case CMD_REQUEST_COMMAND:
549                 {
550                         int n = 0;
551                         float argc;
552
553                         FOREACH_CLIENT(true, LAMBDA(
554                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
555                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
556                                 ++n;
557                         ));
558                         if (n)   LOG_INFO(strcat("Successfully stuffed defer clear to all clients (", ftos(n), ")\n"));  // should a message be added if no players were found?
559                         return;
560                 }
561
562                 default:
563                 case CMD_REQUEST_USAGE:
564                 {
565                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear_all\n");
566                         LOG_INFO("  No arguments required.\n");
567                         LOG_INFO("See also: ^2defer_clear^7\n");
568                         return;
569                 }
570         }
571 }
572
573 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
574 {
575         switch (request)
576         {
577                 case CMD_REQUEST_COMMAND:
578                 {
579                         if (argv(1))
580                         {
581                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
582                                 else race_deleteTime(GetMapname(), stof(argv(1)));
583                                 return;
584                         }
585                 }
586
587                 default:
588                         LOG_INFO("Incorrect parameters for ^2delrec^7\n");
589                 case CMD_REQUEST_USAGE:
590                 {
591                         LOG_INFO("\nUsage:^3 sv_cmd delrec ranking [map]\n");
592                         LOG_INFO("  'ranking' is which ranking level to clear up to, \n");
593                         LOG_INFO("  it will clear all records up to nth place.\n");
594                         LOG_INFO("  if 'map' is not provided it will use current map.\n");
595                         return;
596                 }
597         }
598 }
599
600 void GameCommand_effectindexdump(float request)
601 {
602         switch (request)
603         {
604                 case CMD_REQUEST_COMMAND:
605                 {
606                         float fh, d;
607                         string s;
608
609                         d = db_create();
610                         LOG_INFO("begin of effects list\n");
611                         db_put(d, "TE_GUNSHOT", "1");
612                         LOG_INFO("effect TE_GUNSHOT is ", ftos(_particleeffectnum("TE_GUNSHOT")), "\n");
613                         db_put(d, "TE_GUNSHOTQUAD", "1");
614                         LOG_INFO("effect TE_GUNSHOTQUAD is ", ftos(_particleeffectnum("TE_GUNSHOTQUAD")), "\n");
615                         db_put(d, "TE_SPIKE", "1");
616                         LOG_INFO("effect TE_SPIKE is ", ftos(_particleeffectnum("TE_SPIKE")), "\n");
617                         db_put(d, "TE_SPIKEQUAD", "1");
618                         LOG_INFO("effect TE_SPIKEQUAD is ", ftos(_particleeffectnum("TE_SPIKEQUAD")), "\n");
619                         db_put(d, "TE_SUPERSPIKE", "1");
620                         LOG_INFO("effect TE_SUPERSPIKE is ", ftos(_particleeffectnum("TE_SUPERSPIKE")), "\n");
621                         db_put(d, "TE_SUPERSPIKEQUAD", "1");
622                         LOG_INFO("effect TE_SUPERSPIKEQUAD is ", ftos(_particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
623                         db_put(d, "TE_WIZSPIKE", "1");
624                         LOG_INFO("effect TE_WIZSPIKE is ", ftos(_particleeffectnum("TE_WIZSPIKE")), "\n");
625                         db_put(d, "TE_KNIGHTSPIKE", "1");
626                         LOG_INFO("effect TE_KNIGHTSPIKE is ", ftos(_particleeffectnum("TE_KNIGHTSPIKE")), "\n");
627                         db_put(d, "TE_EXPLOSION", "1");
628                         LOG_INFO("effect TE_EXPLOSION is ", ftos(_particleeffectnum("TE_EXPLOSION")), "\n");
629                         db_put(d, "TE_EXPLOSIONQUAD", "1");
630                         LOG_INFO("effect TE_EXPLOSIONQUAD is ", ftos(_particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
631                         db_put(d, "TE_TAREXPLOSION", "1");
632                         LOG_INFO("effect TE_TAREXPLOSION is ", ftos(_particleeffectnum("TE_TAREXPLOSION")), "\n");
633                         db_put(d, "TE_TELEPORT", "1");
634                         LOG_INFO("effect TE_TELEPORT is ", ftos(_particleeffectnum("TE_TELEPORT")), "\n");
635                         db_put(d, "TE_LAVASPLASH", "1");
636                         LOG_INFO("effect TE_LAVASPLASH is ", ftos(_particleeffectnum("TE_LAVASPLASH")), "\n");
637                         db_put(d, "TE_SMALLFLASH", "1");
638                         LOG_INFO("effect TE_SMALLFLASH is ", ftos(_particleeffectnum("TE_SMALLFLASH")), "\n");
639                         db_put(d, "TE_FLAMEJET", "1");
640                         LOG_INFO("effect TE_FLAMEJET is ", ftos(_particleeffectnum("TE_FLAMEJET")), "\n");
641                         db_put(d, "EF_FLAME", "1");
642                         LOG_INFO("effect EF_FLAME is ", ftos(_particleeffectnum("EF_FLAME")), "\n");
643                         db_put(d, "TE_BLOOD", "1");
644                         LOG_INFO("effect TE_BLOOD is ", ftos(_particleeffectnum("TE_BLOOD")), "\n");
645                         db_put(d, "TE_SPARK", "1");
646                         LOG_INFO("effect TE_SPARK is ", ftos(_particleeffectnum("TE_SPARK")), "\n");
647                         db_put(d, "TE_PLASMABURN", "1");
648                         LOG_INFO("effect TE_PLASMABURN is ", ftos(_particleeffectnum("TE_PLASMABURN")), "\n");
649                         db_put(d, "TE_TEI_G3", "1");
650                         LOG_INFO("effect TE_TEI_G3 is ", ftos(_particleeffectnum("TE_TEI_G3")), "\n");
651                         db_put(d, "TE_TEI_SMOKE", "1");
652                         LOG_INFO("effect TE_TEI_SMOKE is ", ftos(_particleeffectnum("TE_TEI_SMOKE")), "\n");
653                         db_put(d, "TE_TEI_BIGEXPLOSION", "1");
654                         LOG_INFO("effect TE_TEI_BIGEXPLOSION is ", ftos(_particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
655                         db_put(d, "TE_TEI_PLASMAHIT", "1");
656                         LOG_INFO("effect TE_TEI_PLASMAHIT is ", ftos(_particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
657                         db_put(d, "EF_STARDUST", "1");
658                         LOG_INFO("effect EF_STARDUST is ", ftos(_particleeffectnum("EF_STARDUST")), "\n");
659                         db_put(d, "TR_ROCKET", "1");
660                         LOG_INFO("effect TR_ROCKET is ", ftos(_particleeffectnum("TR_ROCKET")), "\n");
661                         db_put(d, "TR_GRENADE", "1");
662                         LOG_INFO("effect TR_GRENADE is ", ftos(_particleeffectnum("TR_GRENADE")), "\n");
663                         db_put(d, "TR_BLOOD", "1");
664                         LOG_INFO("effect TR_BLOOD is ", ftos(_particleeffectnum("TR_BLOOD")), "\n");
665                         db_put(d, "TR_WIZSPIKE", "1");
666                         LOG_INFO("effect TR_WIZSPIKE is ", ftos(_particleeffectnum("TR_WIZSPIKE")), "\n");
667                         db_put(d, "TR_SLIGHTBLOOD", "1");
668                         LOG_INFO("effect TR_SLIGHTBLOOD is ", ftos(_particleeffectnum("TR_SLIGHTBLOOD")), "\n");
669                         db_put(d, "TR_KNIGHTSPIKE", "1");
670                         LOG_INFO("effect TR_KNIGHTSPIKE is ", ftos(_particleeffectnum("TR_KNIGHTSPIKE")), "\n");
671                         db_put(d, "TR_VORESPIKE", "1");
672                         LOG_INFO("effect TR_VORESPIKE is ", ftos(_particleeffectnum("TR_VORESPIKE")), "\n");
673                         db_put(d, "TR_NEHAHRASMOKE", "1");
674                         LOG_INFO("effect TR_NEHAHRASMOKE is ", ftos(_particleeffectnum("TR_NEHAHRASMOKE")), "\n");
675                         db_put(d, "TR_NEXUIZPLASMA", "1");
676                         LOG_INFO("effect TR_NEXUIZPLASMA is ", ftos(_particleeffectnum("TR_NEXUIZPLASMA")), "\n");
677                         db_put(d, "TR_GLOWTRAIL", "1");
678                         LOG_INFO("effect TR_GLOWTRAIL is ", ftos(_particleeffectnum("TR_GLOWTRAIL")), "\n");
679                         db_put(d, "TR_SEEKER", "1");
680                         LOG_INFO("effect TR_SEEKER is ", ftos(_particleeffectnum("TR_SEEKER")), "\n");
681                         db_put(d, "SVC_PARTICLE", "1");
682                         LOG_INFO("effect SVC_PARTICLE is ", ftos(_particleeffectnum("SVC_PARTICLE")), "\n");
683
684                         fh = fopen("effectinfo.txt", FILE_READ);
685                         while ((s = fgets(fh)))
686                         {
687                                 tokenize_console(s);
688                                 if (argv(0) == "effect")
689                                 {
690                                         if (db_get(d, argv(1)) != "1")
691                                         {
692                                                 int i = _particleeffectnum(argv(1));
693                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i), "\n");
694                                                 db_put(d, argv(1), "1");
695                                         }
696                                 }
697                         }
698                         LOG_INFO("end of effects list\n");
699
700                         db_close(d);
701                         return;
702                 }
703
704                 default:
705                 case CMD_REQUEST_USAGE:
706                 {
707                         LOG_INFO("\nUsage:^3 sv_cmd effectindexdump\n");
708                         LOG_INFO("  No arguments required.\n");
709                         return;
710                 }
711         }
712 }
713
714 void GameCommand_extendmatchtime(float request)
715 {
716         switch (request)
717         {
718                 case CMD_REQUEST_COMMAND:
719                 {
720                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
721                         return;
722                 }
723
724                 default:
725                 case CMD_REQUEST_USAGE:
726                 {
727                         LOG_INFO("\nUsage:^3 sv_cmd extendmatchtime\n");
728                         LOG_INFO("  No arguments required.\n");
729                         LOG_INFO("See also: ^2reducematchtime^7\n");
730                         return;
731                 }
732         }
733 }
734
735 void GameCommand_gametype(float request, float argc)
736 {
737         switch (request)
738         {
739                 case CMD_REQUEST_COMMAND:
740                 {
741                         if (argv(1) != "")
742                         {
743                                 string s = argv(1);
744                                 Gametype t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
745
746                                 if (t)
747                                 {
748                                         MapInfo_SwitchGameType(t);
749                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
750                                         if (MapInfo_count > 0)
751                                         {
752                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
753                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
754                                                 lsmaps_reply = strzone(getlsmaps());
755                                                 bprint("Game type successfully switched to ", s, "\n");
756                                         }
757                                         else
758                                         {
759                                                 bprint("Cannot use this game type: no map for it found\n");
760                                                 MapInfo_SwitchGameType(tsave);
761                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
762                                         }
763                                 }
764                                 else
765                                 {
766                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
767                                 }
768
769                                 return;
770                         }
771                 }
772
773                 default:
774                         LOG_INFO("Incorrect parameters for ^2gametype^7\n");
775                 case CMD_REQUEST_USAGE:
776                 {
777                         LOG_INFO("\nUsage:^3 sv_cmd gametype mode\n");
778                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.\n");
779                         LOG_INFO("See also: ^2gotomap^7\n");
780                         return;
781                 }
782         }
783 }
784
785 void GameCommand_gettaginfo(float request, float argc)
786 {
787         switch (request)
788         {
789                 case CMD_REQUEST_COMMAND:
790                 {
791                         entity tmp_entity;
792                         float i;
793                         vector v;
794
795                         if (argc >= 4)
796                         {
797                                 tmp_entity = spawn();
798                                 if (argv(1) == "w")
799                                 {
800                                         .entity weaponentity = weaponentities[0];
801                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
802                                 }
803                                 else
804                                 {
805                                         precache_model(argv(1));
806                                         _setmodel(tmp_entity, argv(1));
807                                 }
808                                 tmp_entity.frame = stof(argv(2));
809                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
810                                 else i = gettagindex(tmp_entity, argv(3));
811                                 if (i)
812                                 {
813                                         v = gettaginfo(tmp_entity, i);
814                                         LOG_INFO("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
815                                         LOG_INFO(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
816                                         LOG_INFO(" vector = ", ftos(v.x), " ", ftos(v.y), " ", ftos(v.z), "\n");
817                                         LOG_INFO(" offset = ", ftos(gettaginfo_offset.x), " ", ftos(gettaginfo_offset.y), " ", ftos(gettaginfo_offset.z), "\n");
818                                         LOG_INFO(" forward = ", ftos(gettaginfo_forward.x), " ", ftos(gettaginfo_forward.y), " ", ftos(gettaginfo_forward.z), "\n");
819                                         LOG_INFO(" right = ", ftos(gettaginfo_right.x), " ", ftos(gettaginfo_right.y), " ", ftos(gettaginfo_right.z), "\n");
820                                         LOG_INFO(" up = ", ftos(gettaginfo_up.x), " ", ftos(gettaginfo_up.y), " ", ftos(gettaginfo_up.z), "\n");
821                                         if (argc >= 6)
822                                         {
823                                                 v.y = -v.y;
824                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
825                                         }
826                                 }
827                                 else
828                                 {
829                                         LOG_INFO("bone not found\n");
830                                 }
831
832                                 delete(tmp_entity);
833                                 return;
834                         }
835                 }
836
837                 default:
838                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
839                 case CMD_REQUEST_USAGE:
840                 {
841                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
842                         LOG_INFO("See also: ^2bbox, trace^7\n");
843                         return;
844                 }
845         }
846 }
847
848 void GameCommand_animbench(float request, float argc)
849 {
850         switch (request)
851         {
852                 case CMD_REQUEST_COMMAND:
853                 {
854                         entity tmp_entity;
855
856                         if (argc >= 4)
857                         {
858                                 tmp_entity = spawn();
859                                 if (argv(1) == "w")
860                                 {
861                                         .entity weaponentity = weaponentities[0];
862                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
863                                 }
864                                 else
865                                 {
866                                         precache_model(argv(1));
867                                         _setmodel(tmp_entity, argv(1));
868                                 }
869                                 float f1 = stof(argv(2));
870                                 float f2 = stof(argv(3));
871                                 float t0;
872                                 float t1 = 0;
873                                 float t2 = 0;
874                                 float n = 0;
875
876                                 while (t1 + t2 < 1)
877                                 {
878                                         tmp_entity.frame = f1;
879                                         t0 = gettime(GETTIME_HIRES);
880                                         getsurfacepoint(tmp_entity, 0, 0);
881                                         t1 += gettime(GETTIME_HIRES) - t0;
882                                         tmp_entity.frame = f2;
883                                         t0 = gettime(GETTIME_HIRES);
884                                         getsurfacepoint(tmp_entity, 0, 0);
885                                         t2 += gettime(GETTIME_HIRES) - t0;
886                                         n += 1;
887                                 }
888                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
889                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
890
891                                 delete(tmp_entity);
892                                 return;
893                         }
894                 }
895
896                 default:
897                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
898                 case CMD_REQUEST_USAGE:
899                 {
900                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
901                         LOG_INFO("See also: ^2bbox, trace^7\n");
902                         return;
903                 }
904         }
905 }
906
907 void GameCommand_gotomap(float request, float argc)
908 {
909         switch (request)
910         {
911                 case CMD_REQUEST_COMMAND:
912                 {
913                         if (argv(1))
914                         {
915                                 LOG_INFO(GotoMap(argv(1)), "\n");
916                                 return;
917                         }
918                 }
919
920                 default:
921                         LOG_INFO("Incorrect parameters for ^2gotomap^7\n");
922                 case CMD_REQUEST_USAGE:
923                 {
924                         LOG_INFO("\nUsage:^3 sv_cmd gotomap map\n");
925                         LOG_INFO("  Where 'map' is the *.bsp file to change to.\n");
926                         LOG_INFO("See also: ^2gametype^7\n");
927                         return;
928                 }
929         }
930 }
931
932 void GameCommand_lockteams(float request)
933 {
934         switch (request)
935         {
936                 case CMD_REQUEST_COMMAND:
937                 {
938                         if (teamplay)
939                         {
940                                 lockteams = 1;
941                                 bprint("^1The teams are now locked.\n");
942                         }
943                         else
944                         {
945                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
946                         }
947                         return;
948                 }
949
950                 default:
951                 case CMD_REQUEST_USAGE:
952                 {
953                         LOG_INFO("\nUsage:^3 sv_cmd lockteams\n");
954                         LOG_INFO("  No arguments required.\n");
955                         LOG_INFO("See also: ^2unlockteams^7\n");
956                         return;
957                 }
958         }
959 }
960
961 void GameCommand_make_mapinfo(float request)
962 {
963         switch (request)
964         {
965                 case CMD_REQUEST_COMMAND:
966                 {
967                         entity tmp_entity;
968
969                         tmp_entity = new(make_mapinfo);
970                         setthink(tmp_entity, make_mapinfo_Think);
971                         tmp_entity.nextthink = time;
972                         MapInfo_Enumerate();
973                         return;
974                 }
975
976                 default:
977                 case CMD_REQUEST_USAGE:
978                 {
979                         LOG_INFO("\nUsage:^3 sv_cmd make_mapinfo\n");
980                         LOG_INFO("  No arguments required.\n");
981                         LOG_INFO("See also: ^2radarmap^7\n");
982                         return;
983                 }
984         }
985 }
986
987 void GameCommand_moveplayer(float request, float argc)
988 {
989         switch (request)
990         {
991                 case CMD_REQUEST_COMMAND:
992                 {
993                         float accepted;
994                         entity client;
995
996                         string targets = strreplace(",", " ", argv(1));
997                         string original_targets = strreplace(" ", ", ", targets);
998                         string destination = argv(2);
999
1000                         string successful, t;
1001                         successful = string_null;
1002
1003                         // lets see if the target(s) even actually exist.
1004                         if ((targets) && (destination))
1005                         {
1006                                 for ( ; targets; )
1007                                 {
1008                                         t = car(targets);
1009                                         targets = cdr(targets);
1010
1011                                         // Check to see if the player is a valid target
1012                                         client = GetFilteredEntity(t);
1013                                         accepted = VerifyClientEntity(client, false, false);
1014
1015                                         if (accepted <= 0)
1016                                         {
1017                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1018                                                 continue;
1019                                         }
1020
1021                                         // Where are we putting this player?
1022                                         if (destination == "spec" || destination == "spectator")
1023                                         {
1024                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1025                                                 {
1026                                                         if (client.caplayer) client.caplayer = 0;
1027                                                         PutObserverInServer(client);
1028
1029                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1030                                                 }
1031                                                 else
1032                                                 {
1033                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1034                                                 }
1035                                                 continue;
1036                                         }
1037                                         else
1038                                         {
1039                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1040                                                 {
1041                                                         if (teamplay)
1042                                                         {
1043                                                                 // set up
1044                                                                 float team_id;
1045                                                                 float save = client.team_forced;
1046                                                                 client.team_forced = 0;
1047
1048                                                                 // find the team to move the player to
1049                                                                 team_id = Team_ColorToTeam(destination);
1050                                                                 if (team_id == client.team)  // already on the destination team
1051                                                                 {
1052                                                                         // keep the forcing undone
1053                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1054                                                                         continue;
1055                                                                 }
1056                                                                 else if (team_id == 0)  // auto team
1057                                                                 {
1058                                                                         CheckAllowedTeams(client);
1059                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1060                                                                 }
1061                                                                 else
1062                                                                 {
1063                                                                         CheckAllowedTeams(client);
1064                                                                 }
1065                                                                 client.team_forced = save;
1066
1067                                                                 // Check to see if the destination team is even available
1068                                                                 switch (team_id)
1069                                                                 {
1070                                                                         case NUM_TEAM_1: if (c1 == -1) { LOG_INFO("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1071                                                                         case NUM_TEAM_2: if (c2 == -1) { LOG_INFO("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1072                                                                         case NUM_TEAM_3: if (c3 == -1) { LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1073                                                                         case NUM_TEAM_4: if (c4 == -1) { LOG_INFO("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1074
1075                                                                         default: LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.\n");
1076                                                                                 return;
1077                                                                 }
1078
1079                                                                 // If so, lets continue and finally move the player
1080                                                                 client.team_forced = 0;
1081                                                                 MoveToTeam(client, team_id, 6);
1082                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1083                                                                 LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1084                                                                 continue;
1085                                                         }
1086                                                         else
1087                                                         {
1088                                                                 LOG_INFO("Can't change teams when currently not playing a team game.\n");
1089                                                                 return;
1090                                                         }
1091                                                 }
1092                                                 else
1093                                                 {
1094                                                         LOG_INFO("Can't change teams if the player isn't in the game.\n");  // well technically we could, but should we allow that? :P
1095                                                         return;
1096                                                 }
1097                                         }
1098                                 }
1099
1100                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1101                                 else LOG_INFO("No players given (", original_targets, ") are able to move.\n");
1102
1103                                 return;  // still correct parameters so return to avoid usage print
1104                         }
1105                 }
1106
1107                 default:
1108                         LOG_INFO("Incorrect parameters for ^2moveplayer^7\n");
1109                 case CMD_REQUEST_USAGE:
1110                 {
1111                         LOG_INFO("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1112                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1113                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating\n");
1114                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1115                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1116                         LOG_INFO("          sv_cmd moveplayer 2 spec \n");
1117                         LOG_INFO("See also: ^2allspec, shuffleteams^7\n");
1118                         return;
1119                 }
1120         }
1121 }
1122
1123 void GameCommand_nospectators(float request)
1124 {
1125         switch (request)
1126         {
1127                 case CMD_REQUEST_COMMAND:
1128                 {
1129                         blockSpectators = 1;
1130                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1131                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, LAMBDA(
1132                                 if(!it.caplayer)
1133                                 {
1134                                         it.spectatortime = time;
1135                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1136                                 }
1137                         ));
1138                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1139                         return;
1140                 }
1141
1142                 default:
1143                 case CMD_REQUEST_USAGE:
1144                 {
1145                         LOG_INFO("\nUsage:^3 sv_cmd nospectators\n");
1146                         LOG_INFO("  No arguments required.\n");
1147                         return;
1148                 }
1149         }
1150 }
1151
1152 void GameCommand_playerdemo(float request, float argc)
1153 {
1154         switch (request)
1155         {
1156                 case CMD_REQUEST_COMMAND:
1157                 {
1158                         if (argv(2) && argv(3))
1159                         {
1160                                 entity client;
1161                                 float i, n, accepted;
1162
1163                                 switch (argv(1))
1164                                 {
1165                                         case "read":
1166                                         {
1167                                                 client = GetIndexedEntity(argc, 2);
1168                                                 accepted = VerifyClientEntity(client, false, true);
1169
1170                                                 if (accepted <= 0)
1171                                                 {
1172                                                         LOG_INFO("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1173                                                         return;
1174                                                 }
1175
1176                                                 playerdemo_open_read(client, argv(next_token));
1177                                                 return;
1178                                         }
1179
1180                                         case "write":
1181                                         {
1182                                                 client = GetIndexedEntity(argc, 2);
1183                                                 accepted = VerifyClientEntity(client, false, false);
1184
1185                                                 if (accepted <= 0)
1186                                                 {
1187                                                         LOG_INFO("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1188                                                         return;
1189                                                 }
1190
1191                                                 playerdemo_open_write(client, argv(next_token));
1192                                                 return;
1193                                         }
1194
1195                                         case "auto_read_and_write":
1196                                         {
1197                                                 n = GetFilteredNumber(argv(3));
1198                                                 cvar_set("bot_number", ftos(n));
1199
1200                                                 localcmd("wait; wait; wait\n");
1201                                                 for (i = 0; i < n; ++i)
1202                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1203                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n + 1), "\n");
1204                                                 return;
1205                                         }
1206
1207                                         case "auto_read":
1208                                         {
1209                                                 n = GetFilteredNumber(argv(3));
1210                                                 cvar_set("bot_number", ftos(n));
1211
1212                                                 localcmd("wait; wait; wait\n");
1213                                                 for (i = 0; i < n; ++i)
1214                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1215                                                 return;
1216                                         }
1217                                 }
1218                         }
1219                 }
1220
1221                 default:
1222                         LOG_INFO("Incorrect parameters for ^2playerdemo^7\n");
1223                 case CMD_REQUEST_USAGE:
1224                 {
1225                         LOG_INFO("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1226                         LOG_INFO("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1227                         return;
1228                 }
1229         }
1230 }
1231
1232 void GameCommand_printstats(float request)
1233 {
1234         switch (request)
1235         {
1236                 case CMD_REQUEST_COMMAND:
1237                 {
1238                         DumpStats(false);
1239                         LOG_INFO("stats dumped.\n");
1240                         return;
1241                 }
1242
1243                 default:
1244                 case CMD_REQUEST_USAGE:
1245                 {
1246                         LOG_INFO("\nUsage:^3 sv_cmd printstats\n");
1247                         LOG_INFO("  No arguments required.\n");
1248                         return;
1249                 }
1250         }
1251 }
1252
1253 void GameCommand_radarmap(float request, float argc)
1254 {
1255         switch (request)
1256         {
1257                 case CMD_REQUEST_COMMAND:
1258                 {
1259                         if (RadarMap_Make(argc)) return;
1260                 }
1261
1262                 default:
1263                         LOG_INFO("Incorrect parameters for ^2radarmap^7\n");
1264                 case CMD_REQUEST_USAGE:
1265                 {
1266                         LOG_INFO("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1267                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.\n");
1268                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1269                         LOG_INFO("See also: ^2make_mapinfo^7\n");
1270                         return;
1271                 }
1272         }
1273 }
1274
1275 void GameCommand_reducematchtime(float request)
1276 {
1277         switch (request)
1278         {
1279                 case CMD_REQUEST_COMMAND:
1280                 {
1281                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1282                         return;
1283                 }
1284
1285                 default:
1286                 case CMD_REQUEST_USAGE:
1287                 {
1288                         LOG_INFO("\nUsage:^3 sv_cmd reducematchtime\n");
1289                         LOG_INFO("  No arguments required.\n");
1290                         LOG_INFO("See also: ^2extendmatchtime^7\n");
1291                         return;
1292                 }
1293         }
1294 }
1295
1296 void GameCommand_setbots(float request, float argc)
1297 {
1298         switch (request)
1299         {
1300                 case CMD_REQUEST_COMMAND:
1301                 {
1302                         if (argc >= 2)
1303                         {
1304                                 cvar_settemp("minplayers", "0");
1305                                 cvar_settemp("bot_number", argv(1));
1306                                 bot_fixcount();
1307                                 return;
1308                         }
1309                 }
1310
1311                 default:
1312                         LOG_INFO("Incorrect parameters for ^2setbots^7\n");
1313                 case CMD_REQUEST_USAGE:
1314                 {
1315                         LOG_INFO("\nUsage:^3 sv_cmd setbots botnumber\n");
1316                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1317                         LOG_INFO("See also: ^2bot_cmd^7\n");
1318                         return;
1319                 }
1320         }
1321 }
1322
1323 void GameCommand_shuffleteams(float request)
1324 {
1325         switch (request)
1326         {
1327                 case CMD_REQUEST_COMMAND:
1328                 {
1329                         if (teamplay)
1330                         {
1331                                 float t_teams, t_players, team_color;
1332
1333                                 // count the total amount of players and total amount of teams
1334                                 t_players = 0;
1335                                 t_teams = 0;
1336                                 FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, LAMBDA(
1337                                         CheckAllowedTeams(it);
1338
1339                                         if (c1 >= 0) t_teams = max(1, t_teams);
1340                                         if (c2 >= 0) t_teams = max(2, t_teams);
1341                                         if (c3 >= 0) t_teams = max(3, t_teams);
1342                                         if (c4 >= 0) t_teams = max(4, t_teams);
1343
1344                                         ++t_players;
1345                                 ));
1346
1347                                 // build a list of the players in a random order
1348                                 FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, LAMBDA(
1349                                         for ( ; ; )
1350                                         {
1351                                                 int idx = bound(1, floor(random() * maxclients) + 1, maxclients);
1352
1353                                                 if (shuffleteams_players[idx])
1354                                                 {
1355                                                         continue;  // a player is already assigned to this slot
1356                                                 }
1357                                                 else
1358                                                 {
1359                                                         shuffleteams_players[idx] = etof(it);
1360                                                         break;
1361                                                 }
1362                                         }
1363                                 ));
1364
1365                                 // finally, from the list made earlier, re-join the players in different order.
1366                                 for (int i = 1; i <= t_teams; ++i)
1367                                 {
1368                                         // find out how many players to assign to this team
1369                                         int pnum = (t_players / t_teams);
1370                                         pnum = ((i == 1) ? ceil(pnum) : floor(pnum));
1371
1372                                         team_color = Team_NumberToTeam(i);
1373
1374                                         // sort through the random list of players made earlier
1375                                         for (int z = 1; z <= maxclients; ++z)
1376                                         {
1377                                                 if (!(shuffleteams_teams[i] >= pnum))
1378                                                 {
1379                                                         if (!(shuffleteams_players[z])) continue;  // not a player, move on to next random slot
1380
1381                                                         entity e = NULL;
1382                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1383                                                                 e = edict_num(shuffleteams_players[z]);
1384
1385                                                         if(!e) continue; // unverified
1386
1387                                                         if (e.team != team_color) MoveToTeam(e, team_color, 6);
1388
1389                                                         shuffleteams_players[z] = 0;
1390                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1391                                                 }
1392                                                 else
1393                                                 {
1394                                                         break;  // move on to next team
1395                                                 }
1396                                         }
1397                                 }
1398
1399                                 bprint("Successfully shuffled the players around randomly.\n");
1400
1401                                 // clear the buffers now
1402                                 for (int i = 0; i < SHUFFLETEAMS_MAX_PLAYERS; ++i)
1403                                         shuffleteams_players[i] = 0;
1404
1405                                 for (int i = 0; i < SHUFFLETEAMS_MAX_TEAMS; ++i)
1406                                         shuffleteams_teams[i] = 0;
1407                         }
1408                         else
1409                         {
1410                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.\n");
1411                         }
1412
1413                         return;
1414                 }
1415
1416                 default:
1417                 case CMD_REQUEST_USAGE:
1418                 {
1419                         LOG_INFO("\nUsage:^3 sv_cmd shuffleteams\n");
1420                         LOG_INFO("  No arguments required.\n");
1421                         LOG_INFO("See also: ^2moveplayer, allspec^7\n");
1422                         return;
1423                 }
1424         }
1425 }
1426
1427 void GameCommand_stuffto(float request, float argc)
1428 {
1429         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1430         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1431         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1432
1433 #ifdef STUFFTO_ENABLED
1434                 switch (request)
1435                 {
1436                         case CMD_REQUEST_COMMAND:
1437                         {
1438                                 if (argv(2))
1439                                 {
1440                                         entity client = GetIndexedEntity(argc, 1);
1441                                         float accepted = VerifyClientEntity(client, true, false);
1442
1443                                         if (accepted > 0)
1444                                         {
1445                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1446                                                 LOG_INFO(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").\n"));
1447                                         }
1448                                         else
1449                                         {
1450                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1451                                         }
1452
1453                                         return;
1454                                 }
1455                         }
1456
1457                         default:
1458                                 LOG_INFO("Incorrect parameters for ^2stuffto^7\n");
1459                         case CMD_REQUEST_USAGE:
1460                         {
1461                                 LOG_INFO("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1462                                 LOG_INFO("  'client' is the entity number or name of the player,\n");
1463                                 LOG_INFO("  and 'command' is the command to be sent to that player.\n");
1464                                 return;
1465                         }
1466                 }
1467 #else
1468                 if (request)
1469                 {
1470                         LOG_INFO("stuffto command is not enabled on this server.\n");
1471                         return;
1472                 }
1473 #endif
1474 }
1475
1476 void GameCommand_trace(float request, float argc)
1477 {
1478         switch (request)
1479         {
1480                 case CMD_REQUEST_COMMAND:
1481                 {
1482                         entity e;
1483                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1484                         float i, f, safe, unsafe, dq, dqf;
1485
1486                         switch (argv(1))
1487                         {
1488                                 case "debug":
1489                                 {
1490                                         float hitcount = 0;
1491                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1492                                         float worst_endpos_bug = 0;
1493                                         for ( ; ; )
1494                                         {
1495                                                 org = world.mins;
1496                                                 delta = world.maxs - world.mins;
1497
1498                                                 start.x = org.x + random() * delta.x;
1499                                                 start.y = org.y + random() * delta.y;
1500                                                 start.z = org.z + random() * delta.z;
1501
1502                                                 end.x = org.x + random() * delta.x;
1503                                                 end.y = org.y + random() * delta.y;
1504                                                 end.z = org.z + random() * delta.z;
1505
1506                                                 start = stov(vtos(start));
1507                                                 end = stov(vtos(end));
1508
1509                                                 tracebox(start, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), end, MOVE_NOMONSTERS, NULL);
1510                                                 if (!trace_startsolid && trace_fraction < 1)
1511                                                 {
1512                                                         p = trace_endpos;
1513                                                         tracebox(p, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), p, MOVE_NOMONSTERS, NULL);
1514                                                         if (trace_startsolid)
1515                                                         {
1516                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1517                                                                 tracebox(start, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), end, MOVE_NOMONSTERS, NULL);
1518
1519                                                                 // how much do we need to back off?
1520                                                                 safe = 1;
1521                                                                 unsafe = 0;
1522                                                                 for ( ; ; )
1523                                                                 {
1524                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1525                                                                         tracebox(pos, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), pos, MOVE_NOMONSTERS, NULL);
1526                                                                         if (trace_startsolid)
1527                                                                         {
1528                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1529                                                                                 unsafe = (safe + unsafe) * 0.5;
1530                                                                         }
1531                                                                         else
1532                                                                         {
1533                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1534                                                                                 safe = (safe + unsafe) * 0.5;
1535                                                                         }
1536                                                                 }
1537
1538                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1539                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1540
1541                                                                 tracebox(p, STAT(PL_MIN, NULL) + '0.1 0.1 0.1', STAT(PL_MAX, NULL) - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1542                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1543                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1544                                                                 if (++hitcount >= 10) break;
1545                                                         }
1546                                                         else
1547                                                         {
1548                                                                 q0 = p;
1549                                                                 dq = 0;
1550                                                                 dqf = 1;
1551                                                                 for ( ; ; )
1552                                                                 {
1553                                                                         q = p + normalize(end - p) * (dq + dqf);
1554                                                                         if (q == q0) break;
1555                                                                         tracebox(p, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), q, MOVE_NOMONSTERS, NULL);
1556                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1557                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1558                                                                         dqf *= 0.5;
1559                                                                         q0 = q;
1560                                                                 }
1561                                                                 if (dq > worst_endpos_bug)
1562                                                                 {
1563                                                                         worst_endpos_bug = dq;
1564                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1565                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1566                                                                         if (++hitcount >= 10) break;
1567                                                                 }
1568                                                         }
1569                                                 }
1570                                         }
1571                                         return;
1572                                 }
1573
1574                                 case "debug2":
1575                                 {
1576                                         e = nextent(NULL);
1577                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1578                                         vv = trace_endpos;
1579                                         if (trace_fraction == 1)
1580                                         {
1581                                                 LOG_INFO("not above ground, aborting\n");
1582                                                 return;
1583                                         }
1584                                         f = 0;
1585                                         for (i = 0; i < 100000; ++i)
1586                                         {
1587                                                 dv = randomvec();
1588                                                 if (dv.z > 0) dv = -1 * dv;
1589                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1590                                                 if (trace_startsolid) LOG_INFO("bug 1\n");
1591                                                 if (trace_fraction == 1)
1592                                                 {
1593                                                         if (dv.z < f)
1594                                                         {
1595                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1596                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1597                                                                 f = dv.z;
1598                                                         }
1599                                                 }
1600                                         }
1601                                         LOG_INFO("highest possible dist: ", ftos(f), "\n");
1602                                         return;
1603                                 }
1604
1605                                 case "walk":
1606                                 {
1607                                         if (argc == 4)
1608                                         {
1609                                                 e = nextent(NULL);
1610                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL)) LOG_INFO("can walk\n");
1611                                                 else LOG_INFO("cannot walk\n");
1612                                                 return;
1613                                         }
1614                                 }
1615
1616                                 case "showline":
1617                                 {
1618                                         if (argc == 4)
1619                                         {
1620                                                 vv = stov(argv(2));
1621                                                 dv = stov(argv(3));
1622                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1623                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1624                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1625                                                 return;
1626                                         }
1627                                 }
1628
1629                                         // no default case, just go straight to invalid
1630                         }
1631                 }
1632
1633                 default:
1634                         LOG_INFO("Incorrect parameters for ^2trace^7\n");
1635                 case CMD_REQUEST_USAGE:
1636                 {
1637                         LOG_INFO("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1638                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1639                         LOG_INFO("See also: ^2bbox, gettaginfo^7\n");
1640                         return;
1641                 }
1642         }
1643 }
1644
1645 void GameCommand_unlockteams(float request)
1646 {
1647         switch (request)
1648         {
1649                 case CMD_REQUEST_COMMAND:
1650                 {
1651                         if (teamplay)
1652                         {
1653                                 lockteams = 0;
1654                                 bprint("^1The teams are now unlocked.\n");
1655                         }
1656                         else
1657                         {
1658                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1659                         }
1660                         return;
1661                 }
1662
1663                 default:
1664                 case CMD_REQUEST_USAGE:
1665                 {
1666                         LOG_INFO("\nUsage:^3 sv_cmd unlockteams\n");
1667                         LOG_INFO("  No arguments required.\n");
1668                         LOG_INFO("See also: ^2lockteams^7\n");
1669                         return;
1670                 }
1671         }
1672 }
1673
1674 void GameCommand_warp(float request, float argc)
1675 {
1676         switch (request)
1677         {
1678                 case CMD_REQUEST_COMMAND:
1679                 {
1680                         if (autocvar_g_campaign)
1681                         {
1682                                 if (argc >= 2)
1683                                 {
1684                                         CampaignLevelWarp(stof(argv(1)));
1685                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".\n");
1686                                 }
1687                                 else
1688                                 {
1689                                         CampaignLevelWarp(-1);
1690                                         LOG_INFO("Successfully warped to next campaign level.\n");
1691                                 }
1692                         }
1693                         else
1694                         {
1695                                 LOG_INFO("Not in campaign, can't level warp\n");
1696                         }
1697                         return;
1698                 }
1699
1700                 default:
1701                 case CMD_REQUEST_USAGE:
1702                 {
1703                         LOG_INFO("\nUsage:^3 sv_cmd warp [level]\n");
1704                         LOG_INFO("  'level' is the level to change campaign mode to.\n");
1705                         LOG_INFO("  if 'level' is not provided it will change to the next level.\n");
1706                         return;
1707                 }
1708         }
1709 }
1710
1711 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1712 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1713 void GameCommand_(float request)
1714 {
1715     switch(request)
1716     {
1717         case CMD_REQUEST_COMMAND:
1718         {
1719
1720             return;
1721         }
1722
1723         default:
1724         case CMD_REQUEST_USAGE:
1725         {
1726             print("\nUsage:^3 sv_cmd \n");
1727             print("  No arguments required.\n");
1728             return;
1729         }
1730     }
1731 }
1732 */
1733
1734
1735 // ==================================
1736 //  Macro system for server commands
1737 // ==================================
1738
1739 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1740 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1741 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1742 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1743 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1744 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1745 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1746 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1747 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1748 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1749 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1750 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1751 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1752 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1753 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1754 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1755 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1756 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1757 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1758 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1759 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1760 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1761 SERVER_COMMAND(playerdemo, "Control the ability to save demos of players") { GameCommand_playerdemo(request, arguments); }
1762 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1763 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1764 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1765 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1766 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1767 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1768 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1769 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1770 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1771
1772 void GameCommand_macro_help()
1773 {
1774         FOREACH(SERVER_COMMANDS, true, LAMBDA(LOG_INFOF("  ^2%s^7: %s\n", it.m_name, it.m_description)));
1775 }
1776
1777 float GameCommand_macro_command(float argc, string command)
1778 {
1779         string c = strtolower(argv(0));
1780         FOREACH(SERVER_COMMANDS, it.m_name == c, LAMBDA(
1781                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1782                 return true;
1783         ));
1784         return false;
1785 }
1786
1787 float GameCommand_macro_usage(float argc)
1788 {
1789         string c = strtolower(argv(1));
1790         FOREACH(SERVER_COMMANDS, it.m_name == c, LAMBDA(
1791                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1792                 return true;
1793         ));
1794         return false;
1795 }
1796
1797 void GameCommand_macro_write_aliases(float fh)
1798 {
1799         FOREACH(SERVER_COMMANDS, true, LAMBDA(CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description)));
1800 }
1801
1802
1803 // =========================================
1804 //  Main Function Called By Engine (sv_cmd)
1805 // =========================================
1806 // If this function exists, game code handles gamecommand instead of the engine code.
1807
1808 void GameCommand(string command)
1809 {
1810         float argc = tokenize_console(command);
1811
1812         // Guide for working with argc arguments by example:
1813         // argc:   1    - 2      - 3     - 4
1814         // argv:   0    - 1      - 2     - 3
1815         // cmd     vote - master - login - password
1816
1817         if (strtolower(argv(0)) == "help")
1818         {
1819                 if (argc == 1)
1820                 {
1821                         LOG_INFO("\nServer console commands:\n");
1822                         GameCommand_macro_help();
1823
1824                         LOG_INFO("\nBanning commands:\n");
1825                         BanCommand_macro_help();
1826
1827                         LOG_INFO("\nCommon networked commands:\n");
1828                         CommonCommand_macro_help(NULL);
1829
1830                         LOG_INFO("\nGeneric commands shared by all programs:\n");
1831                         GenericCommand_macro_help();
1832
1833                         LOG_INFO("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1834                         LOG_INFO("For help about a specific command, type sv_cmd help COMMAND\n");
1835
1836                         return;
1837                 }
1838                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1839                 {
1840                         return;
1841                 }
1842                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1843                 {
1844                         return;
1845                 }
1846                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1847                 {
1848                         return;
1849                 }
1850                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1851                 {
1852                         return;
1853                 }
1854         }
1855         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1856         {
1857                 return;  // handled by a mutator
1858         }
1859         else if (BanCommand(command))
1860         {
1861                 return;  // handled by server/command/ipban.qc
1862         }
1863         else if (CommonCommand_macro_command(argc, NULL, command))
1864         {
1865                 return;  // handled by server/command/common.qc
1866         }
1867         else if (GenericCommand(command))
1868         {
1869                 return;                                        // handled by common/command/generic.qc
1870         }
1871         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1872         {
1873                 return;                                        // handled by one of the above GameCommand_* functions
1874         }
1875
1876         // nothing above caught the command, must be invalid
1877         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1878 }