f99ed23b25240463a3960e496fd0e6542d00c8ac
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / sv_cmd.qc
1 #include "sv_cmd.qh"
2 #include "_mod.qh"
3
4 #include "banning.qh"
5 #include "cmd.qh"
6 #include "common.qh"
7 #include "getreplies.qh"
8 #include "radarmap.qh"
9
10 #include "../anticheat.qh"
11 #include "../campaign.qh"
12 #include "../client.qh"
13 #include "../player.qh"
14 #include "../g_world.qh"
15 #include "../ipban.qh"
16 #include "../playerdemo.qh"
17 #include "../teamplay.qh"
18
19 #include "../bot/api.qh"
20
21 #include "../mutators/_mod.qh"
22
23 #include <common/constants.qh>
24 #include <common/net_linked.qh>
25 #include <common/mapinfo.qh>
26 #include <common/notifications/all.qh>
27 #include <common/teams.qh>
28 #include <common/util.qh>
29
30 #include <common/monsters/sv_monsters.qh>
31
32
33 void PutObserverInServer(entity this);
34
35 // =====================================================
36 //  Server side game commands code, reworked by Samual
37 // =====================================================
38
39 //  used by GameCommand_make_mapinfo()
40 void make_mapinfo_Think(entity this)
41 {
42         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
43         {
44                 LOG_INFO("Done rebuiling mapinfos.\n");
45                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
46                 delete(this);
47         }
48         else
49         {
50                 setthink(this, make_mapinfo_Think);
51                 this.nextthink = time;
52         }
53 }
54
55 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
56 void changematchtime(float delta, float mi, float ma)
57 {
58         float cur;
59         float update;
60         float lim;
61
62         if (delta == 0) return;
63         if (autocvar_timelimit < 0) return;
64
65         if (mi <= 10) mi = 10;  // at least ten sec in the future
66         cur = time - game_starttime;
67         if (cur > 0) mi += cur; // from current time!
68
69         lim = autocvar_timelimit * 60;
70
71         if (delta > 0)
72         {
73                 if (lim == 0) return; // cannot increase any further
74                 else if (lim < ma) update = min(ma, lim + delta);
75                 else                  // already above maximum: FAIL
76                         return;
77         }
78         else
79         {
80                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
81                         update = max(mi, ma);
82                 else if (lim > mi) // above minimum: decrease
83                         update = max(mi, lim + delta);
84                 else               // already below minimum: FAIL
85                         return;
86         }
87
88         cvar_set("timelimit", ftos(update / 60));
89 }
90
91
92 // =======================
93 //  Command Sub-Functions
94 // =======================
95
96 void GameCommand_adminmsg(float request, float argc)
97 {
98         switch (request)
99         {
100                 case CMD_REQUEST_COMMAND:
101                 {
102                         entity client;
103                         float accepted;
104
105                         string targets = strreplace(",", " ", argv(1));
106                         string original_targets = strreplace(" ", ", ", targets);
107                         string admin_message = argv(2);
108                         float infobartime = stof(argv(3));
109
110                         string successful, t;
111                         successful = string_null;
112
113                         if ((targets) && (admin_message))
114                         {
115                                 for ( ; targets; )
116                                 {
117                                         t = car(targets);
118                                         targets = cdr(targets);
119
120                                         // Check to see if the player is a valid target
121                                         client = GetFilteredEntity(t);
122                                         accepted = VerifyClientEntity(client, true, false);
123
124                                         if (accepted <= 0)
125                                         {
126                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
127                                                 continue;
128                                         }
129
130                                         // send the centerprint/console print or infomessage
131                                         if (infobartime)
132                                         {
133                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
134                                         }
135                                         else
136                                         {
137                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
138                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
139                                         }
140
141                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
142                                         LOG_TRACE("Message sent to ", client.netname);
143                                         continue;
144                                 }
145
146                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
147                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.\n");
148
149                                 return;
150                         }
151                 }
152
153                 default:
154                         LOG_INFO("Incorrect parameters for ^2adminmsg^7\n");
155                 case CMD_REQUEST_USAGE:
156                 {
157                         LOG_INFO("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
158                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
159                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.\n");
160                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.\n");
161                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
162                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"\n");
163                         return;
164                 }
165         }
166 }
167
168 void GameCommand_allready(float request)
169 {
170         switch (request)
171         {
172                 case CMD_REQUEST_COMMAND:
173                 {
174                         ReadyRestart();
175                         return;
176                 }
177
178                 default:
179                 case CMD_REQUEST_USAGE:
180                 {
181                         LOG_INFO("\nUsage:^3 sv_cmd allready\n");
182                         LOG_INFO("  No arguments required.\n");
183                         return;
184                 }
185         }
186 }
187
188 void GameCommand_allspec(float request, float argc)
189 {
190         switch (request)
191         {
192                 case CMD_REQUEST_COMMAND:
193                 {
194                         string reason = argv(1);
195                         int n = 0;
196                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
197                                 if (it.caplayer) it.caplayer = 0;
198                                 PutObserverInServer(it);
199                                 ++n;
200                         ));
201                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
202                         else   LOG_INFO("No players found to spectate.\n");
203                         return;
204                 }
205
206                 default:
207                 case CMD_REQUEST_USAGE:
208                 {
209                         LOG_INFO("\nUsage:^3 sv_cmd allspec [reason]\n");
210                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.\n");
211                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7\n");
212                         return;
213                 }
214         }
215 }
216
217 void GameCommand_anticheat(float request, float argc)
218 {
219         switch (request)
220         {
221                 case CMD_REQUEST_COMMAND:
222                 {
223                         entity client = GetIndexedEntity(argc, 1);
224                         float accepted = VerifyClientEntity(client, false, false);
225
226                         if (accepted > 0)
227                         {
228                                 anticheat_report_to_eventlog(client);
229                                 return;
230                         }
231                         else
232                         {
233                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
234                         }
235                 }
236
237                 default:
238                         LOG_INFO("Incorrect parameters for ^2anticheat^7\n");
239                 case CMD_REQUEST_USAGE:
240                 {
241                         LOG_INFO("\nUsage:^3 sv_cmd anticheat client\n");
242                         LOG_INFO("  'client' is the entity number or name of the player.\n");
243                         return;
244                 }
245         }
246 }
247
248 void GameCommand_bbox(float request)
249 {
250         switch (request)
251         {
252                 case CMD_REQUEST_COMMAND:
253                 {
254                         LOG_INFO("Original size: ", ftos(world.absmin.x), " ", ftos(world.absmin.y), " ", ftos(world.absmin.z));
255                         LOG_INFO(" ", ftos(world.absmax.x), " ", ftos(world.absmax.y), " ", ftos(world.absmax.z), "\n");
256                         LOG_INFO("Currently set size: ", ftos(world.mins.x), " ", ftos(world.mins.y), " ", ftos(world.mins.z));
257                         LOG_INFO(" ", ftos(world.maxs.x), " ", ftos(world.maxs.y), " ", ftos(world.maxs.z), "\n");
258                         LOG_INFO("Solid bounding box size:");
259
260                         tracebox('1 0 0' * world.absmin.x,
261                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
262                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
263                                 '1 0 0' * world.absmax.x,
264                                 MOVE_WORLDONLY,
265                                 NULL);
266                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmin.x));
267                         else LOG_INFO(" ", ftos(trace_endpos.x));
268
269                         tracebox('0 1 0' * world.absmin.y,
270                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
271                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
272                                 '0 1 0' * world.absmax.y,
273                                 MOVE_WORLDONLY,
274                                 NULL);
275                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmin.y));
276                         else LOG_INFO(" ", ftos(trace_endpos.y));
277
278                         tracebox('0 0 1' * world.absmin.z,
279                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
280                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
281                                 '0 0 1' * world.absmax.z,
282                                 MOVE_WORLDONLY,
283                                 NULL);
284                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmin.z));
285                         else LOG_INFO(" ", ftos(trace_endpos.z));
286
287                         tracebox('1 0 0' * world.absmax.x,
288                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
289                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
290                                 '1 0 0' * world.absmin.x,
291                                 MOVE_WORLDONLY,
292                                 NULL);
293                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmax.x));
294                         else LOG_INFO(" ", ftos(trace_endpos.x));
295
296                         tracebox('0 1 0' * world.absmax.y,
297                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
298                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
299                                 '0 1 0' * world.absmin.y,
300                                 MOVE_WORLDONLY,
301                                 NULL);
302                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmax.y));
303                         else LOG_INFO(" ", ftos(trace_endpos.y));
304
305                         tracebox('0 0 1' * world.absmax.z,
306                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
307                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
308                                 '0 0 1' * world.absmin.z,
309                                 MOVE_WORLDONLY,
310                                 NULL);
311                         if (trace_startsolid) LOG_INFO(" ", ftos(world.absmax.z));
312                         else LOG_INFO(" ", ftos(trace_endpos.z));
313
314                         LOG_INFO("\n");
315                         return;
316                 }
317
318                 default:
319                 case CMD_REQUEST_USAGE:
320                 {
321                         LOG_INFO("\nUsage:^3 sv_cmd bbox\n");
322                         LOG_INFO("  No arguments required.\n");
323                         LOG_INFO("See also: ^2gettaginfo, trace^7\n");
324                         return;
325                 }
326         }
327 }
328
329 void GameCommand_bot_cmd(float request, float argc, string command)
330 {
331         switch (request)
332         {
333                 case CMD_REQUEST_COMMAND:
334                 {
335                         entity bot;
336
337                         if (argv(1) == "reset")
338                         {
339                                 bot_resetqueues();
340                                 return;
341                         }
342                         else if (argv(1) == "setbots")
343                         {
344                                 cvar_settemp("bot_vs_human", "0");
345                                 cvar_settemp("minplayers", "0");
346                                 cvar_settemp("bot_number", "0");
347                                 bot_fixcount();
348                                 cvar_settemp("bot_number", argv(2));
349                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count\n");
350                                 return;
351                         }
352                         else if (argv(1) == "load" && argc == 3)
353                         {
354                                 float fh, i;
355                                 string s;
356                                 fh = fopen(argv(2), FILE_READ);
357                                 if (fh < 0)
358                                 {
359                                         LOG_INFO("cannot open the file\n");
360                                         return;
361                                 }
362
363                                 i = 0;
364                                 while ((s = fgets(fh)))
365                                 {
366                                         argc = tokenize_console(s);
367
368                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
369                                         {
370                                                 if (argv(2) == "reset")
371                                                 {
372                                                         bot_resetqueues();
373                                                 }
374                                                 else if (argv(2) == "setbots")
375                                                 {
376                                                         cvar_settemp("bot_vs_human", "0");
377                                                         cvar_settemp("minplayers", "0");
378                                                         cvar_settemp("bot_number", "0");
379                                                         bot_fixcount();
380                                                         cvar_settemp("bot_number", argv(3));
381                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count\n");
382                                                 }
383                                                 else
384                                                 {
385                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
386                                                         bot = find_bot_by_number(stof(argv(2)));
387                                                         if (bot == NULL) bot = find_bot_by_name(argv(2));
388                                                         if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
389                                                 }
390                                         }
391                                         else
392                                         {
393                                                 localcmd(strcat(s, "\n"));
394                                         }
395
396                                         ++i;
397                                 }
398                                 LOG_INFO(ftos(i), " commands read\n");
399                                 fclose(fh);
400                                 return;
401                         }
402                         else if (argv(1) == "help")
403                         {
404                                 if (argv(2)) bot_cmdhelp(argv(2));
405                                 else bot_list_commands();
406                                 return;
407                         }
408                         else if (argc >= 3)  // this comes last
409                         {
410                                 bot = find_bot_by_number(stof(argv(1)));
411                                 if (bot == NULL) bot = find_bot_by_name(argv(1));
412                                 if (bot)
413                                 {
414                                         LOG_INFO(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
415                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
416                                         return;
417                                 }
418                                 else
419                                 {
420                                         LOG_INFO(strcat("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?\n"));  // don't return so that usage is shown
421                                 }
422                         }
423                 }
424
425                 default:
426                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7\n");
427                 case CMD_REQUEST_USAGE:
428                 {
429                         LOG_INFO("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
430                         LOG_INFO("  'client' can be either the name or entity id of the bot\n");
431                         LOG_INFO("  For full list of commands, see bot_cmd help [command].\n");
432                         LOG_INFO("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
433                         LOG_INFO("          sv_cmd bot_cmd client presskey jump\n");
434                         return;
435                 }
436         }
437 }
438
439 void GameCommand_cointoss(float request, float argc)
440 {
441         switch (request)
442         {
443                 case CMD_REQUEST_COMMAND:
444                 {
445                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
446                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
447                         string choice = ((random() > 0.5) ? result1 : result2);
448
449                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
450                         return;
451                 }
452
453                 default:
454                 case CMD_REQUEST_USAGE:
455                 {
456                         LOG_INFO("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
457                         LOG_INFO("  Where 'result1' and 'result2' are user created options.\n");
458                         return;
459                 }
460         }
461 }
462
463 void GameCommand_database(float request, float argc)
464 {
465         switch (request)
466         {
467                 case CMD_REQUEST_COMMAND:
468                 {
469                         if (argc == 3)
470                         {
471                                 if (argv(1) == "save")
472                                 {
473                                         db_save(ServerProgsDB, argv(2));
474                                         LOG_INFO(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
475                                         return;
476                                 }
477                                 else if (argv(1) == "dump")
478                                 {
479                                         db_dump(ServerProgsDB, argv(2));
480                                         LOG_INFO("DB dumped.\n");  // wtf does this do?
481                                         return;
482                                 }
483                                 else if (argv(1) == "load")
484                                 {
485                                         db_close(ServerProgsDB);
486                                         ServerProgsDB = db_load(argv(2));
487                                         LOG_INFO(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
488                                         return;
489                                 }
490                         }
491                 }
492
493                 default:
494                         LOG_INFO("Incorrect parameters for ^2database^7\n");
495                 case CMD_REQUEST_USAGE:
496                 {
497                         LOG_INFO("\nUsage:^3 sv_cmd database action filename\n");
498                         LOG_INFO("  Where 'action' is the command to complete,\n");
499                         LOG_INFO("  and 'filename' is what it acts upon.\n");
500                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"\n");
501                         return;
502                 }
503         }
504 }
505
506 void GameCommand_defer_clear(float request, float argc)
507 {
508         switch (request)
509         {
510                 case CMD_REQUEST_COMMAND:
511                 {
512                         entity client;
513                         float accepted;
514
515                         if (argc >= 2)
516                         {
517                                 client = GetIndexedEntity(argc, 1);
518                                 accepted = VerifyClientEntity(client, true, false);
519
520                                 if (accepted > 0)
521                                 {
522                                         stuffcmd(client, "defer clear\n");
523                                         LOG_INFO("defer clear stuffed to ", client.netname, "\n");
524                                 }
525                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
526
527                                 return;
528                         }
529                 }
530
531                 default:
532                         LOG_INFO("Incorrect parameters for ^2defer_clear^7\n");
533                 case CMD_REQUEST_USAGE:
534                 {
535                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear client\n");
536                         LOG_INFO("  'client' is the entity number or name of the player.\n");
537                         LOG_INFO("See also: ^2defer_clear_all^7\n");
538                         return;
539                 }
540         }
541 }
542
543 void GameCommand_defer_clear_all(float request)
544 {
545         switch (request)
546         {
547                 case CMD_REQUEST_COMMAND:
548                 {
549                         int n = 0;
550                         float argc;
551
552                         FOREACH_CLIENT(true, LAMBDA(
553                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
554                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
555                                 ++n;
556                         ));
557                         if (n)   LOG_INFO(strcat("Successfully stuffed defer clear to all clients (", ftos(n), ")\n"));  // should a message be added if no players were found?
558                         return;
559                 }
560
561                 default:
562                 case CMD_REQUEST_USAGE:
563                 {
564                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear_all\n");
565                         LOG_INFO("  No arguments required.\n");
566                         LOG_INFO("See also: ^2defer_clear^7\n");
567                         return;
568                 }
569         }
570 }
571
572 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
573 {
574         switch (request)
575         {
576                 case CMD_REQUEST_COMMAND:
577                 {
578                         if (argv(1))
579                         {
580                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
581                                 else race_deleteTime(GetMapname(), stof(argv(1)));
582                                 return;
583                         }
584                 }
585
586                 default:
587                         LOG_INFO("Incorrect parameters for ^2delrec^7\n");
588                 case CMD_REQUEST_USAGE:
589                 {
590                         LOG_INFO("\nUsage:^3 sv_cmd delrec ranking [map]\n");
591                         LOG_INFO("  'ranking' is which ranking level to clear up to, \n");
592                         LOG_INFO("  it will clear all records up to nth place.\n");
593                         LOG_INFO("  if 'map' is not provided it will use current map.\n");
594                         return;
595                 }
596         }
597 }
598
599 void GameCommand_effectindexdump(float request)
600 {
601         switch (request)
602         {
603                 case CMD_REQUEST_COMMAND:
604                 {
605                         float fh, d;
606                         string s;
607
608                         d = db_create();
609                         LOG_INFO("begin of effects list\n");
610                         db_put(d, "TE_GUNSHOT", "1");
611                         LOG_INFO("effect TE_GUNSHOT is ", ftos(_particleeffectnum("TE_GUNSHOT")), "\n");
612                         db_put(d, "TE_GUNSHOTQUAD", "1");
613                         LOG_INFO("effect TE_GUNSHOTQUAD is ", ftos(_particleeffectnum("TE_GUNSHOTQUAD")), "\n");
614                         db_put(d, "TE_SPIKE", "1");
615                         LOG_INFO("effect TE_SPIKE is ", ftos(_particleeffectnum("TE_SPIKE")), "\n");
616                         db_put(d, "TE_SPIKEQUAD", "1");
617                         LOG_INFO("effect TE_SPIKEQUAD is ", ftos(_particleeffectnum("TE_SPIKEQUAD")), "\n");
618                         db_put(d, "TE_SUPERSPIKE", "1");
619                         LOG_INFO("effect TE_SUPERSPIKE is ", ftos(_particleeffectnum("TE_SUPERSPIKE")), "\n");
620                         db_put(d, "TE_SUPERSPIKEQUAD", "1");
621                         LOG_INFO("effect TE_SUPERSPIKEQUAD is ", ftos(_particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
622                         db_put(d, "TE_WIZSPIKE", "1");
623                         LOG_INFO("effect TE_WIZSPIKE is ", ftos(_particleeffectnum("TE_WIZSPIKE")), "\n");
624                         db_put(d, "TE_KNIGHTSPIKE", "1");
625                         LOG_INFO("effect TE_KNIGHTSPIKE is ", ftos(_particleeffectnum("TE_KNIGHTSPIKE")), "\n");
626                         db_put(d, "TE_EXPLOSION", "1");
627                         LOG_INFO("effect TE_EXPLOSION is ", ftos(_particleeffectnum("TE_EXPLOSION")), "\n");
628                         db_put(d, "TE_EXPLOSIONQUAD", "1");
629                         LOG_INFO("effect TE_EXPLOSIONQUAD is ", ftos(_particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
630                         db_put(d, "TE_TAREXPLOSION", "1");
631                         LOG_INFO("effect TE_TAREXPLOSION is ", ftos(_particleeffectnum("TE_TAREXPLOSION")), "\n");
632                         db_put(d, "TE_TELEPORT", "1");
633                         LOG_INFO("effect TE_TELEPORT is ", ftos(_particleeffectnum("TE_TELEPORT")), "\n");
634                         db_put(d, "TE_LAVASPLASH", "1");
635                         LOG_INFO("effect TE_LAVASPLASH is ", ftos(_particleeffectnum("TE_LAVASPLASH")), "\n");
636                         db_put(d, "TE_SMALLFLASH", "1");
637                         LOG_INFO("effect TE_SMALLFLASH is ", ftos(_particleeffectnum("TE_SMALLFLASH")), "\n");
638                         db_put(d, "TE_FLAMEJET", "1");
639                         LOG_INFO("effect TE_FLAMEJET is ", ftos(_particleeffectnum("TE_FLAMEJET")), "\n");
640                         db_put(d, "EF_FLAME", "1");
641                         LOG_INFO("effect EF_FLAME is ", ftos(_particleeffectnum("EF_FLAME")), "\n");
642                         db_put(d, "TE_BLOOD", "1");
643                         LOG_INFO("effect TE_BLOOD is ", ftos(_particleeffectnum("TE_BLOOD")), "\n");
644                         db_put(d, "TE_SPARK", "1");
645                         LOG_INFO("effect TE_SPARK is ", ftos(_particleeffectnum("TE_SPARK")), "\n");
646                         db_put(d, "TE_PLASMABURN", "1");
647                         LOG_INFO("effect TE_PLASMABURN is ", ftos(_particleeffectnum("TE_PLASMABURN")), "\n");
648                         db_put(d, "TE_TEI_G3", "1");
649                         LOG_INFO("effect TE_TEI_G3 is ", ftos(_particleeffectnum("TE_TEI_G3")), "\n");
650                         db_put(d, "TE_TEI_SMOKE", "1");
651                         LOG_INFO("effect TE_TEI_SMOKE is ", ftos(_particleeffectnum("TE_TEI_SMOKE")), "\n");
652                         db_put(d, "TE_TEI_BIGEXPLOSION", "1");
653                         LOG_INFO("effect TE_TEI_BIGEXPLOSION is ", ftos(_particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
654                         db_put(d, "TE_TEI_PLASMAHIT", "1");
655                         LOG_INFO("effect TE_TEI_PLASMAHIT is ", ftos(_particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
656                         db_put(d, "EF_STARDUST", "1");
657                         LOG_INFO("effect EF_STARDUST is ", ftos(_particleeffectnum("EF_STARDUST")), "\n");
658                         db_put(d, "TR_ROCKET", "1");
659                         LOG_INFO("effect TR_ROCKET is ", ftos(_particleeffectnum("TR_ROCKET")), "\n");
660                         db_put(d, "TR_GRENADE", "1");
661                         LOG_INFO("effect TR_GRENADE is ", ftos(_particleeffectnum("TR_GRENADE")), "\n");
662                         db_put(d, "TR_BLOOD", "1");
663                         LOG_INFO("effect TR_BLOOD is ", ftos(_particleeffectnum("TR_BLOOD")), "\n");
664                         db_put(d, "TR_WIZSPIKE", "1");
665                         LOG_INFO("effect TR_WIZSPIKE is ", ftos(_particleeffectnum("TR_WIZSPIKE")), "\n");
666                         db_put(d, "TR_SLIGHTBLOOD", "1");
667                         LOG_INFO("effect TR_SLIGHTBLOOD is ", ftos(_particleeffectnum("TR_SLIGHTBLOOD")), "\n");
668                         db_put(d, "TR_KNIGHTSPIKE", "1");
669                         LOG_INFO("effect TR_KNIGHTSPIKE is ", ftos(_particleeffectnum("TR_KNIGHTSPIKE")), "\n");
670                         db_put(d, "TR_VORESPIKE", "1");
671                         LOG_INFO("effect TR_VORESPIKE is ", ftos(_particleeffectnum("TR_VORESPIKE")), "\n");
672                         db_put(d, "TR_NEHAHRASMOKE", "1");
673                         LOG_INFO("effect TR_NEHAHRASMOKE is ", ftos(_particleeffectnum("TR_NEHAHRASMOKE")), "\n");
674                         db_put(d, "TR_NEXUIZPLASMA", "1");
675                         LOG_INFO("effect TR_NEXUIZPLASMA is ", ftos(_particleeffectnum("TR_NEXUIZPLASMA")), "\n");
676                         db_put(d, "TR_GLOWTRAIL", "1");
677                         LOG_INFO("effect TR_GLOWTRAIL is ", ftos(_particleeffectnum("TR_GLOWTRAIL")), "\n");
678                         db_put(d, "TR_SEEKER", "1");
679                         LOG_INFO("effect TR_SEEKER is ", ftos(_particleeffectnum("TR_SEEKER")), "\n");
680                         db_put(d, "SVC_PARTICLE", "1");
681                         LOG_INFO("effect SVC_PARTICLE is ", ftos(_particleeffectnum("SVC_PARTICLE")), "\n");
682
683                         fh = fopen("effectinfo.txt", FILE_READ);
684                         while ((s = fgets(fh)))
685                         {
686                                 tokenize_console(s);
687                                 if (argv(0) == "effect")
688                                 {
689                                         if (db_get(d, argv(1)) != "1")
690                                         {
691                                                 int i = _particleeffectnum(argv(1));
692                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i), "\n");
693                                                 db_put(d, argv(1), "1");
694                                         }
695                                 }
696                         }
697                         LOG_INFO("end of effects list\n");
698
699                         db_close(d);
700                         return;
701                 }
702
703                 default:
704                 case CMD_REQUEST_USAGE:
705                 {
706                         LOG_INFO("\nUsage:^3 sv_cmd effectindexdump\n");
707                         LOG_INFO("  No arguments required.\n");
708                         return;
709                 }
710         }
711 }
712
713 void GameCommand_extendmatchtime(float request)
714 {
715         switch (request)
716         {
717                 case CMD_REQUEST_COMMAND:
718                 {
719                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
720                         return;
721                 }
722
723                 default:
724                 case CMD_REQUEST_USAGE:
725                 {
726                         LOG_INFO("\nUsage:^3 sv_cmd extendmatchtime\n");
727                         LOG_INFO("  No arguments required.\n");
728                         LOG_INFO("See also: ^2reducematchtime^7\n");
729                         return;
730                 }
731         }
732 }
733
734 void GameCommand_gametype(float request, float argc)
735 {
736         switch (request)
737         {
738                 case CMD_REQUEST_COMMAND:
739                 {
740                         if (argv(1) != "")
741                         {
742                                 string s = argv(1);
743                                 Gametype t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
744
745                                 if (t)
746                                 {
747                                         MapInfo_SwitchGameType(t);
748                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
749                                         if (MapInfo_count > 0)
750                                         {
751                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
752                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
753                                                 lsmaps_reply = strzone(getlsmaps());
754                                                 bprint("Game type successfully switched to ", s, "\n");
755                                         }
756                                         else
757                                         {
758                                                 bprint("Cannot use this game type: no map for it found\n");
759                                                 MapInfo_SwitchGameType(tsave);
760                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
761                                         }
762                                 }
763                                 else
764                                 {
765                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
766                                 }
767
768                                 return;
769                         }
770                 }
771
772                 default:
773                         LOG_INFO("Incorrect parameters for ^2gametype^7\n");
774                 case CMD_REQUEST_USAGE:
775                 {
776                         LOG_INFO("\nUsage:^3 sv_cmd gametype mode\n");
777                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.\n");
778                         LOG_INFO("See also: ^2gotomap^7\n");
779                         return;
780                 }
781         }
782 }
783
784 void GameCommand_gettaginfo(float request, float argc)
785 {
786         switch (request)
787         {
788                 case CMD_REQUEST_COMMAND:
789                 {
790                         entity tmp_entity;
791                         float i;
792                         vector v;
793
794                         if (argc >= 4)
795                         {
796                                 tmp_entity = spawn();
797                                 if (argv(1) == "w")
798                                 {
799                                         .entity weaponentity = weaponentities[0];
800                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
801                                 }
802                                 else
803                                 {
804                                         precache_model(argv(1));
805                                         _setmodel(tmp_entity, argv(1));
806                                 }
807                                 tmp_entity.frame = stof(argv(2));
808                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
809                                 else i = gettagindex(tmp_entity, argv(3));
810                                 if (i)
811                                 {
812                                         v = gettaginfo(tmp_entity, i);
813                                         LOG_INFO("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
814                                         LOG_INFO(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
815                                         LOG_INFO(" vector = ", ftos(v.x), " ", ftos(v.y), " ", ftos(v.z), "\n");
816                                         LOG_INFO(" offset = ", ftos(gettaginfo_offset.x), " ", ftos(gettaginfo_offset.y), " ", ftos(gettaginfo_offset.z), "\n");
817                                         LOG_INFO(" forward = ", ftos(gettaginfo_forward.x), " ", ftos(gettaginfo_forward.y), " ", ftos(gettaginfo_forward.z), "\n");
818                                         LOG_INFO(" right = ", ftos(gettaginfo_right.x), " ", ftos(gettaginfo_right.y), " ", ftos(gettaginfo_right.z), "\n");
819                                         LOG_INFO(" up = ", ftos(gettaginfo_up.x), " ", ftos(gettaginfo_up.y), " ", ftos(gettaginfo_up.z), "\n");
820                                         if (argc >= 6)
821                                         {
822                                                 v.y = -v.y;
823                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
824                                         }
825                                 }
826                                 else
827                                 {
828                                         LOG_INFO("bone not found\n");
829                                 }
830
831                                 delete(tmp_entity);
832                                 return;
833                         }
834                 }
835
836                 default:
837                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
838                 case CMD_REQUEST_USAGE:
839                 {
840                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
841                         LOG_INFO("See also: ^2bbox, trace^7\n");
842                         return;
843                 }
844         }
845 }
846
847 void GameCommand_animbench(float request, float argc)
848 {
849         switch (request)
850         {
851                 case CMD_REQUEST_COMMAND:
852                 {
853                         entity tmp_entity;
854
855                         if (argc >= 4)
856                         {
857                                 tmp_entity = spawn();
858                                 if (argv(1) == "w")
859                                 {
860                                         .entity weaponentity = weaponentities[0];
861                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
862                                 }
863                                 else
864                                 {
865                                         precache_model(argv(1));
866                                         _setmodel(tmp_entity, argv(1));
867                                 }
868                                 float f1 = stof(argv(2));
869                                 float f2 = stof(argv(3));
870                                 float t0;
871                                 float t1 = 0;
872                                 float t2 = 0;
873                                 float n = 0;
874
875                                 while (t1 + t2 < 1)
876                                 {
877                                         tmp_entity.frame = f1;
878                                         t0 = gettime(GETTIME_HIRES);
879                                         getsurfacepoint(tmp_entity, 0, 0);
880                                         t1 += gettime(GETTIME_HIRES) - t0;
881                                         tmp_entity.frame = f2;
882                                         t0 = gettime(GETTIME_HIRES);
883                                         getsurfacepoint(tmp_entity, 0, 0);
884                                         t2 += gettime(GETTIME_HIRES) - t0;
885                                         n += 1;
886                                 }
887                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
888                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
889
890                                 delete(tmp_entity);
891                                 return;
892                         }
893                 }
894
895                 default:
896                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
897                 case CMD_REQUEST_USAGE:
898                 {
899                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
900                         LOG_INFO("See also: ^2bbox, trace^7\n");
901                         return;
902                 }
903         }
904 }
905
906 void GameCommand_gotomap(float request, float argc)
907 {
908         switch (request)
909         {
910                 case CMD_REQUEST_COMMAND:
911                 {
912                         if (argv(1))
913                         {
914                                 LOG_INFO(GotoMap(argv(1)), "\n");
915                                 return;
916                         }
917                 }
918
919                 default:
920                         LOG_INFO("Incorrect parameters for ^2gotomap^7\n");
921                 case CMD_REQUEST_USAGE:
922                 {
923                         LOG_INFO("\nUsage:^3 sv_cmd gotomap map\n");
924                         LOG_INFO("  Where 'map' is the *.bsp file to change to.\n");
925                         LOG_INFO("See also: ^2gametype^7\n");
926                         return;
927                 }
928         }
929 }
930
931 void GameCommand_lockteams(float request)
932 {
933         switch (request)
934         {
935                 case CMD_REQUEST_COMMAND:
936                 {
937                         if (teamplay)
938                         {
939                                 lockteams = 1;
940                                 bprint("^1The teams are now locked.\n");
941                         }
942                         else
943                         {
944                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
945                         }
946                         return;
947                 }
948
949                 default:
950                 case CMD_REQUEST_USAGE:
951                 {
952                         LOG_INFO("\nUsage:^3 sv_cmd lockteams\n");
953                         LOG_INFO("  No arguments required.\n");
954                         LOG_INFO("See also: ^2unlockteams^7\n");
955                         return;
956                 }
957         }
958 }
959
960 void GameCommand_make_mapinfo(float request)
961 {
962         switch (request)
963         {
964                 case CMD_REQUEST_COMMAND:
965                 {
966                         entity tmp_entity;
967
968                         tmp_entity = new(make_mapinfo);
969                         setthink(tmp_entity, make_mapinfo_Think);
970                         tmp_entity.nextthink = time;
971                         MapInfo_Enumerate();
972                         return;
973                 }
974
975                 default:
976                 case CMD_REQUEST_USAGE:
977                 {
978                         LOG_INFO("\nUsage:^3 sv_cmd make_mapinfo\n");
979                         LOG_INFO("  No arguments required.\n");
980                         LOG_INFO("See also: ^2radarmap^7\n");
981                         return;
982                 }
983         }
984 }
985
986 void GameCommand_moveplayer(float request, float argc)
987 {
988         switch (request)
989         {
990                 case CMD_REQUEST_COMMAND:
991                 {
992                         float accepted;
993                         entity client;
994
995                         string targets = strreplace(",", " ", argv(1));
996                         string original_targets = strreplace(" ", ", ", targets);
997                         string destination = argv(2);
998
999                         string successful, t;
1000                         successful = string_null;
1001
1002                         // lets see if the target(s) even actually exist.
1003                         if ((targets) && (destination))
1004                         {
1005                                 for ( ; targets; )
1006                                 {
1007                                         t = car(targets);
1008                                         targets = cdr(targets);
1009
1010                                         // Check to see if the player is a valid target
1011                                         client = GetFilteredEntity(t);
1012                                         accepted = VerifyClientEntity(client, false, false);
1013
1014                                         if (accepted <= 0)
1015                                         {
1016                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1017                                                 continue;
1018                                         }
1019
1020                                         // Where are we putting this player?
1021                                         if (destination == "spec" || destination == "spectator")
1022                                         {
1023                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1024                                                 {
1025                                                         if (client.caplayer) client.caplayer = 0;
1026                                                         PutObserverInServer(client);
1027
1028                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1029                                                 }
1030                                                 else
1031                                                 {
1032                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1033                                                 }
1034                                                 continue;
1035                                         }
1036                                         else
1037                                         {
1038                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1039                                                 {
1040                                                         if (teamplay)
1041                                                         {
1042                                                                 // set up
1043                                                                 float team_id;
1044                                                                 float save = client.team_forced;
1045                                                                 client.team_forced = 0;
1046
1047                                                                 // find the team to move the player to
1048                                                                 team_id = Team_ColorToTeam(destination);
1049                                                                 if (team_id == client.team)  // already on the destination team
1050                                                                 {
1051                                                                         // keep the forcing undone
1052                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1053                                                                         continue;
1054                                                                 }
1055                                                                 else if (team_id == 0)  // auto team
1056                                                                 {
1057                                                                         CheckAllowedTeams(client);
1058                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1059                                                                 }
1060                                                                 else
1061                                                                 {
1062                                                                         CheckAllowedTeams(client);
1063                                                                 }
1064                                                                 client.team_forced = save;
1065
1066                                                                 // Check to see if the destination team is even available
1067                                                                 switch (team_id)
1068                                                                 {
1069                                                                         case NUM_TEAM_1: if (c1 == -1) { LOG_INFO("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1070                                                                         case NUM_TEAM_2: if (c2 == -1) { LOG_INFO("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1071                                                                         case NUM_TEAM_3: if (c3 == -1) { LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1072                                                                         case NUM_TEAM_4: if (c4 == -1) { LOG_INFO("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1073
1074                                                                         default: LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.\n");
1075                                                                                 return;
1076                                                                 }
1077
1078                                                                 // If so, lets continue and finally move the player
1079                                                                 client.team_forced = 0;
1080                                                                 MoveToTeam(client, team_id, 6);
1081                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1082                                                                 LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1083                                                                 continue;
1084                                                         }
1085                                                         else
1086                                                         {
1087                                                                 LOG_INFO("Can't change teams when currently not playing a team game.\n");
1088                                                                 return;
1089                                                         }
1090                                                 }
1091                                                 else
1092                                                 {
1093                                                         LOG_INFO("Can't change teams if the player isn't in the game.\n");  // well technically we could, but should we allow that? :P
1094                                                         return;
1095                                                 }
1096                                         }
1097                                 }
1098
1099                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1100                                 else LOG_INFO("No players given (", original_targets, ") are able to move.\n");
1101
1102                                 return;  // still correct parameters so return to avoid usage print
1103                         }
1104                 }
1105
1106                 default:
1107                         LOG_INFO("Incorrect parameters for ^2moveplayer^7\n");
1108                 case CMD_REQUEST_USAGE:
1109                 {
1110                         LOG_INFO("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1111                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1112                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating\n");
1113                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1114                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1115                         LOG_INFO("          sv_cmd moveplayer 2 spec \n");
1116                         LOG_INFO("See also: ^2allspec, shuffleteams^7\n");
1117                         return;
1118                 }
1119         }
1120 }
1121
1122 void GameCommand_nospectators(float request)
1123 {
1124         switch (request)
1125         {
1126                 case CMD_REQUEST_COMMAND:
1127                 {
1128                         blockSpectators = 1;
1129                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1130                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, LAMBDA(
1131                                 if(!it.caplayer)
1132                                 {
1133                                         it.spectatortime = time;
1134                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1135                                 }
1136                         ));
1137                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1138                         return;
1139                 }
1140
1141                 default:
1142                 case CMD_REQUEST_USAGE:
1143                 {
1144                         LOG_INFO("\nUsage:^3 sv_cmd nospectators\n");
1145                         LOG_INFO("  No arguments required.\n");
1146                         return;
1147                 }
1148         }
1149 }
1150
1151 void GameCommand_playerdemo(float request, float argc)
1152 {
1153         switch (request)
1154         {
1155                 case CMD_REQUEST_COMMAND:
1156                 {
1157                         if (argv(2) && argv(3))
1158                         {
1159                                 entity client;
1160                                 float i, n, accepted;
1161
1162                                 switch (argv(1))
1163                                 {
1164                                         case "read":
1165                                         {
1166                                                 client = GetIndexedEntity(argc, 2);
1167                                                 accepted = VerifyClientEntity(client, false, true);
1168
1169                                                 if (accepted <= 0)
1170                                                 {
1171                                                         LOG_INFO("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1172                                                         return;
1173                                                 }
1174
1175                                                 playerdemo_open_read(client, argv(next_token));
1176                                                 return;
1177                                         }
1178
1179                                         case "write":
1180                                         {
1181                                                 client = GetIndexedEntity(argc, 2);
1182                                                 accepted = VerifyClientEntity(client, false, false);
1183
1184                                                 if (accepted <= 0)
1185                                                 {
1186                                                         LOG_INFO("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1187                                                         return;
1188                                                 }
1189
1190                                                 playerdemo_open_write(client, argv(next_token));
1191                                                 return;
1192                                         }
1193
1194                                         case "auto_read_and_write":
1195                                         {
1196                                                 n = GetFilteredNumber(argv(3));
1197                                                 cvar_set("bot_number", ftos(n));
1198
1199                                                 localcmd("wait; wait; wait\n");
1200                                                 for (i = 0; i < n; ++i)
1201                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1202                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n + 1), "\n");
1203                                                 return;
1204                                         }
1205
1206                                         case "auto_read":
1207                                         {
1208                                                 n = GetFilteredNumber(argv(3));
1209                                                 cvar_set("bot_number", ftos(n));
1210
1211                                                 localcmd("wait; wait; wait\n");
1212                                                 for (i = 0; i < n; ++i)
1213                                                         localcmd("sv_cmd playerdemo read ", ftos(i + 2), " ", argv(2), ftos(i + 1), "\n");
1214                                                 return;
1215                                         }
1216                                 }
1217                         }
1218                 }
1219
1220                 default:
1221                         LOG_INFO("Incorrect parameters for ^2playerdemo^7\n");
1222                 case CMD_REQUEST_USAGE:
1223                 {
1224                         LOG_INFO("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1225                         LOG_INFO("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1226                         return;
1227                 }
1228         }
1229 }
1230
1231 void GameCommand_printstats(float request)
1232 {
1233         switch (request)
1234         {
1235                 case CMD_REQUEST_COMMAND:
1236                 {
1237                         DumpStats(false);
1238                         LOG_INFO("stats dumped.\n");
1239                         return;
1240                 }
1241
1242                 default:
1243                 case CMD_REQUEST_USAGE:
1244                 {
1245                         LOG_INFO("\nUsage:^3 sv_cmd printstats\n");
1246                         LOG_INFO("  No arguments required.\n");
1247                         return;
1248                 }
1249         }
1250 }
1251
1252 void GameCommand_radarmap(float request, float argc)
1253 {
1254         switch (request)
1255         {
1256                 case CMD_REQUEST_COMMAND:
1257                 {
1258                         if (RadarMap_Make(argc)) return;
1259                 }
1260
1261                 default:
1262                         LOG_INFO("Incorrect parameters for ^2radarmap^7\n");
1263                 case CMD_REQUEST_USAGE:
1264                 {
1265                         LOG_INFO("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1266                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.\n");
1267                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1268                         LOG_INFO("See also: ^2make_mapinfo^7\n");
1269                         return;
1270                 }
1271         }
1272 }
1273
1274 void GameCommand_reducematchtime(float request)
1275 {
1276         switch (request)
1277         {
1278                 case CMD_REQUEST_COMMAND:
1279                 {
1280                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1281                         return;
1282                 }
1283
1284                 default:
1285                 case CMD_REQUEST_USAGE:
1286                 {
1287                         LOG_INFO("\nUsage:^3 sv_cmd reducematchtime\n");
1288                         LOG_INFO("  No arguments required.\n");
1289                         LOG_INFO("See also: ^2extendmatchtime^7\n");
1290                         return;
1291                 }
1292         }
1293 }
1294
1295 void GameCommand_setbots(float request, float argc)
1296 {
1297         switch (request)
1298         {
1299                 case CMD_REQUEST_COMMAND:
1300                 {
1301                         if (argc >= 2)
1302                         {
1303                                 cvar_settemp("minplayers", "0");
1304                                 cvar_settemp("bot_number", argv(1));
1305                                 bot_fixcount();
1306                                 return;
1307                         }
1308                 }
1309
1310                 default:
1311                         LOG_INFO("Incorrect parameters for ^2setbots^7\n");
1312                 case CMD_REQUEST_USAGE:
1313                 {
1314                         LOG_INFO("\nUsage:^3 sv_cmd setbots botnumber\n");
1315                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1316                         LOG_INFO("See also: ^2bot_cmd^7\n");
1317                         return;
1318                 }
1319         }
1320 }
1321
1322 void GameCommand_shuffleteams(float request)
1323 {
1324         switch (request)
1325         {
1326                 case CMD_REQUEST_COMMAND:
1327                 {
1328                         if (!teamplay)
1329                         {
1330                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.\n");
1331                                 return;
1332                         }
1333
1334                         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, LAMBDA(
1335                                 if (it.team_forced) {
1336                                         // we could theoretically assign forced players to their teams
1337                                         // and shuffle the rest to fill the empty spots but in practise
1338                                         // either all players or none are gonna have forced teams
1339                                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.\n");
1340                                         return;
1341                                 }
1342                         ));
1343
1344                         int number_of_teams = 0;
1345                         CheckAllowedTeams(NULL);
1346                         if (c1 >= 0) number_of_teams = max(1, number_of_teams);
1347                         if (c2 >= 0) number_of_teams = max(2, number_of_teams);
1348                         if (c3 >= 0) number_of_teams = max(3, number_of_teams);
1349                         if (c4 >= 0) number_of_teams = max(4, number_of_teams);
1350
1351                         int team_index = 0;
1352                         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, LAMBDA(
1353                                 int target_team_number = Team_NumberToTeam(team_index + 1);
1354                                 if (it.team != target_team_number) MoveToTeam(it, target_team_number, 6);
1355                                 team_index = (team_index + 1) % number_of_teams;
1356                         ));
1357
1358                         bprint("Successfully shuffled the players around randomly.\n");
1359                         return;
1360                 }
1361
1362                 default:
1363                 case CMD_REQUEST_USAGE:
1364                 {
1365                         LOG_INFO("\nUsage:^3 sv_cmd shuffleteams\n");
1366                         LOG_INFO("  No arguments required.\n");
1367                         LOG_INFO("See also: ^2moveplayer, allspec^7\n");
1368                         return;
1369                 }
1370         }
1371 }
1372
1373 void GameCommand_stuffto(float request, float argc)
1374 {
1375         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1376         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1377         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1378
1379 #ifdef STUFFTO_ENABLED
1380                 switch (request)
1381                 {
1382                         case CMD_REQUEST_COMMAND:
1383                         {
1384                                 if (argv(2))
1385                                 {
1386                                         entity client = GetIndexedEntity(argc, 1);
1387                                         float accepted = VerifyClientEntity(client, true, false);
1388
1389                                         if (accepted > 0)
1390                                         {
1391                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1392                                                 LOG_INFO(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").\n"));
1393                                         }
1394                                         else
1395                                         {
1396                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1397                                         }
1398
1399                                         return;
1400                                 }
1401                         }
1402
1403                         default:
1404                                 LOG_INFO("Incorrect parameters for ^2stuffto^7\n");
1405                         case CMD_REQUEST_USAGE:
1406                         {
1407                                 LOG_INFO("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1408                                 LOG_INFO("  'client' is the entity number or name of the player,\n");
1409                                 LOG_INFO("  and 'command' is the command to be sent to that player.\n");
1410                                 return;
1411                         }
1412                 }
1413 #else
1414                 if (request)
1415                 {
1416                         LOG_INFO("stuffto command is not enabled on this server.\n");
1417                         return;
1418                 }
1419 #endif
1420 }
1421
1422 void GameCommand_trace(float request, float argc)
1423 {
1424         switch (request)
1425         {
1426                 case CMD_REQUEST_COMMAND:
1427                 {
1428                         entity e;
1429                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1430                         float i, f, safe, unsafe, dq, dqf;
1431
1432                         switch (argv(1))
1433                         {
1434                                 case "debug":
1435                                 {
1436                                         float hitcount = 0;
1437                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1438                                         float worst_endpos_bug = 0;
1439                                         for ( ; ; )
1440                                         {
1441                                                 org = world.mins;
1442                                                 delta = world.maxs - world.mins;
1443
1444                                                 start.x = org.x + random() * delta.x;
1445                                                 start.y = org.y + random() * delta.y;
1446                                                 start.z = org.z + random() * delta.z;
1447
1448                                                 end.x = org.x + random() * delta.x;
1449                                                 end.y = org.y + random() * delta.y;
1450                                                 end.z = org.z + random() * delta.z;
1451
1452                                                 start = stov(vtos(start));
1453                                                 end = stov(vtos(end));
1454
1455                                                 tracebox(start, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), end, MOVE_NOMONSTERS, NULL);
1456                                                 if (!trace_startsolid && trace_fraction < 1)
1457                                                 {
1458                                                         p = trace_endpos;
1459                                                         tracebox(p, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), p, MOVE_NOMONSTERS, NULL);
1460                                                         if (trace_startsolid)
1461                                                         {
1462                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1463                                                                 tracebox(start, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), end, MOVE_NOMONSTERS, NULL);
1464
1465                                                                 // how much do we need to back off?
1466                                                                 safe = 1;
1467                                                                 unsafe = 0;
1468                                                                 for ( ; ; )
1469                                                                 {
1470                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1471                                                                         tracebox(pos, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), pos, MOVE_NOMONSTERS, NULL);
1472                                                                         if (trace_startsolid)
1473                                                                         {
1474                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1475                                                                                 unsafe = (safe + unsafe) * 0.5;
1476                                                                         }
1477                                                                         else
1478                                                                         {
1479                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1480                                                                                 safe = (safe + unsafe) * 0.5;
1481                                                                         }
1482                                                                 }
1483
1484                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1485                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1486
1487                                                                 tracebox(p, STAT(PL_MIN, NULL) + '0.1 0.1 0.1', STAT(PL_MAX, NULL) - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1488                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1489                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1490                                                                 if (++hitcount >= 10) break;
1491                                                         }
1492                                                         else
1493                                                         {
1494                                                                 q0 = p;
1495                                                                 dq = 0;
1496                                                                 dqf = 1;
1497                                                                 for ( ; ; )
1498                                                                 {
1499                                                                         q = p + normalize(end - p) * (dq + dqf);
1500                                                                         if (q == q0) break;
1501                                                                         tracebox(p, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), q, MOVE_NOMONSTERS, NULL);
1502                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1503                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1504                                                                         dqf *= 0.5;
1505                                                                         q0 = q;
1506                                                                 }
1507                                                                 if (dq > worst_endpos_bug)
1508                                                                 {
1509                                                                         worst_endpos_bug = dq;
1510                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1511                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1512                                                                         if (++hitcount >= 10) break;
1513                                                                 }
1514                                                         }
1515                                                 }
1516                                         }
1517                                         return;
1518                                 }
1519
1520                                 case "debug2":
1521                                 {
1522                                         e = nextent(NULL);
1523                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1524                                         vv = trace_endpos;
1525                                         if (trace_fraction == 1)
1526                                         {
1527                                                 LOG_INFO("not above ground, aborting\n");
1528                                                 return;
1529                                         }
1530                                         f = 0;
1531                                         for (i = 0; i < 100000; ++i)
1532                                         {
1533                                                 dv = randomvec();
1534                                                 if (dv.z > 0) dv = -1 * dv;
1535                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1536                                                 if (trace_startsolid) LOG_INFO("bug 1\n");
1537                                                 if (trace_fraction == 1)
1538                                                 {
1539                                                         if (dv.z < f)
1540                                                         {
1541                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1542                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1543                                                                 f = dv.z;
1544                                                         }
1545                                                 }
1546                                         }
1547                                         LOG_INFO("highest possible dist: ", ftos(f), "\n");
1548                                         return;
1549                                 }
1550
1551                                 case "walk":
1552                                 {
1553                                         if (argc == 4)
1554                                         {
1555                                                 e = nextent(NULL);
1556                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL)) LOG_INFO("can walk\n");
1557                                                 else LOG_INFO("cannot walk\n");
1558                                                 return;
1559                                         }
1560                                 }
1561
1562                                 case "showline":
1563                                 {
1564                                         if (argc == 4)
1565                                         {
1566                                                 vv = stov(argv(2));
1567                                                 dv = stov(argv(3));
1568                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1569                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1570                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1571                                                 return;
1572                                         }
1573                                 }
1574
1575                                         // no default case, just go straight to invalid
1576                         }
1577                 }
1578
1579                 default:
1580                         LOG_INFO("Incorrect parameters for ^2trace^7\n");
1581                 case CMD_REQUEST_USAGE:
1582                 {
1583                         LOG_INFO("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1584                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1585                         LOG_INFO("See also: ^2bbox, gettaginfo^7\n");
1586                         return;
1587                 }
1588         }
1589 }
1590
1591 void GameCommand_unlockteams(float request)
1592 {
1593         switch (request)
1594         {
1595                 case CMD_REQUEST_COMMAND:
1596                 {
1597                         if (teamplay)
1598                         {
1599                                 lockteams = 0;
1600                                 bprint("^1The teams are now unlocked.\n");
1601                         }
1602                         else
1603                         {
1604                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1605                         }
1606                         return;
1607                 }
1608
1609                 default:
1610                 case CMD_REQUEST_USAGE:
1611                 {
1612                         LOG_INFO("\nUsage:^3 sv_cmd unlockteams\n");
1613                         LOG_INFO("  No arguments required.\n");
1614                         LOG_INFO("See also: ^2lockteams^7\n");
1615                         return;
1616                 }
1617         }
1618 }
1619
1620 void GameCommand_warp(float request, float argc)
1621 {
1622         switch (request)
1623         {
1624                 case CMD_REQUEST_COMMAND:
1625                 {
1626                         if (autocvar_g_campaign)
1627                         {
1628                                 if (argc >= 2)
1629                                 {
1630                                         CampaignLevelWarp(stof(argv(1)));
1631                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".\n");
1632                                 }
1633                                 else
1634                                 {
1635                                         CampaignLevelWarp(-1);
1636                                         LOG_INFO("Successfully warped to next campaign level.\n");
1637                                 }
1638                         }
1639                         else
1640                         {
1641                                 LOG_INFO("Not in campaign, can't level warp\n");
1642                         }
1643                         return;
1644                 }
1645
1646                 default:
1647                 case CMD_REQUEST_USAGE:
1648                 {
1649                         LOG_INFO("\nUsage:^3 sv_cmd warp [level]\n");
1650                         LOG_INFO("  'level' is the level to change campaign mode to.\n");
1651                         LOG_INFO("  if 'level' is not provided it will change to the next level.\n");
1652                         return;
1653                 }
1654         }
1655 }
1656
1657 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1658 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1659 void GameCommand_(float request)
1660 {
1661     switch(request)
1662     {
1663         case CMD_REQUEST_COMMAND:
1664         {
1665
1666             return;
1667         }
1668
1669         default:
1670         case CMD_REQUEST_USAGE:
1671         {
1672             print("\nUsage:^3 sv_cmd \n");
1673             print("  No arguments required.\n");
1674             return;
1675         }
1676     }
1677 }
1678 */
1679
1680
1681 // ==================================
1682 //  Macro system for server commands
1683 // ==================================
1684
1685 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1686 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1687 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1688 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1689 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1690 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1691 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1692 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1693 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1694 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1695 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1696 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1697 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1698 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1699 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1700 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1701 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1702 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1703 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1704 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1705 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1706 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1707 SERVER_COMMAND(playerdemo, "Control the ability to save demos of players") { GameCommand_playerdemo(request, arguments); }
1708 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1709 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1710 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1711 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1712 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1713 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1714 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1715 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1716 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1717
1718 void GameCommand_macro_help()
1719 {
1720         FOREACH(SERVER_COMMANDS, true, LAMBDA(LOG_INFOF("  ^2%s^7: %s\n", it.m_name, it.m_description)));
1721 }
1722
1723 float GameCommand_macro_command(float argc, string command)
1724 {
1725         string c = strtolower(argv(0));
1726         FOREACH(SERVER_COMMANDS, it.m_name == c, LAMBDA(
1727                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1728                 return true;
1729         ));
1730         return false;
1731 }
1732
1733 float GameCommand_macro_usage(float argc)
1734 {
1735         string c = strtolower(argv(1));
1736         FOREACH(SERVER_COMMANDS, it.m_name == c, LAMBDA(
1737                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1738                 return true;
1739         ));
1740         return false;
1741 }
1742
1743 void GameCommand_macro_write_aliases(float fh)
1744 {
1745         FOREACH(SERVER_COMMANDS, true, LAMBDA(CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description)));
1746 }
1747
1748
1749 // =========================================
1750 //  Main Function Called By Engine (sv_cmd)
1751 // =========================================
1752 // If this function exists, game code handles gamecommand instead of the engine code.
1753
1754 void GameCommand(string command)
1755 {
1756         float argc = tokenize_console(command);
1757
1758         // Guide for working with argc arguments by example:
1759         // argc:   1    - 2      - 3     - 4
1760         // argv:   0    - 1      - 2     - 3
1761         // cmd     vote - master - login - password
1762
1763         if (strtolower(argv(0)) == "help")
1764         {
1765                 if (argc == 1)
1766                 {
1767                         LOG_INFO("\nServer console commands:\n");
1768                         GameCommand_macro_help();
1769
1770                         LOG_INFO("\nBanning commands:\n");
1771                         BanCommand_macro_help();
1772
1773                         LOG_INFO("\nCommon networked commands:\n");
1774                         CommonCommand_macro_help(NULL);
1775
1776                         LOG_INFO("\nGeneric commands shared by all programs:\n");
1777                         GenericCommand_macro_help();
1778
1779                         LOG_INFO("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1780                         LOG_INFO("For help about a specific command, type sv_cmd help COMMAND\n");
1781
1782                         return;
1783                 }
1784                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1785                 {
1786                         return;
1787                 }
1788                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1789                 {
1790                         return;
1791                 }
1792                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1793                 {
1794                         return;
1795                 }
1796                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1797                 {
1798                         return;
1799                 }
1800         }
1801         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1802         {
1803                 return;  // handled by a mutator
1804         }
1805         else if (BanCommand(command))
1806         {
1807                 return;  // handled by server/command/ipban.qc
1808         }
1809         else if (CommonCommand_macro_command(argc, NULL, command))
1810         {
1811                 return;  // handled by server/command/common.qc
1812         }
1813         else if (GenericCommand(command))
1814         {
1815                 return;                                        // handled by common/command/generic.qc
1816         }
1817         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1818         {
1819                 return;                                        // handled by one of the above GameCommand_* functions
1820         }
1821
1822         // nothing above caught the command, must be invalid
1823         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1824 }