qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if(accepted <= 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_mobbutcher(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         if(autocvar_g_campaign) { print("This command doesn't work in campaign mode.\n"); return; }
 149                         if(g_invasion) { print("This command doesn't work during an invasion.\n"); return; }
 150
 151                         float removed_count = 0;
 152                         entity head;
 153
 154                         FOR_EACH_MONSTER(head)
 155                         {
 156                                 monster_remove(head);
 157                                 ++removed_count;
 158                         }
 159
 160                         monsters_total = 0; // reset stats?
 161                         monsters_killed = 0;
 162
 163                         totalspawned = 0;
 164
 165                         if(removed_count <= 0)
 166                                 print("No monsters to kill\n");
 167                         else
 168                                 printf("Killed %d monster%s\n", removed_count, ((removed_count == 1) ? "" : "s"));
 169
 170                         return; // never fall through to usage
 171                 }
 172
 173                 default:
 174                 case CMD_REQUEST_USAGE:
 175                 {
 176                         print("\nUsage:^3 sv_cmd mobbutcher\n");
 177                         print("  No arguments required.\n");
 178                         return;
 179                 }
 180         }
 181 }
 182
 183 void GameCommand_allready(float request)
 184 {
 185         switch(request)
 186         {
 187                 case CMD_REQUEST_COMMAND:
 188                 {
 189                         ReadyRestart();
 190                         return;
 191                 }
 192
 193                 default:
 194                 case CMD_REQUEST_USAGE:
 195                 {
 196                         print("\nUsage:^3 sv_cmd allready\n");
 197                         print("  No arguments required.\n");
 198                         return;
 199                 }
 200         }
 201 }
 202
 203 void GameCommand_allspec(float request, float argc)
 204 {
 205         switch(request)
 206         {
 207                 case CMD_REQUEST_COMMAND:
 208                 {
 209                         entity client;
 210                         string reason = argv(1);
 211                         float i = 0;
 212
 213                         FOR_EACH_REALPLAYER(client)
 214                         {
 215                                 self = client;
 216                                 if(self.caplayer)
 217                                         self.caplayer = 0;
 218                                 PutObserverInServer();
 219                                 ++i;
 220                         }
 221                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 222                         else { print("No players found to spectate.\n"); }
 223                         return;
 224                 }
 225
 226                 default:
 227                 case CMD_REQUEST_USAGE:
 228                 {
 229                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 230                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 231                         print("See also: ^2moveplayer, shuffleteams^7\n");
 232                         return;
 233                 }
 234         }
 235 }
 236
 237 void GameCommand_anticheat(float request, float argc)
 238 {
 239         switch(request)
 240         {
 241                 case CMD_REQUEST_COMMAND:
 242                 {
 243                         entity client = GetIndexedEntity(argc, 1);
 244                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 245
 246                         if(accepted > 0)
 247                         {
 248                                 self = client;
 249                                 anticheat_report();
 250                                 return;
 251                         }
 252                         else
 253                         {
 254                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 255                         }
 256                 }
 257
 258                 default:
 259                         print("Incorrect parameters for ^2anticheat^7\n");
 260                 case CMD_REQUEST_USAGE:
 261                 {
 262                         print("\nUsage:^3 sv_cmd anticheat client\n");
 263                         print("  'client' is the entity number or name of the player.\n");
 264                         return;
 265                 }
 266         }
 267 }
 268
 269 void GameCommand_bbox(float request)
 270 {
 271         switch(request)
 272         {
 273                 case CMD_REQUEST_COMMAND:
 274                 {
 275                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 276                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 277                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 278                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 279                         print("Solid bounding box size:");
 280
 281                         tracebox('1 0 0' * world.absmin_x,
 282                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 283                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 284                                                         '1 0 0' * world.absmax_x,
 285                                         MOVE_WORLDONLY,
 286                                         world);
 287                         if(trace_startsolid)
 288                                 print(" ", ftos(world.absmin_x));
 289                         else
 290                                 print(" ", ftos(trace_endpos_x));
 291
 292                         tracebox('0 1 0' * world.absmin_y,
 293                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 294                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 295                                                         '0 1 0' * world.absmax_y,
 296                                         MOVE_WORLDONLY,
 297                                         world);
 298                         if(trace_startsolid)
 299                                 print(" ", ftos(world.absmin_y));
 300                         else
 301                                 print(" ", ftos(trace_endpos_y));
 302
 303                         tracebox('0 0 1' * world.absmin_z,
 304                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 305                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 306                                                         '0 0 1' * world.absmax_z,
 307                                         MOVE_WORLDONLY,
 308                                         world);
 309                         if(trace_startsolid)
 310                                 print(" ", ftos(world.absmin_z));
 311                         else
 312                                 print(" ", ftos(trace_endpos_z));
 313
 314                         tracebox('1 0 0' * world.absmax_x,
 315                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 316                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 317                                                         '1 0 0' * world.absmin_x,
 318                                         MOVE_WORLDONLY,
 319                                         world);
 320                         if(trace_startsolid)
 321                                 print(" ", ftos(world.absmax_x));
 322                         else
 323                                 print(" ", ftos(trace_endpos_x));
 324
 325                         tracebox('0 1 0' * world.absmax_y,
 326                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 327                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 328                                                         '0 1 0' * world.absmin_y,
 329                                         MOVE_WORLDONLY,
 330                                         world);
 331                         if(trace_startsolid)
 332                                 print(" ", ftos(world.absmax_y));
 333                         else
 334                                 print(" ", ftos(trace_endpos_y));
 335
 336                         tracebox('0 0 1' * world.absmax_z,
 337                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 338                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 339                                                         '0 0 1' * world.absmin_z,
 340                                         MOVE_WORLDONLY,
 341                                         world);
 342                         if(trace_startsolid)
 343                                 print(" ", ftos(world.absmax_z));
 344                         else
 345                                 print(" ", ftos(trace_endpos_z));
 346
 347                         print("\n");
 348                         return;
 349                 }
 350
 351                 default:
 352                 case CMD_REQUEST_USAGE:
 353                 {
 354                         print("\nUsage:^3 sv_cmd bbox\n");
 355                         print("  No arguments required.\n");
 356                         print("See also: ^2gettaginfo, trace^7\n");
 357                         return;
 358                 }
 359         }
 360 }
 361
 362 void GameCommand_bot_cmd(float request, float argc, string command)
 363 {
 364         switch(request)
 365         {
 366                 case CMD_REQUEST_COMMAND:
 367                 {
 368                         entity bot;
 369
 370                         if(argv(1) == "reset")
 371                         {
 372                                 bot_resetqueues();
 373                                 return;
 374                         }
 375                         else if(argv(1) == "setbots")
 376                         {
 377                                 cvar_settemp("bot_vs_human", "0");
 378                                 cvar_settemp("minplayers", "0");
 379                                 cvar_settemp("bot_number", "0");
 380                                 bot_fixcount();
 381                                 cvar_settemp("bot_number", argv(2));
 382                                 if(!bot_fixcount())
 383                                         print("Sorry, could not set requested bot count\n");
 384                                 return;
 385                         }
 386                         else if(argv(1) == "load" && argc == 3)
 387                         {
 388                                 float fh, i;
 389                                 string s;
 390                                 fh = fopen(argv(2), FILE_READ);
 391                                 if(fh < 0)
 392                                 {
 393                                         print("cannot open the file\n");
 394                                         return;
 395                                 }
 396
 397                                 i = 0;
 398                                 while((s = fgets(fh)))
 399                                 {
 400                                         argc = tokenize_console(s);
 401
 402                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 403                                         {
 404                                                 if(argv(2) == "reset")
 405                                                 {
 406                                                         bot_resetqueues();
 407                                                 }
 408                                                 else if(argv(2) == "setbots")
 409                                                 {
 410                                                         cvar_settemp("bot_vs_human", "0");
 411                                                         cvar_settemp("minplayers", "0");
 412                                                         cvar_settemp("bot_number", "0");
 413                                                         bot_fixcount();
 414                                                         cvar_settemp("bot_number", argv(3));
 415                                                         if(!bot_fixcount())
 416                                                                 print("Sorry, could not set requested bot count\n");
 417                                                 }
 418                                                 else
 419                                                 {
 420                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 421                                                         bot = find_bot_by_number(stof(argv(2)));
 422                                                         if(bot == world)
 423                                                                 bot = find_bot_by_name(argv(2));
 424                                                         if(bot)
 425                                                                 bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 426                                                 }
 427                                         }
 428                                         else
 429                                                 localcmd(strcat(s, "\n"));
 430
 431                                         ++i;
 432                                 }
 433                                 print(ftos(i), " commands read\n");
 434                                 fclose(fh);
 435                                 return;
 436                         }
 437                         else if(argv(1) == "help")
 438                         {
 439                                 if(argv(2))
 440                                         bot_cmdhelp(argv(2));
 441                                 else
 442                                         bot_list_commands();
 443                                 return;
 444                         }
 445                         else if(argc >= 3) // this comes last
 446                         {
 447                                 bot = find_bot_by_number(stof(argv(1)));
 448                                 if(bot == world)
 449                                         bot = find_bot_by_name(argv(1));
 450                                 if(bot)
 451                                 {
 452                                         print(strcat("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname, "\n"));
 453                                         bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 454                                         return;
 455                                 }
 456                                 else
 457                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 458                         }
 459                 }
 460
 461                 default:
 462                         print("Incorrect parameters for ^2bot_cmd^7\n");
 463                 case CMD_REQUEST_USAGE:
 464                 {
 465                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 466                         print("  'client' can be either the name or entity id of the bot\n");
 467                         print("  For full list of commands, see bot_cmd help [command].\n");
 468                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 469                         print("          sv_cmd bot_cmd client presskey jump\n");
 470                         return;
 471                 }
 472         }
 473 }
 474
 475 void GameCommand_cointoss(float request, float argc)
 476 {
 477         switch(request)
 478         {
 479                 case CMD_REQUEST_COMMAND:
 480                 {
 481                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 482                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 483                         string choice = ((random() > 0.5) ? result1 : result2);
 484
 485                         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_COINTOSS, choice);
 486                         return;
 487                 }
 488
 489                 default:
 490                 case CMD_REQUEST_USAGE:
 491                 {
 492                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 493                         print("  Where 'result1' and 'result2' are user created options.\n");
 494                         return;
 495                 }
 496         }
 497 }
 498
 499 void GameCommand_database(float request, float argc)
 500 {
 501         switch(request)
 502         {
 503                 case CMD_REQUEST_COMMAND:
 504                 {
 505                         if(argc == 3)
 506                         {
 507                                 if(argv(1) == "save")
 508                                 {
 509                                         db_save(ServerProgsDB, argv(2));
 510                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 511                                         return;
 512                                 }
 513                                 else if(argv(1) == "dump")
 514                                 {
 515                                         db_dump(ServerProgsDB, argv(2));
 516                                         print("DB dumped.\n"); // wtf does this do?
 517                                         return;
 518                                 }
 519                                 else if(argv(1) == "load")
 520                                 {
 521                                         db_close(ServerProgsDB);
 522                                         ServerProgsDB = db_load(argv(2));
 523                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 524                                         return;
 525                                 }
 526                         }
 527                 }
 528
 529                 default:
 530                         print("Incorrect parameters for ^2database^7\n");
 531                 case CMD_REQUEST_USAGE:
 532                 {
 533                         print("\nUsage:^3 sv_cmd database action filename\n");
 534                         print("  Where 'action' is the command to complete,\n");
 535                         print("  and 'filename' is what it acts upon.\n");
 536                         print("  Full list of commands here: \"save, dump, load.\"\n");
 537                         return;
 538                 }
 539         }
 540 }
 541
 542 void GameCommand_defer_clear(float request, float argc)
 543 {
 544         switch(request)
 545         {
 546                 case CMD_REQUEST_COMMAND:
 547                 {
 548                         entity client;
 549                         float accepted;
 550
 551                         if(argc >= 2)
 552                         {
 553                                 client = GetIndexedEntity(argc, 1);
 554                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 555
 556                                 if(accepted > 0)
 557                                 {
 558                                         stuffcmd(client, "defer clear\n");
 559                                         print("defer clear stuffed to ", client.netname, "\n");
 560                                 }
 561                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 562
 563                                 return;
 564                         }
 565                 }
 566
 567                 default:
 568                         print("Incorrect parameters for ^2defer_clear^7\n");
 569                 case CMD_REQUEST_USAGE:
 570                 {
 571                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 572                         print("  'client' is the entity number or name of the player.\n");
 573                         print("See also: ^2defer_clear_all^7\n");
 574                         return;
 575                 }
 576         }
 577 }
 578
 579 void GameCommand_defer_clear_all(float request)
 580 {
 581         switch(request)
 582         {
 583                 case CMD_REQUEST_COMMAND:
 584                 {
 585                         entity client;
 586                         float i = 0;
 587                         float argc;
 588
 589                         FOR_EACH_CLIENT(client)
 590                         {
 591                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 592                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 593                                 ++i;
 594                         }
 595                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 596                         return;
 597                 }
 598
 599                 default:
 600                 case CMD_REQUEST_USAGE:
 601                 {
 602                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 603                         print("  No arguments required.\n");
 604                         print("See also: ^2defer_clear^7\n");
 605                         return;
 606                 }
 607         }
 608 }
 609
 610 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 611 {
 612         switch(request)
 613         {
 614                 case CMD_REQUEST_COMMAND:
 615                 {
 616                         if(argv(1))
 617                         {
 618                                 if(argv(2))
 619                                         race_deleteTime(argv(2), stof(argv(1)));
 620                                 else
 621                                         race_deleteTime(GetMapname(), stof(argv(1)));
 622                                 return;
 623                         }
 624                 }
 625
 626                 default:
 627                         print("Incorrect parameters for ^2delrec^7\n");
 628                 case CMD_REQUEST_USAGE:
 629                 {
 630                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 631                         print("  'ranking' is which ranking level to clear up to, \n");
 632                         print("  it will clear all records up to nth place.\n");
 633                         print("  if 'map' is not provided it will use current map.\n");
 634                         return;
 635                 }
 636         }
 637 }
 638
 639 void GameCommand_effectindexdump(float request)
 640 {
 641         switch(request)
 642         {
 643                 case CMD_REQUEST_COMMAND:
 644                 {
 645                         float fh, d;
 646                         string s;
 647
 648                         d = db_create();
 649                         print("begin of effects list\n");
 650                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 651                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 652                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 653                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 654                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 655                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 656                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 657                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 658                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 659                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 660                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 661                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 662                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 663                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 664                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 665                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 666                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 667                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 668                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 669                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 670                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 671                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 672                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 673                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 674                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 675                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 676                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 677                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 678                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 679                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 680                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 681                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 682                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 683                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 684                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 685                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 686
 687                         fh = fopen("effectinfo.txt", FILE_READ);
 688                         while((s = fgets(fh)))
 689                         {
 690                                 tokenize_console(s);
 691                                 if(argv(0) == "effect")
 692                                 {
 693                                         if(db_get(d, argv(1)) != "1")
 694                                         {
 695                                                 if(particleeffectnum(argv(1)) >= 0)
 696                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 697                                                 db_put(d, argv(1), "1");
 698                                         }
 699                                 }
 700                         }
 701                         print("end of effects list\n");
 702
 703                         db_close(d);
 704                         return;
 705                 }
 706
 707                 default:
 708                 case CMD_REQUEST_USAGE:
 709                 {
 710                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 711                         print("  No arguments required.\n");
 712                         return;
 713                 }
 714         }
 715 }
 716
 717 void GameCommand_extendmatchtime(float request)
 718 {
 719         switch(request)
 720         {
 721                 case CMD_REQUEST_COMMAND:
 722                 {
 723                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 724                         return;
 725                 }
 726
 727                 default:
 728                 case CMD_REQUEST_USAGE:
 729                 {
 730                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 731                         print("  No arguments required.\n");
 732                         print("See also: ^2reducematchtime^7\n");
 733                         return;
 734                 }
 735         }
 736 }
 737
 738 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 739 {
 740         switch(request)
 741         {
 742                 case CMD_REQUEST_COMMAND:
 743                 {
 744                         entity client;
 745
 746                         for(client = world; (client = find(client, classname, argv(1))); )
 747                                 print(etos(client), "\n");
 748
 749                         return;
 750                 }
 751
 752                 default:
 753                         print("Incorrect parameters for ^2find^7\n");
 754                 case CMD_REQUEST_USAGE:
 755                 {
 756                         print("\nUsage:^3 sv_cmd find classname\n");
 757                         print("  Where 'classname' is the classname to search for.\n");
 758                         return;
 759                 }
 760         }
 761 }
 762
 763 void GameCommand_gametype(float request, float argc)
 764 {
 765         switch(request)
 766         {
 767                 case CMD_REQUEST_COMMAND:
 768                 {
 769                         if(argv(1) != "")
 770                         {
 771                                 string s = argv(1);
 772                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 773
 774                                 if(t)
 775                                 {
 776                                         MapInfo_SwitchGameType(t);
 777                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 778                                         if(MapInfo_count > 0)
 779                                         {
 780                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 781                                                 if(lsmaps_reply != "") { strunzone(lsmaps_reply); }
 782                                                 lsmaps_reply = strzone(getlsmaps());
 783                                                 bprint("Game type successfully switched to ", s, "\n");
 784                                         }
 785                                         else
 786                                         {
 787                                                 bprint("Cannot use this game type: no map for it found\n");
 788                                                 MapInfo_SwitchGameType(tsave);
 789                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 790                                         }
 791                                 }
 792                                 else
 793                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 794
 795                                 return;
 796                         }
 797                 }
 798
 799                 default:
 800                         print("Incorrect parameters for ^2gametype^7\n");
 801                 case CMD_REQUEST_USAGE:
 802                 {
 803                         print("\nUsage:^3 sv_cmd gametype mode\n");
 804                         print("  Where 'mode' is the gametype mode to switch to.\n");
 805                         print("See also: ^2gotomap^7\n");
 806                         return;
 807                 }
 808         }
 809 }
 810
 811 void GameCommand_gettaginfo(float request, float argc)
 812 {
 813         switch(request)
 814         {
 815                 case CMD_REQUEST_COMMAND:
 816                 {
 817                         entity tmp_entity;
 818                         float i;
 819                         vector v;
 820
 821                         if(argc >= 4)
 822                         {
 823                                 tmp_entity = spawn();
 824                                 if(argv(1) == "w")
 825                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 826                                 else
 827                                 {
 828                                         precache_model(argv(1));
 829                                         setmodel(tmp_entity, argv(1));
 830                                 }
 831                                 tmp_entity.frame = stof(argv(2));
 832                                 if(substring(argv(3), 0, 1) == "#")
 833                                         i = stof(substring(argv(3), 1, -1));
 834                                 else
 835                                         i = gettagindex(tmp_entity, argv(3));
 836                                 if(i)
 837                                 {
 838                                         v = gettaginfo(tmp_entity, i);
 839                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 840                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 841                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 842                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 843                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 844                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 845                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 846                                         if(argc >= 6)
 847                                         {
 848                                                 v_y = -v_y;
 849                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 850                                         }
 851                                 }
 852                                 else
 853                                         print("bone not found\n");
 854
 855                                 remove(tmp_entity);
 856                                 return;
 857                         }
 858                 }
 859
 860                 default:
 861                         print("Incorrect parameters for ^2gettaginfo^7\n");
 862                 case CMD_REQUEST_USAGE:
 863                 {
 864                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 865                         print("See also: ^2bbox, trace^7\n");
 866                         return;
 867                 }
 868         }
 869 }
 870
 871 void GameCommand_animbench(float request, float argc)
 872 {
 873         switch(request)
 874         {
 875                 case CMD_REQUEST_COMMAND:
 876                 {
 877                         entity tmp_entity;
 878
 879                         if(argc >= 4)
 880                         {
 881                                 tmp_entity = spawn();
 882                                 if(argv(1) == "w")
 883                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 884                                 else
 885                                 {
 886                                         precache_model(argv(1));
 887                                         setmodel(tmp_entity, argv(1));
 888                                 }
 889                                 float f1 = stof(argv(2));
 890                                 float f2 = stof(argv(3));
 891                                 float t0;
 892                                 float t1 = 0;
 893                                 float t2 = 0;
 894                                 float n = 0;
 895
 896                                 while(t1 + t2 < 1)
 897                                 {
 898                                         tmp_entity.frame = f1;
 899                                         t0 = gettime(GETTIME_HIRES);
 900                                         getsurfacepoint(tmp_entity, 0, 0);
 901                                         t1 += gettime(GETTIME_HIRES) - t0;
 902                                         tmp_entity.frame = f2;
 903                                         t0 = gettime(GETTIME_HIRES);
 904                                         getsurfacepoint(tmp_entity, 0, 0);
 905                                         t2 += gettime(GETTIME_HIRES) - t0;
 906                                         n += 1;
 907                                 }
 908                                 print("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s\n");
 909                                 print("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s\n");
 910
 911                                 remove(tmp_entity);
 912                                 return;
 913                         }
 914                 }
 915
 916                 default:
 917                         print("Incorrect parameters for ^2gettaginfo^7\n");
 918                 case CMD_REQUEST_USAGE:
 919                 {
 920                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 921                         print("See also: ^2bbox, trace^7\n");
 922                         return;
 923                 }
 924         }
 925 }
 926
 927 void GameCommand_gotomap(float request, float argc)
 928 {
 929         switch(request)
 930         {
 931                 case CMD_REQUEST_COMMAND:
 932                 {
 933                         if(argv(1))
 934                         {
 935                                 print(GotoMap(argv(1)), "\n");
 936                                 return;
 937                         }
 938                 }
 939
 940                 default:
 941                         print("Incorrect parameters for ^2gotomap^7\n");
 942                 case CMD_REQUEST_USAGE:
 943                 {
 944                         print("\nUsage:^3 sv_cmd gotomap map\n");
 945                         print("  Where 'map' is the *.bsp file to change to.\n");
 946                         print("See also: ^2gametype^7\n");
 947                         return;
 948                 }
 949         }
 950 }
 951
 952 void GameCommand_lockteams(float request)
 953 {
 954         switch(request)
 955         {
 956                 case CMD_REQUEST_COMMAND:
 957                 {
 958                         if(teamplay)
 959                         {
 960                                 lockteams = 1;
 961                                 bprint("^1The teams are now locked.\n");
 962                         }
 963                         else
 964                         {
 965                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 966                         }
 967                         return;
 968                 }
 969
 970                 default:
 971                 case CMD_REQUEST_USAGE:
 972                 {
 973                         print("\nUsage:^3 sv_cmd lockteams\n");
 974                         print("  No arguments required.\n");
 975                         print("See also: ^2unlockteams^7\n");
 976                         return;
 977                 }
 978         }
 979 }
 980
 981 void GameCommand_make_mapinfo(float request)
 982 {
 983         switch(request)
 984         {
 985                 case CMD_REQUEST_COMMAND:
 986                 {
 987                         entity tmp_entity;
 988
 989                         tmp_entity = spawn();
 990                         tmp_entity.classname = "make_mapinfo";
 991                         tmp_entity.think = make_mapinfo_Think;
 992                         tmp_entity.nextthink = time;
 993                         MapInfo_Enumerate();
 994                         return;
 995                 }
 996
 997                 default:
 998                 case CMD_REQUEST_USAGE:
 999                 {
1000                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
1001                         print("  No arguments required.\n");
1002                         print("See also: ^2radarmap^7\n");
1003                         return;
1004                 }
1005         }
1006 }
1007
1008 void GameCommand_moveplayer(float request, float argc)
1009 {
1010         switch(request)
1011         {
1012                 case CMD_REQUEST_COMMAND:
1013                 {
1014                         float accepted;
1015                         entity client;
1016
1017                         string targets = strreplace(",", " ", argv(1));
1018                         string original_targets = strreplace(" ", ", ", targets);
1019                         string destination = argv(2);
1020
1021                         string successful, t;
1022                         successful = string_null;
1023
1024                         // lets see if the target(s) even actually exist.
1025                         if((targets) && (destination))
1026                         {
1027                                 for(;targets;)
1028                                 {
1029                                         t = car(targets); targets = cdr(targets);
1030
1031                                         // Check to see if the player is a valid target
1032                                         client = GetFilteredEntity(t);
1033                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
1034
1035                                         if(accepted <= 0)
1036                                         {
1037                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
1038                                                 continue;
1039                                         }
1040
1041                                         // Where are we putting this player?
1042                                         if(destination == "spec" || destination == "spectator")
1043                                         {
1044                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1045                                                 {
1046                                                         self = client;
1047                                                         if(self.caplayer)
1048                                                                 self.caplayer = 0;
1049                                                         PutObserverInServer();
1050
1051                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
1052                                                 }
1053                                                 else
1054                                                 {
1055                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
1056                                                 }
1057                                                 continue;
1058                                         }
1059                                         else
1060                                         {
1061                                                 if(!IS_SPEC(client) && !IS_OBSERVER(client))
1062                                                 {
1063                                                         if(teamplay)
1064                                                         {
1065                                                                 // set up
1066                                                                 float team_id;
1067                                                                 float save = client.team_forced;
1068                                                                 client.team_forced = 0;
1069
1070                                                                 // find the team to move the player to
1071                                                                 team_id = Team_ColorToTeam(destination);
1072                                                                 if(team_id == client.team) // already on the destination team
1073                                                                 {
1074                                                                         // keep the forcing undone
1075                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", Team_ColoredFullName(client.team), (targets ? "^7, skipping to next player.\n" : "^7.\n"));
1076                                                                         continue;
1077                                                                 }
1078                                                                 else if(team_id == 0)  // auto team
1079                                                                 {
1080                                                                         CheckAllowedTeams(client);
1081                                                                         team_id = Team_NumberToTeam(FindSmallestTeam(client, FALSE));
1082                                                                 }
1083                                                                 else
1084                                                                 {
1085                                                                         CheckAllowedTeams(client);
1086                                                                 }
1087                                                                 client.team_forced = save;
1088
1089                                                                 // Check to see if the destination team is even available
1090                                                                 switch(team_id)
1091                                                                 {
1092                                                                         case NUM_TEAM_1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
1093                                                                         case NUM_TEAM_2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
1094                                                                         case NUM_TEAM_3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
1095                                                                         case NUM_TEAM_4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
1096
1097                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
1098                                                                 }
1099
1100                                                                 // If so, lets continue and finally move the player
1101                                                                 client.team_forced = 0;
1102                                                                 MoveToTeam(client, team_id, 6);
1103                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
1104                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", Team_ColoredFullName(team_id), "^7.\n");
1105                                                                 continue;
1106                                                         }
1107                                                         else
1108                                                         {
1109                                                                 print("Can't change teams when currently not playing a team game.\n");
1110                                                                 return;
1111                                                         }
1112                                                 }
1113                                                 else
1114                                                 {
1115                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
1116                                                         return;
1117                                                 }
1118                                         }
1119                                 }
1120
1121                                 if(successful)
1122                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1123                                 else
1124                                         print("No players given (", original_targets, ") are able to move.\n");
1125
1126                                 return; // still correct parameters so return to avoid usage print
1127                         }
1128                 }
1129
1130                 default:
1131                         print("Incorrect parameters for ^2moveplayer^7\n");
1132                 case CMD_REQUEST_USAGE:
1133                 {
1134                         print("\nUsage:^3 sv_cmd moveplayer clients destination\n");
1135                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1136                         print("  'destination' is what to send the player to, be it team or spectating\n");
1137                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1138                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1139                         print("          sv_cmd moveplayer 2 spec \n");
1140                         print("See also: ^2allspec, shuffleteams^7\n");
1141                         return;
1142                 }
1143         }
1144 }
1145
1146 void GameCommand_nospectators(float request)
1147 {
1148         switch(request)
1149         {
1150                 case CMD_REQUEST_COMMAND:
1151                 {
1152                         blockSpectators = 1;
1153                         entity plr;
1154                         FOR_EACH_REALCLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1155                         {
1156                                 if(IS_SPEC(plr) || IS_OBSERVER(plr))
1157                                 if(!plr.caplayer)
1158                                 {
1159                                         plr.spectatortime = time;
1160                                         Send_Notification(NOTIF_ONE_ONLY, plr, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1161                                 }
1162                         }
1163                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1164                         return;
1165                 }
1166
1167                 default:
1168                 case CMD_REQUEST_USAGE:
1169                 {
1170                         print("\nUsage:^3 sv_cmd nospectators\n");
1171                         print("  No arguments required.\n");
1172                         return;
1173                 }
1174         }
1175 }
1176
1177 void GameCommand_playerdemo(float request, float argc)
1178 {
1179         switch(request)
1180         {
1181                 case CMD_REQUEST_COMMAND:
1182                 {
1183                         if(argv(2) && argv(3))
1184                         {
1185                                 entity client;
1186                                 float i, n, accepted;
1187
1188                                 switch(argv(1))
1189                                 {
1190                                         case "read":
1191                                         {
1192                                                 client = GetIndexedEntity(argc, 2);
1193                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1194
1195                                                 if(accepted <= 0)
1196                                                 {
1197                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1198                                                         return;
1199                                                 }
1200
1201                                                 self = client;
1202                                                 playerdemo_open_read(argv(next_token));
1203                                                 return;
1204                                         }
1205
1206                                         case "write":
1207                                         {
1208                                                 client = GetIndexedEntity(argc, 2);
1209                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1210
1211                                                 if(accepted <= 0)
1212                                                 {
1213                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1214                                                         return;
1215                                                 }
1216
1217                                                 self = client;
1218                                                 playerdemo_open_write(argv(next_token));
1219                                                 return;
1220                                         }
1221
1222                                         case "auto_read_and_write":
1223                                         {
1224                                                 n = GetFilteredNumber(argv(3));
1225                                                 cvar_set("bot_number", ftos(n));
1226
1227                                                 localcmd("wait; wait; wait\n");
1228                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1229
1230                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1231                                                 return;
1232                                         }
1233
1234                                         case "auto_read":
1235                                         {
1236                                                 n = GetFilteredNumber(argv(3));
1237                                                 cvar_set("bot_number", ftos(n));
1238
1239                                                 localcmd("wait; wait; wait\n");
1240                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1241                                                 return;
1242                                         }
1243                                 }
1244                         }
1245                 }
1246
1247                 default:
1248                         print("Incorrect parameters for ^2playerdemo^7\n");
1249                 case CMD_REQUEST_USAGE:
1250                 {
1251                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1252                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1253                         return;
1254                 }
1255         }
1256 }
1257
1258 void GameCommand_printstats(float request)
1259 {
1260         switch(request)
1261         {
1262                 case CMD_REQUEST_COMMAND:
1263                 {
1264                         DumpStats(FALSE);
1265                         print("stats dumped.\n");
1266                         return;
1267                 }
1268
1269                 default:
1270                 case CMD_REQUEST_USAGE:
1271                 {
1272                         print("\nUsage:^3 sv_cmd printstats\n");
1273                         print("  No arguments required.\n");
1274                         return;
1275                 }
1276         }
1277 }
1278
1279 void GameCommand_radarmap(float request, float argc)
1280 {
1281         switch(request)
1282         {
1283                 case CMD_REQUEST_COMMAND:
1284                 {
1285                         if(RadarMap_Make(argc))
1286                                 return;
1287                 }
1288
1289                 default:
1290                         print("Incorrect parameters for ^2radarmap^7\n");
1291                 case CMD_REQUEST_USAGE:
1292                 {
1293                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1294                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1295                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1296                         print("See also: ^2make_mapinfo^7\n");
1297                         return;
1298                 }
1299         }
1300 }
1301
1302 void GameCommand_reducematchtime(float request)
1303 {
1304         switch(request)
1305         {
1306                 case CMD_REQUEST_COMMAND:
1307                 {
1308                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1309                         return;
1310                 }
1311
1312                 default:
1313                 case CMD_REQUEST_USAGE:
1314                 {
1315                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1316                         print("  No arguments required.\n");
1317                         print("See also: ^2extendmatchtime^7\n");
1318                         return;
1319                 }
1320         }
1321 }
1322
1323 void GameCommand_setbots(float request, float argc)
1324 {
1325         switch(request)
1326         {
1327                 case CMD_REQUEST_COMMAND:
1328                 {
1329                         if(argc >= 2)
1330                         {
1331                                 cvar_settemp("minplayers", "0");
1332                                 cvar_settemp("bot_number", argv(1));
1333                                 bot_fixcount();
1334                                 return;
1335                         }
1336                 }
1337
1338                 default:
1339                         print("Incorrect parameters for ^2setbots^7\n");
1340                 case CMD_REQUEST_USAGE:
1341                 {
1342                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1343                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1344                         print("See also: ^2bot_cmd^7\n");
1345                         return;
1346                 }
1347         }
1348 }
1349
1350 void GameCommand_shuffleteams(float request)
1351 {
1352         switch(request)
1353         {
1354                 case CMD_REQUEST_COMMAND:
1355                 {
1356                         if(teamplay)
1357                         {
1358                                 entity tmp_player;
1359                                 float i, x, z, t_teams, t_players, team_color;
1360
1361                                 // count the total amount of players and total amount of teams
1362                                 t_players = 0;
1363                                 t_teams = 0;
1364                                 FOR_EACH_PLAYER(tmp_player)
1365                                 {
1366                                         CheckAllowedTeams(tmp_player);
1367
1368                                         if(c1 >= 0) t_teams = max(1, t_teams);
1369                                         if(c2 >= 0) t_teams = max(2, t_teams);
1370                                         if(c3 >= 0) t_teams = max(3, t_teams);
1371                                         if(c4 >= 0) t_teams = max(4, t_teams);
1372
1373                                         ++t_players;
1374                                 }
1375
1376                                 // build a list of the players in a random order
1377                                 FOR_EACH_PLAYER(tmp_player)
1378                                 {
1379                                         for(;;)
1380                                         {
1381                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1382
1383                                                 if(shuffleteams_players[i])
1384                                                 {
1385                                                         continue; // a player is already assigned to this slot
1386                                                 }
1387                                                 else
1388                                                 {
1389                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1390                                                         break;
1391                                                 }
1392                                         }
1393                                 }
1394
1395                                 // finally, from the list made earlier, re-join the players in different order.
1396                                 for(i = 1; i <= t_teams; ++i)
1397                                 {
1398                                         // find out how many players to assign to this team
1399                                         x = (t_players / t_teams);
1400                                         x = ((i == 1) ? ceil(x) : floor(x));
1401
1402                                         team_color = Team_NumberToTeam(i);
1403
1404                                         // sort through the random list of players made earlier
1405                                         for(z = 1; z <= maxclients; ++z)
1406                                         {
1407                                                 if (!(shuffleteams_teams[i] >= x))
1408                                                 {
1409                                                         if (!(shuffleteams_players[z]))
1410                                                                 continue; // not a player, move on to next random slot
1411
1412                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1413                                                                 self = edict_num(shuffleteams_players[z]);
1414
1415                                                         if(self.team != team_color)
1416                                                                 MoveToTeam(self, team_color, 6);
1417
1418                                                         shuffleteams_players[z] = 0;
1419                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1420                                                 }
1421                                                 else
1422                                                 {
1423                                                         break; // move on to next team
1424                                                 }
1425                                         }
1426                                 }
1427
1428                                 bprint("Successfully shuffled the players around randomly.\n");
1429
1430                                 // clear the buffers now
1431                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1432                                         shuffleteams_players[i] = 0;
1433
1434                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1435                                         shuffleteams_teams[i] = 0;
1436                         }
1437                         else
1438                         {
1439                                 print("Can't shuffle teams when currently not playing a team game.\n");
1440                         }
1441
1442                         return;
1443                 }
1444
1445                 default:
1446                 case CMD_REQUEST_USAGE:
1447                 {
1448                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1449                         print("  No arguments required.\n");
1450                         print("See also: ^2moveplayer, allspec^7\n");
1451                         return;
1452                 }
1453         }
1454 }
1455
1456 void GameCommand_stuffto(float request, float argc)
1457 {
1458         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1459         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1460         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1461
1462         #ifdef STUFFTO_ENABLED
1463         #message "stuffto command enabled"
1464         switch(request)
1465         {
1466                 case CMD_REQUEST_COMMAND:
1467                 {
1468                         if(argv(2))
1469                         {
1470                                 entity client = GetIndexedEntity(argc, 1);
1471                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1472
1473                                 if(accepted > 0)
1474                                 {
1475                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1476                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1477                                 }
1478                                 else
1479                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1480
1481                                 return;
1482                         }
1483                 }
1484
1485                 default:
1486                         print("Incorrect parameters for ^2stuffto^7\n");
1487                 case CMD_REQUEST_USAGE:
1488                 {
1489                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1490                         print("  'client' is the entity number or name of the player,\n");
1491                         print("  and 'command' is the command to be sent to that player.\n");
1492                         return;
1493                 }
1494         }
1495         #else
1496         if(request)
1497         {
1498                 print("stuffto command is not enabled on this server.\n");
1499                 return;
1500         }
1501         #endif
1502 }
1503
1504 void GameCommand_trace(float request, float argc)
1505 {
1506         switch(request)
1507         {
1508                 case CMD_REQUEST_COMMAND:
1509                 {
1510                         entity e;
1511                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1512                         float i, f, safe, unsafe, dq, dqf;
1513
1514                         switch(argv(1))
1515                         {
1516                                 case "debug":
1517                                 {
1518                                         float hitcount = 0;
1519                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1520                                         float worst_endpos_bug = 0;
1521                                         for(;;)
1522                                         {
1523                                                 org = world.mins;
1524                                                 delta = world.maxs - world.mins;
1525
1526                                                 start_x = org_x + random() * delta_x;
1527                                                 start_y = org_y + random() * delta_y;
1528                                                 start_z = org_z + random() * delta_z;
1529
1530                                                 end_x = org_x + random() * delta_x;
1531                                                 end_y = org_y + random() * delta_y;
1532                                                 end_z = org_z + random() * delta_z;
1533
1534                                                 start = stov(vtos(start));
1535                                                 end = stov(vtos(end));
1536
1537                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1538                                                 if(!trace_startsolid && trace_fraction < 1)
1539                                                 {
1540                                                         p = trace_endpos;
1541                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1542                                                         if(trace_startsolid)
1543                                                         {
1544                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1545                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1546
1547                                                                 // how much do we need to back off?
1548                                                                 safe = 1;
1549                                                                 unsafe = 0;
1550                                                                 for(;;)
1551                                                                 {
1552                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1553                                                                         tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1554                                                                         if(trace_startsolid)
1555                                                                         {
1556                                                                                 if((safe + unsafe) * 0.5 == unsafe)
1557                                                                                         break;
1558                                                                                 unsafe = (safe + unsafe) * 0.5;
1559                                                                         }
1560                                                                         else
1561                                                                         {
1562                                                                                 if((safe + unsafe) * 0.5 == safe)
1563                                                                                         break;
1564                                                                                 safe = (safe + unsafe) * 0.5;
1565                                                                         }
1566                                                                 }
1567
1568                                                                 print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1569                                                                 print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1570
1571                                                                 tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1572                                                                 if(trace_startsolid)
1573                                                                         print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1574                                                                 else
1575                                                                         print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1576                                                                 if (++hitcount >= 10)
1577                                                                         break;
1578                                                         }
1579                                                         else
1580                                                         {
1581                                                                 q0 = p;
1582                                                                 dq = 0;
1583                                                                 dqf = 1;
1584                                                                 for(;;)
1585                                                                 {
1586                                                                         q = p + normalize(end - p) * (dq + dqf);
1587                                                                         if(q == q0)
1588                                                                                 break;
1589                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1590                                                                         if(trace_startsolid)
1591                                                                                 error("THIS ONE cannot happen");
1592                                                                         if(trace_fraction > 0)
1593                                                                                 dq += dqf * trace_fraction;
1594                                                                         dqf *= 0.5;
1595                                                                         q0 = q;
1596                                                                 }
1597                                                                 if(dq > worst_endpos_bug)
1598                                                                 {
1599                                                                         worst_endpos_bug = dq;
1600                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1601                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1602                                                                         if (++hitcount >= 10)
1603                                                                                 break;
1604                                                                 }
1605                                                         }
1606                                                 }
1607                                         }
1608                                         return;
1609                                 }
1610
1611                                 case "debug2":
1612                                 {
1613                                         e = nextent(world);
1614                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1615                                         vv = trace_endpos;
1616                                         if(trace_fraction == 1)
1617                                         {
1618                                                 print("not above ground, aborting\n");
1619                                                 return;
1620                                         }
1621                                         f = 0;
1622                                         for(i = 0; i < 100000; ++i)
1623                                         {
1624                                                 dv = randomvec();
1625                                                 if(dv_z > 0)
1626                                                         dv = -1 * dv;
1627                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1628                                                 if(trace_startsolid)
1629                                                         print("bug 1\n");
1630                                                 if(trace_fraction == 1)
1631                                                 if(dv_z < f)
1632                                                 {
1633                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1634                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1635                                                         f = dv_z;
1636                                                 }
1637                                         }
1638                                         print("highest possible dist: ", ftos(f), "\n");
1639                                         return;
1640                                 }
1641
1642                                 case "walk":
1643                                 {
1644                                         if(argc == 4)
1645                                         {
1646                                                 e = nextent(world);
1647                                                 if(tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), MOVE_NORMAL))
1648                                                         print("can walk\n");
1649                                                 else
1650                                                         print("cannot walk\n");
1651                                                 return;
1652                                         }
1653                                 }
1654
1655                                 case "showline":
1656                                 {
1657                                         if(argc == 4)
1658                                         {
1659                                                 vv = stov(argv(2));
1660                                                 dv = stov(argv(3));
1661                                                 traceline(vv, dv, MOVE_NORMAL, world);
1662                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1663                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1664                                                 return;
1665                                         }
1666                                 }
1667
1668                                 // no default case, just go straight to invalid
1669                         }
1670                 }
1671
1672                 default:
1673                         print("Incorrect parameters for ^2trace^7\n");
1674                 case CMD_REQUEST_USAGE:
1675                 {
1676                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1677                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1678                         print("See also: ^2bbox, gettaginfo^7\n");
1679                         return;
1680                 }
1681         }
1682 }
1683
1684 void GameCommand_unlockteams(float request)
1685 {
1686         switch(request)
1687         {
1688                 case CMD_REQUEST_COMMAND:
1689                 {
1690                         if(teamplay)
1691                         {
1692                                 lockteams = 0;
1693                                 bprint("^1The teams are now unlocked.\n");
1694                         }
1695                         else
1696                         {
1697                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1698                         }
1699                         return;
1700                 }
1701
1702                 default:
1703                 case CMD_REQUEST_USAGE:
1704                 {
1705                         print("\nUsage:^3 sv_cmd unlockteams\n");
1706                         print("  No arguments required.\n");
1707                         print("See also: ^2lockteams^7\n");
1708                         return;
1709                 }
1710         }
1711 }
1712
1713 void GameCommand_warp(float request, float argc)
1714 {
1715         switch (request)
1716         {
1717                 case CMD_REQUEST_COMMAND:
1718                 {
1719                         if(autocvar_g_campaign)
1720                         {
1721                                 if(argc >= 2)
1722                                 {
1723                                         CampaignLevelWarp(stof(argv(1)));
1724                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1725                                 }
1726                                 else
1727                                 {
1728                                         CampaignLevelWarp(-1);
1729                                         print("Successfully warped to next campaign level.\n");
1730                                 }
1731                         }
1732                         else
1733                                 print("Not in campaign, can't level warp\n");
1734                         return;
1735                 }
1736
1737                 default:
1738                 case CMD_REQUEST_USAGE:
1739                 {
1740                         print("\nUsage:^3 sv_cmd warp [level]\n");
1741                         print("  'level' is the level to change campaign mode to.\n");
1742                         print("  if 'level' is not provided it will change to the next level.\n");
1743                         return;
1744                 }
1745         }
1746 }
1747
1748 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1749 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1750 void GameCommand_(float request)
1751 {
1752         switch(request)
1753         {
1754                 case CMD_REQUEST_COMMAND:
1755                 {
1756
1757                         return;
1758                 }
1759
1760                 default:
1761                 case CMD_REQUEST_USAGE:
1762                 {
1763                         print("\nUsage:^3 sv_cmd \n");
1764                         print("  No arguments required.\n");
1765                         return;
1766                 }
1767         }
1768 }
1769 */
1770
1771
1772 // ==================================
1773 //  Macro system for server commands
1774 // ==================================
1775
1776 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1777 #define SERVER_COMMANDS(request,arguments,command) \
1778         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1779         SERVER_COMMAND("mobbutcher", GameCommand_mobbutcher(request), "Instantly removes all monsters on the map") \
1780         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1781         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1782         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1783         SERVER_COMMAND("animbench", GameCommand_animbench(request, arguments), "Benchmark model animation (LAGS)") \
1784         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1785         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments, command), "Control and send commands to bots") \
1786         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1787         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1788         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1789         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1790         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1791         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1792         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1793         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1794         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1795         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1796         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1797         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1798         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1799         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1800         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1801         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1802         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1803         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1804         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1805         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1806         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1807         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1808         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1809         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1810         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1811         /* nothing */
1812
1813 void GameCommand_macro_help()
1814 {
1815         #define SERVER_COMMAND(name,function,description) \
1816                 { print("  ^2", name, "^7: ", description, "\n"); }
1817
1818         SERVER_COMMANDS(0, 0, "")
1819         #undef SERVER_COMMAND
1820
1821         return;
1822 }
1823
1824 float GameCommand_macro_command(float argc, string command)
1825 {
1826         #define SERVER_COMMAND(name,function,description) \
1827                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1828
1829         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1830         #undef SERVER_COMMAND
1831
1832         return FALSE;
1833 }
1834
1835 float GameCommand_macro_usage(float argc)
1836 {
1837         #define SERVER_COMMAND(name,function,description) \
1838                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1839
1840         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1841         #undef SERVER_COMMAND
1842
1843         return FALSE;
1844 }
1845
1846 void GameCommand_macro_write_aliases(float fh)
1847 {
1848         #define SERVER_COMMAND(name,function,description) \
1849                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1850
1851         SERVER_COMMANDS(0, 0, "")
1852         #undef SERVER_COMMAND
1853
1854         return;
1855 }
1856
1857
1858 // =========================================
1859 //  Main Function Called By Engine (sv_cmd)
1860 // =========================================
1861 // If this function exists, game code handles gamecommand instead of the engine code.
1862
1863 void GameCommand(string command)
1864 {
1865         float argc = tokenize_console(command);
1866
1867         // Guide for working with argc arguments by example:
1868         // argc:   1    - 2      - 3     - 4
1869         // argv:   0    - 1      - 2     - 3
1870         // cmd     vote - master - login - password
1871
1872         if(strtolower(argv(0)) == "help")
1873         {
1874                 if(argc == 1)
1875                 {
1876                         print("\nServer console commands:\n");
1877                         GameCommand_macro_help();
1878
1879                         print("\nBanning commands:\n");
1880                         BanCommand_macro_help();
1881
1882                         print("\nCommon networked commands:\n");
1883                         CommonCommand_macro_help(world);
1884
1885                         print("\nGeneric commands shared by all programs:\n");
1886                         GenericCommand_macro_help();
1887
1888                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1889                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1890
1891                         return;
1892                 }
1893                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1894                 {
1895                         return;
1896                 }
1897                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1898                 {
1899                         return;
1900                 }
1901                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1902                 {
1903                         return;
1904                 }
1905                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1906                 {
1907                         return;
1908                 }
1909         }
1910         else if(BanCommand(command))
1911         {
1912                 return; // handled by server/command/ipban.qc
1913         }
1914         else if(CommonCommand_macro_command(argc, world, command))
1915         {
1916                 return; // handled by server/command/common.qc
1917         }
1918         else if(GenericCommand(command))
1919         {
1920                 return; // handled by common/command/generic.qc
1921         }
1922         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1923         {
1924                 return; // handled by one of the above GameCommand_* functions
1925         }
1926
1927         // nothing above caught the command, must be invalid
1928         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1929
1930         return;
1931 }