qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2 #include "_mod.qh"
   3
   4 #include <common/effects/all.qh>
   5
   6 #include "banning.qh"
   7 #include "cmd.qh"
   8 #include "common.qh"
   9 #include "getreplies.qh"
  10 #include "radarmap.qh"
  11
  12 #include "../anticheat.qh"
  13 #include "../campaign.qh"
  14 #include "../client.qh"
  15 #include "../player.qh"
  16 #include "../world.qh"
  17 #include "../ipban.qh"
  18 #include "../teamplay.qh"
  19
  20 #include "../bot/api.qh"
  21
  22 #include <server/mutators/_mod.qh>
  23 #include <common/gamemodes/_mod.qh>
  24
  25 #include <common/constants.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/mapinfo.qh>
  28 #include <common/notifications/all.qh>
  29 #include <common/teams.qh>
  30 #include <common/util.qh>
  31
  32 #include <common/monsters/sv_monsters.qh>
  33
  34 //  used by GameCommand_make_mapinfo()
  35 void make_mapinfo_Think(entity this)
  36 {
  37         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  38         {
  39                 LOG_INFO("Done rebuiling mapinfos.");
  40                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  41                 delete(this);
  42         }
  43         else
  44         {
  45                 setthink(this, make_mapinfo_Think);
  46                 this.nextthink = time;
  47         }
  48 }
  49
  50 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  51 void changematchtime(float delta, float mi, float ma)
  52 {
  53         float cur;
  54         float update;
  55         float lim;
  56
  57         if (delta == 0) return;
  58         if (autocvar_timelimit < 0) return;
  59
  60         if (mi <= 10) mi = 10;  // at least ten sec in the future
  61         cur = time - game_starttime;
  62         if (cur > 0) mi += cur; // from current time!
  63
  64         lim = autocvar_timelimit * 60;
  65
  66         if (delta > 0)
  67         {
  68                 if (lim == 0) return; // cannot increase any further
  69                 else if (lim < ma) update = min(ma, lim + delta);
  70                 else                  // already above maximum: FAIL
  71                         return;
  72         }
  73         else
  74         {
  75                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  76                         update = max(mi, ma);
  77                 else if (lim > mi) // above minimum: decrease
  78                         update = max(mi, lim + delta);
  79                 else               // already below minimum: FAIL
  80                         return;
  81         }
  82
  83         cvar_set("timelimit", ftos(update / 60));
  84 }
  85
  86
  87 // =======================
  88 //  Command Sub-Functions
  89 // =======================
  90
  91 void GameCommand_adminmsg(int request, int argc)
  92 {
  93         switch (request)
  94         {
  95                 case CMD_REQUEST_COMMAND:
  96                 {
  97                         entity client;
  98                         float accepted;
  99
 100                         string targets = strreplace(",", " ", argv(1));
 101                         string original_targets = strreplace(" ", ", ", targets);
 102                         string admin_message = argv(2);
 103                         float infobartime = stof(argv(3));
 104
 105                         string successful, t;
 106                         successful = string_null;
 107
 108                         if ((targets) && (admin_message))
 109                         {
 110                                 for ( ; targets; )
 111                                 {
 112                                         t = car(targets);
 113                                         targets = cdr(targets);
 114
 115                                         // Check to see if the player is a valid target
 116                                         client = GetFilteredEntity(t);
 117                                         accepted = VerifyClientEntity(client, true, false);
 118
 119                                         if (accepted <= 0)
 120                                         {
 121                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 122                                                 continue;
 123                                         }
 124
 125                                         // send the centerprint/console print or infomessage
 126                                         if (infobartime)
 127                                         {
 128                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 129                                         }
 130                                         else
 131                                         {
 132                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 133                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 134                                         }
 135
 136                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
 137                                         LOG_TRACE("Message sent to ", playername(client, false));
 138                                         continue;
 139                                 }
 140
 141                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 142                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 143
 144                                 return;
 145                         }
 146                 }
 147
 148                 default:
 149                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 150                 case CMD_REQUEST_USAGE:
 151                 {
 152                         LOG_HELP("Usage:^3 sv_cmd adminmsg clients \"message\" [infobartime]");
 153                         LOG_HELP("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
 154                         LOG_HELP("  If infobartime is provided, the message will be sent to infobar.");
 155                         LOG_HELP("  Otherwise, it will just be sent as a centerprint message.");
 156                         LOG_HELP("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 157                         LOG_HELP("          adminmsg 2,5 \"this message will be a centerprint\"");
 158                         return;
 159                 }
 160         }
 161 }
 162
 163 void GameCommand_allready(int request)
 164 {
 165         switch (request)
 166         {
 167                 case CMD_REQUEST_COMMAND:
 168                 {
 169                         ReadyRestart();
 170                         return;
 171                 }
 172
 173                 default:
 174                 case CMD_REQUEST_USAGE:
 175                 {
 176                         LOG_HELP("Usage:^3 sv_cmd allready");
 177                         LOG_HELP("  No arguments required.");
 178                         return;
 179                 }
 180         }
 181 }
 182
 183 void GameCommand_allspec(int request, int argc)
 184 {
 185         switch (request)
 186         {
 187                 case CMD_REQUEST_COMMAND:
 188                 {
 189                         string reason = argv(1);
 190                         int n = 0;
 191                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 192                                 if (it.caplayer) it.caplayer = 0;
 193                                 PutObserverInServer(it);
 194                                 ++n;
 195                         });
 196                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 197                         else   LOG_INFO("No players found to spectate.");
 198                         return;
 199                 }
 200
 201                 default:
 202                 case CMD_REQUEST_USAGE:
 203                 {
 204                         LOG_HELP("Usage:^3 sv_cmd allspec [reason]");
 205                         LOG_HELP("  Where 'reason' is an optional argument for explanation of allspec command.");
 206                         LOG_HELP("See also: ^2moveplayer, shuffleteams^7");
 207                         return;
 208                 }
 209         }
 210 }
 211
 212 void GameCommand_anticheat(int request, int argc)
 213 {
 214         switch (request)
 215         {
 216                 case CMD_REQUEST_COMMAND:
 217                 {
 218                         entity client = GetIndexedEntity(argc, 1);
 219                         float accepted = VerifyClientEntity(client, false, false);
 220
 221                         if (accepted > 0)
 222                         {
 223                                 anticheat_report_to_eventlog(client);
 224                                 return;
 225                         }
 226                         else
 227                         {
 228                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 229                         }
 230                 }
 231
 232                 default:
 233                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 234                 case CMD_REQUEST_USAGE:
 235                 {
 236                         LOG_HELP("Usage:^3 sv_cmd anticheat client");
 237                         LOG_HELP("  'client' is the entity number or name of the player.");
 238                         return;
 239                 }
 240         }
 241 }
 242
 243 void GameCommand_bbox(int request)
 244 {
 245         switch (request)
 246         {
 247                 case CMD_REQUEST_COMMAND:
 248                 {
 249                         vector size_min = '0 0 0';
 250                         vector size_max = '0 0 0';
 251                         tracebox('1 0 0' * world.absmin.x,
 252                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 253                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 254                                 '1 0 0' * world.absmax.x,
 255                                 MOVE_WORLDONLY,
 256                                 NULL);
 257                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 258
 259                         tracebox('0 1 0' * world.absmin.y,
 260                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 261                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 262                                 '0 1 0' * world.absmax.y,
 263                                 MOVE_WORLDONLY,
 264                                 NULL);
 265                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 266
 267                         tracebox('0 0 1' * world.absmin.z,
 268                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 269                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 270                                 '0 0 1' * world.absmax.z,
 271                                 MOVE_WORLDONLY,
 272                                 NULL);
 273                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 274
 275                         tracebox('1 0 0' * world.absmax.x,
 276                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 277                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 278                                 '1 0 0' * world.absmin.x,
 279                                 MOVE_WORLDONLY,
 280                                 NULL);
 281                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 282
 283                         tracebox('0 1 0' * world.absmax.y,
 284                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 285                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 286                                 '0 1 0' * world.absmin.y,
 287                                 MOVE_WORLDONLY,
 288                                 NULL);
 289                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 290
 291                         tracebox('0 0 1' * world.absmax.z,
 292                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 293                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 294                                 '0 0 1' * world.absmin.z,
 295                                 MOVE_WORLDONLY,
 296                                 NULL);
 297                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 298
 299                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 300                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 301                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 302                         return;
 303                 }
 304
 305                 default:
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         LOG_HELP("Usage:^3 sv_cmd bbox");
 309                         LOG_HELP("  No arguments required.");
 310                         LOG_HELP("See also: ^2gettaginfo, trace^7");
 311                         return;
 312                 }
 313         }
 314 }
 315
 316 void GameCommand_bot_cmd(int request, int argc, string command)
 317 {
 318         switch (request)
 319         {
 320                 case CMD_REQUEST_COMMAND:
 321                 {
 322                         entity bot;
 323
 324                         if (argv(1) == "reset")
 325                         {
 326                                 bot_resetqueues();
 327                                 return;
 328                         }
 329                         else if (argv(1) == "setbots")
 330                         {
 331                                 cvar_settemp("bot_vs_human", "0");
 332                                 cvar_settemp("minplayers", "0");
 333                                 cvar_settemp("minplayers_per_team", "0");
 334                                 cvar_settemp("bot_number", "0");
 335                                 bot_fixcount();
 336                                 cvar_settemp("bot_number", argv(2));
 337                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 338                                 return;
 339                         }
 340                         else if (argv(1) == "load" && argc == 3)
 341                         {
 342                                 float fh, i;
 343                                 string s;
 344                                 fh = fopen(argv(2), FILE_READ);
 345                                 if (fh < 0)
 346                                 {
 347                                         LOG_INFO("cannot open the file");
 348                                         return;
 349                                 }
 350
 351                                 i = 0;
 352                                 while ((s = fgets(fh)))
 353                                 {
 354                                         argc = tokenize_console(s);
 355
 356                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 357                                         {
 358                                                 if (argv(2) == "reset")
 359                                                 {
 360                                                         bot_resetqueues();
 361                                                 }
 362                                                 else if (argv(2) == "setbots")
 363                                                 {
 364                                                         cvar_settemp("bot_vs_human", "0");
 365                                                         cvar_settemp("minplayers", "0");
 366                                                         cvar_settemp("minplayers_per_team", "0");
 367                                                         cvar_settemp("bot_number", "0");
 368                                                         bot_fixcount();
 369                                                         cvar_settemp("bot_number", argv(3));
 370                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 371                                                 }
 372                                                 else
 373                                                 {
 374                                                         if(argv(2) == "*" || argv(2) == "all")
 375                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 376                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 377                                                                 });
 378                                                         else
 379                                                         {
 380                                                                 bot = find_bot_by_number(stof(argv(2)));
 381                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 382                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 383                                                         }
 384                                                 }
 385                                         }
 386                                         else
 387                                         {
 388                                                 localcmd(strcat(s, "\n"));
 389                                         }
 390
 391                                         ++i;
 392                                 }
 393                                 LOG_INFO(ftos(i), " commands read");
 394                                 fclose(fh);
 395                                 return;
 396                         }
 397                         else if (argv(1) == "help")
 398                         {
 399                                 if (argv(2)) bot_cmdhelp(argv(2));
 400                                 else bot_list_commands();
 401                                 return;
 402                         }
 403                         else if (argc >= 3)  // this comes last
 404                         {
 405                                 if(argv(1) == "*" || argv(1) == "all")
 406                                 {
 407                                         int bot_num = 0;
 408                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 409                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 410                                                 bot_num++;
 411                                         });
 412                                         if(bot_num)
 413                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 414                                         return;
 415                                 }
 416                                 else
 417                                 {
 418                                         bot = find_bot_by_number(stof(argv(1)));
 419                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 420                                         if (bot)
 421                                         {
 422                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 423                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 424                                                 return;
 425                                         }
 426                                         else
 427                                         {
 428                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 429                                         }
 430                                 }
 431                         }
 432                 }
 433
 434                 default:
 435                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 436                 case CMD_REQUEST_USAGE:
 437                 {
 438                         LOG_HELP("Usage:^3 sv_cmd bot_cmd client command [argument]");
 439                         LOG_HELP("  'client' can be either the name of the bot or a progressive number (not the entity number!)");
 440                         LOG_HELP("           can also be '*' or 'all' to allow sending the command to all the bots");
 441                         LOG_HELP("  For full list of commands, see bot_cmd help [command].");
 442                         LOG_HELP("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 443                         LOG_HELP("          sv_cmd bot_cmd 1 presskey jump");
 444                         LOG_HELP("          sv_cmd bot_cmd * pause");
 445                         return;
 446                 }
 447         }
 448 }
 449
 450 void GameCommand_cointoss(int request, int argc)
 451 {
 452         switch (request)
 453         {
 454                 case CMD_REQUEST_COMMAND:
 455                 {
 456                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 457                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 458                         string choice = ((random() > 0.5) ? result1 : result2);
 459
 460                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 461                         return;
 462                 }
 463
 464                 default:
 465                 case CMD_REQUEST_USAGE:
 466                 {
 467                         LOG_HELP("Usage:^3 sv_cmd cointoss [result1 result2]");
 468                         LOG_HELP("  Where 'result1' and 'result2' are user created options.");
 469                         return;
 470                 }
 471         }
 472 }
 473
 474 void GameCommand_database(int request, int argc)
 475 {
 476         switch (request)
 477         {
 478                 case CMD_REQUEST_COMMAND:
 479                 {
 480                         if (argc == 3)
 481                         {
 482                                 if (argv(1) == "save")
 483                                 {
 484                                         db_save(ServerProgsDB, argv(2));
 485                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 486                                         return;
 487                                 }
 488                                 else if (argv(1) == "dump")
 489                                 {
 490                                         db_dump(ServerProgsDB, argv(2));
 491                                         LOG_INFO("DB dumped.");  // wtf does this do?
 492                                         return;
 493                                 }
 494                                 else if (argv(1) == "load")
 495                                 {
 496                                         db_close(ServerProgsDB);
 497                                         ServerProgsDB = db_load(argv(2));
 498                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 499                                         return;
 500                                 }
 501                         }
 502                 }
 503
 504                 default:
 505                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 506                 case CMD_REQUEST_USAGE:
 507                 {
 508                         LOG_HELP("Usage:^3 sv_cmd database action filename");
 509                         LOG_HELP("  Where 'action' is the command to complete,");
 510                         LOG_HELP("  and 'filename' is what it acts upon.");
 511                         LOG_HELP("  Full list of commands here: \"save, dump, load.\"");
 512                         return;
 513                 }
 514         }
 515 }
 516
 517 void GameCommand_defer_clear(int request, int argc)
 518 {
 519         switch (request)
 520         {
 521                 case CMD_REQUEST_COMMAND:
 522                 {
 523                         entity client;
 524                         float accepted;
 525
 526                         if (argc >= 2)
 527                         {
 528                                 client = GetIndexedEntity(argc, 1);
 529                                 accepted = VerifyClientEntity(client, true, false);
 530
 531                                 if (accepted > 0)
 532                                 {
 533                                         stuffcmd(client, "defer clear\n");
 534                                         LOG_INFO("defer clear stuffed to ", playername(client, false));
 535                                 }
 536                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 537
 538                                 return;
 539                         }
 540                 }
 541
 542                 default:
 543                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 544                 case CMD_REQUEST_USAGE:
 545                 {
 546                         LOG_HELP("Usage:^3 sv_cmd defer_clear client");
 547                         LOG_HELP("  'client' is the entity number or name of the player.");
 548                         LOG_HELP("See also: ^2defer_clear_all^7");
 549                         return;
 550                 }
 551         }
 552 }
 553
 554 void GameCommand_defer_clear_all(int request)
 555 {
 556         switch (request)
 557         {
 558                 case CMD_REQUEST_COMMAND:
 559                 {
 560                         int n = 0;
 561                         int argc;
 562
 563                         FOREACH_CLIENT(true, {
 564                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 565                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 566                                 ++n;
 567                         });
 568                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 569                         return;
 570                 }
 571
 572                 default:
 573                 case CMD_REQUEST_USAGE:
 574                 {
 575                         LOG_HELP("Usage:^3 sv_cmd defer_clear_all");
 576                         LOG_HELP("  No arguments required.");
 577                         LOG_HELP("See also: ^2defer_clear^7");
 578                         return;
 579                 }
 580         }
 581 }
 582
 583 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
 584 {
 585         switch (request)
 586         {
 587                 case CMD_REQUEST_COMMAND:
 588                 {
 589                         if (argv(1))
 590                         {
 591                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 592                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 593                                 return;
 594                         }
 595                 }
 596
 597                 default:
 598                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 599                 case CMD_REQUEST_USAGE:
 600                 {
 601                         LOG_HELP("Usage:^3 sv_cmd delrec ranking [map]");
 602                         LOG_HELP("  'ranking' is which ranking level to clear up to, ");
 603                         LOG_HELP("  it will clear all records up to nth place.");
 604                         LOG_HELP("  if 'map' is not provided it will use current map.");
 605                         return;
 606                 }
 607         }
 608 }
 609
 610 void print_Effect_Index(int d, string effect_name)
 611 {
 612         // this is inside a function to avoid expanding it on compilation everytime
 613         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
 614         db_put(d, effect_name, "1");
 615 }
 616
 617 void GameCommand_effectindexdump(int request)
 618 {
 619         switch (request)
 620         {
 621                 case CMD_REQUEST_COMMAND:
 622                 {
 623                         float fh, d;
 624                         string s;
 625
 626                         d = db_create();
 627                         LOG_INFO("begin of effects list");
 628
 629                         print_Effect_Index(d, "TE_GUNSHOT");
 630                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
 631                         print_Effect_Index(d, "TE_SPIKE");
 632                         print_Effect_Index(d, "TE_SPIKEQUAD");
 633                         print_Effect_Index(d, "TE_SUPERSPIKE");
 634                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
 635                         print_Effect_Index(d, "TE_WIZSPIKE");
 636                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
 637                         print_Effect_Index(d, "TE_EXPLOSION");
 638                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
 639                         print_Effect_Index(d, "TE_TAREXPLOSION");
 640                         print_Effect_Index(d, "TE_TELEPORT");
 641                         print_Effect_Index(d, "TE_LAVASPLASH");
 642                         print_Effect_Index(d, "TE_SMALLFLASH");
 643                         print_Effect_Index(d, "TE_FLAMEJET");
 644                         print_Effect_Index(d, "EF_FLAME");
 645                         print_Effect_Index(d, "TE_BLOOD");
 646                         print_Effect_Index(d, "TE_SPARK");
 647                         print_Effect_Index(d, "TE_PLASMABURN");
 648                         print_Effect_Index(d, "TE_TEI_G3");
 649                         print_Effect_Index(d, "TE_TEI_SMOKE");
 650                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
 651                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
 652                         print_Effect_Index(d, "EF_STARDUST");
 653                         print_Effect_Index(d, "TR_ROCKET");
 654                         print_Effect_Index(d, "TR_GRENADE");
 655                         print_Effect_Index(d, "TR_BLOOD");
 656                         print_Effect_Index(d, "TR_WIZSPIKE");
 657                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
 658                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
 659                         print_Effect_Index(d, "TR_VORESPIKE");
 660                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
 661                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
 662                         print_Effect_Index(d, "TR_GLOWTRAIL");
 663                         print_Effect_Index(d, "TR_SEEKER");
 664                         print_Effect_Index(d, "SVC_PARTICLE");
 665
 666                         fh = fopen("effectinfo.txt", FILE_READ);
 667                         while ((s = fgets(fh)))
 668                         {
 669                                 tokenize_console(s);
 670                                 if (argv(0) == "effect")
 671                                 {
 672                                         if (db_get(d, argv(1)) != "1")
 673                                         {
 674                                                 int i = _particleeffectnum(argv(1));
 675                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 676                                                 db_put(d, argv(1), "1");
 677                                         }
 678                                 }
 679                         }
 680                         LOG_INFO("end of effects list");
 681
 682                         db_close(d);
 683                         return;
 684                 }
 685
 686                 default:
 687                 case CMD_REQUEST_USAGE:
 688                 {
 689                         LOG_HELP("Usage:^3 sv_cmd effectindexdump");
 690                         LOG_HELP("  No arguments required.");
 691                         return;
 692                 }
 693         }
 694 }
 695
 696 void GameCommand_extendmatchtime(int request)
 697 {
 698         switch (request)
 699         {
 700                 case CMD_REQUEST_COMMAND:
 701                 {
 702                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 703                         return;
 704                 }
 705
 706                 default:
 707                 case CMD_REQUEST_USAGE:
 708                 {
 709                         LOG_HELP("Usage:^3 sv_cmd extendmatchtime");
 710                         LOG_HELP("  No arguments required.");
 711                         LOG_HELP("See also: ^2reducematchtime^7");
 712                         return;
 713                 }
 714         }
 715 }
 716
 717 void GameCommand_gametype(int request, int argc)
 718 {
 719         switch (request)
 720         {
 721                 case CMD_REQUEST_COMMAND:
 722                 {
 723                         if (argv(1) != "")
 724                         {
 725                                 string s = argv(1);
 726                                 Gametype t = MapInfo_Type_FromString(s, false), tsave = MapInfo_CurrentGametype();
 727
 728                                 if (t)
 729                                 {
 730                                         MapInfo_SwitchGameType(t);
 731                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 732                                         if (MapInfo_count > 0)
 733                                         {
 734                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 735                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 736                                                 lsmaps_reply = strzone(getlsmaps());
 737                                                 bprint("Game type successfully switched to ", s, "\n");
 738                                         }
 739                                         else
 740                                         {
 741                                                 bprint("Cannot use this game type: no map for it found\n");
 742                                                 MapInfo_SwitchGameType(tsave);
 743                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 744                                         }
 745                                 }
 746                                 else
 747                                 {
 748                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 749                                 }
 750
 751                                 return;
 752                         }
 753                 }
 754
 755                 default:
 756                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 757                 case CMD_REQUEST_USAGE:
 758                 {
 759                         LOG_HELP("Usage:^3 sv_cmd gametype mode");
 760                         LOG_HELP("  Where 'mode' is the gametype mode to switch to.");
 761                         LOG_HELP("See also: ^2gotomap^7");
 762                         return;
 763                 }
 764         }
 765 }
 766
 767 void GameCommand_gettaginfo(int request, int argc)
 768 {
 769         switch (request)
 770         {
 771                 case CMD_REQUEST_COMMAND:
 772                 {
 773                         entity tmp_entity;
 774                         float i;
 775                         vector v;
 776
 777                         if (argc >= 4)
 778                         {
 779                                 tmp_entity = spawn();
 780                                 if (argv(1) == "w")
 781                                 {
 782                                         .entity weaponentity = weaponentities[0];
 783                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 784                                 }
 785                                 else
 786                                 {
 787                                         precache_model(argv(1));
 788                                         _setmodel(tmp_entity, argv(1));
 789                                 }
 790                                 tmp_entity.frame = stof(argv(2));
 791                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 792                                 else i = gettagindex(tmp_entity, argv(3));
 793                                 if (i)
 794                                 {
 795                                         v = gettaginfo(tmp_entity, i);
 796                                         LOG_INFOF(
 797                                                 "model %s frame %s tag %s index %s parent %s",
 798                                                 tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 799                                         );
 800                                         LOG_INFOF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 801                                         LOG_INFOF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 802                                         LOG_INFOF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 803                                         LOG_INFOF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 804                                         LOG_INFOF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 805                                         if (argc >= 6)
 806                                         {
 807                                                 v.y = -v.y;
 808                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 809                                         }
 810                                 }
 811                                 else
 812                                 {
 813                                         LOG_INFO("bone not found");
 814                                 }
 815
 816                                 delete(tmp_entity);
 817                                 return;
 818                         }
 819                 }
 820
 821                 default:
 822                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 823                 case CMD_REQUEST_USAGE:
 824                 {
 825                         LOG_HELP("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 826                         LOG_HELP("See also: ^2bbox, trace^7");
 827                         return;
 828                 }
 829         }
 830 }
 831
 832 void GameCommand_animbench(int request, int argc)
 833 {
 834         switch (request)
 835         {
 836                 case CMD_REQUEST_COMMAND:
 837                 {
 838                         entity tmp_entity;
 839
 840                         if (argc >= 4)
 841                         {
 842                                 tmp_entity = spawn();
 843                                 if (argv(1) == "w")
 844                                 {
 845                                         .entity weaponentity = weaponentities[0];
 846                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 847                                 }
 848                                 else
 849                                 {
 850                                         precache_model(argv(1));
 851                                         _setmodel(tmp_entity, argv(1));
 852                                 }
 853                                 float f1 = stof(argv(2));
 854                                 float f2 = stof(argv(3));
 855                                 float t0;
 856                                 float t1 = 0;
 857                                 float t2 = 0;
 858                                 float n = 0;
 859
 860                                 while (t1 + t2 < 1)
 861                                 {
 862                                         tmp_entity.frame = f1;
 863                                         t0 = gettime(GETTIME_HIRES);
 864                                         getsurfacepoint(tmp_entity, 0, 0);
 865                                         t1 += gettime(GETTIME_HIRES) - t0;
 866                                         tmp_entity.frame = f2;
 867                                         t0 = gettime(GETTIME_HIRES);
 868                                         getsurfacepoint(tmp_entity, 0, 0);
 869                                         t2 += gettime(GETTIME_HIRES) - t0;
 870                                         n += 1;
 871                                 }
 872                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 873                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 874
 875                                 delete(tmp_entity);
 876                                 return;
 877                         }
 878                 }
 879
 880                 default:
 881                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 882                 case CMD_REQUEST_USAGE:
 883                 {
 884                         LOG_HELP("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 885                         LOG_HELP("See also: ^2bbox, trace^7");
 886                         return;
 887                 }
 888         }
 889 }
 890
 891 void GameCommand_gotomap(int request, int argc)
 892 {
 893         switch (request)
 894         {
 895                 case CMD_REQUEST_COMMAND:
 896                 {
 897                         if (argv(1))
 898                         {
 899                                 LOG_INFO(GotoMap(argv(1)));
 900                                 return;
 901                         }
 902                 }
 903
 904                 default:
 905                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 906                 case CMD_REQUEST_USAGE:
 907                 {
 908                         LOG_HELP("Usage:^3 sv_cmd gotomap map");
 909                         LOG_HELP("  Where 'map' is the *.bsp file to change to.");
 910                         LOG_HELP("See also: ^2gametype^7");
 911                         return;
 912                 }
 913         }
 914 }
 915
 916 void GameCommand_lockteams(int request)
 917 {
 918         switch (request)
 919         {
 920                 case CMD_REQUEST_COMMAND:
 921                 {
 922                         if (teamplay)
 923                         {
 924                                 lockteams = 1;
 925                                 bprint("^1The teams are now locked.\n");
 926                         }
 927                         else
 928                         {
 929                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 930                         }
 931                         return;
 932                 }
 933
 934                 default:
 935                 case CMD_REQUEST_USAGE:
 936                 {
 937                         LOG_HELP("Usage:^3 sv_cmd lockteams");
 938                         LOG_HELP("  No arguments required.");
 939                         LOG_HELP("See also: ^2unlockteams^7");
 940                         return;
 941                 }
 942         }
 943 }
 944
 945 void GameCommand_make_mapinfo(int request)
 946 {
 947         switch (request)
 948         {
 949                 case CMD_REQUEST_COMMAND:
 950                 {
 951                         entity tmp_entity;
 952
 953                         tmp_entity = new(make_mapinfo);
 954                         setthink(tmp_entity, make_mapinfo_Think);
 955                         tmp_entity.nextthink = time;
 956                         MapInfo_Enumerate();
 957                         return;
 958                 }
 959
 960                 default:
 961                 case CMD_REQUEST_USAGE:
 962                 {
 963                         LOG_HELP("Usage:^3 sv_cmd make_mapinfo");
 964                         LOG_HELP("  No arguments required.");
 965                         LOG_HELP("See also: ^2radarmap^7");
 966                         return;
 967                 }
 968         }
 969 }
 970
 971 void GameCommand_moveplayer(int request, int argc)
 972 {
 973         switch (request)
 974         {
 975                 case CMD_REQUEST_COMMAND:
 976                 {
 977                         float accepted;
 978                         entity client;
 979
 980                         string targets = strreplace(",", " ", argv(1));
 981                         string original_targets = strreplace(" ", ", ", targets);
 982                         string destination = argv(2);
 983
 984                         string successful, t;
 985                         successful = string_null;
 986
 987                         // lets see if the target(s) even actually exist.
 988                         if ((targets) && (destination))
 989                         {
 990                                 for ( ; targets; )
 991                                 {
 992                                         t = car(targets);
 993                                         targets = cdr(targets);
 994
 995                                         // Check to see if the player is a valid target
 996                                         client = GetFilteredEntity(t);
 997                                         accepted = VerifyClientEntity(client, false, false);
 998
 999                                         if (accepted <= 0)
1000                                         {
1001                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
1002                                                 continue;
1003                                         }
1004
1005                                         // Where are we putting this player?
1006                                         if (destination == "spec" || destination == "spectator")
1007                                         {
1008                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1009                                                 {
1010                                                         if (client.caplayer) client.caplayer = 0;
1011                                                         PutObserverInServer(client);
1012
1013                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1014                                                 }
1015                                                 else
1016                                                 {
1017                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already spectating.");
1018                                                 }
1019                                                 continue;
1020                                         }
1021                                         else
1022                                         {
1023                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1024                                                 {
1025                                                         if (teamplay)
1026                                                         {
1027                                                                 // set up
1028                                                                 int save = Player_GetForcedTeamIndex(client);
1029                                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1030
1031                                                                 // find the team to move the player to
1032                                                                 int team_num = Team_ColorToTeam(destination);
1033                                                                 entity balance;
1034                                                                 if (team_num == client.team)  // already on the destination team
1035                                                                 {
1036                                                                         // keep the forcing undone
1037                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7."));
1038                                                                         continue;
1039                                                                 }
1040                                                                 else if (team_num == 0)  // auto team
1041                                                                 {
1042                                                                         balance = TeamBalance_CheckAllowedTeams(client);
1043                                                                         team_num = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1044                                                                 }
1045                                                                 else
1046                                                                 {
1047                                                                         balance = TeamBalance_CheckAllowedTeams(client);
1048                                                                 }
1049                                                                 Player_SetForcedTeamIndex(client, save);
1050
1051                                                                 // Check to see if the destination team is even available
1052                                                                 int team_id = Team_TeamToIndex(team_num);
1053                                                                 if (team_id == -1)
1054                                                                 {
1055                                                                         LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.");
1056                                                                         TeamBalance_Destroy(balance);
1057                                                                         return;
1058                                                                 }
1059                                                                 if (!TeamBalance_IsTeamAllowed(balance, team_id))
1060                                                                 {
1061                                                                         LOG_INFOF("Sorry, can't move player to %s team if it doesn't exist.", destination);
1062                                                                         TeamBalance_Destroy(balance);
1063                                                                         return;
1064                                                                 }
1065                                                                 TeamBalance_Destroy(balance);
1066
1067                                                                 // If so, lets continue and finally move the player
1068                                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1069                                                                 if (MoveToTeam(client, team_id, 6))
1070                                                                 {
1071                                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1072                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") has been moved to the ", Team_ColoredFullName(team_id), "^7.");
1073                                                                 }
1074                                                                 else
1075                                                                 {
1076                                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ")");
1077                                                                 }
1078                                                                 continue;
1079                                                         }
1080                                                         else
1081                                                         {
1082                                                                 LOG_INFO("Can't change teams when currently not playing a team game.");
1083                                                                 return;
1084                                                         }
1085                                                 }
1086                                                 else
1087                                                 {
1088                                                         LOG_INFO("Can't change teams if the player isn't in the game.");  // well technically we could, but should we allow that? :P
1089                                                         return;
1090                                                 }
1091                                         }
1092                                 }
1093
1094                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1095                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1096
1097                                 return;  // still correct parameters so return to avoid usage print
1098                         }
1099                 }
1100
1101                 default:
1102                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1103                 case CMD_REQUEST_USAGE:
1104                 {
1105                         LOG_HELP("Usage:^3 sv_cmd moveplayer clients destination");
1106                         LOG_HELP("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
1107                         LOG_HELP("  'destination' is what to send the player to, be it team or spectating");
1108                         LOG_HELP("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"");
1109                         LOG_HELP("Examples: sv_cmd moveplayer 1,3,5 red");
1110                         LOG_HELP("          sv_cmd moveplayer 2 spec");
1111                         LOG_HELP("See also: ^2allspec, shuffleteams^7");
1112                         return;
1113                 }
1114         }
1115 }
1116
1117 void GameCommand_nospectators(int request)
1118 {
1119         switch (request)
1120         {
1121                 case CMD_REQUEST_COMMAND:
1122                 {
1123                         blockSpectators = 1;
1124                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1125                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1126                                 if(!it.caplayer)
1127                                 {
1128                                         CS(it).spectatortime = time;
1129                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1130                                 }
1131                         });
1132                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1133                         return;
1134                 }
1135
1136                 default:
1137                 case CMD_REQUEST_USAGE:
1138                 {
1139                         LOG_HELP("Usage:^3 sv_cmd nospectators");
1140                         LOG_HELP("  No arguments required.");
1141                         return;
1142                 }
1143         }
1144 }
1145
1146 void GameCommand_printstats(int request)
1147 {
1148         switch (request)
1149         {
1150                 case CMD_REQUEST_COMMAND:
1151                 {
1152                         DumpStats(false);
1153                         LOG_INFO("stats dumped.");
1154                         return;
1155                 }
1156
1157                 default:
1158                 case CMD_REQUEST_USAGE:
1159                 {
1160                         LOG_HELP("Usage:^3 sv_cmd printstats");
1161                         LOG_HELP("  No arguments required.");
1162                         return;
1163                 }
1164         }
1165 }
1166
1167 void GameCommand_radarmap(int request, int argc)
1168 {
1169         switch (request)
1170         {
1171                 case CMD_REQUEST_COMMAND:
1172                 {
1173                         if (RadarMap_Make(argc)) return;
1174                 }
1175
1176                 default:
1177                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1178                 case CMD_REQUEST_USAGE:
1179                 {
1180                         LOG_HELP("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1181                         LOG_HELP("  The quality factor Q is roughly proportional to the time taken.");
1182                         LOG_HELP("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1183                         LOG_HELP("See also: ^2make_mapinfo^7");
1184                         return;
1185                 }
1186         }
1187 }
1188
1189 void GameCommand_reducematchtime(int request)
1190 {
1191         switch (request)
1192         {
1193                 case CMD_REQUEST_COMMAND:
1194                 {
1195                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1196                         return;
1197                 }
1198
1199                 default:
1200                 case CMD_REQUEST_USAGE:
1201                 {
1202                         LOG_HELP("Usage:^3 sv_cmd reducematchtime");
1203                         LOG_HELP("  No arguments required.");
1204                         LOG_HELP("See also: ^2extendmatchtime^7");
1205                         return;
1206                 }
1207         }
1208 }
1209
1210 void GameCommand_setbots(int request, int argc)
1211 {
1212         switch (request)
1213         {
1214                 case CMD_REQUEST_COMMAND:
1215                 {
1216                         if (argc >= 2)
1217                         {
1218                                 cvar_settemp("minplayers", "0");
1219                                 cvar_settemp("minplayers_per_team", "0");
1220                                 cvar_settemp("bot_number", argv(1));
1221                                 bot_fixcount();
1222                                 return;
1223                         }
1224                 }
1225
1226                 default:
1227                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1228                 case CMD_REQUEST_USAGE:
1229                 {
1230                         LOG_HELP("Usage:^3 sv_cmd setbots botnumber");
1231                         LOG_HELP("  Where 'botnumber' is the amount of bots to set bot_number cvar to.");
1232                         LOG_HELP("See also: ^2bot_cmd^7");
1233                         return;
1234                 }
1235         }
1236 }
1237
1238 void shuffleteams()
1239 {
1240         if (!teamplay)
1241         {
1242                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1243                 return;
1244         }
1245
1246         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1247                 if (Player_HasRealForcedTeam(it)) {
1248                         // we could theoretically assign forced players to their teams
1249                         // and shuffle the rest to fill the empty spots but in practise
1250                         // either all players or none are gonna have forced teams
1251                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1252                         return;
1253                 }
1254         });
1255
1256         int number_of_teams = 0;
1257         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1258         for (int i = 1; i <= NUM_TEAMS; ++i)
1259         {
1260                 if (TeamBalance_IsTeamAllowed(balance, i))
1261                 {
1262                         number_of_teams = max(i, number_of_teams);
1263                 }
1264         }
1265         TeamBalance_Destroy(balance);
1266
1267         int team_index = 0;
1268         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1269                 int target_team_index = team_index + 1;
1270                 if (Entity_GetTeamIndex(it) != target_team_index)
1271                 {
1272                         MoveToTeam(it, target_team_index, 6);
1273                 }
1274                 team_index = (team_index + 1) % number_of_teams;
1275         });
1276
1277         bprint("Successfully shuffled the players around randomly.\n");
1278 }
1279
1280 void GameCommand_shuffleteams(int request)
1281 {
1282         switch (request)
1283         {
1284                 case CMD_REQUEST_COMMAND:
1285                 {
1286                         if (shuffleteams_on_reset_map)
1287                         {
1288                                 bprint("Players will be shuffled when this round is over.\n");
1289                                 shuffleteams_on_reset_map = true;
1290                         }
1291                         else
1292                                 shuffleteams();
1293                         return;
1294                 }
1295
1296                 default:
1297                 case CMD_REQUEST_USAGE:
1298                 {
1299                         LOG_HELP("Usage:^3 sv_cmd shuffleteams");
1300                         LOG_HELP("  No arguments required.");
1301                         LOG_HELP("See also: ^2moveplayer, allspec^7");
1302                         return;
1303                 }
1304         }
1305 }
1306
1307 void GameCommand_stuffto(int request, int argc)
1308 {
1309         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1310         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1311         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1312
1313 #ifdef STUFFTO_ENABLED
1314                 switch (request)
1315                 {
1316                         case CMD_REQUEST_COMMAND:
1317                         {
1318                                 if (argv(2))
1319                                 {
1320                                         entity client = GetIndexedEntity(argc, 1);
1321                                         float accepted = VerifyClientEntity(client, true, false);
1322
1323                                         if (accepted > 0)
1324                                         {
1325                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1326                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1327                                         }
1328                                         else
1329                                         {
1330                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1331                                         }
1332
1333                                         return;
1334                                 }
1335                         }
1336
1337                         default:
1338                                 LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1339                         case CMD_REQUEST_USAGE:
1340                         {
1341                                 LOG_HELP("Usage:^3 sv_cmd stuffto client \"command\"");
1342                                 LOG_HELP("  'client' is the entity number or name of the player,");
1343                                 LOG_HELP("  and 'command' is the command to be sent to that player.");
1344                                 return;
1345                         }
1346                 }
1347 #else
1348                 if (request)
1349                 {
1350                         LOG_HELP("stuffto command is not enabled on this server.");
1351                         return;
1352                 }
1353 #endif
1354 }
1355
1356 void GameCommand_trace(int request, int argc)
1357 {
1358         switch (request)
1359         {
1360                 case CMD_REQUEST_COMMAND:
1361                 {
1362                         entity e;
1363                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1364                         float i, f, safe, unsafe, dq, dqf;
1365
1366                         switch (argv(1))
1367                         {
1368                                 case "debug":
1369                                 {
1370                                         float hitcount = 0;
1371                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1372                                         float worst_endpos_bug = 0;
1373                                         for ( ; ; )
1374                                         {
1375                                                 org = world.mins;
1376                                                 delta = world.maxs - world.mins;
1377
1378                                                 start.x = org.x + random() * delta.x;
1379                                                 start.y = org.y + random() * delta.y;
1380                                                 start.z = org.z + random() * delta.z;
1381
1382                                                 end.x = org.x + random() * delta.x;
1383                                                 end.y = org.y + random() * delta.y;
1384                                                 end.z = org.z + random() * delta.z;
1385
1386                                                 start = stov(vtos(start));
1387                                                 end = stov(vtos(end));
1388
1389                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1390                                                 if (!trace_startsolid && trace_fraction < 1)
1391                                                 {
1392                                                         p = trace_endpos;
1393                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1394                                                         if (trace_startsolid)
1395                                                         {
1396                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1397                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1398
1399                                                                 // how much do we need to back off?
1400                                                                 safe = 1;
1401                                                                 unsafe = 0;
1402                                                                 for ( ; ; )
1403                                                                 {
1404                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1405                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1406                                                                         if (trace_startsolid)
1407                                                                         {
1408                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1409                                                                                 unsafe = (safe + unsafe) * 0.5;
1410                                                                         }
1411                                                                         else
1412                                                                         {
1413                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1414                                                                                 safe = (safe + unsafe) * 0.5;
1415                                                                         }
1416                                                                 }
1417
1418                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1419                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1420
1421                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1422                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1423                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1424                                                                 if (++hitcount >= 10) break;
1425                                                         }
1426                                                         else
1427                                                         {
1428                                                                 q0 = p;
1429                                                                 dq = 0;
1430                                                                 dqf = 1;
1431                                                                 for ( ; ; )
1432                                                                 {
1433                                                                         q = p + normalize(end - p) * (dq + dqf);
1434                                                                         if (q == q0) break;
1435                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1436                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1437                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1438                                                                         dqf *= 0.5;
1439                                                                         q0 = q;
1440                                                                 }
1441                                                                 if (dq > worst_endpos_bug)
1442                                                                 {
1443                                                                         worst_endpos_bug = dq;
1444                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1445                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1446                                                                         if (++hitcount >= 10) break;
1447                                                                 }
1448                                                         }
1449                                                 }
1450                                         }
1451                                         return;
1452                                 }
1453
1454                                 case "debug2":
1455                                 {
1456                                         e = nextent(NULL);
1457                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1458                                         vv = trace_endpos;
1459                                         if (trace_fraction == 1)
1460                                         {
1461                                                 LOG_INFO("not above ground, aborting");
1462                                                 return;
1463                                         }
1464                                         f = 0;
1465                                         for (i = 0; i < 100000; ++i)
1466                                         {
1467                                                 dv = randomvec();
1468                                                 if (dv.z > 0) dv = -1 * dv;
1469                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1470                                                 if (trace_startsolid) LOG_INFO("bug 1");
1471                                                 if (trace_fraction == 1)
1472                                                 {
1473                                                         if (dv.z < f)
1474                                                         {
1475                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1476                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1477                                                                 f = dv.z;
1478                                                         }
1479                                                 }
1480                                         }
1481                                         LOG_INFO("highest possible dist: ", ftos(f));
1482                                         return;
1483                                 }
1484
1485                                 case "walk":
1486                                 {
1487                                         if (argc == 4 || argc == 5)
1488                                         {
1489                                                 e = nextent(NULL);
1490                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1491                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1492                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1493                                                         LOG_INFO("can walk");
1494                                                 else
1495                                                         LOG_INFO("cannot walk");
1496                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1497                                                 return;
1498                                         }
1499                                 }
1500
1501                                 case "showline":
1502                                 {
1503                                         if (argc == 4)
1504                                         {
1505                                                 vv = stov(argv(2));
1506                                                 dv = stov(argv(3));
1507                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1508                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1509                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1510                                                 return;
1511                                         }
1512                                 }
1513
1514                                         // no default case, just go straight to invalid
1515                         }
1516                 }
1517
1518                 default:
1519                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1520                 case CMD_REQUEST_USAGE:
1521                 {
1522                         LOG_HELP("Usage:^3 sv_cmd trace command [startpos endpos] [endpos_height]");
1523                         LOG_HELP("  Where startpos and endpos are parameters for 'walk' and 'showline' commands,");
1524                         LOG_HELP("  'endpos_height' is an optional parameter for 'walk' command,");
1525                         LOG_HELP("  Full list of commands here: \"debug, debug2, walk, showline.\"");
1526                         LOG_HELP("See also: ^2bbox, gettaginfo^7");
1527                         return;
1528                 }
1529         }
1530 }
1531
1532 void GameCommand_unlockteams(int request)
1533 {
1534         switch (request)
1535         {
1536                 case CMD_REQUEST_COMMAND:
1537                 {
1538                         if (teamplay)
1539                         {
1540                                 lockteams = 0;
1541                                 bprint("^1The teams are now unlocked.\n");
1542                         }
1543                         else
1544                         {
1545                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1546                         }
1547                         return;
1548                 }
1549
1550                 default:
1551                 case CMD_REQUEST_USAGE:
1552                 {
1553                         LOG_HELP("Usage:^3 sv_cmd unlockteams");
1554                         LOG_HELP("  No arguments required.");
1555                         LOG_HELP("See also: ^2lockteams^7");
1556                         return;
1557                 }
1558         }
1559 }
1560
1561 void GameCommand_warp(int request, int argc)
1562 {
1563         switch (request)
1564         {
1565                 case CMD_REQUEST_COMMAND:
1566                 {
1567                         if (autocvar_g_campaign)
1568                         {
1569                                 if (argc >= 2)
1570                                 {
1571                                         CampaignLevelWarp(stof(argv(1)));
1572                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1573                                 }
1574                                 else
1575                                 {
1576                                         CampaignLevelWarp(-1);
1577                                         LOG_INFO("Successfully warped to next campaign level.");
1578                                 }
1579                         }
1580                         else
1581                         {
1582                                 LOG_INFO("Not in campaign, can't level warp");
1583                         }
1584                         return;
1585                 }
1586
1587                 default:
1588                 case CMD_REQUEST_USAGE:
1589                 {
1590                         LOG_HELP("Usage:^3 sv_cmd warp [level]");
1591                         LOG_HELP("  'level' is the level to change campaign mode to.");
1592                         LOG_HELP("  if 'level' is not provided it will change to the next level.");
1593                         return;
1594                 }
1595         }
1596 }
1597
1598 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1599 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1600 void GameCommand_(int request)
1601 {
1602     switch(request)
1603     {
1604         case CMD_REQUEST_COMMAND:
1605         {
1606
1607             return;
1608         }
1609
1610         default:
1611         case CMD_REQUEST_USAGE:
1612         {
1613             LOG_HELP("Usage:^3 sv_cmd ");
1614             LOG_HELP("  No arguments required.");
1615             return;
1616         }
1617     }
1618 }
1619 */
1620
1621
1622 // ==================================
1623 //  Macro system for server commands
1624 // ==================================
1625
1626 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1627 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1628 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1629 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1630 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1631 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1632 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1633 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1634 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1635 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1636 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1637 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1638 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1639 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1640 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1641 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1642 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1643 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1644 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1645 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1646 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1647 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1648 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1649 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1650 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1651 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1652 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1653 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1654 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1655 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1656 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1657
1658 void GameCommand_macro_help()
1659 {
1660         FOREACH(SERVER_COMMANDS, true, { LOG_HELPF("  ^2%s^7: %s", it.m_name, it.m_description); });
1661 }
1662
1663 float GameCommand_macro_command(int argc, string command)
1664 {
1665         string c = strtolower(argv(0));
1666         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1667                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1668                 return true;
1669         });
1670         return false;
1671 }
1672
1673 float GameCommand_macro_usage(int argc)
1674 {
1675         string c = strtolower(argv(1));
1676         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1677                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1678                 return true;
1679         });
1680         return false;
1681 }
1682
1683 void GameCommand_macro_write_aliases(float fh)
1684 {
1685         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1686 }
1687
1688
1689 // =========================================
1690 //  Main Function Called By Engine (sv_cmd)
1691 // =========================================
1692 // If this function exists, game code handles gamecommand instead of the engine code.
1693
1694 void GameCommand(string command)
1695 {
1696         int argc = tokenize_console(command);
1697
1698         // Guide for working with argc arguments by example:
1699         // argc:   1    - 2      - 3     - 4
1700         // argv:   0    - 1      - 2     - 3
1701         // cmd     vote - master - login - password
1702
1703         if (strtolower(argv(0)) == "help")
1704         {
1705                 if (argc == 1)
1706                 {
1707                         LOG_HELP("Server console commands:");
1708                         GameCommand_macro_help();
1709
1710                         LOG_HELP("\nBanning commands:");
1711                         BanCommand_macro_help();
1712
1713                         LOG_HELP("\nCommon networked commands:");
1714                         CommonCommand_macro_help(NULL);
1715
1716                         LOG_HELP("\nGeneric commands shared by all programs:");
1717                         GenericCommand_macro_help();
1718
1719                         LOG_HELP("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n"
1720                                 "For help about a specific command, type sv_cmd help COMMAND");
1721
1722                         return;
1723                 }
1724                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1725                 {
1726                         return;
1727                 }
1728                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1729                 {
1730                         return;
1731                 }
1732                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1733                 {
1734                         return;
1735                 }
1736                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1737                 {
1738                         return;
1739                 }
1740         }
1741         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1742         {
1743                 return;  // handled by a mutator
1744         }
1745         else if (BanCommand(command))
1746         {
1747                 return;  // handled by server/command/ipban.qc
1748         }
1749         else if (CommonCommand_macro_command(argc, NULL, command))
1750         {
1751                 return;  // handled by server/command/common.qc
1752         }
1753         else if (GenericCommand(command))
1754         {
1755                 return;                                        // handled by common/command/generic.qc
1756         }
1757         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1758         {
1759                 return;                                        // handled by one of the above GameCommand_* functions
1760         }
1761
1762         // nothing above caught the command, must be invalid
1763         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1764 }