Makefile: use `-I.`
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / vote.qc
1 #include <common/command/command.qh>
2 #include "vote.qh"
3
4 #include "common.qh"
5
6 #include "../g_damage.qh"
7 #include "../g_world.qh"
8 #include "../race.qh"
9 #include "../round_handler.qh"
10 #include "../scores.qh"
11
12 #include "../mutators/all.qh"
13
14 #include <common/constants.qh>
15 #include <common/mapinfo.qh>
16 #include <common/notifications.qh>
17 #include <common/playerstats.qh>
18 #include <common/util.qh>
19
20 // =============================================
21 //  Server side voting code, reworked by Samual
22 //  Last updated: December 27th, 2011
23 // =============================================
24
25 //  Nagger for players to know status of voting
26 bool Nagger_SendEntity(entity this, entity to, float sendflags)
27 {
28         int nags, i, f, b;
29         entity e;
30         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
31
32         // bits:
33         //   1 = ready
34         //   2 = player needs to ready up
35         //   4 = vote
36         //   8 = player needs to vote
37         //  16 = warmup
38         // sendflags:
39         //  64 = vote counts
40         // 128 = vote string
41
42         nags = 0;
43         if (readycount)
44         {
45                 nags |= BIT(0);
46                 if (to.ready == 0) nags |= BIT(1);
47         }
48         if (vote_called)
49         {
50                 nags |= BIT(2);
51                 if (to.vote_selection == 0) nags |= BIT(3);
52         }
53         if (warmup_stage) nags |= BIT(4);
54
55         if (sendflags & BIT(6)) nags |= BIT(6);
56
57         if (sendflags & BIT(7)) nags |= BIT(7);
58
59         if (!(nags & 4))  // no vote called? send no string
60                 nags &= ~(BIT(6) | BIT(7));
61
62         WriteByte(MSG_ENTITY, nags);
63
64         if (nags & BIT(6))
65         {
66                 WriteByte(MSG_ENTITY, vote_accept_count);
67                 WriteByte(MSG_ENTITY, vote_reject_count);
68                 WriteByte(MSG_ENTITY, vote_needed_overall);
69                 WriteChar(MSG_ENTITY, to.vote_selection);
70         }
71
72         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
73
74         if (nags & 1)
75         {
76                 for (i = 1; i <= maxclients; i += 8)
77                 {
78                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
79                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
80                         WriteByte(MSG_ENTITY, f);
81                 }
82         }
83
84         return true;
85 }
86
87 void Nagger_Init()
88 {
89         Net_LinkEntity(nagger = new(nagger), false, 0, Nagger_SendEntity);
90         make_pure(nagger);
91 }
92
93 void Nagger_VoteChanged()
94 {
95         if (nagger) nagger.SendFlags |= BIT(7);
96 }
97
98 void Nagger_VoteCountChanged()
99 {
100         if (nagger) nagger.SendFlags |= BIT(6);
101 }
102
103 void Nagger_ReadyCounted()
104 {
105         if (nagger) nagger.SendFlags |= BIT(0);
106 }
107
108 // If the vote_caller is still here, return their name, otherwise vote_caller_name
109 string OriginalCallerName()
110 {
111         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
112         return vote_caller_name;
113 }
114
115 // =======================
116 //  Game logic for voting
117 // =======================
118
119 void VoteReset()
120 {
121         FOREACH_CLIENT(true, LAMBDA(it.vote_selection = 0));
122
123         if (vote_called)
124         {
125                 strunzone(vote_called_command);
126                 strunzone(vote_called_display);
127                 strunzone(vote_caller_name);
128         }
129
130         vote_called = VOTE_NULL;
131         vote_caller = world;
132         vote_caller_name = string_null;
133         vote_endtime = 0;
134
135         vote_called_command = string_null;
136         vote_called_display = string_null;
137
138         vote_parsed_command = string_null;
139         vote_parsed_display = string_null;
140
141         Nagger_VoteChanged();
142 }
143
144 void VoteStop(entity stopper)
145 {
146         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
147         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
148         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
149         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
150         VoteReset();
151 }
152
153 void VoteAccept()
154 {
155         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
156
157         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
158         else localcmd(strcat(vote_called_command, "\n"));
159
160         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
161
162         VoteReset();
163         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
164 }
165
166 void VoteReject()
167 {
168         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
169         VoteReset();
170         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
171 }
172
173 void VoteTimeout()
174 {
175         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
176         VoteReset();
177         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
178 }
179
180 void VoteSpam(float notvoters, float mincount, string result)
181 {
182         bprint(strcat(
183                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
184                 strcat("^2:^1", ftos(vote_reject_count)),
185                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
186                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
187                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
188
189         if (autocvar_sv_eventlog)
190         {
191                 GameLogEcho(strcat(
192                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
193                         strcat(":", ftos(vote_reject_count)),
194                         strcat(":", ftos(vote_abstain_count)),
195                         strcat(":", ftos(notvoters)),
196                         strcat(":", ftos(mincount))));
197         }
198 }
199
200 void VoteCount(float first_count)
201 {
202         // declarations
203         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
204
205         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
206             || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
207             || (autocvar_sv_vote_nospectators == 0));
208
209         float vote_player_count = 0, notvoters = 0;
210         float vote_real_player_count = 0, vote_real_accept_count = 0;
211         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
212         float vote_needed_of_voted, final_needed_votes;
213         float vote_factor_overall, vote_factor_of_voted;
214
215         Nagger_VoteCountChanged();
216
217         // add up all the votes from each connected client
218         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
219                 ++vote_player_count;
220                 if (IS_PLAYER(it))   ++vote_real_player_count;
221                 switch (it.vote_selection)
222                 {
223                         case VOTE_SELECT_REJECT:
224                         { ++vote_reject_count;
225                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
226                         }
227                         case VOTE_SELECT_ACCEPT:
228                         { ++vote_accept_count;
229                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
230                         }
231                         case VOTE_SELECT_ABSTAIN:
232                         { ++vote_abstain_count;
233                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
234                         }
235                         default: break;
236                 }
237         ));
238
239         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
240         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
241         {
242                 if (vote_caller)   vote_caller.vote_waittime = 0;
243                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
244                 VoteReset();
245                 return;
246         }
247
248         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
249         if (!spectators_allowed && (vote_real_player_count > 0))
250         {
251                 vote_accept_count = vote_real_accept_count;
252                 vote_reject_count = vote_real_reject_count;
253                 vote_abstain_count = vote_real_abstain_count;
254                 vote_player_count = vote_real_player_count;
255         }
256
257         // people who have no opinion in any way :D
258         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
259
260         // determine the goal for the vote to be passed or rejected normally
261         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
262         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
263
264         // if the vote times out, determine the amount of votes needed of the people who actually already voted
265         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
266         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
267
268         // are there any players at all on the server? it could be an admin vote
269         if (vote_player_count == 0 && first_count)
270         {
271                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
272                 VoteAccept();
273                 return;
274         }
275
276         // since there ARE players, finally calculate the result of the vote
277         if (vote_accept_count >= vote_needed_overall)
278         {
279                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
280                 VoteAccept();
281                 return;
282         }
283
284         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
285         {
286                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
287                 VoteReject();
288                 return;
289         }
290
291         // there is not enough votes in either direction, now lets just calculate what the voters have said
292         if (time > vote_endtime)
293         {
294                 final_needed_votes = vote_needed_overall;
295
296                 if (autocvar_sv_vote_majority_factor_of_voted)
297                 {
298                         if (vote_accept_count >= vote_needed_of_voted)
299                         {
300                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
301                                 VoteAccept();
302                                 return;
303                         }
304
305                         if (vote_accept_count + vote_reject_count > 0)
306                         {
307                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
308                                 VoteReject();
309                                 return;
310                         }
311
312                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
313                 }
314
315                 // it didn't pass or fail, so not enough votes to even make a decision.
316                 VoteSpam(notvoters, final_needed_votes, "timeout");
317                 VoteTimeout();
318         }
319 }
320
321 void VoteThink()
322 {
323         if (vote_endtime > 0)        // a vote was called
324         {
325                 if (time > vote_endtime) // time is up
326                         VoteCount(false);
327         }
328 }
329
330
331 // =======================
332 //  Game logic for warmup
333 // =======================
334
335 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
336 void reset_map(bool dorespawn)
337 {
338         SELFPARAM();
339
340         if (time <= game_starttime && round_handler_IsActive()) round_handler_Reset(game_starttime);
341
342         MUTATOR_CALLHOOK(reset_map_global);
343
344         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), LAMBDA(
345                 if (it.reset)
346                 {
347                         WITH(entity, self, it, it.reset(it));
348                         continue;
349                 }
350                 if (it.team_saved) it.team = it.team_saved;
351                 if (it.flags & FL_PROJECTILE) remove(it);  // remove any projectiles left
352         ));
353
354         // Waypoints and assault start come LAST
355         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), LAMBDA(
356                 if (it.reset2) WITH(entity, self, it, it.reset2());
357         ));
358
359         FOREACH_CLIENT(IS_PLAYER(it) && it.frozen, LAMBDA(WITH(entity, self, it, Unfreeze(it))));
360
361         // Moving the player reset code here since the player-reset depends
362         // on spawnpoint entities which have to be reset first --blub
363         if (dorespawn)
364         {
365                 if (!MUTATOR_CALLHOOK(reset_map_players))
366                 {
367                         FOREACH_CLIENT(true, LAMBDA(
368                                 setself(it);
369                                 /*
370                                 only reset players if a restart countdown is active
371                                 this can either be due to cvar sv_ready_restart_after_countdown having set
372                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
373                                 sv_ready_restart_after_countdown is not used and countdown is still running
374                                 */
375                                 if (restart_mapalreadyrestarted || (time < game_starttime))
376                                 {
377                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
378                                         if (IS_PLAYER(self))
379                                         {
380                                                 // PlayerScore_Clear(self);
381                                                 self.killcount = 0;
382                                                 // stop the player from moving so that he stands still once he gets respawned
383                                                 self.velocity = '0 0 0';
384                                                 self.avelocity = '0 0 0';
385                                                 self.movement = '0 0 0';
386                                                 PutClientInServer();
387                                         }
388                                 }
389                         ));
390
391                         setself(this);
392                 }
393         }
394 }
395
396 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
397 void ReadyRestart_think()
398 {
399         SELFPARAM();
400         restart_mapalreadyrestarted = true;
401         reset_map(true);
402         Score_ClearAll();
403         remove(this);
404 }
405
406 // Forces a restart of the game without actually reloading the map // this is a mess...
407 void ReadyRestart_force()
408 {
409         bprint("^1Server is restarting...\n");
410
411         VoteReset();
412
413         // clear overtime, we have to decrease timelimit to its original value again.
414         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
415                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
416         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
417
418         readyrestart_happened = true;
419         game_starttime = time + RESTART_COUNTDOWN;
420
421         // clear player attributes
422         FOREACH_CLIENT(true, LAMBDA(
423                 it.alivetime = 0;
424                 it.killcount = 0;
425                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
426         ));
427
428         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
429
430         // disable the warmup global for the server
431         warmup_stage = 0;                // once the game is restarted the game is in match stage
432
433         // reset the .ready status of all players (also spectators)
434         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(it.ready = false));
435         readycount = 0;
436         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
437
438         // lock teams with lockonrestart
439         if (autocvar_teamplay_lockonrestart && teamplay)
440         {
441                 lockteams = true;
442                 bprint("^1The teams are now locked.\n");
443         }
444
445         // initiate the restart-countdown-announcer entity
446         if (autocvar_sv_ready_restart_after_countdown)
447         {
448                 entity restart_timer = new(restart_timer);
449                 make_pure(restart_timer);
450                 restart_timer.think = ReadyRestart_think;
451                 restart_timer.nextthink = game_starttime;
452         }
453
454         // after a restart every players number of allowed timeouts gets reset, too
455         if (autocvar_sv_timeout)
456         {
457                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(it.allowed_timeouts = autocvar_sv_timeout_number));
458         }
459     // reset map immediately if this cvar is not set
460     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
461         if (autocvar_sv_eventlog) GameLogEcho(":restart");
462 }
463
464 void ReadyRestart()
465 {
466         // no assault support yet...
467         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
468         else localcmd("\nsv_hook_gamerestart\n");
469
470         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
471         // Otherwise scores could be manipulated during the countdown.
472         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
473         ReadyRestart_force();
474 }
475
476 // Count the players who are ready and determine whether or not to restart the match
477 void ReadyCount()
478 {
479         float ready_needed_factor, ready_needed_count;
480         float t_ready = 0, t_players = 0;
481
482         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), LAMBDA(
483                 ++t_players;
484                 if (it.ready) ++t_ready;
485         ));
486
487         readycount = t_ready;
488
489         Nagger_ReadyCounted();
490
491         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
492         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
493
494         if (readycount >= ready_needed_count) ReadyRestart();
495 }
496
497
498 // ======================================
499 //  Supporting functions for VoteCommand
500 // ======================================
501
502 float Votecommand_check_assignment(entity caller, float assignment)
503 {
504         float from_server = (!caller);
505
506         if ((assignment == VC_ASGNMNT_BOTH)
507             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
508             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
509
510         return false;
511 }
512
513 string VoteCommand_extractcommand(string input, float startpos, float argc)
514 {
515         string output;
516
517         if ((argc - 1) < startpos) output = "";
518         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
519
520         return output;
521 }
522
523 float VoteCommand_checknasty(string vote_command)
524 {
525         if ((strstrofs(vote_command, ";", 0) >= 0)
526             || (strstrofs(vote_command, "\n", 0) >= 0)
527             || (strstrofs(vote_command, "\r", 0) >= 0)
528             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
529
530         return true;
531 }
532
533 float VoteCommand_checkinlist(string vote_command, string list)
534 {
535         string l = strcat(" ", list, " ");
536
537         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
538
539         return false;
540 }
541
542 string ValidateMap(string validated_map, entity caller)
543 {
544         validated_map = MapInfo_FixName(validated_map);
545
546         if (!validated_map)
547         {
548                 print_to(caller, "This map is not available on this server.");
549                 return string_null;
550         }
551
552         if (!autocvar_sv_vote_override_mostrecent && caller)
553         {
554                 if (Map_IsRecent(validated_map))
555                 {
556                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
557                         return string_null;
558                 }
559         }
560
561         if (!MapInfo_CheckMap(validated_map))
562         {
563                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
564                 return string_null;
565         }
566
567         return validated_map;
568 }
569
570 float VoteCommand_checkargs(float startpos, float argc)
571 {
572         float p, q, check, minargs;
573         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
574         string cmdrestriction = cvar_string(cvarname);  // note: this warns on undefined cvar. We want that.
575         string charlist, arg;
576         float checkmate;
577
578         if (cmdrestriction == "") return true;
579
580         ++startpos;  // skip command name
581
582         // check minimum arg count
583
584         // 0 args: argc == startpos
585         // 1 args: argc == startpos + 1
586         // ...
587
588         minargs = stof(cmdrestriction);
589         if (argc - startpos < minargs) return false;
590
591         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
592
593         for ( ; ; )
594         {
595                 // we know that at any time, startpos <= argc - minargs
596                 // so this means: argc-minargs >= startpos >= argc, thus
597                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
598                 // have been seen already
599
600                 if (startpos >= argc) // all args checked? GOOD
601                         break;
602
603                 if (p < 0)            // no more args? FAIL
604                 {
605                         // exception: exactly minargs left, this one included
606                         if (argc - startpos == minargs) break;
607
608                         // otherwise fail
609                         return false;
610                 }
611
612                 // cut to next semicolon
613                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
614                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
615                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
616
617                 // in case we ever want to allow semicolons in VoteCommand_checknasty
618                 // charlist = strreplace("^^", ";", charlist);
619
620                 if (charlist != "")
621                 {
622                         // verify the arg only contains allowed chars
623                         arg = argv(startpos);
624                         checkmate = strlen(arg);
625                         for (check = 0; check < checkmate; ++check)
626                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
627                         // not allowed character
628                         // all characters are allowed. FINE.
629                 }
630
631                 ++startpos;
632                 --minargs;
633                 p = q;
634         }
635
636         return true;
637 }
638
639 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
640 {
641         string first_command;
642
643         first_command = argv(startpos);
644
645         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
646             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
647             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
648         );*/
649
650         if (
651             (autocvar_sv_vote_limit > 0)
652             &&
653             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
654            )   return false;
655
656         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
657
658         if (!VoteCommand_checkargs(startpos, argc)) return false;
659
660         switch (first_command) // now go through and parse the proper commands to adjust as needed.
661         {
662                 case "kick":
663                 case "kickban":    // catch all kick/kickban commands
664                 {
665                         entity victim = GetIndexedEntity(argc, (startpos + 1));
666                         float accepted = VerifyClientEntity(victim, true, false);
667
668                         if (accepted > 0)
669                         {
670                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
671                                 string command_arguments;
672
673                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
674                                 else command_arguments = reason;
675
676                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
677                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
678                         }
679                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
680
681                         break;
682                 }
683
684                 case "map":
685                 case "chmap":
686                 case "gotomap":  // re-direct all map selection commands to gotomap
687                 {
688                         vote_command = ValidateMap(argv(startpos + 1), caller);
689                         if (!vote_command)   return false;
690                         vote_parsed_command = strcat("gotomap ", vote_command);
691                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
692
693                         break;
694                 }
695
696                 default:
697                 {
698                         vote_parsed_command = vote_command;
699                         vote_parsed_display = strzone(strcat("^1", vote_command));
700
701                         break;
702                 }
703         }
704
705         return true;
706 }
707
708
709 // =======================
710 //  Command Sub-Functions
711 // =======================
712
713 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
714 {
715         switch (request)
716         {
717                 case CMD_REQUEST_COMMAND:
718                 {
719                         if (!vote_called) { print_to(caller, "^1No vote called."); }
720                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
721                         {
722                                 print_to(caller, "^1You have already voted.");
723                         }
724
725                         else  // everything went okay, continue changing vote
726                         {
727                                 print_to(caller, "^1You abstained from your vote.");
728                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
729                                 msg_entity = caller;
730                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
731
732                         return;
733                 }
734
735                 default:
736                 case CMD_REQUEST_USAGE:
737                 {
738                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
739                         print_to(caller, "  No arguments required.");
740                         return;
741                 }
742         }
743 }
744
745 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
746 {
747         switch (request)
748         {
749                 case CMD_REQUEST_COMMAND:
750                 {
751                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
752                             || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
753                             || (autocvar_sv_vote_nospectators == 0));
754
755                         float tmp_playercount = 0;
756
757                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
758
759                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
760                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
761                         {
762                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
763                         }
764                         else if (vote_called)
765                         {
766                                 print_to(caller, "^1There is already a vote called.");
767                         }
768                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
769                         {
770                                 print_to(caller, "^1Only players can call a vote.");
771                         }
772                         else if (caller && !IS_CLIENT(caller))
773                         {
774                                 print_to(caller, "^1Only connected clients can vote.");
775                         }
776                         else if (timeout_status)
777                         {
778                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
779                         }
780                         else if (caller && (time < caller.vote_waittime))
781                         {
782                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
783                         }
784                         else if (!VoteCommand_checknasty(vote_command))
785                         {
786                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
787                         }
788                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
789                         {
790                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
791                         }
792
793                         else  // everything went okay, continue with calling the vote
794                         {
795                                 vote_caller = caller;  // remember who called the vote
796                                 vote_caller_name = strzone(GetCallerName(vote_caller));
797                                 vote_called = VOTE_NORMAL;
798                                 vote_called_command = strzone(vote_parsed_command);
799                                 vote_called_display = strzone(vote_parsed_display);
800                                 vote_endtime = time + autocvar_sv_vote_timeout;
801
802                                 if (caller)
803                                 {
804                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
805                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
806                                         msg_entity = caller;
807                                 }
808
809                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(++tmp_playercount));
810                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
811
812                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
813                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
814                                 Nagger_VoteChanged();
815                                 VoteCount(true);  // needed if you are the only one
816                         }
817
818                         return;
819                 }
820
821                 default:
822                 case CMD_REQUEST_USAGE:
823                 {
824                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
825                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
826                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
827                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
828                         return;
829                 }
830         }
831 }
832
833 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
834 {
835         switch (request)
836         {
837                 case CMD_REQUEST_COMMAND:
838                 {
839                         if (autocvar_sv_vote_master)
840                         {
841                                 switch (strtolower(argv(2)))
842                                 {
843                                         case "do":
844                                         {
845                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
846
847                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
848                                                 else if (!VoteCommand_checknasty(vote_command))
849                                                 {
850                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
851                                                 }
852                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
853                                                 {
854                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
855                                                 }
856
857                                                 else  // everything went okay, proceed with command
858                                                 {
859                                                         localcmd(strcat(vote_parsed_command, "\n"));
860                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
861                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
862                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
863
864                                                 return;
865                                         }
866
867                                         case "login":
868                                         {
869                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
870                                                 else if (caller.vote_master)
871                                                 {
872                                                         print_to(caller, "^1You are already logged in as vote master.");
873                                                 }
874                                                 else if (autocvar_sv_vote_master_password != argv(3))
875                                                 {
876                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
877                                                 }
878
879                                                 else  // everything went okay, proceed with giving this player master privilages
880                                                 {
881                                                         caller.vote_master = true;
882                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
883                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
884                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
885
886                                                 return;
887                                         }
888
889                                         default:  // calling a vote for master
890                                         {
891                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
892                                                     || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
893                                                     || (autocvar_sv_vote_nospectators == 0));
894
895                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
896                                                 else if (vote_called)
897                                                 {
898                                                         print_to(caller, "^1There is already a vote called.");
899                                                 }
900                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
901                                                 {
902                                                         print_to(caller, "^1Only players can call a vote.");
903                                                 }
904                                                 else if (timeout_status)
905                                                 {
906                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
907                                                 }
908
909                                                 else  // everything went okay, continue with creating vote
910                                                 {
911                                                         vote_caller = caller;
912                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
913                                                         vote_called = VOTE_MASTER;
914                                                         vote_called_command = strzone("XXX");
915                                                         vote_called_display = strzone("^3master");
916                                                         vote_endtime = time + autocvar_sv_vote_timeout;
917
918                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
919                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
920
921                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
922                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
923                                                         Nagger_VoteChanged();
924                                                         VoteCount(true);  // needed if you are the only one
925                                                 }
926
927                                                 return;
928                                         }
929                                 }
930                         }
931                         else { print_to(caller, "^1Master control of voting is not allowed."); }
932
933                         return;
934                 }
935
936                 default:
937                 case CMD_REQUEST_USAGE:
938                 {
939                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
940                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
941                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
942                         return;
943                 }
944         }
945 }
946
947 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
948 {
949         switch (request)
950         {
951                 case CMD_REQUEST_COMMAND:
952                 {
953                         if (!vote_called) { print_to(caller, "^1No vote called."); }
954                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
955                         {
956                                 print_to(caller, "^1You have already voted.");
957                         }
958                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
959                         {
960                                 VoteStop(caller);
961                         }
962
963                         else  // everything went okay, continue changing vote
964                         {
965                                 print_to(caller, "^1You rejected the vote.");
966                                 caller.vote_selection = VOTE_SELECT_REJECT;
967                                 msg_entity = caller;
968                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
969
970                         return;
971                 }
972
973                 default:
974                 case CMD_REQUEST_USAGE:
975                 {
976                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
977                         print_to(caller, "  No arguments required.");
978                         return;
979                 }
980         }
981 }
982
983 void VoteCommand_status(float request, entity caller)  // BOTH
984 {
985         switch (request)
986         {
987                 case CMD_REQUEST_COMMAND:
988                 {
989                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
990                         else print_to(caller, "^1No vote called.");
991
992                         return;
993                 }
994
995                 default:
996                 case CMD_REQUEST_USAGE:
997                 {
998                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
999                         print_to(caller, "  No arguments required.");
1000                         return;
1001                 }
1002         }
1003 }
1004
1005 void VoteCommand_stop(float request, entity caller)  // BOTH
1006 {
1007         switch (request)
1008         {
1009                 case CMD_REQUEST_COMMAND:
1010                 {
1011                         if (!vote_called)   print_to(caller, "^1No vote called.");
1012                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1013                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1014                         return;
1015                 }
1016
1017                 default:
1018                 case CMD_REQUEST_USAGE:
1019                 {
1020                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1021                         print_to(caller, "  No arguments required.");
1022                         return;
1023                 }
1024         }
1025 }
1026
1027 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1028 {
1029         switch (request)
1030         {
1031                 case CMD_REQUEST_COMMAND:
1032                 {
1033                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1034                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1035                         {
1036                                 print_to(caller, "^1You have already voted.");
1037                         }
1038
1039                         else  // everything went okay, continue changing vote
1040                         {
1041                                 print_to(caller, "^1You accepted the vote.");
1042                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1043                                 msg_entity = caller;
1044                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1045
1046                         return;
1047                 }
1048
1049                 default:
1050                 case CMD_REQUEST_USAGE:
1051                 {
1052                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1053                         print_to(caller, "  No arguments required.");
1054                         return;
1055                 }
1056         }
1057 }
1058
1059 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1060 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1061 void VoteCommand_(float request)
1062 {
1063     switch(request)
1064     {
1065         case CMD_REQUEST_COMMAND:
1066         {
1067
1068             return;
1069         }
1070
1071         default:
1072         case CMD_REQUEST_USAGE:
1073         {
1074             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1075             print_to(caller, "  No arguments required.");
1076             return;
1077         }
1078     }
1079 }
1080 */
1081
1082
1083 // ================================
1084 //  Macro system for vote commands
1085 // ================================
1086
1087 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1088 #define VOTE_COMMANDS(request, caller, arguments, command) \
1089         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1090         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1091         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1092         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1093         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1094         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1095         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1096         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1097         /* nothing */
1098
1099 void VoteCommand_macro_help(entity caller, float argc)
1100 {
1101         string command_origin = GetCommandPrefix(caller);
1102
1103         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1104         {
1105                 print_to(caller, "\nVoting commands:\n");
1106                 #define VOTE_COMMAND(name, function, description, assignment) \
1107                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1108
1109                 VOTE_COMMANDS(0, caller, 0, "");
1110 #undef VOTE_COMMAND
1111
1112                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1113                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1114                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1115         }
1116         else  // usage for individual command
1117         {
1118                 #define VOTE_COMMAND(name, function, description, assignment) \
1119                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1120
1121                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1122 #undef VOTE_COMMAND
1123         }
1124 }
1125
1126 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1127 {
1128         #define VOTE_COMMAND(name, function, description, assignment) \
1129                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1130
1131         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1132 #undef VOTE_COMMAND
1133
1134         return false;
1135 }
1136
1137
1138 // ======================================
1139 //  Main function handling vote commands
1140 // ======================================
1141
1142 void VoteCommand(float request, entity caller, float argc, string vote_command)
1143 {
1144         // Guide for working with argc arguments by example:
1145         // argc:   1    - 2      - 3     - 4
1146         // argv:   0    - 1      - 2     - 3
1147         // cmd     vote - master - login - password
1148
1149         switch (request)
1150         {
1151                 case CMD_REQUEST_COMMAND:
1152                 {
1153                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1154                 }
1155
1156                 default:
1157                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1158                 case CMD_REQUEST_USAGE:
1159                 {
1160                         VoteCommand_macro_help(caller, argc);
1161                         return;
1162                 }
1163         }
1164 }