Merge remote-tracking branch 'origin/master' into terencehill/ca_arena_mutators
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / vote.qc
1 // =============================================
2 //  Server side voting code, reworked by Samual
3 //  Last updated: December 27th, 2011
4 // =============================================
5
6 //  Nagger for players to know status of voting
7 float Nagger_SendEntity(entity to, float sendflags)
8 {
9         float nags, i, f, b;
10         entity e;
11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
12
13         // bits:
14         //   1 = ready
15         //   2 = player needs to ready up
16         //   4 = vote
17         //   8 = player needs to vote
18         //  16 = warmup
19         // sendflags:
20         //  64 = vote counts
21         // 128 = vote string
22
23         nags = 0;
24         if(readycount)
25         {
26                 nags |= 1;
27                 if(to.ready == 0)
28                         nags |= 2;
29         }
30         if(vote_called)
31         {
32                 nags |= 4;
33                 if(to.vote_selection == 0)
34                         nags |= 8;
35         }
36         if(inWarmupStage)
37                 nags |= 16;
38
39         if(sendflags & 64)
40                 nags |= 64;
41
42         if(sendflags & 128)
43                 nags |= 128;
44
45         if(!(nags & 4)) // no vote called? send no string
46                 nags &~= (64 | 128);
47
48         WriteByte(MSG_ENTITY, nags);
49
50         if(nags & 64)
51         {
52                 WriteByte(MSG_ENTITY, vote_accept_count);
53                 WriteByte(MSG_ENTITY, vote_reject_count);
54                 WriteByte(MSG_ENTITY, vote_needed_overall);
55                 WriteChar(MSG_ENTITY, to.vote_selection);
56         }
57
58         if(nags & 128)
59                 WriteString(MSG_ENTITY, vote_called_display);
60
61         if(nags & 1)
62         {
63                 for(i = 1; i <= maxclients; i += 8)
64                 {
65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
67                                         f |= b;
68                         WriteByte(MSG_ENTITY, f);
69                 }
70         }
71
72         return TRUE;
73 }
74
75 void Nagger_Init()
76 {
77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
78 }
79
80 void Nagger_VoteChanged()
81 {
82         if(nagger)
83                 nagger.SendFlags |= 128;
84 }
85
86 void Nagger_VoteCountChanged()
87 {
88         if(nagger)
89                 nagger.SendFlags |= 64;
90 }
91
92 void Nagger_ReadyCounted()
93 {
94         if(nagger)
95                 nagger.SendFlags |= 1;
96 }
97
98
99 // =======================
100 //  Game logic for voting
101 // =======================
102
103 void VoteReset() 
104 {
105         entity tmp_player;
106
107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
108
109         if(vote_called)
110         {
111                 strunzone(vote_called_command);
112                 strunzone(vote_called_display);
113         }
114
115         vote_called = VOTE_NULL;
116         vote_caller = world;
117         vote_endtime = 0;
118         
119         vote_called_command = string_null;
120         vote_called_display = string_null;
121         
122         vote_parsed_command = string_null;
123         vote_parsed_display = string_null;
124
125         Nagger_VoteChanged();
126 }
127
128 void VoteStop(entity stopper) 
129 {
130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
132         
133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
135
136         VoteReset();
137 }
138
139 void VoteAccept() 
140 {
141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
142         
143         if((vote_called == VOTE_MASTER) && vote_caller)
144                 vote_caller.vote_master = 1;
145         else
146                 localcmd(strcat(vote_called_command, "\n"));
147         
148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
149
150         VoteReset();
151         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
152 }
153
154 void VoteReject() 
155 {
156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
157         VoteReset();
158         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
159 }
160
161 void VoteTimeout() 
162 {
163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
164         VoteReset();
165         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
166 }
167
168 void VoteSpam(float notvoters, float mincount, string result)
169 {
170         bprint(strcat(
171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
172                 strcat("^2:^1", ftos(vote_reject_count)),
173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
176         
177         if(autocvar_sv_eventlog)
178         {
179                 GameLogEcho(strcat(
180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
181                         strcat(":", ftos(vote_reject_count)),
182                         strcat(":", ftos(vote_abstain_count)),
183                         strcat(":", ftos(notvoters)),
184                         strcat(":", ftos(mincount))));
185         }
186 }
187
188 void VoteCount(float first_count) 
189 {
190         // declarations
191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
192         
193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2) 
194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
195                                 || (autocvar_sv_vote_nospectators == 0));
196                                 
197         float vote_player_count = 0, is_player, notvoters = 0;
198         float vote_real_player_count = 0, vote_real_accept_count = 0;
199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
200         float vote_needed_of_voted, final_needed_votes;
201         float vote_factor_overall, vote_factor_of_voted;
202         
203         entity tmp_player;
204
205         Nagger_VoteCountChanged();
206         
207         // add up all the votes from each connected client
208         FOR_EACH_REALCLIENT(tmp_player)
209         {
210                 is_player = (tmp_player.classname == "player");
211                 
212                 ++vote_player_count;
213                 if(is_player) { ++vote_real_player_count; }
214                 
215                 switch(tmp_player.vote_selection)
216                 {
217                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
218                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
219                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
220                         default: break;
221                 }
222         }
223         
224         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
225         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count) 
226         {
227                 if(vote_caller) { vote_caller.vote_waittime = 0; }
228                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
229                 VoteReset();
230                 return;
231         }
232         
233         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators. 
234         if(!spectators_allowed && (vote_real_player_count > 0))
235         {
236                 vote_accept_count = vote_real_accept_count;
237                 vote_reject_count = vote_real_reject_count;
238                 vote_abstain_count = vote_real_abstain_count;
239                 vote_player_count = vote_real_player_count;
240         }
241         
242         // people who have no opinion in any way :D
243         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
244
245         // determine the goal for the vote to be passed or rejected normally
246         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
247         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
248         
249         // if the vote times out, determine the amount of votes needed of the people who actually already voted
250         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
251         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
252         
253         // are there any players at all on the server? it could be an admin vote
254         if(vote_player_count == 0 && first_count)
255         {
256                 VoteSpam(0, -1, "yes"); // no players at all, just accept it 
257                 VoteAccept();
258                 return;
259         }
260         
261         // since there ARE players, finally calculate the result of the vote    
262         if(vote_accept_count >= vote_needed_overall)
263         {
264                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
265                 VoteAccept();
266                 return;
267         }
268         
269         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
270         {
271                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
272                 VoteReject();
273                 return;
274         }
275         
276         // there is not enough votes in either direction, now lets just calculate what the voters have said
277         if(time > vote_endtime)
278         {
279                 final_needed_votes = vote_needed_overall;
280                 
281                 if(autocvar_sv_vote_majority_factor_of_voted)
282                 {
283                         if(vote_accept_count >= vote_needed_of_voted)
284                         {
285                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
286                                 VoteAccept();
287                                 return;
288                         }
289                         
290                         if(vote_accept_count + vote_reject_count > 0)
291                         {
292                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
293                                 VoteReject();
294                                 return;
295                         }
296                         
297                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
298                 }
299
300                 // it didn't pass or fail, so not enough votes to even make a decision. 
301                 VoteSpam(notvoters, final_needed_votes, "timeout");
302                 VoteTimeout();
303         }
304 }
305
306 void VoteThink() 
307 {
308         if(vote_endtime > 0) // a vote was called
309         if(time > vote_endtime) // time is up
310         {
311                 VoteCount(FALSE);
312         }
313         
314         return;
315 }
316
317
318 // =======================
319 //  Game logic for warmup
320 // =======================
321
322 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
323 void reset_map(float dorespawn)
324 {
325         entity oldself;
326         oldself = self;
327
328         if(time <= game_starttime && round_handler_IsActive())
329                 round_handler_Reset(game_starttime);
330
331         if(g_race || g_cts)
332                 race_ReadyRestart();
333         else MUTATOR_CALLHOOK(reset_map_global);
334
335         lms_lowest_lives = 999;
336         lms_next_place = player_count;
337
338         for(self = world; (self = nextent(self)); )
339         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
340         {
341                 if(self.reset)
342                 {
343                         self.reset();
344                         continue;
345                 }
346
347                 if(self.team_saved)
348                         self.team = self.team_saved;
349
350                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
351                         remove(self);
352         }
353
354         // Waypoints and assault start come LAST
355         for(self = world; (self = nextent(self)); )
356         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
357         {
358                 if(self.reset2)
359                 {
360                         self.reset2();
361                         continue;
362                 }
363         }
364
365         // Moving the player reset code here since the player-reset depends
366         // on spawnpoint entities which have to be reset first --blub
367         if(dorespawn)
368         if(!MUTATOR_CALLHOOK(reset_map_players))
369         FOR_EACH_CLIENT(self) // reset all players
370         {
371                 /*
372                 only reset players if a restart countdown is active
373                 this can either be due to cvar sv_ready_restart_after_countdown having set
374                 restart_mapalreadyrestarted to 1 after the countdown ended or when
375                 sv_ready_restart_after_countdown is not used and countdown is still running
376                 */
377                 if (restart_mapalreadyrestarted || (time < game_starttime))
378                 {
379                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
380                         if (IS_PLAYER(self)) {
381                                 //PlayerScore_Clear(self);
382                                 if(g_lms)
383                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
384                                 self.killcount = 0;
385                                 //stop the player from moving so that he stands still once he gets respawned
386                                 self.velocity = '0 0 0';
387                                 self.avelocity = '0 0 0';
388                                 self.movement = '0 0 0';
389                                 PutClientInServer();
390                         }
391                 }
392         }
393
394         if(g_keyhunt)
395                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
396
397         self = oldself;
398 }
399
400 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
401 void ReadyRestart_think() 
402 {
403         restart_mapalreadyrestarted = 1;
404         reset_map(TRUE);
405         Score_ClearAll();
406         remove(self);
407         
408         return;
409 }
410
411 // Forces a restart of the game without actually reloading the map // this is a mess...
412 void ReadyRestart_force()
413 {
414         entity tmp_player, restart_timer;
415
416         bprint("^1Server is restarting...\n");
417
418         VoteReset();
419
420         // clear overtime, we have to decrease timelimit to its original value again.
421         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
422
423         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
424
425         readyrestart_happened = 1;
426         game_starttime = time + RESTART_COUNTDOWN;
427
428         // clear player attributes
429         FOR_EACH_CLIENT(tmp_player)
430         {
431                 tmp_player.alivetime = 0;
432                 tmp_player.killcount = 0;
433                 PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, -PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, 0));
434         }
435
436         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
437
438         // disable the warmup global for the server
439         inWarmupStage = 0; // once the game is restarted the game is in match stage
440
441         // reset the .ready status of all players (also spectators)
442         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
443         readycount = 0;
444         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
445
446         // lock teams with lockonrestart
447         if(autocvar_teamplay_lockonrestart && teamplay)
448         {
449                 lockteams = 1;
450                 bprint("^1The teams are now locked.\n");
451         }
452
453         //initiate the restart-countdown-announcer entity
454         if(autocvar_sv_ready_restart_after_countdown)
455         {
456                 restart_timer = spawn();
457                 restart_timer.think = ReadyRestart_think;
458                 restart_timer.nextthink = game_starttime;
459         }
460
461         // after a restart every players number of allowed timeouts gets reset, too
462         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
463
464         //reset map immediately if this cvar is not set
465         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
466
467         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
468 }
469
470 void ReadyRestart()
471 {
472         // no arena, assault support yet...
473         if(g_arena | g_assault | gameover | intermission_running | race_completing)
474                 localcmd("restart\n");
475         else
476                 localcmd("\nsv_hook_gamerestart\n");
477
478         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
479         // Otherwise scores could be manipulated during the countdown.
480         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
481
482         ReadyRestart_force();
483         
484         return;
485 }
486
487 // Count the players who are ready and determine whether or not to restart the match
488 void ReadyCount()
489 {
490         entity tmp_player;
491         float ready_needed_factor, ready_needed_count;
492         float t_ready = 0, t_players = 0;
493
494         FOR_EACH_REALCLIENT(tmp_player)
495         {
496                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
497                 {
498                         ++t_players;
499                         if(tmp_player.ready) { ++t_ready; }
500                 }
501         }
502
503         readycount = t_ready;
504
505         Nagger_ReadyCounted();
506
507         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
508         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
509         
510         if(readycount >= ready_needed_count)
511         {
512                 ReadyRestart();
513         }
514                 
515         return;
516 }
517
518
519 // ======================================
520 //  Supporting functions for VoteCommand
521 // ======================================
522
523 float Votecommand_check_assignment(entity caller, float assignment)
524 {
525         float from_server = (!caller);
526         
527         if((assignment == VC_ASGNMNT_BOTH) 
528                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY) 
529                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
530         {
531                 return TRUE;
532         }
533
534         return FALSE;
535 }
536
537 string VoteCommand_extractcommand(string input, float startpos, float argc) 
538 {
539         string output;
540         
541         if((argc - 1) < startpos)
542                 output = "";
543         else
544                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
545                 
546         return output;
547 }
548
549 float VoteCommand_checknasty(string vote_command)
550 {
551         if((strstrofs(vote_command, ";", 0) >= 0)
552                 || (strstrofs(vote_command, "\n", 0) >= 0)
553                 || (strstrofs(vote_command, "\r", 0) >= 0)
554                 || (strstrofs(vote_command, "$", 0) >= 0))
555                 return FALSE;
556                 
557         return TRUE;
558 }
559
560 float VoteCommand_checkinlist(string vote_command, string list)
561 {
562         string l = strcat(" ", list, " ");
563         
564         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
565                 return TRUE;
566         
567         return FALSE;
568 }
569
570 string ValidateMap(string validated_map, entity caller)
571 {
572         validated_map = MapInfo_FixName(validated_map);
573         
574         if not(validated_map)
575         {
576                 print_to(caller, "This map is not available on this server.");
577                 return string_null;
578         }
579         
580         if(!autocvar_sv_vote_override_mostrecent && caller)
581         {
582                 if(Map_IsRecent(validated_map))
583                 {
584                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
585                         return string_null;
586                 }
587         }
588         
589         if(!MapInfo_CheckMap(validated_map))
590         {
591                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
592                 return string_null;
593         }
594
595         return validated_map;
596 }
597
598 float VoteCommand_checkargs(float startpos, float argc)
599 {
600         float p, q, check, minargs;
601         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
602         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
603         string charlist, arg;
604         float checkmate;
605
606         if(cmdrestriction == "")
607                 return TRUE;
608
609         ++startpos; // skip command name
610
611         // check minimum arg count
612
613         // 0 args: argc == startpos
614         // 1 args: argc == startpos + 1
615         // ...
616
617         minargs = stof(cmdrestriction);
618         if(argc - startpos < minargs)
619                 return FALSE;
620
621         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
622
623         for(;;)
624         {
625                 // we know that at any time, startpos <= argc - minargs
626                 // so this means: argc-minargs >= startpos >= argc, thus
627                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
628                 // have been seen already
629
630                 if(startpos >= argc) // all args checked? GOOD
631                         break;
632
633                 if(p < 0) // no more args? FAIL
634                 {
635                         // exception: exactly minargs left, this one included
636                         if(argc - startpos == minargs)
637                                 break;
638
639                         // otherwise fail
640                         return FALSE;
641                 }
642
643                 // cut to next semicolon
644                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
645                 if(q < 0)
646                         charlist = substring(cmdrestriction, p+1, -1);
647                 else
648                         charlist = substring(cmdrestriction, p+1, q - (p+1));
649
650                 // in case we ever want to allow semicolons in VoteCommand_checknasty
651                 // charlist = strreplace("^^", ";", charlist);
652
653                 if(charlist != "")
654                 {
655                         // verify the arg only contains allowed chars
656                         arg = argv(startpos);
657                         checkmate = strlen(arg);
658                         for(check = 0; check < checkmate; ++check)
659                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
660                                         return FALSE; // not allowed character
661                         // all characters are allowed. FINE.
662                 }
663
664                 ++startpos;
665                 --minargs;
666                 p = q;
667         }
668
669         return TRUE;
670 }
671
672 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
673 {
674         string first_command;
675         
676         first_command = argv(startpos);
677
678         if not(VoteCommand_checkinlist(first_command, vote_list))
679                 return FALSE;
680
681         if not(VoteCommand_checkargs(startpos, argc))
682                 return FALSE;
683
684         switch(first_command) // now go through and parse the proper commands to adjust as needed.
685         {
686                 case "kick":
687                 case "kickban": // catch all kick/kickban commands
688                 {
689                         entity victim = GetIndexedEntity(argc, (startpos + 1));
690                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
691                         
692                         if(accepted > 0)
693                         {
694                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
695                                 string command_arguments;
696                                 
697                                 if(first_command == "kickban")
698                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
699                                 else
700                                         command_arguments = reason;
701                                 
702                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
703                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
704                         }
705                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
706                         
707                         break;
708                 }
709                 
710                 case "map":
711                 case "chmap":
712                 case "gotomap": // re-direct all map selection commands to gotomap
713                 {
714                         vote_command = ValidateMap(argv(startpos + 1), caller);
715                         if not(vote_command) { return FALSE; }
716                         vote_parsed_command = strcat("gotomap ", vote_command);
717                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
718                         
719                         break;
720                 }
721                 
722                 default: 
723                 { 
724                         vote_parsed_command = vote_command;
725                         vote_parsed_display = strzone(strcat("^1", vote_command));
726                         
727                         break; 
728                 }
729         }
730
731         return TRUE;
732 }
733
734
735 // =======================
736 //  Command Sub-Functions
737 // =======================
738
739 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
740 {
741         switch(request)
742         {
743                 case CMD_REQUEST_COMMAND:
744                 {
745                         if not(vote_called) { print_to(caller, "^1No vote called."); }
746                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
747                         
748                         else // everything went okay, continue changing vote
749                         {
750                                 print_to(caller, "^1You abstained from your vote.");
751                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
752                                 msg_entity = caller;
753                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
754                         }
755                         
756                         return;
757                 }
758                         
759                 default:
760                 case CMD_REQUEST_USAGE:
761                 {
762                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
763                         print_to(caller, "  No arguments required.");
764                         return;
765                 }
766         }
767 }
768
769 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
770 {
771         switch(request)
772         {
773                 case CMD_REQUEST_COMMAND:
774                 {
775                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2) 
776                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage) 
777                                 || (autocvar_sv_vote_nospectators == 0));
778                                 
779                         float tmp_playercount = 0;
780                         entity tmp_player;
781                         
782                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
783                         
784                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
785                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
786                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
787                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
788                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
789                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
790                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
791                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
792
793                         else // everything went okay, continue with calling the vote
794                         {
795                                 vote_caller = caller; // remember who called the vote
796                                 vote_called = VOTE_NORMAL;
797                                 vote_called_command = strzone(vote_parsed_command);
798                                 vote_called_display = strzone(vote_parsed_display);
799                                 vote_endtime = time + autocvar_sv_vote_timeout;
800                                 
801                                 if(caller)
802                                 {
803                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
804                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
805                                         msg_entity = caller;
806                                 }
807                                 
808                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
809                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
810                                 
811                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
812                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
813                                 Nagger_VoteChanged();
814                                 VoteCount(TRUE); // needed if you are the only one
815                         }
816                         
817                         return;
818                 }
819                         
820                 default:
821                 case CMD_REQUEST_USAGE:
822                 {
823                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
824                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
825                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
826                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
827                         return;
828                 }
829         }
830 }
831
832 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
833 {
834         switch(request)
835         {
836                 case CMD_REQUEST_COMMAND:
837                 {
838                         if(autocvar_sv_vote_master)
839                         {
840                                 switch(strtolower(argv(2)))
841                                 {
842                                         case "do":
843                                         {
844                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
845                                                 
846                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
847                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
848                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
849                                                 
850                                                 else // everything went okay, proceed with command
851                                                 {
852                                                         localcmd(strcat(vote_parsed_command, "\n"));
853                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
854                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
855                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
856                                                 }
857                                                 
858                                                 return;
859                                         }
860                                         
861                                         case "login":
862                                         {
863                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
864                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
865                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
866
867                                                 else // everything went okay, proceed with giving this player master privilages
868                                                 {
869                                                         caller.vote_master = TRUE;
870                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
871                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
872                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
873                                                 }
874                                                 
875                                                 return;
876                                         }
877                                         
878                                         default: // calling a vote for master
879                                         {
880                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2) 
881                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage) 
882                                                         || (autocvar_sv_vote_nospectators == 0));
883                                                 
884                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
885                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
886                                                 else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
887                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
888                                                 
889                                                 else // everything went okay, continue with creating vote
890                                                 {
891                                                         vote_caller = caller;
892                                                         vote_called = VOTE_MASTER;
893                                                         vote_called_command = strzone("XXX");
894                                                         vote_called_display = strzone("^3master");
895                                                         vote_endtime = time + autocvar_sv_vote_timeout;
896                                                         
897                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
898                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
899                                                         
900                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
901                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
902                                                         Nagger_VoteChanged();
903                                                         VoteCount(TRUE); // needed if you are the only one
904                                                 }
905                                                 
906                                                 return;
907                                         }
908                                 }
909                         }
910                         else { print_to(caller, "^1Master control of voting is not allowed."); }
911                         
912                         return;
913                 }
914                         
915                 default:
916                 case CMD_REQUEST_USAGE:
917                 {
918                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
919                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
920                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
921                         return;
922                 }
923         }
924 }
925
926 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
927 {
928         switch(request)
929         {
930                 case CMD_REQUEST_COMMAND:
931                 {
932                         if not(vote_called) { print_to(caller, "^1No vote called."); }
933                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
934                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
935                         
936                         else // everything went okay, continue changing vote
937                         {
938                                 print_to(caller, "^1You rejected the vote.");
939                                 caller.vote_selection = VOTE_SELECT_REJECT;
940                                 msg_entity = caller;
941                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
942                         }
943                         
944                         return;
945                 }
946                         
947                 default:
948                 case CMD_REQUEST_USAGE:
949                 {
950                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
951                         print_to(caller, "  No arguments required.");
952                         return;
953                 }
954         }
955 }
956
957 void VoteCommand_status(float request, entity caller) // BOTH
958 {
959         switch(request)
960         {
961                 case CMD_REQUEST_COMMAND:
962                 {
963                         if(vote_called)
964                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
965                         else
966                                 print_to(caller, "^1No vote called.");
967                                 
968                         return;
969                 }
970                         
971                 default:
972                 case CMD_REQUEST_USAGE:
973                 {
974                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
975                         print_to(caller, "  No arguments required.");
976                         return;
977                 }
978         }
979 }
980
981 void VoteCommand_stop(float request, entity caller) // BOTH
982 {
983         switch(request)
984         {
985                 case CMD_REQUEST_COMMAND:
986                 {
987                         if not(vote_called) { print_to(caller, "^1No vote called."); }
988                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
989                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
990                         
991                         return;
992                 }
993                         
994                 default:
995                 case CMD_REQUEST_USAGE:
996                 {
997                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
998                         print_to(caller, "  No arguments required.");
999                         return;
1000                 }
1001         }
1002 }
1003
1004 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1005 {
1006         switch(request)
1007         {
1008                 case CMD_REQUEST_COMMAND:
1009                 {
1010                         if not(vote_called) { print_to(caller, "^1No vote called."); }
1011                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1012                         
1013                         else // everything went okay, continue changing vote
1014                         {
1015                                 print_to(caller, "^1You accepted the vote.");
1016                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1017                                 msg_entity = caller;
1018                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
1019                         }
1020                         
1021                         return;
1022                 }
1023                         
1024                 default:
1025                 case CMD_REQUEST_USAGE:
1026                 {
1027                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1028                         print_to(caller, "  No arguments required.");
1029                         return;
1030                 }
1031         }
1032 }
1033
1034 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1035 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1036 void VoteCommand_(float request)
1037 {
1038         switch(request)
1039         {
1040                 case CMD_REQUEST_COMMAND:
1041                 {
1042                         
1043                         return;
1044                 }
1045                         
1046                 default:
1047                 case CMD_REQUEST_USAGE:
1048                 {
1049                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1050                         print_to(caller, "  No arguments required.");
1051                         return;
1052                 }
1053         }
1054 }
1055 */
1056
1057
1058 // ================================
1059 //  Macro system for vote commands
1060 // ================================
1061
1062 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1063 #define VOTE_COMMANDS(request,caller,arguments,command) \
1064         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1065         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1066         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1067         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1068         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1069         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1070         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1071         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1072         /* nothing */
1073
1074 void VoteCommand_macro_help(entity caller, float argc)
1075 {
1076         string command_origin = GetCommandPrefix(caller);
1077         
1078         if(argc == 2) // help display listing all commands
1079         {
1080                 print_to(caller, "\nVoting commands:\n");
1081                 #define VOTE_COMMAND(name,function,description,assignment) \
1082                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1083                         
1084                 VOTE_COMMANDS(0, caller, 0, "")
1085                 #undef VOTE_COMMAND
1086                 
1087                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1088                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1089                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1090         }
1091         else // usage for individual command
1092         {
1093                 #define VOTE_COMMAND(name,function,description,assignment) \
1094                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1095                         
1096                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1097                 #undef VOTE_COMMAND
1098         }
1099         
1100         return;
1101 }
1102
1103 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1104 {
1105         #define VOTE_COMMAND(name,function,description,assignment) \
1106                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1107                 
1108         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1109         #undef VOTE_COMMAND
1110         
1111         return FALSE;
1112 }
1113
1114
1115 // ======================================
1116 //  Main function handling vote commands
1117 // ======================================
1118
1119 void VoteCommand(float request, entity caller, float argc, string vote_command) 
1120 {
1121         // Guide for working with argc arguments by example:
1122         // argc:   1    - 2      - 3     - 4
1123         // argv:   0    - 1      - 2     - 3 
1124         // cmd     vote - master - login - password
1125         
1126         switch(request)
1127         {
1128                 case CMD_REQUEST_COMMAND:
1129                 {
1130                         if(VoteCommand_macro_command(caller, argc, vote_command))
1131                                 return;
1132                 }
1133                         
1134                 default:
1135                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1136                 case CMD_REQUEST_USAGE:
1137                 {
1138                         VoteCommand_macro_help(caller, argc);
1139                         return;
1140                 }
1141         }
1142 }