qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7 #include "vote.qh"
   8
   9 #include "common.qh"
  10
  11 #include "../g_damage.qh"
  12 #include "../g_world.qh"
  13 #include "../race.qh"
  14 #include "../round_handler.qh"
  15 #include "../scores.qh"
  16
  17 #include "../mutators/_mod.qh"
  18
  19 #include <common/constants.qh>
  20 #include <common/net_linked.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/notifications/all.qh>
  23 #include <common/playerstats.qh>
  24 #include <common/util.qh>
  25
  26 // =============================================
  27 //  Server side voting code, reworked by Samual
  28 //  Last updated: December 27th, 2011
  29 // =============================================
  30
  31 //  Nagger for players to know status of voting
  32 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  33 {
  34         int nags, i, f, b;
  35         entity e;
  36         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  37
  38         // bits:
  39         //   1 = ready
  40         //   2 = player needs to ready up
  41         //   4 = vote
  42         //   8 = player needs to vote
  43         //  16 = warmup
  44         // sendflags:
  45         //  64 = vote counts
  46         // 128 = vote string
  47
  48         nags = 0;
  49         if (readycount)
  50         {
  51                 nags |= BIT(0);
  52                 if (to.ready == 0) nags |= BIT(1);
  53         }
  54         if (vote_called)
  55         {
  56                 nags |= BIT(2);
  57                 if (to.vote_selection == 0) nags |= BIT(3);
  58         }
  59         if (warmup_stage) nags |= BIT(4);
  60
  61         if (sendflags & BIT(6)) nags |= BIT(6);
  62
  63         if (sendflags & BIT(7)) nags |= BIT(7);
  64
  65         if (!(nags & 4))  // no vote called? send no string
  66                 nags &= ~(BIT(6) | BIT(7));
  67
  68         WriteByte(MSG_ENTITY, nags);
  69
  70         if (nags & BIT(6))
  71         {
  72                 WriteByte(MSG_ENTITY, vote_accept_count);
  73                 WriteByte(MSG_ENTITY, vote_reject_count);
  74                 WriteByte(MSG_ENTITY, vote_needed_overall);
  75                 WriteChar(MSG_ENTITY, to.vote_selection);
  76         }
  77
  78         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  79
  80         if (nags & 1)
  81         {
  82                 for (i = 1; i <= maxclients; i += 8)
  83                 {
  84                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  85                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  86                         WriteByte(MSG_ENTITY, f);
  87                 }
  88         }
  89
  90         return true;
  91 }
  92
  93 void Nagger_Init()
  94 {
  95         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  96 }
  97
  98 void Nagger_VoteChanged()
  99 {
 100         if (nagger) nagger.SendFlags |= BIT(7);
 101 }
 102
 103 void Nagger_VoteCountChanged()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(6);
 106 }
 107
 108 void Nagger_ReadyCounted()
 109 {
 110         if (nagger) nagger.SendFlags |= BIT(0);
 111 }
 112
 113 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 114 string OriginalCallerName()
 115 {
 116         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller, false);
 117         return vote_caller_name;
 118 }
 119
 120 // =======================
 121 //  Game logic for voting
 122 // =======================
 123
 124 void VoteReset()
 125 {
 126         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 127
 128         if (vote_called)
 129         {
 130                 strunzone(vote_called_command);
 131                 strunzone(vote_called_display);
 132                 strunzone(vote_caller_name);
 133         }
 134
 135         vote_called = VOTE_NULL;
 136         vote_caller = NULL;
 137         vote_caller_name = string_null;
 138         vote_endtime = 0;
 139
 140         vote_called_command = string_null;
 141         vote_called_display = string_null;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 152         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 154         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 155         VoteReset();
 156 }
 157
 158 void VoteAccept()
 159 {
 160         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 161
 162         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 163         else localcmd(strcat(vote_called_command, "\n"));
 164
 165         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 166
 167         VoteReset();
 168         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 169 }
 170
 171 void VoteReject()
 172 {
 173         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 174         VoteReset();
 175         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 176 }
 177
 178 void VoteTimeout()
 179 {
 180         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 181         VoteReset();
 182         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 183 }
 184
 185 void VoteSpam(float notvoters, float mincount, string result)
 186 {
 187         bprint(strcat(
 188                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 189                 strcat("^2:^1", ftos(vote_reject_count)),
 190                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 191                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 192                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 193
 194         if (autocvar_sv_eventlog)
 195         {
 196                 GameLogEcho(strcat(
 197                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 198                         strcat(":", ftos(vote_reject_count)),
 199                         strcat(":", ftos(vote_abstain_count)),
 200                         strcat(":", ftos(notvoters)),
 201                         strcat(":", ftos(mincount))));
 202         }
 203 }
 204
 205 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 206
 207 void VoteCount(float first_count)
 208 {
 209         // declarations
 210         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 211
 212         float vote_player_count = 0, notvoters = 0;
 213         float vote_real_player_count = 0, vote_real_accept_count = 0;
 214         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 215         float vote_needed_of_voted, final_needed_votes;
 216         float vote_factor_overall, vote_factor_of_voted;
 217
 218         Nagger_VoteCountChanged();
 219
 220         // add up all the votes from each connected client
 221         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 222                 ++vote_player_count;
 223                 if (IS_PLAYER(it))   ++vote_real_player_count;
 224                 switch (it.vote_selection)
 225                 {
 226                         case VOTE_SELECT_REJECT:
 227                         { ++vote_reject_count;
 228                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 229                         }
 230                         case VOTE_SELECT_ACCEPT:
 231                         { ++vote_accept_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 233                         }
 234                         case VOTE_SELECT_ABSTAIN:
 235                         { ++vote_abstain_count;
 236                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 237                         }
 238                         default: break;
 239                 }
 240         });
 241
 242         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 243         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 244         {
 245                 if (vote_caller)   vote_caller.vote_waittime = 0;
 246                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 247                 VoteReset();
 248                 return;
 249         }
 250
 251         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 252         if (!spectators_allowed && (vote_real_player_count > 0))
 253         {
 254                 vote_accept_count = vote_real_accept_count;
 255                 vote_reject_count = vote_real_reject_count;
 256                 vote_abstain_count = vote_real_abstain_count;
 257                 vote_player_count = vote_real_player_count;
 258         }
 259
 260         // people who have no opinion in any way :D
 261         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 262
 263         // determine the goal for the vote to be passed or rejected normally
 264         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 265         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 266
 267         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 268         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 269         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 270
 271         // are there any players at all on the server? it could be an admin vote
 272         if (vote_player_count == 0 && first_count)
 273         {
 274                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 275                 VoteAccept();
 276                 return;
 277         }
 278
 279         // since there ARE players, finally calculate the result of the vote
 280         if (vote_accept_count >= vote_needed_overall)
 281         {
 282                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 283                 VoteAccept();
 284                 return;
 285         }
 286
 287         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 288         {
 289                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 290                 VoteReject();
 291                 return;
 292         }
 293
 294         // there is not enough votes in either direction, now lets just calculate what the voters have said
 295         if (time > vote_endtime)
 296         {
 297                 final_needed_votes = vote_needed_overall;
 298
 299                 if (autocvar_sv_vote_majority_factor_of_voted)
 300                 {
 301                         if (vote_accept_count >= vote_needed_of_voted)
 302                         {
 303                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 304                                 VoteAccept();
 305                                 return;
 306                         }
 307
 308                         if (vote_accept_count + vote_reject_count > 0)
 309                         {
 310                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 311                                 VoteReject();
 312                                 return;
 313                         }
 314
 315                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 316                 }
 317
 318                 // it didn't pass or fail, so not enough votes to even make a decision.
 319                 VoteSpam(notvoters, final_needed_votes, "timeout");
 320                 VoteTimeout();
 321         }
 322 }
 323
 324 void VoteThink()
 325 {
 326         if (vote_endtime > 0)        // a vote was called
 327         {
 328                 if (time > vote_endtime) // time is up
 329                         VoteCount(false);
 330         }
 331 }
 332
 333
 334 // =======================
 335 //  Game logic for warmup
 336 // =======================
 337
 338 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 339 void reset_map(bool dorespawn)
 340 {
 341         if (time <= game_starttime)
 342         {
 343                 if (game_stopped)
 344                         return;
 345                 if (round_handler_IsActive())
 346                         round_handler_Reset(game_starttime);
 347         }
 348
 349         MUTATOR_CALLHOOK(reset_map_global);
 350
 351         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 352         {
 353                 if(IS_CLIENT(it))
 354                         continue;
 355                 if (it.reset)
 356                 {
 357                         it.reset(it);
 358                         continue;
 359                 }
 360                 if (it.team_saved) it.team = it.team_saved;
 361                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 362         });
 363
 364         // Waypoints and assault start come LAST
 365         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 366                 if (it.reset2) it.reset2(it);
 367         });
 368
 369         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it); });
 370
 371         // Moving the player reset code here since the player-reset depends
 372         // on spawnpoint entities which have to be reset first --blub
 373         if (dorespawn)
 374         {
 375                 if (!MUTATOR_CALLHOOK(reset_map_players))
 376                 {
 377                         if (restart_mapalreadyrestarted || (time < game_starttime))
 378                         {
 379                                 FOREACH_CLIENT(IS_PLAYER(it),
 380                                 {
 381                                         /*
 382                                         only reset players if a restart countdown is active
 383                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 384                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 385                                         sv_ready_restart_after_countdown is not used and countdown is still running
 386                                         */
 387                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 388                                         // PlayerScore_Clear(it);
 389                                         CS(it).killcount = 0;
 390                                         // stop the player from moving so that he stands still once he gets respawned
 391                                         it.velocity = '0 0 0';
 392                                         it.avelocity = '0 0 0';
 393                                         CS(it).movement = '0 0 0';
 394                                         PutClientInServer(it);
 395                                 });
 396                         }
 397                 }
 398         }
 399 }
 400
 401 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 402 void ReadyRestart_think(entity this)
 403 {
 404         restart_mapalreadyrestarted = true;
 405         reset_map(true);
 406         Score_ClearAll();
 407         delete(this);
 408 }
 409
 410 // Forces a restart of the game without actually reloading the map // this is a mess...
 411 void ReadyRestart_force()
 412 {
 413         if (time <= game_starttime && game_stopped)
 414                 return;
 415
 416         bprint("^1Server is restarting...\n");
 417
 418         VoteReset();
 419
 420         // clear overtime, we have to decrease timelimit to its original value again.
 421         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 422                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 423         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 424
 425         readyrestart_happened = true;
 426         game_starttime = time + RESTART_COUNTDOWN;
 427
 428         // clear player attributes
 429         FOREACH_CLIENT(IS_PLAYER(it), {
 430                 it.alivetime = 0;
 431                 CS(it).killcount = 0;
 432                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
 433         });
 434
 435         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 436
 437         // disable the warmup global for the server
 438         warmup_stage = 0;                // once the game is restarted the game is in match stage
 439
 440         // reset the .ready status of all players (also spectators)
 441         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 442         readycount = 0;
 443         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 444
 445         // lock teams with lockonrestart
 446         if (autocvar_teamplay_lockonrestart && teamplay)
 447         {
 448                 lockteams = true;
 449                 bprint("^1The teams are now locked.\n");
 450         }
 451
 452         // initiate the restart-countdown-announcer entity
 453         if (autocvar_sv_ready_restart_after_countdown)
 454         {
 455                 entity restart_timer = new_pure(restart_timer);
 456                 setthink(restart_timer, ReadyRestart_think);
 457                 restart_timer.nextthink = game_starttime;
 458         }
 459
 460         // after a restart every players number of allowed timeouts gets reset, too
 461         if (autocvar_sv_timeout)
 462         {
 463                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 464         }
 465     // reset map immediately if this cvar is not set
 466     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 467         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 468 }
 469
 470 void ReadyRestart()
 471 {
 472         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || game_stopped || race_completing) localcmd("restart\n");
 473         else localcmd("\nsv_hook_gamerestart\n");
 474
 475         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 476         // Otherwise scores could be manipulated during the countdown.
 477         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 478         ReadyRestart_force();
 479 }
 480
 481 // Count the players who are ready and determine whether or not to restart the match
 482 void ReadyCount()
 483 {
 484         float ready_needed_factor, ready_needed_count;
 485         float t_ready = 0, t_players = 0;
 486
 487         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 488                 ++t_players;
 489                 if (it.ready) ++t_ready;
 490         });
 491
 492         readycount = t_ready;
 493
 494         Nagger_ReadyCounted();
 495
 496         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 497         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 498
 499         if (readycount >= ready_needed_count) ReadyRestart();
 500 }
 501
 502
 503 // ======================================
 504 //  Supporting functions for VoteCommand
 505 // ======================================
 506
 507 float Votecommand_check_assignment(entity caller, float assignment)
 508 {
 509         float from_server = (!caller);
 510
 511         if ((assignment == VC_ASGNMNT_BOTH)
 512             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 513             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 514
 515         return false;
 516 }
 517
 518 string VoteCommand_extractcommand(string input, float startpos, float argc)
 519 {
 520         string output;
 521
 522         if ((argc - 1) < startpos) output = "";
 523         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 524
 525         return output;
 526 }
 527
 528 float VoteCommand_checknasty(string vote_command)
 529 {
 530         if ((strstrofs(vote_command, ";", 0) >= 0)
 531             || (strstrofs(vote_command, "\n", 0) >= 0)
 532             || (strstrofs(vote_command, "\r", 0) >= 0)
 533             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 534
 535         return true;
 536 }
 537
 538 float VoteCommand_checkinlist(string vote_command, string list)
 539 {
 540         string l = strcat(" ", list, " ");
 541
 542         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 543
 544         return false;
 545 }
 546
 547 string ValidateMap(string validated_map, entity caller)
 548 {
 549         validated_map = MapInfo_FixName(validated_map);
 550
 551         if (!validated_map)
 552         {
 553                 print_to(caller, "This map is not available on this server.");
 554                 return string_null;
 555         }
 556
 557         if (!autocvar_sv_vote_override_mostrecent && caller)
 558         {
 559                 if (Map_IsRecent(validated_map))
 560                 {
 561                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 562                         return string_null;
 563                 }
 564         }
 565
 566         if (!MapInfo_CheckMap(validated_map))
 567         {
 568                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 569                 return string_null;
 570         }
 571
 572         return validated_map;
 573 }
 574
 575 float VoteCommand_checkargs(float startpos, float argc)
 576 {
 577         float p, q, check, minargs;
 578         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 579         string cmdrestriction = "";  // No we don't.
 580         string charlist, arg;
 581         float checkmate;
 582
 583         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 584                 cmdrestriction = cvar_string(cvarname);
 585         else
 586                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 587
 588         if (cmdrestriction == "") return true;
 589
 590         ++startpos;  // skip command name
 591
 592         // check minimum arg count
 593
 594         // 0 args: argc == startpos
 595         // 1 args: argc == startpos + 1
 596         // ...
 597
 598         minargs = stof(cmdrestriction);
 599         if (argc - startpos < minargs) return false;
 600
 601         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 602
 603         for ( ; ; )
 604         {
 605                 // we know that at any time, startpos <= argc - minargs
 606                 // so this means: argc-minargs >= startpos >= argc, thus
 607                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 608                 // have been seen already
 609
 610                 if (startpos >= argc) // all args checked? GOOD
 611                         break;
 612
 613                 if (p < 0)            // no more args? FAIL
 614                 {
 615                         // exception: exactly minargs left, this one included
 616                         if (argc - startpos == minargs) break;
 617
 618                         // otherwise fail
 619                         return false;
 620                 }
 621
 622                 // cut to next semicolon
 623                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 624                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 625                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 626
 627                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 628                 // charlist = strreplace("^^", ";", charlist);
 629
 630                 if (charlist != "")
 631                 {
 632                         // verify the arg only contains allowed chars
 633                         arg = argv(startpos);
 634                         checkmate = strlen(arg);
 635                         for (check = 0; check < checkmate; ++check)
 636                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 637                         // not allowed character
 638                         // all characters are allowed. FINE.
 639                 }
 640
 641                 ++startpos;
 642                 --minargs;
 643                 p = q;
 644         }
 645
 646         return true;
 647 }
 648
 649 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 650 {
 651         string first_command;
 652
 653         first_command = argv(startpos);
 654
 655         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 656             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 657             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 658         );*/
 659
 660         if (
 661             (autocvar_sv_vote_limit > 0)
 662             &&
 663             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 664            )   return 0;
 665
 666         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 667
 668         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 669
 670         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 671         {
 672                 case "kick":
 673                 case "kickban":    // catch all kick/kickban commands
 674                 {
 675                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 676                         float accepted = VerifyClientEntity(victim, true, false);
 677
 678                         if (accepted > 0)
 679                         {
 680                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 681                                 string command_arguments;
 682
 683                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 684                                 else command_arguments = reason;
 685
 686                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 687                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 688                         }
 689                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
 690
 691                         break;
 692                 }
 693
 694                 case "map":
 695                 case "chmap":
 696                 case "gotomap":  // re-direct all map selection commands to gotomap
 697                 {
 698                         vote_command = ValidateMap(argv(startpos + 1), caller);
 699                         if (!vote_command)  return -1;
 700                         vote_parsed_command = strcat("gotomap ", vote_command);
 701                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 702
 703                         break;
 704                 }
 705
 706                 default:
 707                 {
 708                         vote_parsed_command = vote_command;
 709                         vote_parsed_display = strzone(strcat("^1", vote_command));
 710
 711                         break;
 712                 }
 713         }
 714
 715         return 1;
 716 }
 717
 718
 719 // =======================
 720 //  Command Sub-Functions
 721 // =======================
 722
 723 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 724 {
 725         switch (request)
 726         {
 727                 case CMD_REQUEST_COMMAND:
 728                 {
 729                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 730                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 731                         {
 732                                 print_to(caller, "^1You have already voted.");
 733                         }
 734
 735                         else  // everything went okay, continue changing vote
 736                         {
 737                                 print_to(caller, "^1You abstained from your vote.");
 738                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 739                                 msg_entity = caller;
 740                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 741
 742                         return;
 743                 }
 744
 745                 default:
 746                 case CMD_REQUEST_USAGE:
 747                 {
 748                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 749                         print_to(caller, "  No arguments required.");
 750                         return;
 751                 }
 752         }
 753 }
 754
 755 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 756 {
 757         switch (request)
 758         {
 759                 case CMD_REQUEST_COMMAND:
 760                 {
 761                         float tmp_playercount = 0;
 762                         int parse_error;
 763
 764                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 765
 766                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 767                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 768                         {
 769                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 770                         }
 771                         else if (vote_called)
 772                         {
 773                                 print_to(caller, "^1There is already a vote called.");
 774                         }
 775                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 776                         {
 777                                 print_to(caller, "^1Only players can call a vote.");
 778                         }
 779                         else if (caller && !IS_CLIENT(caller))
 780                         {
 781                                 print_to(caller, "^1Only connected clients can vote.");
 782                         }
 783                         else if (timeout_status)
 784                         {
 785                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 786                         }
 787                         else if (caller && (time < caller.vote_waittime))
 788                         {
 789                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 790                         }
 791                         else if (!VoteCommand_checknasty(vote_command))
 792                         {
 793                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 794                         }
 795                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 796                         {
 797                                 if(parse_error == 0)
 798                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 799                         }
 800
 801                         else  // everything went okay, continue with calling the vote
 802                         {
 803                                 vote_caller = caller;  // remember who called the vote
 804                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 805                                 vote_called = VOTE_NORMAL;
 806                                 vote_called_command = strzone(vote_parsed_command);
 807                                 vote_called_display = strzone(vote_parsed_display);
 808                                 vote_endtime = time + autocvar_sv_vote_timeout;
 809
 810                                 if (caller)
 811                                 {
 812                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 813                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 814                                         msg_entity = caller;
 815                                 }
 816
 817                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 818                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 819
 820                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 821                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 822                                 Nagger_VoteChanged();
 823                                 VoteCount(true);  // needed if you are the only one
 824                         }
 825
 826                         return;
 827                 }
 828
 829                 default:
 830                 case CMD_REQUEST_USAGE:
 831                 {
 832                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 833                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 834                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 835                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 836                         return;
 837                 }
 838         }
 839 }
 840
 841 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 842 {
 843         switch (request)
 844         {
 845                 case CMD_REQUEST_COMMAND:
 846                 {
 847                         if (autocvar_sv_vote_master)
 848                         {
 849                                 switch (strtolower(argv(2)))
 850                                 {
 851                                         case "do":
 852                                         {
 853                                                 int parse_error;
 854                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 855
 856                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 857                                                 else if (!VoteCommand_checknasty(vote_command))
 858                                                 {
 859                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 860                                                 }
 861                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 862                                                 {
 863                                                         if(parse_error == 0)
 864                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 865                                                 }
 866
 867                                                 else  // everything went okay, proceed with command
 868                                                 {
 869                                                         localcmd(strcat(vote_parsed_command, "\n"));
 870                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 871                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 872                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 873
 874                                                 return;
 875                                         }
 876
 877                                         case "login":
 878                                         {
 879                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 880                                                 else if (caller.vote_master)
 881                                                 {
 882                                                         print_to(caller, "^1You are already logged in as vote master.");
 883                                                 }
 884                                                 else if (autocvar_sv_vote_master_password != argv(3))
 885                                                 {
 886                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 887                                                 }
 888
 889                                                 else  // everything went okay, proceed with giving this player master privilages
 890                                                 {
 891                                                         caller.vote_master = true;
 892                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 893                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 894                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 895
 896                                                 return;
 897                                         }
 898
 899                                         default:  // calling a vote for master
 900                                         {
 901                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 902                                                 else if (vote_called)
 903                                                 {
 904                                                         print_to(caller, "^1There is already a vote called.");
 905                                                 }
 906                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 907                                                 {
 908                                                         print_to(caller, "^1Only players can call a vote.");
 909                                                 }
 910                                                 else if (timeout_status)
 911                                                 {
 912                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 913                                                 }
 914
 915                                                 else  // everything went okay, continue with creating vote
 916                                                 {
 917                                                         vote_caller = caller;
 918                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 919                                                         vote_called = VOTE_MASTER;
 920                                                         vote_called_command = strzone("XXX");
 921                                                         vote_called_display = strzone("^3master");
 922                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 923
 924                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 925                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 926
 927                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 928                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 929                                                         Nagger_VoteChanged();
 930                                                         VoteCount(true);  // needed if you are the only one
 931                                                 }
 932
 933                                                 return;
 934                                         }
 935                                 }
 936                         }
 937                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 938
 939                         return;
 940                 }
 941
 942                 default:
 943                 case CMD_REQUEST_USAGE:
 944                 {
 945                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 946                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 947                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 948                         return;
 949                 }
 950         }
 951 }
 952
 953 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 954 {
 955         switch (request)
 956         {
 957                 case CMD_REQUEST_COMMAND:
 958                 {
 959                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 960                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 961                         {
 962                                 print_to(caller, "^1You have already voted.");
 963                         }
 964                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 965                         {
 966                                 VoteStop(caller);
 967                         }
 968
 969                         else  // everything went okay, continue changing vote
 970                         {
 971                                 print_to(caller, "^1You rejected the vote.");
 972                                 caller.vote_selection = VOTE_SELECT_REJECT;
 973                                 msg_entity = caller;
 974                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 975
 976                         return;
 977                 }
 978
 979                 default:
 980                 case CMD_REQUEST_USAGE:
 981                 {
 982                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 983                         print_to(caller, "  No arguments required.");
 984                         return;
 985                 }
 986         }
 987 }
 988
 989 void VoteCommand_status(float request, entity caller)  // BOTH
 990 {
 991         switch (request)
 992         {
 993                 case CMD_REQUEST_COMMAND:
 994                 {
 995                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
 996                         else print_to(caller, "^1No vote called.");
 997
 998                         return;
 999                 }
1000
1001                 default:
1002                 case CMD_REQUEST_USAGE:
1003                 {
1004                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1005                         print_to(caller, "  No arguments required.");
1006                         return;
1007                 }
1008         }
1009 }
1010
1011 void VoteCommand_stop(float request, entity caller)  // BOTH
1012 {
1013         switch (request)
1014         {
1015                 case CMD_REQUEST_COMMAND:
1016                 {
1017                         if (!vote_called)   print_to(caller, "^1No vote called.");
1018                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1019                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1020                         return;
1021                 }
1022
1023                 default:
1024                 case CMD_REQUEST_USAGE:
1025                 {
1026                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1027                         print_to(caller, "  No arguments required.");
1028                         return;
1029                 }
1030         }
1031 }
1032
1033 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1034 {
1035         switch (request)
1036         {
1037                 case CMD_REQUEST_COMMAND:
1038                 {
1039                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1040                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1041                         {
1042                                 print_to(caller, "^1You have already voted.");
1043                         }
1044
1045                         else  // everything went okay, continue changing vote
1046                         {
1047                                 print_to(caller, "^1You accepted the vote.");
1048                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1049                                 msg_entity = caller;
1050                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1051
1052                         return;
1053                 }
1054
1055                 default:
1056                 case CMD_REQUEST_USAGE:
1057                 {
1058                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1059                         print_to(caller, "  No arguments required.");
1060                         return;
1061                 }
1062         }
1063 }
1064
1065 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1066 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1067 void VoteCommand_(float request)
1068 {
1069     switch(request)
1070     {
1071         case CMD_REQUEST_COMMAND:
1072         {
1073
1074             return;
1075         }
1076
1077         default:
1078         case CMD_REQUEST_USAGE:
1079         {
1080             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1081             print_to(caller, "  No arguments required.");
1082             return;
1083         }
1084     }
1085 }
1086 */
1087
1088
1089 // ================================
1090 //  Macro system for vote commands
1091 // ================================
1092
1093 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1094 #define VOTE_COMMANDS(request, caller, arguments, command) \
1095         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1096         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1097         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1098         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1099         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1100         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1101         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1102         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1103         /* nothing */
1104
1105 void VoteCommand_macro_help(entity caller, float argc)
1106 {
1107         string command_origin = GetCommandPrefix(caller);
1108
1109         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1110         {
1111                 print_to(caller, "\nVoting commands:\n");
1112                 #define VOTE_COMMAND(name, function, description, assignment) \
1113                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1114
1115                 VOTE_COMMANDS(0, caller, 0, "");
1116 #undef VOTE_COMMAND
1117
1118                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1119                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1120                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1121         }
1122         else  // usage for individual command
1123         {
1124                 #define VOTE_COMMAND(name, function, description, assignment) \
1125                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1126
1127                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1128 #undef VOTE_COMMAND
1129         }
1130 }
1131
1132 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1133 {
1134         #define VOTE_COMMAND(name, function, description, assignment) \
1135                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1136
1137         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1138 #undef VOTE_COMMAND
1139
1140         return false;
1141 }
1142
1143
1144 // ======================================
1145 //  Main function handling vote commands
1146 // ======================================
1147
1148 void VoteCommand(float request, entity caller, float argc, string vote_command)
1149 {
1150         // Guide for working with argc arguments by example:
1151         // argc:   1    - 2      - 3     - 4
1152         // argv:   0    - 1      - 2     - 3
1153         // cmd     vote - master - login - password
1154
1155         switch (request)
1156         {
1157                 case CMD_REQUEST_COMMAND:
1158                 {
1159                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1160                 }
1161
1162                 default:
1163                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1164                 case CMD_REQUEST_USAGE:
1165                 {
1166                         VoteCommand_macro_help(caller, argc);
1167                         return;
1168                 }
1169         }
1170 }