qcsrc/server/command/sv_cmd.qc

   1 #include "../../common/command/command.qh"
   2 #include "sv_cmd.qh"
   3 #include "../_all.qh"
   4
   5 #include "banning.qh"
   6 #include "cmd.qh"
   7 #include "common.qh"
   8 #include "getreplies.qh"
   9 #include "radarmap.qh"
  10
  11 #include "../anticheat.qh"
  12 #include "../campaign.qh"
  13 #include "../cl_client.qh"
  14 #include "../cl_player.qh"
  15 #include "../g_world.qh"
  16 #include "../ipban.qh"
  17 #include "../playerdemo.qh"
  18 #include "../teamplay.qh"
  19
  20 #include "../bot/bot.qh"
  21 #include "../bot/navigation.qh"
  22 #include "../bot/scripting.qh"
  23
  24 #include "../mutators/mutators_include.qh"
  25
  26 #include "../../common/constants.qh"
  27 #include "../../common/mapinfo.qh"
  28 #include "../../common/notifications.qh"
  29 #include "../../common/teams.qh"
  30 #include "../../common/util.qh"
  31
  32 #include "../../common/monsters/sv_monsters.qh"
  33
  34
  35 void PutObserverInServer (void);
  36
  37 // =====================================================
  38 //  Server side game commands code, reworked by Samual
  39 //  Last updated: December 29th, 2011
  40 // =====================================================
  41
  42 //  used by GameCommand_make_mapinfo()
  43 void make_mapinfo_Think()
  44 {
  45         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  46         {
  47                 print("Done rebuiling mapinfos.\n");
  48                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  49                 remove(self);
  50         }
  51         else
  52         {
  53                 self.think = make_mapinfo_Think;
  54                 self.nextthink = time;
  55         }
  56 }
  57
  58 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  59 void changematchtime(float delta, float mi, float ma)
  60 {
  61         float cur;
  62         float update;
  63         float lim;
  64
  65         if(delta == 0)
  66                 return;
  67         if(autocvar_timelimit < 0)
  68                 return;
  69
  70         if(mi <= 10)
  71                 mi = 10; // at least ten sec in the future
  72         cur = time - game_starttime;
  73         if(cur > 0)
  74                 mi += cur; // from current time!
  75
  76         lim = autocvar_timelimit * 60;
  77
  78         if(delta > 0)
  79         {
  80                 if(lim == 0)
  81                         return; // cannot increase any further
  82                 else if(lim < ma)
  83                         update = min(ma, lim + delta);
  84                 else // already above maximum: FAIL
  85                         return;
  86         }
  87         else
  88         {
  89                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  90                         update = max(mi, ma);
  91                 else if(lim > mi) // above minimum: decrease
  92                         update = max(mi, lim + delta);
  93                 else // already below minimum: FAIL
  94                         return;
  95         }
  96
  97         cvar_set("timelimit", ftos(update / 60));
  98 }
  99
 100
 101 // =======================
 102 //  Command Sub-Functions
 103 // =======================
 104
 105 void GameCommand_adminmsg(float request, float argc)
 106 {
 107         switch(request)
 108         {
 109                 case CMD_REQUEST_COMMAND:
 110                 {
 111                         entity client;
 112                         float accepted;
 113
 114                         string targets = strreplace(",", " ", argv(1));
 115                         string original_targets = strreplace(" ", ", ", targets);
 116                         string admin_message = argv(2);
 117                         float infobartime = stof(argv(3));
 118
 119                         string successful, t;
 120                         successful = string_null;
 121
 122                         if((targets) && (admin_message))
 123                         {
 124                                 for (;targets;)
 125                                 {
 126                                         t = car(targets); targets = cdr(targets);
 127
 128                                         // Check to see if the player is a valid target
 129                                         client = GetFilteredEntity(t);
 130                                         accepted = VerifyClientEntity(client, true, false);
 131
 132                                         if(accepted <= 0)
 133                                         {
 134                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 135                                                 continue;
 136                                         }
 137
 138                                         // send the centerprint/console print or infomessage
 139                                         if(infobartime)
 140                                         {
 141                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 142                                         }
 143                                         else
 144                                         {
 145                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 146                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 147                                         }
 148
 149                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 150                                         dprint("Message sent to ", client.netname, "\n");
 151                                         continue;
 152                                 }
 153
 154                                 if(successful)
 155                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 156                                 else
 157                                         print("No players given (", original_targets, ") could receive the message.\n");
 158
 159                                 return;
 160                         }
 161                 }
 162
 163                 default:
 164                         print("Incorrect parameters for ^2adminmsg^7\n");
 165                 case CMD_REQUEST_USAGE:
 166                 {
 167                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 168                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 169                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 170                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 171                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 172                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 173                         return;
 174                 }
 175         }
 176 }
 177
 178 void GameCommand_mobbutcher(float request)
 179 {
 180         switch(request)
 181         {
 182                 case CMD_REQUEST_COMMAND:
 183                 {
 184                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
 185                         if(g_invasion) { print("This command doesn't work during an invasion.\n"); return; }
 186
 187                         float removed_count = 0;
 188                         entity head;
 189
 190                         FOR_EACH_MONSTER(head)
 191                         {
 192                                 monster_remove(head);
 193                                 ++removed_count;
 194                         }
 195
 196                         monsters_total = 0; // reset stats?
 197                         monsters_killed = 0;
 198
 199                         totalspawned = 0;
 200
 201                         if(removed_count <= 0)
 202                                 print("No monsters to kill\n");
 203                         else
 204                                 printf("Killed %d monster%s\n", removed_count, ((removed_count == 1) ? "" : "s"));
 205
 206                         return; // never fall through to usage
 207                 }
 208
 209                 default:
 210                 case CMD_REQUEST_USAGE:
 211                 {
 212                         print("\nUsage:^3 sv_cmd mobbutcher\n");
 213                         print("  No arguments required.\n");
 214                         return;
 215                 }
 216         }
 217 }
 218
 219 void GameCommand_allready(float request)
 220 {
 221         switch(request)
 222         {
 223                 case CMD_REQUEST_COMMAND:
 224                 {
 225                         ReadyRestart();
 226                         return;
 227                 }
 228
 229                 default:
 230                 case CMD_REQUEST_USAGE:
 231                 {
 232                         print("\nUsage:^3 sv_cmd allready\n");
 233                         print("  No arguments required.\n");
 234                         return;
 235                 }
 236         }
 237 }
 238
 239 void GameCommand_allspec(float request, float argc)
 240 {
 241         switch(request)
 242         {
 243                 case CMD_REQUEST_COMMAND:
 244                 {
 245                         entity client;
 246                         string reason = argv(1);
 247                         float i = 0;
 248
 249                         FOR_EACH_REALPLAYER(client)
 250                         {
 251                                 self = client;
 252                                 if(self.caplayer)
 253                                         self.caplayer = 0;
 254                                 PutObserverInServer();
 255                                 ++i;
 256                         }
 257                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 258                         else { print("No players found to spectate.\n"); }
 259                         return;
 260                 }
 261
 262                 default:
 263                 case CMD_REQUEST_USAGE:
 264                 {
 265                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 266                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 267                         print("See also: ^2moveplayer, shuffleteams^7\n");
 268                         return;
 269                 }
 270         }
 271 }
 272
 273 void GameCommand_anticheat(float request, float argc)
 274 {
 275         switch(request)
 276         {
 277                 case CMD_REQUEST_COMMAND:
 278                 {
 279                         entity client = GetIndexedEntity(argc, 1);
 280                         float accepted = VerifyClientEntity(client, false, false);
 281
 282                         if(accepted > 0)
 283                         {
 284                                 self = client;
 285                                 anticheat_report();
 286                                 return;
 287                         }
 288                         else
 289                         {
 290                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 291                         }
 292                 }
 293
 294                 default:
 295                         print("Incorrect parameters for ^2anticheat^7\n");
 296                 case CMD_REQUEST_USAGE:
 297                 {
 298                         print("\nUsage:^3 sv_cmd anticheat client\n");
 299                         print("  'client' is the entity number or name of the player.\n");
 300                         return;
 301                 }
 302         }
 303 }
 304
 305 void GameCommand_bbox(float request)
 306 {
 307         switch(request)
 308         {
 309                 case CMD_REQUEST_COMMAND:
 310                 {
 311                         print("Original size: ", ftos(world.absmin.x), " ", ftos(world.absmin.y), " ", ftos(world.absmin.z));
 312                         print(" ", ftos(world.absmax.x), " ", ftos(world.absmax.y), " ", ftos(world.absmax.z), "\n");
 313                         print("Currently set size: ", ftos(world.mins.x), " ", ftos(world.mins.y), " ", ftos(world.mins.z));
 314                         print(" ", ftos(world.maxs.x), " ", ftos(world.maxs.y), " ", ftos(world.maxs.z), "\n");
 315                         print("Solid bounding box size:");
 316
 317                         tracebox('1 0 0' * world.absmin.x,
 318                                                         '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 319                                                         '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 320                                                         '1 0 0' * world.absmax.x,
 321                                         MOVE_WORLDONLY,
 322                                         world);
 323                         if(trace_startsolid)
 324                                 print(" ", ftos(world.absmin.x));
 325                         else
 326                                 print(" ", ftos(trace_endpos.x));
 327
 328                         tracebox('0 1 0' * world.absmin.y,
 329                                                         '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 330                                                         '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 331                                                         '0 1 0' * world.absmax.y,
 332                                         MOVE_WORLDONLY,
 333                                         world);
 334                         if(trace_startsolid)
 335                                 print(" ", ftos(world.absmin.y));
 336                         else
 337                                 print(" ", ftos(trace_endpos.y));
 338
 339                         tracebox('0 0 1' * world.absmin.z,
 340                                                         '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 341                                                         '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 342                                                         '0 0 1' * world.absmax.z,
 343                                         MOVE_WORLDONLY,
 344                                         world);
 345                         if(trace_startsolid)
 346                                 print(" ", ftos(world.absmin.z));
 347                         else
 348                                 print(" ", ftos(trace_endpos.z));
 349
 350                         tracebox('1 0 0' * world.absmax.x,
 351                                                         '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 352                                                         '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 353                                                         '1 0 0' * world.absmin.x,
 354                                         MOVE_WORLDONLY,
 355                                         world);
 356                         if(trace_startsolid)
 357                                 print(" ", ftos(world.absmax.x));
 358                         else
 359                                 print(" ", ftos(trace_endpos.x));
 360
 361                         tracebox('0 1 0' * world.absmax.y,
 362                                                         '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 363                                                         '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 364                                                         '0 1 0' * world.absmin.y,
 365                                         MOVE_WORLDONLY,
 366                                         world);
 367                         if(trace_startsolid)
 368                                 print(" ", ftos(world.absmax.y));
 369                         else
 370                                 print(" ", ftos(trace_endpos.y));
 371
 372                         tracebox('0 0 1' * world.absmax.z,
 373                                                         '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 374                                                         '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 375                                                         '0 0 1' * world.absmin.z,
 376                                         MOVE_WORLDONLY,
 377                                         world);
 378                         if(trace_startsolid)
 379                                 print(" ", ftos(world.absmax.z));
 380                         else
 381                                 print(" ", ftos(trace_endpos.z));
 382
 383                         print("\n");
 384                         return;
 385                 }
 386
 387                 default:
 388                 case CMD_REQUEST_USAGE:
 389                 {
 390                         print("\nUsage:^3 sv_cmd bbox\n");
 391                         print("  No arguments required.\n");
 392                         print("See also: ^2gettaginfo, trace^7\n");
 393                         return;
 394                 }
 395         }
 396 }
 397
 398 void GameCommand_bot_cmd(float request, float argc, string command)
 399 {
 400         switch(request)
 401         {
 402                 case CMD_REQUEST_COMMAND:
 403                 {
 404                         entity bot;
 405
 406                         if(argv(1) == "reset")
 407                         {
 408                                 bot_resetqueues();
 409                                 return;
 410                         }
 411                         else if(argv(1) == "setbots")
 412                         {
 413                                 cvar_settemp("bot_vs_human", "0");
 414                                 cvar_settemp("minplayers", "0");
 415                                 cvar_settemp("bot_number", "0");
 416                                 bot_fixcount();
 417                                 cvar_settemp("bot_number", argv(2));
 418                                 if(!bot_fixcount())
 419                                         print("Sorry, could not set requested bot count\n");
 420                                 return;
 421                         }
 422                         else if(argv(1) == "load" && argc == 3)
 423                         {
 424                                 float fh, i;
 425                                 string s;
 426                                 fh = fopen(argv(2), FILE_READ);
 427                                 if(fh < 0)
 428                                 {
 429                                         print("cannot open the file\n");
 430                                         return;
 431                                 }
 432
 433                                 i = 0;
 434                                 while((s = fgets(fh)))
 435                                 {
 436                                         argc = tokenize_console(s);
 437
 438                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 439                                         {
 440                                                 if(argv(2) == "reset")
 441                                                 {
 442                                                         bot_resetqueues();
 443                                                 }
 444                                                 else if(argv(2) == "setbots")
 445                                                 {
 446                                                         cvar_settemp("bot_vs_human", "0");
 447                                                         cvar_settemp("minplayers", "0");
 448                                                         cvar_settemp("bot_number", "0");
 449                                                         bot_fixcount();
 450                                                         cvar_settemp("bot_number", argv(3));
 451                                                         if(!bot_fixcount())
 452                                                                 print("Sorry, could not set requested bot count\n");
 453                                                 }
 454                                                 else
 455                                                 {
 456                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 457                                                         bot = find_bot_by_number(stof(argv(2)));
 458                                                         if(bot == world)
 459                                                                 bot = find_bot_by_name(argv(2));
 460                                                         if(bot)
 461                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 462                                                 }
 463                                         }
 464                                         else
 465                                                 localcmd(strcat(s, "\n"));
 466
 467                                         ++i;
 468                                 }
 469                                 print(ftos(i), " commands read\n");
 470                                 fclose(fh);
 471                                 return;
 472                         }
 473                         else if(argv(1) == "help")
 474                         {
 475                                 if(argv(2))
 476                                         bot_cmdhelp(argv(2));
 477                                 else
 478                                         bot_list_commands();
 479                                 return;
 480                         }
 481                         else if(argc >= 3) // this comes last
 482                         {
 483                                 bot = find_bot_by_number(stof(argv(1)));
 484                                 if(bot == world)
 485                                         bot = find_bot_by_name(argv(1));
 486                                 if(bot)
 487                                 {
 488                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 489                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 490                                         return;
 491                                 }
 492                                 else
 493                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 494                         }
 495                 }
 496
 497                 default:
 498                         print("Incorrect parameters for ^2bot_cmd^7\n");
 499                 case CMD_REQUEST_USAGE:
 500                 {
 501                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 502                         print("  'client' can be either the name or entity id of the bot\n");
 503                         print("  For full list of commands, see bot_cmd help [command].\n");
 504                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 505                         print("          sv_cmd bot_cmd client presskey jump\n");
 506                         return;
 507                 }
 508         }
 509 }
 510
 511 void GameCommand_cointoss(float request, float argc)
 512 {
 513         switch(request)
 514         {
 515                 case CMD_REQUEST_COMMAND:
 516                 {
 517                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 518                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 519                         string choice = ((random() > 0.5) ? result1 : result2);
 520
 521                         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_COINTOSS, choice);
 522                         return;
 523                 }
 524
 525                 default:
 526                 case CMD_REQUEST_USAGE:
 527                 {
 528                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 529                         print("  Where 'result1' and 'result2' are user created options.\n");
 530                         return;
 531                 }
 532         }
 533 }
 534
 535 void GameCommand_database(float request, float argc)
 536 {
 537         switch(request)
 538         {
 539                 case CMD_REQUEST_COMMAND:
 540                 {
 541                         if(argc == 3)
 542                         {
 543                                 if(argv(1) == "save")
 544                                 {
 545                                         db_save(ServerProgsDB, argv(2));
 546                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 547                                         return;
 548                                 }
 549                                 else if(argv(1) == "dump")
 550                                 {
 551                                         db_dump(ServerProgsDB, argv(2));
 552                                         print("DB dumped.\n"); // wtf does this do?
 553                                         return;
 554                                 }
 555                                 else if(argv(1) == "load")
 556                                 {
 557                                         db_close(ServerProgsDB);
 558                                         ServerProgsDB = db_load(argv(2));
 559                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 560                                         return;
 561                                 }
 562                         }
 563                 }
 564
 565                 default:
 566                         print("Incorrect parameters for ^2database^7\n");
 567                 case CMD_REQUEST_USAGE:
 568                 {
 569                         print("\nUsage:^3 sv_cmd database action filename\n");
 570                         print("  Where 'action' is the command to complete,\n");
 571                         print("  and 'filename' is what it acts upon.\n");
 572                         print("  Full list of commands here: \"save, dump, load.\"\n");
 573                         return;
 574                 }
 575         }
 576 }
 577
 578 void GameCommand_defer_clear(float request, float argc)
 579 {
 580         switch(request)
 581         {
 582                 case CMD_REQUEST_COMMAND:
 583                 {
 584                         entity client;
 585                         float accepted;
 586
 587                         if(argc >= 2)
 588                         {
 589                                 client = GetIndexedEntity(argc, 1);
 590                                 accepted = VerifyClientEntity(client, true, false);
 591
 592                                 if(accepted > 0)
 593                                 {
 594                                         stuffcmd(client, "defer clear\n");
 595                                         print("defer clear stuffed to ", client.netname, "\n");
 596                                 }
 597                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 598
 599                                 return;
 600                         }
 601                 }
 602
 603                 default:
 604                         print("Incorrect parameters for ^2defer_clear^7\n");
 605                 case CMD_REQUEST_USAGE:
 606                 {
 607                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 608                         print("  'client' is the entity number or name of the player.\n");
 609                         print("See also: ^2defer_clear_all^7\n");
 610                         return;
 611                 }
 612         }
 613 }
 614
 615 void GameCommand_defer_clear_all(float request)
 616 {
 617         switch(request)
 618         {
 619                 case CMD_REQUEST_COMMAND:
 620                 {
 621                         entity client;
 622                         float i = 0;
 623                         float argc;
 624
 625                         FOR_EACH_CLIENT(client)
 626                         {
 627                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 628                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 629                                 ++i;
 630                         }
 631                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 632                         return;
 633                 }
 634
 635                 default:
 636                 case CMD_REQUEST_USAGE:
 637                 {
 638                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 639                         print("  No arguments required.\n");
 640                         print("See also: ^2defer_clear^7\n");
 641                         return;
 642                 }
 643         }
 644 }
 645
 646 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 647 {
 648         switch(request)
 649         {
 650                 case CMD_REQUEST_COMMAND:
 651                 {
 652                         if(argv(1))
 653                         {
 654                                 if(argv(2))
 655                                         race_deleteTime(argv(2), stof(argv(1)));
 656                                 else
 657                                         race_deleteTime(GetMapname(), stof(argv(1)));
 658                                 return;
 659                         }
 660                 }
 661
 662                 default:
 663                         print("Incorrect parameters for ^2delrec^7\n");
 664                 case CMD_REQUEST_USAGE:
 665                 {
 666                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 667                         print("  'ranking' is which ranking level to clear up to, \n");
 668                         print("  it will clear all records up to nth place.\n");
 669                         print("  if 'map' is not provided it will use current map.\n");
 670                         return;
 671                 }
 672         }
 673 }
 674
 675 void GameCommand_effectindexdump(float request)
 676 {
 677         switch(request)
 678         {
 679                 case CMD_REQUEST_COMMAND:
 680                 {
 681                         float fh, d;
 682                         string s;
 683
 684                         d = db_create();
 685                         print("begin of effects list\n");
 686                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 687                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 688                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 689                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 690                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 691                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 692                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 693                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 694                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 695                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 696                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 697                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 698                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 699                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 700                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 701                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 702                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 703                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 704                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 705                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 706                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 707                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 708                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 709                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 710                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 711                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 712                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 713                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 714                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 715                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 716                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 717                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 718                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 719                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 720                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 721                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 722
 723                         fh = fopen("effectinfo.txt", FILE_READ);
 724                         while((s = fgets(fh)))
 725                         {
 726                                 tokenize_console(s);
 727                                 if(argv(0) == "effect")
 728                                 {
 729                                         if(db_get(d, argv(1)) != "1")
 730                                         {
 731                                                 if(particleeffectnum(argv(1)) >= 0)
 732                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 733                                                 db_put(d, argv(1), "1");
 734                                         }
 735                                 }
 736                         }
 737                         print("end of effects list\n");
 738
 739                         db_close(d);
 740                         return;
 741                 }
 742
 743                 default:
 744                 case CMD_REQUEST_USAGE:
 745                 {
 746                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 747                         print("  No arguments required.\n");
 748                         return;
 749                 }
 750         }
 751 }
 752
 753 void GameCommand_extendmatchtime(float request)
 754 {
 755         switch(request)
 756         {
 757                 case CMD_REQUEST_COMMAND:
 758                 {
 759                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 760                         return;
 761                 }
 762
 763                 default:
 764                 case CMD_REQUEST_USAGE:
 765                 {
 766                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 767                         print("  No arguments required.\n");
 768                         print("See also: ^2reducematchtime^7\n");
 769                         return;
 770                 }
 771         }
 772 }
 773
 774 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 775 {
 776         switch(request)
 777         {
 778                 case CMD_REQUEST_COMMAND:
 779                 {
 780                         entity client;
 781
 782                         for(client = world; (client = find(client, classname, argv(1))); )
 783                                 print(etos(client), "\n");
 784
 785                         return;
 786                 }
 787
 788                 default:
 789                         print("Incorrect parameters for ^2find^7\n");
 790                 case CMD_REQUEST_USAGE:
 791                 {
 792                         print("\nUsage:^3 sv_cmd find classname\n");
 793                         print("  Where 'classname' is the classname to search for.\n");
 794                         return;
 795                 }
 796         }
 797 }
 798
 799 void GameCommand_gametype(float request, float argc)
 800 {
 801         switch(request)
 802         {
 803                 case CMD_REQUEST_COMMAND:
 804                 {
 805                         if(argv(1) != "")
 806                         {
 807                                 string s = argv(1);
 808                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 809
 810                                 if(t)
 811                                 {
 812                                         MapInfo_SwitchGameType(t);
 813                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 814                                         if(MapInfo_count > 0)
 815                                         {
 816                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 817                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 818                                                 lsmaps_reply = strzone(getlsmaps());
 819                                                 bprint("Game type successfully switched to ", s, "\n");
 820                                         }
 821                                         else
 822                                         {
 823                                                 bprint("Cannot use this game type: no map for it found\n");
 824                                                 MapInfo_SwitchGameType(tsave);
 825                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 826                                         }
 827                                 }
 828                                 else
 829                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 830
 831                                 return;
 832                         }
 833                 }
 834
 835                 default:
 836                         print("Incorrect parameters for ^2gametype^7\n");
 837                 case CMD_REQUEST_USAGE:
 838                 {
 839                         print("\nUsage:^3 sv_cmd gametype mode\n");
 840                         print("  Where 'mode' is the gametype mode to switch to.\n");
 841                         print("See also: ^2gotomap^7\n");
 842                         return;
 843                 }
 844         }
 845 }
 846
 847 void GameCommand_gettaginfo(float request, float argc)
 848 {
 849         switch(request)
 850         {
 851                 case CMD_REQUEST_COMMAND:
 852                 {
 853                         entity tmp_entity;
 854                         float i;
 855                         vector v;
 856
 857                         if(argc >= 4)
 858                         {
 859                                 tmp_entity = spawn();
 860                                 if(argv(1) == "w")
 861                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 862                                 else
 863                                 {
 864                                         precache_model(argv(1));
 865                                         setmodel(tmp_entity, argv(1));
 866                                 }
 867                                 tmp_entity.frame = stof(argv(2));
 868                                 if(substring(argv(3), 0, 1) == "#")
 869                                         i = stof(substring(argv(3), 1, -1));
 870                                 else
 871                                         i = gettagindex(tmp_entity, argv(3));
 872                                 if(i)
 873                                 {
 874                                         v = gettaginfo(tmp_entity, i);
 875                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 876                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 877                                         print(" vector = ", ftos(v.x), " ", ftos(v.y), " ", ftos(v.z), "\n");
 878                                         print(" offset = ", ftos(gettaginfo_offset.x), " ", ftos(gettaginfo_offset.y), " ", ftos(gettaginfo_offset.z), "\n");
 879                                         print(" forward = ", ftos(gettaginfo_forward.x), " ", ftos(gettaginfo_forward.y), " ", ftos(gettaginfo_forward.z), "\n");
 880                                         print(" right = ", ftos(gettaginfo_right.x), " ", ftos(gettaginfo_right.y), " ", ftos(gettaginfo_right.z), "\n");
 881                                         print(" up = ", ftos(gettaginfo_up.x), " ", ftos(gettaginfo_up.y), " ", ftos(gettaginfo_up.z), "\n");
 882                                         if(argc >= 6)
 883                                         {
 884                                                 v.y = -v.y;
 885                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 886                                         }
 887                                 }
 888                                 else
 889                                         print("bone not found\n");
 890
 891                                 remove(tmp_entity);
 892                                 return;
 893                         }
 894                 }
 895
 896                 default:
 897                         print("Incorrect parameters for ^2gettaginfo^7\n");
 898                 case CMD_REQUEST_USAGE:
 899                 {
 900                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 901                         print("See also: ^2bbox, trace^7\n");
 902                         return;
 903                 }
 904         }
 905 }
 906
 907 void GameCommand_animbench(float request, float argc)
 908 {
 909         switch(request)
 910         {
 911                 case CMD_REQUEST_COMMAND:
 912                 {
 913                         entity tmp_entity;
 914
 915                         if(argc >= 4)
 916                         {
 917                                 tmp_entity = spawn();
 918                                 if(argv(1) == "w")
 919                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 920                                 else
 921                                 {
 922                                         precache_model(argv(1));
 923                                         setmodel(tmp_entity, argv(1));
 924                                 }
 925                                 float f1 = stof(argv(2));
 926                                 float f2 = stof(argv(3));
 927                                 float t0;
 928                                 float t1 = 0;
 929                                 float t2 = 0;
 930                                 float n = 0;
 931
 932                                 while(t1 + t2 < 1)
 933                                 {
 934                                         tmp_entity.frame = f1;
 935                                         t0 = gettime(GETTIME_HIRES);
 936                                         getsurfacepoint(tmp_entity, 0, 0);
 937                                         t1 += gettime(GETTIME_HIRES) - t0;
 938                                         tmp_entity.frame = f2;
 939                                         t0 = gettime(GETTIME_HIRES);
 940                                         getsurfacepoint(tmp_entity, 0, 0);
 941                                         t2 += gettime(GETTIME_HIRES) - t0;
 942                                         n += 1;
 943                                 }
 944                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 945                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 946
 947                                 remove(tmp_entity);
 948                                 return;
 949                         }
 950                 }
 951
 952                 default:
 953                         print("Incorrect parameters for ^2gettaginfo^7\n");
 954                 case CMD_REQUEST_USAGE:
 955                 {
 956                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 957                         print("See also: ^2bbox, trace^7\n");
 958                         return;
 959                 }
 960         }
 961 }
 962
 963 void GameCommand_gotomap(float request, float argc)
 964 {
 965         switch(request)
 966         {
 967                 case CMD_REQUEST_COMMAND:
 968                 {
 969                         if(argv(1))
 970                         {
 971                                 print(GotoMap(argv(1)), "\n");
 972                                 return;
 973                         }
 974                 }
 975
 976                 default:
 977                         print("Incorrect parameters for ^2gotomap^7\n");
 978                 case CMD_REQUEST_USAGE:
 979                 {
 980                         print("\nUsage:^3 sv_cmd gotomap map\n");
 981                         print("  Where 'map' is the *.bsp file to change to.\n");
 982                         print("See also: ^2gametype^7\n");
 983                         return;
 984                 }
 985         }
 986 }
 987
 988 void GameCommand_lockteams(float request)
 989 {
 990         switch(request)
 991         {
 992                 case CMD_REQUEST_COMMAND:
 993                 {
 994                         if(teamplay)
 995                         {
 996                                 lockteams = 1;
 997                                 bprint("^1The teams are now locked.\n");
 998                         }
 999                         else
1000                         {
1001                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
1002                         }
1003                         return;
1004                 }
1005
1006                 default:
1007                 case CMD_REQUEST_USAGE:
1008                 {
1009                         print("\nUsage:^3 sv_cmd lockteams\n");
1010                         print("  No arguments required.\n");
1011                         print("See also: ^2unlockteams^7\n");
1012                         return;
1013                 }
1014         }
1015 }
1016
1017 void GameCommand_make_mapinfo(float request)
1018 {
1019         switch(request)
1020         {
1021                 case CMD_REQUEST_COMMAND:
1022                 {
1023                         entity tmp_entity;
1024
1025                         tmp_entity = spawn();
1026                         tmp_entity.classname = "make_mapinfo";
1027                         tmp_entity.think = make_mapinfo_Think;
1028                         tmp_entity.nextthink = time;
1029                         MapInfo_Enumerate();
1030                         return;
1031                 }
1032
1033                 default:
1034                 case CMD_REQUEST_USAGE:
1035                 {
1036                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1037                         print("  No arguments required.\n");
1038                         print("See also: ^2radarmap^7\n");
1039                         return;
1040                 }
1041         }
1042 }
1043
1044 void GameCommand_moveplayer(float request, float argc)
1045 {
1046         switch(request)
1047         {
1048                 case CMD_REQUEST_COMMAND:
1049                 {
1050                         float accepted;
1051                         entity client;
1052
1053                         string targets = strreplace(",", " ", argv(1));
1054                         string original_targets = strreplace(" ", ", ", targets);
1055                         string destination = argv(2);
1056
1057                         string successful, t;
1058                         successful = string_null;
1059
1060                         // lets see if the target(s) even actually exist.
1061                         if((targets) && (destination))
1062                         {
1063                                 for (;targets;)
1064                                 {
1065                                         t = car(targets); targets = cdr(targets);
1066
1067                                         // Check to see if the player is a valid target
1068                                         client = GetFilteredEntity(t);
1069                                         accepted = VerifyClientEntity(client, false, false);
1070
1071                                         if(accepted <= 0)
1072                                         {
1073                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1074                                                 continue;
1075                                         }
1076
1077                                         // Where are we putting this player?
1078                                         if(destination == "spec" || destination == "spectator")
1079                                         {
1080                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1081                                                 {
1082                                                         self = client;
1083                                                         if(self.caplayer)
1084                                                                 self.caplayer = 0;
1085                                                         PutObserverInServer();
1086
1087                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1088                                                 }
1089                                                 else
1090                                                 {
1091                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1092                                                 }
1093                                                 continue;
1094                                         }
1095                                         else
1096                                         {
1097                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1098                                                 {
1099                                                         if(teamplay)
1100                                                         {
1101                                                                 // set up
1102                                                                 float team_id;
1103                                                                 float save = client.team_forced;
1104                                                                 client.team_forced = 0;
1105
1106                                                                 // find the team to move the player to
1107                                                                 team_id = Team_ColorToTeam(destination);
1108                                                                 if(team_id == client.team) // already on the destination team
1109                                                                 {
1110                                                                         // keep the forcing undone
1111                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1112                                                                         continue;
1113                                                                 }
1114                                                                 else if(team_id == 0)  // auto team
1115                                                                 {
1116                                                                         CheckAllowedTeams(client);
1117                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1118                                                                 }
1119                                                                 else
1120                                                                 {
1121                                                                         CheckAllowedTeams(client);
1122                                                                 }
1123                                                                 client.team_forced = save;
1124
1125                                                                 // Check to see if the destination team is even available
1126                                                                 switch(team_id)
1127                                                                 {
1128                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1129                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1130                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1131                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1132
1133                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1134                                                                 }
1135
1136                                                                 // If so, lets continue and finally move the player
1137                                                                 client.team_forced = 0;
1138                                                                 MoveToTeam(client, team_id, 6);
1139                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1140                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1141                                                                 continue;
1142                                                         }
1143                                                         else
1144                                                         {
1145                                                                 print("Can't change teams when currently not playing a team game.\n");
1146                                                                 return;
1147                                                         }
1148                                                 }
1149                                                 else
1150                                                 {
1151                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1152                                                         return;
1153                                                 }
1154                                         }
1155                                 }
1156
1157                                 if(successful)
1158                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1159                                 else
1160                                         print("No players given (", original_targets, ") are able to move.\n");
1161
1162                                 return; // still correct parameters so return to avoid usage print
1163                         }
1164                 }
1165
1166                 default:
1167                         print("Incorrect parameters for ^2moveplayer^7\n");
1168                 case CMD_REQUEST_USAGE:
1169                 {
1170                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1171                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1172                         print("  'destination' is what to send the player to, be it team or spectating\n");
1173                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1174                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1175                         print("          sv_cmd moveplayer 2 spec \n");
1176                         print("See also: ^2allspec, shuffleteams^7\n");
1177                         return;
1178                 }
1179         }
1180 }
1181
1182 void GameCommand_nospectators(float request)
1183 {
1184         switch(request)
1185         {
1186                 case CMD_REQUEST_COMMAND:
1187                 {
1188                         blockSpectators = 1;
1189                         entity plr;
1190                         FOR_EACH_REALCLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1191                         {
1192                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1193                                 if(!plr.caplayer)
1194                                 {
1195                                         plr.spectatortime = time;
1196                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1197                                 }
1198                         }
1199                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1200                         return;
1201                 }
1202
1203                 default:
1204                 case CMD_REQUEST_USAGE:
1205                 {
1206                         print("\nUsage:^3 sv_cmd nospectators\n");
1207                         print("  No arguments required.\n");
1208                         return;
1209                 }
1210         }
1211 }
1212
1213 void GameCommand_playerdemo(float request, float argc)
1214 {
1215         switch(request)
1216         {
1217                 case CMD_REQUEST_COMMAND:
1218                 {
1219                         if(argv(2) && argv(3))
1220                         {
1221                                 entity client;
1222                                 float i, n, accepted;
1223
1224                                 switch(argv(1))
1225                                 {
1226                                         case "read":
1227                                         {
1228                                                 client = GetIndexedEntity(argc, 2);
1229                                                 accepted = VerifyClientEntity(client, false, true);
1230
1231                                                 if(accepted <= 0)
1232                                                 {
1233                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1234                                                         return;
1235                                                 }
1236
1237                                                 self = client;
1238                                                 playerdemo_open_read(argv(next_token));
1239                                                 return;
1240                                         }
1241
1242                                         case "write":
1243                                         {
1244                                                 client = GetIndexedEntity(argc, 2);
1245                                                 accepted = VerifyClientEntity(client, false, false);
1246
1247                                                 if(accepted <= 0)
1248                                                 {
1249                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1250                                                         return;
1251                                                 }
1252
1253                                                 self = client;
1254                                                 playerdemo_open_write(argv(next_token));
1255                                                 return;
1256                                         }
1257
1258                                         case "auto_read_and_write":
1259                                         {
1260                                                 n = GetFilteredNumber(argv(3));
1261                                                 cvar_set("bot_number", ftos(n));
1262
1263                                                 localcmd("wait; wait; wait\n");
1264                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1265
1266                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1267                                                 return;
1268                                         }
1269
1270                                         case "auto_read":
1271                                         {
1272                                                 n = GetFilteredNumber(argv(3));
1273                                                 cvar_set("bot_number", ftos(n));
1274
1275                                                 localcmd("wait; wait; wait\n");
1276                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1277                                                 return;
1278                                         }
1279                                 }
1280                         }
1281                 }
1282
1283                 default:
1284                         print("Incorrect parameters for ^2playerdemo^7\n");
1285                 case CMD_REQUEST_USAGE:
1286                 {
1287                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1288                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1289                         return;
1290                 }
1291         }
1292 }
1293
1294 void GameCommand_printstats(float request)
1295 {
1296         switch(request)
1297         {
1298                 case CMD_REQUEST_COMMAND:
1299                 {
1300                         DumpStats(false);
1301                         print("stats dumped.\n");
1302                         return;
1303                 }
1304
1305                 default:
1306                 case CMD_REQUEST_USAGE:
1307                 {
1308                         print("\nUsage:^3 sv_cmd printstats\n");
1309                         print("  No arguments required.\n");
1310                         return;
1311                 }
1312         }
1313 }
1314
1315 void GameCommand_radarmap(float request, float argc)
1316 {
1317         switch(request)
1318         {
1319                 case CMD_REQUEST_COMMAND:
1320                 {
1321                         if(RadarMap_Make(argc))
1322                                 return;
1323                 }
1324
1325                 default:
1326                         print("Incorrect parameters for ^2radarmap^7\n");
1327                 case CMD_REQUEST_USAGE:
1328                 {
1329                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1330                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1331                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1332                         print("See also: ^2make_mapinfo^7\n");
1333                         return;
1334                 }
1335         }
1336 }
1337
1338 void GameCommand_reducematchtime(float request)
1339 {
1340         switch(request)
1341         {
1342                 case CMD_REQUEST_COMMAND:
1343                 {
1344                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1345                         return;
1346                 }
1347
1348                 default:
1349                 case CMD_REQUEST_USAGE:
1350                 {
1351                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1352                         print("  No arguments required.\n");
1353                         print("See also: ^2extendmatchtime^7\n");
1354                         return;
1355                 }
1356         }
1357 }
1358
1359 void GameCommand_setbots(float request, float argc)
1360 {
1361         switch(request)
1362         {
1363                 case CMD_REQUEST_COMMAND:
1364                 {
1365                         if(argc >= 2)
1366                         {
1367                                 cvar_settemp("minplayers", "0");
1368                                 cvar_settemp("bot_number", argv(1));
1369                                 bot_fixcount();
1370                                 return;
1371                         }
1372                 }
1373
1374                 default:
1375                         print("Incorrect parameters for ^2setbots^7\n");
1376                 case CMD_REQUEST_USAGE:
1377                 {
1378                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1379                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1380                         print("See also: ^2bot_cmd^7\n");
1381                         return;
1382                 }
1383         }
1384 }
1385
1386 void GameCommand_shuffleteams(float request)
1387 {
1388         switch(request)
1389         {
1390                 case CMD_REQUEST_COMMAND:
1391                 {
1392                         if(teamplay)
1393                         {
1394                                 entity tmp_player;
1395                                 int i;
1396                                 float x, t_teams, t_players, team_color;
1397
1398                                 // count the total amount of players and total amount of teams
1399                                 t_players = 0;
1400                                 t_teams = 0;
1401                                 FOR_EACH_CLIENT(tmp_player)
1402                                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer)
1403                                 {
1404                                         CheckAllowedTeams(tmp_player);
1405
1406                                         if(c1 >= 0) t_teams = max(1, t_teams);
1407                                         if(c2 >= 0) t_teams = max(2, t_teams);
1408                                         if(c3 >= 0) t_teams = max(3, t_teams);
1409                                         if(c4 >= 0) t_teams = max(4, t_teams);
1410
1411                                         ++t_players;
1412                                 }
1413
1414                                 // build a list of the players in a random order
1415                                 FOR_EACH_CLIENT(tmp_player)
1416                                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer)
1417                                 {
1418                                         for (;;)
1419                                         {
1420                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1421
1422                                                 if(shuffleteams_players[i])
1423                                                 {
1424                                                         continue; // a player is already assigned to this slot
1425                                                 }
1426                                                 else
1427                                                 {
1428                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1429                                                         break;
1430                                                 }
1431                                         }
1432                                 }
1433
1434                                 // finally, from the list made earlier, re-join the players in different order.
1435                                 for (int i = 1; i <= t_teams; ++i)
1436                                 {
1437                                         // find out how many players to assign to this team
1438                                         x = (t_players / t_teams);
1439                                         x = ((i == 1) ? ceil(x) : floor(x));
1440
1441                                         team_color = Team_NumberToTeam(i);
1442
1443                                         // sort through the random list of players made earlier
1444                                         for (int z = 1; z <= maxclients; ++z)
1445                                         {
1446                                                 if (!(shuffleteams_teams[i] >= x))
1447                                                 {
1448                                                         if (!(shuffleteams_players[z]))
1449                                                                 continue; // not a player, move on to next random slot
1450
1451                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1452                                                                 self = edict_num(shuffleteams_players[z]);
1453
1454                                                         if(self.team != team_color)
1455                                                                 MoveToTeam(self, team_color, 6);
1456
1457                                                         shuffleteams_players[z] = 0;
1458                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1459                                                 }
1460                                                 else
1461                                                 {
1462                                                         break; // move on to next team
1463                                                 }
1464                                         }
1465                                 }
1466
1467                                 bprint("Successfully shuffled the players around randomly.\n");
1468
1469                                 // clear the buffers now
1470                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1471                                         shuffleteams_players[i] = 0;
1472
1473                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1474                                         shuffleteams_teams[i] = 0;
1475                         }
1476                         else
1477                         {
1478                                 print("Can't shuffle teams when currently not playing a team game.\n");
1479                         }
1480
1481                         return;
1482                 }
1483
1484                 default:
1485                 case CMD_REQUEST_USAGE:
1486                 {
1487                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1488                         print("  No arguments required.\n");
1489                         print("See also: ^2moveplayer, allspec^7\n");
1490                         return;
1491                 }
1492         }
1493 }
1494
1495 void GameCommand_stuffto(float request, float argc)
1496 {
1497         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1498         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1499         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1500
1501         #ifdef STUFFTO_ENABLED
1502         #message "stuffto command enabled"
1503         switch(request)
1504         {
1505                 case CMD_REQUEST_COMMAND:
1506                 {
1507                         if(argv(2))
1508                         {
1509                                 entity client = GetIndexedEntity(argc, 1);
1510                                 float accepted = VerifyClientEntity(client, true, false);
1511
1512                                 if(accepted > 0)
1513                                 {
1514                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1515                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1516                                 }
1517                                 else
1518                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1519
1520                                 return;
1521                         }
1522                 }
1523
1524                 default:
1525                         print("Incorrect parameters for ^2stuffto^7\n");
1526                 case CMD_REQUEST_USAGE:
1527                 {
1528                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1529                         print("  'client' is the entity number or name of the player,\n");
1530                         print("  and 'command' is the command to be sent to that player.\n");
1531                         return;
1532                 }
1533         }
1534         #else
1535         if(request)
1536         {
1537                 print("stuffto command is not enabled on this server.\n");
1538                 return;
1539         }
1540         #endif
1541 }
1542
1543 void GameCommand_trace(float request, float argc)
1544 {
1545         switch(request)
1546         {
1547                 case CMD_REQUEST_COMMAND:
1548                 {
1549                         entity e;
1550                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1551                         float i, f, safe, unsafe, dq, dqf;
1552
1553                         switch(argv(1))
1554                         {
1555                                 case "debug":
1556                                 {
1557                                         float hitcount = 0;
1558                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1559                                         float worst_endpos_bug = 0;
1560                                         for (;;)
1561                                         {
1562                                                 org = world.mins;
1563                                                 delta = world.maxs - world.mins;
1564
1565                                                 start.x = org.x + random() * delta.x;
1566                                                 start.y = org.y + random() * delta.y;
1567                                                 start.z = org.z + random() * delta.z;
1568
1569                                                 end.x = org.x + random() * delta.x;
1570                                                 end.y = org.y + random() * delta.y;
1571                                                 end.z = org.z + random() * delta.z;
1572
1573                                                 start = stov(vtos(start));
1574                                                 end = stov(vtos(end));
1575
1576                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1577                                                 if(!trace_startsolid && trace_fraction < 1)
1578                                                 {
1579                                                         p = trace_endpos;
1580                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1581                                                         if(trace_startsolid)
1582                                                         {
1583                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1584                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1585
1586                                                                 // how much do we need to back off?
1587                                                                 safe = 1;
1588                                                                 unsafe = 0;
1589                                                                 for (;;)
1590                                                                 {
1591                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1592                                                                         tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1593                                                                         if(trace_startsolid)
1594                                                                         {
1595                                                                                 if((safe + unsafe) * 0.5 == unsafe)
1596                                                                                         break;
1597                                                                                 unsafe = (safe + unsafe) * 0.5;
1598                                                                         }
1599                                                                         else
1600                                                                         {
1601                                                                                 if((safe + unsafe) * 0.5 == safe)
1602                                                                                         break;
1603                                                                                 safe = (safe + unsafe) * 0.5;
1604                                                                         }
1605                                                                 }
1606
1607                                                                 print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1608                                                                 print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1609
1610                                                                 tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1611                                                                 if(trace_startsolid)
1612                                                                         print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1613                                                                 else
1614                                                                         print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1615                                                                 if (++hitcount >= 10)
1616                                                                         break;
1617                                                         }
1618                                                         else
1619                                                         {
1620                                                                 q0 = p;
1621                                                                 dq = 0;
1622                                                                 dqf = 1;
1623                                                                 for (;;)
1624                                                                 {
1625                                                                         q = p + normalize(end - p) * (dq + dqf);
1626                                                                         if(q == q0)
1627                                                                                 break;
1628                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1629                                                                         if(trace_startsolid)
1630                                                                                 error("THIS ONE cannot happen");
1631                                                                         if(trace_fraction > 0)
1632                                                                                 dq += dqf * trace_fraction;
1633                                                                         dqf *= 0.5;
1634                                                                         q0 = q;
1635                                                                 }
1636                                                                 if(dq > worst_endpos_bug)
1637                                                                 {
1638                                                                         worst_endpos_bug = dq;
1639                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1640                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1641                                                                         if (++hitcount >= 10)
1642                                                                                 break;
1643                                                                 }
1644                                                         }
1645                                                 }
1646                                         }
1647                                         return;
1648                                 }
1649
1650                                 case "debug2":
1651                                 {
1652                                         e = nextent(world);
1653                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1654                                         vv = trace_endpos;
1655                                         if(trace_fraction == 1)
1656                                         {
1657                                                 print("not above ground, aborting\n");
1658                                                 return;
1659                                         }
1660                                         f = 0;
1661                                         for(i = 0; i < 100000; ++i)
1662                                         {
1663                                                 dv = randomvec();
1664                                                 if(dv.z > 0)
1665                                                         dv = -1 * dv;
1666                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1667                                                 if(trace_startsolid)
1668                                                         print("bug 1\n");
1669                                                 if(trace_fraction == 1)
1670                                                 if(dv.z < f)
1671                                                 {
1672                                                         print("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1673                                                         print(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1674                                                         f = dv.z;
1675                                                 }
1676                                         }
1677                                         print("highest possible dist: ", ftos(f), "\n");
1678                                         return;
1679                                 }
1680
1681                                 case "walk":
1682                                 {
1683                                         if(argc == 4)
1684                                         {
1685                                                 e = nextent(world);
1686                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1687                                                         print("can walk\n");
1688                                                 else
1689                                                         print("cannot walk\n");
1690                                                 return;
1691                                         }
1692                                 }
1693
1694                                 case "showline":
1695                                 {
1696                                         if(argc == 4)
1697                                         {
1698                                                 vv = stov(argv(2));
1699                                                 dv = stov(argv(3));
1700                                                 traceline(vv, dv, MOVE_NORMAL, world);
1701                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1702                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1703                                                 return;
1704                                         }
1705                                 }
1706
1707                                 // no default case, just go straight to invalid
1708                         }
1709                 }
1710
1711                 default:
1712                         print("Incorrect parameters for ^2trace^7\n");
1713                 case CMD_REQUEST_USAGE:
1714                 {
1715                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1716                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1717                         print("See also: ^2bbox, gettaginfo^7\n");
1718                         return;
1719                 }
1720         }
1721 }
1722
1723 void GameCommand_unlockteams(float request)
1724 {
1725         switch(request)
1726         {
1727                 case CMD_REQUEST_COMMAND:
1728                 {
1729                         if(teamplay)
1730                         {
1731                                 lockteams = 0;
1732                                 bprint("^1The teams are now unlocked.\n");
1733                         }
1734                         else
1735                         {
1736                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1737                         }
1738                         return;
1739                 }
1740
1741                 default:
1742                 case CMD_REQUEST_USAGE:
1743                 {
1744                         print("\nUsage:^3 sv_cmd unlockteams\n");
1745                         print("  No arguments required.\n");
1746                         print("See also: ^2lockteams^7\n");
1747                         return;
1748                 }
1749         }
1750 }
1751
1752 void GameCommand_warp(float request, float argc)
1753 {
1754         switch (request)
1755         {
1756                 case CMD_REQUEST_COMMAND:
1757                 {
1758                         if(autocvar_g_campaign)
1759                         {
1760                                 if(argc >= 2)
1761                                 {
1762                                         CampaignLevelWarp(stof(argv(1)));
1763                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1764                                 }
1765                                 else
1766                                 {
1767                                         CampaignLevelWarp(-1);
1768                                         print("Successfully warped to next campaign level.\n");
1769                                 }
1770                         }
1771                         else
1772                                 print("Not in campaign, can't level warp\n");
1773                         return;
1774                 }
1775
1776                 default:
1777                 case CMD_REQUEST_USAGE:
1778                 {
1779                         print("\nUsage:^3 sv_cmd warp [level]\n");
1780                         print("  'level' is the level to change campaign mode to.\n");
1781                         print("  if 'level' is not provided it will change to the next level.\n");
1782                         return;
1783                 }
1784         }
1785 }
1786
1787 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1788 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1789 void GameCommand_(float request)
1790 {
1791         switch(request)
1792         {
1793                 case CMD_REQUEST_COMMAND:
1794                 {
1795
1796                         return;
1797                 }
1798
1799                 default:
1800                 case CMD_REQUEST_USAGE:
1801                 {
1802                         print("\nUsage:^3 sv_cmd \n");
1803                         print("  No arguments required.\n");
1804                         return;
1805                 }
1806         }
1807 }
1808 */
1809
1810
1811 // ==================================
1812 //  Macro system for server commands
1813 // ==================================
1814
1815 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1816 #define SERVER_COMMANDS(request,arguments,command) \
1817         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1818         SERVER_COMMAND("mobbutcher", GameCommand_mobbutcher(request), "Instantly removes all monsters on the map") \
1819         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1820         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1821         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1822         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1823         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1824         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1825         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1826         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1827         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1828         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1829         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1830         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1831         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1832         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1833         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1834         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1835         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1836         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1837         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1838         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1839         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1840         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1841         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1842         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1843         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1844         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1845         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1846         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1847         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1848         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1849         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1850         /* nothing */
1851
1852 void GameCommand_macro_help()
1853 {
1854         #define SERVER_COMMAND(name,function,description) \
1855                 { print("  ^2", name, "^7: ", description, "\n"); }
1856
1857         SERVER_COMMANDS(0, 0, "");
1858         #undef SERVER_COMMAND
1859
1860         return;
1861 }
1862
1863 float GameCommand_macro_command(float argc, string command)
1864 {
1865         #define SERVER_COMMAND(name,function,description) \
1866                 { if(name == strtolower(argv(0))) { function; return true; } }
1867
1868         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
1869         #undef SERVER_COMMAND
1870
1871         return false;
1872 }
1873
1874 float GameCommand_macro_usage(float argc)
1875 {
1876         #define SERVER_COMMAND(name,function,description) \
1877                 { if(name == strtolower(argv(1))) { function; return true; } }
1878
1879         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "");
1880         #undef SERVER_COMMAND
1881
1882         return false;
1883 }
1884
1885 void GameCommand_macro_write_aliases(float fh)
1886 {
1887         #define SERVER_COMMAND(name,function,description) \
1888                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1889
1890         SERVER_COMMANDS(0, 0, "");
1891         #undef SERVER_COMMAND
1892
1893         return;
1894 }
1895
1896
1897 // =========================================
1898 //  Main Function Called By Engine (sv_cmd)
1899 // =========================================
1900 // If this function exists, game code handles gamecommand instead of the engine code.
1901
1902 void GameCommand(string command)
1903 {
1904         float argc = tokenize_console(command);
1905
1906         // Guide for working with argc arguments by example:
1907         // argc:   1    - 2      - 3     - 4
1908         // argv:   0    - 1      - 2     - 3
1909         // cmd     vote - master - login - password
1910
1911         if(strtolower(argv(0)) == "help")
1912         {
1913                 if(argc == 1)
1914                 {
1915                         print("\nServer console commands:\n");
1916                         GameCommand_macro_help();
1917
1918                         print("\nBanning commands:\n");
1919                         BanCommand_macro_help();
1920
1921                         print("\nCommon networked commands:\n");
1922                         CommonCommand_macro_help(world);
1923
1924                         print("\nGeneric commands shared by all programs:\n");
1925                         GenericCommand_macro_help();
1926
1927                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1928                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1929
1930                         return;
1931                 }
1932                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1933                 {
1934                         return;
1935                 }
1936                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1937                 {
1938                         return;
1939                 }
1940                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1941                 {
1942                         return;
1943                 }
1944                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1945                 {
1946                         return;
1947                 }
1948         }
1949         else if(BanCommand(command))
1950         {
1951                 return; // handled by server/command/ipban.qc
1952         }
1953         else if(CommonCommand_macro_command(argc, world, command))
1954         {
1955                 return; // handled by server/command/common.qc
1956         }
1957         else if(GenericCommand(command))
1958         {
1959                 return; // handled by common/command/generic.qc
1960         }
1961         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1962         {
1963                 return; // handled by one of the above GameCommand_* functions
1964         }
1965
1966         // nothing above caught the command, must be invalid
1967         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1968
1969         return;
1970 }