qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2 #include <common/command/command.qh>
   3 #include "vote.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/all.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/mapinfo.qh>
  17 #include <common/notifications/all.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/util.qh>
  20
  21 // =============================================
  22 //  Server side voting code, reworked by Samual
  23 //  Last updated: December 27th, 2011
  24 // =============================================
  25
  26 //  Nagger for players to know status of voting
  27 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  28 {
  29         int nags, i, f, b;
  30         entity e;
  31         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  32
  33         // bits:
  34         //   1 = ready
  35         //   2 = player needs to ready up
  36         //   4 = vote
  37         //   8 = player needs to vote
  38         //  16 = warmup
  39         // sendflags:
  40         //  64 = vote counts
  41         // 128 = vote string
  42
  43         nags = 0;
  44         if (readycount)
  45         {
  46                 nags |= BIT(0);
  47                 if (to.ready == 0) nags |= BIT(1);
  48         }
  49         if (vote_called)
  50         {
  51                 nags |= BIT(2);
  52                 if (to.vote_selection == 0) nags |= BIT(3);
  53         }
  54         if (warmup_stage) nags |= BIT(4);
  55
  56         if (sendflags & BIT(6)) nags |= BIT(6);
  57
  58         if (sendflags & BIT(7)) nags |= BIT(7);
  59
  60         if (!(nags & 4))  // no vote called? send no string
  61                 nags &= ~(BIT(6) | BIT(7));
  62
  63         WriteByte(MSG_ENTITY, nags);
  64
  65         if (nags & BIT(6))
  66         {
  67                 WriteByte(MSG_ENTITY, vote_accept_count);
  68                 WriteByte(MSG_ENTITY, vote_reject_count);
  69                 WriteByte(MSG_ENTITY, vote_needed_overall);
  70                 WriteChar(MSG_ENTITY, to.vote_selection);
  71         }
  72
  73         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  74
  75         if (nags & 1)
  76         {
  77                 for (i = 1; i <= maxclients; i += 8)
  78                 {
  79                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  80                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  81                         WriteByte(MSG_ENTITY, f);
  82                 }
  83         }
  84
  85         return true;
  86 }
  87
  88 void Nagger_Init()
  89 {
  90         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  91 }
  92
  93 void Nagger_VoteChanged()
  94 {
  95         if (nagger) nagger.SendFlags |= BIT(7);
  96 }
  97
  98 void Nagger_VoteCountChanged()
  99 {
 100         if (nagger) nagger.SendFlags |= BIT(6);
 101 }
 102
 103 void Nagger_ReadyCounted()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(0);
 106 }
 107
 108 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 109 string OriginalCallerName()
 110 {
 111         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 112         return vote_caller_name;
 113 }
 114
 115 // =======================
 116 //  Game logic for voting
 117 // =======================
 118
 119 void VoteReset()
 120 {
 121         FOREACH_CLIENT(true, LAMBDA(it.vote_selection = 0));
 122
 123         if (vote_called)
 124         {
 125                 strunzone(vote_called_command);
 126                 strunzone(vote_called_display);
 127                 strunzone(vote_caller_name);
 128         }
 129
 130         vote_called = VOTE_NULL;
 131         vote_caller = NULL;
 132         vote_caller_name = string_null;
 133         vote_endtime = 0;
 134
 135         vote_called_command = string_null;
 136         vote_called_display = string_null;
 137
 138         vote_parsed_command = string_null;
 139         vote_parsed_display = string_null;
 140
 141         Nagger_VoteChanged();
 142 }
 143
 144 void VoteStop(entity stopper)
 145 {
 146         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 147         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 148         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 149         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 150         VoteReset();
 151 }
 152
 153 void VoteAccept()
 154 {
 155         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 156
 157         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 158         else localcmd(strcat(vote_called_command, "\n"));
 159
 160         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 161
 162         VoteReset();
 163         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 164 }
 165
 166 void VoteReject()
 167 {
 168         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 169         VoteReset();
 170         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 171 }
 172
 173 void VoteTimeout()
 174 {
 175         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 176         VoteReset();
 177         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 178 }
 179
 180 void VoteSpam(float notvoters, float mincount, string result)
 181 {
 182         bprint(strcat(
 183                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 184                 strcat("^2:^1", ftos(vote_reject_count)),
 185                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 186                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 187                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 188
 189         if (autocvar_sv_eventlog)
 190         {
 191                 GameLogEcho(strcat(
 192                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 193                         strcat(":", ftos(vote_reject_count)),
 194                         strcat(":", ftos(vote_abstain_count)),
 195                         strcat(":", ftos(notvoters)),
 196                         strcat(":", ftos(mincount))));
 197         }
 198 }
 199
 200 void VoteCount(float first_count)
 201 {
 202         // declarations
 203         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 204
 205         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 206
 207         float vote_player_count = 0, notvoters = 0;
 208         float vote_real_player_count = 0, vote_real_accept_count = 0;
 209         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 210         float vote_needed_of_voted, final_needed_votes;
 211         float vote_factor_overall, vote_factor_of_voted;
 212
 213         Nagger_VoteCountChanged();
 214
 215         // add up all the votes from each connected client
 216         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), LAMBDA(
 217                 ++vote_player_count;
 218                 if (IS_PLAYER(it))   ++vote_real_player_count;
 219                 switch (it.vote_selection)
 220                 {
 221                         case VOTE_SELECT_REJECT:
 222                         { ++vote_reject_count;
 223                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 224                         }
 225                         case VOTE_SELECT_ACCEPT:
 226                         { ++vote_accept_count;
 227                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 228                         }
 229                         case VOTE_SELECT_ABSTAIN:
 230                         { ++vote_abstain_count;
 231                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 232                         }
 233                         default: break;
 234                 }
 235         ));
 236
 237         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 238         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 239         {
 240                 if (vote_caller)   vote_caller.vote_waittime = 0;
 241                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 242                 VoteReset();
 243                 return;
 244         }
 245
 246         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 247         if (!spectators_allowed && (vote_real_player_count > 0))
 248         {
 249                 vote_accept_count = vote_real_accept_count;
 250                 vote_reject_count = vote_real_reject_count;
 251                 vote_abstain_count = vote_real_abstain_count;
 252                 vote_player_count = vote_real_player_count;
 253         }
 254
 255         // people who have no opinion in any way :D
 256         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 257
 258         // determine the goal for the vote to be passed or rejected normally
 259         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 260         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 261
 262         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 263         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 264         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 265
 266         // are there any players at all on the server? it could be an admin vote
 267         if (vote_player_count == 0 && first_count)
 268         {
 269                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 270                 VoteAccept();
 271                 return;
 272         }
 273
 274         // since there ARE players, finally calculate the result of the vote
 275         if (vote_accept_count >= vote_needed_overall)
 276         {
 277                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 278                 VoteAccept();
 279                 return;
 280         }
 281
 282         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 283         {
 284                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 285                 VoteReject();
 286                 return;
 287         }
 288
 289         // there is not enough votes in either direction, now lets just calculate what the voters have said
 290         if (time > vote_endtime)
 291         {
 292                 final_needed_votes = vote_needed_overall;
 293
 294                 if (autocvar_sv_vote_majority_factor_of_voted)
 295                 {
 296                         if (vote_accept_count >= vote_needed_of_voted)
 297                         {
 298                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 299                                 VoteAccept();
 300                                 return;
 301                         }
 302
 303                         if (vote_accept_count + vote_reject_count > 0)
 304                         {
 305                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 306                                 VoteReject();
 307                                 return;
 308                         }
 309
 310                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 311                 }
 312
 313                 // it didn't pass or fail, so not enough votes to even make a decision.
 314                 VoteSpam(notvoters, final_needed_votes, "timeout");
 315                 VoteTimeout();
 316         }
 317 }
 318
 319 void VoteThink()
 320 {
 321         if (vote_endtime > 0)        // a vote was called
 322         {
 323                 if (time > vote_endtime) // time is up
 324                         VoteCount(false);
 325         }
 326 }
 327
 328
 329 // =======================
 330 //  Game logic for warmup
 331 // =======================
 332
 333 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 334 void reset_map(bool dorespawn)
 335 {
 336         if (time <= game_starttime && round_handler_IsActive()) round_handler_Reset(game_starttime);
 337
 338         MUTATOR_CALLHOOK(reset_map_global);
 339
 340         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 341                 if (it.reset)
 342                 {
 343                         it.reset(it);
 344                         continue;
 345                 }
 346                 if (it.team_saved) it.team = it.team_saved;
 347                 if (it.flags & FL_PROJECTILE) remove(it);  // remove any projectiles left
 348         });
 349
 350         // Waypoints and assault start come LAST
 351         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 352                 if (it.reset2) it.reset2(it);
 353         });
 354
 355         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), LAMBDA(Unfreeze(it)));
 356
 357         // Moving the player reset code here since the player-reset depends
 358         // on spawnpoint entities which have to be reset first --blub
 359         if (dorespawn)
 360         {
 361                 if (!MUTATOR_CALLHOOK(reset_map_players))
 362                 {
 363                         FOREACH_CLIENT(true, LAMBDA(
 364                                 /*
 365                                 only reset players if a restart countdown is active
 366                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 367                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 368                                 sv_ready_restart_after_countdown is not used and countdown is still running
 369                                 */
 370                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 371                                 {
 372                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 373                                         if (IS_PLAYER(it))
 374                                         {
 375                                                 // PlayerScore_Clear(it);
 376                                                 it.killcount = 0;
 377                                                 // stop the player from moving so that he stands still once he gets respawned
 378                                                 it.velocity = '0 0 0';
 379                                                 it.avelocity = '0 0 0';
 380                                                 it.movement = '0 0 0';
 381                                                 WITHSELF(it, PutClientInServer());
 382                                         }
 383                                 }
 384                         ));
 385                 }
 386         }
 387 }
 388
 389 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 390 void ReadyRestart_think(entity this)
 391 {
 392         restart_mapalreadyrestarted = true;
 393         reset_map(true);
 394         Score_ClearAll();
 395         remove(this);
 396 }
 397
 398 // Forces a restart of the game without actually reloading the map // this is a mess...
 399 void ReadyRestart_force()
 400 {
 401         bprint("^1Server is restarting...\n");
 402
 403         VoteReset();
 404
 405         // clear overtime, we have to decrease timelimit to its original value again.
 406         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 407                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 408         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 409
 410         readyrestart_happened = true;
 411         game_starttime = time + RESTART_COUNTDOWN;
 412
 413         // clear player attributes
 414         FOREACH_CLIENT(true, LAMBDA(
 415                 it.alivetime = 0;
 416                 it.killcount = 0;
 417                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
 418         ));
 419
 420         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 421
 422         // disable the warmup global for the server
 423         warmup_stage = 0;                // once the game is restarted the game is in match stage
 424
 425         // reset the .ready status of all players (also spectators)
 426         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(it.ready = false));
 427         readycount = 0;
 428         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 429
 430         // lock teams with lockonrestart
 431         if (autocvar_teamplay_lockonrestart && teamplay)
 432         {
 433                 lockteams = true;
 434                 bprint("^1The teams are now locked.\n");
 435         }
 436
 437         // initiate the restart-countdown-announcer entity
 438         if (autocvar_sv_ready_restart_after_countdown)
 439         {
 440                 entity restart_timer = new_pure(restart_timer);
 441                 setthink(restart_timer, ReadyRestart_think);
 442                 restart_timer.nextthink = game_starttime;
 443         }
 444
 445         // after a restart every players number of allowed timeouts gets reset, too
 446         if (autocvar_sv_timeout)
 447         {
 448                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(it.allowed_timeouts = autocvar_sv_timeout_number));
 449         }
 450     // reset map immediately if this cvar is not set
 451     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 452         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 453 }
 454
 455 void ReadyRestart()
 456 {
 457         // no assault support yet...
 458         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 459         else localcmd("\nsv_hook_gamerestart\n");
 460
 461         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 462         // Otherwise scores could be manipulated during the countdown.
 463         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 464         ReadyRestart_force();
 465 }
 466
 467 // Count the players who are ready and determine whether or not to restart the match
 468 void ReadyCount()
 469 {
 470         float ready_needed_factor, ready_needed_count;
 471         float t_ready = 0, t_players = 0;
 472
 473         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), LAMBDA(
 474                 ++t_players;
 475                 if (it.ready) ++t_ready;
 476         ));
 477
 478         readycount = t_ready;
 479
 480         Nagger_ReadyCounted();
 481
 482         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 483         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 484
 485         if (readycount >= ready_needed_count) ReadyRestart();
 486 }
 487
 488
 489 // ======================================
 490 //  Supporting functions for VoteCommand
 491 // ======================================
 492
 493 float Votecommand_check_assignment(entity caller, float assignment)
 494 {
 495         float from_server = (!caller);
 496
 497         if ((assignment == VC_ASGNMNT_BOTH)
 498             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 499             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 500
 501         return false;
 502 }
 503
 504 string VoteCommand_extractcommand(string input, float startpos, float argc)
 505 {
 506         string output;
 507
 508         if ((argc - 1) < startpos) output = "";
 509         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 510
 511         return output;
 512 }
 513
 514 float VoteCommand_checknasty(string vote_command)
 515 {
 516         if ((strstrofs(vote_command, ";", 0) >= 0)
 517             || (strstrofs(vote_command, "\n", 0) >= 0)
 518             || (strstrofs(vote_command, "\r", 0) >= 0)
 519             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 520
 521         return true;
 522 }
 523
 524 float VoteCommand_checkinlist(string vote_command, string list)
 525 {
 526         string l = strcat(" ", list, " ");
 527
 528         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 529
 530         return false;
 531 }
 532
 533 string ValidateMap(string validated_map, entity caller)
 534 {
 535         validated_map = MapInfo_FixName(validated_map);
 536
 537         if (!validated_map)
 538         {
 539                 print_to(caller, "This map is not available on this server.");
 540                 return string_null;
 541         }
 542
 543         if (!autocvar_sv_vote_override_mostrecent && caller)
 544         {
 545                 if (Map_IsRecent(validated_map))
 546                 {
 547                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 548                         return string_null;
 549                 }
 550         }
 551
 552         if (!MapInfo_CheckMap(validated_map))
 553         {
 554                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 555                 return string_null;
 556         }
 557
 558         return validated_map;
 559 }
 560
 561 float VoteCommand_checkargs(float startpos, float argc)
 562 {
 563         float p, q, check, minargs;
 564         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 565         string cmdrestriction = "";  // No we don't.
 566         string charlist, arg;
 567         float checkmate;
 568
 569         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 570                 cmdrestriction = cvar_string(cvarname);
 571         else
 572                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.\n");
 573
 574         if (cmdrestriction == "") return true;
 575
 576         ++startpos;  // skip command name
 577
 578         // check minimum arg count
 579
 580         // 0 args: argc == startpos
 581         // 1 args: argc == startpos + 1
 582         // ...
 583
 584         minargs = stof(cmdrestriction);
 585         if (argc - startpos < minargs) return false;
 586
 587         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 588
 589         for ( ; ; )
 590         {
 591                 // we know that at any time, startpos <= argc - minargs
 592                 // so this means: argc-minargs >= startpos >= argc, thus
 593                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 594                 // have been seen already
 595
 596                 if (startpos >= argc) // all args checked? GOOD
 597                         break;
 598
 599                 if (p < 0)            // no more args? FAIL
 600                 {
 601                         // exception: exactly minargs left, this one included
 602                         if (argc - startpos == minargs) break;
 603
 604                         // otherwise fail
 605                         return false;
 606                 }
 607
 608                 // cut to next semicolon
 609                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 610                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 611                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 612
 613                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 614                 // charlist = strreplace("^^", ";", charlist);
 615
 616                 if (charlist != "")
 617                 {
 618                         // verify the arg only contains allowed chars
 619                         arg = argv(startpos);
 620                         checkmate = strlen(arg);
 621                         for (check = 0; check < checkmate; ++check)
 622                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 623                         // not allowed character
 624                         // all characters are allowed. FINE.
 625                 }
 626
 627                 ++startpos;
 628                 --minargs;
 629                 p = q;
 630         }
 631
 632         return true;
 633 }
 634
 635 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 636 {
 637         string first_command;
 638
 639         first_command = argv(startpos);
 640
 641         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 642             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 643             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 644         );*/
 645
 646         if (
 647             (autocvar_sv_vote_limit > 0)
 648             &&
 649             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 650            )   return false;
 651
 652         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 653
 654         if (!VoteCommand_checkargs(startpos, argc)) return false;
 655
 656         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 657         {
 658                 case "kick":
 659                 case "kickban":    // catch all kick/kickban commands
 660                 {
 661                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 662                         float accepted = VerifyClientEntity(victim, true, false);
 663
 664                         if (accepted > 0)
 665                         {
 666                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 667                                 string command_arguments;
 668
 669                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 670                                 else command_arguments = reason;
 671
 672                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 673                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 674                         }
 675                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 676
 677                         break;
 678                 }
 679
 680                 case "map":
 681                 case "chmap":
 682                 case "gotomap":  // re-direct all map selection commands to gotomap
 683                 {
 684                         vote_command = ValidateMap(argv(startpos + 1), caller);
 685                         if (!vote_command)   return false;
 686                         vote_parsed_command = strcat("gotomap ", vote_command);
 687                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 688
 689                         break;
 690                 }
 691
 692                 default:
 693                 {
 694                         vote_parsed_command = vote_command;
 695                         vote_parsed_display = strzone(strcat("^1", vote_command));
 696
 697                         break;
 698                 }
 699         }
 700
 701         return true;
 702 }
 703
 704
 705 // =======================
 706 //  Command Sub-Functions
 707 // =======================
 708
 709 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 710 {
 711         switch (request)
 712         {
 713                 case CMD_REQUEST_COMMAND:
 714                 {
 715                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 716                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 717                         {
 718                                 print_to(caller, "^1You have already voted.");
 719                         }
 720
 721                         else  // everything went okay, continue changing vote
 722                         {
 723                                 print_to(caller, "^1You abstained from your vote.");
 724                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 725                                 msg_entity = caller;
 726                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 727
 728                         return;
 729                 }
 730
 731                 default:
 732                 case CMD_REQUEST_USAGE:
 733                 {
 734                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 735                         print_to(caller, "  No arguments required.");
 736                         return;
 737                 }
 738         }
 739 }
 740
 741 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 742 {
 743         switch (request)
 744         {
 745                 case CMD_REQUEST_COMMAND:
 746                 {
 747                         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 748
 749                         float tmp_playercount = 0;
 750
 751                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 752
 753                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 754                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 755                         {
 756                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 757                         }
 758                         else if (vote_called)
 759                         {
 760                                 print_to(caller, "^1There is already a vote called.");
 761                         }
 762                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 763                         {
 764                                 print_to(caller, "^1Only players can call a vote.");
 765                         }
 766                         else if (caller && !IS_CLIENT(caller))
 767                         {
 768                                 print_to(caller, "^1Only connected clients can vote.");
 769                         }
 770                         else if (timeout_status)
 771                         {
 772                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 773                         }
 774                         else if (caller && (time < caller.vote_waittime))
 775                         {
 776                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 777                         }
 778                         else if (!VoteCommand_checknasty(vote_command))
 779                         {
 780                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 781                         }
 782                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 783                         {
 784                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 785                         }
 786
 787                         else  // everything went okay, continue with calling the vote
 788                         {
 789                                 vote_caller = caller;  // remember who called the vote
 790                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 791                                 vote_called = VOTE_NORMAL;
 792                                 vote_called_command = strzone(vote_parsed_command);
 793                                 vote_called_display = strzone(vote_parsed_display);
 794                                 vote_endtime = time + autocvar_sv_vote_timeout;
 795
 796                                 if (caller)
 797                                 {
 798                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 799                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 800                                         msg_entity = caller;
 801                                 }
 802
 803                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(++tmp_playercount));
 804                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 805
 806                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 807                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 808                                 Nagger_VoteChanged();
 809                                 VoteCount(true);  // needed if you are the only one
 810                         }
 811
 812                         return;
 813                 }
 814
 815                 default:
 816                 case CMD_REQUEST_USAGE:
 817                 {
 818                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 819                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 820                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 821                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 822                         return;
 823                 }
 824         }
 825 }
 826
 827 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 828 {
 829         switch (request)
 830         {
 831                 case CMD_REQUEST_COMMAND:
 832                 {
 833                         if (autocvar_sv_vote_master)
 834                         {
 835                                 switch (strtolower(argv(2)))
 836                                 {
 837                                         case "do":
 838                                         {
 839                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 840
 841                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 842                                                 else if (!VoteCommand_checknasty(vote_command))
 843                                                 {
 844                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 845                                                 }
 846                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 847                                                 {
 848                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 849                                                 }
 850
 851                                                 else  // everything went okay, proceed with command
 852                                                 {
 853                                                         localcmd(strcat(vote_parsed_command, "\n"));
 854                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 855                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 856                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 857
 858                                                 return;
 859                                         }
 860
 861                                         case "login":
 862                                         {
 863                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 864                                                 else if (caller.vote_master)
 865                                                 {
 866                                                         print_to(caller, "^1You are already logged in as vote master.");
 867                                                 }
 868                                                 else if (autocvar_sv_vote_master_password != argv(3))
 869                                                 {
 870                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 871                                                 }
 872
 873                                                 else  // everything went okay, proceed with giving this player master privilages
 874                                                 {
 875                                                         caller.vote_master = true;
 876                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 877                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 878                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 879
 880                                                 return;
 881                                         }
 882
 883                                         default:  // calling a vote for master
 884                                         {
 885                                                 bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 886
 887                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 888                                                 else if (vote_called)
 889                                                 {
 890                                                         print_to(caller, "^1There is already a vote called.");
 891                                                 }
 892                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 893                                                 {
 894                                                         print_to(caller, "^1Only players can call a vote.");
 895                                                 }
 896                                                 else if (timeout_status)
 897                                                 {
 898                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 899                                                 }
 900
 901                                                 else  // everything went okay, continue with creating vote
 902                                                 {
 903                                                         vote_caller = caller;
 904                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 905                                                         vote_called = VOTE_MASTER;
 906                                                         vote_called_command = strzone("XXX");
 907                                                         vote_called_display = strzone("^3master");
 908                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 909
 910                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 911                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 912
 913                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 914                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 915                                                         Nagger_VoteChanged();
 916                                                         VoteCount(true);  // needed if you are the only one
 917                                                 }
 918
 919                                                 return;
 920                                         }
 921                                 }
 922                         }
 923                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 924
 925                         return;
 926                 }
 927
 928                 default:
 929                 case CMD_REQUEST_USAGE:
 930                 {
 931                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 932                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 933                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 934                         return;
 935                 }
 936         }
 937 }
 938
 939 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 940 {
 941         switch (request)
 942         {
 943                 case CMD_REQUEST_COMMAND:
 944                 {
 945                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 946                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 947                         {
 948                                 print_to(caller, "^1You have already voted.");
 949                         }
 950                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 951                         {
 952                                 VoteStop(caller);
 953                         }
 954
 955                         else  // everything went okay, continue changing vote
 956                         {
 957                                 print_to(caller, "^1You rejected the vote.");
 958                                 caller.vote_selection = VOTE_SELECT_REJECT;
 959                                 msg_entity = caller;
 960                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 961
 962                         return;
 963                 }
 964
 965                 default:
 966                 case CMD_REQUEST_USAGE:
 967                 {
 968                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 969                         print_to(caller, "  No arguments required.");
 970                         return;
 971                 }
 972         }
 973 }
 974
 975 void VoteCommand_status(float request, entity caller)  // BOTH
 976 {
 977         switch (request)
 978         {
 979                 case CMD_REQUEST_COMMAND:
 980                 {
 981                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
 982                         else print_to(caller, "^1No vote called.");
 983
 984                         return;
 985                 }
 986
 987                 default:
 988                 case CMD_REQUEST_USAGE:
 989                 {
 990                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 991                         print_to(caller, "  No arguments required.");
 992                         return;
 993                 }
 994         }
 995 }
 996
 997 void VoteCommand_stop(float request, entity caller)  // BOTH
 998 {
 999         switch (request)
1000         {
1001                 case CMD_REQUEST_COMMAND:
1002                 {
1003                         if (!vote_called)   print_to(caller, "^1No vote called.");
1004                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1005                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1006                         return;
1007                 }
1008
1009                 default:
1010                 case CMD_REQUEST_USAGE:
1011                 {
1012                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1013                         print_to(caller, "  No arguments required.");
1014                         return;
1015                 }
1016         }
1017 }
1018
1019 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1020 {
1021         switch (request)
1022         {
1023                 case CMD_REQUEST_COMMAND:
1024                 {
1025                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1026                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1027                         {
1028                                 print_to(caller, "^1You have already voted.");
1029                         }
1030
1031                         else  // everything went okay, continue changing vote
1032                         {
1033                                 print_to(caller, "^1You accepted the vote.");
1034                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1035                                 msg_entity = caller;
1036                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1037
1038                         return;
1039                 }
1040
1041                 default:
1042                 case CMD_REQUEST_USAGE:
1043                 {
1044                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1045                         print_to(caller, "  No arguments required.");
1046                         return;
1047                 }
1048         }
1049 }
1050
1051 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1052 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1053 void VoteCommand_(float request)
1054 {
1055     switch(request)
1056     {
1057         case CMD_REQUEST_COMMAND:
1058         {
1059
1060             return;
1061         }
1062
1063         default:
1064         case CMD_REQUEST_USAGE:
1065         {
1066             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1067             print_to(caller, "  No arguments required.");
1068             return;
1069         }
1070     }
1071 }
1072 */
1073
1074
1075 // ================================
1076 //  Macro system for vote commands
1077 // ================================
1078
1079 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1080 #define VOTE_COMMANDS(request, caller, arguments, command) \
1081         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1082         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1083         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1084         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1085         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1086         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1087         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1088         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1089         /* nothing */
1090
1091 void VoteCommand_macro_help(entity caller, float argc)
1092 {
1093         string command_origin = GetCommandPrefix(caller);
1094
1095         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1096         {
1097                 print_to(caller, "\nVoting commands:\n");
1098                 #define VOTE_COMMAND(name, function, description, assignment) \
1099                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1100
1101                 VOTE_COMMANDS(0, caller, 0, "");
1102 #undef VOTE_COMMAND
1103
1104                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1105                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1106                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1107         }
1108         else  // usage for individual command
1109         {
1110                 #define VOTE_COMMAND(name, function, description, assignment) \
1111                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1112
1113                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1114 #undef VOTE_COMMAND
1115         }
1116 }
1117
1118 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1119 {
1120         #define VOTE_COMMAND(name, function, description, assignment) \
1121                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1122
1123         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1124 #undef VOTE_COMMAND
1125
1126         return false;
1127 }
1128
1129
1130 // ======================================
1131 //  Main function handling vote commands
1132 // ======================================
1133
1134 void VoteCommand(float request, entity caller, float argc, string vote_command)
1135 {
1136         // Guide for working with argc arguments by example:
1137         // argc:   1    - 2      - 3     - 4
1138         // argv:   0    - 1      - 2     - 3
1139         // cmd     vote - master - login - password
1140
1141         switch (request)
1142         {
1143                 case CMD_REQUEST_COMMAND:
1144                 {
1145                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1146                 }
1147
1148                 default:
1149                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1150                 case CMD_REQUEST_USAGE:
1151                 {
1152                         VoteCommand_macro_help(caller, argc);
1153                         return;
1154                 }
1155         }
1156 }