qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if(accepted <= 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_mobbutcher(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
 149                         if(g_invasion) { print("This command doesn't work during an invasion.\n"); return; }
 150
 151                         float removed_count = 0;
 152                         entity head;
 153
 154                         FOR_EACH_MONSTER(head)
 155                         {
 156                                 monster_remove(head);
 157                                 ++removed_count;
 158                         }
 159
 160                         monsters_total = 0; // reset stats?
 161                         monsters_killed = 0;
 162
 163                         totalspawned = 0;
 164
 165                         if(removed_count <= 0)
 166                                 print("No monsters to kill\n");
 167                         else
 168                                 printf("Killed %d monster%s\n", removed_count, ((removed_count == 1) ? "" : "s"));
 169
 170                         return; // never fall through to usage
 171                 }
 172
 173                 default:
 174                 case CMD_REQUEST_USAGE:
 175                 {
 176                         print("\nUsage:^3 sv_cmd mobbutcher\n");
 177                         print("  No arguments required.\n");
 178                         return;
 179                 }
 180         }
 181 }
 182
 183 void GameCommand_allready(float request)
 184 {
 185         switch(request)
 186         {
 187                 case CMD_REQUEST_COMMAND:
 188                 {
 189                         ReadyRestart();
 190                         return;
 191                 }
 192
 193                 default:
 194                 case CMD_REQUEST_USAGE:
 195                 {
 196                         print("\nUsage:^3 sv_cmd allready\n");
 197                         print("  No arguments required.\n");
 198                         return;
 199                 }
 200         }
 201 }
 202
 203 void GameCommand_allspec(float request, float argc)
 204 {
 205         switch(request)
 206         {
 207                 case CMD_REQUEST_COMMAND:
 208                 {
 209                         entity client;
 210                         string reason = argv(1);
 211                         float i = 0;
 212
 213                         FOR_EACH_REALPLAYER(client)
 214                         {
 215                                 self = client;
 216                                 if(self.caplayer)
 217                                         self.caplayer = 0;
 218                                 PutObserverInServer();
 219                                 ++i;
 220                         }
 221                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 222                         else { print("No players found to spectate.\n"); }
 223                         return;
 224                 }
 225
 226                 default:
 227                 case CMD_REQUEST_USAGE:
 228                 {
 229                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 230                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 231                         print("See also: ^2moveplayer, shuffleteams^7\n");
 232                         return;
 233                 }
 234         }
 235 }
 236
 237 void GameCommand_anticheat(float request, float argc)
 238 {
 239         switch(request)
 240         {
 241                 case CMD_REQUEST_COMMAND:
 242                 {
 243                         entity client = GetIndexedEntity(argc, 1);
 244                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 245
 246                         if(accepted > 0)
 247                         {
 248                                 self = client;
 249                                 anticheat_report();
 250                                 return;
 251                         }
 252                         else
 253                         {
 254                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 255                         }
 256                 }
 257
 258                 default:
 259                         print("Incorrect parameters for ^2anticheat^7\n");
 260                 case CMD_REQUEST_USAGE:
 261                 {
 262                         print("\nUsage:^3 sv_cmd anticheat client\n");
 263                         print("  'client' is the entity number or name of the player.\n");
 264                         return;
 265                 }
 266         }
 267 }
 268
 269 void GameCommand_bbox(float request)
 270 {
 271         switch(request)
 272         {
 273                 case CMD_REQUEST_COMMAND:
 274                 {
 275                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 276                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 277                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 278                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 279                         print("Solid bounding box size:");
 280
 281                         tracebox('1 0 0' * world.absmin_x,
 282                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 283                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 284                                                         '1 0 0' * world.absmax_x,
 285                                         MOVE_WORLDONLY,
 286                                         world);
 287                         if(trace_startsolid)
 288                                 print(" ", ftos(world.absmin_x));
 289                         else
 290                                 print(" ", ftos(trace_endpos_x));
 291
 292                         tracebox('0 1 0' * world.absmin_y,
 293                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 294                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 295                                                         '0 1 0' * world.absmax_y,
 296                                         MOVE_WORLDONLY,
 297                                         world);
 298                         if(trace_startsolid)
 299                                 print(" ", ftos(world.absmin_y));
 300                         else
 301                                 print(" ", ftos(trace_endpos_y));
 302
 303                         tracebox('0 0 1' * world.absmin_z,
 304                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 305                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 306                                                         '0 0 1' * world.absmax_z,
 307                                         MOVE_WORLDONLY,
 308                                         world);
 309                         if(trace_startsolid)
 310                                 print(" ", ftos(world.absmin_z));
 311                         else
 312                                 print(" ", ftos(trace_endpos_z));
 313
 314                         tracebox('1 0 0' * world.absmax_x,
 315                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 316                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 317                                                         '1 0 0' * world.absmin_x,
 318                                         MOVE_WORLDONLY,
 319                                         world);
 320                         if(trace_startsolid)
 321                                 print(" ", ftos(world.absmax_x));
 322                         else
 323                                 print(" ", ftos(trace_endpos_x));
 324
 325                         tracebox('0 1 0' * world.absmax_y,
 326                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 327                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 328                                                         '0 1 0' * world.absmin_y,
 329                                         MOVE_WORLDONLY,
 330                                         world);
 331                         if(trace_startsolid)
 332                                 print(" ", ftos(world.absmax_y));
 333                         else
 334                                 print(" ", ftos(trace_endpos_y));
 335
 336                         tracebox('0 0 1' * world.absmax_z,
 337                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 338                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 339                                                         '0 0 1' * world.absmin_z,
 340                                         MOVE_WORLDONLY,
 341                                         world);
 342                         if(trace_startsolid)
 343                                 print(" ", ftos(world.absmax_z));
 344                         else
 345                                 print(" ", ftos(trace_endpos_z));
 346
 347                         print("\n");
 348                         return;
 349                 }
 350
 351                 default:
 352                 case CMD_REQUEST_USAGE:
 353                 {
 354                         print("\nUsage:^3 sv_cmd bbox\n");
 355                         print("  No arguments required.\n");
 356                         print("See also: ^2gettaginfo, trace^7\n");
 357                         return;
 358                 }
 359         }
 360 }
 361
 362 void GameCommand_bot_cmd(float request, float argc, string command)
 363 {
 364         switch(request)
 365         {
 366                 case CMD_REQUEST_COMMAND:
 367                 {
 368                         entity bot;
 369
 370                         if(argv(1) == "reset")
 371                         {
 372                                 bot_resetqueues();
 373                                 return;
 374                         }
 375                         else if(argv(1) == "setbots")
 376                         {
 377                                 cvar_settemp("bot_vs_human", "0");
 378                                 cvar_settemp("minplayers", "0");
 379                                 cvar_settemp("bot_number", "0");
 380                                 bot_fixcount();
 381                                 cvar_settemp("bot_number", argv(2));
 382                                 if(!bot_fixcount())
 383                                         print("Sorry, could not set requested bot count\n");
 384                                 return;
 385                         }
 386                         else if(argv(1) == "load" && argc == 3)
 387                         {
 388                                 float fh, i;
 389                                 string s;
 390                                 fh = fopen(argv(2), FILE_READ);
 391                                 if(fh < 0)
 392                                 {
 393                                         print("cannot open the file\n");
 394                                         return;
 395                                 }
 396
 397                                 i = 0;
 398                                 while((s = fgets(fh)))
 399                                 {
 400                                         argc = tokenize_console(s);
 401
 402                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 403                                         {
 404                                                 if(argv(2) == "reset")
 405                                                 {
 406                                                         bot_resetqueues();
 407                                                 }
 408                                                 else if(argv(2) == "setbots")
 409                                                 {
 410                                                         cvar_settemp("bot_vs_human", "0");
 411                                                         cvar_settemp("minplayers", "0");
 412                                                         cvar_settemp("bot_number", "0");
 413                                                         bot_fixcount();
 414                                                         cvar_settemp("bot_number", argv(3));
 415                                                         if(!bot_fixcount())
 416                                                                 print("Sorry, could not set requested bot count\n");
 417                                                 }
 418                                                 else
 419                                                 {
 420                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 421                                                         bot = find_bot_by_number(stof(argv(2)));
 422                                                         if(bot == world)
 423                                                                 bot = find_bot_by_name(argv(2));
 424                                                         if(bot)
 425                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 426                                                 }
 427                                         }
 428                                         else
 429                                                 localcmd(strcat(s, "\n"));
 430
 431                                         ++i;
 432                                 }
 433                                 print(ftos(i), " commands read\n");
 434                                 fclose(fh);
 435                                 return;
 436                         }
 437                         else if(argv(1) == "help")
 438                         {
 439                                 if(argv(2))
 440                                         bot_cmdhelp(argv(2));
 441                                 else
 442                                         bot_list_commands();
 443                                 return;
 444                         }
 445                         else if(argc >= 3) // this comes last
 446                         {
 447                                 bot = find_bot_by_number(stof(argv(1)));
 448                                 if(bot == world)
 449                                         bot = find_bot_by_name(argv(1));
 450                                 if(bot)
 451                                 {
 452                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 453                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 454                                         return;
 455                                 }
 456                                 else
 457                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 458                         }
 459                 }
 460
 461                 default:
 462                         print("Incorrect parameters for ^2bot_cmd^7\n");
 463                 case CMD_REQUEST_USAGE:
 464                 {
 465                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 466                         print("  'client' can be either the name or entity id of the bot\n");
 467                         print("  For full list of commands, see bot_cmd help [command].\n");
 468                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 469                         print("          sv_cmd bot_cmd client presskey jump\n");
 470                         return;
 471                 }
 472         }
 473 }
 474
 475 void GameCommand_cointoss(float request, float argc)
 476 {
 477         switch(request)
 478         {
 479                 case CMD_REQUEST_COMMAND:
 480                 {
 481                         entity client;
 482                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
 483                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
 484                         string choice = ((random() > 0.5) ? result1 : result2);
 485
 486                         FOR_EACH_CLIENT(client)
 487                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
 488                         bprint(strcat("^3Throwing coin... Result: ", choice));
 489                         return;
 490                 }
 491
 492                 default:
 493                 case CMD_REQUEST_USAGE:
 494                 {
 495                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 496                         print("  Where 'result1' and 'result2' are user created options.\n");
 497                         return;
 498                 }
 499         }
 500 }
 501
 502 void GameCommand_database(float request, float argc)
 503 {
 504         switch(request)
 505         {
 506                 case CMD_REQUEST_COMMAND:
 507                 {
 508                         if(argc == 3)
 509                         {
 510                                 if(argv(1) == "save")
 511                                 {
 512                                         db_save(ServerProgsDB, argv(2));
 513                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 514                                         return;
 515                                 }
 516                                 else if(argv(1) == "dump")
 517                                 {
 518                                         db_dump(ServerProgsDB, argv(2));
 519                                         print("DB dumped.\n"); // wtf does this do?
 520                                         return;
 521                                 }
 522                                 else if(argv(1) == "load")
 523                                 {
 524                                         db_close(ServerProgsDB);
 525                                         ServerProgsDB = db_load(argv(2));
 526                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 527                                         return;
 528                                 }
 529                         }
 530                 }
 531
 532                 default:
 533                         print("Incorrect parameters for ^2database^7\n");
 534                 case CMD_REQUEST_USAGE:
 535                 {
 536                         print("\nUsage:^3 sv_cmd database action filename\n");
 537                         print("  Where 'action' is the command to complete,\n");
 538                         print("  and 'filename' is what it acts upon.\n");
 539                         print("  Full list of commands here: \"save, dump, load.\"\n");
 540                         return;
 541                 }
 542         }
 543 }
 544
 545 void GameCommand_defer_clear(float request, float argc)
 546 {
 547         switch(request)
 548         {
 549                 case CMD_REQUEST_COMMAND:
 550                 {
 551                         entity client;
 552                         float accepted;
 553
 554                         if(argc >= 2)
 555                         {
 556                                 client = GetIndexedEntity(argc, 1);
 557                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 558
 559                                 if(accepted > 0)
 560                                 {
 561                                         stuffcmd(client, "defer clear\n");
 562                                         print("defer clear stuffed to ", client.netname, "\n");
 563                                 }
 564                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 565
 566                                 return;
 567                         }
 568                 }
 569
 570                 default:
 571                         print("Incorrect parameters for ^2defer_clear^7\n");
 572                 case CMD_REQUEST_USAGE:
 573                 {
 574                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 575                         print("  'client' is the entity number or name of the player.\n");
 576                         print("See also: ^2defer_clear_all^7\n");
 577                         return;
 578                 }
 579         }
 580 }
 581
 582 void GameCommand_defer_clear_all(float request)
 583 {
 584         switch(request)
 585         {
 586                 case CMD_REQUEST_COMMAND:
 587                 {
 588                         entity client;
 589                         float i = 0;
 590                         float argc;
 591
 592                         FOR_EACH_CLIENT(client)
 593                         {
 594                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 595                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 596                                 ++i;
 597                         }
 598                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 599                         return;
 600                 }
 601
 602                 default:
 603                 case CMD_REQUEST_USAGE:
 604                 {
 605                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 606                         print("  No arguments required.\n");
 607                         print("See also: ^2defer_clear^7\n");
 608                         return;
 609                 }
 610         }
 611 }
 612
 613 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 614 {
 615         switch(request)
 616         {
 617                 case CMD_REQUEST_COMMAND:
 618                 {
 619                         if(argv(1))
 620                         {
 621                                 if(argv(2))
 622                                         race_deleteTime(argv(2), stof(argv(1)));
 623                                 else
 624                                         race_deleteTime(GetMapname(), stof(argv(1)));
 625                                 return;
 626                         }
 627                 }
 628
 629                 default:
 630                         print("Incorrect parameters for ^2delrec^7\n");
 631                 case CMD_REQUEST_USAGE:
 632                 {
 633                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 634                         print("  'ranking' is which ranking level to clear up to, \n");
 635                         print("  it will clear all records up to nth place.\n");
 636                         print("  if 'map' is not provided it will use current map.\n");
 637                         return;
 638                 }
 639         }
 640 }
 641
 642 void GameCommand_effectindexdump(float request)
 643 {
 644         switch(request)
 645         {
 646                 case CMD_REQUEST_COMMAND:
 647                 {
 648                         float fh, d;
 649                         string s;
 650
 651                         d = db_create();
 652                         print("begin of effects list\n");
 653                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 654                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 655                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 656                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 657                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 658                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 659                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 660                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 661                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 662                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 663                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 664                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 665                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 666                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 667                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 668                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 669                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 670                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 671                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 672                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 673                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 674                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 675                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 676                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 677                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 678                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 679                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 680                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 681                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 682                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 683                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 684                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 685                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 686                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 687                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 688                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 689
 690                         fh = fopen("effectinfo.txt", FILE_READ);
 691                         while((s = fgets(fh)))
 692                         {
 693                                 tokenize_console(s);
 694                                 if(argv(0) == "effect")
 695                                 {
 696                                         if(db_get(d, argv(1)) != "1")
 697                                         {
 698                                                 if(particleeffectnum(argv(1)) >= 0)
 699                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 700                                                 db_put(d, argv(1), "1");
 701                                         }
 702                                 }
 703                         }
 704                         print("end of effects list\n");
 705
 706                         db_close(d);
 707                         return;
 708                 }
 709
 710                 default:
 711                 case CMD_REQUEST_USAGE:
 712                 {
 713                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 714                         print("  No arguments required.\n");
 715                         return;
 716                 }
 717         }
 718 }
 719
 720 void GameCommand_extendmatchtime(float request)
 721 {
 722         switch(request)
 723         {
 724                 case CMD_REQUEST_COMMAND:
 725                 {
 726                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 727                         return;
 728                 }
 729
 730                 default:
 731                 case CMD_REQUEST_USAGE:
 732                 {
 733                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 734                         print("  No arguments required.\n");
 735                         print("See also: ^2reducematchtime^7\n");
 736                         return;
 737                 }
 738         }
 739 }
 740
 741 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 742 {
 743         switch(request)
 744         {
 745                 case CMD_REQUEST_COMMAND:
 746                 {
 747                         entity client;
 748
 749                         for(client = world; (client = find(client, classname, argv(1))); )
 750                                 print(etos(client), "\n");
 751
 752                         return;
 753                 }
 754
 755                 default:
 756                         print("Incorrect parameters for ^2find^7\n");
 757                 case CMD_REQUEST_USAGE:
 758                 {
 759                         print("\nUsage:^3 sv_cmd find classname\n");
 760                         print("  Where 'classname' is the classname to search for.\n");
 761                         return;
 762                 }
 763         }
 764 }
 765
 766 void GameCommand_gametype(float request, float argc)
 767 {
 768         switch(request)
 769         {
 770                 case CMD_REQUEST_COMMAND:
 771                 {
 772                         if(argv(1) != "")
 773                         {
 774                                 string s = argv(1);
 775                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 776
 777                                 if(t)
 778                                 {
 779                                         MapInfo_SwitchGameType(t);
 780                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 781                                         if(MapInfo_count > 0)
 782                                         {
 783                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 784                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 785                                                 lsmaps_reply = strzone(getlsmaps());
 786                                                 bprint("Game type successfully switched to ", s, "\n");
 787                                         }
 788                                         else
 789                                         {
 790                                                 bprint("Cannot use this game type: no map for it found\n");
 791                                                 MapInfo_SwitchGameType(tsave);
 792                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 793                                         }
 794                                 }
 795                                 else
 796                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 797
 798                                 return;
 799                         }
 800                 }
 801
 802                 default:
 803                         print("Incorrect parameters for ^2gametype^7\n");
 804                 case CMD_REQUEST_USAGE:
 805                 {
 806                         print("\nUsage:^3 sv_cmd gametype mode\n");
 807                         print("  Where 'mode' is the gametype mode to switch to.\n");
 808                         print("See also: ^2gotomap^7\n");
 809                         return;
 810                 }
 811         }
 812 }
 813
 814 void GameCommand_gettaginfo(float request, float argc)
 815 {
 816         switch(request)
 817         {
 818                 case CMD_REQUEST_COMMAND:
 819                 {
 820                         entity tmp_entity;
 821                         float i;
 822                         vector v;
 823
 824                         if(argc >= 4)
 825                         {
 826                                 tmp_entity = spawn();
 827                                 if(argv(1) == "w")
 828                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 829                                 else
 830                                 {
 831                                         precache_model(argv(1));
 832                                         setmodel(tmp_entity, argv(1));
 833                                 }
 834                                 tmp_entity.frame = stof(argv(2));
 835                                 if(substring(argv(3), 0, 1) == "#")
 836                                         i = stof(substring(argv(3), 1, -1));
 837                                 else
 838                                         i = gettagindex(tmp_entity, argv(3));
 839                                 if(i)
 840                                 {
 841                                         v = gettaginfo(tmp_entity, i);
 842                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 843                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 844                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 845                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 846                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 847                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 848                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 849                                         if(argc >= 6)
 850                                         {
 851                                                 v_y = -v_y;
 852                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 853                                         }
 854                                 }
 855                                 else
 856                                         print("bone not found\n");
 857
 858                                 remove(tmp_entity);
 859                                 return;
 860                         }
 861                 }
 862
 863                 default:
 864                         print("Incorrect parameters for ^2gettaginfo^7\n");
 865                 case CMD_REQUEST_USAGE:
 866                 {
 867                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 868                         print("See also: ^2bbox, trace^7\n");
 869                         return;
 870                 }
 871         }
 872 }
 873
 874 void GameCommand_animbench(float request, float argc)
 875 {
 876         switch(request)
 877         {
 878                 case CMD_REQUEST_COMMAND:
 879                 {
 880                         entity tmp_entity;
 881
 882                         if(argc >= 4)
 883                         {
 884                                 tmp_entity = spawn();
 885                                 if(argv(1) == "w")
 886                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 887                                 else
 888                                 {
 889                                         precache_model(argv(1));
 890                                         setmodel(tmp_entity, argv(1));
 891                                 }
 892                                 float f1 = stof(argv(2));
 893                                 float f2 = stof(argv(3));
 894                                 float t0;
 895                                 float t1 = 0;
 896                                 float t2 = 0;
 897                                 float n = 0;
 898
 899                                 while(t1 + t2 < 1)
 900                                 {
 901                                         tmp_entity.frame = f1;
 902                                         t0 = gettime(GETTIME_HIRES);
 903                                         getsurfacepoint(tmp_entity, 0, 0);
 904                                         t1 += gettime(GETTIME_HIRES) - t0;
 905                                         tmp_entity.frame = f2;
 906                                         t0 = gettime(GETTIME_HIRES);
 907                                         getsurfacepoint(tmp_entity, 0, 0);
 908                                         t2 += gettime(GETTIME_HIRES) - t0;
 909                                         n += 1;
 910                                 }
 911                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 912                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 913
 914                                 remove(tmp_entity);
 915                                 return;
 916                         }
 917                 }
 918
 919                 default:
 920                         print("Incorrect parameters for ^2gettaginfo^7\n");
 921                 case CMD_REQUEST_USAGE:
 922                 {
 923                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 924                         print("See also: ^2bbox, trace^7\n");
 925                         return;
 926                 }
 927         }
 928 }
 929
 930 void GameCommand_gotomap(float request, float argc)
 931 {
 932         switch(request)
 933         {
 934                 case CMD_REQUEST_COMMAND:
 935                 {
 936                         if(argv(1))
 937                         {
 938                                 print(GotoMap(argv(1)), "\n");
 939                                 return;
 940                         }
 941                 }
 942
 943                 default:
 944                         print("Incorrect parameters for ^2gotomap^7\n");
 945                 case CMD_REQUEST_USAGE:
 946                 {
 947                         print("\nUsage:^3 sv_cmd gotomap map\n");
 948                         print("  Where 'map' is the *.bsp file to change to.\n");
 949                         print("See also: ^2gametype^7\n");
 950                         return;
 951                 }
 952         }
 953 }
 954
 955 void GameCommand_lockteams(float request)
 956 {
 957         switch(request)
 958         {
 959                 case CMD_REQUEST_COMMAND:
 960                 {
 961                         if(teamplay)
 962                         {
 963                                 lockteams = 1;
 964                                 bprint("^1The teams are now locked.\n");
 965                         }
 966                         else
 967                         {
 968                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 969                         }
 970                         return;
 971                 }
 972
 973                 default:
 974                 case CMD_REQUEST_USAGE:
 975                 {
 976                         print("\nUsage:^3 sv_cmd lockteams\n");
 977                         print("  No arguments required.\n");
 978                         print("See also: ^2unlockteams^7\n");
 979                         return;
 980                 }
 981         }
 982 }
 983
 984 void GameCommand_make_mapinfo(float request)
 985 {
 986         switch(request)
 987         {
 988                 case CMD_REQUEST_COMMAND:
 989                 {
 990                         entity tmp_entity;
 991
 992                         tmp_entity = spawn();
 993                         tmp_entity.classname = "make_mapinfo";
 994                         tmp_entity.think = make_mapinfo_Think;
 995                         tmp_entity.nextthink = time;
 996                         MapInfo_Enumerate();
 997                         return;
 998                 }
 999
1000                 default:
1001                 case CMD_REQUEST_USAGE:
1002                 {
1003                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1004                         print("  No arguments required.\n");
1005                         print("See also: ^2radarmap^7\n");
1006                         return;
1007                 }
1008         }
1009 }
1010
1011 void GameCommand_moveplayer(float request, float argc)
1012 {
1013         switch(request)
1014         {
1015                 case CMD_REQUEST_COMMAND:
1016                 {
1017                         float accepted;
1018                         entity client;
1019
1020                         string targets = strreplace(",", " ", argv(1));
1021                         string original_targets = strreplace(" ", ", ", targets);
1022                         string destination = argv(2);
1023
1024                         string successful, t;
1025                         successful = string_null;
1026
1027                         // lets see if the target(s) even actually exist.
1028                         if((targets) && (destination))
1029                         {
1030                                 for(;targets;)
1031                                 {
1032                                         t = car(targets); targets = cdr(targets);
1033
1034                                         // Check to see if the player is a valid target
1035                                         client = GetFilteredEntity(t);
1036                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
1037
1038                                         if(accepted <= 0)
1039                                         {
1040                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1041                                                 continue;
1042                                         }
1043
1044                                         // Where are we putting this player?
1045                                         if(destination == "spec" || destination == "spectator")
1046                                         {
1047                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1048                                                 {
1049                                                         self = client;
1050                                                         if(self.caplayer)
1051                                                                 self.caplayer = 0;
1052                                                         PutObserverInServer();
1053
1054                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1055                                                 }
1056                                                 else
1057                                                 {
1058                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1059                                                 }
1060                                                 continue;
1061                                         }
1062                                         else
1063                                         {
1064                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1065                                                 {
1066                                                         if(teamplay)
1067                                                         {
1068                                                                 // set up
1069                                                                 float team_id;
1070                                                                 float save = client.team_forced;
1071                                                                 client.team_forced = 0;
1072
1073                                                                 // find the team to move the player to
1074                                                                 team_id = Team_ColorToTeam(destination);
1075                                                                 if(team_id == client.team) // already on the destination team
1076                                                                 {
1077                                                                         // keep the forcing undone
1078                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1079                                                                         continue;
1080                                                                 }
1081                                                                 else if(team_id == 0)  // auto team
1082                                                                 {
1083                                                                         CheckAllowedTeams(client);
1084                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1085                                                                 }
1086                                                                 else
1087                                                                 {
1088                                                                         CheckAllowedTeams(client);
1089                                                                 }
1090                                                                 client.team_forced = save;
1091
1092                                                                 // Check to see if the destination team is even available
1093                                                                 switch(team_id)
1094                                                                 {
1095                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1096                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1097                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1098                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1099
1100                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1101                                                                 }
1102
1103                                                                 // If so, lets continue and finally move the player
1104                                                                 client.team_forced = 0;
1105                                                                 MoveToTeam(client, team_id, 6);
1106                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1107                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1108                                                                 continue;
1109                                                         }
1110                                                         else
1111                                                         {
1112                                                                 print("Can't change teams when currently not playing a team game.\n");
1113                                                                 return;
1114                                                         }
1115                                                 }
1116                                                 else
1117                                                 {
1118                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1119                                                         return;
1120                                                 }
1121                                         }
1122                                 }
1123
1124                                 if(successful)
1125                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1126                                 else
1127                                         print("No players given (", original_targets, ") are able to move.\n");
1128
1129                                 return; // still correct parameters so return to avoid usage print
1130                         }
1131                 }
1132
1133                 default:
1134                         print("Incorrect parameters for ^2moveplayer^7\n");
1135                 case CMD_REQUEST_USAGE:
1136                 {
1137                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1138                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1139                         print("  'destination' is what to send the player to, be it team or spectating\n");
1140                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1141                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1142                         print("          sv_cmd moveplayer 2 spec \n");
1143                         print("See also: ^2allspec, shuffleteams^7\n");
1144                         return;
1145                 }
1146         }
1147 }
1148
1149 void GameCommand_nospectators(float request)
1150 {
1151         switch(request)
1152         {
1153                 case CMD_REQUEST_COMMAND:
1154                 {
1155                         blockSpectators = 1;
1156                         entity plr;
1157                         FOR_EACH_REALCLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1158                         {
1159                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1160                                 if(!plr.caplayer)
1161                                 {
1162                                         plr.spectatortime = time;
1163                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1164                                 }
1165                         }
1166                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1167                         return;
1168                 }
1169
1170                 default:
1171                 case CMD_REQUEST_USAGE:
1172                 {
1173                         print("\nUsage:^3 sv_cmd nospectators\n");
1174                         print("  No arguments required.\n");
1175                         return;
1176                 }
1177         }
1178 }
1179
1180 void GameCommand_playerdemo(float request, float argc)
1181 {
1182         switch(request)
1183         {
1184                 case CMD_REQUEST_COMMAND:
1185                 {
1186                         if(argv(2) && argv(3))
1187                         {
1188                                 entity client;
1189                                 float i, n, accepted;
1190
1191                                 switch(argv(1))
1192                                 {
1193                                         case "read":
1194                                         {
1195                                                 client = GetIndexedEntity(argc, 2);
1196                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1197
1198                                                 if(accepted <= 0)
1199                                                 {
1200                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1201                                                         return;
1202                                                 }
1203
1204                                                 self = client;
1205                                                 playerdemo_open_read(argv(next_token));
1206                                                 return;
1207                                         }
1208
1209                                         case "write":
1210                                         {
1211                                                 client = GetIndexedEntity(argc, 2);
1212                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1213
1214                                                 if(accepted <= 0)
1215                                                 {
1216                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1217                                                         return;
1218                                                 }
1219
1220                                                 self = client;
1221                                                 playerdemo_open_write(argv(next_token));
1222                                                 return;
1223                                         }
1224
1225                                         case "auto_read_and_write":
1226                                         {
1227                                                 n = GetFilteredNumber(argv(3));
1228                                                 cvar_set("bot_number", ftos(n));
1229
1230                                                 localcmd("wait; wait; wait\n");
1231                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1232
1233                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1234                                                 return;
1235                                         }
1236
1237                                         case "auto_read":
1238                                         {
1239                                                 n = GetFilteredNumber(argv(3));
1240                                                 cvar_set("bot_number", ftos(n));
1241
1242                                                 localcmd("wait; wait; wait\n");
1243                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1244                                                 return;
1245                                         }
1246                                 }
1247                         }
1248                 }
1249
1250                 default:
1251                         print("Incorrect parameters for ^2playerdemo^7\n");
1252                 case CMD_REQUEST_USAGE:
1253                 {
1254                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1255                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1256                         return;
1257                 }
1258         }
1259 }
1260
1261 void GameCommand_printstats(float request)
1262 {
1263         switch(request)
1264         {
1265                 case CMD_REQUEST_COMMAND:
1266                 {
1267                         DumpStats(FALSE);
1268                         print("stats dumped.\n");
1269                         return;
1270                 }
1271
1272                 default:
1273                 case CMD_REQUEST_USAGE:
1274                 {
1275                         print("\nUsage:^3 sv_cmd printstats\n");
1276                         print("  No arguments required.\n");
1277                         return;
1278                 }
1279         }
1280 }
1281
1282 void GameCommand_radarmap(float request, float argc)
1283 {
1284         switch(request)
1285         {
1286                 case CMD_REQUEST_COMMAND:
1287                 {
1288                         if(RadarMap_Make(argc))
1289                                 return;
1290                 }
1291
1292                 default:
1293                         print("Incorrect parameters for ^2radarmap^7\n");
1294                 case CMD_REQUEST_USAGE:
1295                 {
1296                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1297                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1298                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1299                         print("See also: ^2make_mapinfo^7\n");
1300                         return;
1301                 }
1302         }
1303 }
1304
1305 void GameCommand_reducematchtime(float request)
1306 {
1307         switch(request)
1308         {
1309                 case CMD_REQUEST_COMMAND:
1310                 {
1311                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1312                         return;
1313                 }
1314
1315                 default:
1316                 case CMD_REQUEST_USAGE:
1317                 {
1318                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1319                         print("  No arguments required.\n");
1320                         print("See also: ^2extendmatchtime^7\n");
1321                         return;
1322                 }
1323         }
1324 }
1325
1326 void GameCommand_setbots(float request, float argc)
1327 {
1328         switch(request)
1329         {
1330                 case CMD_REQUEST_COMMAND:
1331                 {
1332                         if(argc >= 2)
1333                         {
1334                                 cvar_settemp("minplayers", "0");
1335                                 cvar_settemp("bot_number", argv(1));
1336                                 bot_fixcount();
1337                                 return;
1338                         }
1339                 }
1340
1341                 default:
1342                         print("Incorrect parameters for ^2setbots^7\n");
1343                 case CMD_REQUEST_USAGE:
1344                 {
1345                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1346                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1347                         print("See also: ^2bot_cmd^7\n");
1348                         return;
1349                 }
1350         }
1351 }
1352
1353 void GameCommand_shuffleteams(float request)
1354 {
1355         switch(request)
1356         {
1357                 case CMD_REQUEST_COMMAND:
1358                 {
1359                         if(teamplay)
1360                         {
1361                                 entity tmp_player;
1362                                 float i, x, z, t_teams, t_players, team_color;
1363
1364                                 // count the total amount of players and total amount of teams
1365                                 t_players = 0;
1366                                 t_teams = 0;
1367                                 FOR_EACH_PLAYER(tmp_player)
1368                                 {
1369                                         CheckAllowedTeams(tmp_player);
1370
1371                                         if(c1 >= 0) t_teams = max(1, t_teams);
1372                                         if(c2 >= 0) t_teams = max(2, t_teams);
1373                                         if(c3 >= 0) t_teams = max(3, t_teams);
1374                                         if(c4 >= 0) t_teams = max(4, t_teams);
1375
1376                                         ++t_players;
1377                                 }
1378
1379                                 // build a list of the players in a random order
1380                                 FOR_EACH_PLAYER(tmp_player)
1381                                 {
1382                                         for(;;)
1383                                         {
1384                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1385
1386                                                 if(shuffleteams_players[i])
1387                                                 {
1388                                                         continue; // a player is already assigned to this slot
1389                                                 }
1390                                                 else
1391                                                 {
1392                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1393                                                         break;
1394                                                 }
1395                                         }
1396                                 }
1397
1398                                 // finally, from the list made earlier, re-join the players in different order.
1399                                 for(i = 1; i <= t_teams; ++i)
1400                                 {
1401                                         // find out how many players to assign to this team
1402                                         x = (t_players / t_teams);
1403                                         x = ((i == 1) ? ceil(x) : floor(x));
1404
1405                                         team_color = Team_NumberToTeam(i);
1406
1407                                         // sort through the random list of players made earlier
1408                                         for(z = 1; z <= maxclients; ++z)
1409                                         {
1410                                                 if (!(shuffleteams_teams[i] >= x))
1411                                                 {
1412                                                         if (!(shuffleteams_players[z]))
1413                                                                 continue; // not a player, move on to next random slot
1414
1415                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1416                                                                 self = edict_num(shuffleteams_players[z]);
1417
1418                                                         if(self.team != team_color)
1419                                                                 MoveToTeam(self, team_color, 6);
1420
1421                                                         shuffleteams_players[z] = 0;
1422                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1423                                                 }
1424                                                 else
1425                                                 {
1426                                                         break; // move on to next team
1427                                                 }
1428                                         }
1429                                 }
1430
1431                                 bprint("Successfully shuffled the players around randomly.\n");
1432
1433                                 // clear the buffers now
1434                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1435                                         shuffleteams_players[i] = 0;
1436
1437                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1438                                         shuffleteams_teams[i] = 0;
1439                         }
1440                         else
1441                         {
1442                                 print("Can't shuffle teams when currently not playing a team game.\n");
1443                         }
1444
1445                         return;
1446                 }
1447
1448                 default:
1449                 case CMD_REQUEST_USAGE:
1450                 {
1451                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1452                         print("  No arguments required.\n");
1453                         print("See also: ^2moveplayer, allspec^7\n");
1454                         return;
1455                 }
1456         }
1457 }
1458
1459 void GameCommand_stuffto(float request, float argc)
1460 {
1461         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1462         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1463         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1464
1465         #ifdef STUFFTO_ENABLED
1466         #message "stuffto command enabled"
1467         switch(request)
1468         {
1469                 case CMD_REQUEST_COMMAND:
1470                 {
1471                         if(argv(2))
1472                         {
1473                                 entity client = GetIndexedEntity(argc, 1);
1474                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1475
1476                                 if(accepted > 0)
1477                                 {
1478                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1479                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1480                                 }
1481                                 else
1482                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1483
1484                                 return;
1485                         }
1486                 }
1487
1488                 default:
1489                         print("Incorrect parameters for ^2stuffto^7\n");
1490                 case CMD_REQUEST_USAGE:
1491                 {
1492                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1493                         print("  'client' is the entity number or name of the player,\n");
1494                         print("  and 'command' is the command to be sent to that player.\n");
1495                         return;
1496                 }
1497         }
1498         #else
1499         if(request)
1500         {
1501                 print("stuffto command is not enabled on this server.\n");
1502                 return;
1503         }
1504         #endif
1505 }
1506
1507 void GameCommand_trace(float request, float argc)
1508 {
1509         switch(request)
1510         {
1511                 case CMD_REQUEST_COMMAND:
1512                 {
1513                         entity e;
1514                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1515                         float i, f, safe, unsafe, dq, dqf;
1516
1517                         switch(argv(1))
1518                         {
1519                                 case "debug":
1520                                 {
1521                                         float hitcount = 0;
1522                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1523                                         float worst_endpos_bug = 0;
1524                                         for(;;)
1525                                         {
1526                                                 org = world.mins;
1527                                                 delta = world.maxs - world.mins;
1528
1529                                                 start_x = org_x + random() * delta_x;
1530                                                 start_y = org_y + random() * delta_y;
1531                                                 start_z = org_z + random() * delta_z;
1532
1533                                                 end_x = org_x + random() * delta_x;
1534                                                 end_y = org_y + random() * delta_y;
1535                                                 end_z = org_z + random() * delta_z;
1536
1537                                                 start = stov(vtos(start));
1538                                                 end = stov(vtos(end));
1539
1540                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1541                                                 if(!trace_startsolid && trace_fraction < 1)
1542                                                 {
1543                                                         p = trace_endpos;
1544                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1545                                                         if(trace_startsolid)
1546                                                         {
1547                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1548                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1549
1550                                                                 // how much do we need to back off?
1551                                                                 safe = 1;
1552                                                                 unsafe = 0;
1553                                                                 for(;;)
1554                                                                 {
1555                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1556                                                                         tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1557                                                                         if(trace_startsolid)
1558                                                                         {
1559                                                                                 if((safe + unsafe) * 0.5 == unsafe)
1560                                                                                         break;
1561                                                                                 unsafe = (safe + unsafe) * 0.5;
1562                                                                         }
1563                                                                         else
1564                                                                         {
1565                                                                                 if((safe + unsafe) * 0.5 == safe)
1566                                                                                         break;
1567                                                                                 safe = (safe + unsafe) * 0.5;
1568                                                                         }
1569                                                                 }
1570
1571                                                                 print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1572                                                                 print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1573
1574                                                                 tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1575                                                                 if(trace_startsolid)
1576                                                                         print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1577                                                                 else
1578                                                                         print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1579                                                                 if (++hitcount >= 10)
1580                                                                         break;
1581                                                         }
1582                                                         else
1583                                                         {
1584                                                                 q0 = p;
1585                                                                 dq = 0;
1586                                                                 dqf = 1;
1587                                                                 for(;;)
1588                                                                 {
1589                                                                         q = p + normalize(end - p) * (dq + dqf);
1590                                                                         if(q == q0)
1591                                                                                 break;
1592                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1593                                                                         if(trace_startsolid)
1594                                                                                 error("THIS ONE cannot happen");
1595                                                                         if(trace_fraction > 0)
1596                                                                                 dq += dqf * trace_fraction;
1597                                                                         dqf *= 0.5;
1598                                                                         q0 = q;
1599                                                                 }
1600                                                                 if(dq > worst_endpos_bug)
1601                                                                 {
1602                                                                         worst_endpos_bug = dq;
1603                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1604                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1605                                                                         if (++hitcount >= 10)
1606                                                                                 break;
1607                                                                 }
1608                                                         }
1609                                                 }
1610                                         }
1611                                         return;
1612                                 }
1613
1614                                 case "debug2":
1615                                 {
1616                                         e = nextent(world);
1617                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1618                                         vv = trace_endpos;
1619                                         if(trace_fraction == 1)
1620                                         {
1621                                                 print("not above ground, aborting\n");
1622                                                 return;
1623                                         }
1624                                         f = 0;
1625                                         for(i = 0; i < 100000; ++i)
1626                                         {
1627                                                 dv = randomvec();
1628                                                 if(dv_z > 0)
1629                                                         dv = -1 * dv;
1630                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1631                                                 if(trace_startsolid)
1632                                                         print("bug 1\n");
1633                                                 if(trace_fraction == 1)
1634                                                 if(dv_z < f)
1635                                                 {
1636                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1637                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1638                                                         f = dv_z;
1639                                                 }
1640                                         }
1641                                         print("highest possible dist: ", ftos(f), "\n");
1642                                         return;
1643                                 }
1644
1645                                 case "walk":
1646                                 {
1647                                         if(argc == 4)
1648                                         {
1649                                                 e = nextent(world);
1650                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1651                                                         print("can walk\n");
1652                                                 else
1653                                                         print("cannot walk\n");
1654                                                 return;
1655                                         }
1656                                 }
1657
1658                                 case "showline":
1659                                 {
1660                                         if(argc == 4)
1661                                         {
1662                                                 vv = stov(argv(2));
1663                                                 dv = stov(argv(3));
1664                                                 traceline(vv, dv, MOVE_NORMAL, world);
1665                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1666                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1667                                                 return;
1668                                         }
1669                                 }
1670
1671                                 // no default case, just go straight to invalid
1672                         }
1673                 }
1674
1675                 default:
1676                         print("Incorrect parameters for ^2trace^7\n");
1677                 case CMD_REQUEST_USAGE:
1678                 {
1679                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1680                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1681                         print("See also: ^2bbox, gettaginfo^7\n");
1682                         return;
1683                 }
1684         }
1685 }
1686
1687 void GameCommand_unlockteams(float request)
1688 {
1689         switch(request)
1690         {
1691                 case CMD_REQUEST_COMMAND:
1692                 {
1693                         if(teamplay)
1694                         {
1695                                 lockteams = 0;
1696                                 bprint("^1The teams are now unlocked.\n");
1697                         }
1698                         else
1699                         {
1700                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1701                         }
1702                         return;
1703                 }
1704
1705                 default:
1706                 case CMD_REQUEST_USAGE:
1707                 {
1708                         print("\nUsage:^3 sv_cmd unlockteams\n");
1709                         print("  No arguments required.\n");
1710                         print("See also: ^2lockteams^7\n");
1711                         return;
1712                 }
1713         }
1714 }
1715
1716 void GameCommand_warp(float request, float argc)
1717 {
1718         switch (request)
1719         {
1720                 case CMD_REQUEST_COMMAND:
1721                 {
1722                         if(autocvar_g_campaign)
1723                         {
1724                                 if(argc >= 2)
1725                                 {
1726                                         CampaignLevelWarp(stof(argv(1)));
1727                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1728                                 }
1729                                 else
1730                                 {
1731                                         CampaignLevelWarp(-1);
1732                                         print("Successfully warped to next campaign level.\n");
1733                                 }
1734                         }
1735                         else
1736                                 print("Not in campaign, can't level warp\n");
1737                         return;
1738                 }
1739
1740                 default:
1741                 case CMD_REQUEST_USAGE:
1742                 {
1743                         print("\nUsage:^3 sv_cmd warp [level]\n");
1744                         print("  'level' is the level to change campaign mode to.\n");
1745                         print("  if 'level' is not provided it will change to the next level.\n");
1746                         return;
1747                 }
1748         }
1749 }
1750
1751 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1752 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1753 void GameCommand_(float request)
1754 {
1755         switch(request)
1756         {
1757                 case CMD_REQUEST_COMMAND:
1758                 {
1759
1760                         return;
1761                 }
1762
1763                 default:
1764                 case CMD_REQUEST_USAGE:
1765                 {
1766                         print("\nUsage:^3 sv_cmd \n");
1767                         print("  No arguments required.\n");
1768                         return;
1769                 }
1770         }
1771 }
1772 */
1773
1774
1775 // ==================================
1776 //  Macro system for server commands
1777 // ==================================
1778
1779 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1780 #define SERVER_COMMANDS(request,arguments,command) \
1781         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1782         SERVER_COMMAND("mobbutcher", GameCommand_mobbutcher(request), "Instantly removes all monsters on the map") \
1783         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1784         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1785         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1786         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1787         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1788         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1789         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1790         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1791         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1792         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1793         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1794         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1795         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1796         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1797         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1798         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1799         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1800         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1801         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1802         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1803         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1804         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1805         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1806         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1807         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1808         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1809         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1810         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1811         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1812         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1813         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1814         /* nothing */
1815
1816 void GameCommand_macro_help()
1817 {
1818         #define SERVER_COMMAND(name,function,description) \
1819                 { print("  ^2", name, "^7: ", description, "\n"); }
1820
1821         SERVER_COMMANDS(0, 0, "")
1822         #undef SERVER_COMMAND
1823
1824         return;
1825 }
1826
1827 float GameCommand_macro_command(float argc, string command)
1828 {
1829         #define SERVER_COMMAND(name,function,description) \
1830                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1831
1832         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1833         #undef SERVER_COMMAND
1834
1835         return FALSE;
1836 }
1837
1838 float GameCommand_macro_usage(float argc)
1839 {
1840         #define SERVER_COMMAND(name,function,description) \
1841                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1842
1843         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1844         #undef SERVER_COMMAND
1845
1846         return FALSE;
1847 }
1848
1849 void GameCommand_macro_write_aliases(float fh)
1850 {
1851         #define SERVER_COMMAND(name,function,description) \
1852                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1853
1854         SERVER_COMMANDS(0, 0, "")
1855         #undef SERVER_COMMAND
1856
1857         return;
1858 }
1859
1860
1861 // =========================================
1862 //  Main Function Called By Engine (sv_cmd)
1863 // =========================================
1864 // If this function exists, game code handles gamecommand instead of the engine code.
1865
1866 void GameCommand(string command)
1867 {
1868         float argc = tokenize_console(command);
1869
1870         // Guide for working with argc arguments by example:
1871         // argc:   1    - 2      - 3     - 4
1872         // argv:   0    - 1      - 2     - 3
1873         // cmd     vote - master - login - password
1874
1875         if(strtolower(argv(0)) == "help")
1876         {
1877                 if(argc == 1)
1878                 {
1879                         print("\nServer console commands:\n");
1880                         GameCommand_macro_help();
1881
1882                         print("\nBanning commands:\n");
1883                         BanCommand_macro_help();
1884
1885                         print("\nCommon networked commands:\n");
1886                         CommonCommand_macro_help(world);
1887
1888                         print("\nGeneric commands shared by all programs:\n");
1889                         GenericCommand_macro_help();
1890
1891                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1892                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1893
1894                         return;
1895                 }
1896                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1897                 {
1898                         return;
1899                 }
1900                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1901                 {
1902                         return;
1903                 }
1904                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1905                 {
1906                         return;
1907                 }
1908                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1909                 {
1910                         return;
1911                 }
1912         }
1913         else if(BanCommand(command))
1914         {
1915                 return; // handled by server/command/ipban.qc
1916         }
1917         else if(CommonCommand_macro_command(argc, world, command))
1918         {
1919                 return; // handled by server/command/common.qc
1920         }
1921         else if(GenericCommand(command))
1922         {
1923                 return; // handled by common/command/generic.qc
1924         }
1925         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1926         {
1927                 return; // handled by one of the above GameCommand_* functions
1928         }
1929
1930         // nothing above caught the command, must be invalid
1931         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1932
1933         return;
1934 }