qcsrc/server/command/sv_cmd.qc

   1 #include "../../common/command/command.qh"
   2 #include "sv_cmd.qh"
   3 #include "../_all.qh"
   4
   5 #include "banning.qh"
   6 #include "cmd.qh"
   7 #include "common.qh"
   8 #include "getreplies.qh"
   9 #include "radarmap.qh"
  10
  11 #include "../anticheat.qh"
  12 #include "../campaign.qh"
  13 #include "../cl_client.qh"
  14 #include "../cl_player.qh"
  15 #include "../g_world.qh"
  16 #include "../ipban.qh"
  17 #include "../playerdemo.qh"
  18 #include "../teamplay.qh"
  19
  20 #include "../bot/bot.qh"
  21 #include "../bot/navigation.qh"
  22 #include "../bot/scripting.qh"
  23
  24 #include "../mutators/mutators_include.qh"
  25
  26 #include "../../common/constants.qh"
  27 #include "../../common/mapinfo.qh"
  28 #include "../../common/notifications.qh"
  29 #include "../../common/teams.qh"
  30 #include "../../common/util.qh"
  31
  32 #include "../../common/monsters/sv_monsters.qh"
  33
  34 #include "../../warpzonelib/mathlib.qh"
  35
  36 void PutObserverInServer (void);
  37
  38 // =====================================================
  39 //  Server side game commands code, reworked by Samual
  40 //  Last updated: December 29th, 2011
  41 // =====================================================
  42
  43 //  used by GameCommand_make_mapinfo()
  44 void make_mapinfo_Think()
  45 {
  46         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  47         {
  48                 print("Done rebuiling mapinfos.\n");
  49                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  50                 remove(self);
  51         }
  52         else
  53         {
  54                 self.think = make_mapinfo_Think;
  55                 self.nextthink = time;
  56         }
  57 }
  58
  59 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  60 void changematchtime(float delta, float mi, float ma)
  61 {
  62         float cur;
  63         float update;
  64         float lim;
  65
  66         if(delta == 0)
  67                 return;
  68         if(autocvar_timelimit < 0)
  69                 return;
  70
  71         if(mi <= 10)
  72                 mi = 10; // at least ten sec in the future
  73         cur = time - game_starttime;
  74         if(cur > 0)
  75                 mi += cur; // from current time!
  76
  77         lim = autocvar_timelimit * 60;
  78
  79         if(delta > 0)
  80         {
  81                 if(lim == 0)
  82                         return; // cannot increase any further
  83                 else if(lim < ma)
  84                         update = min(ma, lim + delta);
  85                 else // already above maximum: FAIL
  86                         return;
  87         }
  88         else
  89         {
  90                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  91                         update = max(mi, ma);
  92                 else if(lim > mi) // above minimum: decrease
  93                         update = max(mi, lim + delta);
  94                 else // already below minimum: FAIL
  95                         return;
  96         }
  97
  98         cvar_set("timelimit", ftos(update / 60));
  99 }
 100
 101
 102 // =======================
 103 //  Command Sub-Functions
 104 // =======================
 105
 106 void GameCommand_adminmsg(float request, float argc)
 107 {
 108         switch(request)
 109         {
 110                 case CMD_REQUEST_COMMAND:
 111                 {
 112                         entity client;
 113                         float accepted;
 114
 115                         string targets = strreplace(",", " ", argv(1));
 116                         string original_targets = strreplace(" ", ", ", targets);
 117                         string admin_message = argv(2);
 118                         float infobartime = stof(argv(3));
 119
 120                         string successful, t;
 121                         successful = string_null;
 122
 123                         if((targets) && (admin_message))
 124                         {
 125                                 for (;targets;)
 126                                 {
 127                                         t = car(targets); targets = cdr(targets);
 128
 129                                         // Check to see if the player is a valid target
 130                                         client = GetFilteredEntity(t);
 131                                         accepted = VerifyClientEntity(client, true, false);
 132
 133                                         if(accepted <= 0)
 134                                         {
 135                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 136                                                 continue;
 137                                         }
 138
 139                                         // send the centerprint/console print or infomessage
 140                                         if(infobartime)
 141                                         {
 142                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 143                                         }
 144                                         else
 145                                         {
 146                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 147                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 148                                         }
 149
 150                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 151                                         dprint("Message sent to ", client.netname, "\n");
 152                                         continue;
 153                                 }
 154
 155                                 if(successful)
 156                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 157                                 else
 158                                         print("No players given (", original_targets, ") could receive the message.\n");
 159
 160                                 return;
 161                         }
 162                 }
 163
 164                 default:
 165                         print("Incorrect parameters for ^2adminmsg^7\n");
 166                 case CMD_REQUEST_USAGE:
 167                 {
 168                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 169                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 170                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 171                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 172                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 173                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 174                         return;
 175                 }
 176         }
 177 }
 178
 179 void GameCommand_mobbutcher(float request)
 180 {
 181         switch(request)
 182         {
 183                 case CMD_REQUEST_COMMAND:
 184                 {
 185                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
 186                         if(g_invasion) { print("This command doesn't work during an invasion.\n"); return; }
 187
 188                         float removed_count = 0;
 189                         entity head;
 190
 191                         FOR_EACH_MONSTER(head)
 192                         {
 193                                 monster_remove(head);
 194                                 ++removed_count;
 195                         }
 196
 197                         monsters_total = 0; // reset stats?
 198                         monsters_killed = 0;
 199
 200                         totalspawned = 0;
 201
 202                         if(removed_count <= 0)
 203                                 print("No monsters to kill\n");
 204                         else
 205                                 printf("Killed %d monster%s\n", removed_count, ((removed_count == 1) ? "" : "s"));
 206
 207                         return; // never fall through to usage
 208                 }
 209
 210                 default:
 211                 case CMD_REQUEST_USAGE:
 212                 {
 213                         print("\nUsage:^3 sv_cmd mobbutcher\n");
 214                         print("  No arguments required.\n");
 215                         return;
 216                 }
 217         }
 218 }
 219
 220 void GameCommand_allready(float request)
 221 {
 222         switch(request)
 223         {
 224                 case CMD_REQUEST_COMMAND:
 225                 {
 226                         ReadyRestart();
 227                         return;
 228                 }
 229
 230                 default:
 231                 case CMD_REQUEST_USAGE:
 232                 {
 233                         print("\nUsage:^3 sv_cmd allready\n");
 234                         print("  No arguments required.\n");
 235                         return;
 236                 }
 237         }
 238 }
 239
 240 void GameCommand_allspec(float request, float argc)
 241 {
 242         switch(request)
 243         {
 244                 case CMD_REQUEST_COMMAND:
 245                 {
 246                         entity client;
 247                         string reason = argv(1);
 248                         float i = 0;
 249
 250                         FOR_EACH_REALPLAYER(client)
 251                         {
 252                                 self = client;
 253                                 if(self.caplayer)
 254                                         self.caplayer = 0;
 255                                 PutObserverInServer();
 256                                 ++i;
 257                         }
 258                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 259                         else { print("No players found to spectate.\n"); }
 260                         return;
 261                 }
 262
 263                 default:
 264                 case CMD_REQUEST_USAGE:
 265                 {
 266                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 267                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 268                         print("See also: ^2moveplayer, shuffleteams^7\n");
 269                         return;
 270                 }
 271         }
 272 }
 273
 274 void GameCommand_anticheat(float request, float argc)
 275 {
 276         switch(request)
 277         {
 278                 case CMD_REQUEST_COMMAND:
 279                 {
 280                         entity client = GetIndexedEntity(argc, 1);
 281                         float accepted = VerifyClientEntity(client, false, false);
 282
 283                         if(accepted > 0)
 284                         {
 285                                 self = client;
 286                                 anticheat_report();
 287                                 return;
 288                         }
 289                         else
 290                         {
 291                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 292                         }
 293                 }
 294
 295                 default:
 296                         print("Incorrect parameters for ^2anticheat^7\n");
 297                 case CMD_REQUEST_USAGE:
 298                 {
 299                         print("\nUsage:^3 sv_cmd anticheat client\n");
 300                         print("  'client' is the entity number or name of the player.\n");
 301                         return;
 302                 }
 303         }
 304 }
 305
 306 void GameCommand_bbox(float request)
 307 {
 308         switch(request)
 309         {
 310                 case CMD_REQUEST_COMMAND:
 311                 {
 312                         print("Original size: ", ftos(world.absmin.x), " ", ftos(world.absmin.y), " ", ftos(world.absmin.z));
 313                         print(" ", ftos(world.absmax.x), " ", ftos(world.absmax.y), " ", ftos(world.absmax.z), "\n");
 314                         print("Currently set size: ", ftos(world.mins.x), " ", ftos(world.mins.y), " ", ftos(world.mins.z));
 315                         print(" ", ftos(world.maxs.x), " ", ftos(world.maxs.y), " ", ftos(world.maxs.z), "\n");
 316                         print("Solid bounding box size:");
 317
 318                         tracebox('1 0 0' * world.absmin.x,
 319                                                         '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 320                                                         '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 321                                                         '1 0 0' * world.absmax.x,
 322                                         MOVE_WORLDONLY,
 323                                         world);
 324                         if(trace_startsolid)
 325                                 print(" ", ftos(world.absmin.x));
 326                         else
 327                                 print(" ", ftos(trace_endpos.x));
 328
 329                         tracebox('0 1 0' * world.absmin.y,
 330                                                         '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 331                                                         '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 332                                                         '0 1 0' * world.absmax.y,
 333                                         MOVE_WORLDONLY,
 334                                         world);
 335                         if(trace_startsolid)
 336                                 print(" ", ftos(world.absmin.y));
 337                         else
 338                                 print(" ", ftos(trace_endpos.y));
 339
 340                         tracebox('0 0 1' * world.absmin.z,
 341                                                         '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 342                                                         '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 343                                                         '0 0 1' * world.absmax.z,
 344                                         MOVE_WORLDONLY,
 345                                         world);
 346                         if(trace_startsolid)
 347                                 print(" ", ftos(world.absmin.z));
 348                         else
 349                                 print(" ", ftos(trace_endpos.z));
 350
 351                         tracebox('1 0 0' * world.absmax.x,
 352                                                         '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 353                                                         '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 354                                                         '1 0 0' * world.absmin.x,
 355                                         MOVE_WORLDONLY,
 356                                         world);
 357                         if(trace_startsolid)
 358                                 print(" ", ftos(world.absmax.x));
 359                         else
 360                                 print(" ", ftos(trace_endpos.x));
 361
 362                         tracebox('0 1 0' * world.absmax.y,
 363                                                         '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 364                                                         '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 365                                                         '0 1 0' * world.absmin.y,
 366                                         MOVE_WORLDONLY,
 367                                         world);
 368                         if(trace_startsolid)
 369                                 print(" ", ftos(world.absmax.y));
 370                         else
 371                                 print(" ", ftos(trace_endpos.y));
 372
 373                         tracebox('0 0 1' * world.absmax.z,
 374                                                         '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 375                                                         '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 376                                                         '0 0 1' * world.absmin.z,
 377                                         MOVE_WORLDONLY,
 378                                         world);
 379                         if(trace_startsolid)
 380                                 print(" ", ftos(world.absmax.z));
 381                         else
 382                                 print(" ", ftos(trace_endpos.z));
 383
 384                         print("\n");
 385                         return;
 386                 }
 387
 388                 default:
 389                 case CMD_REQUEST_USAGE:
 390                 {
 391                         print("\nUsage:^3 sv_cmd bbox\n");
 392                         print("  No arguments required.\n");
 393                         print("See also: ^2gettaginfo, trace^7\n");
 394                         return;
 395                 }
 396         }
 397 }
 398
 399 void GameCommand_bot_cmd(float request, float argc, string command)
 400 {
 401         switch(request)
 402         {
 403                 case CMD_REQUEST_COMMAND:
 404                 {
 405                         entity bot;
 406
 407                         if(argv(1) == "reset")
 408                         {
 409                                 bot_resetqueues();
 410                                 return;
 411                         }
 412                         else if(argv(1) == "setbots")
 413                         {
 414                                 cvar_settemp("bot_vs_human", "0");
 415                                 cvar_settemp("minplayers", "0");
 416                                 cvar_settemp("bot_number", "0");
 417                                 bot_fixcount();
 418                                 cvar_settemp("bot_number", argv(2));
 419                                 if(!bot_fixcount())
 420                                         print("Sorry, could not set requested bot count\n");
 421                                 return;
 422                         }
 423                         else if(argv(1) == "load" && argc == 3)
 424                         {
 425                                 float fh, i;
 426                                 string s;
 427                                 fh = fopen(argv(2), FILE_READ);
 428                                 if(fh < 0)
 429                                 {
 430                                         print("cannot open the file\n");
 431                                         return;
 432                                 }
 433
 434                                 i = 0;
 435                                 while((s = fgets(fh)))
 436                                 {
 437                                         argc = tokenize_console(s);
 438
 439                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 440                                         {
 441                                                 if(argv(2) == "reset")
 442                                                 {
 443                                                         bot_resetqueues();
 444                                                 }
 445                                                 else if(argv(2) == "setbots")
 446                                                 {
 447                                                         cvar_settemp("bot_vs_human", "0");
 448                                                         cvar_settemp("minplayers", "0");
 449                                                         cvar_settemp("bot_number", "0");
 450                                                         bot_fixcount();
 451                                                         cvar_settemp("bot_number", argv(3));
 452                                                         if(!bot_fixcount())
 453                                                                 print("Sorry, could not set requested bot count\n");
 454                                                 }
 455                                                 else
 456                                                 {
 457                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 458                                                         bot = find_bot_by_number(stof(argv(2)));
 459                                                         if(bot == world)
 460                                                                 bot = find_bot_by_name(argv(2));
 461                                                         if(bot)
 462                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 463                                                 }
 464                                         }
 465                                         else
 466                                                 localcmd(strcat(s, "\n"));
 467
 468                                         ++i;
 469                                 }
 470                                 print(ftos(i), " commands read\n");
 471                                 fclose(fh);
 472                                 return;
 473                         }
 474                         else if(argv(1) == "help")
 475                         {
 476                                 if(argv(2))
 477                                         bot_cmdhelp(argv(2));
 478                                 else
 479                                         bot_list_commands();
 480                                 return;
 481                         }
 482                         else if(argc >= 3) // this comes last
 483                         {
 484                                 bot = find_bot_by_number(stof(argv(1)));
 485                                 if(bot == world)
 486                                         bot = find_bot_by_name(argv(1));
 487                                 if(bot)
 488                                 {
 489                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 490                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 491                                         return;
 492                                 }
 493                                 else
 494                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 495                         }
 496                 }
 497
 498                 default:
 499                         print("Incorrect parameters for ^2bot_cmd^7\n");
 500                 case CMD_REQUEST_USAGE:
 501                 {
 502                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 503                         print("  'client' can be either the name or entity id of the bot\n");
 504                         print("  For full list of commands, see bot_cmd help [command].\n");
 505                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 506                         print("          sv_cmd bot_cmd client presskey jump\n");
 507                         return;
 508                 }
 509         }
 510 }
 511
 512 void GameCommand_cointoss(float request, float argc)
 513 {
 514         switch(request)
 515         {
 516                 case CMD_REQUEST_COMMAND:
 517                 {
 518                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 519                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 520                         string choice = ((random() > 0.5) ? result1 : result2);
 521
 522                         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_COINTOSS, choice);
 523                         return;
 524                 }
 525
 526                 default:
 527                 case CMD_REQUEST_USAGE:
 528                 {
 529                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 530                         print("  Where 'result1' and 'result2' are user created options.\n");
 531                         return;
 532                 }
 533         }
 534 }
 535
 536 void GameCommand_database(float request, float argc)
 537 {
 538         switch(request)
 539         {
 540                 case CMD_REQUEST_COMMAND:
 541                 {
 542                         if(argc == 3)
 543                         {
 544                                 if(argv(1) == "save")
 545                                 {
 546                                         db_save(ServerProgsDB, argv(2));
 547                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 548                                         return;
 549                                 }
 550                                 else if(argv(1) == "dump")
 551                                 {
 552                                         db_dump(ServerProgsDB, argv(2));
 553                                         print("DB dumped.\n"); // wtf does this do?
 554                                         return;
 555                                 }
 556                                 else if(argv(1) == "load")
 557                                 {
 558                                         db_close(ServerProgsDB);
 559                                         ServerProgsDB = db_load(argv(2));
 560                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 561                                         return;
 562                                 }
 563                         }
 564                 }
 565
 566                 default:
 567                         print("Incorrect parameters for ^2database^7\n");
 568                 case CMD_REQUEST_USAGE:
 569                 {
 570                         print("\nUsage:^3 sv_cmd database action filename\n");
 571                         print("  Where 'action' is the command to complete,\n");
 572                         print("  and 'filename' is what it acts upon.\n");
 573                         print("  Full list of commands here: \"save, dump, load.\"\n");
 574                         return;
 575                 }
 576         }
 577 }
 578
 579 void GameCommand_defer_clear(float request, float argc)
 580 {
 581         switch(request)
 582         {
 583                 case CMD_REQUEST_COMMAND:
 584                 {
 585                         entity client;
 586                         float accepted;
 587
 588                         if(argc >= 2)
 589                         {
 590                                 client = GetIndexedEntity(argc, 1);
 591                                 accepted = VerifyClientEntity(client, true, false);
 592
 593                                 if(accepted > 0)
 594                                 {
 595                                         stuffcmd(client, "defer clear\n");
 596                                         print("defer clear stuffed to ", client.netname, "\n");
 597                                 }
 598                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 599
 600                                 return;
 601                         }
 602                 }
 603
 604                 default:
 605                         print("Incorrect parameters for ^2defer_clear^7\n");
 606                 case CMD_REQUEST_USAGE:
 607                 {
 608                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 609                         print("  'client' is the entity number or name of the player.\n");
 610                         print("See also: ^2defer_clear_all^7\n");
 611                         return;
 612                 }
 613         }
 614 }
 615
 616 void GameCommand_defer_clear_all(float request)
 617 {
 618         switch(request)
 619         {
 620                 case CMD_REQUEST_COMMAND:
 621                 {
 622                         entity client;
 623                         float i = 0;
 624                         float argc;
 625
 626                         FOR_EACH_CLIENT(client)
 627                         {
 628                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 629                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 630                                 ++i;
 631                         }
 632                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 633                         return;
 634                 }
 635
 636                 default:
 637                 case CMD_REQUEST_USAGE:
 638                 {
 639                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 640                         print("  No arguments required.\n");
 641                         print("See also: ^2defer_clear^7\n");
 642                         return;
 643                 }
 644         }
 645 }
 646
 647 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 648 {
 649         switch(request)
 650         {
 651                 case CMD_REQUEST_COMMAND:
 652                 {
 653                         if(argv(1))
 654                         {
 655                                 if(argv(2))
 656                                         race_deleteTime(argv(2), stof(argv(1)));
 657                                 else
 658                                         race_deleteTime(GetMapname(), stof(argv(1)));
 659                                 return;
 660                         }
 661                 }
 662
 663                 default:
 664                         print("Incorrect parameters for ^2delrec^7\n");
 665                 case CMD_REQUEST_USAGE:
 666                 {
 667                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 668                         print("  'ranking' is which ranking level to clear up to, \n");
 669                         print("  it will clear all records up to nth place.\n");
 670                         print("  if 'map' is not provided it will use current map.\n");
 671                         return;
 672                 }
 673         }
 674 }
 675
 676 void GameCommand_effectindexdump(float request)
 677 {
 678         switch(request)
 679         {
 680                 case CMD_REQUEST_COMMAND:
 681                 {
 682                         float fh, d;
 683                         string s;
 684
 685                         d = db_create();
 686                         print("begin of effects list\n");
 687                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 688                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 689                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 690                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 691                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 692                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 693                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 694                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 695                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 696                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 697                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 698                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 699                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 700                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 701                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 702                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 703                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 704                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 705                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 706                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 707                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 708                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 709                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 710                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 711                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 712                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 713                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 714                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 715                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 716                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 717                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 718                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 719                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 720                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 721                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 722                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 723
 724                         fh = fopen("effectinfo.txt", FILE_READ);
 725                         while((s = fgets(fh)))
 726                         {
 727                                 tokenize_console(s);
 728                                 if(argv(0) == "effect")
 729                                 {
 730                                         if(db_get(d, argv(1)) != "1")
 731                                         {
 732                                                 if(particleeffectnum(argv(1)) >= 0)
 733                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 734                                                 db_put(d, argv(1), "1");
 735                                         }
 736                                 }
 737                         }
 738                         print("end of effects list\n");
 739
 740                         db_close(d);
 741                         return;
 742                 }
 743
 744                 default:
 745                 case CMD_REQUEST_USAGE:
 746                 {
 747                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 748                         print("  No arguments required.\n");
 749                         return;
 750                 }
 751         }
 752 }
 753
 754 void GameCommand_extendmatchtime(float request)
 755 {
 756         switch(request)
 757         {
 758                 case CMD_REQUEST_COMMAND:
 759                 {
 760                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 761                         return;
 762                 }
 763
 764                 default:
 765                 case CMD_REQUEST_USAGE:
 766                 {
 767                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 768                         print("  No arguments required.\n");
 769                         print("See also: ^2reducematchtime^7\n");
 770                         return;
 771                 }
 772         }
 773 }
 774
 775 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 776 {
 777         switch(request)
 778         {
 779                 case CMD_REQUEST_COMMAND:
 780                 {
 781                         entity client;
 782
 783                         for(client = world; (client = find(client, classname, argv(1))); )
 784                                 print(etos(client), "\n");
 785
 786                         return;
 787                 }
 788
 789                 default:
 790                         print("Incorrect parameters for ^2find^7\n");
 791                 case CMD_REQUEST_USAGE:
 792                 {
 793                         print("\nUsage:^3 sv_cmd find classname\n");
 794                         print("  Where 'classname' is the classname to search for.\n");
 795                         return;
 796                 }
 797         }
 798 }
 799
 800 void GameCommand_gametype(float request, float argc)
 801 {
 802         switch(request)
 803         {
 804                 case CMD_REQUEST_COMMAND:
 805                 {
 806                         if(argv(1) != "")
 807                         {
 808                                 string s = argv(1);
 809                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 810
 811                                 if(t)
 812                                 {
 813                                         MapInfo_SwitchGameType(t);
 814                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 815                                         if(MapInfo_count > 0)
 816                                         {
 817                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 818                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 819                                                 lsmaps_reply = strzone(getlsmaps());
 820                                                 bprint("Game type successfully switched to ", s, "\n");
 821                                         }
 822                                         else
 823                                         {
 824                                                 bprint("Cannot use this game type: no map for it found\n");
 825                                                 MapInfo_SwitchGameType(tsave);
 826                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 827                                         }
 828                                 }
 829                                 else
 830                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 831
 832                                 return;
 833                         }
 834                 }
 835
 836                 default:
 837                         print("Incorrect parameters for ^2gametype^7\n");
 838                 case CMD_REQUEST_USAGE:
 839                 {
 840                         print("\nUsage:^3 sv_cmd gametype mode\n");
 841                         print("  Where 'mode' is the gametype mode to switch to.\n");
 842                         print("See also: ^2gotomap^7\n");
 843                         return;
 844                 }
 845         }
 846 }
 847
 848 void GameCommand_gettaginfo(float request, float argc)
 849 {
 850         switch(request)
 851         {
 852                 case CMD_REQUEST_COMMAND:
 853                 {
 854                         entity tmp_entity;
 855                         float i;
 856                         vector v;
 857
 858                         if(argc >= 4)
 859                         {
 860                                 tmp_entity = spawn();
 861                                 if(argv(1) == "w")
 862                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 863                                 else
 864                                 {
 865                                         precache_model(argv(1));
 866                                         setmodel(tmp_entity, argv(1));
 867                                 }
 868                                 tmp_entity.frame = stof(argv(2));
 869                                 if(substring(argv(3), 0, 1) == "#")
 870                                         i = stof(substring(argv(3), 1, -1));
 871                                 else
 872                                         i = gettagindex(tmp_entity, argv(3));
 873                                 if(i)
 874                                 {
 875                                         v = gettaginfo(tmp_entity, i);
 876                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 877                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 878                                         print(" vector = ", ftos(v.x), " ", ftos(v.y), " ", ftos(v.z), "\n");
 879                                         print(" offset = ", ftos(gettaginfo_offset.x), " ", ftos(gettaginfo_offset.y), " ", ftos(gettaginfo_offset.z), "\n");
 880                                         print(" forward = ", ftos(gettaginfo_forward.x), " ", ftos(gettaginfo_forward.y), " ", ftos(gettaginfo_forward.z), "\n");
 881                                         print(" right = ", ftos(gettaginfo_right.x), " ", ftos(gettaginfo_right.y), " ", ftos(gettaginfo_right.z), "\n");
 882                                         print(" up = ", ftos(gettaginfo_up.x), " ", ftos(gettaginfo_up.y), " ", ftos(gettaginfo_up.z), "\n");
 883                                         if(argc >= 6)
 884                                         {
 885                                                 v.y = -v.y;
 886                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 887                                         }
 888                                 }
 889                                 else
 890                                         print("bone not found\n");
 891
 892                                 remove(tmp_entity);
 893                                 return;
 894                         }
 895                 }
 896
 897                 default:
 898                         print("Incorrect parameters for ^2gettaginfo^7\n");
 899                 case CMD_REQUEST_USAGE:
 900                 {
 901                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 902                         print("See also: ^2bbox, trace^7\n");
 903                         return;
 904                 }
 905         }
 906 }
 907
 908 void GameCommand_animbench(float request, float argc)
 909 {
 910         switch(request)
 911         {
 912                 case CMD_REQUEST_COMMAND:
 913                 {
 914                         entity tmp_entity;
 915
 916                         if(argc >= 4)
 917                         {
 918                                 tmp_entity = spawn();
 919                                 if(argv(1) == "w")
 920                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 921                                 else
 922                                 {
 923                                         precache_model(argv(1));
 924                                         setmodel(tmp_entity, argv(1));
 925                                 }
 926                                 float f1 = stof(argv(2));
 927                                 float f2 = stof(argv(3));
 928                                 float t0;
 929                                 float t1 = 0;
 930                                 float t2 = 0;
 931                                 float n = 0;
 932
 933                                 while(t1 + t2 < 1)
 934                                 {
 935                                         tmp_entity.frame = f1;
 936                                         t0 = gettime(GETTIME_HIRES);
 937                                         getsurfacepoint(tmp_entity, 0, 0);
 938                                         t1 += gettime(GETTIME_HIRES) - t0;
 939                                         tmp_entity.frame = f2;
 940                                         t0 = gettime(GETTIME_HIRES);
 941                                         getsurfacepoint(tmp_entity, 0, 0);
 942                                         t2 += gettime(GETTIME_HIRES) - t0;
 943                                         n += 1;
 944                                 }
 945                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 946                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 947
 948                                 remove(tmp_entity);
 949                                 return;
 950                         }
 951                 }
 952
 953                 default:
 954                         print("Incorrect parameters for ^2gettaginfo^7\n");
 955                 case CMD_REQUEST_USAGE:
 956                 {
 957                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 958                         print("See also: ^2bbox, trace^7\n");
 959                         return;
 960                 }
 961         }
 962 }
 963
 964 void GameCommand_gotomap(float request, float argc)
 965 {
 966         switch(request)
 967         {
 968                 case CMD_REQUEST_COMMAND:
 969                 {
 970                         if(argv(1))
 971                         {
 972                                 print(GotoMap(argv(1)), "\n");
 973                                 return;
 974                         }
 975                 }
 976
 977                 default:
 978                         print("Incorrect parameters for ^2gotomap^7\n");
 979                 case CMD_REQUEST_USAGE:
 980                 {
 981                         print("\nUsage:^3 sv_cmd gotomap map\n");
 982                         print("  Where 'map' is the *.bsp file to change to.\n");
 983                         print("See also: ^2gametype^7\n");
 984                         return;
 985                 }
 986         }
 987 }
 988
 989 void GameCommand_lockteams(float request)
 990 {
 991         switch(request)
 992         {
 993                 case CMD_REQUEST_COMMAND:
 994                 {
 995                         if(teamplay)
 996                         {
 997                                 lockteams = 1;
 998                                 bprint("^1The teams are now locked.\n");
 999                         }
1000                         else
1001                         {
1002                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
1003                         }
1004                         return;
1005                 }
1006
1007                 default:
1008                 case CMD_REQUEST_USAGE:
1009                 {
1010                         print("\nUsage:^3 sv_cmd lockteams\n");
1011                         print("  No arguments required.\n");
1012                         print("See also: ^2unlockteams^7\n");
1013                         return;
1014                 }
1015         }
1016 }
1017
1018 void GameCommand_make_mapinfo(float request)
1019 {
1020         switch(request)
1021         {
1022                 case CMD_REQUEST_COMMAND:
1023                 {
1024                         entity tmp_entity;
1025
1026                         tmp_entity = spawn();
1027                         tmp_entity.classname = "make_mapinfo";
1028                         tmp_entity.think = make_mapinfo_Think;
1029                         tmp_entity.nextthink = time;
1030                         MapInfo_Enumerate();
1031                         return;
1032                 }
1033
1034                 default:
1035                 case CMD_REQUEST_USAGE:
1036                 {
1037                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1038                         print("  No arguments required.\n");
1039                         print("See also: ^2radarmap^7\n");
1040                         return;
1041                 }
1042         }
1043 }
1044
1045 void GameCommand_moveplayer(float request, float argc)
1046 {
1047         switch(request)
1048         {
1049                 case CMD_REQUEST_COMMAND:
1050                 {
1051                         float accepted;
1052                         entity client;
1053
1054                         string targets = strreplace(",", " ", argv(1));
1055                         string original_targets = strreplace(" ", ", ", targets);
1056                         string destination = argv(2);
1057
1058                         string successful, t;
1059                         successful = string_null;
1060
1061                         // lets see if the target(s) even actually exist.
1062                         if((targets) && (destination))
1063                         {
1064                                 for (;targets;)
1065                                 {
1066                                         t = car(targets); targets = cdr(targets);
1067
1068                                         // Check to see if the player is a valid target
1069                                         client = GetFilteredEntity(t);
1070                                         accepted = VerifyClientEntity(client, false, false);
1071
1072                                         if(accepted <= 0)
1073                                         {
1074                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1075                                                 continue;
1076                                         }
1077
1078                                         // Where are we putting this player?
1079                                         if(destination == "spec" || destination == "spectator")
1080                                         {
1081                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1082                                                 {
1083                                                         self = client;
1084                                                         if(self.caplayer)
1085                                                                 self.caplayer = 0;
1086                                                         PutObserverInServer();
1087
1088                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1089                                                 }
1090                                                 else
1091                                                 {
1092                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1093                                                 }
1094                                                 continue;
1095                                         }
1096                                         else
1097                                         {
1098                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1099                                                 {
1100                                                         if(teamplay)
1101                                                         {
1102                                                                 // set up
1103                                                                 float team_id;
1104                                                                 float save = client.team_forced;
1105                                                                 client.team_forced = 0;
1106
1107                                                                 // find the team to move the player to
1108                                                                 team_id = Team_ColorToTeam(destination);
1109                                                                 if(team_id == client.team) // already on the destination team
1110                                                                 {
1111                                                                         // keep the forcing undone
1112                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1113                                                                         continue;
1114                                                                 }
1115                                                                 else if(team_id == 0)  // auto team
1116                                                                 {
1117                                                                         CheckAllowedTeams(client);
1118                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1119                                                                 }
1120                                                                 else
1121                                                                 {
1122                                                                         CheckAllowedTeams(client);
1123                                                                 }
1124                                                                 client.team_forced = save;
1125
1126                                                                 // Check to see if the destination team is even available
1127                                                                 switch(team_id)
1128                                                                 {
1129                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1130                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1131                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1132                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1133
1134                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1135                                                                 }
1136
1137                                                                 // If so, lets continue and finally move the player
1138                                                                 client.team_forced = 0;
1139                                                                 MoveToTeam(client, team_id, 6);
1140                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1141                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1142                                                                 continue;
1143                                                         }
1144                                                         else
1145                                                         {
1146                                                                 print("Can't change teams when currently not playing a team game.\n");
1147                                                                 return;
1148                                                         }
1149                                                 }
1150                                                 else
1151                                                 {
1152                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1153                                                         return;
1154                                                 }
1155                                         }
1156                                 }
1157
1158                                 if(successful)
1159                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1160                                 else
1161                                         print("No players given (", original_targets, ") are able to move.\n");
1162
1163                                 return; // still correct parameters so return to avoid usage print
1164                         }
1165                 }
1166
1167                 default:
1168                         print("Incorrect parameters for ^2moveplayer^7\n");
1169                 case CMD_REQUEST_USAGE:
1170                 {
1171                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1172                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1173                         print("  'destination' is what to send the player to, be it team or spectating\n");
1174                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1175                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1176                         print("          sv_cmd moveplayer 2 spec \n");
1177                         print("See also: ^2allspec, shuffleteams^7\n");
1178                         return;
1179                 }
1180         }
1181 }
1182
1183 void GameCommand_nospectators(float request)
1184 {
1185         switch(request)
1186         {
1187                 case CMD_REQUEST_COMMAND:
1188                 {
1189                         blockSpectators = 1;
1190                         entity plr;
1191                         FOR_EACH_REALCLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1192                         {
1193                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1194                                 if(!plr.caplayer)
1195                                 {
1196                                         plr.spectatortime = time;
1197                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1198                                 }
1199                         }
1200                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1201                         return;
1202                 }
1203
1204                 default:
1205                 case CMD_REQUEST_USAGE:
1206                 {
1207                         print("\nUsage:^3 sv_cmd nospectators\n");
1208                         print("  No arguments required.\n");
1209                         return;
1210                 }
1211         }
1212 }
1213
1214 void GameCommand_playerdemo(float request, float argc)
1215 {
1216         switch(request)
1217         {
1218                 case CMD_REQUEST_COMMAND:
1219                 {
1220                         if(argv(2) && argv(3))
1221                         {
1222                                 entity client;
1223                                 float i, n, accepted;
1224
1225                                 switch(argv(1))
1226                                 {
1227                                         case "read":
1228                                         {
1229                                                 client = GetIndexedEntity(argc, 2);
1230                                                 accepted = VerifyClientEntity(client, false, true);
1231
1232                                                 if(accepted <= 0)
1233                                                 {
1234                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1235                                                         return;
1236                                                 }
1237
1238                                                 self = client;
1239                                                 playerdemo_open_read(argv(next_token));
1240                                                 return;
1241                                         }
1242
1243                                         case "write":
1244                                         {
1245                                                 client = GetIndexedEntity(argc, 2);
1246                                                 accepted = VerifyClientEntity(client, false, false);
1247
1248                                                 if(accepted <= 0)
1249                                                 {
1250                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1251                                                         return;
1252                                                 }
1253
1254                                                 self = client;
1255                                                 playerdemo_open_write(argv(next_token));
1256                                                 return;
1257                                         }
1258
1259                                         case "auto_read_and_write":
1260                                         {
1261                                                 n = GetFilteredNumber(argv(3));
1262                                                 cvar_set("bot_number", ftos(n));
1263
1264                                                 localcmd("wait; wait; wait\n");
1265                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1266
1267                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1268                                                 return;
1269                                         }
1270
1271                                         case "auto_read":
1272                                         {
1273                                                 n = GetFilteredNumber(argv(3));
1274                                                 cvar_set("bot_number", ftos(n));
1275
1276                                                 localcmd("wait; wait; wait\n");
1277                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1278                                                 return;
1279                                         }
1280                                 }
1281                         }
1282                 }
1283
1284                 default:
1285                         print("Incorrect parameters for ^2playerdemo^7\n");
1286                 case CMD_REQUEST_USAGE:
1287                 {
1288                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1289                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1290                         return;
1291                 }
1292         }
1293 }
1294
1295 void GameCommand_printstats(float request)
1296 {
1297         switch(request)
1298         {
1299                 case CMD_REQUEST_COMMAND:
1300                 {
1301                         DumpStats(false);
1302                         print("stats dumped.\n");
1303                         return;
1304                 }
1305
1306                 default:
1307                 case CMD_REQUEST_USAGE:
1308                 {
1309                         print("\nUsage:^3 sv_cmd printstats\n");
1310                         print("  No arguments required.\n");
1311                         return;
1312                 }
1313         }
1314 }
1315
1316 void GameCommand_radarmap(float request, float argc)
1317 {
1318         switch(request)
1319         {
1320                 case CMD_REQUEST_COMMAND:
1321                 {
1322                         if(RadarMap_Make(argc))
1323                                 return;
1324                 }
1325
1326                 default:
1327                         print("Incorrect parameters for ^2radarmap^7\n");
1328                 case CMD_REQUEST_USAGE:
1329                 {
1330                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1331                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1332                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1333                         print("See also: ^2make_mapinfo^7\n");
1334                         return;
1335                 }
1336         }
1337 }
1338
1339 void GameCommand_reducematchtime(float request)
1340 {
1341         switch(request)
1342         {
1343                 case CMD_REQUEST_COMMAND:
1344                 {
1345                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1346                         return;
1347                 }
1348
1349                 default:
1350                 case CMD_REQUEST_USAGE:
1351                 {
1352                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1353                         print("  No arguments required.\n");
1354                         print("See also: ^2extendmatchtime^7\n");
1355                         return;
1356                 }
1357         }
1358 }
1359
1360 void GameCommand_setbots(float request, float argc)
1361 {
1362         switch(request)
1363         {
1364                 case CMD_REQUEST_COMMAND:
1365                 {
1366                         if(argc >= 2)
1367                         {
1368                                 cvar_settemp("minplayers", "0");
1369                                 cvar_settemp("bot_number", argv(1));
1370                                 bot_fixcount();
1371                                 return;
1372                         }
1373                 }
1374
1375                 default:
1376                         print("Incorrect parameters for ^2setbots^7\n");
1377                 case CMD_REQUEST_USAGE:
1378                 {
1379                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1380                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1381                         print("See also: ^2bot_cmd^7\n");
1382                         return;
1383                 }
1384         }
1385 }
1386
1387 void GameCommand_shuffleteams(float request)
1388 {
1389         switch(request)
1390         {
1391                 case CMD_REQUEST_COMMAND:
1392                 {
1393                         if(teamplay)
1394                         {
1395                                 entity tmp_player;
1396                                 int i;
1397                                 float x, t_teams, t_players, team_color;
1398
1399                                 // count the total amount of players and total amount of teams
1400                                 t_players = 0;
1401                                 t_teams = 0;
1402                                 FOR_EACH_CLIENT(tmp_player)
1403                                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer)
1404                                 {
1405                                         CheckAllowedTeams(tmp_player);
1406
1407                                         if(c1 >= 0) t_teams = max(1, t_teams);
1408                                         if(c2 >= 0) t_teams = max(2, t_teams);
1409                                         if(c3 >= 0) t_teams = max(3, t_teams);
1410                                         if(c4 >= 0) t_teams = max(4, t_teams);
1411
1412                                         ++t_players;
1413                                 }
1414
1415                                 // build a list of the players in a random order
1416                                 FOR_EACH_CLIENT(tmp_player)
1417                                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer)
1418                                 {
1419                                         for (;;)
1420                                         {
1421                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1422
1423                                                 if(shuffleteams_players[i])
1424                                                 {
1425                                                         continue; // a player is already assigned to this slot
1426                                                 }
1427                                                 else
1428                                                 {
1429                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1430                                                         break;
1431                                                 }
1432                                         }
1433                                 }
1434
1435                                 // finally, from the list made earlier, re-join the players in different order.
1436                                 for (int i = 1; i <= t_teams; ++i)
1437                                 {
1438                                         // find out how many players to assign to this team
1439                                         x = (t_players / t_teams);
1440                                         x = ((i == 1) ? ceil(x) : floor(x));
1441
1442                                         team_color = Team_NumberToTeam(i);
1443
1444                                         // sort through the random list of players made earlier
1445                                         for (int z = 1; z <= maxclients; ++z)
1446                                         {
1447                                                 if (!(shuffleteams_teams[i] >= x))
1448                                                 {
1449                                                         if (!(shuffleteams_players[z]))
1450                                                                 continue; // not a player, move on to next random slot
1451
1452                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1453                                                                 self = edict_num(shuffleteams_players[z]);
1454
1455                                                         if(self.team != team_color)
1456                                                                 MoveToTeam(self, team_color, 6);
1457
1458                                                         shuffleteams_players[z] = 0;
1459                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1460                                                 }
1461                                                 else
1462                                                 {
1463                                                         break; // move on to next team
1464                                                 }
1465                                         }
1466                                 }
1467
1468                                 bprint("Successfully shuffled the players around randomly.\n");
1469
1470                                 // clear the buffers now
1471                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1472                                         shuffleteams_players[i] = 0;
1473
1474                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1475                                         shuffleteams_teams[i] = 0;
1476                         }
1477                         else
1478                         {
1479                                 print("Can't shuffle teams when currently not playing a team game.\n");
1480                         }
1481
1482                         return;
1483                 }
1484
1485                 default:
1486                 case CMD_REQUEST_USAGE:
1487                 {
1488                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1489                         print("  No arguments required.\n");
1490                         print("See also: ^2moveplayer, allspec^7\n");
1491                         return;
1492                 }
1493         }
1494 }
1495
1496 void GameCommand_stuffto(float request, float argc)
1497 {
1498         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1499         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1500         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1501
1502         #ifdef STUFFTO_ENABLED
1503         #message "stuffto command enabled"
1504         switch(request)
1505         {
1506                 case CMD_REQUEST_COMMAND:
1507                 {
1508                         if(argv(2))
1509                         {
1510                                 entity client = GetIndexedEntity(argc, 1);
1511                                 float accepted = VerifyClientEntity(client, true, false);
1512
1513                                 if(accepted > 0)
1514                                 {
1515                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1516                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1517                                 }
1518                                 else
1519                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1520
1521                                 return;
1522                         }
1523                 }
1524
1525                 default:
1526                         print("Incorrect parameters for ^2stuffto^7\n");
1527                 case CMD_REQUEST_USAGE:
1528                 {
1529                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1530                         print("  'client' is the entity number or name of the player,\n");
1531                         print("  and 'command' is the command to be sent to that player.\n");
1532                         return;
1533                 }
1534         }
1535         #else
1536         if(request)
1537         {
1538                 print("stuffto command is not enabled on this server.\n");
1539                 return;
1540         }
1541         #endif
1542 }
1543
1544 void GameCommand_trace(float request, float argc)
1545 {
1546         switch(request)
1547         {
1548                 case CMD_REQUEST_COMMAND:
1549                 {
1550                         entity e;
1551                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1552                         float i, f, safe, unsafe, dq, dqf;
1553
1554                         switch(argv(1))
1555                         {
1556                                 case "debug":
1557                                 {
1558                                         float hitcount = 0;
1559                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1560                                         float worst_endpos_bug = 0;
1561                                         for (;;)
1562                                         {
1563                                                 org = world.mins;
1564                                                 delta = world.maxs - world.mins;
1565
1566                                                 start.x = org.x + random() * delta.x;
1567                                                 start.y = org.y + random() * delta.y;
1568                                                 start.z = org.z + random() * delta.z;
1569
1570                                                 end.x = org.x + random() * delta.x;
1571                                                 end.y = org.y + random() * delta.y;
1572                                                 end.z = org.z + random() * delta.z;
1573
1574                                                 start = stov(vtos(start));
1575                                                 end = stov(vtos(end));
1576
1577                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1578                                                 if(!trace_startsolid && trace_fraction < 1)
1579                                                 {
1580                                                         p = trace_endpos;
1581                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1582                                                         if(trace_startsolid)
1583                                                         {
1584                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1585                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1586
1587                                                                 // how much do we need to back off?
1588                                                                 safe = 1;
1589                                                                 unsafe = 0;
1590                                                                 for (;;)
1591                                                                 {
1592                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1593                                                                         tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1594                                                                         if(trace_startsolid)
1595                                                                         {
1596                                                                                 if((safe + unsafe) * 0.5 == unsafe)
1597                                                                                         break;
1598                                                                                 unsafe = (safe + unsafe) * 0.5;
1599                                                                         }
1600                                                                         else
1601                                                                         {
1602                                                                                 if((safe + unsafe) * 0.5 == safe)
1603                                                                                         break;
1604                                                                                 safe = (safe + unsafe) * 0.5;
1605                                                                         }
1606                                                                 }
1607
1608                                                                 print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1609                                                                 print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1610
1611                                                                 tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1612                                                                 if(trace_startsolid)
1613                                                                         print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1614                                                                 else
1615                                                                         print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1616                                                                 if (++hitcount >= 10)
1617                                                                         break;
1618                                                         }
1619                                                         else
1620                                                         {
1621                                                                 q0 = p;
1622                                                                 dq = 0;
1623                                                                 dqf = 1;
1624                                                                 for (;;)
1625                                                                 {
1626                                                                         q = p + normalize(end - p) * (dq + dqf);
1627                                                                         if(q == q0)
1628                                                                                 break;
1629                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1630                                                                         if(trace_startsolid)
1631                                                                                 error("THIS ONE cannot happen");
1632                                                                         if(trace_fraction > 0)
1633                                                                                 dq += dqf * trace_fraction;
1634                                                                         dqf *= 0.5;
1635                                                                         q0 = q;
1636                                                                 }
1637                                                                 if(dq > worst_endpos_bug)
1638                                                                 {
1639                                                                         worst_endpos_bug = dq;
1640                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1641                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1642                                                                         if (++hitcount >= 10)
1643                                                                                 break;
1644                                                                 }
1645                                                         }
1646                                                 }
1647                                         }
1648                                         return;
1649                                 }
1650
1651                                 case "debug2":
1652                                 {
1653                                         e = nextent(world);
1654                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1655                                         vv = trace_endpos;
1656                                         if(trace_fraction == 1)
1657                                         {
1658                                                 print("not above ground, aborting\n");
1659                                                 return;
1660                                         }
1661                                         f = 0;
1662                                         for(i = 0; i < 100000; ++i)
1663                                         {
1664                                                 dv = randomvec();
1665                                                 if(dv.z > 0)
1666                                                         dv = -1 * dv;
1667                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1668                                                 if(trace_startsolid)
1669                                                         print("bug 1\n");
1670                                                 if(trace_fraction == 1)
1671                                                 if(dv.z < f)
1672                                                 {
1673                                                         print("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1674                                                         print(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1675                                                         f = dv.z;
1676                                                 }
1677                                         }
1678                                         print("highest possible dist: ", ftos(f), "\n");
1679                                         return;
1680                                 }
1681
1682                                 case "walk":
1683                                 {
1684                                         if(argc == 4)
1685                                         {
1686                                                 e = nextent(world);
1687                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1688                                                         print("can walk\n");
1689                                                 else
1690                                                         print("cannot walk\n");
1691                                                 return;
1692                                         }
1693                                 }
1694
1695                                 case "showline":
1696                                 {
1697                                         if(argc == 4)
1698                                         {
1699                                                 vv = stov(argv(2));
1700                                                 dv = stov(argv(3));
1701                                                 traceline(vv, dv, MOVE_NORMAL, world);
1702                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1703                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1704                                                 return;
1705                                         }
1706                                 }
1707
1708                                 // no default case, just go straight to invalid
1709                         }
1710                 }
1711
1712                 default:
1713                         print("Incorrect parameters for ^2trace^7\n");
1714                 case CMD_REQUEST_USAGE:
1715                 {
1716                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1717                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1718                         print("See also: ^2bbox, gettaginfo^7\n");
1719                         return;
1720                 }
1721         }
1722 }
1723
1724 void GameCommand_unlockteams(float request)
1725 {
1726         switch(request)
1727         {
1728                 case CMD_REQUEST_COMMAND:
1729                 {
1730                         if(teamplay)
1731                         {
1732                                 lockteams = 0;
1733                                 bprint("^1The teams are now unlocked.\n");
1734                         }
1735                         else
1736                         {
1737                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1738                         }
1739                         return;
1740                 }
1741
1742                 default:
1743                 case CMD_REQUEST_USAGE:
1744                 {
1745                         print("\nUsage:^3 sv_cmd unlockteams\n");
1746                         print("  No arguments required.\n");
1747                         print("See also: ^2lockteams^7\n");
1748                         return;
1749                 }
1750         }
1751 }
1752
1753 void GameCommand_warp(float request, float argc)
1754 {
1755         switch (request)
1756         {
1757                 case CMD_REQUEST_COMMAND:
1758                 {
1759                         if(autocvar_g_campaign)
1760                         {
1761                                 if(argc >= 2)
1762                                 {
1763                                         CampaignLevelWarp(stof(argv(1)));
1764                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1765                                 }
1766                                 else
1767                                 {
1768                                         CampaignLevelWarp(-1);
1769                                         print("Successfully warped to next campaign level.\n");
1770                                 }
1771                         }
1772                         else
1773                                 print("Not in campaign, can't level warp\n");
1774                         return;
1775                 }
1776
1777                 default:
1778                 case CMD_REQUEST_USAGE:
1779                 {
1780                         print("\nUsage:^3 sv_cmd warp [level]\n");
1781                         print("  'level' is the level to change campaign mode to.\n");
1782                         print("  if 'level' is not provided it will change to the next level.\n");
1783                         return;
1784                 }
1785         }
1786 }
1787
1788 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1789 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1790 void GameCommand_(float request)
1791 {
1792         switch(request)
1793         {
1794                 case CMD_REQUEST_COMMAND:
1795                 {
1796
1797                         return;
1798                 }
1799
1800                 default:
1801                 case CMD_REQUEST_USAGE:
1802                 {
1803                         print("\nUsage:^3 sv_cmd \n");
1804                         print("  No arguments required.\n");
1805                         return;
1806                 }
1807         }
1808 }
1809 */
1810
1811
1812 // ==================================
1813 //  Macro system for server commands
1814 // ==================================
1815
1816 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1817 #define SERVER_COMMANDS(request,arguments,command) \
1818         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1819         SERVER_COMMAND("mobbutcher", GameCommand_mobbutcher(request), "Instantly removes all monsters on the map") \
1820         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1821         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1822         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1823         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1824         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1825         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1826         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1827         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1828         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1829         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1830         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1831         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1832         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1833         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1834         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1835         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1836         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1837         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1838         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1839         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1840         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1841         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1842         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1843         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1844         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1845         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1846         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1847         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1848         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1849         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1850         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1851         /* nothing */
1852
1853 void GameCommand_macro_help()
1854 {
1855         #define SERVER_COMMAND(name,function,description) \
1856                 { print("  ^2", name, "^7: ", description, "\n"); }
1857
1858         SERVER_COMMANDS(0, 0, "");
1859         #undef SERVER_COMMAND
1860
1861         return;
1862 }
1863
1864 float GameCommand_macro_command(float argc, string command)
1865 {
1866         #define SERVER_COMMAND(name,function,description) \
1867                 { if(name == strtolower(argv(0))) { function; return true; } }
1868
1869         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
1870         #undef SERVER_COMMAND
1871
1872         return false;
1873 }
1874
1875 float GameCommand_macro_usage(float argc)
1876 {
1877         #define SERVER_COMMAND(name,function,description) \
1878                 { if(name == strtolower(argv(1))) { function; return true; } }
1879
1880         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "");
1881         #undef SERVER_COMMAND
1882
1883         return false;
1884 }
1885
1886 void GameCommand_macro_write_aliases(float fh)
1887 {
1888         #define SERVER_COMMAND(name,function,description) \
1889                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1890
1891         SERVER_COMMANDS(0, 0, "");
1892         #undef SERVER_COMMAND
1893
1894         return;
1895 }
1896
1897
1898 // =========================================
1899 //  Main Function Called By Engine (sv_cmd)
1900 // =========================================
1901 // If this function exists, game code handles gamecommand instead of the engine code.
1902
1903 void GameCommand(string command)
1904 {
1905         float argc = tokenize_console(command);
1906
1907         // Guide for working with argc arguments by example:
1908         // argc:   1    - 2      - 3     - 4
1909         // argv:   0    - 1      - 2     - 3
1910         // cmd     vote - master - login - password
1911
1912         if(strtolower(argv(0)) == "help")
1913         {
1914                 if(argc == 1)
1915                 {
1916                         print("\nServer console commands:\n");
1917                         GameCommand_macro_help();
1918
1919                         print("\nBanning commands:\n");
1920                         BanCommand_macro_help();
1921
1922                         print("\nCommon networked commands:\n");
1923                         CommonCommand_macro_help(world);
1924
1925                         print("\nGeneric commands shared by all programs:\n");
1926                         GenericCommand_macro_help();
1927
1928                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1929                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1930
1931                         return;
1932                 }
1933                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1934                 {
1935                         return;
1936                 }
1937                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1938                 {
1939                         return;
1940                 }
1941                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1942                 {
1943                         return;
1944                 }
1945                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1946                 {
1947                         return;
1948                 }
1949         }
1950         else if(BanCommand(command))
1951         {
1952                 return; // handled by server/command/ipban.qc
1953         }
1954         else if(CommonCommand_macro_command(argc, world, command))
1955         {
1956                 return; // handled by server/command/common.qc
1957         }
1958         else if(GenericCommand(command))
1959         {
1960                 return; // handled by common/command/generic.qc
1961         }
1962         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1963         {
1964                 return; // handled by one of the above GameCommand_* functions
1965         }
1966
1967         // nothing above caught the command, must be invalid
1968         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1969
1970         return;
1971 }