Merge remote-tracking branch 'origin/divVerent/merged-translations'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / vote.qc
1 // =============================================
2 //  Server side voting code, reworked by Samual
3 //  Last updated: December 27th, 2011
4 // =============================================
5
6 //  Nagger for players to know status of voting
7 float Nagger_SendEntity(entity to, float sendflags)
8 {
9         float nags, i, f, b;
10         entity e;
11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
12
13         // bits:
14         //   1 = ready
15         //   2 = player needs to ready up
16         //   4 = vote
17         //   8 = player needs to vote
18         //  16 = warmup
19         // sendflags:
20         //  64 = vote counts
21         // 128 = vote string
22
23         nags = 0;
24         if(readycount)
25         {
26                 nags |= 1;
27                 if(to.ready == 0)
28                         nags |= 2;
29         }
30         if(vote_called)
31         {
32                 nags |= 4;
33                 if(to.vote_selection == 0)
34                         nags |= 8;
35         }
36         if(inWarmupStage)
37                 nags |= 16;
38
39         if(sendflags & 64)
40                 nags |= 64;
41
42         if(sendflags & 128)
43                 nags |= 128;
44
45         if(!(nags & 4)) // no vote called? send no string
46                 nags &= ~(64 | 128);
47
48         WriteByte(MSG_ENTITY, nags);
49
50         if(nags & 64)
51         {
52                 WriteByte(MSG_ENTITY, vote_accept_count);
53                 WriteByte(MSG_ENTITY, vote_reject_count);
54                 WriteByte(MSG_ENTITY, vote_needed_overall);
55                 WriteChar(MSG_ENTITY, to.vote_selection);
56         }
57
58         if(nags & 128)
59                 WriteString(MSG_ENTITY, vote_called_display);
60
61         if(nags & 1)
62         {
63                 for(i = 1; i <= maxclients; i += 8)
64                 {
65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
66                                 if(!IS_REAL_CLIENT(e) || e.ready)
67                                         f |= b;
68                         WriteByte(MSG_ENTITY, f);
69                 }
70         }
71
72         return TRUE;
73 }
74
75 void Nagger_Init()
76 {
77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
78 }
79
80 void Nagger_VoteChanged()
81 {
82         if(nagger)
83                 nagger.SendFlags |= 128;
84 }
85
86 void Nagger_VoteCountChanged()
87 {
88         if(nagger)
89                 nagger.SendFlags |= 64;
90 }
91
92 void Nagger_ReadyCounted()
93 {
94         if(nagger)
95                 nagger.SendFlags |= 1;
96 }
97
98
99 // =======================
100 //  Game logic for voting
101 // =======================
102
103 void VoteReset() 
104 {
105         entity tmp_player;
106
107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
108
109         if(vote_called)
110         {
111                 strunzone(vote_called_command);
112                 strunzone(vote_called_display);
113         }
114
115         vote_called = VOTE_NULL;
116         vote_caller = world;
117         vote_endtime = 0;
118         
119         vote_called_command = string_null;
120         vote_called_display = string_null;
121         
122         vote_parsed_command = string_null;
123         vote_parsed_display = string_null;
124
125         Nagger_VoteChanged();
126 }
127
128 void VoteStop(entity stopper) 
129 {
130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
132         
133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
135
136         VoteReset();
137 }
138
139 void VoteAccept() 
140 {
141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
142         
143         if((vote_called == VOTE_MASTER) && vote_caller)
144                 vote_caller.vote_master = 1;
145         else
146                 localcmd(strcat(vote_called_command, "\n"));
147         
148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
149
150         VoteReset();
151         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
152 }
153
154 void VoteReject() 
155 {
156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
157         VoteReset();
158         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
159 }
160
161 void VoteTimeout() 
162 {
163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
164         VoteReset();
165         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
166 }
167
168 void VoteSpam(float notvoters, float mincount, string result)
169 {
170         bprint(strcat(
171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
172                 strcat("^2:^1", ftos(vote_reject_count)),
173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
176         
177         if(autocvar_sv_eventlog)
178         {
179                 GameLogEcho(strcat(
180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
181                         strcat(":", ftos(vote_reject_count)),
182                         strcat(":", ftos(vote_abstain_count)),
183                         strcat(":", ftos(notvoters)),
184                         strcat(":", ftos(mincount))));
185         }
186 }
187
188 void VoteCount(float first_count) 
189 {
190         // declarations
191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
192         
193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2) 
194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
195                                 || (autocvar_sv_vote_nospectators == 0));
196                                 
197         float vote_player_count = 0, notvoters = 0;
198         float vote_real_player_count = 0, vote_real_accept_count = 0;
199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
200         float vote_needed_of_voted, final_needed_votes;
201         float vote_factor_overall, vote_factor_of_voted;
202         
203         entity tmp_player;
204
205         Nagger_VoteCountChanged();
206         
207         // add up all the votes from each connected client
208         FOR_EACH_REALCLIENT(tmp_player)
209         {
210                 ++vote_player_count;
211                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
212                 
213                 switch(tmp_player.vote_selection)
214                 {
215                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
216                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
217                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
218                         default: break;
219                 }
220         }
221         
222         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
223         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count) 
224         {
225                 if(vote_caller) { vote_caller.vote_waittime = 0; }
226                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
227                 VoteReset();
228                 return;
229         }
230         
231         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators. 
232         if(!spectators_allowed && (vote_real_player_count > 0))
233         {
234                 vote_accept_count = vote_real_accept_count;
235                 vote_reject_count = vote_real_reject_count;
236                 vote_abstain_count = vote_real_abstain_count;
237                 vote_player_count = vote_real_player_count;
238         }
239         
240         // people who have no opinion in any way :D
241         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
242
243         // determine the goal for the vote to be passed or rejected normally
244         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
245         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
246         
247         // if the vote times out, determine the amount of votes needed of the people who actually already voted
248         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
249         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
250         
251         // are there any players at all on the server? it could be an admin vote
252         if(vote_player_count == 0 && first_count)
253         {
254                 VoteSpam(0, -1, "yes"); // no players at all, just accept it 
255                 VoteAccept();
256                 return;
257         }
258         
259         // since there ARE players, finally calculate the result of the vote    
260         if(vote_accept_count >= vote_needed_overall)
261         {
262                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
263                 VoteAccept();
264                 return;
265         }
266         
267         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
268         {
269                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
270                 VoteReject();
271                 return;
272         }
273         
274         // there is not enough votes in either direction, now lets just calculate what the voters have said
275         if(time > vote_endtime)
276         {
277                 final_needed_votes = vote_needed_overall;
278                 
279                 if(autocvar_sv_vote_majority_factor_of_voted)
280                 {
281                         if(vote_accept_count >= vote_needed_of_voted)
282                         {
283                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
284                                 VoteAccept();
285                                 return;
286                         }
287                         
288                         if(vote_accept_count + vote_reject_count > 0)
289                         {
290                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
291                                 VoteReject();
292                                 return;
293                         }
294                         
295                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
296                 }
297
298                 // it didn't pass or fail, so not enough votes to even make a decision. 
299                 VoteSpam(notvoters, final_needed_votes, "timeout");
300                 VoteTimeout();
301         }
302 }
303
304 void VoteThink() 
305 {
306         if(vote_endtime > 0) // a vote was called
307         if(time > vote_endtime) // time is up
308         {
309                 VoteCount(FALSE);
310         }
311         
312         return;
313 }
314
315
316 // =======================
317 //  Game logic for warmup
318 // =======================
319
320 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
321 void reset_map(float dorespawn)
322 {
323         entity oldself;
324         oldself = self;
325
326         if(time <= game_starttime && round_handler_IsActive())
327                 round_handler_Reset(game_starttime);
328
329         if(g_race || g_cts)
330                 race_ReadyRestart();
331         else MUTATOR_CALLHOOK(reset_map_global);
332
333         for(self = world; (self = nextent(self)); )
334         if(IS_NOT_A_CLIENT(self))
335         {
336                 if(self.reset)
337                 {
338                         self.reset();
339                         continue;
340                 }
341
342                 if(self.team_saved)
343                         self.team = self.team_saved;
344
345                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
346                         remove(self);
347         }
348
349         // Waypoints and assault start come LAST
350         for(self = world; (self = nextent(self)); )
351         if(IS_NOT_A_CLIENT(self))
352         {
353                 if(self.reset2)
354                 {
355                         self.reset2();
356                         continue;
357                 }
358         }
359
360         // Moving the player reset code here since the player-reset depends
361         // on spawnpoint entities which have to be reset first --blub
362         if(dorespawn)
363         if(!MUTATOR_CALLHOOK(reset_map_players))
364         FOR_EACH_CLIENT(self) // reset all players
365         {
366                 /*
367                 only reset players if a restart countdown is active
368                 this can either be due to cvar sv_ready_restart_after_countdown having set
369                 restart_mapalreadyrestarted to 1 after the countdown ended or when
370                 sv_ready_restart_after_countdown is not used and countdown is still running
371                 */
372                 if (restart_mapalreadyrestarted || (time < game_starttime))
373                 {
374                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
375                         if (IS_PLAYER(self)) {
376                                 //PlayerScore_Clear(self);
377                                 self.killcount = 0;
378                                 //stop the player from moving so that he stands still once he gets respawned
379                                 self.velocity = '0 0 0';
380                                 self.avelocity = '0 0 0';
381                                 self.movement = '0 0 0';
382                                 PutClientInServer();
383                         }
384                 }
385         }
386
387         if(g_keyhunt)
388                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
389
390         self = oldself;
391 }
392
393 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
394 void ReadyRestart_think() 
395 {
396         restart_mapalreadyrestarted = 1;
397         reset_map(TRUE);
398         Score_ClearAll();
399         remove(self);
400         
401         return;
402 }
403
404 // Forces a restart of the game without actually reloading the map // this is a mess...
405 void ReadyRestart_force()
406 {
407         entity tmp_player, restart_timer;
408
409         bprint("^1Server is restarting...\n");
410
411         VoteReset();
412
413         // clear overtime, we have to decrease timelimit to its original value again.
414         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
415
416         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
417
418         readyrestart_happened = 1;
419         game_starttime = time + RESTART_COUNTDOWN;
420
421         // clear player attributes
422         FOR_EACH_CLIENT(tmp_player)
423         {
424                 tmp_player.alivetime = 0;
425                 tmp_player.killcount = 0;
426                 PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, -PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, 0));
427         }
428
429         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
430
431         // disable the warmup global for the server
432         inWarmupStage = 0; // once the game is restarted the game is in match stage
433
434         // reset the .ready status of all players (also spectators)
435         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
436         readycount = 0;
437         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
438
439         // lock teams with lockonrestart
440         if(autocvar_teamplay_lockonrestart && teamplay)
441         {
442                 lockteams = 1;
443                 bprint("^1The teams are now locked.\n");
444         }
445
446         //initiate the restart-countdown-announcer entity
447         if(autocvar_sv_ready_restart_after_countdown)
448         {
449                 restart_timer = spawn();
450                 restart_timer.think = ReadyRestart_think;
451                 restart_timer.nextthink = game_starttime;
452         }
453
454         // after a restart every players number of allowed timeouts gets reset, too
455         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
456
457         //reset map immediately if this cvar is not set
458         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
459
460         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
461 }
462
463 void ReadyRestart()
464 {
465         // no arena, assault support yet...
466         if(g_arena | g_assault | gameover | intermission_running | race_completing)
467                 localcmd("restart\n");
468         else
469                 localcmd("\nsv_hook_gamerestart\n");
470
471         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
472         // Otherwise scores could be manipulated during the countdown.
473         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
474
475         ReadyRestart_force();
476         
477         return;
478 }
479
480 // Count the players who are ready and determine whether or not to restart the match
481 void ReadyCount()
482 {
483         entity tmp_player;
484         float ready_needed_factor, ready_needed_count;
485         float t_ready = 0, t_players = 0;
486
487         FOR_EACH_REALCLIENT(tmp_player)
488         {
489                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
490                 {
491                         ++t_players;
492                         if(tmp_player.ready) { ++t_ready; }
493                 }
494         }
495
496         readycount = t_ready;
497
498         Nagger_ReadyCounted();
499
500         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
501         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
502         
503         if(readycount >= ready_needed_count)
504         {
505                 ReadyRestart();
506         }
507                 
508         return;
509 }
510
511
512 // ======================================
513 //  Supporting functions for VoteCommand
514 // ======================================
515
516 float Votecommand_check_assignment(entity caller, float assignment)
517 {
518         float from_server = (!caller);
519         
520         if((assignment == VC_ASGNMNT_BOTH) 
521                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY) 
522                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
523         {
524                 return TRUE;
525         }
526
527         return FALSE;
528 }
529
530 string VoteCommand_extractcommand(string input, float startpos, float argc) 
531 {
532         string output;
533         
534         if((argc - 1) < startpos)
535                 output = "";
536         else
537                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
538                 
539         return output;
540 }
541
542 float VoteCommand_checknasty(string vote_command)
543 {
544         if((strstrofs(vote_command, ";", 0) >= 0)
545                 || (strstrofs(vote_command, "\n", 0) >= 0)
546                 || (strstrofs(vote_command, "\r", 0) >= 0)
547                 || (strstrofs(vote_command, "$", 0) >= 0))
548                 return FALSE;
549                 
550         return TRUE;
551 }
552
553 float VoteCommand_checkinlist(string vote_command, string list)
554 {
555         string l = strcat(" ", list, " ");
556         
557         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
558                 return TRUE;
559         
560         return FALSE;
561 }
562
563 string ValidateMap(string validated_map, entity caller)
564 {
565         validated_map = MapInfo_FixName(validated_map);
566         
567         if not(validated_map)
568         {
569                 print_to(caller, "This map is not available on this server.");
570                 return string_null;
571         }
572         
573         if(!autocvar_sv_vote_override_mostrecent && caller)
574         {
575                 if(Map_IsRecent(validated_map))
576                 {
577                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
578                         return string_null;
579                 }
580         }
581         
582         if(!MapInfo_CheckMap(validated_map))
583         {
584                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
585                 return string_null;
586         }
587
588         return validated_map;
589 }
590
591 float VoteCommand_checkargs(float startpos, float argc)
592 {
593         float p, q, check, minargs;
594         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
595         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
596         string charlist, arg;
597         float checkmate;
598
599         if(cmdrestriction == "")
600                 return TRUE;
601
602         ++startpos; // skip command name
603
604         // check minimum arg count
605
606         // 0 args: argc == startpos
607         // 1 args: argc == startpos + 1
608         // ...
609
610         minargs = stof(cmdrestriction);
611         if(argc - startpos < minargs)
612                 return FALSE;
613
614         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
615
616         for(;;)
617         {
618                 // we know that at any time, startpos <= argc - minargs
619                 // so this means: argc-minargs >= startpos >= argc, thus
620                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
621                 // have been seen already
622
623                 if(startpos >= argc) // all args checked? GOOD
624                         break;
625
626                 if(p < 0) // no more args? FAIL
627                 {
628                         // exception: exactly minargs left, this one included
629                         if(argc - startpos == minargs)
630                                 break;
631
632                         // otherwise fail
633                         return FALSE;
634                 }
635
636                 // cut to next semicolon
637                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
638                 if(q < 0)
639                         charlist = substring(cmdrestriction, p+1, -1);
640                 else
641                         charlist = substring(cmdrestriction, p+1, q - (p+1));
642
643                 // in case we ever want to allow semicolons in VoteCommand_checknasty
644                 // charlist = strreplace("^^", ";", charlist);
645
646                 if(charlist != "")
647                 {
648                         // verify the arg only contains allowed chars
649                         arg = argv(startpos);
650                         checkmate = strlen(arg);
651                         for(check = 0; check < checkmate; ++check)
652                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
653                                         return FALSE; // not allowed character
654                         // all characters are allowed. FINE.
655                 }
656
657                 ++startpos;
658                 --minargs;
659                 p = q;
660         }
661
662         return TRUE;
663 }
664
665 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
666 {
667         string first_command;
668         
669         first_command = argv(startpos);
670
671         /*dprint(sprintf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
672                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
673                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
674         ));*/
675
676         if(
677                 (autocvar_sv_vote_limit > 0)
678                 &&
679                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
680         )
681                 return FALSE;
682
683         if not(VoteCommand_checkinlist(first_command, vote_list))
684                 return FALSE;
685
686         if not(VoteCommand_checkargs(startpos, argc))
687                 return FALSE;
688
689         switch(first_command) // now go through and parse the proper commands to adjust as needed.
690         {
691                 case "kick":
692                 case "kickban": // catch all kick/kickban commands
693                 {
694                         entity victim = GetIndexedEntity(argc, (startpos + 1));
695                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
696                         
697                         if(accepted > 0)
698                         {
699                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
700                                 string command_arguments;
701                                 
702                                 if(first_command == "kickban")
703                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
704                                 else
705                                         command_arguments = reason;
706                                 
707                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
708                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
709                         }
710                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
711                         
712                         break;
713                 }
714                 
715                 case "map":
716                 case "chmap":
717                 case "gotomap": // re-direct all map selection commands to gotomap
718                 {
719                         vote_command = ValidateMap(argv(startpos + 1), caller);
720                         if not(vote_command) { return FALSE; }
721                         vote_parsed_command = strcat("gotomap ", vote_command);
722                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
723                         
724                         break;
725                 }
726                 
727                 default: 
728                 { 
729                         vote_parsed_command = vote_command;
730                         vote_parsed_display = strzone(strcat("^1", vote_command));
731                         
732                         break; 
733                 }
734         }
735
736         return TRUE;
737 }
738
739
740 // =======================
741 //  Command Sub-Functions
742 // =======================
743
744 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
745 {
746         switch(request)
747         {
748                 case CMD_REQUEST_COMMAND:
749                 {
750                         if not(vote_called) { print_to(caller, "^1No vote called."); }
751                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
752                         
753                         else // everything went okay, continue changing vote
754                         {
755                                 print_to(caller, "^1You abstained from your vote.");
756                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
757                                 msg_entity = caller;
758                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
759                         }
760                         
761                         return;
762                 }
763                         
764                 default:
765                 case CMD_REQUEST_USAGE:
766                 {
767                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
768                         print_to(caller, "  No arguments required.");
769                         return;
770                 }
771         }
772 }
773
774 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
775 {
776         switch(request)
777         {
778                 case CMD_REQUEST_COMMAND:
779                 {
780                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2) 
781                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage) 
782                                 || (autocvar_sv_vote_nospectators == 0));
783                                 
784                         float tmp_playercount = 0;
785                         entity tmp_player;
786                         
787                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
788                         
789                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
790                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
791                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
792                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
793                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
794                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
795                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
796                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
797
798                         else // everything went okay, continue with calling the vote
799                         {
800                                 vote_caller = caller; // remember who called the vote
801                                 vote_called = VOTE_NORMAL;
802                                 vote_called_command = strzone(vote_parsed_command);
803                                 vote_called_display = strzone(vote_parsed_display);
804                                 vote_endtime = time + autocvar_sv_vote_timeout;
805                                 
806                                 if(caller)
807                                 {
808                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
809                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
810                                         msg_entity = caller;
811                                 }
812                                 
813                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
814                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
815                                 
816                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
817                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
818                                 Nagger_VoteChanged();
819                                 VoteCount(TRUE); // needed if you are the only one
820                         }
821                         
822                         return;
823                 }
824                         
825                 default:
826                 case CMD_REQUEST_USAGE:
827                 {
828                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
829                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
830                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
831                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
832                         return;
833                 }
834         }
835 }
836
837 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
838 {
839         switch(request)
840         {
841                 case CMD_REQUEST_COMMAND:
842                 {
843                         if(autocvar_sv_vote_master)
844                         {
845                                 switch(strtolower(argv(2)))
846                                 {
847                                         case "do":
848                                         {
849                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
850                                                 
851                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
852                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
853                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
854                                                 
855                                                 else // everything went okay, proceed with command
856                                                 {
857                                                         localcmd(strcat(vote_parsed_command, "\n"));
858                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
859                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
860                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
861                                                 }
862                                                 
863                                                 return;
864                                         }
865                                         
866                                         case "login":
867                                         {
868                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
869                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
870                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
871
872                                                 else // everything went okay, proceed with giving this player master privilages
873                                                 {
874                                                         caller.vote_master = TRUE;
875                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
876                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
877                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
878                                                 }
879                                                 
880                                                 return;
881                                         }
882                                         
883                                         default: // calling a vote for master
884                                         {
885                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2) 
886                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage) 
887                                                         || (autocvar_sv_vote_nospectators == 0));
888                                                 
889                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
890                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
891                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
892                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
893                                                 
894                                                 else // everything went okay, continue with creating vote
895                                                 {
896                                                         vote_caller = caller;
897                                                         vote_called = VOTE_MASTER;
898                                                         vote_called_command = strzone("XXX");
899                                                         vote_called_display = strzone("^3master");
900                                                         vote_endtime = time + autocvar_sv_vote_timeout;
901                                                         
902                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
903                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
904                                                         
905                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
906                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
907                                                         Nagger_VoteChanged();
908                                                         VoteCount(TRUE); // needed if you are the only one
909                                                 }
910                                                 
911                                                 return;
912                                         }
913                                 }
914                         }
915                         else { print_to(caller, "^1Master control of voting is not allowed."); }
916                         
917                         return;
918                 }
919                         
920                 default:
921                 case CMD_REQUEST_USAGE:
922                 {
923                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
924                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
925                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
926                         return;
927                 }
928         }
929 }
930
931 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
932 {
933         switch(request)
934         {
935                 case CMD_REQUEST_COMMAND:
936                 {
937                         if not(vote_called) { print_to(caller, "^1No vote called."); }
938                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
939                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
940                         
941                         else // everything went okay, continue changing vote
942                         {
943                                 print_to(caller, "^1You rejected the vote.");
944                                 caller.vote_selection = VOTE_SELECT_REJECT;
945                                 msg_entity = caller;
946                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
947                         }
948                         
949                         return;
950                 }
951                         
952                 default:
953                 case CMD_REQUEST_USAGE:
954                 {
955                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
956                         print_to(caller, "  No arguments required.");
957                         return;
958                 }
959         }
960 }
961
962 void VoteCommand_status(float request, entity caller) // BOTH
963 {
964         switch(request)
965         {
966                 case CMD_REQUEST_COMMAND:
967                 {
968                         if(vote_called)
969                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
970                         else
971                                 print_to(caller, "^1No vote called.");
972                                 
973                         return;
974                 }
975                         
976                 default:
977                 case CMD_REQUEST_USAGE:
978                 {
979                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
980                         print_to(caller, "  No arguments required.");
981                         return;
982                 }
983         }
984 }
985
986 void VoteCommand_stop(float request, entity caller) // BOTH
987 {
988         switch(request)
989         {
990                 case CMD_REQUEST_COMMAND:
991                 {
992                         if not(vote_called) { print_to(caller, "^1No vote called."); }
993                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
994                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
995                         
996                         return;
997                 }
998                         
999                 default:
1000                 case CMD_REQUEST_USAGE:
1001                 {
1002                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1003                         print_to(caller, "  No arguments required.");
1004                         return;
1005                 }
1006         }
1007 }
1008
1009 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1010 {
1011         switch(request)
1012         {
1013                 case CMD_REQUEST_COMMAND:
1014                 {
1015                         if not(vote_called) { print_to(caller, "^1No vote called."); }
1016                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1017                         
1018                         else // everything went okay, continue changing vote
1019                         {
1020                                 print_to(caller, "^1You accepted the vote.");
1021                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1022                                 msg_entity = caller;
1023                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
1024                         }
1025                         
1026                         return;
1027                 }
1028                         
1029                 default:
1030                 case CMD_REQUEST_USAGE:
1031                 {
1032                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1033                         print_to(caller, "  No arguments required.");
1034                         return;
1035                 }
1036         }
1037 }
1038
1039 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1040 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1041 void VoteCommand_(float request)
1042 {
1043         switch(request)
1044         {
1045                 case CMD_REQUEST_COMMAND:
1046                 {
1047                         
1048                         return;
1049                 }
1050                         
1051                 default:
1052                 case CMD_REQUEST_USAGE:
1053                 {
1054                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1055                         print_to(caller, "  No arguments required.");
1056                         return;
1057                 }
1058         }
1059 }
1060 */
1061
1062
1063 // ================================
1064 //  Macro system for vote commands
1065 // ================================
1066
1067 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1068 #define VOTE_COMMANDS(request,caller,arguments,command) \
1069         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1070         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1071         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1072         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1073         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1074         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1075         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1076         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1077         /* nothing */
1078
1079 void VoteCommand_macro_help(entity caller, float argc)
1080 {
1081         string command_origin = GetCommandPrefix(caller);
1082
1083         if(argc == 2 || argv(2) == "help") // help display listing all commands
1084         {
1085                 print_to(caller, "\nVoting commands:\n");
1086                 #define VOTE_COMMAND(name,function,description,assignment) \
1087                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1088                         
1089                 VOTE_COMMANDS(0, caller, 0, "")
1090                 #undef VOTE_COMMAND
1091                 
1092                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1093                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1094                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1095         }
1096         else // usage for individual command
1097         {
1098                 #define VOTE_COMMAND(name,function,description,assignment) \
1099                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1100                         
1101                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1102                 #undef VOTE_COMMAND
1103         }
1104         
1105         return;
1106 }
1107
1108 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1109 {
1110         #define VOTE_COMMAND(name,function,description,assignment) \
1111                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1112                 
1113         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1114         #undef VOTE_COMMAND
1115         
1116         return FALSE;
1117 }
1118
1119
1120 // ======================================
1121 //  Main function handling vote commands
1122 // ======================================
1123
1124 void VoteCommand(float request, entity caller, float argc, string vote_command) 
1125 {
1126         // Guide for working with argc arguments by example:
1127         // argc:   1    - 2      - 3     - 4
1128         // argv:   0    - 1      - 2     - 3 
1129         // cmd     vote - master - login - password
1130         
1131         switch(request)
1132         {
1133                 case CMD_REQUEST_COMMAND:
1134                 {
1135                         if(VoteCommand_macro_command(caller, argc, vote_command))
1136                                 return;
1137                 }
1138                         
1139                 default:
1140                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1141                 case CMD_REQUEST_USAGE:
1142                 {
1143                         VoteCommand_macro_help(caller, argc);
1144                         return;
1145                 }
1146         }
1147 }