Merge branch 'master' into TimePath/combined_updates
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / vote.qc
1 // =============================================
2 //  Server side voting code, reworked by Samual
3 //  Last updated: December 27th, 2011
4 // =============================================
5
6 //  Nagger for players to know status of voting
7 float Nagger_SendEntity(entity to, float sendflags)
8 {
9         float nags, i, f, b;
10         entity e;
11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
12
13         // bits:
14         //   1 = ready
15         //   2 = player needs to ready up
16         //   4 = vote
17         //   8 = player needs to vote
18         //  16 = warmup
19         // sendflags:
20         //  64 = vote counts
21         // 128 = vote string
22
23         nags = 0;
24         if(readycount)
25         {
26                 nags |= 1;
27                 if(to.ready == 0)
28                         nags |= 2;
29         }
30         if(vote_called)
31         {
32                 nags |= 4;
33                 if(to.vote_selection == 0)
34                         nags |= 8;
35         }
36         if(warmup_stage)
37                 nags |= 16;
38
39         if(sendflags & 64)
40                 nags |= 64;
41
42         if(sendflags & 128)
43                 nags |= 128;
44
45         if(!(nags & 4)) // no vote called? send no string
46                 nags &= ~(64 | 128);
47
48         WriteByte(MSG_ENTITY, nags);
49
50         if(nags & 64)
51         {
52                 WriteByte(MSG_ENTITY, vote_accept_count);
53                 WriteByte(MSG_ENTITY, vote_reject_count);
54                 WriteByte(MSG_ENTITY, vote_needed_overall);
55                 WriteChar(MSG_ENTITY, to.vote_selection);
56         }
57
58         if(nags & 128)
59                 WriteString(MSG_ENTITY, vote_called_display);
60
61         if(nags & 1)
62         {
63                 for(i = 1; i <= maxclients; i += 8)
64                 {
65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
66                                 if(!IS_REAL_CLIENT(e) || e.ready)
67                                         f |= b;
68                         WriteByte(MSG_ENTITY, f);
69                 }
70         }
71
72         return TRUE;
73 }
74
75 void Nagger_Init()
76 {
77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
78 }
79
80 void Nagger_VoteChanged()
81 {
82         if(nagger)
83                 nagger.SendFlags |= 128;
84 }
85
86 void Nagger_VoteCountChanged()
87 {
88         if(nagger)
89                 nagger.SendFlags |= 64;
90 }
91
92 void Nagger_ReadyCounted()
93 {
94         if(nagger)
95                 nagger.SendFlags |= 1;
96 }
97
98
99 // =======================
100 //  Game logic for voting
101 // =======================
102
103 void VoteReset()
104 {
105         entity tmp_player;
106
107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
108
109         if(vote_called)
110         {
111                 strunzone(vote_called_command);
112                 strunzone(vote_called_display);
113         }
114
115         vote_called = VOTE_NULL;
116         vote_caller = world;
117         vote_endtime = 0;
118
119         vote_called_command = string_null;
120         vote_called_display = string_null;
121
122         vote_parsed_command = string_null;
123         vote_parsed_display = string_null;
124
125         Nagger_VoteChanged();
126 }
127
128 void VoteStop(entity stopper)
129 {
130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
132
133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
135
136         VoteReset();
137 }
138
139 void VoteAccept()
140 {
141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
142
143         if((vote_called == VOTE_MASTER) && vote_caller)
144                 vote_caller.vote_master = 1;
145         else
146                 localcmd(strcat(vote_called_command, "\n"));
147
148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
149
150         VoteReset();
151         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
152 }
153
154 void VoteReject()
155 {
156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
157         VoteReset();
158         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
159 }
160
161 void VoteTimeout()
162 {
163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
164         VoteReset();
165         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
166 }
167
168 void VoteSpam(float notvoters, float mincount, string result)
169 {
170         bprint(strcat(
171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
172                 strcat("^2:^1", ftos(vote_reject_count)),
173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
176
177         if(autocvar_sv_eventlog)
178         {
179                 GameLogEcho(strcat(
180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
181                         strcat(":", ftos(vote_reject_count)),
182                         strcat(":", ftos(vote_abstain_count)),
183                         strcat(":", ftos(notvoters)),
184                         strcat(":", ftos(mincount))));
185         }
186 }
187
188 void VoteCount(float first_count)
189 {
190         // declarations
191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
192
193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
194                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
195                                 || (autocvar_sv_vote_nospectators == 0));
196
197         float vote_player_count = 0, notvoters = 0;
198         float vote_real_player_count = 0, vote_real_accept_count = 0;
199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
200         float vote_needed_of_voted, final_needed_votes;
201         float vote_factor_overall, vote_factor_of_voted;
202
203         entity tmp_player;
204
205         Nagger_VoteCountChanged();
206
207         // add up all the votes from each connected client
208         FOR_EACH_REALCLIENT(tmp_player)
209         {
210                 ++vote_player_count;
211                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
212
213                 switch(tmp_player.vote_selection)
214                 {
215                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
216                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
217                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
218                         default: break;
219                 }
220         }
221
222         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
223         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
224         {
225                 if(vote_caller) { vote_caller.vote_waittime = 0; }
226                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
227                 VoteReset();
228                 return;
229         }
230
231         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
232         if(!spectators_allowed && (vote_real_player_count > 0))
233         {
234                 vote_accept_count = vote_real_accept_count;
235                 vote_reject_count = vote_real_reject_count;
236                 vote_abstain_count = vote_real_abstain_count;
237                 vote_player_count = vote_real_player_count;
238         }
239
240         // people who have no opinion in any way :D
241         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
242
243         // determine the goal for the vote to be passed or rejected normally
244         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
245         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
246
247         // if the vote times out, determine the amount of votes needed of the people who actually already voted
248         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
249         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
250
251         // are there any players at all on the server? it could be an admin vote
252         if(vote_player_count == 0 && first_count)
253         {
254                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
255                 VoteAccept();
256                 return;
257         }
258
259         // since there ARE players, finally calculate the result of the vote
260         if(vote_accept_count >= vote_needed_overall)
261         {
262                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
263                 VoteAccept();
264                 return;
265         }
266
267         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
268         {
269                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
270                 VoteReject();
271                 return;
272         }
273
274         // there is not enough votes in either direction, now lets just calculate what the voters have said
275         if(time > vote_endtime)
276         {
277                 final_needed_votes = vote_needed_overall;
278
279                 if(autocvar_sv_vote_majority_factor_of_voted)
280                 {
281                         if(vote_accept_count >= vote_needed_of_voted)
282                         {
283                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
284                                 VoteAccept();
285                                 return;
286                         }
287
288                         if(vote_accept_count + vote_reject_count > 0)
289                         {
290                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
291                                 VoteReject();
292                                 return;
293                         }
294
295                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
296                 }
297
298                 // it didn't pass or fail, so not enough votes to even make a decision.
299                 VoteSpam(notvoters, final_needed_votes, "timeout");
300                 VoteTimeout();
301         }
302 }
303
304 void VoteThink()
305 {
306         if(vote_endtime > 0) // a vote was called
307         if(time > vote_endtime) // time is up
308         {
309                 VoteCount(FALSE);
310         }
311
312         return;
313 }
314
315
316 // =======================
317 //  Game logic for warmup
318 // =======================
319
320 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
321 void reset_map(float dorespawn)
322 {
323         entity oldself;
324         oldself = self;
325
326         if(time <= game_starttime && round_handler_IsActive())
327                 round_handler_Reset(game_starttime);
328
329         MUTATOR_CALLHOOK(reset_map_global);
330
331         for(self = world; (self = nextent(self)); )
332         if(IS_NOT_A_CLIENT(self))
333         {
334                 if(self.reset)
335                 {
336                         self.reset();
337                         continue;
338                 }
339
340                 if(self.team_saved)
341                         self.team = self.team_saved;
342
343                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
344                         remove(self);
345         }
346
347         // Waypoints and assault start come LAST
348         for(self = world; (self = nextent(self)); )
349         if(IS_NOT_A_CLIENT(self))
350         {
351                 if(self.reset2)
352                 {
353                         self.reset2();
354                         continue;
355                 }
356         }
357
358         FOR_EACH_PLAYER(self)
359         if(self.frozen)
360                 Unfreeze(self);
361
362         // Moving the player reset code here since the player-reset depends
363         // on spawnpoint entities which have to be reset first --blub
364         if(dorespawn)
365         if(!MUTATOR_CALLHOOK(reset_map_players))
366         FOR_EACH_CLIENT(self) // reset all players
367         {
368                 /*
369                 only reset players if a restart countdown is active
370                 this can either be due to cvar sv_ready_restart_after_countdown having set
371                 restart_mapalreadyrestarted to 1 after the countdown ended or when
372                 sv_ready_restart_after_countdown is not used and countdown is still running
373                 */
374                 if (restart_mapalreadyrestarted || (time < game_starttime))
375                 {
376                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
377                         if (IS_PLAYER(self)) {
378                                 //PlayerScore_Clear(self);
379                                 self.killcount = 0;
380                                 //stop the player from moving so that he stands still once he gets respawned
381                                 self.velocity = '0 0 0';
382                                 self.avelocity = '0 0 0';
383                                 self.movement = '0 0 0';
384                                 PutClientInServer();
385                         }
386                 }
387         }
388
389         if(g_keyhunt)
390                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
391
392         self = oldself;
393 }
394
395 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
396 void ReadyRestart_think()
397 {
398         restart_mapalreadyrestarted = 1;
399         reset_map(TRUE);
400         Score_ClearAll();
401         remove(self);
402
403         return;
404 }
405
406 // Forces a restart of the game without actually reloading the map // this is a mess...
407 void ReadyRestart_force()
408 {
409         entity tmp_player, restart_timer;
410
411         bprint("^1Server is restarting...\n");
412
413         VoteReset();
414
415         // clear overtime, we have to decrease timelimit to its original value again.
416         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
417
418         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
419
420         readyrestart_happened = 1;
421         game_starttime = time + RESTART_COUNTDOWN;
422
423         // clear player attributes
424         FOR_EACH_CLIENT(tmp_player)
425         {
426                 tmp_player.alivetime = 0;
427                 tmp_player.killcount = 0;
428                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
429         }
430
431         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
432
433         // disable the warmup global for the server
434         warmup_stage = 0; // once the game is restarted the game is in match stage
435
436         // reset the .ready status of all players (also spectators)
437         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
438         readycount = 0;
439         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
440
441         // lock teams with lockonrestart
442         if(autocvar_teamplay_lockonrestart && teamplay)
443         {
444                 lockteams = 1;
445                 bprint("^1The teams are now locked.\n");
446         }
447
448         //initiate the restart-countdown-announcer entity
449         if(autocvar_sv_ready_restart_after_countdown)
450         {
451                 restart_timer = spawn();
452                 restart_timer.think = ReadyRestart_think;
453                 restart_timer.nextthink = game_starttime;
454         }
455
456         // after a restart every players number of allowed timeouts gets reset, too
457         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
458
459         //reset map immediately if this cvar is not set
460         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
461
462         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
463 }
464
465 void ReadyRestart()
466 {
467         // no arena, assault support yet...
468         if(g_assault | gameover | intermission_running | race_completing)
469                 localcmd("restart\n");
470         else
471                 localcmd("\nsv_hook_gamerestart\n");
472
473         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
474         // Otherwise scores could be manipulated during the countdown.
475         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
476
477         ReadyRestart_force();
478
479         return;
480 }
481
482 // Count the players who are ready and determine whether or not to restart the match
483 void ReadyCount()
484 {
485         entity tmp_player;
486         float ready_needed_factor, ready_needed_count;
487         float t_ready = 0, t_players = 0;
488
489         FOR_EACH_REALCLIENT(tmp_player)
490         {
491                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
492                 {
493                         ++t_players;
494                         if(tmp_player.ready) { ++t_ready; }
495                 }
496         }
497
498         readycount = t_ready;
499
500         Nagger_ReadyCounted();
501
502         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
503         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
504
505         if(readycount >= ready_needed_count)
506         {
507                 ReadyRestart();
508         }
509
510         return;
511 }
512
513
514 // ======================================
515 //  Supporting functions for VoteCommand
516 // ======================================
517
518 float Votecommand_check_assignment(entity caller, float assignment)
519 {
520         float from_server = (!caller);
521
522         if((assignment == VC_ASGNMNT_BOTH)
523                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
524                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
525         {
526                 return TRUE;
527         }
528
529         return FALSE;
530 }
531
532 string VoteCommand_extractcommand(string input, float startpos, float argc)
533 {
534         string output;
535
536         if((argc - 1) < startpos)
537                 output = "";
538         else
539                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
540
541         return output;
542 }
543
544 float VoteCommand_checknasty(string vote_command)
545 {
546         if((strstrofs(vote_command, ";", 0) >= 0)
547                 || (strstrofs(vote_command, "\n", 0) >= 0)
548                 || (strstrofs(vote_command, "\r", 0) >= 0)
549                 || (strstrofs(vote_command, "$", 0) >= 0))
550                 return FALSE;
551
552         return TRUE;
553 }
554
555 float VoteCommand_checkinlist(string vote_command, string list)
556 {
557         string l = strcat(" ", list, " ");
558
559         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
560                 return TRUE;
561
562         return FALSE;
563 }
564
565 string ValidateMap(string validated_map, entity caller)
566 {
567         validated_map = MapInfo_FixName(validated_map);
568
569         if (!validated_map)
570         {
571                 print_to(caller, "This map is not available on this server.");
572                 return string_null;
573         }
574
575         if(!autocvar_sv_vote_override_mostrecent && caller)
576         {
577                 if(Map_IsRecent(validated_map))
578                 {
579                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
580                         return string_null;
581                 }
582         }
583
584         if(!MapInfo_CheckMap(validated_map))
585         {
586                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
587                 return string_null;
588         }
589
590         return validated_map;
591 }
592
593 float VoteCommand_checkargs(float startpos, float argc)
594 {
595         float p, q, check, minargs;
596         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
597         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
598         string charlist, arg;
599         float checkmate;
600
601         if(cmdrestriction == "")
602                 return TRUE;
603
604         ++startpos; // skip command name
605
606         // check minimum arg count
607
608         // 0 args: argc == startpos
609         // 1 args: argc == startpos + 1
610         // ...
611
612         minargs = stof(cmdrestriction);
613         if(argc - startpos < minargs)
614                 return FALSE;
615
616         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
617
618         for(;;)
619         {
620                 // we know that at any time, startpos <= argc - minargs
621                 // so this means: argc-minargs >= startpos >= argc, thus
622                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
623                 // have been seen already
624
625                 if(startpos >= argc) // all args checked? GOOD
626                         break;
627
628                 if(p < 0) // no more args? FAIL
629                 {
630                         // exception: exactly minargs left, this one included
631                         if(argc - startpos == minargs)
632                                 break;
633
634                         // otherwise fail
635                         return FALSE;
636                 }
637
638                 // cut to next semicolon
639                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
640                 if(q < 0)
641                         charlist = substring(cmdrestriction, p+1, -1);
642                 else
643                         charlist = substring(cmdrestriction, p+1, q - (p+1));
644
645                 // in case we ever want to allow semicolons in VoteCommand_checknasty
646                 // charlist = strreplace("^^", ";", charlist);
647
648                 if(charlist != "")
649                 {
650                         // verify the arg only contains allowed chars
651                         arg = argv(startpos);
652                         checkmate = strlen(arg);
653                         for(check = 0; check < checkmate; ++check)
654                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
655                                         return FALSE; // not allowed character
656                         // all characters are allowed. FINE.
657                 }
658
659                 ++startpos;
660                 --minargs;
661                 p = q;
662         }
663
664         return TRUE;
665 }
666
667 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
668 {
669         string first_command;
670
671         first_command = argv(startpos);
672
673         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
674                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
675                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
676         );*/
677
678         if(
679                 (autocvar_sv_vote_limit > 0)
680                 &&
681                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
682         )
683                 return FALSE;
684
685         if (!VoteCommand_checkinlist(first_command, vote_list))
686                 return FALSE;
687
688         if (!VoteCommand_checkargs(startpos, argc))
689                 return FALSE;
690
691         switch(first_command) // now go through and parse the proper commands to adjust as needed.
692         {
693                 case "kick":
694                 case "kickban": // catch all kick/kickban commands
695                 {
696                         entity victim = GetIndexedEntity(argc, (startpos + 1));
697                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
698
699                         if(accepted > 0)
700                         {
701                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
702                                 string command_arguments;
703
704                                 if(first_command == "kickban")
705                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
706                                 else
707                                         command_arguments = reason;
708
709                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
710                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
711                         }
712                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
713
714                         break;
715                 }
716
717                 case "map":
718                 case "chmap":
719                 case "gotomap": // re-direct all map selection commands to gotomap
720                 {
721                         vote_command = ValidateMap(argv(startpos + 1), caller);
722                         if (!vote_command) { return FALSE; }
723                         vote_parsed_command = strcat("gotomap ", vote_command);
724                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
725
726                         break;
727                 }
728
729                 default:
730                 {
731                         vote_parsed_command = vote_command;
732                         vote_parsed_display = strzone(strcat("^1", vote_command));
733
734                         break;
735                 }
736         }
737
738         return TRUE;
739 }
740
741
742 // =======================
743 //  Command Sub-Functions
744 // =======================
745
746 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
747 {
748         switch(request)
749         {
750                 case CMD_REQUEST_COMMAND:
751                 {
752                         if (!vote_called) { print_to(caller, "^1No vote called."); }
753                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
754
755                         else // everything went okay, continue changing vote
756                         {
757                                 print_to(caller, "^1You abstained from your vote.");
758                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
759                                 msg_entity = caller;
760                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
761                         }
762
763                         return;
764                 }
765
766                 default:
767                 case CMD_REQUEST_USAGE:
768                 {
769                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
770                         print_to(caller, "  No arguments required.");
771                         return;
772                 }
773         }
774 }
775
776 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
777 {
778         switch(request)
779         {
780                 case CMD_REQUEST_COMMAND:
781                 {
782                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
783                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
784                                 || (autocvar_sv_vote_nospectators == 0));
785
786                         float tmp_playercount = 0;
787                         entity tmp_player;
788
789                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
790
791                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
792                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
793                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
794                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
795                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
796                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
797                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
798                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
799
800                         else // everything went okay, continue with calling the vote
801                         {
802                                 vote_caller = caller; // remember who called the vote
803                                 vote_called = VOTE_NORMAL;
804                                 vote_called_command = strzone(vote_parsed_command);
805                                 vote_called_display = strzone(vote_parsed_display);
806                                 vote_endtime = time + autocvar_sv_vote_timeout;
807
808                                 if(caller)
809                                 {
810                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
811                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
812                                         msg_entity = caller;
813                                 }
814
815                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
816                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
817
818                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
819                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
820                                 Nagger_VoteChanged();
821                                 VoteCount(TRUE); // needed if you are the only one
822                         }
823
824                         return;
825                 }
826
827                 default:
828                 case CMD_REQUEST_USAGE:
829                 {
830                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
831                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
832                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
833                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
834                         return;
835                 }
836         }
837 }
838
839 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
840 {
841         switch(request)
842         {
843                 case CMD_REQUEST_COMMAND:
844                 {
845                         if(autocvar_sv_vote_master)
846                         {
847                                 switch(strtolower(argv(2)))
848                                 {
849                                         case "do":
850                                         {
851                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
852
853                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
854                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
855                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
856
857                                                 else // everything went okay, proceed with command
858                                                 {
859                                                         localcmd(strcat(vote_parsed_command, "\n"));
860                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
861                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
862                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
863                                                 }
864
865                                                 return;
866                                         }
867
868                                         case "login":
869                                         {
870                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
871                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
872                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
873
874                                                 else // everything went okay, proceed with giving this player master privilages
875                                                 {
876                                                         caller.vote_master = TRUE;
877                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
878                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
879                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
880                                                 }
881
882                                                 return;
883                                         }
884
885                                         default: // calling a vote for master
886                                         {
887                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
888                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
889                                                         || (autocvar_sv_vote_nospectators == 0));
890
891                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
892                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
893                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
894                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
895
896                                                 else // everything went okay, continue with creating vote
897                                                 {
898                                                         vote_caller = caller;
899                                                         vote_called = VOTE_MASTER;
900                                                         vote_called_command = strzone("XXX");
901                                                         vote_called_display = strzone("^3master");
902                                                         vote_endtime = time + autocvar_sv_vote_timeout;
903
904                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
905                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
906
907                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
908                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
909                                                         Nagger_VoteChanged();
910                                                         VoteCount(TRUE); // needed if you are the only one
911                                                 }
912
913                                                 return;
914                                         }
915                                 }
916                         }
917                         else { print_to(caller, "^1Master control of voting is not allowed."); }
918
919                         return;
920                 }
921
922                 default:
923                 case CMD_REQUEST_USAGE:
924                 {
925                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
926                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
927                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
928                         return;
929                 }
930         }
931 }
932
933 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
934 {
935         switch(request)
936         {
937                 case CMD_REQUEST_COMMAND:
938                 {
939                         if (!vote_called) { print_to(caller, "^1No vote called."); }
940                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
941                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
942
943                         else // everything went okay, continue changing vote
944                         {
945                                 print_to(caller, "^1You rejected the vote.");
946                                 caller.vote_selection = VOTE_SELECT_REJECT;
947                                 msg_entity = caller;
948                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
949                         }
950
951                         return;
952                 }
953
954                 default:
955                 case CMD_REQUEST_USAGE:
956                 {
957                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
958                         print_to(caller, "  No arguments required.");
959                         return;
960                 }
961         }
962 }
963
964 void VoteCommand_status(float request, entity caller) // BOTH
965 {
966         switch(request)
967         {
968                 case CMD_REQUEST_COMMAND:
969                 {
970                         if(vote_called)
971                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
972                         else
973                                 print_to(caller, "^1No vote called.");
974
975                         return;
976                 }
977
978                 default:
979                 case CMD_REQUEST_USAGE:
980                 {
981                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
982                         print_to(caller, "  No arguments required.");
983                         return;
984                 }
985         }
986 }
987
988 void VoteCommand_stop(float request, entity caller) // BOTH
989 {
990         switch(request)
991         {
992                 case CMD_REQUEST_COMMAND:
993                 {
994                         if (!vote_called) { print_to(caller, "^1No vote called."); }
995                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
996                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
997
998                         return;
999                 }
1000
1001                 default:
1002                 case CMD_REQUEST_USAGE:
1003                 {
1004                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1005                         print_to(caller, "  No arguments required.");
1006                         return;
1007                 }
1008         }
1009 }
1010
1011 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1012 {
1013         switch(request)
1014         {
1015                 case CMD_REQUEST_COMMAND:
1016                 {
1017                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1018                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1019
1020                         else // everything went okay, continue changing vote
1021                         {
1022                                 print_to(caller, "^1You accepted the vote.");
1023                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1024                                 msg_entity = caller;
1025                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
1026                         }
1027
1028                         return;
1029                 }
1030
1031                 default:
1032                 case CMD_REQUEST_USAGE:
1033                 {
1034                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1035                         print_to(caller, "  No arguments required.");
1036                         return;
1037                 }
1038         }
1039 }
1040
1041 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1042 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1043 void VoteCommand_(float request)
1044 {
1045         switch(request)
1046         {
1047                 case CMD_REQUEST_COMMAND:
1048                 {
1049
1050                         return;
1051                 }
1052
1053                 default:
1054                 case CMD_REQUEST_USAGE:
1055                 {
1056                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1057                         print_to(caller, "  No arguments required.");
1058                         return;
1059                 }
1060         }
1061 }
1062 */
1063
1064
1065 // ================================
1066 //  Macro system for vote commands
1067 // ================================
1068
1069 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1070 #define VOTE_COMMANDS(request,caller,arguments,command) \
1071         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1072         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1073         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1074         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1075         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1076         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1077         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1078         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1079         /* nothing */
1080
1081 void VoteCommand_macro_help(entity caller, float argc)
1082 {
1083         string command_origin = GetCommandPrefix(caller);
1084
1085         if(argc == 2 || argv(2) == "help") // help display listing all commands
1086         {
1087                 print_to(caller, "\nVoting commands:\n");
1088                 #define VOTE_COMMAND(name,function,description,assignment) \
1089                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1090
1091                 VOTE_COMMANDS(0, caller, 0, "")
1092                 #undef VOTE_COMMAND
1093
1094                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1095                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1096                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1097         }
1098         else // usage for individual command
1099         {
1100                 #define VOTE_COMMAND(name,function,description,assignment) \
1101                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1102
1103                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1104                 #undef VOTE_COMMAND
1105         }
1106
1107         return;
1108 }
1109
1110 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1111 {
1112         #define VOTE_COMMAND(name,function,description,assignment) \
1113                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1114
1115         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1116         #undef VOTE_COMMAND
1117
1118         return FALSE;
1119 }
1120
1121
1122 // ======================================
1123 //  Main function handling vote commands
1124 // ======================================
1125
1126 void VoteCommand(float request, entity caller, float argc, string vote_command)
1127 {
1128         // Guide for working with argc arguments by example:
1129         // argc:   1    - 2      - 3     - 4
1130         // argv:   0    - 1      - 2     - 3
1131         // cmd     vote - master - login - password
1132
1133         switch(request)
1134         {
1135                 case CMD_REQUEST_COMMAND:
1136                 {
1137                         if(VoteCommand_macro_command(caller, argc, vote_command))
1138                                 return;
1139                 }
1140
1141                 default:
1142                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1143                 case CMD_REQUEST_USAGE:
1144                 {
1145                         VoteCommand_macro_help(caller, argc);
1146                         return;
1147                 }
1148         }
1149 }