2f5f41efd0e5ead00bfcbb24fd1c8cabe56f80ff
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / vote.qc
1 #include "vote.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5
6 #include <common/command/_mod.qh>
7 #include "vote.qh"
8
9 #include "common.qh"
10
11 #include "../g_damage.qh"
12 #include "../g_world.qh"
13 #include "../teamplay.qh"
14 #include "../race.qh"
15 #include "../round_handler.qh"
16 #include "../scores.qh"
17
18 #include <server/mutators/_mod.qh>
19 #include <common/gamemodes/_mod.qh>
20
21 #include <common/constants.qh>
22 #include <common/net_linked.qh>
23 #include <common/mapinfo.qh>
24 #include <common/notifications/all.qh>
25 #include <common/playerstats.qh>
26 #include <common/util.qh>
27
28 // =============================================
29 //  Server side voting code, reworked by Samual
30 //  Last updated: December 27th, 2011
31 // =============================================
32
33 //  Nagger for players to know status of voting
34 bool Nagger_SendEntity(entity this, entity to, float sendflags)
35 {
36         int nags, i, f, b;
37         entity e;
38         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
39
40         // bits:
41         //   1 = ready
42         //   2 = player needs to ready up
43         //   4 = vote
44         //   8 = player needs to vote
45         //  16 = warmup
46         // sendflags:
47         //  64 = vote counts
48         // 128 = vote string
49
50         nags = 0;
51         if (readycount)
52         {
53                 nags |= BIT(0);
54                 if (to.ready == 0) nags |= BIT(1);
55         }
56         if (vote_called)
57         {
58                 nags |= BIT(2);
59                 if (to.vote_selection == 0) nags |= BIT(3);
60         }
61         if (warmup_stage) nags |= BIT(4);
62
63         if (sendflags & BIT(6)) nags |= BIT(6);
64
65         if (sendflags & BIT(7)) nags |= BIT(7);
66
67         if (!(nags & 4))  // no vote called? send no string
68                 nags &= ~(BIT(6) | BIT(7));
69
70         WriteByte(MSG_ENTITY, nags);
71
72         if (nags & BIT(6))
73         {
74                 WriteByte(MSG_ENTITY, vote_accept_count);
75                 WriteByte(MSG_ENTITY, vote_reject_count);
76                 WriteByte(MSG_ENTITY, vote_needed_overall);
77                 WriteChar(MSG_ENTITY, to.vote_selection);
78         }
79
80         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
81
82         if (nags & 1)
83         {
84                 for (i = 1; i <= maxclients; i += 8)
85                 {
86                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
87                                 if (!IS_REAL_CLIENT(e) || e.ready)
88                                         f |= b;
89                         WriteByte(MSG_ENTITY, f);
90                 }
91         }
92
93         return true;
94 }
95
96 void Nagger_Init()
97 {
98         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
99 }
100
101 void Nagger_VoteChanged()
102 {
103         if (nagger) nagger.SendFlags |= BIT(7);
104 }
105
106 void Nagger_VoteCountChanged()
107 {
108         if (nagger) nagger.SendFlags |= BIT(6);
109 }
110
111 void Nagger_ReadyCounted()
112 {
113         if (nagger) nagger.SendFlags |= BIT(0);
114 }
115
116 // If the vote_caller is still here, return their name, otherwise vote_caller_name
117 string OriginalCallerName()
118 {
119         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller, false);
120         return vote_caller_name;
121 }
122
123 // =======================
124 //  Game logic for voting
125 // =======================
126
127 void VoteReset()
128 {
129         FOREACH_CLIENT(true, { it.vote_selection = 0; });
130
131         if (vote_called)
132         {
133                 strfree(vote_called_command);
134                 strfree(vote_called_display);
135                 strfree(vote_caller_name);
136         }
137
138         vote_called = VOTE_NULL;
139         vote_caller = NULL;
140         vote_endtime = 0;
141
142         vote_parsed_command = string_null;
143         vote_parsed_display = string_null;
144
145         Nagger_VoteChanged();
146 }
147
148 void VoteStop(entity stopper)
149 {
150         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
151         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
152         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
153         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
154         VoteReset();
155 }
156
157 void VoteAccept()
158 {
159         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
160
161         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
162         else localcmd(strcat(vote_called_command, "\n"));
163
164         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
165
166         VoteReset();
167         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
168 }
169
170 void VoteReject()
171 {
172         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
173         VoteReset();
174         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
175 }
176
177 void VoteTimeout()
178 {
179         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
180         VoteReset();
181         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
182 }
183
184 void VoteSpam(float notvoters, float mincount, string result)
185 {
186         bprint(strcat(
187                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
188                 strcat("^2:^1", ftos(vote_reject_count)),
189                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
190                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
191                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
192
193         if (autocvar_sv_eventlog)
194         {
195                 GameLogEcho(strcat(
196                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
197                         strcat(":", ftos(vote_reject_count)),
198                         strcat(":", ftos(vote_abstain_count)),
199                         strcat(":", ftos(notvoters)),
200                         strcat(":", ftos(mincount))));
201         }
202 }
203
204 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
205
206 void VoteCount(float first_count)
207 {
208         // declarations
209         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
210
211         float vote_player_count = 0, notvoters = 0;
212         float vote_real_player_count = 0, vote_real_accept_count = 0;
213         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
214         float vote_needed_of_voted, final_needed_votes;
215         float vote_factor_overall, vote_factor_of_voted;
216
217         Nagger_VoteCountChanged();
218
219         // add up all the votes from each connected client
220         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
221                 ++vote_player_count;
222                 if (IS_PLAYER(it))   ++vote_real_player_count;
223                 switch (it.vote_selection)
224                 {
225                         case VOTE_SELECT_REJECT:
226                         { ++vote_reject_count;
227                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
228                         }
229                         case VOTE_SELECT_ACCEPT:
230                         { ++vote_accept_count;
231                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
232                         }
233                         case VOTE_SELECT_ABSTAIN:
234                         { ++vote_abstain_count;
235                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
236                         }
237                         default: break;
238                 }
239         });
240
241         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
242         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
243         {
244                 if (vote_caller)   vote_caller.vote_waittime = 0;
245                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
246                 VoteReset();
247                 return;
248         }
249
250         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
251         if (!spectators_allowed && (vote_real_player_count > 0))
252         {
253                 vote_accept_count = vote_real_accept_count;
254                 vote_reject_count = vote_real_reject_count;
255                 vote_abstain_count = vote_real_abstain_count;
256                 vote_player_count = vote_real_player_count;
257         }
258
259         // people who have no opinion in any way :D
260         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
261
262         // determine the goal for the vote to be passed or rejected normally
263         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
264         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
265
266         // if the vote times out, determine the amount of votes needed of the people who actually already voted
267         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
268         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
269
270         // are there any players at all on the server? it could be an admin vote
271         if (vote_player_count == 0 && first_count)
272         {
273                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
274                 VoteAccept();
275                 return;
276         }
277
278         // since there ARE players, finally calculate the result of the vote
279         if (vote_accept_count >= vote_needed_overall)
280         {
281                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
282                 VoteAccept();
283                 return;
284         }
285
286         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
287         {
288                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
289                 VoteReject();
290                 return;
291         }
292
293         // there is not enough votes in either direction, now lets just calculate what the voters have said
294         if (time > vote_endtime)
295         {
296                 final_needed_votes = vote_needed_overall;
297
298                 if (autocvar_sv_vote_majority_factor_of_voted)
299                 {
300                         if (vote_accept_count >= vote_needed_of_voted)
301                         {
302                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
303                                 VoteAccept();
304                                 return;
305                         }
306
307                         if (vote_accept_count + vote_reject_count > 0)
308                         {
309                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
310                                 VoteReject();
311                                 return;
312                         }
313
314                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
315                 }
316
317                 // it didn't pass or fail, so not enough votes to even make a decision.
318                 VoteSpam(notvoters, final_needed_votes, "timeout");
319                 VoteTimeout();
320         }
321 }
322
323 void VoteThink()
324 {
325         if (vote_endtime > 0)        // a vote was called
326         {
327                 if (time > vote_endtime) // time is up
328                         VoteCount(false);
329         }
330 }
331
332
333 // =======================
334 //  Game logic for warmup
335 // =======================
336
337 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
338 void reset_map(bool dorespawn)
339 {
340         if (time <= game_starttime)
341         {
342                 if (game_stopped)
343                         return;
344                 if (round_handler_IsActive())
345                         round_handler_Reset(game_starttime);
346         }
347
348         if (shuffleteams_on_reset_map)
349         {
350                 shuffleteams();
351                 shuffleteams_on_reset_map = false;
352         }
353         MUTATOR_CALLHOOK(reset_map_global);
354
355         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
356         {
357                 if(IS_CLIENT(it))
358                         continue;
359                 if (it.reset)
360                 {
361                         it.reset(it);
362                         continue;
363                 }
364                 if (it.team_saved) it.team = it.team_saved;
365                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
366         });
367
368         // Waypoints and assault start come LAST
369         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
370                 if (it.reset2) it.reset2(it);
371         });
372
373         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it, false); });
374
375         // Moving the player reset code here since the player-reset depends
376         // on spawnpoint entities which have to be reset first --blub
377         if (dorespawn)
378         {
379                 if (!MUTATOR_CALLHOOK(reset_map_players))
380                 {
381                         if (restart_mapalreadyrestarted || (time < game_starttime))
382                         {
383                                 FOREACH_CLIENT(IS_PLAYER(it),
384                                 {
385                                         /*
386                                         only reset players if a restart countdown is active
387                                         this can either be due to cvar sv_ready_restart_after_countdown having set
388                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
389                                         sv_ready_restart_after_countdown is not used and countdown is still running
390                                         */
391                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
392                                         // PlayerScore_Clear(it);
393                                         CS(it).killcount = 0;
394                                         // stop the player from moving so that he stands still once he gets respawned
395                                         it.velocity = '0 0 0';
396                                         it.avelocity = '0 0 0';
397                                         CS(it).movement = '0 0 0';
398                                         PutClientInServer(it);
399                                 });
400                         }
401                 }
402         }
403 }
404
405 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
406 void ReadyRestart_think(entity this)
407 {
408         restart_mapalreadyrestarted = true;
409         reset_map(true);
410         Score_ClearAll();
411         delete(this);
412 }
413
414 // Forces a restart of the game without actually reloading the map // this is a mess...
415 void ReadyRestart_force()
416 {
417         if (time <= game_starttime && game_stopped)
418                 return;
419
420         bprint("^1Server is restarting...\n");
421
422         VoteReset();
423
424         // clear overtime, we have to decrease timelimit to its original value again.
425         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
426                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
427         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
428
429         readyrestart_happened = true;
430         game_starttime = time + RESTART_COUNTDOWN;
431
432         // clear player attributes
433         FOREACH_CLIENT(IS_PLAYER(it), {
434                 it.alivetime = 0;
435                 CS(it).killcount = 0;
436                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
437                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
438         });
439
440         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
441
442         // disable the warmup global for the server
443         if(warmup_stage)
444                 localcmd("\nsv_hook_warmupend\n");
445         warmup_stage = 0;                // once the game is restarted the game is in match stage
446
447         // reset the .ready status of all players (also spectators)
448         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
449         readycount = 0;
450         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
451
452         // lock teams with lockonrestart
453         if (autocvar_teamplay_lockonrestart && teamplay)
454         {
455                 lockteams = true;
456                 bprint("^1The teams are now locked.\n");
457         }
458
459         // initiate the restart-countdown-announcer entity
460         if (sv_ready_restart_after_countdown)
461         {
462                 entity restart_timer = new_pure(restart_timer);
463                 setthink(restart_timer, ReadyRestart_think);
464                 restart_timer.nextthink = game_starttime;
465         }
466
467         // after a restart every players number of allowed timeouts gets reset, too
468         if (autocvar_sv_timeout)
469         {
470                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
471         }
472
473         if (!sv_ready_restart_after_countdown) reset_map(true);
474         if (autocvar_sv_eventlog) GameLogEcho(":restart");
475 }
476
477 void ReadyRestart()
478 {
479         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
480         else localcmd("\nsv_hook_readyrestart\n");
481
482         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
483         // Otherwise scores could be manipulated during the countdown.
484         if (!sv_ready_restart_after_countdown) Score_ClearAll();
485         ReadyRestart_force();
486 }
487
488 // Count the players who are ready and determine whether or not to restart the match
489 void ReadyCount()
490 {
491         float ready_needed_factor, ready_needed_count;
492         float t_ready = 0, t_players = 0;
493
494         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
495                 ++t_players;
496                 if (it.ready) ++t_ready;
497         });
498
499         readycount = t_ready;
500
501         Nagger_ReadyCounted();
502
503         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
504         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
505
506         if (readycount >= ready_needed_count) ReadyRestart();
507 }
508
509
510 // ======================================
511 //  Supporting functions for VoteCommand
512 // ======================================
513
514 float Votecommand_check_assignment(entity caller, float assignment)
515 {
516         float from_server = (!caller);
517
518         if ((assignment == VC_ASGNMNT_BOTH)
519             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
520             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
521
522         return false;
523 }
524
525 string VoteCommand_extractcommand(string input, float startpos, int argc)
526 {
527         string output;
528
529         if ((argc - 1) < startpos) output = "";
530         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
531
532         return output;
533 }
534
535 float VoteCommand_checknasty(string vote_command)
536 {
537         if ((strstrofs(vote_command, ";", 0) >= 0)
538             || (strstrofs(vote_command, "\n", 0) >= 0)
539             || (strstrofs(vote_command, "\r", 0) >= 0)
540             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
541
542         return true;
543 }
544
545 // NOTE: requires input to be surrounded by spaces
546 string VoteCommand_checkreplacements(string input)
547 {
548         string output = input;
549         // allow gotomap replacements
550         output = strreplace(" map ", " gotomap ", output);
551         output = strreplace(" chmap ", " gotomap ", output);
552         return output;
553 }
554
555 float VoteCommand_checkinlist(string vote_command, string list)
556 {
557         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
558
559         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
560
561         return false;
562 }
563
564 string ValidateMap(string validated_map, entity caller)
565 {
566         validated_map = MapInfo_FixName(validated_map);
567
568         if (!validated_map)
569         {
570                 print_to(caller, "This map is not available on this server.");
571                 return string_null;
572         }
573
574         if (!autocvar_sv_vote_override_mostrecent && caller)
575         {
576                 if (Map_IsRecent(validated_map))
577                 {
578                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
579                         return string_null;
580                 }
581         }
582
583         if (!MapInfo_CheckMap(validated_map))
584         {
585                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
586                 return string_null;
587         }
588
589         return validated_map;
590 }
591
592 float VoteCommand_checkargs(float startpos, int argc)
593 {
594         float p, q, check, minargs;
595         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
596         string cmdrestriction = "";  // No we don't.
597         string charlist, arg;
598         float checkmate;
599
600         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
601                 cmdrestriction = cvar_string(cvarname);
602         else
603                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
604
605         if (cmdrestriction == "") return true;
606
607         ++startpos;  // skip command name
608
609         // check minimum arg count
610
611         // 0 args: argc == startpos
612         // 1 args: argc == startpos + 1
613         // ...
614
615         minargs = stof(cmdrestriction);
616         if (argc - startpos < minargs) return false;
617
618         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
619
620         for ( ; ; )
621         {
622                 // we know that at any time, startpos <= argc - minargs
623                 // so this means: argc-minargs >= startpos >= argc, thus
624                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
625                 // have been seen already
626
627                 if (startpos >= argc) // all args checked? GOOD
628                         break;
629
630                 if (p < 0)            // no more args? FAIL
631                 {
632                         // exception: exactly minargs left, this one included
633                         if (argc - startpos == minargs) break;
634
635                         // otherwise fail
636                         return false;
637                 }
638
639                 // cut to next semicolon
640                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
641                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
642                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
643
644                 // in case we ever want to allow semicolons in VoteCommand_checknasty
645                 // charlist = strreplace("^^", ";", charlist);
646
647                 if (charlist != "")
648                 {
649                         // verify the arg only contains allowed chars
650                         arg = argv(startpos);
651                         checkmate = strlen(arg);
652                         for (check = 0; check < checkmate; ++check)
653                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
654                         // not allowed character
655                         // all characters are allowed. FINE.
656                 }
657
658                 ++startpos;
659                 --minargs;
660                 p = q;
661         }
662
663         return true;
664 }
665
666 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
667 {
668         string first_command = argv(startpos);
669         int missing_chars = argv_start_index(startpos);
670
671         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
672                 return 0;
673
674         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
675
676         if (!VoteCommand_checkargs(startpos, argc)) return 0;
677
678         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
679         {
680                 case MUT_VOTEPARSE_CONTINUE: { break; }
681                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
682                 case MUT_VOTEPARSE_INVALID: { return -1; }
683                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
684         }
685
686         switch (first_command) // now go through and parse the proper commands to adjust as needed.
687         {
688                 case "kick":
689                 case "kickban":    // catch all kick/kickban commands
690                 {
691                         entity victim = GetIndexedEntity(argc, (startpos + 1));
692                         float accepted = VerifyClientEntity(victim, true, false);
693
694                         if (accepted > 0)
695                         {
696                                 string reason = "No reason provided";
697                                 if(argc > next_token)
698                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
699
700                                 string command_arguments = reason;
701                                 if (first_command == "kickban")
702                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
703
704                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
705                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
706                         }
707                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
708
709                         break;
710                 }
711
712                 case "map":
713                 case "chmap":
714                 case "gotomap":  // re-direct all map selection commands to gotomap
715                 {
716                         vote_command = ValidateMap(argv(startpos + 1), caller);
717                         if (!vote_command)  return -1;
718                         vote_parsed_command = strcat("gotomap ", vote_command);
719                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
720
721                         break;
722                 }
723
724                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
725                 // maybe fallback instead of aborting if map name is invalid?
726                 case "nextmap":
727                 {
728                         vote_command = ValidateMap(argv(startpos + 1), caller);
729                         if (!vote_command)  return -1;
730                         vote_parsed_command = strcat("nextmap ", vote_command);
731                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
732
733                         break;
734                 }
735
736                 case "timelimit": // include restrictions on the maximum votable time limit
737                 {
738                         float timelimit_vote = stof(argv(startpos + 1));
739                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
740                         {
741                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
742                                 return -1;
743                         }
744                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
745                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
746                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
747
748                         break;
749                 }
750
751                 case "restart":
752                 {
753                         // add a delay so that vote result can be seen and announcer can be heard
754                         // if the vote is accepted
755                         vote_parsed_command = strcat("defer 1 ", vote_command);
756                         vote_parsed_display = strzone(strcat("^1", vote_command));
757
758                         break;
759                 }
760
761                 default:
762                 {
763                         vote_parsed_command = vote_command;
764                         vote_parsed_display = strzone(strcat("^1", vote_command));
765
766                         break;
767                 }
768         }
769
770         return 1;
771 }
772
773
774 // =======================
775 //  Command Sub-Functions
776 // =======================
777
778 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
779 {
780         switch (request)
781         {
782                 case CMD_REQUEST_COMMAND:
783                 {
784                         if (!vote_called) { print_to(caller, "^1No vote called."); }
785                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
786                         {
787                                 print_to(caller, "^1You have already voted.");
788                         }
789
790                         else  // everything went okay, continue changing vote
791                         {
792                                 print_to(caller, "^1You abstained from your vote.");
793                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
794                                 msg_entity = caller;
795                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
796
797                         return;
798                 }
799
800                 default:
801                 case CMD_REQUEST_USAGE:
802                 {
803                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
804                         print_to(caller, "  No arguments required.");
805                         return;
806                 }
807         }
808 }
809
810 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
811 {
812         switch (request)
813         {
814                 case CMD_REQUEST_COMMAND:
815                 {
816                         float tmp_playercount = 0;
817                         int parse_error;
818
819                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
820
821                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
822                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
823                         {
824                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
825                         }
826                         else if (vote_called)
827                         {
828                                 print_to(caller, "^1There is already a vote called.");
829                         }
830                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
831                         {
832                                 print_to(caller, "^1Only players can call a vote.");
833                         }
834                         else if (caller && !IS_CLIENT(caller))
835                         {
836                                 print_to(caller, "^1Only connected clients can vote.");
837                         }
838                         else if (timeout_status && vote_command != "timein")
839                         {
840                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
841                         }
842                         else if (caller && (time < caller.vote_waittime))
843                         {
844                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
845                         }
846                         else if (!VoteCommand_checknasty(vote_command))
847                         {
848                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
849                         }
850                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
851                         {
852                                 if(parse_error == 0)
853                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
854                         }
855                         else  // everything went okay, continue with calling the vote
856                         {
857                                 vote_caller = caller;  // remember who called the vote
858                                 vote_caller_name = strzone(GetCallerName(vote_caller));
859                                 vote_called = VOTE_NORMAL;
860                                 vote_called_command = strzone(vote_parsed_command);
861                                 vote_called_display = strzone(vote_parsed_display);
862                                 vote_endtime = time + autocvar_sv_vote_timeout;
863
864                                 if (caller)
865                                 {
866                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
867                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
868                                         msg_entity = caller;
869                                 }
870
871                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
872
873                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
874                                 if (autocvar_sv_eventlog)
875                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
876                                 Nagger_VoteChanged();
877                                 VoteCount(true);  // needed if you are the only one
878
879                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
880                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
881                         }
882
883                         return;
884                 }
885
886                 default:
887                 case CMD_REQUEST_USAGE:
888                 {
889                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
890                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
891                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
892                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
893                         return;
894                 }
895         }
896 }
897
898 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
899 {
900         switch (request)
901         {
902                 case CMD_REQUEST_COMMAND:
903                 {
904                         if (autocvar_sv_vote_master)
905                         {
906                                 switch (strtolower(argv(2)))
907                                 {
908                                         case "do":
909                                         {
910                                                 int parse_error;
911                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
912
913                                                 if (!caller.vote_master)
914                                                         print_to(caller, "^1You do not have vote master privileges.");
915                                                 else if (!VoteCommand_checknasty(vote_command))
916                                                 {
917                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
918                                                 }
919                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
920                                                 {
921                                                         if(parse_error == 0)
922                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
923                                                 }
924                                                 else  // everything went okay, proceed with command
925                                                 {
926                                                         localcmd(strcat(vote_parsed_command, "\n"));
927                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
928                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
929                                                         if (autocvar_sv_eventlog)
930                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
931                                                 }
932
933                                                 return;
934                                         }
935
936                                         case "login":
937                                         {
938                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
939                                                 else if (caller.vote_master)
940                                                 {
941                                                         print_to(caller, "^1You are already logged in as vote master.");
942                                                 }
943                                                 else if (autocvar_sv_vote_master_password != argv(3))
944                                                 {
945                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
946                                                 }
947                                                 else  // everything went okay, proceed with giving this player master privilages
948                                                 {
949                                                         caller.vote_master = true;
950                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
951                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
952                                                         if (autocvar_sv_eventlog)
953                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
954                                                 }
955
956                                                 return;
957                                         }
958
959                                         default:  // calling a vote for master
960                                         {
961                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
962                                                 else if (vote_called)
963                                                 {
964                                                         print_to(caller, "^1There is already a vote called.");
965                                                 }
966                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
967                                                 {
968                                                         print_to(caller, "^1Only players can call a vote.");
969                                                 }
970                                                 else if (timeout_status)
971                                                 {
972                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
973                                                 }
974                                                 else  // everything went okay, continue with creating vote
975                                                 {
976                                                         vote_caller = caller;
977                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
978                                                         vote_called = VOTE_MASTER;
979                                                         vote_called_command = strzone("XXX");
980                                                         vote_called_display = strzone("^3master");
981                                                         vote_endtime = time + autocvar_sv_vote_timeout;
982
983                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
984                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
985
986                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
987                                                         if (autocvar_sv_eventlog)
988                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
989                                                         Nagger_VoteChanged();
990                                                         VoteCount(true);  // needed if you are the only one
991                                                 }
992
993                                                 return;
994                                         }
995                                 }
996                         }
997                         else { print_to(caller, "^1Master control of voting is not allowed."); }
998
999                         return;
1000                 }
1001
1002                 default:
1003                 case CMD_REQUEST_USAGE:
1004                 {
1005                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
1006                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
1007                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
1008                         return;
1009                 }
1010         }
1011 }
1012
1013 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1014 {
1015         switch (request)
1016         {
1017                 case CMD_REQUEST_COMMAND:
1018                 {
1019                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1020                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1021                         {
1022                                 print_to(caller, "^1You have already voted.");
1023                         }
1024                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1025                         {
1026                                 VoteStop(caller);
1027                         }
1028
1029                         else  // everything went okay, continue changing vote
1030                         {
1031                                 print_to(caller, "^1You rejected the vote.");
1032                                 caller.vote_selection = VOTE_SELECT_REJECT;
1033                                 msg_entity = caller;
1034                                 if (!autocvar_sv_vote_singlecount)
1035                                         VoteCount(false);
1036                         }
1037
1038                         return;
1039                 }
1040
1041                 default:
1042                 case CMD_REQUEST_USAGE:
1043                 {
1044                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1045                         print_to(caller, "  No arguments required.");
1046                         return;
1047                 }
1048         }
1049 }
1050
1051 void VoteCommand_status(int request, entity caller)  // BOTH
1052 {
1053         switch (request)
1054         {
1055                 case CMD_REQUEST_COMMAND:
1056                 {
1057                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1058                         else print_to(caller, "^1No vote called.");
1059
1060                         return;
1061                 }
1062
1063                 default:
1064                 case CMD_REQUEST_USAGE:
1065                 {
1066                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1067                         print_to(caller, "  No arguments required.");
1068                         return;
1069                 }
1070         }
1071 }
1072
1073 void VoteCommand_stop(int request, entity caller)  // BOTH
1074 {
1075         switch (request)
1076         {
1077                 case CMD_REQUEST_COMMAND:
1078                 {
1079                         if (!vote_called)   print_to(caller, "^1No vote called.");
1080                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1081                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1082                         return;
1083                 }
1084
1085                 default:
1086                 case CMD_REQUEST_USAGE:
1087                 {
1088                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1089                         print_to(caller, "  No arguments required.");
1090                         return;
1091                 }
1092         }
1093 }
1094
1095 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1096 {
1097         switch (request)
1098         {
1099                 case CMD_REQUEST_COMMAND:
1100                 {
1101                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1102                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1103                         {
1104                                 print_to(caller, "^1You have already voted.");
1105                         }
1106                         else  // everything went okay, continue changing vote
1107                         {
1108                                 print_to(caller, "^1You accepted the vote.");
1109                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1110                                 msg_entity = caller;
1111                                 if (!autocvar_sv_vote_singlecount)
1112                                         VoteCount(false);
1113                         }
1114
1115                         return;
1116                 }
1117
1118                 default:
1119                 case CMD_REQUEST_USAGE:
1120                 {
1121                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1122                         print_to(caller, "  No arguments required.");
1123                         return;
1124                 }
1125         }
1126 }
1127
1128 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1129 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1130 void VoteCommand_(int request)
1131 {
1132     switch(request)
1133     {
1134         case CMD_REQUEST_COMMAND:
1135         {
1136
1137             return;
1138         }
1139
1140         default:
1141         case CMD_REQUEST_USAGE:
1142         {
1143             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1144             print_to(caller, "  No arguments required.");
1145             return;
1146         }
1147     }
1148 }
1149 */
1150
1151
1152 // ================================
1153 //  Macro system for vote commands
1154 // ================================
1155
1156 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1157 #define VOTE_COMMANDS(request, caller, arguments, command) \
1158         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1159         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1160         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1161         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1162         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1163         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1164         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1165         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1166         /* nothing */
1167
1168 void VoteCommand_macro_help(entity caller, int argc)
1169 {
1170         string command_origin = GetCommandPrefix(caller);
1171
1172         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1173         {
1174                 print_to(caller, "\nVoting commands:\n");
1175                 #define VOTE_COMMAND(name, function, description, assignment) \
1176                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1177
1178                 VOTE_COMMANDS(0, caller, 0, "");
1179 #undef VOTE_COMMAND
1180
1181                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1182                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1183                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1184         }
1185         else  // usage for individual command
1186         {
1187                 #define VOTE_COMMAND(name, function, description, assignment) \
1188                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1189
1190                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1191 #undef VOTE_COMMAND
1192
1193                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1194                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1195                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1196                 else
1197                         print_to(caller, "No documentation exists for this vote");
1198         }
1199 }
1200
1201 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1202 {
1203         #define VOTE_COMMAND(name, function, description, assignment) \
1204                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1205
1206         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1207 #undef VOTE_COMMAND
1208
1209         return false;
1210 }
1211
1212
1213 // ======================================
1214 //  Main function handling vote commands
1215 // ======================================
1216
1217 void VoteCommand(int request, entity caller, int argc, string vote_command)
1218 {
1219         // Guide for working with argc arguments by example:
1220         // argc:   1    - 2      - 3     - 4
1221         // argv:   0    - 1      - 2     - 3
1222         // cmd     vote - master - login - password
1223
1224         switch (request)
1225         {
1226                 case CMD_REQUEST_COMMAND:
1227                 {
1228                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1229                 }
1230
1231                 default:
1232                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1233                 case CMD_REQUEST_USAGE:
1234                 {
1235                         VoteCommand_macro_help(caller, argc);
1236                         return;
1237                 }
1238         }
1239 }