Merge commit '40b7b8b8f77676', fixes #1937
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / sv_cmd.qc
1 // =====================================================
2 //  Server side game commands code, reworked by Samual
3 //  Last updated: December 29th, 2011
4 // =====================================================
5
6 //  used by GameCommand_make_mapinfo()
7 void make_mapinfo_Think()
8 {
9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
10         {
11                 print("Done rebuiling mapinfos.\n");
12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
13                 remove(self);
14         }
15         else
16         {
17                 self.think = make_mapinfo_Think;
18                 self.nextthink = time;
19         }
20 }
21
22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
23 void changematchtime(float delta, float mi, float ma)
24 {
25         float cur;
26         float new;
27         float lim;
28
29         if(delta == 0)
30                 return;
31         if(autocvar_timelimit < 0)
32                 return;
33
34         if(mi <= 10)
35                 mi = 10; // at least ten sec in the future
36         cur = time - game_starttime;
37         if(cur > 0)
38                 mi += cur; // from current time!
39
40         lim = autocvar_timelimit * 60;
41
42         if(delta > 0)
43         {
44                 if(lim == 0)
45                         return; // cannot increase any further
46                 else if(lim < ma)
47                         new = min(ma, lim + delta);
48                 else // already above maximum: FAIL
49                         return;
50         }
51         else
52         {
53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
54                         new = max(mi, ma);
55                 else if(lim > mi) // above minimum: decrease
56                         new = max(mi, lim + delta);
57                 else // already below minimum: FAIL
58                         return;
59         }
60
61         cvar_set("timelimit", ftos(new / 60));
62 }
63
64
65 // =======================
66 //  Command Sub-Functions
67 // =======================
68
69 void GameCommand_adminmsg(float request, float argc)
70 {
71         switch(request)
72         {
73                 case CMD_REQUEST_COMMAND:
74                 {
75                         entity client;
76                         float accepted;
77
78                         string targets = strreplace(",", " ", argv(1));
79                         string original_targets = strreplace(" ", ", ", targets);
80                         string admin_message = argv(2);
81                         float infobartime = stof(argv(3));
82
83                         string successful, t;
84                         successful = string_null;
85
86                         if((targets) && (admin_message))
87                         {
88                                 for(;targets;)
89                                 {
90                                         t = car(targets); targets = cdr(targets);
91
92                                         // Check to see if the player is a valid target
93                                         client = GetFilteredEntity(t);
94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
95
96                                         if(accepted <= 0)
97                                         {
98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
99                                                 continue;
100                                         }
101
102                                         // send the centerprint/console print or infomessage
103                                         if(infobartime)
104                                         {
105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
106                                         }
107                                         else
108                                         {
109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
111                                         }
112
113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
114                                         dprint("Message sent to ", client.netname, "\n");
115                                         continue;
116                                 }
117
118                                 if(successful)
119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
120                                 else
121                                         print("No players given (", original_targets, ") could receive the message.\n");
122
123                                 return;
124                         }
125                 }
126
127                 default:
128                         print("Incorrect parameters for ^2adminmsg^7\n");
129                 case CMD_REQUEST_USAGE:
130                 {
131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
137                         return;
138                 }
139         }
140 }
141
142 void GameCommand_mobbutcher(float request)
143 {
144         switch(request)
145         {
146                 case CMD_REQUEST_COMMAND:
147                 {
148                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
149                         if(g_invasion) { print("This command doesn't work during an invasion.\n"); return; }
150
151                         float removed_count = 0;
152                         entity head;
153
154                         FOR_EACH_MONSTER(head)
155                         {
156                                 monster_remove(head);
157                                 ++removed_count;
158                         }
159
160                         monsters_total = 0; // reset stats?
161                         monsters_killed = 0;
162
163                         totalspawned = 0;
164
165                         if(removed_count <= 0)
166                                 print("No monsters to kill\n");
167                         else
168                                 printf("Killed %d monster%s\n", removed_count, ((removed_count == 1) ? "" : "s"));
169
170                         return; // never fall through to usage
171                 }
172
173                 default:
174                 case CMD_REQUEST_USAGE:
175                 {
176                         print("\nUsage:^3 sv_cmd mobbutcher\n");
177                         print("  No arguments required.\n");
178                         return;
179                 }
180         }
181 }
182
183 void GameCommand_allready(float request)
184 {
185         switch(request)
186         {
187                 case CMD_REQUEST_COMMAND:
188                 {
189                         ReadyRestart();
190                         return;
191                 }
192
193                 default:
194                 case CMD_REQUEST_USAGE:
195                 {
196                         print("\nUsage:^3 sv_cmd allready\n");
197                         print("  No arguments required.\n");
198                         return;
199                 }
200         }
201 }
202
203 void GameCommand_allspec(float request, float argc)
204 {
205         switch(request)
206         {
207                 case CMD_REQUEST_COMMAND:
208                 {
209                         entity client;
210                         string reason = argv(1);
211                         float i = 0;
212
213                         FOR_EACH_REALPLAYER(client)
214                         {
215                                 self = client;
216                                 PutObserverInServer();
217                                 ++i;
218                         }
219                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
220                         else { print("No players found to spectate.\n"); }
221                         return;
222                 }
223
224                 default:
225                 case CMD_REQUEST_USAGE:
226                 {
227                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
228                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
229                         print("See also: ^2moveplayer, shuffleteams^7\n");
230                         return;
231                 }
232         }
233 }
234
235 void GameCommand_anticheat(float request, float argc)
236 {
237         switch(request)
238         {
239                 case CMD_REQUEST_COMMAND:
240                 {
241                         entity client = GetIndexedEntity(argc, 1);
242                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
243
244                         if(accepted > 0)
245                         {
246                                 self = client;
247                                 anticheat_report();
248                                 return;
249                         }
250                         else
251                         {
252                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
253                         }
254                 }
255
256                 default:
257                         print("Incorrect parameters for ^2anticheat^7\n");
258                 case CMD_REQUEST_USAGE:
259                 {
260                         print("\nUsage:^3 sv_cmd anticheat client\n");
261                         print("  'client' is the entity number or name of the player.\n");
262                         return;
263                 }
264         }
265 }
266
267 void GameCommand_bbox(float request)
268 {
269         switch(request)
270         {
271                 case CMD_REQUEST_COMMAND:
272                 {
273                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
274                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
275                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
276                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
277                         print("Solid bounding box size:");
278
279                         tracebox('1 0 0' * world.absmin_x,
280                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
281                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
282                                                         '1 0 0' * world.absmax_x,
283                                         MOVE_WORLDONLY,
284                                         world);
285                         if(trace_startsolid)
286                                 print(" ", ftos(world.absmin_x));
287                         else
288                                 print(" ", ftos(trace_endpos_x));
289
290                         tracebox('0 1 0' * world.absmin_y,
291                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
292                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
293                                                         '0 1 0' * world.absmax_y,
294                                         MOVE_WORLDONLY,
295                                         world);
296                         if(trace_startsolid)
297                                 print(" ", ftos(world.absmin_y));
298                         else
299                                 print(" ", ftos(trace_endpos_y));
300
301                         tracebox('0 0 1' * world.absmin_z,
302                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
303                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
304                                                         '0 0 1' * world.absmax_z,
305                                         MOVE_WORLDONLY,
306                                         world);
307                         if(trace_startsolid)
308                                 print(" ", ftos(world.absmin_z));
309                         else
310                                 print(" ", ftos(trace_endpos_z));
311
312                         tracebox('1 0 0' * world.absmax_x,
313                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
314                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
315                                                         '1 0 0' * world.absmin_x,
316                                         MOVE_WORLDONLY,
317                                         world);
318                         if(trace_startsolid)
319                                 print(" ", ftos(world.absmax_x));
320                         else
321                                 print(" ", ftos(trace_endpos_x));
322
323                         tracebox('0 1 0' * world.absmax_y,
324                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
325                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
326                                                         '0 1 0' * world.absmin_y,
327                                         MOVE_WORLDONLY,
328                                         world);
329                         if(trace_startsolid)
330                                 print(" ", ftos(world.absmax_y));
331                         else
332                                 print(" ", ftos(trace_endpos_y));
333
334                         tracebox('0 0 1' * world.absmax_z,
335                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
336                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
337                                                         '0 0 1' * world.absmin_z,
338                                         MOVE_WORLDONLY,
339                                         world);
340                         if(trace_startsolid)
341                                 print(" ", ftos(world.absmax_z));
342                         else
343                                 print(" ", ftos(trace_endpos_z));
344
345                         print("\n");
346                         return;
347                 }
348
349                 default:
350                 case CMD_REQUEST_USAGE:
351                 {
352                         print("\nUsage:^3 sv_cmd bbox\n");
353                         print("  No arguments required.\n");
354                         print("See also: ^2gettaginfo, trace^7\n");
355                         return;
356                 }
357         }
358 }
359
360 void GameCommand_bot_cmd(float request, float argc, string command)
361 {
362         switch(request)
363         {
364                 case CMD_REQUEST_COMMAND:
365                 {
366                         entity bot;
367
368                         if(argv(1) == "reset")
369                         {
370                                 bot_resetqueues();
371                                 return;
372                         }
373                         else if(argv(1) == "setbots")
374                         {
375                                 cvar_settemp("bot_vs_human", "0");
376                                 cvar_settemp("minplayers", "0");
377                                 cvar_settemp("bot_number", "0");
378                                 bot_fixcount();
379                                 cvar_settemp("bot_number", argv(2));
380                                 if(!bot_fixcount())
381                                         print("Sorry, could not set requested bot count\n");
382                                 return;
383                         }
384                         else if(argv(1) == "load" && argc == 3)
385                         {
386                                 float fh, i;
387                                 string s;
388                                 fh = fopen(argv(2), FILE_READ);
389                                 if(fh < 0)
390                                 {
391                                         print("cannot open the file\n");
392                                         return;
393                                 }
394
395                                 i = 0;
396                                 while((s = fgets(fh)))
397                                 {
398                                         argc = tokenize_console(s);
399
400                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
401                                         {
402                                                 if(argv(2) == "reset")
403                                                 {
404                                                         bot_resetqueues();
405                                                 }
406                                                 else if(argv(2) == "setbots")
407                                                 {
408                                                         cvar_settemp("bot_vs_human", "0");
409                                                         cvar_settemp("minplayers", "0");
410                                                         cvar_settemp("bot_number", "0");
411                                                         bot_fixcount();
412                                                         cvar_settemp("bot_number", argv(3));
413                                                         if(!bot_fixcount())
414                                                                 print("Sorry, could not set requested bot count\n");
415                                                 }
416                                                 else
417                                                 {
418                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
419                                                         bot = find_bot_by_number(stof(argv(2)));
420                                                         if(bot == world)
421                                                                 bot = find_bot_by_name(argv(2));
422                                                         if(bot)
423                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
424                                                 }
425                                         }
426                                         else
427                                                 localcmd(strcat(s, "\n"));
428
429                                         ++i;
430                                 }
431                                 print(ftos(i), " commands read\n");
432                                 fclose(fh);
433                                 return;
434                         }
435                         else if(argv(1) == "help")
436                         {
437                                 if(argv(2))
438                                         bot_cmdhelp(argv(2));
439                                 else
440                                         bot_list_commands();
441                                 return;
442                         }
443                         else if(argc >= 3) // this comes last
444                         {
445                                 bot = find_bot_by_number(stof(argv(1)));
446                                 if(bot == world)
447                                         bot = find_bot_by_name(argv(1));
448                                 if(bot)
449                                 {
450                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
451                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
452                                         return;
453                                 }
454                                 else
455                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
456                         }
457                 }
458
459                 default:
460                         print("Incorrect parameters for ^2bot_cmd^7\n");
461                 case CMD_REQUEST_USAGE:
462                 {
463                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
464                         print("  'client' can be either the name or entity id of the bot\n");
465                         print("  For full list of commands, see bot_cmd help [command].\n");
466                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
467                         print("          sv_cmd bot_cmd client presskey jump\n");
468                         return;
469                 }
470         }
471 }
472
473 void GameCommand_cointoss(float request, float argc)
474 {
475         switch(request)
476         {
477                 case CMD_REQUEST_COMMAND:
478                 {
479                         entity client;
480                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
481                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
482                         string choice = ((random() > 0.5) ? result1 : result2);
483
484                         FOR_EACH_CLIENT(client)
485                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
486                         bprint(strcat("^3Throwing coin... Result: ", choice));
487                         return;
488                 }
489
490                 default:
491                 case CMD_REQUEST_USAGE:
492                 {
493                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
494                         print("  Where 'result1' and 'result2' are user created options.\n");
495                         return;
496                 }
497         }
498 }
499
500 void GameCommand_database(float request, float argc)
501 {
502         switch(request)
503         {
504                 case CMD_REQUEST_COMMAND:
505                 {
506                         if(argc == 3)
507                         {
508                                 if(argv(1) == "save")
509                                 {
510                                         db_save(ServerProgsDB, argv(2));
511                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
512                                         return;
513                                 }
514                                 else if(argv(1) == "dump")
515                                 {
516                                         db_dump(ServerProgsDB, argv(2));
517                                         print("DB dumped.\n"); // wtf does this do?
518                                         return;
519                                 }
520                                 else if(argv(1) == "load")
521                                 {
522                                         db_close(ServerProgsDB);
523                                         ServerProgsDB = db_load(argv(2));
524                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
525                                         return;
526                                 }
527                         }
528                 }
529
530                 default:
531                         print("Incorrect parameters for ^2database^7\n");
532                 case CMD_REQUEST_USAGE:
533                 {
534                         print("\nUsage:^3 sv_cmd database action filename\n");
535                         print("  Where 'action' is the command to complete,\n");
536                         print("  and 'filename' is what it acts upon.\n");
537                         print("  Full list of commands here: \"save, dump, load.\"\n");
538                         return;
539                 }
540         }
541 }
542
543 void GameCommand_defer_clear(float request, float argc)
544 {
545         switch(request)
546         {
547                 case CMD_REQUEST_COMMAND:
548                 {
549                         entity client;
550                         float accepted;
551
552                         if(argc >= 2)
553                         {
554                                 client = GetIndexedEntity(argc, 1);
555                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
556
557                                 if(accepted > 0)
558                                 {
559                                         stuffcmd(client, "defer clear\n");
560                                         print("defer clear stuffed to ", client.netname, "\n");
561                                 }
562                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
563
564                                 return;
565                         }
566                 }
567
568                 default:
569                         print("Incorrect parameters for ^2defer_clear^7\n");
570                 case CMD_REQUEST_USAGE:
571                 {
572                         print("\nUsage:^3 sv_cmd defer_clear client\n");
573                         print("  'client' is the entity number or name of the player.\n");
574                         print("See also: ^2defer_clear_all^7\n");
575                         return;
576                 }
577         }
578 }
579
580 void GameCommand_defer_clear_all(float request)
581 {
582         switch(request)
583         {
584                 case CMD_REQUEST_COMMAND:
585                 {
586                         entity client;
587                         float i = 0;
588                         float argc;
589
590                         FOR_EACH_CLIENT(client)
591                         {
592                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
593                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
594                                 ++i;
595                         }
596                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
597                         return;
598                 }
599
600                 default:
601                 case CMD_REQUEST_USAGE:
602                 {
603                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
604                         print("  No arguments required.\n");
605                         print("See also: ^2defer_clear^7\n");
606                         return;
607                 }
608         }
609 }
610
611 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
612 {
613         switch(request)
614         {
615                 case CMD_REQUEST_COMMAND:
616                 {
617                         if(argv(1))
618                         {
619                                 if(argv(2))
620                                         race_deleteTime(argv(2), stof(argv(1)));
621                                 else
622                                         race_deleteTime(GetMapname(), stof(argv(1)));
623                                 return;
624                         }
625                 }
626
627                 default:
628                         print("Incorrect parameters for ^2delrec^7\n");
629                 case CMD_REQUEST_USAGE:
630                 {
631                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
632                         print("  'ranking' is which ranking level to clear up to, \n");
633                         print("  it will clear all records up to nth place.\n");
634                         print("  if 'map' is not provided it will use current map.\n");
635                         return;
636                 }
637         }
638 }
639
640 void GameCommand_effectindexdump(float request)
641 {
642         switch(request)
643         {
644                 case CMD_REQUEST_COMMAND:
645                 {
646                         float fh, d;
647                         string s;
648
649                         d = db_create();
650                         print("begin of effects list\n");
651                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
652                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
653                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
654                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
655                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
656                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
657                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
658                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
659                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
660                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
661                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
662                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
663                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
664                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
665                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
666                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
667                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
668                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
669                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
670                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
671                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
672                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
673                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
674                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
675                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
676                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
677                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
678                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
679                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
680                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
681                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
682                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
683                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
684                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
685                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
686                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
687
688                         fh = fopen("effectinfo.txt", FILE_READ);
689                         while((s = fgets(fh)))
690                         {
691                                 tokenize_console(s);
692                                 if(argv(0) == "effect")
693                                 {
694                                         if(db_get(d, argv(1)) != "1")
695                                         {
696                                                 if(particleeffectnum(argv(1)) >= 0)
697                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
698                                                 db_put(d, argv(1), "1");
699                                         }
700                                 }
701                         }
702                         print("end of effects list\n");
703
704                         db_close(d);
705                         return;
706                 }
707
708                 default:
709                 case CMD_REQUEST_USAGE:
710                 {
711                         print("\nUsage:^3 sv_cmd effectindexdump\n");
712                         print("  No arguments required.\n");
713                         return;
714                 }
715         }
716 }
717
718 void GameCommand_extendmatchtime(float request)
719 {
720         switch(request)
721         {
722                 case CMD_REQUEST_COMMAND:
723                 {
724                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
725                         return;
726                 }
727
728                 default:
729                 case CMD_REQUEST_USAGE:
730                 {
731                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
732                         print("  No arguments required.\n");
733                         print("See also: ^2reducematchtime^7\n");
734                         return;
735                 }
736         }
737 }
738
739 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
740 {
741         switch(request)
742         {
743                 case CMD_REQUEST_COMMAND:
744                 {
745                         entity client;
746
747                         for(client = world; (client = find(client, classname, argv(1))); )
748                                 print(etos(client), "\n");
749
750                         return;
751                 }
752
753                 default:
754                         print("Incorrect parameters for ^2find^7\n");
755                 case CMD_REQUEST_USAGE:
756                 {
757                         print("\nUsage:^3 sv_cmd find classname\n");
758                         print("  Where 'classname' is the classname to search for.\n");
759                         return;
760                 }
761         }
762 }
763
764 void GameCommand_gametype(float request, float argc)
765 {
766         switch(request)
767         {
768                 case CMD_REQUEST_COMMAND:
769                 {
770                         if(argv(1) != "")
771                         {
772                                 string s = argv(1);
773                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
774
775                                 if(t)
776                                 {
777                                         MapInfo_SwitchGameType(t);
778                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
779                                         if(MapInfo_count > 0)
780                                         {
781                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
782                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
783                                                 lsmaps_reply = strzone(getlsmaps());
784                                                 bprint("Game type successfully switched to ", s, "\n");
785                                         }
786                                         else
787                                         {
788                                                 bprint("Cannot use this game type: no map for it found\n");
789                                                 MapInfo_SwitchGameType(tsave);
790                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
791                                         }
792                                 }
793                                 else
794                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
795
796                                 return;
797                         }
798                 }
799
800                 default:
801                         print("Incorrect parameters for ^2gametype^7\n");
802                 case CMD_REQUEST_USAGE:
803                 {
804                         print("\nUsage:^3 sv_cmd gametype mode\n");
805                         print("  Where 'mode' is the gametype mode to switch to.\n");
806                         print("See also: ^2gotomap^7\n");
807                         return;
808                 }
809         }
810 }
811
812 void GameCommand_gettaginfo(float request, float argc)
813 {
814         switch(request)
815         {
816                 case CMD_REQUEST_COMMAND:
817                 {
818                         entity tmp_entity;
819                         float i;
820                         vector v;
821
822                         if(argc >= 4)
823                         {
824                                 tmp_entity = spawn();
825                                 if(argv(1) == "w")
826                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
827                                 else
828                                 {
829                                         precache_model(argv(1));
830                                         setmodel(tmp_entity, argv(1));
831                                 }
832                                 tmp_entity.frame = stof(argv(2));
833                                 if(substring(argv(3), 0, 1) == "#")
834                                         i = stof(substring(argv(3), 1, -1));
835                                 else
836                                         i = gettagindex(tmp_entity, argv(3));
837                                 if(i)
838                                 {
839                                         v = gettaginfo(tmp_entity, i);
840                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
841                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
842                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
843                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
844                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
845                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
846                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
847                                         if(argc >= 6)
848                                         {
849                                                 v_y = -v_y;
850                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
851                                         }
852                                 }
853                                 else
854                                         print("bone not found\n");
855
856                                 remove(tmp_entity);
857                                 return;
858                         }
859                 }
860
861                 default:
862                         print("Incorrect parameters for ^2gettaginfo^7\n");
863                 case CMD_REQUEST_USAGE:
864                 {
865                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
866                         print("See also: ^2bbox, trace^7\n");
867                         return;
868                 }
869         }
870 }
871
872 void GameCommand_animbench(float request, float argc)
873 {
874         switch(request)
875         {
876                 case CMD_REQUEST_COMMAND:
877                 {
878                         entity tmp_entity;
879
880                         if(argc >= 4)
881                         {
882                                 tmp_entity = spawn();
883                                 if(argv(1) == "w")
884                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
885                                 else
886                                 {
887                                         precache_model(argv(1));
888                                         setmodel(tmp_entity, argv(1));
889                                 }
890                                 float f1 = stof(argv(2));
891                                 float f2 = stof(argv(3));
892                                 float t0;
893                                 float t1 = 0;
894                                 float t2 = 0;
895                                 float n = 0;
896
897                                 while(t1 + t2 < 1)
898                                 {
899                                         tmp_entity.frame = f1;
900                                         t0 = gettime(GETTIME_HIRES);
901                                         getsurfacepoint(tmp_entity, 0, 0);
902                                         t1 += gettime(GETTIME_HIRES) - t0;
903                                         tmp_entity.frame = f2;
904                                         t0 = gettime(GETTIME_HIRES);
905                                         getsurfacepoint(tmp_entity, 0, 0);
906                                         t2 += gettime(GETTIME_HIRES) - t0;
907                                         n += 1;
908                                 }
909                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
910                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
911
912                                 remove(tmp_entity);
913                                 return;
914                         }
915                 }
916
917                 default:
918                         print("Incorrect parameters for ^2gettaginfo^7\n");
919                 case CMD_REQUEST_USAGE:
920                 {
921                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
922                         print("See also: ^2bbox, trace^7\n");
923                         return;
924                 }
925         }
926 }
927
928 void GameCommand_gotomap(float request, float argc)
929 {
930         switch(request)
931         {
932                 case CMD_REQUEST_COMMAND:
933                 {
934                         if(argv(1))
935                         {
936                                 print(GotoMap(argv(1)), "\n");
937                                 return;
938                         }
939                 }
940
941                 default:
942                         print("Incorrect parameters for ^2gotomap^7\n");
943                 case CMD_REQUEST_USAGE:
944                 {
945                         print("\nUsage:^3 sv_cmd gotomap map\n");
946                         print("  Where 'map' is the *.bsp file to change to.\n");
947                         print("See also: ^2gametype^7\n");
948                         return;
949                 }
950         }
951 }
952
953 void GameCommand_lockteams(float request)
954 {
955         switch(request)
956         {
957                 case CMD_REQUEST_COMMAND:
958                 {
959                         if(teamplay)
960                         {
961                                 lockteams = 1;
962                                 bprint("^1The teams are now locked.\n");
963                         }
964                         else
965                         {
966                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
967                         }
968                         return;
969                 }
970
971                 default:
972                 case CMD_REQUEST_USAGE:
973                 {
974                         print("\nUsage:^3 sv_cmd lockteams\n");
975                         print("  No arguments required.\n");
976                         print("See also: ^2unlockteams^7\n");
977                         return;
978                 }
979         }
980 }
981
982 void GameCommand_make_mapinfo(float request)
983 {
984         switch(request)
985         {
986                 case CMD_REQUEST_COMMAND:
987                 {
988                         entity tmp_entity;
989
990                         tmp_entity = spawn();
991                         tmp_entity.classname = "make_mapinfo";
992                         tmp_entity.think = make_mapinfo_Think;
993                         tmp_entity.nextthink = time;
994                         MapInfo_Enumerate();
995                         return;
996                 }
997
998                 default:
999                 case CMD_REQUEST_USAGE:
1000                 {
1001                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1002                         print("  No arguments required.\n");
1003                         print("See also: ^2radarmap^7\n");
1004                         return;
1005                 }
1006         }
1007 }
1008
1009 void GameCommand_moveplayer(float request, float argc)
1010 {
1011         switch(request)
1012         {
1013                 case CMD_REQUEST_COMMAND:
1014                 {
1015                         float accepted;
1016                         entity client;
1017
1018                         string targets = strreplace(",", " ", argv(1));
1019                         string original_targets = strreplace(" ", ", ", targets);
1020                         string destination = argv(2);
1021
1022                         string successful, t;
1023                         successful = string_null;
1024
1025                         // lets see if the target(s) even actually exist.
1026                         if((targets) && (destination))
1027                         {
1028                                 for(;targets;)
1029                                 {
1030                                         t = car(targets); targets = cdr(targets);
1031
1032                                         // Check to see if the player is a valid target
1033                                         client = GetFilteredEntity(t);
1034                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
1035
1036                                         if(accepted <= 0)
1037                                         {
1038                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1039                                                 continue;
1040                                         }
1041
1042                                         // Where are we putting this player?
1043                                         if(destination == "spec" || destination == "spectator")
1044                                         {
1045                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1046                                                 {
1047                                                         self = client;
1048                                                         PutObserverInServer();
1049
1050                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1051                                                 }
1052                                                 else
1053                                                 {
1054                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1055                                                 }
1056                                                 continue;
1057                                         }
1058                                         else
1059                                         {
1060                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1061                                                 {
1062                                                         if(teamplay)
1063                                                         {
1064                                                                 // set up
1065                                                                 float team_id;
1066                                                                 float save = client.team_forced;
1067                                                                 client.team_forced = 0;
1068
1069                                                                 // find the team to move the player to
1070                                                                 team_id = Team_ColorToTeam(destination);
1071                                                                 if(team_id == client.team) // already on the destination team
1072                                                                 {
1073                                                                         // keep the forcing undone
1074                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1075                                                                         continue;
1076                                                                 }
1077                                                                 else if(team_id == 0)  // auto team
1078                                                                 {
1079                                                                         CheckAllowedTeams(client);
1080                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1081                                                                 }
1082                                                                 else
1083                                                                 {
1084                                                                         CheckAllowedTeams(client);
1085                                                                 }
1086                                                                 client.team_forced = save;
1087
1088                                                                 // Check to see if the destination team is even available
1089                                                                 switch(team_id)
1090                                                                 {
1091                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1092                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1093                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1094                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1095
1096                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1097                                                                 }
1098
1099                                                                 // If so, lets continue and finally move the player
1100                                                                 client.team_forced = 0;
1101                                                                 MoveToTeam(client, team_id, 6);
1102                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1103                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1104                                                                 continue;
1105                                                         }
1106                                                         else
1107                                                         {
1108                                                                 print("Can't change teams when currently not playing a team game.\n");
1109                                                                 return;
1110                                                         }
1111                                                 }
1112                                                 else
1113                                                 {
1114                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1115                                                         return;
1116                                                 }
1117                                         }
1118                                 }
1119
1120                                 if(successful)
1121                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1122                                 else
1123                                         print("No players given (", original_targets, ") are able to move.\n");
1124
1125                                 return; // still correct parameters so return to avoid usage print
1126                         }
1127                 }
1128
1129                 default:
1130                         print("Incorrect parameters for ^2moveplayer^7\n");
1131                 case CMD_REQUEST_USAGE:
1132                 {
1133                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1134                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1135                         print("  'destination' is what to send the player to, be it team or spectating\n");
1136                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1137                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1138                         print("          sv_cmd moveplayer 2 spec \n");
1139                         print("See also: ^2allspec, shuffleteams^7\n");
1140                         return;
1141                 }
1142         }
1143 }
1144
1145 void GameCommand_nospectators(float request)
1146 {
1147         switch(request)
1148         {
1149                 case CMD_REQUEST_COMMAND:
1150                 {
1151                         blockSpectators = 1;
1152                         entity plr;
1153                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1154                         {
1155                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1156                                 {
1157                                         plr.spectatortime = time;
1158                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1159                                 }
1160                         }
1161                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1162                         return;
1163                 }
1164
1165                 default:
1166                 case CMD_REQUEST_USAGE:
1167                 {
1168                         print("\nUsage:^3 sv_cmd nospectators\n");
1169                         print("  No arguments required.\n");
1170                         return;
1171                 }
1172         }
1173 }
1174
1175 void GameCommand_playerdemo(float request, float argc)
1176 {
1177         switch(request)
1178         {
1179                 case CMD_REQUEST_COMMAND:
1180                 {
1181                         if(argv(2) && argv(3))
1182                         {
1183                                 entity client;
1184                                 float i, n, accepted;
1185
1186                                 switch(argv(1))
1187                                 {
1188                                         case "read":
1189                                         {
1190                                                 client = GetIndexedEntity(argc, 2);
1191                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1192
1193                                                 if(accepted <= 0)
1194                                                 {
1195                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1196                                                         return;
1197                                                 }
1198
1199                                                 self = client;
1200                                                 playerdemo_open_read(argv(next_token));
1201                                                 return;
1202                                         }
1203
1204                                         case "write":
1205                                         {
1206                                                 client = GetIndexedEntity(argc, 2);
1207                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1208
1209                                                 if(accepted <= 0)
1210                                                 {
1211                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1212                                                         return;
1213                                                 }
1214
1215                                                 self = client;
1216                                                 playerdemo_open_write(argv(next_token));
1217                                                 return;
1218                                         }
1219
1220                                         case "auto_read_and_write":
1221                                         {
1222                                                 n = GetFilteredNumber(argv(3));
1223                                                 cvar_set("bot_number", ftos(n));
1224
1225                                                 localcmd("wait; wait; wait\n");
1226                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1227
1228                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1229                                                 return;
1230                                         }
1231
1232                                         case "auto_read":
1233                                         {
1234                                                 n = GetFilteredNumber(argv(3));
1235                                                 cvar_set("bot_number", ftos(n));
1236
1237                                                 localcmd("wait; wait; wait\n");
1238                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1239                                                 return;
1240                                         }
1241                                 }
1242                         }
1243                 }
1244
1245                 default:
1246                         print("Incorrect parameters for ^2playerdemo^7\n");
1247                 case CMD_REQUEST_USAGE:
1248                 {
1249                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1250                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1251                         return;
1252                 }
1253         }
1254 }
1255
1256 void GameCommand_printstats(float request)
1257 {
1258         switch(request)
1259         {
1260                 case CMD_REQUEST_COMMAND:
1261                 {
1262                         DumpStats(FALSE);
1263                         print("stats dumped.\n");
1264                         return;
1265                 }
1266
1267                 default:
1268                 case CMD_REQUEST_USAGE:
1269                 {
1270                         print("\nUsage:^3 sv_cmd printstats\n");
1271                         print("  No arguments required.\n");
1272                         return;
1273                 }
1274         }
1275 }
1276
1277 void GameCommand_radarmap(float request, float argc)
1278 {
1279         switch(request)
1280         {
1281                 case CMD_REQUEST_COMMAND:
1282                 {
1283                         if(RadarMap_Make(argc))
1284                                 return;
1285                 }
1286
1287                 default:
1288                         print("Incorrect parameters for ^2radarmap^7\n");
1289                 case CMD_REQUEST_USAGE:
1290                 {
1291                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1292                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1293                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1294                         print("See also: ^2make_mapinfo^7\n");
1295                         return;
1296                 }
1297         }
1298 }
1299
1300 void GameCommand_reducematchtime(float request)
1301 {
1302         switch(request)
1303         {
1304                 case CMD_REQUEST_COMMAND:
1305                 {
1306                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1307                         return;
1308                 }
1309
1310                 default:
1311                 case CMD_REQUEST_USAGE:
1312                 {
1313                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1314                         print("  No arguments required.\n");
1315                         print("See also: ^2extendmatchtime^7\n");
1316                         return;
1317                 }
1318         }
1319 }
1320
1321 void GameCommand_setbots(float request, float argc)
1322 {
1323         switch(request)
1324         {
1325                 case CMD_REQUEST_COMMAND:
1326                 {
1327                         if(argc >= 2)
1328                         {
1329                                 cvar_settemp("minplayers", "0");
1330                                 cvar_settemp("bot_number", argv(1));
1331                                 bot_fixcount();
1332                                 return;
1333                         }
1334                 }
1335
1336                 default:
1337                         print("Incorrect parameters for ^2setbots^7\n");
1338                 case CMD_REQUEST_USAGE:
1339                 {
1340                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1341                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1342                         print("See also: ^2bot_cmd^7\n");
1343                         return;
1344                 }
1345         }
1346 }
1347
1348 void GameCommand_shuffleteams(float request)
1349 {
1350         switch(request)
1351         {
1352                 case CMD_REQUEST_COMMAND:
1353                 {
1354                         if(teamplay)
1355                         {
1356                                 entity tmp_player;
1357                                 float i, x, z, t_teams, t_players, team_color;
1358
1359                                 // count the total amount of players and total amount of teams
1360                                 t_players = 0;
1361                                 t_teams = 0;
1362                                 FOR_EACH_PLAYER(tmp_player)
1363                                 {
1364                                         CheckAllowedTeams(tmp_player);
1365
1366                                         if(c1 >= 0) t_teams = max(1, t_teams);
1367                                         if(c2 >= 0) t_teams = max(2, t_teams);
1368                                         if(c3 >= 0) t_teams = max(3, t_teams);
1369                                         if(c4 >= 0) t_teams = max(4, t_teams);
1370
1371                                         ++t_players;
1372                                 }
1373
1374                                 // build a list of the players in a random order
1375                                 FOR_EACH_PLAYER(tmp_player)
1376                                 {
1377                                         for(;;)
1378                                         {
1379                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1380
1381                                                 if(shuffleteams_players[i])
1382                                                 {
1383                                                         continue; // a player is already assigned to this slot
1384                                                 }
1385                                                 else
1386                                                 {
1387                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1388                                                         break;
1389                                                 }
1390                                         }
1391                                 }
1392
1393                                 // finally, from the list made earlier, re-join the players in different order.
1394                                 for(i = 1; i <= t_teams; ++i)
1395                                 {
1396                                         // find out how many players to assign to this team
1397                                         x = (t_players / t_teams);
1398                                         x = ((i == 1) ? ceil(x) : floor(x));
1399
1400                                         team_color = Team_NumberToTeam(i);
1401
1402                                         // sort through the random list of players made earlier
1403                                         for(z = 1; z <= maxclients; ++z)
1404                                         {
1405                                                 if (!(shuffleteams_teams[i] >= x))
1406                                                 {
1407                                                         if (!(shuffleteams_players[z]))
1408                                                                 continue; // not a player, move on to next random slot
1409
1410                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1411                                                                 self = edict_num(shuffleteams_players[z]);
1412
1413                                                         if(self.team != team_color)
1414                                                                 MoveToTeam(self, team_color, 6);
1415
1416                                                         shuffleteams_players[z] = 0;
1417                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1418                                                 }
1419                                                 else
1420                                                 {
1421                                                         break; // move on to next team
1422                                                 }
1423                                         }
1424                                 }
1425
1426                                 bprint("Successfully shuffled the players around randomly.\n");
1427
1428                                 // clear the buffers now
1429                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1430                                         shuffleteams_players[i] = 0;
1431
1432                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1433                                         shuffleteams_teams[i] = 0;
1434                         }
1435                         else
1436                         {
1437                                 print("Can't shuffle teams when currently not playing a team game.\n");
1438                         }
1439
1440                         return;
1441                 }
1442
1443                 default:
1444                 case CMD_REQUEST_USAGE:
1445                 {
1446                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1447                         print("  No arguments required.\n");
1448                         print("See also: ^2moveplayer, allspec^7\n");
1449                         return;
1450                 }
1451         }
1452 }
1453
1454 void GameCommand_stuffto(float request, float argc)
1455 {
1456         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1457         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1458         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1459
1460         #ifdef STUFFTO_ENABLED
1461         #message "stuffto command enabled"
1462         switch(request)
1463         {
1464                 case CMD_REQUEST_COMMAND:
1465                 {
1466                         if(argv(2))
1467                         {
1468                                 entity client = GetIndexedEntity(argc, 1);
1469                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1470
1471                                 if(accepted > 0)
1472                                 {
1473                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1474                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1475                                 }
1476                                 else
1477                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1478
1479                                 return;
1480                         }
1481                 }
1482
1483                 default:
1484                         print("Incorrect parameters for ^2stuffto^7\n");
1485                 case CMD_REQUEST_USAGE:
1486                 {
1487                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1488                         print("  'client' is the entity number or name of the player,\n");
1489                         print("  and 'command' is the command to be sent to that player.\n");
1490                         return;
1491                 }
1492         }
1493         #else
1494         if(request)
1495         {
1496                 print("stuffto command is not enabled on this server.\n");
1497                 return;
1498         }
1499         #endif
1500 }
1501
1502 void GameCommand_trace(float request, float argc)
1503 {
1504         switch(request)
1505         {
1506                 case CMD_REQUEST_COMMAND:
1507                 {
1508                         entity e;
1509                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1510                         float i, f, safe, unsafe, dq, dqf;
1511
1512                         switch(argv(1))
1513                         {
1514                                 case "debug":
1515                                 {
1516                                         float hitcount = 0;
1517                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1518                                         float worst_endpos_bug = 0;
1519                                         for(;;)
1520                                         {
1521                                                 org = world.mins;
1522                                                 delta = world.maxs - world.mins;
1523
1524                                                 start_x = org_x + random() * delta_x;
1525                                                 start_y = org_y + random() * delta_y;
1526                                                 start_z = org_z + random() * delta_z;
1527
1528                                                 end_x = org_x + random() * delta_x;
1529                                                 end_y = org_y + random() * delta_y;
1530                                                 end_z = org_z + random() * delta_z;
1531
1532                                                 start = stov(vtos(start));
1533                                                 end = stov(vtos(end));
1534
1535                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1536                                                 if(!trace_startsolid && trace_fraction < 1)
1537                                                 {
1538                                                         p = trace_endpos;
1539                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1540                                                         if(trace_startsolid)
1541                                                         {
1542                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1543                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1544
1545                                                                 // how much do we need to back off?
1546                                                                 safe = 1;
1547                                                                 unsafe = 0;
1548                                                                 for(;;)
1549                                                                 {
1550                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1551                                                                         tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1552                                                                         if(trace_startsolid)
1553                                                                         {
1554                                                                                 if((safe + unsafe) * 0.5 == unsafe)
1555                                                                                         break;
1556                                                                                 unsafe = (safe + unsafe) * 0.5;
1557                                                                         }
1558                                                                         else
1559                                                                         {
1560                                                                                 if((safe + unsafe) * 0.5 == safe)
1561                                                                                         break;
1562                                                                                 safe = (safe + unsafe) * 0.5;
1563                                                                         }
1564                                                                 }
1565
1566                                                                 print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1567                                                                 print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1568
1569                                                                 tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1570                                                                 if(trace_startsolid)
1571                                                                         print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1572                                                                 else
1573                                                                         print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1574                                                                 if (++hitcount >= 10)
1575                                                                         break;
1576                                                         }
1577                                                         else
1578                                                         {
1579                                                                 q0 = p;
1580                                                                 dq = 0;
1581                                                                 dqf = 1;
1582                                                                 for(;;)
1583                                                                 {
1584                                                                         q = p + normalize(end - p) * (dq + dqf);
1585                                                                         if(q == q0)
1586                                                                                 break;
1587                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1588                                                                         if(trace_startsolid)
1589                                                                                 error("THIS ONE cannot happen");
1590                                                                         if(trace_fraction > 0)
1591                                                                                 dq += dqf * trace_fraction;
1592                                                                         dqf *= 0.5;
1593                                                                         q0 = q;
1594                                                                 }
1595                                                                 if(dq > worst_endpos_bug)
1596                                                                 {
1597                                                                         worst_endpos_bug = dq;
1598                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1599                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1600                                                                         if (++hitcount >= 10)
1601                                                                                 break;
1602                                                                 }
1603                                                         }
1604                                                 }
1605                                         }
1606                                         return;
1607                                 }
1608
1609                                 case "debug2":
1610                                 {
1611                                         e = nextent(world);
1612                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1613                                         vv = trace_endpos;
1614                                         if(trace_fraction == 1)
1615                                         {
1616                                                 print("not above ground, aborting\n");
1617                                                 return;
1618                                         }
1619                                         f = 0;
1620                                         for(i = 0; i < 100000; ++i)
1621                                         {
1622                                                 dv = randomvec();
1623                                                 if(dv_z > 0)
1624                                                         dv = -1 * dv;
1625                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1626                                                 if(trace_startsolid)
1627                                                         print("bug 1\n");
1628                                                 if(trace_fraction == 1)
1629                                                 if(dv_z < f)
1630                                                 {
1631                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1632                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1633                                                         f = dv_z;
1634                                                 }
1635                                         }
1636                                         print("highest possible dist: ", ftos(f), "\n");
1637                                         return;
1638                                 }
1639
1640                                 case "walk":
1641                                 {
1642                                         if(argc == 4)
1643                                         {
1644                                                 e = nextent(world);
1645                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1646                                                         print("can walk\n");
1647                                                 else
1648                                                         print("cannot walk\n");
1649                                                 return;
1650                                         }
1651                                 }
1652
1653                                 case "showline":
1654                                 {
1655                                         if(argc == 4)
1656                                         {
1657                                                 vv = stov(argv(2));
1658                                                 dv = stov(argv(3));
1659                                                 traceline(vv, dv, MOVE_NORMAL, world);
1660                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1661                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1662                                                 return;
1663                                         }
1664                                 }
1665
1666                                 // no default case, just go straight to invalid
1667                         }
1668                 }
1669
1670                 default:
1671                         print("Incorrect parameters for ^2trace^7\n");
1672                 case CMD_REQUEST_USAGE:
1673                 {
1674                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1675                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1676                         print("See also: ^2bbox, gettaginfo^7\n");
1677                         return;
1678                 }
1679         }
1680 }
1681
1682 void GameCommand_unlockteams(float request)
1683 {
1684         switch(request)
1685         {
1686                 case CMD_REQUEST_COMMAND:
1687                 {
1688                         if(teamplay)
1689                         {
1690                                 lockteams = 0;
1691                                 bprint("^1The teams are now unlocked.\n");
1692                         }
1693                         else
1694                         {
1695                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1696                         }
1697                         return;
1698                 }
1699
1700                 default:
1701                 case CMD_REQUEST_USAGE:
1702                 {
1703                         print("\nUsage:^3 sv_cmd unlockteams\n");
1704                         print("  No arguments required.\n");
1705                         print("See also: ^2lockteams^7\n");
1706                         return;
1707                 }
1708         }
1709 }
1710
1711 void GameCommand_warp(float request, float argc)
1712 {
1713         switch (request)
1714         {
1715                 case CMD_REQUEST_COMMAND:
1716                 {
1717                         if(autocvar_g_campaign)
1718                         {
1719                                 if(argc >= 2)
1720                                 {
1721                                         CampaignLevelWarp(stof(argv(1)));
1722                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1723                                 }
1724                                 else
1725                                 {
1726                                         CampaignLevelWarp(-1);
1727                                         print("Successfully warped to next campaign level.\n");
1728                                 }
1729                         }
1730                         else
1731                                 print("Not in campaign, can't level warp\n");
1732                         return;
1733                 }
1734
1735                 default:
1736                 case CMD_REQUEST_USAGE:
1737                 {
1738                         print("\nUsage:^3 sv_cmd warp [level]\n");
1739                         print("  'level' is the level to change campaign mode to.\n");
1740                         print("  if 'level' is not provided it will change to the next level.\n");
1741                         return;
1742                 }
1743         }
1744 }
1745
1746 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1747 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1748 void GameCommand_(float request)
1749 {
1750         switch(request)
1751         {
1752                 case CMD_REQUEST_COMMAND:
1753                 {
1754
1755                         return;
1756                 }
1757
1758                 default:
1759                 case CMD_REQUEST_USAGE:
1760                 {
1761                         print("\nUsage:^3 sv_cmd \n");
1762                         print("  No arguments required.\n");
1763                         return;
1764                 }
1765         }
1766 }
1767 */
1768
1769
1770 // ==================================
1771 //  Macro system for server commands
1772 // ==================================
1773
1774 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1775 #define SERVER_COMMANDS(request,arguments,command) \
1776         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1777         SERVER_COMMAND("mobbutcher", GameCommand_mobbutcher(request), "Instantly removes all monsters on the map") \
1778         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1779         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1780         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1781         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1782         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1783         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1784         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1785         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1786         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1787         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1788         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1789         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1790         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1791         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1792         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1793         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1794         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1795         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1796         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1797         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1798         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1799         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1800         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1801         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1802         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1803         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1804         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1805         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1806         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1807         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1808         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1809         /* nothing */
1810
1811 void GameCommand_macro_help()
1812 {
1813         #define SERVER_COMMAND(name,function,description) \
1814                 { print("  ^2", name, "^7: ", description, "\n"); }
1815
1816         SERVER_COMMANDS(0, 0, "")
1817         #undef SERVER_COMMAND
1818
1819         return;
1820 }
1821
1822 float GameCommand_macro_command(float argc, string command)
1823 {
1824         #define SERVER_COMMAND(name,function,description) \
1825                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1826
1827         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1828         #undef SERVER_COMMAND
1829
1830         return FALSE;
1831 }
1832
1833 float GameCommand_macro_usage(float argc)
1834 {
1835         #define SERVER_COMMAND(name,function,description) \
1836                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1837
1838         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1839         #undef SERVER_COMMAND
1840
1841         return FALSE;
1842 }
1843
1844 void GameCommand_macro_write_aliases(float fh)
1845 {
1846         #define SERVER_COMMAND(name,function,description) \
1847                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1848
1849         SERVER_COMMANDS(0, 0, "")
1850         #undef SERVER_COMMAND
1851
1852         return;
1853 }
1854
1855
1856 // =========================================
1857 //  Main Function Called By Engine (sv_cmd)
1858 // =========================================
1859 // If this function exists, game code handles gamecommand instead of the engine code.
1860
1861 void GameCommand(string command)
1862 {
1863         float argc = tokenize_console(command);
1864
1865         // Guide for working with argc arguments by example:
1866         // argc:   1    - 2      - 3     - 4
1867         // argv:   0    - 1      - 2     - 3
1868         // cmd     vote - master - login - password
1869
1870         if(strtolower(argv(0)) == "help")
1871         {
1872                 if(argc == 1)
1873                 {
1874                         print("\nServer console commands:\n");
1875                         GameCommand_macro_help();
1876
1877                         print("\nBanning commands:\n");
1878                         BanCommand_macro_help();
1879
1880                         print("\nCommon networked commands:\n");
1881                         CommonCommand_macro_help(world);
1882
1883                         print("\nGeneric commands shared by all programs:\n");
1884                         GenericCommand_macro_help();
1885
1886                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1887                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1888
1889                         return;
1890                 }
1891                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1892                 {
1893                         return;
1894                 }
1895                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1896                 {
1897                         return;
1898                 }
1899                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1900                 {
1901                         return;
1902                 }
1903                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1904                 {
1905                         return;
1906                 }
1907         }
1908         else if(BanCommand(command))
1909         {
1910                 return; // handled by server/command/ipban.qc
1911         }
1912         else if(CommonCommand_macro_command(argc, world, command))
1913         {
1914                 return; // handled by server/command/common.qc
1915         }
1916         else if(GenericCommand(command))
1917         {
1918                 return; // handled by common/command/generic.qc
1919         }
1920         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1921         {
1922                 return; // handled by one of the above GameCommand_* functions
1923         }
1924
1925         // nothing above caught the command, must be invalid
1926         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1927
1928         return;
1929 }