qcsrc/server/command/sv_cmd.qc

   1 #include "../../common/command/command.qh"
   2 #include "sv_cmd.qh"
   3 #include "../_all.qh"
   4
   5 #include "banning.qh"
   6 #include "cmd.qh"
   7 #include "common.qh"
   8 #include "getreplies.qh"
   9 #include "radarmap.qh"
  10
  11 #include "../anticheat.qh"
  12 #include "../campaign.qh"
  13 #include "../cl_client.qh"
  14 #include "../cl_player.qh"
  15 #include "../g_world.qh"
  16 #include "../ipban.qh"
  17 #include "../playerdemo.qh"
  18 #include "../teamplay.qh"
  19
  20 #include "../bot/bot.qh"
  21 #include "../bot/navigation.qh"
  22 #include "../bot/scripting.qh"
  23
  24 #include "../mutators/mutators_include.qh"
  25
  26 #include "../../common/constants.qh"
  27 #include "../../common/mapinfo.qh"
  28 #include "../../common/notifications.qh"
  29 #include "../../common/teams.qh"
  30 #include "../../common/util.qh"
  31
  32 #include "../../common/monsters/sv_monsters.qh"
  33
  34
  35 void PutObserverInServer (void);
  36
  37 // =====================================================
  38 //  Server side game commands code, reworked by Samual
  39 //  Last updated: December 29th, 2011
  40 // =====================================================
  41
  42 //  used by GameCommand_make_mapinfo()
  43 void make_mapinfo_Think()
  44 {SELFPARAM();
  45         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  46         {
  47                 LOG_INFO("Done rebuiling mapinfos.\n");
  48                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  49                 remove(self);
  50         }
  51         else
  52         {
  53                 self.think = make_mapinfo_Think;
  54                 self.nextthink = time;
  55         }
  56 }
  57
  58 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  59 void changematchtime(float delta, float mi, float ma)
  60 {
  61         float cur;
  62         float update;
  63         float lim;
  64
  65         if(delta == 0)
  66                 return;
  67         if(autocvar_timelimit < 0)
  68                 return;
  69
  70         if(mi <= 10)
  71                 mi = 10; // at least ten sec in the future
  72         cur = time - game_starttime;
  73         if(cur > 0)
  74                 mi += cur; // from current time!
  75
  76         lim = autocvar_timelimit * 60;
  77
  78         if(delta > 0)
  79         {
  80                 if(lim == 0)
  81                         return; // cannot increase any further
  82                 else if(lim < ma)
  83                         update = min(ma, lim + delta);
  84                 else // already above maximum: FAIL
  85                         return;
  86         }
  87         else
  88         {
  89                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  90                         update = max(mi, ma);
  91                 else if(lim > mi) // above minimum: decrease
  92                         update = max(mi, lim + delta);
  93                 else // already below minimum: FAIL
  94                         return;
  95         }
  96
  97         cvar_set("timelimit", ftos(update / 60));
  98 }
  99
 100
 101 // =======================
 102 //  Command Sub-Functions
 103 // =======================
 104
 105 void GameCommand_adminmsg(float request, float argc)
 106 {
 107         switch(request)
 108         {
 109                 case CMD_REQUEST_COMMAND:
 110                 {
 111                         entity client;
 112                         float accepted;
 113
 114                         string targets = strreplace(",", " ", argv(1));
 115                         string original_targets = strreplace(" ", ", ", targets);
 116                         string admin_message = argv(2);
 117                         float infobartime = stof(argv(3));
 118
 119                         string successful, t;
 120                         successful = string_null;
 121
 122                         if((targets) && (admin_message))
 123                         {
 124                                 for (;targets;)
 125                                 {
 126                                         t = car(targets); targets = cdr(targets);
 127
 128                                         // Check to see if the player is a valid target
 129                                         client = GetFilteredEntity(t);
 130                                         accepted = VerifyClientEntity(client, true, false);
 131
 132                                         if(accepted <= 0)
 133                                         {
 134                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 135                                                 continue;
 136                                         }
 137
 138                                         // send the centerprint/console print or infomessage
 139                                         if(infobartime)
 140                                         {
 141                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 142                                         }
 143                                         else
 144                                         {
 145                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 146                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 147                                         }
 148
 149                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 150                                         LOG_TRACE("Message sent to ", client.netname, "\n");
 151                                         continue;
 152                                 }
 153
 154                                 if(successful)
 155                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 156                                 else
 157                                         LOG_INFO("No players given (", original_targets, ") could receive the message.\n");
 158
 159                                 return;
 160                         }
 161                 }
 162
 163                 default:
 164                         LOG_INFO("Incorrect parameters for ^2adminmsg^7\n");
 165                 case CMD_REQUEST_USAGE:
 166                 {
 167                         LOG_INFO("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 168                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 169                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.\n");
 170                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.\n");
 171                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 172                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 173                         return;
 174                 }
 175         }
 176 }
 177
 178 void GameCommand_allready(float request)
 179 {
 180         switch(request)
 181         {
 182                 case CMD_REQUEST_COMMAND:
 183                 {
 184                         ReadyRestart();
 185                         return;
 186                 }
 187
 188                 default:
 189                 case CMD_REQUEST_USAGE:
 190                 {
 191                         LOG_INFO("\nUsage:^3 sv_cmd allready\n");
 192                         LOG_INFO("  No arguments required.\n");
 193                         return;
 194                 }
 195         }
 196 }
 197
 198 void GameCommand_allspec(float request, float argc)
 199 {SELFPARAM();
 200         switch(request)
 201         {
 202                 case CMD_REQUEST_COMMAND:
 203                 {
 204                         entity client;
 205                         string reason = argv(1);
 206                         float i = 0;
 207
 208                         FOR_EACH_REALPLAYER(client)
 209                         {
 210                                 self = client;
 211                                 if(self.caplayer)
 212                                         self.caplayer = 0;
 213                                 PutObserverInServer();
 214                                 ++i;
 215                         }
 216                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 217                         else { LOG_INFO("No players found to spectate.\n"); }
 218                         return;
 219                 }
 220
 221                 default:
 222                 case CMD_REQUEST_USAGE:
 223                 {
 224                         LOG_INFO("\nUsage:^3 sv_cmd allspec [reason]\n");
 225                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 226                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7\n");
 227                         return;
 228                 }
 229         }
 230 }
 231
 232 void GameCommand_anticheat(float request, float argc)
 233 {SELFPARAM();
 234         switch(request)
 235         {
 236                 case CMD_REQUEST_COMMAND:
 237                 {
 238                         entity client = GetIndexedEntity(argc, 1);
 239                         float accepted = VerifyClientEntity(client, false, false);
 240
 241                         if(accepted > 0)
 242                         {
 243                                 self = client;
 244                                 anticheat_report();
 245                                 return;
 246                         }
 247                         else
 248                         {
 249                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 250                         }
 251                 }
 252
 253                 default:
 254                         LOG_INFO("Incorrect parameters for ^2anticheat^7\n");
 255                 case CMD_REQUEST_USAGE:
 256                 {
 257                         LOG_INFO("\nUsage:^3 sv_cmd anticheat client\n");
 258                         LOG_INFO("  'client' is the entity number or name of the player.\n");
 259                         return;
 260                 }
 261         }
 262 }
 263
 264 void GameCommand_bbox(float request)
 265 {
 266         switch(request)
 267         {
 268                 case CMD_REQUEST_COMMAND:
 269                 {
 270                         LOG_INFO("Original size: ", ftos(world.absmin.x), " ", ftos(world.absmin.y), " ", ftos(world.absmin.z));
 271                         LOG_INFO(" ", ftos(world.absmax.x), " ", ftos(world.absmax.y), " ", ftos(world.absmax.z), "\n");
 272                         LOG_INFO("Currently set size: ", ftos(world.mins.x), " ", ftos(world.mins.y), " ", ftos(world.mins.z));
 273                         LOG_INFO(" ", ftos(world.maxs.x), " ", ftos(world.maxs.y), " ", ftos(world.maxs.z), "\n");
 274                         LOG_INFO("Solid bounding box size:");
 275
 276                         tracebox('1 0 0' * world.absmin.x,
 277                                                         '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 278                                                         '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 279                                                         '1 0 0' * world.absmax.x,
 280                                         MOVE_WORLDONLY,
 281                                         world);
 282                         if(trace_startsolid)
 283                                 LOG_INFO(" ", ftos(world.absmin.x));
 284                         else
 285                                 LOG_INFO(" ", ftos(trace_endpos.x));
 286
 287                         tracebox('0 1 0' * world.absmin.y,
 288                                                         '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 289                                                         '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 290                                                         '0 1 0' * world.absmax.y,
 291                                         MOVE_WORLDONLY,
 292                                         world);
 293                         if(trace_startsolid)
 294                                 LOG_INFO(" ", ftos(world.absmin.y));
 295                         else
 296                                 LOG_INFO(" ", ftos(trace_endpos.y));
 297
 298                         tracebox('0 0 1' * world.absmin.z,
 299                                                         '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 300                                                         '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 301                                                         '0 0 1' * world.absmax.z,
 302                                         MOVE_WORLDONLY,
 303                                         world);
 304                         if(trace_startsolid)
 305                                 LOG_INFO(" ", ftos(world.absmin.z));
 306                         else
 307                                 LOG_INFO(" ", ftos(trace_endpos.z));
 308
 309                         tracebox('1 0 0' * world.absmax.x,
 310                                                         '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 311                                                         '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 312                                                         '1 0 0' * world.absmin.x,
 313                                         MOVE_WORLDONLY,
 314                                         world);
 315                         if(trace_startsolid)
 316                                 LOG_INFO(" ", ftos(world.absmax.x));
 317                         else
 318                                 LOG_INFO(" ", ftos(trace_endpos.x));
 319
 320                         tracebox('0 1 0' * world.absmax.y,
 321                                                         '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 322                                                         '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 323                                                         '0 1 0' * world.absmin.y,
 324                                         MOVE_WORLDONLY,
 325                                         world);
 326                         if(trace_startsolid)
 327                                 LOG_INFO(" ", ftos(world.absmax.y));
 328                         else
 329                                 LOG_INFO(" ", ftos(trace_endpos.y));
 330
 331                         tracebox('0 0 1' * world.absmax.z,
 332                                                         '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 333                                                         '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 334                                                         '0 0 1' * world.absmin.z,
 335                                         MOVE_WORLDONLY,
 336                                         world);
 337                         if(trace_startsolid)
 338                                 LOG_INFO(" ", ftos(world.absmax.z));
 339                         else
 340                                 LOG_INFO(" ", ftos(trace_endpos.z));
 341
 342                         LOG_INFO("\n");
 343                         return;
 344                 }
 345
 346                 default:
 347                 case CMD_REQUEST_USAGE:
 348                 {
 349                         LOG_INFO("\nUsage:^3 sv_cmd bbox\n");
 350                         LOG_INFO("  No arguments required.\n");
 351                         LOG_INFO("See also: ^2gettaginfo, trace^7\n");
 352                         return;
 353                 }
 354         }
 355 }
 356
 357 void GameCommand_bot_cmd(float request, float argc, string command)
 358 {
 359         switch(request)
 360         {
 361                 case CMD_REQUEST_COMMAND:
 362                 {
 363                         entity bot;
 364
 365                         if(argv(1) == "reset")
 366                         {
 367                                 bot_resetqueues();
 368                                 return;
 369                         }
 370                         else if(argv(1) == "setbots")
 371                         {
 372                                 cvar_settemp("bot_vs_human", "0");
 373                                 cvar_settemp("minplayers", "0");
 374                                 cvar_settemp("bot_number", "0");
 375                                 bot_fixcount();
 376                                 cvar_settemp("bot_number", argv(2));
 377                                 if(!bot_fixcount())
 378                                         LOG_INFO("Sorry, could not set requested bot count\n");
 379                                 return;
 380                         }
 381                         else if(argv(1) == "load" && argc == 3)
 382                         {
 383                                 float fh, i;
 384                                 string s;
 385                                 fh = fopen(argv(2), FILE_READ);
 386                                 if(fh < 0)
 387                                 {
 388                                         LOG_INFO("cannot open the file\n");
 389                                         return;
 390                                 }
 391
 392                                 i = 0;
 393                                 while((s = fgets(fh)))
 394                                 {
 395                                         argc = tokenize_console(s);
 396
 397                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 398                                         {
 399                                                 if(argv(2) == "reset")
 400                                                 {
 401                                                         bot_resetqueues();
 402                                                 }
 403                                                 else if(argv(2) == "setbots")
 404                                                 {
 405                                                         cvar_settemp("bot_vs_human", "0");
 406                                                         cvar_settemp("minplayers", "0");
 407                                                         cvar_settemp("bot_number", "0");
 408                                                         bot_fixcount();
 409                                                         cvar_settemp("bot_number", argv(3));
 410                                                         if(!bot_fixcount())
 411                                                                 LOG_INFO("Sorry, could not set requested bot count\n");
 412                                                 }
 413                                                 else
 414                                                 {
 415                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 416                                                         bot = find_bot_by_number(stof(argv(2)));
 417                                                         if(bot == world)
 418                                                                 bot = find_bot_by_name(argv(2));
 419                                                         if(bot)
 420                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 421                                                 }
 422                                         }
 423                                         else
 424                                                 localcmd(strcat(s, "\n"));
 425
 426                                         ++i;
 427                                 }
 428                                 LOG_INFO(ftos(i), " commands read\n");
 429                                 fclose(fh);
 430                                 return;
 431                         }
 432                         else if(argv(1) == "help")
 433                         {
 434                                 if(argv(2))
 435                                         bot_cmdhelp(argv(2));
 436                                 else
 437                                         bot_list_commands();
 438                                 return;
 439                         }
 440                         else if(argc >= 3) // this comes last
 441                         {
 442                                 bot = find_bot_by_number(stof(argv(1)));
 443                                 if(bot == world)
 444                                         bot = find_bot_by_name(argv(1));
 445                                 if(bot)
 446                                 {
 447                                         LOG_INFO(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 448                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 449                                         return;
 450                                 }
 451                                 else
 452                                         LOG_INFO(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 453                         }
 454                 }
 455
 456                 default:
 457                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7\n");
 458                 case CMD_REQUEST_USAGE:
 459                 {
 460                         LOG_INFO("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 461                         LOG_INFO("  'client' can be either the name or entity id of the bot\n");
 462                         LOG_INFO("  For full list of commands, see bot_cmd help [command].\n");
 463                         LOG_INFO("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 464                         LOG_INFO("          sv_cmd bot_cmd client presskey jump\n");
 465                         return;
 466                 }
 467         }
 468 }
 469
 470 void GameCommand_cointoss(float request, float argc)
 471 {
 472         switch(request)
 473         {
 474                 case CMD_REQUEST_COMMAND:
 475                 {
 476                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 477                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 478                         string choice = ((random() > 0.5) ? result1 : result2);
 479
 480                         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_COINTOSS, choice);
 481                         return;
 482                 }
 483
 484                 default:
 485                 case CMD_REQUEST_USAGE:
 486                 {
 487                         LOG_INFO("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 488                         LOG_INFO("  Where 'result1' and 'result2' are user created options.\n");
 489                         return;
 490                 }
 491         }
 492 }
 493
 494 void GameCommand_database(float request, float argc)
 495 {
 496         switch(request)
 497         {
 498                 case CMD_REQUEST_COMMAND:
 499                 {
 500                         if(argc == 3)
 501                         {
 502                                 if(argv(1) == "save")
 503                                 {
 504                                         db_save(ServerProgsDB, argv(2));
 505                                         LOG_INFO(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 506                                         return;
 507                                 }
 508                                 else if(argv(1) == "dump")
 509                                 {
 510                                         db_dump(ServerProgsDB, argv(2));
 511                                         LOG_INFO("DB dumped.\n"); // wtf does this do?
 512                                         return;
 513                                 }
 514                                 else if(argv(1) == "load")
 515                                 {
 516                                         db_close(ServerProgsDB);
 517                                         ServerProgsDB = db_load(argv(2));
 518                                         LOG_INFO(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 519                                         return;
 520                                 }
 521                         }
 522                 }
 523
 524                 default:
 525                         LOG_INFO("Incorrect parameters for ^2database^7\n");
 526                 case CMD_REQUEST_USAGE:
 527                 {
 528                         LOG_INFO("\nUsage:^3 sv_cmd database action filename\n");
 529                         LOG_INFO("  Where 'action' is the command to complete,\n");
 530                         LOG_INFO("  and 'filename' is what it acts upon.\n");
 531                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"\n");
 532                         return;
 533                 }
 534         }
 535 }
 536
 537 void GameCommand_defer_clear(float request, float argc)
 538 {
 539         switch(request)
 540         {
 541                 case CMD_REQUEST_COMMAND:
 542                 {
 543                         entity client;
 544                         float accepted;
 545
 546                         if(argc >= 2)
 547                         {
 548                                 client = GetIndexedEntity(argc, 1);
 549                                 accepted = VerifyClientEntity(client, true, false);
 550
 551                                 if(accepted > 0)
 552                                 {
 553                                         stuffcmd(client, "defer clear\n");
 554                                         LOG_INFO("defer clear stuffed to ", client.netname, "\n");
 555                                 }
 556                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 557
 558                                 return;
 559                         }
 560                 }
 561
 562                 default:
 563                         LOG_INFO("Incorrect parameters for ^2defer_clear^7\n");
 564                 case CMD_REQUEST_USAGE:
 565                 {
 566                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear client\n");
 567                         LOG_INFO("  'client' is the entity number or name of the player.\n");
 568                         LOG_INFO("See also: ^2defer_clear_all^7\n");
 569                         return;
 570                 }
 571         }
 572 }
 573
 574 void GameCommand_defer_clear_all(float request)
 575 {
 576         switch(request)
 577         {
 578                 case CMD_REQUEST_COMMAND:
 579                 {
 580                         entity client;
 581                         float i = 0;
 582                         float argc;
 583
 584                         FOR_EACH_CLIENT(client)
 585                         {
 586                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 587                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 588                                 ++i;
 589                         }
 590                         if(i) { LOG_INFO(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 591                         return;
 592                 }
 593
 594                 default:
 595                 case CMD_REQUEST_USAGE:
 596                 {
 597                         LOG_INFO("\nUsage:^3 sv_cmd defer_clear_all\n");
 598                         LOG_INFO("  No arguments required.\n");
 599                         LOG_INFO("See also: ^2defer_clear^7\n");
 600                         return;
 601                 }
 602         }
 603 }
 604
 605 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 606 {
 607         switch(request)
 608         {
 609                 case CMD_REQUEST_COMMAND:
 610                 {
 611                         if(argv(1))
 612                         {
 613                                 if(argv(2))
 614                                         race_deleteTime(argv(2), stof(argv(1)));
 615                                 else
 616                                         race_deleteTime(GetMapname(), stof(argv(1)));
 617                                 return;
 618                         }
 619                 }
 620
 621                 default:
 622                         LOG_INFO("Incorrect parameters for ^2delrec^7\n");
 623                 case CMD_REQUEST_USAGE:
 624                 {
 625                         LOG_INFO("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 626                         LOG_INFO("  'ranking' is which ranking level to clear up to, \n");
 627                         LOG_INFO("  it will clear all records up to nth place.\n");
 628                         LOG_INFO("  if 'map' is not provided it will use current map.\n");
 629                         return;
 630                 }
 631         }
 632 }
 633
 634 void GameCommand_effectindexdump(float request)
 635 {
 636         switch(request)
 637         {
 638                 case CMD_REQUEST_COMMAND:
 639                 {
 640                         float fh, d;
 641                         string s;
 642
 643                         d = db_create();
 644                         LOG_INFO("begin of effects list\n");
 645                         db_put(d, "TE_GUNSHOT", "1"); LOG_INFO("effect TE_GUNSHOT is ", ftos(_particleeffectnum("TE_GUNSHOT")), "\n");
 646                         db_put(d, "TE_GUNSHOTQUAD", "1"); LOG_INFO("effect TE_GUNSHOTQUAD is ", ftos(_particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 647                         db_put(d, "TE_SPIKE", "1"); LOG_INFO("effect TE_SPIKE is ", ftos(_particleeffectnum("TE_SPIKE")), "\n");
 648                         db_put(d, "TE_SPIKEQUAD", "1"); LOG_INFO("effect TE_SPIKEQUAD is ", ftos(_particleeffectnum("TE_SPIKEQUAD")), "\n");
 649                         db_put(d, "TE_SUPERSPIKE", "1"); LOG_INFO("effect TE_SUPERSPIKE is ", ftos(_particleeffectnum("TE_SUPERSPIKE")), "\n");
 650                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); LOG_INFO("effect TE_SUPERSPIKEQUAD is ", ftos(_particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 651                         db_put(d, "TE_WIZSPIKE", "1"); LOG_INFO("effect TE_WIZSPIKE is ", ftos(_particleeffectnum("TE_WIZSPIKE")), "\n");
 652                         db_put(d, "TE_KNIGHTSPIKE", "1"); LOG_INFO("effect TE_KNIGHTSPIKE is ", ftos(_particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 653                         db_put(d, "TE_EXPLOSION", "1"); LOG_INFO("effect TE_EXPLOSION is ", ftos(_particleeffectnum("TE_EXPLOSION")), "\n");
 654                         db_put(d, "TE_EXPLOSIONQUAD", "1"); LOG_INFO("effect TE_EXPLOSIONQUAD is ", ftos(_particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 655                         db_put(d, "TE_TAREXPLOSION", "1"); LOG_INFO("effect TE_TAREXPLOSION is ", ftos(_particleeffectnum("TE_TAREXPLOSION")), "\n");
 656                         db_put(d, "TE_TELEPORT", "1"); LOG_INFO("effect TE_TELEPORT is ", ftos(_particleeffectnum("TE_TELEPORT")), "\n");
 657                         db_put(d, "TE_LAVASPLASH", "1"); LOG_INFO("effect TE_LAVASPLASH is ", ftos(_particleeffectnum("TE_LAVASPLASH")), "\n");
 658                         db_put(d, "TE_SMALLFLASH", "1"); LOG_INFO("effect TE_SMALLFLASH is ", ftos(_particleeffectnum("TE_SMALLFLASH")), "\n");
 659                         db_put(d, "TE_FLAMEJET", "1"); LOG_INFO("effect TE_FLAMEJET is ", ftos(_particleeffectnum("TE_FLAMEJET")), "\n");
 660                         db_put(d, "EF_FLAME", "1"); LOG_INFO("effect EF_FLAME is ", ftos(_particleeffectnum("EF_FLAME")), "\n");
 661                         db_put(d, "TE_BLOOD", "1"); LOG_INFO("effect TE_BLOOD is ", ftos(_particleeffectnum("TE_BLOOD")), "\n");
 662                         db_put(d, "TE_SPARK", "1"); LOG_INFO("effect TE_SPARK is ", ftos(_particleeffectnum("TE_SPARK")), "\n");
 663                         db_put(d, "TE_PLASMABURN", "1"); LOG_INFO("effect TE_PLASMABURN is ", ftos(_particleeffectnum("TE_PLASMABURN")), "\n");
 664                         db_put(d, "TE_TEI_G3", "1"); LOG_INFO("effect TE_TEI_G3 is ", ftos(_particleeffectnum("TE_TEI_G3")), "\n");
 665                         db_put(d, "TE_TEI_SMOKE", "1"); LOG_INFO("effect TE_TEI_SMOKE is ", ftos(_particleeffectnum("TE_TEI_SMOKE")), "\n");
 666                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); LOG_INFO("effect TE_TEI_BIGEXPLOSION is ", ftos(_particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 667                         db_put(d, "TE_TEI_PLASMAHIT", "1"); LOG_INFO("effect TE_TEI_PLASMAHIT is ", ftos(_particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 668                         db_put(d, "EF_STARDUST", "1"); LOG_INFO("effect EF_STARDUST is ", ftos(_particleeffectnum("EF_STARDUST")), "\n");
 669                         db_put(d, "TR_ROCKET", "1"); LOG_INFO("effect TR_ROCKET is ", ftos(_particleeffectnum("TR_ROCKET")), "\n");
 670                         db_put(d, "TR_GRENADE", "1"); LOG_INFO("effect TR_GRENADE is ", ftos(_particleeffectnum("TR_GRENADE")), "\n");
 671                         db_put(d, "TR_BLOOD", "1"); LOG_INFO("effect TR_BLOOD is ", ftos(_particleeffectnum("TR_BLOOD")), "\n");
 672                         db_put(d, "TR_WIZSPIKE", "1"); LOG_INFO("effect TR_WIZSPIKE is ", ftos(_particleeffectnum("TR_WIZSPIKE")), "\n");
 673                         db_put(d, "TR_SLIGHTBLOOD", "1"); LOG_INFO("effect TR_SLIGHTBLOOD is ", ftos(_particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 674                         db_put(d, "TR_KNIGHTSPIKE", "1"); LOG_INFO("effect TR_KNIGHTSPIKE is ", ftos(_particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 675                         db_put(d, "TR_VORESPIKE", "1"); LOG_INFO("effect TR_VORESPIKE is ", ftos(_particleeffectnum("TR_VORESPIKE")), "\n");
 676                         db_put(d, "TR_NEHAHRASMOKE", "1"); LOG_INFO("effect TR_NEHAHRASMOKE is ", ftos(_particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 677                         db_put(d, "TR_NEXUIZPLASMA", "1"); LOG_INFO("effect TR_NEXUIZPLASMA is ", ftos(_particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 678                         db_put(d, "TR_GLOWTRAIL", "1"); LOG_INFO("effect TR_GLOWTRAIL is ", ftos(_particleeffectnum("TR_GLOWTRAIL")), "\n");
 679                         db_put(d, "TR_SEEKER", "1"); LOG_INFO("effect TR_SEEKER is ", ftos(_particleeffectnum("TR_SEEKER")), "\n");
 680                         db_put(d, "SVC_PARTICLE", "1"); LOG_INFO("effect SVC_PARTICLE is ", ftos(_particleeffectnum("SVC_PARTICLE")), "\n");
 681
 682                         fh = fopen("effectinfo.txt", FILE_READ);
 683                         while((s = fgets(fh)))
 684                         {
 685                                 tokenize_console(s);
 686                                 if(argv(0) == "effect")
 687                                 {
 688                                         if(db_get(d, argv(1)) != "1")
 689                                         {
 690                                                 int i = _particleeffectnum(argv(1));
 691                                                 if(i >= 0)
 692                                                         LOG_INFO("effect ", argv(1), " is ", ftos(i), "\n");
 693                                                 db_put(d, argv(1), "1");
 694                                         }
 695                                 }
 696                         }
 697                         LOG_INFO("end of effects list\n");
 698
 699                         db_close(d);
 700                         return;
 701                 }
 702
 703                 default:
 704                 case CMD_REQUEST_USAGE:
 705                 {
 706                         LOG_INFO("\nUsage:^3 sv_cmd effectindexdump\n");
 707                         LOG_INFO("  No arguments required.\n");
 708                         return;
 709                 }
 710         }
 711 }
 712
 713 void GameCommand_extendmatchtime(float request)
 714 {
 715         switch(request)
 716         {
 717                 case CMD_REQUEST_COMMAND:
 718                 {
 719                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 720                         return;
 721                 }
 722
 723                 default:
 724                 case CMD_REQUEST_USAGE:
 725                 {
 726                         LOG_INFO("\nUsage:^3 sv_cmd extendmatchtime\n");
 727                         LOG_INFO("  No arguments required.\n");
 728                         LOG_INFO("See also: ^2reducematchtime^7\n");
 729                         return;
 730                 }
 731         }
 732 }
 733
 734 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 735 {
 736         switch(request)
 737         {
 738                 case CMD_REQUEST_COMMAND:
 739                 {
 740                         entity client;
 741
 742                         for(client = world; (client = find(client, classname, argv(1))); )
 743                                 LOG_INFO(etos(client), "\n");
 744
 745                         return;
 746                 }
 747
 748                 default:
 749                         LOG_INFO("Incorrect parameters for ^2find^7\n");
 750                 case CMD_REQUEST_USAGE:
 751                 {
 752                         LOG_INFO("\nUsage:^3 sv_cmd find classname\n");
 753                         LOG_INFO("  Where 'classname' is the classname to search for.\n");
 754                         return;
 755                 }
 756         }
 757 }
 758
 759 void GameCommand_gametype(float request, float argc)
 760 {
 761         switch(request)
 762         {
 763                 case CMD_REQUEST_COMMAND:
 764                 {
 765                         if(argv(1) != "")
 766                         {
 767                                 string s = argv(1);
 768                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 769
 770                                 if(t)
 771                                 {
 772                                         MapInfo_SwitchGameType(t);
 773                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 774                                         if(MapInfo_count > 0)
 775                                         {
 776                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 777                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 778                                                 lsmaps_reply = strzone(getlsmaps());
 779                                                 bprint("Game type successfully switched to ", s, "\n");
 780                                         }
 781                                         else
 782                                         {
 783                                                 bprint("Cannot use this game type: no map for it found\n");
 784                                                 MapInfo_SwitchGameType(tsave);
 785                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 786                                         }
 787                                 }
 788                                 else
 789                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 790
 791                                 return;
 792                         }
 793                 }
 794
 795                 default:
 796                         LOG_INFO("Incorrect parameters for ^2gametype^7\n");
 797                 case CMD_REQUEST_USAGE:
 798                 {
 799                         LOG_INFO("\nUsage:^3 sv_cmd gametype mode\n");
 800                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.\n");
 801                         LOG_INFO("See also: ^2gotomap^7\n");
 802                         return;
 803                 }
 804         }
 805 }
 806
 807 void GameCommand_gettaginfo(float request, float argc)
 808 {
 809         switch(request)
 810         {
 811                 case CMD_REQUEST_COMMAND:
 812                 {
 813                         entity tmp_entity;
 814                         float i;
 815                         vector v;
 816
 817                         if(argc >= 4)
 818                         {
 819                                 tmp_entity = spawn();
 820                                 if(argv(1) == "w")
 821                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 822                                 else
 823                                 {
 824                                         precache_model(argv(1));
 825                                         setmodel(tmp_entity, argv(1));
 826                                 }
 827                                 tmp_entity.frame = stof(argv(2));
 828                                 if(substring(argv(3), 0, 1) == "#")
 829                                         i = stof(substring(argv(3), 1, -1));
 830                                 else
 831                                         i = gettagindex(tmp_entity, argv(3));
 832                                 if(i)
 833                                 {
 834                                         v = gettaginfo(tmp_entity, i);
 835                                         LOG_INFO("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 836                                         LOG_INFO(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 837                                         LOG_INFO(" vector = ", ftos(v.x), " ", ftos(v.y), " ", ftos(v.z), "\n");
 838                                         LOG_INFO(" offset = ", ftos(gettaginfo_offset.x), " ", ftos(gettaginfo_offset.y), " ", ftos(gettaginfo_offset.z), "\n");
 839                                         LOG_INFO(" forward = ", ftos(gettaginfo_forward.x), " ", ftos(gettaginfo_forward.y), " ", ftos(gettaginfo_forward.z), "\n");
 840                                         LOG_INFO(" right = ", ftos(gettaginfo_right.x), " ", ftos(gettaginfo_right.y), " ", ftos(gettaginfo_right.z), "\n");
 841                                         LOG_INFO(" up = ", ftos(gettaginfo_up.x), " ", ftos(gettaginfo_up.y), " ", ftos(gettaginfo_up.z), "\n");
 842                                         if(argc >= 6)
 843                                         {
 844                                                 v.y = -v.y;
 845                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 846                                         }
 847                                 }
 848                                 else
 849                                         LOG_INFO("bone not found\n");
 850
 851                                 remove(tmp_entity);
 852                                 return;
 853                         }
 854                 }
 855
 856                 default:
 857                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
 858                 case CMD_REQUEST_USAGE:
 859                 {
 860                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 861                         LOG_INFO("See also: ^2bbox, trace^7\n");
 862                         return;
 863                 }
 864         }
 865 }
 866
 867 void GameCommand_animbench(float request, float argc)
 868 {
 869         switch(request)
 870         {
 871                 case CMD_REQUEST_COMMAND:
 872                 {
 873                         entity tmp_entity;
 874
 875                         if(argc >= 4)
 876                         {
 877                                 tmp_entity = spawn();
 878                                 if(argv(1) == "w")
 879                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 880                                 else
 881                                 {
 882                                         precache_model(argv(1));
 883                                         setmodel(tmp_entity, argv(1));
 884                                 }
 885                                 float f1 = stof(argv(2));
 886                                 float f2 = stof(argv(3));
 887                                 float t0;
 888                                 float t1 = 0;
 889                                 float t2 = 0;
 890                                 float n = 0;
 891
 892                                 while(t1 + t2 < 1)
 893                                 {
 894                                         tmp_entity.frame = f1;
 895                                         t0 = gettime(GETTIME_HIRES);
 896                                         getsurfacepoint(tmp_entity, 0, 0);
 897                                         t1 += gettime(GETTIME_HIRES) - t0;
 898                                         tmp_entity.frame = f2;
 899                                         t0 = gettime(GETTIME_HIRES);
 900                                         getsurfacepoint(tmp_entity, 0, 0);
 901                                         t2 += gettime(GETTIME_HIRES) - t0;
 902                                         n += 1;
 903                                 }
 904                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 905                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 906
 907                                 remove(tmp_entity);
 908                                 return;
 909                         }
 910                 }
 911
 912                 default:
 913                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7\n");
 914                 case CMD_REQUEST_USAGE:
 915                 {
 916                         LOG_INFO("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 917                         LOG_INFO("See also: ^2bbox, trace^7\n");
 918                         return;
 919                 }
 920         }
 921 }
 922
 923 void GameCommand_gotomap(float request, float argc)
 924 {
 925         switch(request)
 926         {
 927                 case CMD_REQUEST_COMMAND:
 928                 {
 929                         if(argv(1))
 930                         {
 931                                 LOG_INFO(GotoMap(argv(1)), "\n");
 932                                 return;
 933                         }
 934                 }
 935
 936                 default:
 937                         LOG_INFO("Incorrect parameters for ^2gotomap^7\n");
 938                 case CMD_REQUEST_USAGE:
 939                 {
 940                         LOG_INFO("\nUsage:^3 sv_cmd gotomap map\n");
 941                         LOG_INFO("  Where 'map' is the *.bsp file to change to.\n");
 942                         LOG_INFO("See also: ^2gametype^7\n");
 943                         return;
 944                 }
 945         }
 946 }
 947
 948 void GameCommand_lockteams(float request)
 949 {
 950         switch(request)
 951         {
 952                 case CMD_REQUEST_COMMAND:
 953                 {
 954                         if(teamplay)
 955                         {
 956                                 lockteams = 1;
 957                                 bprint("^1The teams are now locked.\n");
 958                         }
 959                         else
 960                         {
 961                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 962                         }
 963                         return;
 964                 }
 965
 966                 default:
 967                 case CMD_REQUEST_USAGE:
 968                 {
 969                         LOG_INFO("\nUsage:^3 sv_cmd lockteams\n");
 970                         LOG_INFO("  No arguments required.\n");
 971                         LOG_INFO("See also: ^2unlockteams^7\n");
 972                         return;
 973                 }
 974         }
 975 }
 976
 977 void GameCommand_make_mapinfo(float request)
 978 {
 979         switch(request)
 980         {
 981                 case CMD_REQUEST_COMMAND:
 982                 {
 983                         entity tmp_entity;
 984
 985                         tmp_entity = spawn();
 986                         tmp_entity.classname = "make_mapinfo";
 987                         tmp_entity.think = make_mapinfo_Think;
 988                         tmp_entity.nextthink = time;
 989                         MapInfo_Enumerate();
 990                         return;
 991                 }
 992
 993                 default:
 994                 case CMD_REQUEST_USAGE:
 995                 {
 996                         LOG_INFO("\nUsage:^3 sv_cmd make_mapinfo\n");
 997                         LOG_INFO("  No arguments required.\n");
 998                         LOG_INFO("See also: ^2radarmap^7\n");
 999                         return;
1000                 }
1001         }
1002 }
1003
1004 void GameCommand_moveplayer(float request, float argc)
1005 {SELFPARAM();
1006         switch(request)
1007         {
1008                 case CMD_REQUEST_COMMAND:
1009                 {
1010                         float accepted;
1011                         entity client;
1012
1013                         string targets = strreplace(",", " ", argv(1));
1014                         string original_targets = strreplace(" ", ", ", targets);
1015                         string destination = argv(2);
1016
1017                         string successful, t;
1018                         successful = string_null;
1019
1020                         // lets see if the target(s) even actually exist.
1021                         if((targets) && (destination))
1022                         {
1023                                 for (;targets;)
1024                                 {
1025                                         t = car(targets); targets = cdr(targets);
1026
1027                                         // Check to see if the player is a valid target
1028                                         client = GetFilteredEntity(t);
1029                                         accepted = VerifyClientEntity(client, false, false);
1030
1031                                         if(accepted <= 0)
1032                                         {
1033                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1034                                                 continue;
1035                                         }
1036
1037                                         // Where are we putting this player?
1038                                         if(destination == "spec" || destination == "spectator")
1039                                         {
1040                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1041                                                 {
1042                                                         self = client;
1043                                                         if(self.caplayer)
1044                                                                 self.caplayer = 0;
1045                                                         PutObserverInServer();
1046
1047                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1048                                                 }
1049                                                 else
1050                                                 {
1051                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1052                                                 }
1053                                                 continue;
1054                                         }
1055                                         else
1056                                         {
1057                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1058                                                 {
1059                                                         if(teamplay)
1060                                                         {
1061                                                                 // set up
1062                                                                 float team_id;
1063                                                                 float save = client.team_forced;
1064                                                                 client.team_forced = 0;
1065
1066                                                                 // find the team to move the player to
1067                                                                 team_id = Team_ColorToTeam(destination);
1068                                                                 if(team_id == client.team) // already on the destination team
1069                                                                 {
1070                                                                         // keep the forcing undone
1071                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1072                                                                         continue;
1073                                                                 }
1074                                                                 else if(team_id == 0)  // auto team
1075                                                                 {
1076                                                                         CheckAllowedTeams(client);
1077                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1078                                                                 }
1079                                                                 else
1080                                                                 {
1081                                                                         CheckAllowedTeams(client);
1082                                                                 }
1083                                                                 client.team_forced = save;
1084
1085                                                                 // Check to see if the destination team is even available
1086                                                                 switch(team_id)
1087                                                                 {
1088                                                                         case NUM_TEAM_1: if(c1 == -1) { LOG_INFO("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1089                                                                         case NUM_TEAM_2: if(c2 == -1) { LOG_INFO("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1090                                                                         case NUM_TEAM_3: if(c3 == -1) { LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1091                                                                         case NUM_TEAM_4: if(c4 == -1) { LOG_INFO("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1092
1093                                                                         default: LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1094                                                                 }
1095
1096                                                                 // If so, lets continue and finally move the player
1097                                                                 client.team_forced = 0;
1098                                                                 MoveToTeam(client, team_id, 6);
1099                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1100                                                                 LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1101                                                                 continue;
1102                                                         }
1103                                                         else
1104                                                         {
1105                                                                 LOG_INFO("Can't change teams when currently not playing a team game.\n");
1106                                                                 return;
1107                                                         }
1108                                                 }
1109                                                 else
1110                                                 {
1111                                                         LOG_INFO("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1112                                                         return;
1113                                                 }
1114                                         }
1115                                 }
1116
1117                                 if(successful)
1118                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1119                                 else
1120                                         LOG_INFO("No players given (", original_targets, ") are able to move.\n");
1121
1122                                 return; // still correct parameters so return to avoid usage print
1123                         }
1124                 }
1125
1126                 default:
1127                         LOG_INFO("Incorrect parameters for ^2moveplayer^7\n");
1128                 case CMD_REQUEST_USAGE:
1129                 {
1130                         LOG_INFO("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1131                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1132                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating\n");
1133                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1134                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1135                         LOG_INFO("          sv_cmd moveplayer 2 spec \n");
1136                         LOG_INFO("See also: ^2allspec, shuffleteams^7\n");
1137                         return;
1138                 }
1139         }
1140 }
1141
1142 void GameCommand_nospectators(float request)
1143 {
1144         switch(request)
1145         {
1146                 case CMD_REQUEST_COMMAND:
1147                 {
1148                         blockSpectators = 1;
1149                         entity plr;
1150                         FOR_EACH_REALCLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1151                         {
1152                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1153                                 if(!plr.caplayer)
1154                                 {
1155                                         plr.spectatortime = time;
1156                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1157                                 }
1158                         }
1159                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1160                         return;
1161                 }
1162
1163                 default:
1164                 case CMD_REQUEST_USAGE:
1165                 {
1166                         LOG_INFO("\nUsage:^3 sv_cmd nospectators\n");
1167                         LOG_INFO("  No arguments required.\n");
1168                         return;
1169                 }
1170         }
1171 }
1172
1173 void GameCommand_playerdemo(float request, float argc)
1174 {SELFPARAM();
1175         switch(request)
1176         {
1177                 case CMD_REQUEST_COMMAND:
1178                 {
1179                         if(argv(2) && argv(3))
1180                         {
1181                                 entity client;
1182                                 float i, n, accepted;
1183
1184                                 switch(argv(1))
1185                                 {
1186                                         case "read":
1187                                         {
1188                                                 client = GetIndexedEntity(argc, 2);
1189                                                 accepted = VerifyClientEntity(client, false, true);
1190
1191                                                 if(accepted <= 0)
1192                                                 {
1193                                                         LOG_INFO("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1194                                                         return;
1195                                                 }
1196
1197                                                 self = client;
1198                                                 playerdemo_open_read(argv(next_token));
1199                                                 return;
1200                                         }
1201
1202                                         case "write":
1203                                         {
1204                                                 client = GetIndexedEntity(argc, 2);
1205                                                 accepted = VerifyClientEntity(client, false, false);
1206
1207                                                 if(accepted <= 0)
1208                                                 {
1209                                                         LOG_INFO("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1210                                                         return;
1211                                                 }
1212
1213                                                 self = client;
1214                                                 playerdemo_open_write(argv(next_token));
1215                                                 return;
1216                                         }
1217
1218                                         case "auto_read_and_write":
1219                                         {
1220                                                 n = GetFilteredNumber(argv(3));
1221                                                 cvar_set("bot_number", ftos(n));
1222
1223                                                 localcmd("wait; wait; wait\n");
1224                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1225
1226                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1227                                                 return;
1228                                         }
1229
1230                                         case "auto_read":
1231                                         {
1232                                                 n = GetFilteredNumber(argv(3));
1233                                                 cvar_set("bot_number", ftos(n));
1234
1235                                                 localcmd("wait; wait; wait\n");
1236                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1237                                                 return;
1238                                         }
1239                                 }
1240                         }
1241                 }
1242
1243                 default:
1244                         LOG_INFO("Incorrect parameters for ^2playerdemo^7\n");
1245                 case CMD_REQUEST_USAGE:
1246                 {
1247                         LOG_INFO("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1248                         LOG_INFO("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1249                         return;
1250                 }
1251         }
1252 }
1253
1254 void GameCommand_printstats(float request)
1255 {
1256         switch(request)
1257         {
1258                 case CMD_REQUEST_COMMAND:
1259                 {
1260                         DumpStats(false);
1261                         LOG_INFO("stats dumped.\n");
1262                         return;
1263                 }
1264
1265                 default:
1266                 case CMD_REQUEST_USAGE:
1267                 {
1268                         LOG_INFO("\nUsage:^3 sv_cmd printstats\n");
1269                         LOG_INFO("  No arguments required.\n");
1270                         return;
1271                 }
1272         }
1273 }
1274
1275 void GameCommand_radarmap(float request, float argc)
1276 {
1277         switch(request)
1278         {
1279                 case CMD_REQUEST_COMMAND:
1280                 {
1281                         if(RadarMap_Make(argc))
1282                                 return;
1283                 }
1284
1285                 default:
1286                         LOG_INFO("Incorrect parameters for ^2radarmap^7\n");
1287                 case CMD_REQUEST_USAGE:
1288                 {
1289                         LOG_INFO("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1290                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.\n");
1291                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1292                         LOG_INFO("See also: ^2make_mapinfo^7\n");
1293                         return;
1294                 }
1295         }
1296 }
1297
1298 void GameCommand_reducematchtime(float request)
1299 {
1300         switch(request)
1301         {
1302                 case CMD_REQUEST_COMMAND:
1303                 {
1304                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1305                         return;
1306                 }
1307
1308                 default:
1309                 case CMD_REQUEST_USAGE:
1310                 {
1311                         LOG_INFO("\nUsage:^3 sv_cmd reducematchtime\n");
1312                         LOG_INFO("  No arguments required.\n");
1313                         LOG_INFO("See also: ^2extendmatchtime^7\n");
1314                         return;
1315                 }
1316         }
1317 }
1318
1319 void GameCommand_setbots(float request, float argc)
1320 {
1321         switch(request)
1322         {
1323                 case CMD_REQUEST_COMMAND:
1324                 {
1325                         if(argc >= 2)
1326                         {
1327                                 cvar_settemp("minplayers", "0");
1328                                 cvar_settemp("bot_number", argv(1));
1329                                 bot_fixcount();
1330                                 return;
1331                         }
1332                 }
1333
1334                 default:
1335                         LOG_INFO("Incorrect parameters for ^2setbots^7\n");
1336                 case CMD_REQUEST_USAGE:
1337                 {
1338                         LOG_INFO("\nUsage:^3 sv_cmd setbots botnumber\n");
1339                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1340                         LOG_INFO("See also: ^2bot_cmd^7\n");
1341                         return;
1342                 }
1343         }
1344 }
1345
1346 void GameCommand_shuffleteams(float request)
1347 {SELFPARAM();
1348         switch(request)
1349         {
1350                 case CMD_REQUEST_COMMAND:
1351                 {
1352                         if(teamplay)
1353                         {
1354                                 entity tmp_player;
1355                                 int i;
1356                                 float x, t_teams, t_players, team_color;
1357
1358                                 // count the total amount of players and total amount of teams
1359                                 t_players = 0;
1360                                 t_teams = 0;
1361                                 FOR_EACH_CLIENT(tmp_player)
1362                                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer)
1363                                 {
1364                                         CheckAllowedTeams(tmp_player);
1365
1366                                         if(c1 >= 0) t_teams = max(1, t_teams);
1367                                         if(c2 >= 0) t_teams = max(2, t_teams);
1368                                         if(c3 >= 0) t_teams = max(3, t_teams);
1369                                         if(c4 >= 0) t_teams = max(4, t_teams);
1370
1371                                         ++t_players;
1372                                 }
1373
1374                                 // build a list of the players in a random order
1375                                 FOR_EACH_CLIENT(tmp_player)
1376                                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer)
1377                                 {
1378                                         for (;;)
1379                                         {
1380                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1381
1382                                                 if(shuffleteams_players[i])
1383                                                 {
1384                                                         continue; // a player is already assigned to this slot
1385                                                 }
1386                                                 else
1387                                                 {
1388                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1389                                                         break;
1390                                                 }
1391                                         }
1392                                 }
1393
1394                                 // finally, from the list made earlier, re-join the players in different order.
1395                                 for (int i = 1; i <= t_teams; ++i)
1396                                 {
1397                                         // find out how many players to assign to this team
1398                                         x = (t_players / t_teams);
1399                                         x = ((i == 1) ? ceil(x) : floor(x));
1400
1401                                         team_color = Team_NumberToTeam(i);
1402
1403                                         // sort through the random list of players made earlier
1404                                         for (int z = 1; z <= maxclients; ++z)
1405                                         {
1406                                                 if (!(shuffleteams_teams[i] >= x))
1407                                                 {
1408                                                         if (!(shuffleteams_players[z]))
1409                                                                 continue; // not a player, move on to next random slot
1410
1411                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1412                                                                 self = edict_num(shuffleteams_players[z]);
1413
1414                                                         if(self.team != team_color)
1415                                                                 MoveToTeam(self, team_color, 6);
1416
1417                                                         shuffleteams_players[z] = 0;
1418                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1419                                                 }
1420                                                 else
1421                                                 {
1422                                                         break; // move on to next team
1423                                                 }
1424                                         }
1425                                 }
1426
1427                                 bprint("Successfully shuffled the players around randomly.\n");
1428
1429                                 // clear the buffers now
1430                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1431                                         shuffleteams_players[i] = 0;
1432
1433                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1434                                         shuffleteams_teams[i] = 0;
1435                         }
1436                         else
1437                         {
1438                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.\n");
1439                         }
1440
1441                         return;
1442                 }
1443
1444                 default:
1445                 case CMD_REQUEST_USAGE:
1446                 {
1447                         LOG_INFO("\nUsage:^3 sv_cmd shuffleteams\n");
1448                         LOG_INFO("  No arguments required.\n");
1449                         LOG_INFO("See also: ^2moveplayer, allspec^7\n");
1450                         return;
1451                 }
1452         }
1453 }
1454
1455 void GameCommand_stuffto(float request, float argc)
1456 {
1457         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1458         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1459         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1460
1461         #ifdef STUFFTO_ENABLED
1462         #message "stuffto command enabled"
1463         switch(request)
1464         {
1465                 case CMD_REQUEST_COMMAND:
1466                 {
1467                         if(argv(2))
1468                         {
1469                                 entity client = GetIndexedEntity(argc, 1);
1470                                 float accepted = VerifyClientEntity(client, true, false);
1471
1472                                 if(accepted > 0)
1473                                 {
1474                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1475                                         LOG_INFO(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1476                                 }
1477                                 else
1478                                         LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1479
1480                                 return;
1481                         }
1482                 }
1483
1484                 default:
1485                         LOG_INFO("Incorrect parameters for ^2stuffto^7\n");
1486                 case CMD_REQUEST_USAGE:
1487                 {
1488                         LOG_INFO("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1489                         LOG_INFO("  'client' is the entity number or name of the player,\n");
1490                         LOG_INFO("  and 'command' is the command to be sent to that player.\n");
1491                         return;
1492                 }
1493         }
1494         #else
1495         if(request)
1496         {
1497                 LOG_INFO("stuffto command is not enabled on this server.\n");
1498                 return;
1499         }
1500         #endif
1501 }
1502
1503 void GameCommand_trace(float request, float argc)
1504 {
1505         switch(request)
1506         {
1507                 case CMD_REQUEST_COMMAND:
1508                 {
1509                         entity e;
1510                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1511                         float i, f, safe, unsafe, dq, dqf;
1512
1513                         switch(argv(1))
1514                         {
1515                                 case "debug":
1516                                 {
1517                                         float hitcount = 0;
1518                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1519                                         float worst_endpos_bug = 0;
1520                                         for (;;)
1521                                         {
1522                                                 org = world.mins;
1523                                                 delta = world.maxs - world.mins;
1524
1525                                                 start.x = org.x + random() * delta.x;
1526                                                 start.y = org.y + random() * delta.y;
1527                                                 start.z = org.z + random() * delta.z;
1528
1529                                                 end.x = org.x + random() * delta.x;
1530                                                 end.y = org.y + random() * delta.y;
1531                                                 end.z = org.z + random() * delta.z;
1532
1533                                                 start = stov(vtos(start));
1534                                                 end = stov(vtos(end));
1535
1536                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1537                                                 if(!trace_startsolid && trace_fraction < 1)
1538                                                 {
1539                                                         p = trace_endpos;
1540                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1541                                                         if(trace_startsolid)
1542                                                         {
1543                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1544                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1545
1546                                                                 // how much do we need to back off?
1547                                                                 safe = 1;
1548                                                                 unsafe = 0;
1549                                                                 for (;;)
1550                                                                 {
1551                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1552                                                                         tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1553                                                                         if(trace_startsolid)
1554                                                                         {
1555                                                                                 if((safe + unsafe) * 0.5 == unsafe)
1556                                                                                         break;
1557                                                                                 unsafe = (safe + unsafe) * 0.5;
1558                                                                         }
1559                                                                         else
1560                                                                         {
1561                                                                                 if((safe + unsafe) * 0.5 == safe)
1562                                                                                         break;
1563                                                                                 safe = (safe + unsafe) * 0.5;
1564                                                                         }
1565                                                                 }
1566
1567                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1568                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1569
1570                                                                 tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1571                                                                 if(trace_startsolid)
1572                                                                         LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1573                                                                 else
1574                                                                         LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1575                                                                 if (++hitcount >= 10)
1576                                                                         break;
1577                                                         }
1578                                                         else
1579                                                         {
1580                                                                 q0 = p;
1581                                                                 dq = 0;
1582                                                                 dqf = 1;
1583                                                                 for (;;)
1584                                                                 {
1585                                                                         q = p + normalize(end - p) * (dq + dqf);
1586                                                                         if(q == q0)
1587                                                                                 break;
1588                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1589                                                                         if(trace_startsolid)
1590                                                                                 error("THIS ONE cannot happen");
1591                                                                         if(trace_fraction > 0)
1592                                                                                 dq += dqf * trace_fraction;
1593                                                                         dqf *= 0.5;
1594                                                                         q0 = q;
1595                                                                 }
1596                                                                 if(dq > worst_endpos_bug)
1597                                                                 {
1598                                                                         worst_endpos_bug = dq;
1599                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1600                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1601                                                                         if (++hitcount >= 10)
1602                                                                                 break;
1603                                                                 }
1604                                                         }
1605                                                 }
1606                                         }
1607                                         return;
1608                                 }
1609
1610                                 case "debug2":
1611                                 {
1612                                         e = nextent(world);
1613                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1614                                         vv = trace_endpos;
1615                                         if(trace_fraction == 1)
1616                                         {
1617                                                 LOG_INFO("not above ground, aborting\n");
1618                                                 return;
1619                                         }
1620                                         f = 0;
1621                                         for(i = 0; i < 100000; ++i)
1622                                         {
1623                                                 dv = randomvec();
1624                                                 if(dv.z > 0)
1625                                                         dv = -1 * dv;
1626                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1627                                                 if(trace_startsolid)
1628                                                         LOG_INFO("bug 1\n");
1629                                                 if(trace_fraction == 1)
1630                                                 if(dv.z < f)
1631                                                 {
1632                                                         LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1633                                                         LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1634                                                         f = dv.z;
1635                                                 }
1636                                         }
1637                                         LOG_INFO("highest possible dist: ", ftos(f), "\n");
1638                                         return;
1639                                 }
1640
1641                                 case "walk":
1642                                 {
1643                                         if(argc == 4)
1644                                         {
1645                                                 e = nextent(world);
1646                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1647                                                         LOG_INFO("can walk\n");
1648                                                 else
1649                                                         LOG_INFO("cannot walk\n");
1650                                                 return;
1651                                         }
1652                                 }
1653
1654                                 case "showline":
1655                                 {
1656                                         if(argc == 4)
1657                                         {
1658                                                 vv = stov(argv(2));
1659                                                 dv = stov(argv(3));
1660                                                 traceline(vv, dv, MOVE_NORMAL, world);
1661                                                 trailparticles(world, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1662                                                 trailparticles(world, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1663                                                 return;
1664                                         }
1665                                 }
1666
1667                                 // no default case, just go straight to invalid
1668                         }
1669                 }
1670
1671                 default:
1672                         LOG_INFO("Incorrect parameters for ^2trace^7\n");
1673                 case CMD_REQUEST_USAGE:
1674                 {
1675                         LOG_INFO("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1676                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1677                         LOG_INFO("See also: ^2bbox, gettaginfo^7\n");
1678                         return;
1679                 }
1680         }
1681 }
1682
1683 void GameCommand_unlockteams(float request)
1684 {
1685         switch(request)
1686         {
1687                 case CMD_REQUEST_COMMAND:
1688                 {
1689                         if(teamplay)
1690                         {
1691                                 lockteams = 0;
1692                                 bprint("^1The teams are now unlocked.\n");
1693                         }
1694                         else
1695                         {
1696                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1697                         }
1698                         return;
1699                 }
1700
1701                 default:
1702                 case CMD_REQUEST_USAGE:
1703                 {
1704                         LOG_INFO("\nUsage:^3 sv_cmd unlockteams\n");
1705                         LOG_INFO("  No arguments required.\n");
1706                         LOG_INFO("See also: ^2lockteams^7\n");
1707                         return;
1708                 }
1709         }
1710 }
1711
1712 void GameCommand_warp(float request, float argc)
1713 {
1714         switch (request)
1715         {
1716                 case CMD_REQUEST_COMMAND:
1717                 {
1718                         if(autocvar_g_campaign)
1719                         {
1720                                 if(argc >= 2)
1721                                 {
1722                                         CampaignLevelWarp(stof(argv(1)));
1723                                         LOG_INFO("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1724                                 }
1725                                 else
1726                                 {
1727                                         CampaignLevelWarp(-1);
1728                                         LOG_INFO("Successfully warped to next campaign level.\n");
1729                                 }
1730                         }
1731                         else
1732                                 LOG_INFO("Not in campaign, can't level warp\n");
1733                         return;
1734                 }
1735
1736                 default:
1737                 case CMD_REQUEST_USAGE:
1738                 {
1739                         LOG_INFO("\nUsage:^3 sv_cmd warp [level]\n");
1740                         LOG_INFO("  'level' is the level to change campaign mode to.\n");
1741                         LOG_INFO("  if 'level' is not provided it will change to the next level.\n");
1742                         return;
1743                 }
1744         }
1745 }
1746
1747 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1748 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1749 void GameCommand_(float request)
1750 {
1751         switch(request)
1752         {
1753                 case CMD_REQUEST_COMMAND:
1754                 {
1755
1756                         return;
1757                 }
1758
1759                 default:
1760                 case CMD_REQUEST_USAGE:
1761                 {
1762                         print("\nUsage:^3 sv_cmd \n");
1763                         print("  No arguments required.\n");
1764                         return;
1765                 }
1766         }
1767 }
1768 */
1769
1770
1771 // ==================================
1772 //  Macro system for server commands
1773 // ==================================
1774
1775 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1776 #define SERVER_COMMANDS(request,arguments,command) \
1777         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1778         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1779         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1780         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1781         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1782         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1783         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1784         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1785         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1786         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1787         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1788         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1789         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1790         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1791         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1792         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1793         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1794         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1795         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1796         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1797         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1798         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1799         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1800         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1801         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1802         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1803         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1804         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1805         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1806         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1807         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1808         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1809         /* nothing */
1810
1811 void GameCommand_macro_help()
1812 {
1813         #define SERVER_COMMAND(name,function,description) \
1814                 { LOG_INFO("  ^2", name, "^7: ", description, "\n"); }
1815
1816         SERVER_COMMANDS(0, 0, "");
1817         #undef SERVER_COMMAND
1818
1819         return;
1820 }
1821
1822 float GameCommand_macro_command(float argc, string command)
1823 {
1824         #define SERVER_COMMAND(name,function,description) \
1825                 { if(name == strtolower(argv(0))) { function; return true; } }
1826
1827         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
1828         #undef SERVER_COMMAND
1829
1830         return false;
1831 }
1832
1833 float GameCommand_macro_usage(float argc)
1834 {
1835         #define SERVER_COMMAND(name,function,description) \
1836                 { if(name == strtolower(argv(1))) { function; return true; } }
1837
1838         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "");
1839         #undef SERVER_COMMAND
1840
1841         return false;
1842 }
1843
1844 void GameCommand_macro_write_aliases(float fh)
1845 {
1846         #define SERVER_COMMAND(name,function,description) \
1847                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1848
1849         SERVER_COMMANDS(0, 0, "");
1850         #undef SERVER_COMMAND
1851
1852         return;
1853 }
1854
1855
1856 // =========================================
1857 //  Main Function Called By Engine (sv_cmd)
1858 // =========================================
1859 // If this function exists, game code handles gamecommand instead of the engine code.
1860
1861 void GameCommand(string command)
1862 {
1863         float argc = tokenize_console(command);
1864
1865         // Guide for working with argc arguments by example:
1866         // argc:   1    - 2      - 3     - 4
1867         // argv:   0    - 1      - 2     - 3
1868         // cmd     vote - master - login - password
1869
1870         if(strtolower(argv(0)) == "help")
1871         {
1872                 if(argc == 1)
1873                 {
1874                         LOG_INFO("\nServer console commands:\n");
1875                         GameCommand_macro_help();
1876
1877                         LOG_INFO("\nBanning commands:\n");
1878                         BanCommand_macro_help();
1879
1880                         LOG_INFO("\nCommon networked commands:\n");
1881                         CommonCommand_macro_help(world);
1882
1883                         LOG_INFO("\nGeneric commands shared by all programs:\n");
1884                         GenericCommand_macro_help();
1885
1886                         LOG_INFO("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1887                         LOG_INFO("For help about a specific command, type sv_cmd help COMMAND\n");
1888
1889                         return;
1890                 }
1891                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1892                 {
1893                         return;
1894                 }
1895                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1896                 {
1897                         return;
1898                 }
1899                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1900                 {
1901                         return;
1902                 }
1903                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1904                 {
1905                         return;
1906                 }
1907         }
1908         else if(MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1909         {
1910                 return; // handled by a mutator
1911         }
1912         else if(BanCommand(command))
1913         {
1914                 return; // handled by server/command/ipban.qc
1915         }
1916         else if(CommonCommand_macro_command(argc, world, command))
1917         {
1918                 return; // handled by server/command/common.qc
1919         }
1920         else if(GenericCommand(command))
1921         {
1922                 return; // handled by common/command/generic.qc
1923         }
1924         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1925         {
1926                 return; // handled by one of the above GameCommand_* functions
1927         }
1928
1929         // nothing above caught the command, must be invalid
1930         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1931
1932         return;
1933 }