qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2 #include "_mod.qh"
   3
   4 #include <common/effects/all.qh>
   5
   6 #include "banning.qh"
   7 #include "cmd.qh"
   8 #include "common.qh"
   9 #include "getreplies.qh"
  10 #include "radarmap.qh"
  11
  12 #include "../anticheat.qh"
  13 #include "../campaign.qh"
  14 #include "../client.qh"
  15 #include "../player.qh"
  16 #include "../g_world.qh"
  17 #include "../ipban.qh"
  18 #include "../teamplay.qh"
  19
  20 #include "../bot/api.qh"
  21
  22 #include <server/mutators/_mod.qh>
  23 #include <common/gamemodes/_mod.qh>
  24
  25 #include <common/constants.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/mapinfo.qh>
  28 #include <common/notifications/all.qh>
  29 #include <common/teams.qh>
  30 #include <common/util.qh>
  31
  32 #include <common/monsters/sv_monsters.qh>
  33
  34 //  used by GameCommand_make_mapinfo()
  35 void make_mapinfo_Think(entity this)
  36 {
  37         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  38         {
  39                 LOG_INFO("Done rebuiling mapinfos.");
  40                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  41                 delete(this);
  42         }
  43         else
  44         {
  45                 setthink(this, make_mapinfo_Think);
  46                 this.nextthink = time;
  47         }
  48 }
  49
  50 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  51 void changematchtime(float delta, float mi, float ma)
  52 {
  53         float cur;
  54         float update;
  55         float lim;
  56
  57         if (delta == 0) return;
  58         if (autocvar_timelimit < 0) return;
  59
  60         if (mi <= 10) mi = 10;  // at least ten sec in the future
  61         cur = time - game_starttime;
  62         if (cur > 0) mi += cur; // from current time!
  63
  64         lim = autocvar_timelimit * 60;
  65
  66         if (delta > 0)
  67         {
  68                 if (lim == 0) return; // cannot increase any further
  69                 else if (lim < ma) update = min(ma, lim + delta);
  70                 else                  // already above maximum: FAIL
  71                         return;
  72         }
  73         else
  74         {
  75                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  76                         update = max(mi, ma);
  77                 else if (lim > mi) // above minimum: decrease
  78                         update = max(mi, lim + delta);
  79                 else               // already below minimum: FAIL
  80                         return;
  81         }
  82
  83         cvar_set("timelimit", ftos(update / 60));
  84 }
  85
  86
  87 // =======================
  88 //  Command Sub-Functions
  89 // =======================
  90
  91 void GameCommand_adminmsg(float request, float argc)
  92 {
  93         switch (request)
  94         {
  95                 case CMD_REQUEST_COMMAND:
  96                 {
  97                         entity client;
  98                         float accepted;
  99
 100                         string targets = strreplace(",", " ", argv(1));
 101                         string original_targets = strreplace(" ", ", ", targets);
 102                         string admin_message = argv(2);
 103                         float infobartime = stof(argv(3));
 104
 105                         string successful, t;
 106                         successful = string_null;
 107
 108                         if ((targets) && (admin_message))
 109                         {
 110                                 for ( ; targets; )
 111                                 {
 112                                         t = car(targets);
 113                                         targets = cdr(targets);
 114
 115                                         // Check to see if the player is a valid target
 116                                         client = GetFilteredEntity(t);
 117                                         accepted = VerifyClientEntity(client, true, false);
 118
 119                                         if (accepted <= 0)
 120                                         {
 121                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 122                                                 continue;
 123                                         }
 124
 125                                         // send the centerprint/console print or infomessage
 126                                         if (infobartime)
 127                                         {
 128                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 129                                         }
 130                                         else
 131                                         {
 132                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 133                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 134                                         }
 135
 136                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
 137                                         LOG_TRACE("Message sent to ", playername(client, false));
 138                                         continue;
 139                                 }
 140
 141                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 142                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 143
 144                                 return;
 145                         }
 146                 }
 147
 148                 default:
 149                         LOG_INFO("Incorrect parameters for ^2adminmsg^7");
 150                 case CMD_REQUEST_USAGE:
 151                 {
 152                         LOG_INFO("Usage:^3 sv_cmd adminmsg clients \"message\" [infobartime]");
 153                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
 154                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.");
 155                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.");
 156                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 157                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"");
 158                         return;
 159                 }
 160         }
 161 }
 162
 163 void GameCommand_allready(float request)
 164 {
 165         switch (request)
 166         {
 167                 case CMD_REQUEST_COMMAND:
 168                 {
 169                         ReadyRestart();
 170                         return;
 171                 }
 172
 173                 default:
 174                 case CMD_REQUEST_USAGE:
 175                 {
 176                         LOG_INFO("Usage:^3 sv_cmd allready");
 177                         LOG_INFO("  No arguments required.");
 178                         return;
 179                 }
 180         }
 181 }
 182
 183 void GameCommand_allspec(float request, float argc)
 184 {
 185         switch (request)
 186         {
 187                 case CMD_REQUEST_COMMAND:
 188                 {
 189                         string reason = argv(1);
 190                         int n = 0;
 191                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 192                                 if (it.caplayer) it.caplayer = 0;
 193                                 PutObserverInServer(it);
 194                                 ++n;
 195                         });
 196                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 197                         else   LOG_INFO("No players found to spectate.");
 198                         return;
 199                 }
 200
 201                 default:
 202                 case CMD_REQUEST_USAGE:
 203                 {
 204                         LOG_INFO("Usage:^3 sv_cmd allspec [reason]");
 205                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.");
 206                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7");
 207                         return;
 208                 }
 209         }
 210 }
 211
 212 void GameCommand_anticheat(float request, float argc)
 213 {
 214         switch (request)
 215         {
 216                 case CMD_REQUEST_COMMAND:
 217                 {
 218                         entity client = GetIndexedEntity(argc, 1);
 219                         float accepted = VerifyClientEntity(client, false, false);
 220
 221                         if (accepted > 0)
 222                         {
 223                                 anticheat_report_to_eventlog(client);
 224                                 return;
 225                         }
 226                         else
 227                         {
 228                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 229                         }
 230                 }
 231
 232                 default:
 233                         LOG_INFO("Incorrect parameters for ^2anticheat^7");
 234                 case CMD_REQUEST_USAGE:
 235                 {
 236                         LOG_INFO("Usage:^3 sv_cmd anticheat client");
 237                         LOG_INFO("  'client' is the entity number or name of the player.");
 238                         return;
 239                 }
 240         }
 241 }
 242
 243 void GameCommand_bbox(float request)
 244 {
 245         switch (request)
 246         {
 247                 case CMD_REQUEST_COMMAND:
 248                 {
 249                         vector size_min = '0 0 0';
 250                         vector size_max = '0 0 0';
 251                         tracebox('1 0 0' * world.absmin.x,
 252                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 253                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 254                                 '1 0 0' * world.absmax.x,
 255                                 MOVE_WORLDONLY,
 256                                 NULL);
 257                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 258
 259                         tracebox('0 1 0' * world.absmin.y,
 260                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 261                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 262                                 '0 1 0' * world.absmax.y,
 263                                 MOVE_WORLDONLY,
 264                                 NULL);
 265                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 266
 267                         tracebox('0 0 1' * world.absmin.z,
 268                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 269                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 270                                 '0 0 1' * world.absmax.z,
 271                                 MOVE_WORLDONLY,
 272                                 NULL);
 273                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 274
 275                         tracebox('1 0 0' * world.absmax.x,
 276                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 277                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 278                                 '1 0 0' * world.absmin.x,
 279                                 MOVE_WORLDONLY,
 280                                 NULL);
 281                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 282
 283                         tracebox('0 1 0' * world.absmax.y,
 284                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 285                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 286                                 '0 1 0' * world.absmin.y,
 287                                 MOVE_WORLDONLY,
 288                                 NULL);
 289                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 290
 291                         tracebox('0 0 1' * world.absmax.z,
 292                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 293                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 294                                 '0 0 1' * world.absmin.z,
 295                                 MOVE_WORLDONLY,
 296                                 NULL);
 297                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 298
 299                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 300                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 301                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 302                         return;
 303                 }
 304
 305                 default:
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         LOG_INFO("Usage:^3 sv_cmd bbox");
 309                         LOG_INFO("  No arguments required.");
 310                         LOG_INFO("See also: ^2gettaginfo, trace^7");
 311                         return;
 312                 }
 313         }
 314 }
 315
 316 void GameCommand_bot_cmd(float request, float argc, string command)
 317 {
 318         switch (request)
 319         {
 320                 case CMD_REQUEST_COMMAND:
 321                 {
 322                         entity bot;
 323
 324                         if (argv(1) == "reset")
 325                         {
 326                                 bot_resetqueues();
 327                                 return;
 328                         }
 329                         else if (argv(1) == "setbots")
 330                         {
 331                                 cvar_settemp("bot_vs_human", "0");
 332                                 cvar_settemp("minplayers", "0");
 333                                 cvar_settemp("bot_number", "0");
 334                                 bot_fixcount();
 335                                 cvar_settemp("bot_number", argv(2));
 336                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 337                                 return;
 338                         }
 339                         else if (argv(1) == "load" && argc == 3)
 340                         {
 341                                 float fh, i;
 342                                 string s;
 343                                 fh = fopen(argv(2), FILE_READ);
 344                                 if (fh < 0)
 345                                 {
 346                                         LOG_INFO("cannot open the file");
 347                                         return;
 348                                 }
 349
 350                                 i = 0;
 351                                 while ((s = fgets(fh)))
 352                                 {
 353                                         argc = tokenize_console(s);
 354
 355                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 356                                         {
 357                                                 if (argv(2) == "reset")
 358                                                 {
 359                                                         bot_resetqueues();
 360                                                 }
 361                                                 else if (argv(2) == "setbots")
 362                                                 {
 363                                                         cvar_settemp("bot_vs_human", "0");
 364                                                         cvar_settemp("minplayers", "0");
 365                                                         cvar_settemp("bot_number", "0");
 366                                                         bot_fixcount();
 367                                                         cvar_settemp("bot_number", argv(3));
 368                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 369                                                 }
 370                                                 else
 371                                                 {
 372                                                         if(argv(2) == "*" || argv(2) == "all")
 373                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 374                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 375                                                                 });
 376                                                         else
 377                                                         {
 378                                                                 bot = find_bot_by_number(stof(argv(2)));
 379                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 380                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 381                                                         }
 382                                                 }
 383                                         }
 384                                         else
 385                                         {
 386                                                 localcmd(strcat(s, "\n"));
 387                                         }
 388
 389                                         ++i;
 390                                 }
 391                                 LOG_INFO(ftos(i), " commands read");
 392                                 fclose(fh);
 393                                 return;
 394                         }
 395                         else if (argv(1) == "help")
 396                         {
 397                                 if (argv(2)) bot_cmdhelp(argv(2));
 398                                 else bot_list_commands();
 399                                 return;
 400                         }
 401                         else if (argc >= 3)  // this comes last
 402                         {
 403                                 if(argv(1) == "*" || argv(1) == "all")
 404                                 {
 405                                         int bot_num = 0;
 406                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 407                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 408                                                 bot_num++;
 409                                         });
 410                                         if(bot_num)
 411                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 412                                         return;
 413                                 }
 414                                 else
 415                                 {
 416                                         bot = find_bot_by_number(stof(argv(1)));
 417                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 418                                         if (bot)
 419                                         {
 420                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 421                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 422                                                 return;
 423                                         }
 424                                         else
 425                                         {
 426                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 427                                         }
 428                                 }
 429                         }
 430                 }
 431
 432                 default:
 433                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7");
 434                 case CMD_REQUEST_USAGE:
 435                 {
 436                         LOG_INFO("Usage:^3 sv_cmd bot_cmd client command [argument]");
 437                         LOG_INFO("  'client' can be either the name of the bot or a progressive number (not the entity number!)");
 438                         LOG_INFO("           can also be '*' or 'all' to allow sending the command to all the bots");
 439                         LOG_INFO("  For full list of commands, see bot_cmd help [command].");
 440                         LOG_INFO("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 441                         LOG_INFO("          sv_cmd bot_cmd 1 presskey jump");
 442                         LOG_INFO("          sv_cmd bot_cmd * pause");
 443                         return;
 444                 }
 445         }
 446 }
 447
 448 void GameCommand_cointoss(float request, float argc)
 449 {
 450         switch (request)
 451         {
 452                 case CMD_REQUEST_COMMAND:
 453                 {
 454                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 455                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 456                         string choice = ((random() > 0.5) ? result1 : result2);
 457
 458                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 459                         return;
 460                 }
 461
 462                 default:
 463                 case CMD_REQUEST_USAGE:
 464                 {
 465                         LOG_INFO("Usage:^3 sv_cmd cointoss [result1 result2]");
 466                         LOG_INFO("  Where 'result1' and 'result2' are user created options.");
 467                         return;
 468                 }
 469         }
 470 }
 471
 472 void GameCommand_database(float request, float argc)
 473 {
 474         switch (request)
 475         {
 476                 case CMD_REQUEST_COMMAND:
 477                 {
 478                         if (argc == 3)
 479                         {
 480                                 if (argv(1) == "save")
 481                                 {
 482                                         db_save(ServerProgsDB, argv(2));
 483                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 484                                         return;
 485                                 }
 486                                 else if (argv(1) == "dump")
 487                                 {
 488                                         db_dump(ServerProgsDB, argv(2));
 489                                         LOG_INFO("DB dumped.");  // wtf does this do?
 490                                         return;
 491                                 }
 492                                 else if (argv(1) == "load")
 493                                 {
 494                                         db_close(ServerProgsDB);
 495                                         ServerProgsDB = db_load(argv(2));
 496                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 497                                         return;
 498                                 }
 499                         }
 500                 }
 501
 502                 default:
 503                         LOG_INFO("Incorrect parameters for ^2database^7");
 504                 case CMD_REQUEST_USAGE:
 505                 {
 506                         LOG_INFO("Usage:^3 sv_cmd database action filename");
 507                         LOG_INFO("  Where 'action' is the command to complete,");
 508                         LOG_INFO("  and 'filename' is what it acts upon.");
 509                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"");
 510                         return;
 511                 }
 512         }
 513 }
 514
 515 void GameCommand_defer_clear(float request, float argc)
 516 {
 517         switch (request)
 518         {
 519                 case CMD_REQUEST_COMMAND:
 520                 {
 521                         entity client;
 522                         float accepted;
 523
 524                         if (argc >= 2)
 525                         {
 526                                 client = GetIndexedEntity(argc, 1);
 527                                 accepted = VerifyClientEntity(client, true, false);
 528
 529                                 if (accepted > 0)
 530                                 {
 531                                         stuffcmd(client, "defer clear\n");
 532                                         LOG_INFO("defer clear stuffed to ", playername(client, false));
 533                                 }
 534                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 535
 536                                 return;
 537                         }
 538                 }
 539
 540                 default:
 541                         LOG_INFO("Incorrect parameters for ^2defer_clear^7");
 542                 case CMD_REQUEST_USAGE:
 543                 {
 544                         LOG_INFO("Usage:^3 sv_cmd defer_clear client");
 545                         LOG_INFO("  'client' is the entity number or name of the player.");
 546                         LOG_INFO("See also: ^2defer_clear_all^7");
 547                         return;
 548                 }
 549         }
 550 }
 551
 552 void GameCommand_defer_clear_all(float request)
 553 {
 554         switch (request)
 555         {
 556                 case CMD_REQUEST_COMMAND:
 557                 {
 558                         int n = 0;
 559                         float argc;
 560
 561                         FOREACH_CLIENT(true, {
 562                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 563                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 564                                 ++n;
 565                         });
 566                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 567                         return;
 568                 }
 569
 570                 default:
 571                 case CMD_REQUEST_USAGE:
 572                 {
 573                         LOG_INFO("Usage:^3 sv_cmd defer_clear_all");
 574                         LOG_INFO("  No arguments required.");
 575                         LOG_INFO("See also: ^2defer_clear^7");
 576                         return;
 577                 }
 578         }
 579 }
 580
 581 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 582 {
 583         switch (request)
 584         {
 585                 case CMD_REQUEST_COMMAND:
 586                 {
 587                         if (argv(1))
 588                         {
 589                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 590                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 591                                 return;
 592                         }
 593                 }
 594
 595                 default:
 596                         LOG_INFO("Incorrect parameters for ^2delrec^7");
 597                 case CMD_REQUEST_USAGE:
 598                 {
 599                         LOG_INFO("Usage:^3 sv_cmd delrec ranking [map]");
 600                         LOG_INFO("  'ranking' is which ranking level to clear up to, ");
 601                         LOG_INFO("  it will clear all records up to nth place.");
 602                         LOG_INFO("  if 'map' is not provided it will use current map.");
 603                         return;
 604                 }
 605         }
 606 }
 607
 608 void GameCommand_effectindexdump(float request)
 609 {
 610         switch (request)
 611         {
 612                 case CMD_REQUEST_COMMAND:
 613                 {
 614                         float fh, d;
 615                         string s;
 616
 617                         d = db_create();
 618                         LOG_INFO("begin of effects list");
 619                         db_put(d, "TE_GUNSHOT", "1");
 620                         LOG_INFO("effect TE_GUNSHOT is ", ftos(_particleeffectnum("TE_GUNSHOT")));
 621                         db_put(d, "TE_GUNSHOTQUAD", "1");
 622                         LOG_INFO("effect TE_GUNSHOTQUAD is ", ftos(_particleeffectnum("TE_GUNSHOTQUAD")));
 623                         db_put(d, "TE_SPIKE", "1");
 624                         LOG_INFO("effect TE_SPIKE is ", ftos(_particleeffectnum("TE_SPIKE")));
 625                         db_put(d, "TE_SPIKEQUAD", "1");
 626                         LOG_INFO("effect TE_SPIKEQUAD is ", ftos(_particleeffectnum("TE_SPIKEQUAD")));
 627                         db_put(d, "TE_SUPERSPIKE", "1");
 628                         LOG_INFO("effect TE_SUPERSPIKE is ", ftos(_particleeffectnum("TE_SUPERSPIKE")));
 629                         db_put(d, "TE_SUPERSPIKEQUAD", "1");
 630                         LOG_INFO("effect TE_SUPERSPIKEQUAD is ", ftos(_particleeffectnum("TE_SUPERSPIKEQUAD")));
 631                         db_put(d, "TE_WIZSPIKE", "1");
 632                         LOG_INFO("effect TE_WIZSPIKE is ", ftos(_particleeffectnum("TE_WIZSPIKE")));
 633                         db_put(d, "TE_KNIGHTSPIKE", "1");
 634                         LOG_INFO("effect TE_KNIGHTSPIKE is ", ftos(_particleeffectnum("TE_KNIGHTSPIKE")));
 635                         db_put(d, "TE_EXPLOSION", "1");
 636                         LOG_INFO("effect TE_EXPLOSION is ", ftos(_particleeffectnum("TE_EXPLOSION")));
 637                         db_put(d, "TE_EXPLOSIONQUAD", "1");
 638                         LOG_INFO("effect TE_EXPLOSIONQUAD is ", ftos(_particleeffectnum("TE_EXPLOSIONQUAD")));
 639                         db_put(d, "TE_TAREXPLOSION", "1");
 640                         LOG_INFO("effect TE_TAREXPLOSION is ", ftos(_particleeffectnum("TE_TAREXPLOSION")));
 641                         db_put(d, "TE_TELEPORT", "1");
 642                         LOG_INFO("effect TE_TELEPORT is ", ftos(_particleeffectnum("TE_TELEPORT")));
 643                         db_put(d, "TE_LAVASPLASH", "1");
 644                         LOG_INFO("effect TE_LAVASPLASH is ", ftos(_particleeffectnum("TE_LAVASPLASH")));
 645                         db_put(d, "TE_SMALLFLASH", "1");
 646                         LOG_INFO("effect TE_SMALLFLASH is ", ftos(_particleeffectnum("TE_SMALLFLASH")));
 647                         db_put(d, "TE_FLAMEJET", "1");
 648                         LOG_INFO("effect TE_FLAMEJET is ", ftos(_particleeffectnum("TE_FLAMEJET")));
 649                         db_put(d, "EF_FLAME", "1");
 650                         LOG_INFO("effect EF_FLAME is ", ftos(_particleeffectnum("EF_FLAME")));
 651                         db_put(d, "TE_BLOOD", "1");
 652                         LOG_INFO("effect TE_BLOOD is ", ftos(_particleeffectnum("TE_BLOOD")));
 653                         db_put(d, "TE_SPARK", "1");
 654                         LOG_INFO("effect TE_SPARK is ", ftos(_particleeffectnum("TE_SPARK")));
 655                         db_put(d, "TE_PLASMABURN", "1");
 656                         LOG_INFO("effect TE_PLASMABURN is ", ftos(_particleeffectnum("TE_PLASMABURN")));
 657                         db_put(d, "TE_TEI_G3", "1");
 658                         LOG_INFO("effect TE_TEI_G3 is ", ftos(_particleeffectnum("TE_TEI_G3")));
 659                         db_put(d, "TE_TEI_SMOKE", "1");
 660                         LOG_INFO("effect TE_TEI_SMOKE is ", ftos(_particleeffectnum("TE_TEI_SMOKE")));
 661                         db_put(d, "TE_TEI_BIGEXPLOSION", "1");
 662                         LOG_INFO("effect TE_TEI_BIGEXPLOSION is ", ftos(_particleeffectnum("TE_TEI_BIGEXPLOSION")));
 663                         db_put(d, "TE_TEI_PLASMAHIT", "1");
 664                         LOG_INFO("effect TE_TEI_PLASMAHIT is ", ftos(_particleeffectnum("TE_TEI_PLASMAHIT")));
 665                         db_put(d, "EF_STARDUST", "1");
 666                         LOG_INFO("effect EF_STARDUST is ", ftos(_particleeffectnum("EF_STARDUST")));
 667                         db_put(d, "TR_ROCKET", "1");
 668                         LOG_INFO("effect TR_ROCKET is ", ftos(_particleeffectnum("TR_ROCKET")));
 669                         db_put(d, "TR_GRENADE", "1");
 670                         LOG_INFO("effect TR_GRENADE is ", ftos(_particleeffectnum("TR_GRENADE")));
 671                         db_put(d, "TR_BLOOD", "1");
 672                         LOG_INFO("effect TR_BLOOD is ", ftos(_particleeffectnum("TR_BLOOD")));
 673                         db_put(d, "TR_WIZSPIKE", "1");
 674                         LOG_INFO("effect TR_WIZSPIKE is ", ftos(_particleeffectnum("TR_WIZSPIKE")));
 675                         db_put(d, "TR_SLIGHTBLOOD", "1");
 676                         LOG_INFO("effect TR_SLIGHTBLOOD is ", ftos(_particleeffectnum("TR_SLIGHTBLOOD")));
 677                         db_put(d, "TR_KNIGHTSPIKE", "1");
 678                         LOG_INFO("effect TR_KNIGHTSPIKE is ", ftos(_particleeffectnum("TR_KNIGHTSPIKE")));
 679                         db_put(d, "TR_VORESPIKE", "1");
 680                         LOG_INFO("effect TR_VORESPIKE is ", ftos(_particleeffectnum("TR_VORESPIKE")));
 681                         db_put(d, "TR_NEHAHRASMOKE", "1");
 682                         LOG_INFO("effect TR_NEHAHRASMOKE is ", ftos(_particleeffectnum("TR_NEHAHRASMOKE")));
 683                         db_put(d, "TR_NEXUIZPLASMA", "1");
 684                         LOG_INFO("effect TR_NEXUIZPLASMA is ", ftos(_particleeffectnum("TR_NEXUIZPLASMA")));
 685                         db_put(d, "TR_GLOWTRAIL", "1");
 686                         LOG_INFO("effect TR_GLOWTRAIL is ", ftos(_particleeffectnum("TR_GLOWTRAIL")));
 687                         db_put(d, "TR_SEEKER", "1");
 688                         LOG_INFO("effect TR_SEEKER is ", ftos(_particleeffectnum("TR_SEEKER")));
 689                         db_put(d, "SVC_PARTICLE", "1");
 690                         LOG_INFO("effect SVC_PARTICLE is ", ftos(_particleeffectnum("SVC_PARTICLE")));
 691
 692                         fh = fopen("effectinfo.txt", FILE_READ);
 693                         while ((s = fgets(fh)))
 694                         {
 695                                 tokenize_console(s);
 696                                 if (argv(0) == "effect")
 697                                 {
 698                                         if (db_get(d, argv(1)) != "1")
 699                                         {
 700                                                 int i = _particleeffectnum(argv(1));
 701                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 702                                                 db_put(d, argv(1), "1");
 703                                         }
 704                                 }
 705                         }
 706                         LOG_INFO("end of effects list");
 707
 708                         db_close(d);
 709                         return;
 710                 }
 711
 712                 default:
 713                 case CMD_REQUEST_USAGE:
 714                 {
 715                         LOG_INFO("Usage:^3 sv_cmd effectindexdump");
 716                         LOG_INFO("  No arguments required.");
 717                         return;
 718                 }
 719         }
 720 }
 721
 722 void GameCommand_extendmatchtime(float request)
 723 {
 724         switch (request)
 725         {
 726                 case CMD_REQUEST_COMMAND:
 727                 {
 728                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 729                         return;
 730                 }
 731
 732                 default:
 733                 case CMD_REQUEST_USAGE:
 734                 {
 735                         LOG_INFO("Usage:^3 sv_cmd extendmatchtime");
 736                         LOG_INFO("  No arguments required.");
 737                         LOG_INFO("See also: ^2reducematchtime^7");
 738                         return;
 739                 }
 740         }
 741 }
 742
 743 void GameCommand_gametype(float request, float argc)
 744 {
 745         switch (request)
 746         {
 747                 case CMD_REQUEST_COMMAND:
 748                 {
 749                         if (argv(1) != "")
 750                         {
 751                                 string s = argv(1);
 752                                 Gametype t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 753
 754                                 if (t)
 755                                 {
 756                                         MapInfo_SwitchGameType(t);
 757                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 758                                         if (MapInfo_count > 0)
 759                                         {
 760                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 761                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 762                                                 lsmaps_reply = strzone(getlsmaps());
 763                                                 bprint("Game type successfully switched to ", s, "\n");
 764                                         }
 765                                         else
 766                                         {
 767                                                 bprint("Cannot use this game type: no map for it found\n");
 768                                                 MapInfo_SwitchGameType(tsave);
 769                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 770                                         }
 771                                 }
 772                                 else
 773                                 {
 774                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 775                                 }
 776
 777                                 return;
 778                         }
 779                 }
 780
 781                 default:
 782                         LOG_INFO("Incorrect parameters for ^2gametype^7");
 783                 case CMD_REQUEST_USAGE:
 784                 {
 785                         LOG_INFO("Usage:^3 sv_cmd gametype mode");
 786                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.");
 787                         LOG_INFO("See also: ^2gotomap^7");
 788                         return;
 789                 }
 790         }
 791 }
 792
 793 void GameCommand_gettaginfo(float request, float argc)
 794 {
 795         switch (request)
 796         {
 797                 case CMD_REQUEST_COMMAND:
 798                 {
 799                         entity tmp_entity;
 800                         float i;
 801                         vector v;
 802
 803                         if (argc >= 4)
 804                         {
 805                                 tmp_entity = spawn();
 806                                 if (argv(1) == "w")
 807                                 {
 808                                         .entity weaponentity = weaponentities[0];
 809                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 810                                 }
 811                                 else
 812                                 {
 813                                         precache_model(argv(1));
 814                                         _setmodel(tmp_entity, argv(1));
 815                                 }
 816                                 tmp_entity.frame = stof(argv(2));
 817                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 818                                 else i = gettagindex(tmp_entity, argv(3));
 819                                 if (i)
 820                                 {
 821                                         v = gettaginfo(tmp_entity, i);
 822                                         LOG_INFOF(
 823                                             "model %s frame %s tag %s index %s parent %s",
 824                                             tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 825                                         );
 826                                         LOG_INFOF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 827                                         LOG_INFOF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 828                                         LOG_INFOF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 829                                         LOG_INFOF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 830                                         LOG_INFOF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 831                                         if (argc >= 6)
 832                                         {
 833                                                 v.y = -v.y;
 834                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 835                                         }
 836                                 }
 837                                 else
 838                                 {
 839                                         LOG_INFO("bone not found");
 840                                 }
 841
 842                                 delete(tmp_entity);
 843                                 return;
 844                         }
 845                 }
 846
 847                 default:
 848                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 849                 case CMD_REQUEST_USAGE:
 850                 {
 851                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 852                         LOG_INFO("See also: ^2bbox, trace^7");
 853                         return;
 854                 }
 855         }
 856 }
 857
 858 void GameCommand_animbench(float request, float argc)
 859 {
 860         switch (request)
 861         {
 862                 case CMD_REQUEST_COMMAND:
 863                 {
 864                         entity tmp_entity;
 865
 866                         if (argc >= 4)
 867                         {
 868                                 tmp_entity = spawn();
 869                                 if (argv(1) == "w")
 870                                 {
 871                                         .entity weaponentity = weaponentities[0];
 872                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 873                                 }
 874                                 else
 875                                 {
 876                                         precache_model(argv(1));
 877                                         _setmodel(tmp_entity, argv(1));
 878                                 }
 879                                 float f1 = stof(argv(2));
 880                                 float f2 = stof(argv(3));
 881                                 float t0;
 882                                 float t1 = 0;
 883                                 float t2 = 0;
 884                                 float n = 0;
 885
 886                                 while (t1 + t2 < 1)
 887                                 {
 888                                         tmp_entity.frame = f1;
 889                                         t0 = gettime(GETTIME_HIRES);
 890                                         getsurfacepoint(tmp_entity, 0, 0);
 891                                         t1 += gettime(GETTIME_HIRES) - t0;
 892                                         tmp_entity.frame = f2;
 893                                         t0 = gettime(GETTIME_HIRES);
 894                                         getsurfacepoint(tmp_entity, 0, 0);
 895                                         t2 += gettime(GETTIME_HIRES) - t0;
 896                                         n += 1;
 897                                 }
 898                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 899                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 900
 901                                 delete(tmp_entity);
 902                                 return;
 903                         }
 904                 }
 905
 906                 default:
 907                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 908                 case CMD_REQUEST_USAGE:
 909                 {
 910                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 911                         LOG_INFO("See also: ^2bbox, trace^7");
 912                         return;
 913                 }
 914         }
 915 }
 916
 917 void GameCommand_gotomap(float request, float argc)
 918 {
 919         switch (request)
 920         {
 921                 case CMD_REQUEST_COMMAND:
 922                 {
 923                         if (argv(1))
 924                         {
 925                                 LOG_INFO(GotoMap(argv(1)));
 926                                 return;
 927                         }
 928                 }
 929
 930                 default:
 931                         LOG_INFO("Incorrect parameters for ^2gotomap^7");
 932                 case CMD_REQUEST_USAGE:
 933                 {
 934                         LOG_INFO("Usage:^3 sv_cmd gotomap map");
 935                         LOG_INFO("  Where 'map' is the *.bsp file to change to.");
 936                         LOG_INFO("See also: ^2gametype^7");
 937                         return;
 938                 }
 939         }
 940 }
 941
 942 void GameCommand_lockteams(float request)
 943 {
 944         switch (request)
 945         {
 946                 case CMD_REQUEST_COMMAND:
 947                 {
 948                         if (teamplay)
 949                         {
 950                                 lockteams = 1;
 951                                 bprint("^1The teams are now locked.\n");
 952                         }
 953                         else
 954                         {
 955                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 956                         }
 957                         return;
 958                 }
 959
 960                 default:
 961                 case CMD_REQUEST_USAGE:
 962                 {
 963                         LOG_INFO("Usage:^3 sv_cmd lockteams");
 964                         LOG_INFO("  No arguments required.");
 965                         LOG_INFO("See also: ^2unlockteams^7");
 966                         return;
 967                 }
 968         }
 969 }
 970
 971 void GameCommand_make_mapinfo(float request)
 972 {
 973         switch (request)
 974         {
 975                 case CMD_REQUEST_COMMAND:
 976                 {
 977                         entity tmp_entity;
 978
 979                         tmp_entity = new(make_mapinfo);
 980                         setthink(tmp_entity, make_mapinfo_Think);
 981                         tmp_entity.nextthink = time;
 982                         MapInfo_Enumerate();
 983                         return;
 984                 }
 985
 986                 default:
 987                 case CMD_REQUEST_USAGE:
 988                 {
 989                         LOG_INFO("Usage:^3 sv_cmd make_mapinfo");
 990                         LOG_INFO("  No arguments required.");
 991                         LOG_INFO("See also: ^2radarmap^7");
 992                         return;
 993                 }
 994         }
 995 }
 996
 997 void GameCommand_moveplayer(float request, float argc)
 998 {
 999         switch (request)
1000         {
1001                 case CMD_REQUEST_COMMAND:
1002                 {
1003                         float accepted;
1004                         entity client;
1005
1006                         string targets = strreplace(",", " ", argv(1));
1007                         string original_targets = strreplace(" ", ", ", targets);
1008                         string destination = argv(2);
1009
1010                         string successful, t;
1011                         successful = string_null;
1012
1013                         // lets see if the target(s) even actually exist.
1014                         if ((targets) && (destination))
1015                         {
1016                                 for ( ; targets; )
1017                                 {
1018                                         t = car(targets);
1019                                         targets = cdr(targets);
1020
1021                                         // Check to see if the player is a valid target
1022                                         client = GetFilteredEntity(t);
1023                                         accepted = VerifyClientEntity(client, false, false);
1024
1025                                         if (accepted <= 0)
1026                                         {
1027                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
1028                                                 continue;
1029                                         }
1030
1031                                         // Where are we putting this player?
1032                                         if (destination == "spec" || destination == "spectator")
1033                                         {
1034                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1035                                                 {
1036                                                         if (client.caplayer) client.caplayer = 0;
1037                                                         PutObserverInServer(client);
1038
1039                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1040                                                 }
1041                                                 else
1042                                                 {
1043                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already spectating.");
1044                                                 }
1045                                                 continue;
1046                                         }
1047                                         else
1048                                         {
1049                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1050                                                 {
1051                                                         if (teamplay)
1052                                                         {
1053                                                                 // set up
1054                                                                 float team_id;
1055                                                                 float save = client.team_forced;
1056                                                                 client.team_forced = 0;
1057
1058                                                                 // find the team to move the player to
1059                                                                 team_id = Team_ColorToTeam(destination);
1060                                                                 if (team_id == client.team)  // already on the destination team
1061                                                                 {
1062                                                                         // keep the forcing undone
1063                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7."));
1064                                                                         continue;
1065                                                                 }
1066                                                                 else if (team_id == 0)  // auto team
1067                                                                 {
1068                                                                         CheckAllowedTeams(client);
1069                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1070                                                                 }
1071                                                                 else
1072                                                                 {
1073                                                                         CheckAllowedTeams(client);
1074                                                                 }
1075                                                                 client.team_forced = save;
1076
1077                                                                 // Check to see if the destination team is even available
1078                                                                 switch (team_id)
1079                                                                 {
1080                                                                         case NUM_TEAM_1: if (c1 == -1) { LOG_INFO("Sorry, can't move player to red team if it doesn't exist."); return; } break;
1081                                                                         case NUM_TEAM_2: if (c2 == -1) { LOG_INFO("Sorry, can't move player to blue team if it doesn't exist."); return; } break;
1082                                                                         case NUM_TEAM_3: if (c3 == -1) { LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist."); return; } break;
1083                                                                         case NUM_TEAM_4: if (c4 == -1) { LOG_INFO("Sorry, can't move player to pink team if it doesn't exist."); return; } break;
1084
1085                                                                         default: LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.");
1086                                                                                 return;
1087                                                                 }
1088
1089                                                                 // If so, lets continue and finally move the player
1090                                                                 client.team_forced = 0;
1091                                                                 if (MoveToTeam(client, team_id, 6))
1092                                                                 {
1093                                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1094                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") has been moved to the ", Team_ColoredFullName(team_id), "^7.");
1095                                                                 }
1096                                                                 else
1097                                                                 {
1098                                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ")");
1099                                                                 }
1100                                                                 continue;
1101                                                         }
1102                                                         else
1103                                                         {
1104                                                                 LOG_INFO("Can't change teams when currently not playing a team game.");
1105                                                                 return;
1106                                                         }
1107                                                 }
1108                                                 else
1109                                                 {
1110                                                         LOG_INFO("Can't change teams if the player isn't in the game.");  // well technically we could, but should we allow that? :P
1111                                                         return;
1112                                                 }
1113                                         }
1114                                 }
1115
1116                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1117                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1118
1119                                 return;  // still correct parameters so return to avoid usage print
1120                         }
1121                 }
1122
1123                 default:
1124                         LOG_INFO("Incorrect parameters for ^2moveplayer^7");
1125                 case CMD_REQUEST_USAGE:
1126                 {
1127                         LOG_INFO("Usage:^3 sv_cmd moveplayer clients destination");
1128                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
1129                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating");
1130                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"");
1131                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3");
1132                         LOG_INFO("          sv_cmd moveplayer 2 spec ");
1133                         LOG_INFO("See also: ^2allspec, shuffleteams^7");
1134                         return;
1135                 }
1136         }
1137 }
1138
1139 void GameCommand_nospectators(float request)
1140 {
1141         switch (request)
1142         {
1143                 case CMD_REQUEST_COMMAND:
1144                 {
1145                         blockSpectators = 1;
1146                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1147                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1148                                 if(!it.caplayer)
1149                                 {
1150                                         CS(it).spectatortime = time;
1151                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1152                                 }
1153                         });
1154                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1155                         return;
1156                 }
1157
1158                 default:
1159                 case CMD_REQUEST_USAGE:
1160                 {
1161                         LOG_INFO("Usage:^3 sv_cmd nospectators");
1162                         LOG_INFO("  No arguments required.");
1163                         return;
1164                 }
1165         }
1166 }
1167
1168 void GameCommand_printstats(float request)
1169 {
1170         switch (request)
1171         {
1172                 case CMD_REQUEST_COMMAND:
1173                 {
1174                         DumpStats(false);
1175                         LOG_INFO("stats dumped.");
1176                         return;
1177                 }
1178
1179                 default:
1180                 case CMD_REQUEST_USAGE:
1181                 {
1182                         LOG_INFO("Usage:^3 sv_cmd printstats");
1183                         LOG_INFO("  No arguments required.");
1184                         return;
1185                 }
1186         }
1187 }
1188
1189 void GameCommand_radarmap(float request, float argc)
1190 {
1191         switch (request)
1192         {
1193                 case CMD_REQUEST_COMMAND:
1194                 {
1195                         if (RadarMap_Make(argc)) return;
1196                 }
1197
1198                 default:
1199                         LOG_INFO("Incorrect parameters for ^2radarmap^7");
1200                 case CMD_REQUEST_USAGE:
1201                 {
1202                         LOG_INFO("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1203                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.");
1204                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1205                         LOG_INFO("See also: ^2make_mapinfo^7");
1206                         return;
1207                 }
1208         }
1209 }
1210
1211 void GameCommand_reducematchtime(float request)
1212 {
1213         switch (request)
1214         {
1215                 case CMD_REQUEST_COMMAND:
1216                 {
1217                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1218                         return;
1219                 }
1220
1221                 default:
1222                 case CMD_REQUEST_USAGE:
1223                 {
1224                         LOG_INFO("Usage:^3 sv_cmd reducematchtime");
1225                         LOG_INFO("  No arguments required.");
1226                         LOG_INFO("See also: ^2extendmatchtime^7");
1227                         return;
1228                 }
1229         }
1230 }
1231
1232 void GameCommand_setbots(float request, float argc)
1233 {
1234         switch (request)
1235         {
1236                 case CMD_REQUEST_COMMAND:
1237                 {
1238                         if (argc >= 2)
1239                         {
1240                                 cvar_settemp("minplayers", "0");
1241                                 cvar_settemp("bot_number", argv(1));
1242                                 bot_fixcount();
1243                                 return;
1244                         }
1245                 }
1246
1247                 default:
1248                         LOG_INFO("Incorrect parameters for ^2setbots^7");
1249                 case CMD_REQUEST_USAGE:
1250                 {
1251                         LOG_INFO("Usage:^3 sv_cmd setbots botnumber");
1252                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.");
1253                         LOG_INFO("See also: ^2bot_cmd^7");
1254                         return;
1255                 }
1256         }
1257 }
1258
1259 void GameCommand_shuffleteams(float request)
1260 {
1261         switch (request)
1262         {
1263                 case CMD_REQUEST_COMMAND:
1264                 {
1265                         if (!teamplay)
1266                         {
1267                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1268                                 return;
1269                         }
1270
1271                         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1272                                 if (it.team_forced) {
1273                                         // we could theoretically assign forced players to their teams
1274                                         // and shuffle the rest to fill the empty spots but in practise
1275                                         // either all players or none are gonna have forced teams
1276                                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1277                                         return;
1278                                 }
1279                         });
1280
1281                         int number_of_teams = 0;
1282                         CheckAllowedTeams(NULL);
1283                         if (c1 >= 0) number_of_teams = max(1, number_of_teams);
1284                         if (c2 >= 0) number_of_teams = max(2, number_of_teams);
1285                         if (c3 >= 0) number_of_teams = max(3, number_of_teams);
1286                         if (c4 >= 0) number_of_teams = max(4, number_of_teams);
1287
1288                         int team_index = 0;
1289                         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1290                                 int target_team_number = Team_NumberToTeam(team_index + 1);
1291                                 if (it.team != target_team_number) MoveToTeam(it, target_team_number, 6);
1292                                 team_index = (team_index + 1) % number_of_teams;
1293                         });
1294
1295                         bprint("Successfully shuffled the players around randomly.\n");
1296                         return;
1297                 }
1298
1299                 default:
1300                 case CMD_REQUEST_USAGE:
1301                 {
1302                         LOG_INFO("Usage:^3 sv_cmd shuffleteams");
1303                         LOG_INFO("  No arguments required.");
1304                         LOG_INFO("See also: ^2moveplayer, allspec^7");
1305                         return;
1306                 }
1307         }
1308 }
1309
1310 void GameCommand_stuffto(float request, float argc)
1311 {
1312         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1313         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1314         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1315
1316 #ifdef STUFFTO_ENABLED
1317                 switch (request)
1318                 {
1319                         case CMD_REQUEST_COMMAND:
1320                         {
1321                                 if (argv(2))
1322                                 {
1323                                         entity client = GetIndexedEntity(argc, 1);
1324                                         float accepted = VerifyClientEntity(client, true, false);
1325
1326                                         if (accepted > 0)
1327                                         {
1328                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1329                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1330                                         }
1331                                         else
1332                                         {
1333                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1334                                         }
1335
1336                                         return;
1337                                 }
1338                         }
1339
1340                         default:
1341                                 LOG_INFO("Incorrect parameters for ^2stuffto^7");
1342                         case CMD_REQUEST_USAGE:
1343                         {
1344                                 LOG_INFO("Usage:^3 sv_cmd stuffto client \"command\"");
1345                                 LOG_INFO("  'client' is the entity number or name of the player,");
1346                                 LOG_INFO("  and 'command' is the command to be sent to that player.");
1347                                 return;
1348                         }
1349                 }
1350 #else
1351                 if (request)
1352                 {
1353                         LOG_INFO("stuffto command is not enabled on this server.");
1354                         return;
1355                 }
1356 #endif
1357 }
1358
1359 void GameCommand_trace(float request, float argc)
1360 {
1361         switch (request)
1362         {
1363                 case CMD_REQUEST_COMMAND:
1364                 {
1365                         entity e;
1366                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1367                         float i, f, safe, unsafe, dq, dqf;
1368
1369                         switch (argv(1))
1370                         {
1371                                 case "debug":
1372                                 {
1373                                         float hitcount = 0;
1374                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1375                                         float worst_endpos_bug = 0;
1376                                         for ( ; ; )
1377                                         {
1378                                                 org = world.mins;
1379                                                 delta = world.maxs - world.mins;
1380
1381                                                 start.x = org.x + random() * delta.x;
1382                                                 start.y = org.y + random() * delta.y;
1383                                                 start.z = org.z + random() * delta.z;
1384
1385                                                 end.x = org.x + random() * delta.x;
1386                                                 end.y = org.y + random() * delta.y;
1387                                                 end.z = org.z + random() * delta.z;
1388
1389                                                 start = stov(vtos(start));
1390                                                 end = stov(vtos(end));
1391
1392                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1393                                                 if (!trace_startsolid && trace_fraction < 1)
1394                                                 {
1395                                                         p = trace_endpos;
1396                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1397                                                         if (trace_startsolid)
1398                                                         {
1399                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1400                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1401
1402                                                                 // how much do we need to back off?
1403                                                                 safe = 1;
1404                                                                 unsafe = 0;
1405                                                                 for ( ; ; )
1406                                                                 {
1407                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1408                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1409                                                                         if (trace_startsolid)
1410                                                                         {
1411                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1412                                                                                 unsafe = (safe + unsafe) * 0.5;
1413                                                                         }
1414                                                                         else
1415                                                                         {
1416                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1417                                                                                 safe = (safe + unsafe) * 0.5;
1418                                                                         }
1419                                                                 }
1420
1421                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1422                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1423
1424                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1425                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1426                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1427                                                                 if (++hitcount >= 10) break;
1428                                                         }
1429                                                         else
1430                                                         {
1431                                                                 q0 = p;
1432                                                                 dq = 0;
1433                                                                 dqf = 1;
1434                                                                 for ( ; ; )
1435                                                                 {
1436                                                                         q = p + normalize(end - p) * (dq + dqf);
1437                                                                         if (q == q0) break;
1438                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1439                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1440                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1441                                                                         dqf *= 0.5;
1442                                                                         q0 = q;
1443                                                                 }
1444                                                                 if (dq > worst_endpos_bug)
1445                                                                 {
1446                                                                         worst_endpos_bug = dq;
1447                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1448                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1449                                                                         if (++hitcount >= 10) break;
1450                                                                 }
1451                                                         }
1452                                                 }
1453                                         }
1454                                         return;
1455                                 }
1456
1457                                 case "debug2":
1458                                 {
1459                                         e = nextent(NULL);
1460                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1461                                         vv = trace_endpos;
1462                                         if (trace_fraction == 1)
1463                                         {
1464                                                 LOG_INFO("not above ground, aborting");
1465                                                 return;
1466                                         }
1467                                         f = 0;
1468                                         for (i = 0; i < 100000; ++i)
1469                                         {
1470                                                 dv = randomvec();
1471                                                 if (dv.z > 0) dv = -1 * dv;
1472                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1473                                                 if (trace_startsolid) LOG_INFO("bug 1");
1474                                                 if (trace_fraction == 1)
1475                                                 {
1476                                                         if (dv.z < f)
1477                                                         {
1478                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1479                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1480                                                                 f = dv.z;
1481                                                         }
1482                                                 }
1483                                         }
1484                                         LOG_INFO("highest possible dist: ", ftos(f));
1485                                         return;
1486                                 }
1487
1488                                 case "walk":
1489                                 {
1490                                         if (argc == 4 || argc == 5)
1491                                         {
1492                                                 e = nextent(NULL);
1493                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1494                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1495                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1496                                                         LOG_INFO("can walk");
1497                                                 else
1498                                                         LOG_INFO("cannot walk");
1499                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1500                                                 return;
1501                                         }
1502                                 }
1503
1504                                 case "showline":
1505                                 {
1506                                         if (argc == 4)
1507                                         {
1508                                                 vv = stov(argv(2));
1509                                                 dv = stov(argv(3));
1510                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1511                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1512                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1513                                                 return;
1514                                         }
1515                                 }
1516
1517                                         // no default case, just go straight to invalid
1518                         }
1519                 }
1520
1521                 default:
1522                         LOG_INFO("Incorrect parameters for ^2trace^7");
1523                 case CMD_REQUEST_USAGE:
1524                 {
1525                         LOG_INFO("Usage:^3 sv_cmd trace command [startpos endpos] [endpos_height]");
1526                         LOG_INFO("  Where startpos and endpos are parameters for 'walk' and 'showline' commands,");
1527                         LOG_INFO("  'endpos_height' is an optional parameter for 'walk' command,");
1528                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"");
1529                         LOG_INFO("See also: ^2bbox, gettaginfo^7");
1530                         return;
1531                 }
1532         }
1533 }
1534
1535 void GameCommand_unlockteams(float request)
1536 {
1537         switch (request)
1538         {
1539                 case CMD_REQUEST_COMMAND:
1540                 {
1541                         if (teamplay)
1542                         {
1543                                 lockteams = 0;
1544                                 bprint("^1The teams are now unlocked.\n");
1545                         }
1546                         else
1547                         {
1548                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1549                         }
1550                         return;
1551                 }
1552
1553                 default:
1554                 case CMD_REQUEST_USAGE:
1555                 {
1556                         LOG_INFO("Usage:^3 sv_cmd unlockteams");
1557                         LOG_INFO("  No arguments required.");
1558                         LOG_INFO("See also: ^2lockteams^7");
1559                         return;
1560                 }
1561         }
1562 }
1563
1564 void GameCommand_warp(float request, float argc)
1565 {
1566         switch (request)
1567         {
1568                 case CMD_REQUEST_COMMAND:
1569                 {
1570                         if (autocvar_g_campaign)
1571                         {
1572                                 if (argc >= 2)
1573                                 {
1574                                         CampaignLevelWarp(stof(argv(1)));
1575                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1576                                 }
1577                                 else
1578                                 {
1579                                         CampaignLevelWarp(-1);
1580                                         LOG_INFO("Successfully warped to next campaign level.");
1581                                 }
1582                         }
1583                         else
1584                         {
1585                                 LOG_INFO("Not in campaign, can't level warp");
1586                         }
1587                         return;
1588                 }
1589
1590                 default:
1591                 case CMD_REQUEST_USAGE:
1592                 {
1593                         LOG_INFO("Usage:^3 sv_cmd warp [level]");
1594                         LOG_INFO("  'level' is the level to change campaign mode to.");
1595                         LOG_INFO("  if 'level' is not provided it will change to the next level.");
1596                         return;
1597                 }
1598         }
1599 }
1600
1601 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1602 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1603 void GameCommand_(float request)
1604 {
1605     switch(request)
1606     {
1607         case CMD_REQUEST_COMMAND:
1608         {
1609
1610             return;
1611         }
1612
1613         default:
1614         case CMD_REQUEST_USAGE:
1615         {
1616             print("\nUsage:^3 sv_cmd \n");
1617             print("  No arguments required.\n");
1618             return;
1619         }
1620     }
1621 }
1622 */
1623
1624
1625 // ==================================
1626 //  Macro system for server commands
1627 // ==================================
1628
1629 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1630 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1631 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1632 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1633 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1634 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1635 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1636 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1637 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1638 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1639 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1640 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1641 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1642 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1643 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1644 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1645 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1646 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1647 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1648 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1649 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1650 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1651 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1652 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1653 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1654 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1655 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1656 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1657 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1658 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1659 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1660
1661 void GameCommand_macro_help()
1662 {
1663         FOREACH(SERVER_COMMANDS, true, { LOG_INFOF("  ^2%s^7: %s", it.m_name, it.m_description); });
1664 }
1665
1666 float GameCommand_macro_command(float argc, string command)
1667 {
1668         string c = strtolower(argv(0));
1669         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1670                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1671                 return true;
1672         });
1673         return false;
1674 }
1675
1676 float GameCommand_macro_usage(float argc)
1677 {
1678         string c = strtolower(argv(1));
1679         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1680                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1681                 return true;
1682         });
1683         return false;
1684 }
1685
1686 void GameCommand_macro_write_aliases(float fh)
1687 {
1688         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1689 }
1690
1691
1692 // =========================================
1693 //  Main Function Called By Engine (sv_cmd)
1694 // =========================================
1695 // If this function exists, game code handles gamecommand instead of the engine code.
1696
1697 void GameCommand(string command)
1698 {
1699         float argc = tokenize_console(command);
1700
1701         // Guide for working with argc arguments by example:
1702         // argc:   1    - 2      - 3     - 4
1703         // argv:   0    - 1      - 2     - 3
1704         // cmd     vote - master - login - password
1705
1706         if (strtolower(argv(0)) == "help")
1707         {
1708                 if (argc == 1)
1709                 {
1710                         LOG_INFO("Server console commands:");
1711                         GameCommand_macro_help();
1712
1713                         LOG_INFO("\nBanning commands:");
1714                         BanCommand_macro_help();
1715
1716                         LOG_INFO("\nCommon networked commands:");
1717                         CommonCommand_macro_help(NULL);
1718
1719                         LOG_INFO("\nGeneric commands shared by all programs:");
1720                         GenericCommand_macro_help();
1721
1722                         LOG_INFO(
1723                             "\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n"
1724                 "For help about a specific command, type sv_cmd help COMMAND"
1725             );
1726
1727                         return;
1728                 }
1729                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1730                 {
1731                         return;
1732                 }
1733                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1734                 {
1735                         return;
1736                 }
1737                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1738                 {
1739                         return;
1740                 }
1741                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1742                 {
1743                         return;
1744                 }
1745         }
1746         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1747         {
1748                 return;  // handled by a mutator
1749         }
1750         else if (BanCommand(command))
1751         {
1752                 return;  // handled by server/command/ipban.qc
1753         }
1754         else if (CommonCommand_macro_command(argc, NULL, command))
1755         {
1756                 return;  // handled by server/command/common.qc
1757         }
1758         else if (GenericCommand(command))
1759         {
1760                 return;                                        // handled by common/command/generic.qc
1761         }
1762         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1763         {
1764                 return;                                        // handled by one of the above GameCommand_* functions
1765         }
1766
1767         // nothing above caught the command, must be invalid
1768         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1769 }