qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2 #include "_mod.qh"
   3
   4 #include <common/effects/all.qh>
   5
   6 #include "banning.qh"
   7 #include "cmd.qh"
   8 #include "common.qh"
   9 #include "getreplies.qh"
  10 #include "radarmap.qh"
  11
  12 #include "../anticheat.qh"
  13 #include "../campaign.qh"
  14 #include "../client.qh"
  15 #include "../player.qh"
  16 #include "../g_world.qh"
  17 #include "../ipban.qh"
  18 #include "../teamplay.qh"
  19
  20 #include "../bot/api.qh"
  21
  22 #include "../mutators/_mod.qh"
  23
  24 #include <common/constants.qh>
  25 #include <common/net_linked.qh>
  26 #include <common/mapinfo.qh>
  27 #include <common/notifications/all.qh>
  28 #include <common/teams.qh>
  29 #include <common/util.qh>
  30
  31 #include <common/monsters/sv_monsters.qh>
  32
  33
  34 void PutObserverInServer(entity this);
  35
  36 // =====================================================
  37 //  Server side game commands code, reworked by Samual
  38 // =====================================================
  39
  40 //  used by GameCommand_make_mapinfo()
  41 void make_mapinfo_Think(entity this)
  42 {
  43         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  44         {
  45                 LOG_INFO("Done rebuiling mapinfos.");
  46                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  47                 delete(this);
  48         }
  49         else
  50         {
  51                 setthink(this, make_mapinfo_Think);
  52                 this.nextthink = time;
  53         }
  54 }
  55
  56 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  57 void changematchtime(float delta, float mi, float ma)
  58 {
  59         float cur;
  60         float update;
  61         float lim;
  62
  63         if (delta == 0) return;
  64         if (autocvar_timelimit < 0) return;
  65
  66         if (mi <= 10) mi = 10;  // at least ten sec in the future
  67         cur = time - game_starttime;
  68         if (cur > 0) mi += cur; // from current time!
  69
  70         lim = autocvar_timelimit * 60;
  71
  72         if (delta > 0)
  73         {
  74                 if (lim == 0) return; // cannot increase any further
  75                 else if (lim < ma) update = min(ma, lim + delta);
  76                 else                  // already above maximum: FAIL
  77                         return;
  78         }
  79         else
  80         {
  81                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  82                         update = max(mi, ma);
  83                 else if (lim > mi) // above minimum: decrease
  84                         update = max(mi, lim + delta);
  85                 else               // already below minimum: FAIL
  86                         return;
  87         }
  88
  89         cvar_set("timelimit", ftos(update / 60));
  90 }
  91
  92
  93 // =======================
  94 //  Command Sub-Functions
  95 // =======================
  96
  97 void GameCommand_adminmsg(float request, float argc)
  98 {
  99         switch (request)
 100         {
 101                 case CMD_REQUEST_COMMAND:
 102                 {
 103                         entity client;
 104                         float accepted;
 105
 106                         string targets = strreplace(",", " ", argv(1));
 107                         string original_targets = strreplace(" ", ", ", targets);
 108                         string admin_message = argv(2);
 109                         float infobartime = stof(argv(3));
 110
 111                         string successful, t;
 112                         successful = string_null;
 113
 114                         if ((targets) && (admin_message))
 115                         {
 116                                 for ( ; targets; )
 117                                 {
 118                                         t = car(targets);
 119                                         targets = cdr(targets);
 120
 121                                         // Check to see if the player is a valid target
 122                                         client = GetFilteredEntity(t);
 123                                         accepted = VerifyClientEntity(client, true, false);
 124
 125                                         if (accepted <= 0)
 126                                         {
 127                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 128                                                 continue;
 129                                         }
 130
 131                                         // send the centerprint/console print or infomessage
 132                                         if (infobartime)
 133                                         {
 134                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 135                                         }
 136                                         else
 137                                         {
 138                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 139                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 140                                         }
 141
 142                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
 143                                         LOG_TRACE("Message sent to ", playername(client, false));
 144                                         continue;
 145                                 }
 146
 147                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 148                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 149
 150                                 return;
 151                         }
 152                 }
 153
 154                 default:
 155                         LOG_INFO("Incorrect parameters for ^2adminmsg^7");
 156                 case CMD_REQUEST_USAGE:
 157                 {
 158                         LOG_INFO("Usage:^3 sv_cmd adminmsg clients \"message\" [infobartime]");
 159                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
 160                         LOG_INFO("  If infobartime is provided, the message will be sent to infobar.");
 161                         LOG_INFO("  Otherwise, it will just be sent as a centerprint message.");
 162                         LOG_INFO("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 163                         LOG_INFO("          adminmsg 2,5 \"this message will be a centerprint\"");
 164                         return;
 165                 }
 166         }
 167 }
 168
 169 void GameCommand_allready(float request)
 170 {
 171         switch (request)
 172         {
 173                 case CMD_REQUEST_COMMAND:
 174                 {
 175                         ReadyRestart();
 176                         return;
 177                 }
 178
 179                 default:
 180                 case CMD_REQUEST_USAGE:
 181                 {
 182                         LOG_INFO("Usage:^3 sv_cmd allready");
 183                         LOG_INFO("  No arguments required.");
 184                         return;
 185                 }
 186         }
 187 }
 188
 189 void GameCommand_allspec(float request, float argc)
 190 {
 191         switch (request)
 192         {
 193                 case CMD_REQUEST_COMMAND:
 194                 {
 195                         string reason = argv(1);
 196                         int n = 0;
 197                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 198                                 if (it.caplayer) it.caplayer = 0;
 199                                 PutObserverInServer(it);
 200                                 ++n;
 201                         });
 202                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 203                         else   LOG_INFO("No players found to spectate.");
 204                         return;
 205                 }
 206
 207                 default:
 208                 case CMD_REQUEST_USAGE:
 209                 {
 210                         LOG_INFO("Usage:^3 sv_cmd allspec [reason]");
 211                         LOG_INFO("  Where 'reason' is an optional argument for explanation of allspec command.");
 212                         LOG_INFO("See also: ^2moveplayer, shuffleteams^7");
 213                         return;
 214                 }
 215         }
 216 }
 217
 218 void GameCommand_anticheat(float request, float argc)
 219 {
 220         switch (request)
 221         {
 222                 case CMD_REQUEST_COMMAND:
 223                 {
 224                         entity client = GetIndexedEntity(argc, 1);
 225                         float accepted = VerifyClientEntity(client, false, false);
 226
 227                         if (accepted > 0)
 228                         {
 229                                 anticheat_report_to_eventlog(client);
 230                                 return;
 231                         }
 232                         else
 233                         {
 234                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 235                         }
 236                 }
 237
 238                 default:
 239                         LOG_INFO("Incorrect parameters for ^2anticheat^7");
 240                 case CMD_REQUEST_USAGE:
 241                 {
 242                         LOG_INFO("Usage:^3 sv_cmd anticheat client");
 243                         LOG_INFO("  'client' is the entity number or name of the player.");
 244                         return;
 245                 }
 246         }
 247 }
 248
 249 void GameCommand_bbox(float request)
 250 {
 251         switch (request)
 252         {
 253                 case CMD_REQUEST_COMMAND:
 254                 {
 255                         vector size_min = '0 0 0';
 256                         vector size_max = '0 0 0';
 257                         tracebox('1 0 0' * world.absmin.x,
 258                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 259                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 260                                 '1 0 0' * world.absmax.x,
 261                                 MOVE_WORLDONLY,
 262                                 NULL);
 263                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 264
 265                         tracebox('0 1 0' * world.absmin.y,
 266                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 267                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 268                                 '0 1 0' * world.absmax.y,
 269                                 MOVE_WORLDONLY,
 270                                 NULL);
 271                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 272
 273                         tracebox('0 0 1' * world.absmin.z,
 274                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 275                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 276                                 '0 0 1' * world.absmax.z,
 277                                 MOVE_WORLDONLY,
 278                                 NULL);
 279                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 280
 281                         tracebox('1 0 0' * world.absmax.x,
 282                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 283                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 284                                 '1 0 0' * world.absmin.x,
 285                                 MOVE_WORLDONLY,
 286                                 NULL);
 287                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 288
 289                         tracebox('0 1 0' * world.absmax.y,
 290                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 291                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 292                                 '0 1 0' * world.absmin.y,
 293                                 MOVE_WORLDONLY,
 294                                 NULL);
 295                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 296
 297                         tracebox('0 0 1' * world.absmax.z,
 298                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 299                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 300                                 '0 0 1' * world.absmin.z,
 301                                 MOVE_WORLDONLY,
 302                                 NULL);
 303                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 304
 305                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 306                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 307                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 308                         return;
 309                 }
 310
 311                 default:
 312                 case CMD_REQUEST_USAGE:
 313                 {
 314                         LOG_INFO("Usage:^3 sv_cmd bbox");
 315                         LOG_INFO("  No arguments required.");
 316                         LOG_INFO("See also: ^2gettaginfo, trace^7");
 317                         return;
 318                 }
 319         }
 320 }
 321
 322 void GameCommand_bot_cmd(float request, float argc, string command)
 323 {
 324         switch (request)
 325         {
 326                 case CMD_REQUEST_COMMAND:
 327                 {
 328                         entity bot;
 329
 330                         if (argv(1) == "reset")
 331                         {
 332                                 bot_resetqueues();
 333                                 return;
 334                         }
 335                         else if (argv(1) == "setbots")
 336                         {
 337                                 cvar_settemp("bot_vs_human", "0");
 338                                 cvar_settemp("minplayers", "0");
 339                                 cvar_settemp("bot_number", "0");
 340                                 bot_fixcount();
 341                                 cvar_settemp("bot_number", argv(2));
 342                                 if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 343                                 return;
 344                         }
 345                         else if (argv(1) == "load" && argc == 3)
 346                         {
 347                                 float fh, i;
 348                                 string s;
 349                                 fh = fopen(argv(2), FILE_READ);
 350                                 if (fh < 0)
 351                                 {
 352                                         LOG_INFO("cannot open the file");
 353                                         return;
 354                                 }
 355
 356                                 i = 0;
 357                                 while ((s = fgets(fh)))
 358                                 {
 359                                         argc = tokenize_console(s);
 360
 361                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 362                                         {
 363                                                 if (argv(2) == "reset")
 364                                                 {
 365                                                         bot_resetqueues();
 366                                                 }
 367                                                 else if (argv(2) == "setbots")
 368                                                 {
 369                                                         cvar_settemp("bot_vs_human", "0");
 370                                                         cvar_settemp("minplayers", "0");
 371                                                         cvar_settemp("bot_number", "0");
 372                                                         bot_fixcount();
 373                                                         cvar_settemp("bot_number", argv(3));
 374                                                         if (!bot_fixcount()) LOG_INFO("Sorry, could not set requested bot count");
 375                                                 }
 376                                                 else
 377                                                 {
 378                                                         if(argv(2) == "*" || argv(2) == "all")
 379                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 380                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 381                                                                 });
 382                                                         else
 383                                                         {
 384                                                                 bot = find_bot_by_number(stof(argv(2)));
 385                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 386                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 387                                                         }
 388                                                 }
 389                                         }
 390                                         else
 391                                         {
 392                                                 localcmd(strcat(s, "\n"));
 393                                         }
 394
 395                                         ++i;
 396                                 }
 397                                 LOG_INFO(ftos(i), " commands read");
 398                                 fclose(fh);
 399                                 return;
 400                         }
 401                         else if (argv(1) == "help")
 402                         {
 403                                 if (argv(2)) bot_cmdhelp(argv(2));
 404                                 else bot_list_commands();
 405                                 return;
 406                         }
 407                         else if (argc >= 3)  // this comes last
 408                         {
 409                                 if(argv(1) == "*" || argv(1) == "all")
 410                                 {
 411                                         int bot_num = 0;
 412                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 413                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 414                                                 bot_num++;
 415                                         });
 416                                         if(bot_num)
 417                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 418                                         return;
 419                                 }
 420                                 else
 421                                 {
 422                                         bot = find_bot_by_number(stof(argv(1)));
 423                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 424                                         if (bot)
 425                                         {
 426                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 427                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 428                                                 return;
 429                                         }
 430                                         else
 431                                         {
 432                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 433                                         }
 434                                 }
 435                         }
 436                 }
 437
 438                 default:
 439                         LOG_INFO("Incorrect parameters for ^2bot_cmd^7");
 440                 case CMD_REQUEST_USAGE:
 441                 {
 442                         LOG_INFO("Usage:^3 sv_cmd bot_cmd client command [argument]");
 443                         LOG_INFO("  'client' can be either the name of the bot or a progressive number (not the entity number!)");
 444                         LOG_INFO("           can also be '*' or 'all' to allow sending the command to all the bots");
 445                         LOG_INFO("  For full list of commands, see bot_cmd help [command].");
 446                         LOG_INFO("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 447                         LOG_INFO("          sv_cmd bot_cmd 1 presskey jump");
 448                         LOG_INFO("          sv_cmd bot_cmd * pause");
 449                         return;
 450                 }
 451         }
 452 }
 453
 454 void GameCommand_cointoss(float request, float argc)
 455 {
 456         switch (request)
 457         {
 458                 case CMD_REQUEST_COMMAND:
 459                 {
 460                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 461                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 462                         string choice = ((random() > 0.5) ? result1 : result2);
 463
 464                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 465                         return;
 466                 }
 467
 468                 default:
 469                 case CMD_REQUEST_USAGE:
 470                 {
 471                         LOG_INFO("Usage:^3 sv_cmd cointoss [result1 result2]");
 472                         LOG_INFO("  Where 'result1' and 'result2' are user created options.");
 473                         return;
 474                 }
 475         }
 476 }
 477
 478 void GameCommand_database(float request, float argc)
 479 {
 480         switch (request)
 481         {
 482                 case CMD_REQUEST_COMMAND:
 483                 {
 484                         if (argc == 3)
 485                         {
 486                                 if (argv(1) == "save")
 487                                 {
 488                                         db_save(ServerProgsDB, argv(2));
 489                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 490                                         return;
 491                                 }
 492                                 else if (argv(1) == "dump")
 493                                 {
 494                                         db_dump(ServerProgsDB, argv(2));
 495                                         LOG_INFO("DB dumped.");  // wtf does this do?
 496                                         return;
 497                                 }
 498                                 else if (argv(1) == "load")
 499                                 {
 500                                         db_close(ServerProgsDB);
 501                                         ServerProgsDB = db_load(argv(2));
 502                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 503                                         return;
 504                                 }
 505                         }
 506                 }
 507
 508                 default:
 509                         LOG_INFO("Incorrect parameters for ^2database^7");
 510                 case CMD_REQUEST_USAGE:
 511                 {
 512                         LOG_INFO("Usage:^3 sv_cmd database action filename");
 513                         LOG_INFO("  Where 'action' is the command to complete,");
 514                         LOG_INFO("  and 'filename' is what it acts upon.");
 515                         LOG_INFO("  Full list of commands here: \"save, dump, load.\"");
 516                         return;
 517                 }
 518         }
 519 }
 520
 521 void GameCommand_defer_clear(float request, float argc)
 522 {
 523         switch (request)
 524         {
 525                 case CMD_REQUEST_COMMAND:
 526                 {
 527                         entity client;
 528                         float accepted;
 529
 530                         if (argc >= 2)
 531                         {
 532                                 client = GetIndexedEntity(argc, 1);
 533                                 accepted = VerifyClientEntity(client, true, false);
 534
 535                                 if (accepted > 0)
 536                                 {
 537                                         stuffcmd(client, "defer clear\n");
 538                                         LOG_INFO("defer clear stuffed to ", playername(client, false));
 539                                 }
 540                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 541
 542                                 return;
 543                         }
 544                 }
 545
 546                 default:
 547                         LOG_INFO("Incorrect parameters for ^2defer_clear^7");
 548                 case CMD_REQUEST_USAGE:
 549                 {
 550                         LOG_INFO("Usage:^3 sv_cmd defer_clear client");
 551                         LOG_INFO("  'client' is the entity number or name of the player.");
 552                         LOG_INFO("See also: ^2defer_clear_all^7");
 553                         return;
 554                 }
 555         }
 556 }
 557
 558 void GameCommand_defer_clear_all(float request)
 559 {
 560         switch (request)
 561         {
 562                 case CMD_REQUEST_COMMAND:
 563                 {
 564                         int n = 0;
 565                         float argc;
 566
 567                         FOREACH_CLIENT(true, {
 568                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 569                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 570                                 ++n;
 571                         });
 572                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 573                         return;
 574                 }
 575
 576                 default:
 577                 case CMD_REQUEST_USAGE:
 578                 {
 579                         LOG_INFO("Usage:^3 sv_cmd defer_clear_all");
 580                         LOG_INFO("  No arguments required.");
 581                         LOG_INFO("See also: ^2defer_clear^7");
 582                         return;
 583                 }
 584         }
 585 }
 586
 587 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 588 {
 589         switch (request)
 590         {
 591                 case CMD_REQUEST_COMMAND:
 592                 {
 593                         if (argv(1))
 594                         {
 595                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 596                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 597                                 return;
 598                         }
 599                 }
 600
 601                 default:
 602                         LOG_INFO("Incorrect parameters for ^2delrec^7");
 603                 case CMD_REQUEST_USAGE:
 604                 {
 605                         LOG_INFO("Usage:^3 sv_cmd delrec ranking [map]");
 606                         LOG_INFO("  'ranking' is which ranking level to clear up to, ");
 607                         LOG_INFO("  it will clear all records up to nth place.");
 608                         LOG_INFO("  if 'map' is not provided it will use current map.");
 609                         return;
 610                 }
 611         }
 612 }
 613
 614 void GameCommand_effectindexdump(float request)
 615 {
 616         switch (request)
 617         {
 618                 case CMD_REQUEST_COMMAND:
 619                 {
 620                         float fh, d;
 621                         string s;
 622
 623                         d = db_create();
 624                         LOG_INFO("begin of effects list");
 625                         db_put(d, "TE_GUNSHOT", "1");
 626                         LOG_INFO("effect TE_GUNSHOT is ", ftos(_particleeffectnum("TE_GUNSHOT")));
 627                         db_put(d, "TE_GUNSHOTQUAD", "1");
 628                         LOG_INFO("effect TE_GUNSHOTQUAD is ", ftos(_particleeffectnum("TE_GUNSHOTQUAD")));
 629                         db_put(d, "TE_SPIKE", "1");
 630                         LOG_INFO("effect TE_SPIKE is ", ftos(_particleeffectnum("TE_SPIKE")));
 631                         db_put(d, "TE_SPIKEQUAD", "1");
 632                         LOG_INFO("effect TE_SPIKEQUAD is ", ftos(_particleeffectnum("TE_SPIKEQUAD")));
 633                         db_put(d, "TE_SUPERSPIKE", "1");
 634                         LOG_INFO("effect TE_SUPERSPIKE is ", ftos(_particleeffectnum("TE_SUPERSPIKE")));
 635                         db_put(d, "TE_SUPERSPIKEQUAD", "1");
 636                         LOG_INFO("effect TE_SUPERSPIKEQUAD is ", ftos(_particleeffectnum("TE_SUPERSPIKEQUAD")));
 637                         db_put(d, "TE_WIZSPIKE", "1");
 638                         LOG_INFO("effect TE_WIZSPIKE is ", ftos(_particleeffectnum("TE_WIZSPIKE")));
 639                         db_put(d, "TE_KNIGHTSPIKE", "1");
 640                         LOG_INFO("effect TE_KNIGHTSPIKE is ", ftos(_particleeffectnum("TE_KNIGHTSPIKE")));
 641                         db_put(d, "TE_EXPLOSION", "1");
 642                         LOG_INFO("effect TE_EXPLOSION is ", ftos(_particleeffectnum("TE_EXPLOSION")));
 643                         db_put(d, "TE_EXPLOSIONQUAD", "1");
 644                         LOG_INFO("effect TE_EXPLOSIONQUAD is ", ftos(_particleeffectnum("TE_EXPLOSIONQUAD")));
 645                         db_put(d, "TE_TAREXPLOSION", "1");
 646                         LOG_INFO("effect TE_TAREXPLOSION is ", ftos(_particleeffectnum("TE_TAREXPLOSION")));
 647                         db_put(d, "TE_TELEPORT", "1");
 648                         LOG_INFO("effect TE_TELEPORT is ", ftos(_particleeffectnum("TE_TELEPORT")));
 649                         db_put(d, "TE_LAVASPLASH", "1");
 650                         LOG_INFO("effect TE_LAVASPLASH is ", ftos(_particleeffectnum("TE_LAVASPLASH")));
 651                         db_put(d, "TE_SMALLFLASH", "1");
 652                         LOG_INFO("effect TE_SMALLFLASH is ", ftos(_particleeffectnum("TE_SMALLFLASH")));
 653                         db_put(d, "TE_FLAMEJET", "1");
 654                         LOG_INFO("effect TE_FLAMEJET is ", ftos(_particleeffectnum("TE_FLAMEJET")));
 655                         db_put(d, "EF_FLAME", "1");
 656                         LOG_INFO("effect EF_FLAME is ", ftos(_particleeffectnum("EF_FLAME")));
 657                         db_put(d, "TE_BLOOD", "1");
 658                         LOG_INFO("effect TE_BLOOD is ", ftos(_particleeffectnum("TE_BLOOD")));
 659                         db_put(d, "TE_SPARK", "1");
 660                         LOG_INFO("effect TE_SPARK is ", ftos(_particleeffectnum("TE_SPARK")));
 661                         db_put(d, "TE_PLASMABURN", "1");
 662                         LOG_INFO("effect TE_PLASMABURN is ", ftos(_particleeffectnum("TE_PLASMABURN")));
 663                         db_put(d, "TE_TEI_G3", "1");
 664                         LOG_INFO("effect TE_TEI_G3 is ", ftos(_particleeffectnum("TE_TEI_G3")));
 665                         db_put(d, "TE_TEI_SMOKE", "1");
 666                         LOG_INFO("effect TE_TEI_SMOKE is ", ftos(_particleeffectnum("TE_TEI_SMOKE")));
 667                         db_put(d, "TE_TEI_BIGEXPLOSION", "1");
 668                         LOG_INFO("effect TE_TEI_BIGEXPLOSION is ", ftos(_particleeffectnum("TE_TEI_BIGEXPLOSION")));
 669                         db_put(d, "TE_TEI_PLASMAHIT", "1");
 670                         LOG_INFO("effect TE_TEI_PLASMAHIT is ", ftos(_particleeffectnum("TE_TEI_PLASMAHIT")));
 671                         db_put(d, "EF_STARDUST", "1");
 672                         LOG_INFO("effect EF_STARDUST is ", ftos(_particleeffectnum("EF_STARDUST")));
 673                         db_put(d, "TR_ROCKET", "1");
 674                         LOG_INFO("effect TR_ROCKET is ", ftos(_particleeffectnum("TR_ROCKET")));
 675                         db_put(d, "TR_GRENADE", "1");
 676                         LOG_INFO("effect TR_GRENADE is ", ftos(_particleeffectnum("TR_GRENADE")));
 677                         db_put(d, "TR_BLOOD", "1");
 678                         LOG_INFO("effect TR_BLOOD is ", ftos(_particleeffectnum("TR_BLOOD")));
 679                         db_put(d, "TR_WIZSPIKE", "1");
 680                         LOG_INFO("effect TR_WIZSPIKE is ", ftos(_particleeffectnum("TR_WIZSPIKE")));
 681                         db_put(d, "TR_SLIGHTBLOOD", "1");
 682                         LOG_INFO("effect TR_SLIGHTBLOOD is ", ftos(_particleeffectnum("TR_SLIGHTBLOOD")));
 683                         db_put(d, "TR_KNIGHTSPIKE", "1");
 684                         LOG_INFO("effect TR_KNIGHTSPIKE is ", ftos(_particleeffectnum("TR_KNIGHTSPIKE")));
 685                         db_put(d, "TR_VORESPIKE", "1");
 686                         LOG_INFO("effect TR_VORESPIKE is ", ftos(_particleeffectnum("TR_VORESPIKE")));
 687                         db_put(d, "TR_NEHAHRASMOKE", "1");
 688                         LOG_INFO("effect TR_NEHAHRASMOKE is ", ftos(_particleeffectnum("TR_NEHAHRASMOKE")));
 689                         db_put(d, "TR_NEXUIZPLASMA", "1");
 690                         LOG_INFO("effect TR_NEXUIZPLASMA is ", ftos(_particleeffectnum("TR_NEXUIZPLASMA")));
 691                         db_put(d, "TR_GLOWTRAIL", "1");
 692                         LOG_INFO("effect TR_GLOWTRAIL is ", ftos(_particleeffectnum("TR_GLOWTRAIL")));
 693                         db_put(d, "TR_SEEKER", "1");
 694                         LOG_INFO("effect TR_SEEKER is ", ftos(_particleeffectnum("TR_SEEKER")));
 695                         db_put(d, "SVC_PARTICLE", "1");
 696                         LOG_INFO("effect SVC_PARTICLE is ", ftos(_particleeffectnum("SVC_PARTICLE")));
 697
 698                         fh = fopen("effectinfo.txt", FILE_READ);
 699                         while ((s = fgets(fh)))
 700                         {
 701                                 tokenize_console(s);
 702                                 if (argv(0) == "effect")
 703                                 {
 704                                         if (db_get(d, argv(1)) != "1")
 705                                         {
 706                                                 int i = _particleeffectnum(argv(1));
 707                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 708                                                 db_put(d, argv(1), "1");
 709                                         }
 710                                 }
 711                         }
 712                         LOG_INFO("end of effects list");
 713
 714                         db_close(d);
 715                         return;
 716                 }
 717
 718                 default:
 719                 case CMD_REQUEST_USAGE:
 720                 {
 721                         LOG_INFO("Usage:^3 sv_cmd effectindexdump");
 722                         LOG_INFO("  No arguments required.");
 723                         return;
 724                 }
 725         }
 726 }
 727
 728 void GameCommand_extendmatchtime(float request)
 729 {
 730         switch (request)
 731         {
 732                 case CMD_REQUEST_COMMAND:
 733                 {
 734                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 735                         return;
 736                 }
 737
 738                 default:
 739                 case CMD_REQUEST_USAGE:
 740                 {
 741                         LOG_INFO("Usage:^3 sv_cmd extendmatchtime");
 742                         LOG_INFO("  No arguments required.");
 743                         LOG_INFO("See also: ^2reducematchtime^7");
 744                         return;
 745                 }
 746         }
 747 }
 748
 749 void GameCommand_gametype(float request, float argc)
 750 {
 751         switch (request)
 752         {
 753                 case CMD_REQUEST_COMMAND:
 754                 {
 755                         if (argv(1) != "")
 756                         {
 757                                 string s = argv(1);
 758                                 Gametype t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 759
 760                                 if (t)
 761                                 {
 762                                         MapInfo_SwitchGameType(t);
 763                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 764                                         if (MapInfo_count > 0)
 765                                         {
 766                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 767                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 768                                                 lsmaps_reply = strzone(getlsmaps());
 769                                                 bprint("Game type successfully switched to ", s, "\n");
 770                                         }
 771                                         else
 772                                         {
 773                                                 bprint("Cannot use this game type: no map for it found\n");
 774                                                 MapInfo_SwitchGameType(tsave);
 775                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 776                                         }
 777                                 }
 778                                 else
 779                                 {
 780                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 781                                 }
 782
 783                                 return;
 784                         }
 785                 }
 786
 787                 default:
 788                         LOG_INFO("Incorrect parameters for ^2gametype^7");
 789                 case CMD_REQUEST_USAGE:
 790                 {
 791                         LOG_INFO("Usage:^3 sv_cmd gametype mode");
 792                         LOG_INFO("  Where 'mode' is the gametype mode to switch to.");
 793                         LOG_INFO("See also: ^2gotomap^7");
 794                         return;
 795                 }
 796         }
 797 }
 798
 799 void GameCommand_gettaginfo(float request, float argc)
 800 {
 801         switch (request)
 802         {
 803                 case CMD_REQUEST_COMMAND:
 804                 {
 805                         entity tmp_entity;
 806                         float i;
 807                         vector v;
 808
 809                         if (argc >= 4)
 810                         {
 811                                 tmp_entity = spawn();
 812                                 if (argv(1) == "w")
 813                                 {
 814                                         .entity weaponentity = weaponentities[0];
 815                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 816                                 }
 817                                 else
 818                                 {
 819                                         precache_model(argv(1));
 820                                         _setmodel(tmp_entity, argv(1));
 821                                 }
 822                                 tmp_entity.frame = stof(argv(2));
 823                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 824                                 else i = gettagindex(tmp_entity, argv(3));
 825                                 if (i)
 826                                 {
 827                                         v = gettaginfo(tmp_entity, i);
 828                                         LOG_INFOF(
 829                                             "model %s frame %s tag %s index %s parent %s",
 830                                             tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 831                                         );
 832                                         LOG_INFOF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 833                                         LOG_INFOF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 834                                         LOG_INFOF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 835                                         LOG_INFOF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 836                                         LOG_INFOF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 837                                         if (argc >= 6)
 838                                         {
 839                                                 v.y = -v.y;
 840                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 841                                         }
 842                                 }
 843                                 else
 844                                 {
 845                                         LOG_INFO("bone not found");
 846                                 }
 847
 848                                 delete(tmp_entity);
 849                                 return;
 850                         }
 851                 }
 852
 853                 default:
 854                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 855                 case CMD_REQUEST_USAGE:
 856                 {
 857                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 858                         LOG_INFO("See also: ^2bbox, trace^7");
 859                         return;
 860                 }
 861         }
 862 }
 863
 864 void GameCommand_animbench(float request, float argc)
 865 {
 866         switch (request)
 867         {
 868                 case CMD_REQUEST_COMMAND:
 869                 {
 870                         entity tmp_entity;
 871
 872                         if (argc >= 4)
 873                         {
 874                                 tmp_entity = spawn();
 875                                 if (argv(1) == "w")
 876                                 {
 877                                         .entity weaponentity = weaponentities[0];
 878                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 879                                 }
 880                                 else
 881                                 {
 882                                         precache_model(argv(1));
 883                                         _setmodel(tmp_entity, argv(1));
 884                                 }
 885                                 float f1 = stof(argv(2));
 886                                 float f2 = stof(argv(3));
 887                                 float t0;
 888                                 float t1 = 0;
 889                                 float t2 = 0;
 890                                 float n = 0;
 891
 892                                 while (t1 + t2 < 1)
 893                                 {
 894                                         tmp_entity.frame = f1;
 895                                         t0 = gettime(GETTIME_HIRES);
 896                                         getsurfacepoint(tmp_entity, 0, 0);
 897                                         t1 += gettime(GETTIME_HIRES) - t0;
 898                                         tmp_entity.frame = f2;
 899                                         t0 = gettime(GETTIME_HIRES);
 900                                         getsurfacepoint(tmp_entity, 0, 0);
 901                                         t2 += gettime(GETTIME_HIRES) - t0;
 902                                         n += 1;
 903                                 }
 904                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 905                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 906
 907                                 delete(tmp_entity);
 908                                 return;
 909                         }
 910                 }
 911
 912                 default:
 913                         LOG_INFO("Incorrect parameters for ^2gettaginfo^7");
 914                 case CMD_REQUEST_USAGE:
 915                 {
 916                         LOG_INFO("Usage:^3 sv_cmd gettaginfo model frame index [command one] [command two]");
 917                         LOG_INFO("See also: ^2bbox, trace^7");
 918                         return;
 919                 }
 920         }
 921 }
 922
 923 void GameCommand_gotomap(float request, float argc)
 924 {
 925         switch (request)
 926         {
 927                 case CMD_REQUEST_COMMAND:
 928                 {
 929                         if (argv(1))
 930                         {
 931                                 LOG_INFO(GotoMap(argv(1)));
 932                                 return;
 933                         }
 934                 }
 935
 936                 default:
 937                         LOG_INFO("Incorrect parameters for ^2gotomap^7");
 938                 case CMD_REQUEST_USAGE:
 939                 {
 940                         LOG_INFO("Usage:^3 sv_cmd gotomap map");
 941                         LOG_INFO("  Where 'map' is the *.bsp file to change to.");
 942                         LOG_INFO("See also: ^2gametype^7");
 943                         return;
 944                 }
 945         }
 946 }
 947
 948 void GameCommand_lockteams(float request)
 949 {
 950         switch (request)
 951         {
 952                 case CMD_REQUEST_COMMAND:
 953                 {
 954                         if (teamplay)
 955                         {
 956                                 lockteams = 1;
 957                                 bprint("^1The teams are now locked.\n");
 958                         }
 959                         else
 960                         {
 961                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 962                         }
 963                         return;
 964                 }
 965
 966                 default:
 967                 case CMD_REQUEST_USAGE:
 968                 {
 969                         LOG_INFO("Usage:^3 sv_cmd lockteams");
 970                         LOG_INFO("  No arguments required.");
 971                         LOG_INFO("See also: ^2unlockteams^7");
 972                         return;
 973                 }
 974         }
 975 }
 976
 977 void GameCommand_make_mapinfo(float request)
 978 {
 979         switch (request)
 980         {
 981                 case CMD_REQUEST_COMMAND:
 982                 {
 983                         entity tmp_entity;
 984
 985                         tmp_entity = new(make_mapinfo);
 986                         setthink(tmp_entity, make_mapinfo_Think);
 987                         tmp_entity.nextthink = time;
 988                         MapInfo_Enumerate();
 989                         return;
 990                 }
 991
 992                 default:
 993                 case CMD_REQUEST_USAGE:
 994                 {
 995                         LOG_INFO("Usage:^3 sv_cmd make_mapinfo");
 996                         LOG_INFO("  No arguments required.");
 997                         LOG_INFO("See also: ^2radarmap^7");
 998                         return;
 999                 }
1000         }
1001 }
1002
1003 void GameCommand_moveplayer(float request, float argc)
1004 {
1005         switch (request)
1006         {
1007                 case CMD_REQUEST_COMMAND:
1008                 {
1009                         float accepted;
1010                         entity client;
1011
1012                         string targets = strreplace(",", " ", argv(1));
1013                         string original_targets = strreplace(" ", ", ", targets);
1014                         string destination = argv(2);
1015
1016                         string successful, t;
1017                         successful = string_null;
1018
1019                         // lets see if the target(s) even actually exist.
1020                         if ((targets) && (destination))
1021                         {
1022                                 for ( ; targets; )
1023                                 {
1024                                         t = car(targets);
1025                                         targets = cdr(targets);
1026
1027                                         // Check to see if the player is a valid target
1028                                         client = GetFilteredEntity(t);
1029                                         accepted = VerifyClientEntity(client, false, false);
1030
1031                                         if (accepted <= 0)
1032                                         {
1033                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
1034                                                 continue;
1035                                         }
1036
1037                                         // Where are we putting this player?
1038                                         if (destination == "spec" || destination == "spectator")
1039                                         {
1040                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1041                                                 {
1042                                                         if (client.caplayer) client.caplayer = 0;
1043                                                         PutObserverInServer(client);
1044
1045                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1046                                                 }
1047                                                 else
1048                                                 {
1049                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already spectating.");
1050                                                 }
1051                                                 continue;
1052                                         }
1053                                         else
1054                                         {
1055                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1056                                                 {
1057                                                         if (teamplay)
1058                                                         {
1059                                                                 // set up
1060                                                                 float team_id;
1061                                                                 float save = client.team_forced;
1062                                                                 client.team_forced = 0;
1063
1064                                                                 // find the team to move the player to
1065                                                                 team_id = Team_ColorToTeam(destination);
1066                                                                 if (team_id == client.team)  // already on the destination team
1067                                                                 {
1068                                                                         // keep the forcing undone
1069                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7."));
1070                                                                         continue;
1071                                                                 }
1072                                                                 else if (team_id == 0)  // auto team
1073                                                                 {
1074                                                                         CheckAllowedTeams(client);
1075                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, false));
1076                                                                 }
1077                                                                 else
1078                                                                 {
1079                                                                         CheckAllowedTeams(client);
1080                                                                 }
1081                                                                 client.team_forced = save;
1082
1083                                                                 // Check to see if the destination team is even available
1084                                                                 switch (team_id)
1085                                                                 {
1086                                                                         case NUM_TEAM_1: if (c1 == -1) { LOG_INFO("Sorry, can't move player to red team if it doesn't exist."); return; } break;
1087                                                                         case NUM_TEAM_2: if (c2 == -1) { LOG_INFO("Sorry, can't move player to blue team if it doesn't exist."); return; } break;
1088                                                                         case NUM_TEAM_3: if (c3 == -1) { LOG_INFO("Sorry, can't move player to yellow team if it doesn't exist."); return; } break;
1089                                                                         case NUM_TEAM_4: if (c4 == -1) { LOG_INFO("Sorry, can't move player to pink team if it doesn't exist."); return; } break;
1090
1091                                                                         default: LOG_INFO("Sorry, can't move player here if team ", destination, " doesn't exist.");
1092                                                                                 return;
1093                                                                 }
1094
1095                                                                 // If so, lets continue and finally move the player
1096                                                                 client.team_forced = 0;
1097                                                                 if (MoveToTeam(client, team_id, 6))
1098                                                                 {
1099                                                                         successful = strcat(successful, (successful ? ", " : ""), playername(client, false));
1100                                                                         LOG_INFO("Player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ") has been moved to the ", Team_ColoredFullName(team_id), "^7.");
1101                                                                 }
1102                                                                 else
1103                                                                 {
1104                                                                         LOG_INFO("Unable to move player ", ftos(GetFilteredNumber(t)), " (", playername(client, false), ")");
1105                                                                 }
1106                                                                 continue;
1107                                                         }
1108                                                         else
1109                                                         {
1110                                                                 LOG_INFO("Can't change teams when currently not playing a team game.");
1111                                                                 return;
1112                                                         }
1113                                                 }
1114                                                 else
1115                                                 {
1116                                                         LOG_INFO("Can't change teams if the player isn't in the game.");  // well technically we could, but should we allow that? :P
1117                                                         return;
1118                                                 }
1119                                         }
1120                                 }
1121
1122                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1123                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1124
1125                                 return;  // still correct parameters so return to avoid usage print
1126                         }
1127                 }
1128
1129                 default:
1130                         LOG_INFO("Incorrect parameters for ^2moveplayer^7");
1131                 case CMD_REQUEST_USAGE:
1132                 {
1133                         LOG_INFO("Usage:^3 sv_cmd moveplayer clients destination");
1134                         LOG_INFO("  'clients' is a list (separated by commas) of player entity ID's or nicknames");
1135                         LOG_INFO("  'destination' is what to send the player to, be it team or spectating");
1136                         LOG_INFO("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"");
1137                         LOG_INFO("Examples: sv_cmd moveplayer 1,3,5 red 3");
1138                         LOG_INFO("          sv_cmd moveplayer 2 spec ");
1139                         LOG_INFO("See also: ^2allspec, shuffleteams^7");
1140                         return;
1141                 }
1142         }
1143 }
1144
1145 void GameCommand_nospectators(float request)
1146 {
1147         switch (request)
1148         {
1149                 case CMD_REQUEST_COMMAND:
1150                 {
1151                         blockSpectators = 1;
1152                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1153                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !it.caplayer, {
1154                                 if(!it.caplayer)
1155                                 {
1156                                         CS(it).spectatortime = time;
1157                                         Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1158                                 }
1159                         });
1160                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1161                         return;
1162                 }
1163
1164                 default:
1165                 case CMD_REQUEST_USAGE:
1166                 {
1167                         LOG_INFO("Usage:^3 sv_cmd nospectators");
1168                         LOG_INFO("  No arguments required.");
1169                         return;
1170                 }
1171         }
1172 }
1173
1174 void GameCommand_printstats(float request)
1175 {
1176         switch (request)
1177         {
1178                 case CMD_REQUEST_COMMAND:
1179                 {
1180                         DumpStats(false);
1181                         LOG_INFO("stats dumped.");
1182                         return;
1183                 }
1184
1185                 default:
1186                 case CMD_REQUEST_USAGE:
1187                 {
1188                         LOG_INFO("Usage:^3 sv_cmd printstats");
1189                         LOG_INFO("  No arguments required.");
1190                         return;
1191                 }
1192         }
1193 }
1194
1195 void GameCommand_radarmap(float request, float argc)
1196 {
1197         switch (request)
1198         {
1199                 case CMD_REQUEST_COMMAND:
1200                 {
1201                         if (RadarMap_Make(argc)) return;
1202                 }
1203
1204                 default:
1205                         LOG_INFO("Incorrect parameters for ^2radarmap^7");
1206                 case CMD_REQUEST_USAGE:
1207                 {
1208                         LOG_INFO("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1209                         LOG_INFO("  The quality factor Q is roughly proportional to the time taken.");
1210                         LOG_INFO("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1211                         LOG_INFO("See also: ^2make_mapinfo^7");
1212                         return;
1213                 }
1214         }
1215 }
1216
1217 void GameCommand_reducematchtime(float request)
1218 {
1219         switch (request)
1220         {
1221                 case CMD_REQUEST_COMMAND:
1222                 {
1223                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1224                         return;
1225                 }
1226
1227                 default:
1228                 case CMD_REQUEST_USAGE:
1229                 {
1230                         LOG_INFO("Usage:^3 sv_cmd reducematchtime");
1231                         LOG_INFO("  No arguments required.");
1232                         LOG_INFO("See also: ^2extendmatchtime^7");
1233                         return;
1234                 }
1235         }
1236 }
1237
1238 void GameCommand_setbots(float request, float argc)
1239 {
1240         switch (request)
1241         {
1242                 case CMD_REQUEST_COMMAND:
1243                 {
1244                         if (argc >= 2)
1245                         {
1246                                 cvar_settemp("minplayers", "0");
1247                                 cvar_settemp("bot_number", argv(1));
1248                                 bot_fixcount();
1249                                 return;
1250                         }
1251                 }
1252
1253                 default:
1254                         LOG_INFO("Incorrect parameters for ^2setbots^7");
1255                 case CMD_REQUEST_USAGE:
1256                 {
1257                         LOG_INFO("Usage:^3 sv_cmd setbots botnumber");
1258                         LOG_INFO("  Where 'botnumber' is the amount of bots to set bot_number cvar to.");
1259                         LOG_INFO("See also: ^2bot_cmd^7");
1260                         return;
1261                 }
1262         }
1263 }
1264
1265 void GameCommand_shuffleteams(float request)
1266 {
1267         switch (request)
1268         {
1269                 case CMD_REQUEST_COMMAND:
1270                 {
1271                         if (!teamplay)
1272                         {
1273                                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1274                                 return;
1275                         }
1276
1277                         FOREACH_CLIENT(IS_PLAYER(it) || it.caplayer, {
1278                                 if (it.team_forced) {
1279                                         // we could theoretically assign forced players to their teams
1280                                         // and shuffle the rest to fill the empty spots but in practise
1281                                         // either all players or none are gonna have forced teams
1282                                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1283                                         return;
1284                                 }
1285                         });
1286
1287                         int number_of_teams = 0;
1288                         CheckAllowedTeams(NULL);
1289                         if (c1 >= 0) number_of_teams = max(1, number_of_teams);
1290                         if (c2 >= 0) number_of_teams = max(2, number_of_teams);
1291                         if (c3 >= 0) number_of_teams = max(3, number_of_teams);
1292                         if (c4 >= 0) number_of_teams = max(4, number_of_teams);
1293
1294                         int team_index = 0;
1295                         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || it.caplayer, {
1296                                 int target_team_number = Team_NumberToTeam(team_index + 1);
1297                                 if (it.team != target_team_number) MoveToTeam(it, target_team_number, 6);
1298                                 team_index = (team_index + 1) % number_of_teams;
1299                         });
1300
1301                         bprint("Successfully shuffled the players around randomly.\n");
1302                         return;
1303                 }
1304
1305                 default:
1306                 case CMD_REQUEST_USAGE:
1307                 {
1308                         LOG_INFO("Usage:^3 sv_cmd shuffleteams");
1309                         LOG_INFO("  No arguments required.");
1310                         LOG_INFO("See also: ^2moveplayer, allspec^7");
1311                         return;
1312                 }
1313         }
1314 }
1315
1316 void GameCommand_stuffto(float request, float argc)
1317 {
1318         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1319         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1320         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1321
1322 #ifdef STUFFTO_ENABLED
1323                 switch (request)
1324                 {
1325                         case CMD_REQUEST_COMMAND:
1326                         {
1327                                 if (argv(2))
1328                                 {
1329                                         entity client = GetIndexedEntity(argc, 1);
1330                                         float accepted = VerifyClientEntity(client, true, false);
1331
1332                                         if (accepted > 0)
1333                                         {
1334                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1335                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1336                                         }
1337                                         else
1338                                         {
1339                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1340                                         }
1341
1342                                         return;
1343                                 }
1344                         }
1345
1346                         default:
1347                                 LOG_INFO("Incorrect parameters for ^2stuffto^7");
1348                         case CMD_REQUEST_USAGE:
1349                         {
1350                                 LOG_INFO("Usage:^3 sv_cmd stuffto client \"command\"");
1351                                 LOG_INFO("  'client' is the entity number or name of the player,");
1352                                 LOG_INFO("  and 'command' is the command to be sent to that player.");
1353                                 return;
1354                         }
1355                 }
1356 #else
1357                 if (request)
1358                 {
1359                         LOG_INFO("stuffto command is not enabled on this server.");
1360                         return;
1361                 }
1362 #endif
1363 }
1364
1365 void GameCommand_trace(float request, float argc)
1366 {
1367         switch (request)
1368         {
1369                 case CMD_REQUEST_COMMAND:
1370                 {
1371                         entity e;
1372                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1373                         float i, f, safe, unsafe, dq, dqf;
1374
1375                         switch (argv(1))
1376                         {
1377                                 case "debug":
1378                                 {
1379                                         float hitcount = 0;
1380                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1381                                         float worst_endpos_bug = 0;
1382                                         for ( ; ; )
1383                                         {
1384                                                 org = world.mins;
1385                                                 delta = world.maxs - world.mins;
1386
1387                                                 start.x = org.x + random() * delta.x;
1388                                                 start.y = org.y + random() * delta.y;
1389                                                 start.z = org.z + random() * delta.z;
1390
1391                                                 end.x = org.x + random() * delta.x;
1392                                                 end.y = org.y + random() * delta.y;
1393                                                 end.z = org.z + random() * delta.z;
1394
1395                                                 start = stov(vtos(start));
1396                                                 end = stov(vtos(end));
1397
1398                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1399                                                 if (!trace_startsolid && trace_fraction < 1)
1400                                                 {
1401                                                         p = trace_endpos;
1402                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1403                                                         if (trace_startsolid)
1404                                                         {
1405                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1406                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1407
1408                                                                 // how much do we need to back off?
1409                                                                 safe = 1;
1410                                                                 unsafe = 0;
1411                                                                 for ( ; ; )
1412                                                                 {
1413                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1414                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1415                                                                         if (trace_startsolid)
1416                                                                         {
1417                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1418                                                                                 unsafe = (safe + unsafe) * 0.5;
1419                                                                         }
1420                                                                         else
1421                                                                         {
1422                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1423                                                                                 safe = (safe + unsafe) * 0.5;
1424                                                                         }
1425                                                                 }
1426
1427                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1428                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1429
1430                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1431                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1432                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1433                                                                 if (++hitcount >= 10) break;
1434                                                         }
1435                                                         else
1436                                                         {
1437                                                                 q0 = p;
1438                                                                 dq = 0;
1439                                                                 dqf = 1;
1440                                                                 for ( ; ; )
1441                                                                 {
1442                                                                         q = p + normalize(end - p) * (dq + dqf);
1443                                                                         if (q == q0) break;
1444                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1445                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1446                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1447                                                                         dqf *= 0.5;
1448                                                                         q0 = q;
1449                                                                 }
1450                                                                 if (dq > worst_endpos_bug)
1451                                                                 {
1452                                                                         worst_endpos_bug = dq;
1453                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1454                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1455                                                                         if (++hitcount >= 10) break;
1456                                                                 }
1457                                                         }
1458                                                 }
1459                                         }
1460                                         return;
1461                                 }
1462
1463                                 case "debug2":
1464                                 {
1465                                         e = nextent(NULL);
1466                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1467                                         vv = trace_endpos;
1468                                         if (trace_fraction == 1)
1469                                         {
1470                                                 LOG_INFO("not above ground, aborting");
1471                                                 return;
1472                                         }
1473                                         f = 0;
1474                                         for (i = 0; i < 100000; ++i)
1475                                         {
1476                                                 dv = randomvec();
1477                                                 if (dv.z > 0) dv = -1 * dv;
1478                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1479                                                 if (trace_startsolid) LOG_INFO("bug 1");
1480                                                 if (trace_fraction == 1)
1481                                                 {
1482                                                         if (dv.z < f)
1483                                                         {
1484                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1485                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1486                                                                 f = dv.z;
1487                                                         }
1488                                                 }
1489                                         }
1490                                         LOG_INFO("highest possible dist: ", ftos(f));
1491                                         return;
1492                                 }
1493
1494                                 case "walk":
1495                                 {
1496                                         if (argc == 4 || argc == 5)
1497                                         {
1498                                                 e = nextent(NULL);
1499                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1500                                                         LOG_INFO("can walk");
1501                                                 else
1502                                                         LOG_INFO("cannot walk");
1503                                                 return;
1504                                         }
1505                                 }
1506
1507                                 case "showline":
1508                                 {
1509                                         if (argc == 4)
1510                                         {
1511                                                 vv = stov(argv(2));
1512                                                 dv = stov(argv(3));
1513                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1514                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1515                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1516                                                 return;
1517                                         }
1518                                 }
1519
1520                                         // no default case, just go straight to invalid
1521                         }
1522                 }
1523
1524                 default:
1525                         LOG_INFO("Incorrect parameters for ^2trace^7");
1526                 case CMD_REQUEST_USAGE:
1527                 {
1528                         LOG_INFO("Usage:^3 sv_cmd trace command [startpos endpos] [endpos_height]");
1529                         LOG_INFO("  Where startpos and endpos are parameters for 'walk' and 'showline' commands,");
1530                         LOG_INFO("  'endpos_height' is an optional parameter for 'walk' command,");
1531                         LOG_INFO("  Full list of commands here: \"debug, debug2, walk, showline.\"");
1532                         LOG_INFO("See also: ^2bbox, gettaginfo^7");
1533                         return;
1534                 }
1535         }
1536 }
1537
1538 void GameCommand_unlockteams(float request)
1539 {
1540         switch (request)
1541         {
1542                 case CMD_REQUEST_COMMAND:
1543                 {
1544                         if (teamplay)
1545                         {
1546                                 lockteams = 0;
1547                                 bprint("^1The teams are now unlocked.\n");
1548                         }
1549                         else
1550                         {
1551                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1552                         }
1553                         return;
1554                 }
1555
1556                 default:
1557                 case CMD_REQUEST_USAGE:
1558                 {
1559                         LOG_INFO("Usage:^3 sv_cmd unlockteams");
1560                         LOG_INFO("  No arguments required.");
1561                         LOG_INFO("See also: ^2lockteams^7");
1562                         return;
1563                 }
1564         }
1565 }
1566
1567 void GameCommand_warp(float request, float argc)
1568 {
1569         switch (request)
1570         {
1571                 case CMD_REQUEST_COMMAND:
1572                 {
1573                         if (autocvar_g_campaign)
1574                         {
1575                                 if (argc >= 2)
1576                                 {
1577                                         CampaignLevelWarp(stof(argv(1)));
1578                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1579                                 }
1580                                 else
1581                                 {
1582                                         CampaignLevelWarp(-1);
1583                                         LOG_INFO("Successfully warped to next campaign level.");
1584                                 }
1585                         }
1586                         else
1587                         {
1588                                 LOG_INFO("Not in campaign, can't level warp");
1589                         }
1590                         return;
1591                 }
1592
1593                 default:
1594                 case CMD_REQUEST_USAGE:
1595                 {
1596                         LOG_INFO("Usage:^3 sv_cmd warp [level]");
1597                         LOG_INFO("  'level' is the level to change campaign mode to.");
1598                         LOG_INFO("  if 'level' is not provided it will change to the next level.");
1599                         return;
1600                 }
1601         }
1602 }
1603
1604 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1605 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1606 void GameCommand_(float request)
1607 {
1608     switch(request)
1609     {
1610         case CMD_REQUEST_COMMAND:
1611         {
1612
1613             return;
1614         }
1615
1616         default:
1617         case CMD_REQUEST_USAGE:
1618         {
1619             print("\nUsage:^3 sv_cmd \n");
1620             print("  No arguments required.\n");
1621             return;
1622         }
1623     }
1624 }
1625 */
1626
1627
1628 // ==================================
1629 //  Macro system for server commands
1630 // ==================================
1631
1632 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1633 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1634 SERVER_COMMAND(allready, "Restart the server and reset the players") { GameCommand_allready(request); }
1635 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1636 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1637 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1638 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1639 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1640 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1641 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1642 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1643 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1644 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1645 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1646 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1647 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1648 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1649 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1650 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1651 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1652 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1653 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1654 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1655 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1656 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1657 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1658 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1659 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1660 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1661 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1662 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1663
1664 void GameCommand_macro_help()
1665 {
1666         FOREACH(SERVER_COMMANDS, true, { LOG_INFOF("  ^2%s^7: %s", it.m_name, it.m_description); });
1667 }
1668
1669 float GameCommand_macro_command(float argc, string command)
1670 {
1671         string c = strtolower(argv(0));
1672         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1673                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1674                 return true;
1675         });
1676         return false;
1677 }
1678
1679 float GameCommand_macro_usage(float argc)
1680 {
1681         string c = strtolower(argv(1));
1682         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1683                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1684                 return true;
1685         });
1686         return false;
1687 }
1688
1689 void GameCommand_macro_write_aliases(float fh)
1690 {
1691         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1692 }
1693
1694
1695 // =========================================
1696 //  Main Function Called By Engine (sv_cmd)
1697 // =========================================
1698 // If this function exists, game code handles gamecommand instead of the engine code.
1699
1700 void GameCommand(string command)
1701 {
1702         float argc = tokenize_console(command);
1703
1704         // Guide for working with argc arguments by example:
1705         // argc:   1    - 2      - 3     - 4
1706         // argv:   0    - 1      - 2     - 3
1707         // cmd     vote - master - login - password
1708
1709         if (strtolower(argv(0)) == "help")
1710         {
1711                 if (argc == 1)
1712                 {
1713                         LOG_INFO("Server console commands:");
1714                         GameCommand_macro_help();
1715
1716                         LOG_INFO("\nBanning commands:");
1717                         BanCommand_macro_help();
1718
1719                         LOG_INFO("\nCommon networked commands:");
1720                         CommonCommand_macro_help(NULL);
1721
1722                         LOG_INFO("\nGeneric commands shared by all programs:");
1723                         GenericCommand_macro_help();
1724
1725                         LOG_INFO(
1726                             "\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n"
1727                 "For help about a specific command, type sv_cmd help COMMAND"
1728             );
1729
1730                         return;
1731                 }
1732                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1733                 {
1734                         return;
1735                 }
1736                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1737                 {
1738                         return;
1739                 }
1740                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1741                 {
1742                         return;
1743                 }
1744                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1745                 {
1746                         return;
1747                 }
1748         }
1749         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1750         {
1751                 return;  // handled by a mutator
1752         }
1753         else if (BanCommand(command))
1754         {
1755                 return;  // handled by server/command/ipban.qc
1756         }
1757         else if (CommonCommand_macro_command(argc, NULL, command))
1758         {
1759                 return;  // handled by server/command/common.qc
1760         }
1761         else if (GenericCommand(command))
1762         {
1763                 return;                                        // handled by common/command/generic.qc
1764         }
1765         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1766         {
1767                 return;                                        // handled by one of the above GameCommand_* functions
1768         }
1769
1770         // nothing above caught the command, must be invalid
1771         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1772 }