Replace `MAP(IDENTITY)` with `UNWORDS`
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / vote.qc
1 #include "../../common/command/command.qh"
2 #include "vote.qh"
3 #include "../_all.qh"
4
5 #include "common.qh"
6
7 #include "../g_damage.qh"
8 #include "../g_world.qh"
9 #include "../race.qh"
10 #include "../round_handler.qh"
11 #include "../scores.qh"
12
13 #include "../mutators/mutators_include.qh"
14
15 #include "../../common/constants.qh"
16 #include "../../common/mapinfo.qh"
17 #include "../../common/notifications.qh"
18 #include "../../common/playerstats.qh"
19 #include "../../common/util.qh"
20
21 // =============================================
22 //  Server side voting code, reworked by Samual
23 //  Last updated: December 27th, 2011
24 // =============================================
25
26 //  Nagger for players to know status of voting
27 float Nagger_SendEntity(entity to, float sendflags)
28 {
29         int nags, i, f, b;
30         entity e;
31         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
32
33         // bits:
34         //   1 = ready
35         //   2 = player needs to ready up
36         //   4 = vote
37         //   8 = player needs to vote
38         //  16 = warmup
39         // sendflags:
40         //  64 = vote counts
41         // 128 = vote string
42
43         nags = 0;
44         if(readycount)
45         {
46                 nags |= 1;
47                 if(to.ready == 0)
48                         nags |= 2;
49         }
50         if(vote_called)
51         {
52                 nags |= 4;
53                 if(to.vote_selection == 0)
54                         nags |= 8;
55         }
56         if(warmup_stage)
57                 nags |= 16;
58
59         if(sendflags & 64)
60                 nags |= 64;
61
62         if(sendflags & 128)
63                 nags |= 128;
64
65         if(!(nags & 4)) // no vote called? send no string
66                 nags &= ~(64 | 128);
67
68         WriteByte(MSG_ENTITY, nags);
69
70         if(nags & 64)
71         {
72                 WriteByte(MSG_ENTITY, vote_accept_count);
73                 WriteByte(MSG_ENTITY, vote_reject_count);
74                 WriteByte(MSG_ENTITY, vote_needed_overall);
75                 WriteChar(MSG_ENTITY, to.vote_selection);
76         }
77
78         if(nags & 128)
79                 WriteString(MSG_ENTITY, vote_called_display);
80
81         if(nags & 1)
82         {
83                 for(i = 1; i <= maxclients; i += 8)
84                 {
85                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
86                                 if(!IS_REAL_CLIENT(e) || e.ready)
87                                         f |= b;
88                         WriteByte(MSG_ENTITY, f);
89                 }
90         }
91
92         return true;
93 }
94
95 void Nagger_Init()
96 {
97         Net_LinkEntity(nagger = spawn(), false, 0, Nagger_SendEntity);
98 }
99
100 void Nagger_VoteChanged()
101 {
102         if(nagger)
103                 nagger.SendFlags |= 128;
104 }
105
106 void Nagger_VoteCountChanged()
107 {
108         if(nagger)
109                 nagger.SendFlags |= 64;
110 }
111
112 void Nagger_ReadyCounted()
113 {
114         if(nagger)
115                 nagger.SendFlags |= 1;
116 }
117
118
119 // =======================
120 //  Game logic for voting
121 // =======================
122
123 void VoteReset()
124 {
125         entity tmp_player;
126
127         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
128
129         if(vote_called)
130         {
131                 strunzone(vote_called_command);
132                 strunzone(vote_called_display);
133         }
134
135         vote_called = VOTE_NULL;
136         vote_caller = world;
137         vote_endtime = 0;
138
139         vote_called_command = string_null;
140         vote_called_display = string_null;
141
142         vote_parsed_command = string_null;
143         vote_parsed_display = string_null;
144
145         Nagger_VoteChanged();
146 }
147
148 void VoteStop(entity stopper)
149 {
150         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
151         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
152
153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
154         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
155
156         VoteReset();
157 }
158
159 void VoteAccept()
160 {
161         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
162
163         if((vote_called == VOTE_MASTER) && vote_caller)
164                 vote_caller.vote_master = 1;
165         else
166                 localcmd(strcat(vote_called_command, "\n"));
167
168         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
169
170         VoteReset();
171         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
172 }
173
174 void VoteReject()
175 {
176         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
177         VoteReset();
178         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
179 }
180
181 void VoteTimeout()
182 {
183         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
184         VoteReset();
185         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
186 }
187
188 void VoteSpam(float notvoters, float mincount, string result)
189 {
190         bprint(strcat(
191                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
192                 strcat("^2:^1", ftos(vote_reject_count)),
193                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
194                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
195                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
196
197         if(autocvar_sv_eventlog)
198         {
199                 GameLogEcho(strcat(
200                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
201                         strcat(":", ftos(vote_reject_count)),
202                         strcat(":", ftos(vote_abstain_count)),
203                         strcat(":", ftos(notvoters)),
204                         strcat(":", ftos(mincount))));
205         }
206 }
207
208 void VoteCount(float first_count)
209 {
210         // declarations
211         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
212
213         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
214                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
215                                 || (autocvar_sv_vote_nospectators == 0));
216
217         float vote_player_count = 0, notvoters = 0;
218         float vote_real_player_count = 0, vote_real_accept_count = 0;
219         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
220         float vote_needed_of_voted, final_needed_votes;
221         float vote_factor_overall, vote_factor_of_voted;
222
223         entity tmp_player;
224
225         Nagger_VoteCountChanged();
226
227         // add up all the votes from each connected client
228         FOR_EACH_REALCLIENT(tmp_player)
229         {
230                 ++vote_player_count;
231                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
232
233                 switch(tmp_player.vote_selection)
234                 {
235                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
236                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break; }
237                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
238                         default: break;
239                 }
240         }
241
242         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
243         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
244         {
245                 if(vote_caller) { vote_caller.vote_waittime = 0; }
246                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
247                 VoteReset();
248                 return;
249         }
250
251         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
252         if(!spectators_allowed && (vote_real_player_count > 0))
253         {
254                 vote_accept_count = vote_real_accept_count;
255                 vote_reject_count = vote_real_reject_count;
256                 vote_abstain_count = vote_real_abstain_count;
257                 vote_player_count = vote_real_player_count;
258         }
259
260         // people who have no opinion in any way :D
261         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
262
263         // determine the goal for the vote to be passed or rejected normally
264         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
265         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
266
267         // if the vote times out, determine the amount of votes needed of the people who actually already voted
268         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
269         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
270
271         // are there any players at all on the server? it could be an admin vote
272         if(vote_player_count == 0 && first_count)
273         {
274                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
275                 VoteAccept();
276                 return;
277         }
278
279         // since there ARE players, finally calculate the result of the vote
280         if(vote_accept_count >= vote_needed_overall)
281         {
282                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
283                 VoteAccept();
284                 return;
285         }
286
287         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
288         {
289                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
290                 VoteReject();
291                 return;
292         }
293
294         // there is not enough votes in either direction, now lets just calculate what the voters have said
295         if(time > vote_endtime)
296         {
297                 final_needed_votes = vote_needed_overall;
298
299                 if(autocvar_sv_vote_majority_factor_of_voted)
300                 {
301                         if(vote_accept_count >= vote_needed_of_voted)
302                         {
303                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
304                                 VoteAccept();
305                                 return;
306                         }
307
308                         if(vote_accept_count + vote_reject_count > 0)
309                         {
310                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
311                                 VoteReject();
312                                 return;
313                         }
314
315                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
316                 }
317
318                 // it didn't pass or fail, so not enough votes to even make a decision.
319                 VoteSpam(notvoters, final_needed_votes, "timeout");
320                 VoteTimeout();
321         }
322 }
323
324 void VoteThink()
325 {
326         if(vote_endtime > 0) // a vote was called
327         if(time > vote_endtime) // time is up
328         {
329                 VoteCount(false);
330         }
331
332         return;
333 }
334
335
336 // =======================
337 //  Game logic for warmup
338 // =======================
339
340 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
341 void reset_map(float dorespawn)
342 {
343         entity oldself;
344         oldself = self;
345
346         if(time <= game_starttime && round_handler_IsActive())
347                 round_handler_Reset(game_starttime);
348
349         MUTATOR_CALLHOOK(reset_map_global);
350
351         for(self = world; (self = nextent(self)); )
352         if(IS_NOT_A_CLIENT(self))
353         {
354                 if(self.reset)
355                 {
356                         self.reset();
357                         continue;
358                 }
359
360                 if(self.team_saved)
361                         self.team = self.team_saved;
362
363                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
364                         remove(self);
365         }
366
367         // Waypoints and assault start come LAST
368         for(self = world; (self = nextent(self)); )
369         if(IS_NOT_A_CLIENT(self))
370         {
371                 if(self.reset2)
372                 {
373                         self.reset2();
374                         continue;
375                 }
376         }
377
378         FOR_EACH_PLAYER(self)
379         if(self.frozen)
380                 Unfreeze(self);
381
382         // Moving the player reset code here since the player-reset depends
383         // on spawnpoint entities which have to be reset first --blub
384         if(dorespawn)
385         if(!MUTATOR_CALLHOOK(reset_map_players))
386         FOR_EACH_CLIENT(self) // reset all players
387         {
388                 /*
389                 only reset players if a restart countdown is active
390                 this can either be due to cvar sv_ready_restart_after_countdown having set
391                 restart_mapalreadyrestarted to 1 after the countdown ended or when
392                 sv_ready_restart_after_countdown is not used and countdown is still running
393                 */
394                 if (restart_mapalreadyrestarted || (time < game_starttime))
395                 {
396                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
397                         if (IS_PLAYER(self)) {
398                                 //PlayerScore_Clear(self);
399                                 self.killcount = 0;
400                                 //stop the player from moving so that he stands still once he gets respawned
401                                 self.velocity = '0 0 0';
402                                 self.avelocity = '0 0 0';
403                                 self.movement = '0 0 0';
404                                 PutClientInServer();
405                         }
406                 }
407         }
408
409         if(g_keyhunt)
410                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
411
412         self = oldself;
413 }
414
415 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
416 void ReadyRestart_think()
417 {
418         restart_mapalreadyrestarted = 1;
419         reset_map(true);
420         Score_ClearAll();
421         remove(self);
422
423         return;
424 }
425
426 // Forces a restart of the game without actually reloading the map // this is a mess...
427 void ReadyRestart_force()
428 {
429         entity tmp_player, restart_timer;
430
431         bprint("^1Server is restarting...\n");
432
433         VoteReset();
434
435         // clear overtime, we have to decrease timelimit to its original value again.
436         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
437
438         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
439
440         readyrestart_happened = 1;
441         game_starttime = time + RESTART_COUNTDOWN;
442
443         // clear player attributes
444         FOR_EACH_CLIENT(tmp_player)
445         {
446                 tmp_player.alivetime = 0;
447                 tmp_player.killcount = 0;
448                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
449         }
450
451         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
452
453         // disable the warmup global for the server
454         warmup_stage = 0; // once the game is restarted the game is in match stage
455
456         // reset the .ready status of all players (also spectators)
457         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
458         readycount = 0;
459         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
460
461         // lock teams with lockonrestart
462         if(autocvar_teamplay_lockonrestart && teamplay)
463         {
464                 lockteams = 1;
465                 bprint("^1The teams are now locked.\n");
466         }
467
468         //initiate the restart-countdown-announcer entity
469         if(autocvar_sv_ready_restart_after_countdown)
470         {
471                 restart_timer = spawn();
472                 restart_timer.think = ReadyRestart_think;
473                 restart_timer.nextthink = game_starttime;
474         }
475
476         // after a restart every players number of allowed timeouts gets reset, too
477         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
478
479         //reset map immediately if this cvar is not set
480         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(true); }
481
482         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
483 }
484
485 void ReadyRestart()
486 {
487         // no arena, assault support yet...
488         if(g_assault | gameover | intermission_running | race_completing)
489                 localcmd("restart\n");
490         else
491                 localcmd("\nsv_hook_gamerestart\n");
492
493         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
494         // Otherwise scores could be manipulated during the countdown.
495         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
496
497         ReadyRestart_force();
498
499         return;
500 }
501
502 // Count the players who are ready and determine whether or not to restart the match
503 void ReadyCount()
504 {
505         entity tmp_player;
506         float ready_needed_factor, ready_needed_count;
507         float t_ready = 0, t_players = 0;
508
509         FOR_EACH_REALCLIENT(tmp_player)
510         {
511                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
512                 {
513                         ++t_players;
514                         if(tmp_player.ready) { ++t_ready; }
515                 }
516         }
517
518         readycount = t_ready;
519
520         Nagger_ReadyCounted();
521
522         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
523         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
524
525         if(readycount >= ready_needed_count)
526         {
527                 ReadyRestart();
528         }
529
530         return;
531 }
532
533
534 // ======================================
535 //  Supporting functions for VoteCommand
536 // ======================================
537
538 float Votecommand_check_assignment(entity caller, float assignment)
539 {
540         float from_server = (!caller);
541
542         if((assignment == VC_ASGNMNT_BOTH)
543                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
544                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
545         {
546                 return true;
547         }
548
549         return false;
550 }
551
552 string VoteCommand_extractcommand(string input, float startpos, float argc)
553 {
554         string output;
555
556         if((argc - 1) < startpos)
557                 output = "";
558         else
559                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
560
561         return output;
562 }
563
564 float VoteCommand_checknasty(string vote_command)
565 {
566         if((strstrofs(vote_command, ";", 0) >= 0)
567                 || (strstrofs(vote_command, "\n", 0) >= 0)
568                 || (strstrofs(vote_command, "\r", 0) >= 0)
569                 || (strstrofs(vote_command, "$", 0) >= 0))
570                 return false;
571
572         return true;
573 }
574
575 float VoteCommand_checkinlist(string vote_command, string list)
576 {
577         string l = strcat(" ", list, " ");
578
579         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
580                 return true;
581
582         return false;
583 }
584
585 string ValidateMap(string validated_map, entity caller)
586 {
587         validated_map = MapInfo_FixName(validated_map);
588
589         if (!validated_map)
590         {
591                 print_to(caller, "This map is not available on this server.");
592                 return string_null;
593         }
594
595         if(!autocvar_sv_vote_override_mostrecent && caller)
596         {
597                 if(Map_IsRecent(validated_map))
598                 {
599                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
600                         return string_null;
601                 }
602         }
603
604         if(!MapInfo_CheckMap(validated_map))
605         {
606                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
607                 return string_null;
608         }
609
610         return validated_map;
611 }
612
613 float VoteCommand_checkargs(float startpos, float argc)
614 {
615         float p, q, check, minargs;
616         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
617         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
618         string charlist, arg;
619         float checkmate;
620
621         if(cmdrestriction == "")
622                 return true;
623
624         ++startpos; // skip command name
625
626         // check minimum arg count
627
628         // 0 args: argc == startpos
629         // 1 args: argc == startpos + 1
630         // ...
631
632         minargs = stof(cmdrestriction);
633         if(argc - startpos < minargs)
634                 return false;
635
636         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
637
638         for (;;)
639         {
640                 // we know that at any time, startpos <= argc - minargs
641                 // so this means: argc-minargs >= startpos >= argc, thus
642                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
643                 // have been seen already
644
645                 if(startpos >= argc) // all args checked? GOOD
646                         break;
647
648                 if(p < 0) // no more args? FAIL
649                 {
650                         // exception: exactly minargs left, this one included
651                         if(argc - startpos == minargs)
652                                 break;
653
654                         // otherwise fail
655                         return false;
656                 }
657
658                 // cut to next semicolon
659                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
660                 if(q < 0)
661                         charlist = substring(cmdrestriction, p+1, -1);
662                 else
663                         charlist = substring(cmdrestriction, p+1, q - (p+1));
664
665                 // in case we ever want to allow semicolons in VoteCommand_checknasty
666                 // charlist = strreplace("^^", ";", charlist);
667
668                 if(charlist != "")
669                 {
670                         // verify the arg only contains allowed chars
671                         arg = argv(startpos);
672                         checkmate = strlen(arg);
673                         for(check = 0; check < checkmate; ++check)
674                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
675                                         return false; // not allowed character
676                         // all characters are allowed. FINE.
677                 }
678
679                 ++startpos;
680                 --minargs;
681                 p = q;
682         }
683
684         return true;
685 }
686
687 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
688 {
689         string first_command;
690
691         first_command = argv(startpos);
692
693         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
694                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
695                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
696         );*/
697
698         if(
699                 (autocvar_sv_vote_limit > 0)
700                 &&
701                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
702         )
703                 return false;
704
705         if (!VoteCommand_checkinlist(first_command, vote_list))
706                 return false;
707
708         if (!VoteCommand_checkargs(startpos, argc))
709                 return false;
710
711         switch(first_command) // now go through and parse the proper commands to adjust as needed.
712         {
713                 case "kick":
714                 case "kickban": // catch all kick/kickban commands
715                 {
716                         entity victim = GetIndexedEntity(argc, (startpos + 1));
717                         float accepted = VerifyClientEntity(victim, true, false);
718
719                         if(accepted > 0)
720                         {
721                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
722                                 string command_arguments;
723
724                                 if(first_command == "kickban")
725                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
726                                 else
727                                         command_arguments = reason;
728
729                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
730                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
731                         }
732                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
733
734                         break;
735                 }
736
737                 case "map":
738                 case "chmap":
739                 case "gotomap": // re-direct all map selection commands to gotomap
740                 {
741                         vote_command = ValidateMap(argv(startpos + 1), caller);
742                         if (!vote_command) { return false; }
743                         vote_parsed_command = strcat("gotomap ", vote_command);
744                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
745
746                         break;
747                 }
748
749                 default:
750                 {
751                         vote_parsed_command = vote_command;
752                         vote_parsed_display = strzone(strcat("^1", vote_command));
753
754                         break;
755                 }
756         }
757
758         return true;
759 }
760
761
762 // =======================
763 //  Command Sub-Functions
764 // =======================
765
766 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
767 {
768         switch(request)
769         {
770                 case CMD_REQUEST_COMMAND:
771                 {
772                         if (!vote_called) { print_to(caller, "^1No vote called."); }
773                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
774
775                         else // everything went okay, continue changing vote
776                         {
777                                 print_to(caller, "^1You abstained from your vote.");
778                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
779                                 msg_entity = caller;
780                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
781                         }
782
783                         return;
784                 }
785
786                 default:
787                 case CMD_REQUEST_USAGE:
788                 {
789                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
790                         print_to(caller, "  No arguments required.");
791                         return;
792                 }
793         }
794 }
795
796 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
797 {
798         switch(request)
799         {
800                 case CMD_REQUEST_COMMAND:
801                 {
802                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
803                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
804                                 || (autocvar_sv_vote_nospectators == 0));
805
806                         float tmp_playercount = 0;
807                         entity tmp_player;
808
809                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
810
811                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
812                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
813                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
814                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
815                         else if(caller && !IS_CLIENT(caller)) { print_to(caller, "^1Only connected clients can vote."); }
816                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
817                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
818                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
819                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
820
821                         else // everything went okay, continue with calling the vote
822                         {
823                                 vote_caller = caller; // remember who called the vote
824                                 vote_called = VOTE_NORMAL;
825                                 vote_called_command = strzone(vote_parsed_command);
826                                 vote_called_display = strzone(vote_parsed_display);
827                                 vote_endtime = time + autocvar_sv_vote_timeout;
828
829                                 if(caller)
830                                 {
831                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
832                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
833                                         msg_entity = caller;
834                                 }
835
836                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
837                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
838
839                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
840                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
841                                 Nagger_VoteChanged();
842                                 VoteCount(true); // needed if you are the only one
843                         }
844
845                         return;
846                 }
847
848                 default:
849                 case CMD_REQUEST_USAGE:
850                 {
851                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
852                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
853                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
854                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
855                         return;
856                 }
857         }
858 }
859
860 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
861 {
862         switch(request)
863         {
864                 case CMD_REQUEST_COMMAND:
865                 {
866                         if(autocvar_sv_vote_master)
867                         {
868                                 switch(strtolower(argv(2)))
869                                 {
870                                         case "do":
871                                         {
872                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
873
874                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
875                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
876                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
877
878                                                 else // everything went okay, proceed with command
879                                                 {
880                                                         localcmd(strcat(vote_parsed_command, "\n"));
881                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
882                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
883                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
884                                                 }
885
886                                                 return;
887                                         }
888
889                                         case "login":
890                                         {
891                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
892                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
893                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
894
895                                                 else // everything went okay, proceed with giving this player master privilages
896                                                 {
897                                                         caller.vote_master = true;
898                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
899                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
900                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
901                                                 }
902
903                                                 return;
904                                         }
905
906                                         default: // calling a vote for master
907                                         {
908                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
909                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
910                                                         || (autocvar_sv_vote_nospectators == 0));
911
912                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
913                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
914                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
915                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
916
917                                                 else // everything went okay, continue with creating vote
918                                                 {
919                                                         vote_caller = caller;
920                                                         vote_called = VOTE_MASTER;
921                                                         vote_called_command = strzone("XXX");
922                                                         vote_called_display = strzone("^3master");
923                                                         vote_endtime = time + autocvar_sv_vote_timeout;
924
925                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
926                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
927
928                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
929                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
930                                                         Nagger_VoteChanged();
931                                                         VoteCount(true); // needed if you are the only one
932                                                 }
933
934                                                 return;
935                                         }
936                                 }
937                         }
938                         else { print_to(caller, "^1Master control of voting is not allowed."); }
939
940                         return;
941                 }
942
943                 default:
944                 case CMD_REQUEST_USAGE:
945                 {
946                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
947                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
948                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
949                         return;
950                 }
951         }
952 }
953
954 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
955 {
956         switch(request)
957         {
958                 case CMD_REQUEST_COMMAND:
959                 {
960                         if (!vote_called) { print_to(caller, "^1No vote called."); }
961                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
962                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
963
964                         else // everything went okay, continue changing vote
965                         {
966                                 print_to(caller, "^1You rejected the vote.");
967                                 caller.vote_selection = VOTE_SELECT_REJECT;
968                                 msg_entity = caller;
969                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
970                         }
971
972                         return;
973                 }
974
975                 default:
976                 case CMD_REQUEST_USAGE:
977                 {
978                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
979                         print_to(caller, "  No arguments required.");
980                         return;
981                 }
982         }
983 }
984
985 void VoteCommand_status(float request, entity caller) // BOTH
986 {
987         switch(request)
988         {
989                 case CMD_REQUEST_COMMAND:
990                 {
991                         if(vote_called)
992                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
993                         else
994                                 print_to(caller, "^1No vote called.");
995
996                         return;
997                 }
998
999                 default:
1000                 case CMD_REQUEST_USAGE:
1001                 {
1002                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1003                         print_to(caller, "  No arguments required.");
1004                         return;
1005                 }
1006         }
1007 }
1008
1009 void VoteCommand_stop(float request, entity caller) // BOTH
1010 {
1011         switch(request)
1012         {
1013                 case CMD_REQUEST_COMMAND:
1014                 {
1015                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1016                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
1017                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
1018
1019                         return;
1020                 }
1021
1022                 default:
1023                 case CMD_REQUEST_USAGE:
1024                 {
1025                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1026                         print_to(caller, "  No arguments required.");
1027                         return;
1028                 }
1029         }
1030 }
1031
1032 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1033 {
1034         switch(request)
1035         {
1036                 case CMD_REQUEST_COMMAND:
1037                 {
1038                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1039                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1040
1041                         else // everything went okay, continue changing vote
1042                         {
1043                                 print_to(caller, "^1You accepted the vote.");
1044                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1045                                 msg_entity = caller;
1046                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
1047                         }
1048
1049                         return;
1050                 }
1051
1052                 default:
1053                 case CMD_REQUEST_USAGE:
1054                 {
1055                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1056                         print_to(caller, "  No arguments required.");
1057                         return;
1058                 }
1059         }
1060 }
1061
1062 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1063 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1064 void VoteCommand_(float request)
1065 {
1066         switch(request)
1067         {
1068                 case CMD_REQUEST_COMMAND:
1069                 {
1070
1071                         return;
1072                 }
1073
1074                 default:
1075                 case CMD_REQUEST_USAGE:
1076                 {
1077                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1078                         print_to(caller, "  No arguments required.");
1079                         return;
1080                 }
1081         }
1082 }
1083 */
1084
1085
1086 // ================================
1087 //  Macro system for vote commands
1088 // ================================
1089
1090 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1091 #define VOTE_COMMANDS(request,caller,arguments,command) \
1092         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1093         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1094         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1095         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1096         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1097         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1098         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1099         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1100         /* nothing */
1101
1102 void VoteCommand_macro_help(entity caller, float argc)
1103 {
1104         string command_origin = GetCommandPrefix(caller);
1105
1106         if(argc == 2 || argv(2) == "help") // help display listing all commands
1107         {
1108                 print_to(caller, "\nVoting commands:\n");
1109                 #define VOTE_COMMAND(name,function,description,assignment) \
1110                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1111
1112                 VOTE_COMMANDS(0, caller, 0, "");
1113                 #undef VOTE_COMMAND
1114
1115                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1116                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1117                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1118         }
1119         else // usage for individual command
1120         {
1121                 #define VOTE_COMMAND(name,function,description,assignment) \
1122                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1123
1124                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1125                 #undef VOTE_COMMAND
1126         }
1127
1128         return;
1129 }
1130
1131 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1132 {
1133         #define VOTE_COMMAND(name,function,description,assignment) \
1134                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return true; } } }
1135
1136         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1137         #undef VOTE_COMMAND
1138
1139         return false;
1140 }
1141
1142
1143 // ======================================
1144 //  Main function handling vote commands
1145 // ======================================
1146
1147 void VoteCommand(float request, entity caller, float argc, string vote_command)
1148 {
1149         // Guide for working with argc arguments by example:
1150         // argc:   1    - 2      - 3     - 4
1151         // argv:   0    - 1      - 2     - 3
1152         // cmd     vote - master - login - password
1153
1154         switch(request)
1155         {
1156                 case CMD_REQUEST_COMMAND:
1157                 {
1158                         if(VoteCommand_macro_command(caller, argc, vote_command))
1159                                 return;
1160                 }
1161
1162                 default:
1163                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1164                 case CMD_REQUEST_USAGE:
1165                 {
1166                         VoteCommand_macro_help(caller, argc);
1167                         return;
1168                 }
1169         }
1170 }