qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2 #include <common/command/_mod.qh>
   3 #include "vote.qh"
   4
   5 #include "common.qh"
   6
   7 #include "../g_damage.qh"
   8 #include "../g_world.qh"
   9 #include "../race.qh"
  10 #include "../round_handler.qh"
  11 #include "../scores.qh"
  12
  13 #include "../mutators/_mod.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/notifications/all.qh>
  19 #include <common/playerstats.qh>
  20 #include <common/util.qh>
  21
  22 // =============================================
  23 //  Server side voting code, reworked by Samual
  24 //  Last updated: December 27th, 2011
  25 // =============================================
  26
  27 //  Nagger for players to know status of voting
  28 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  29 {
  30         int nags, i, f, b;
  31         entity e;
  32         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  33
  34         // bits:
  35         //   1 = ready
  36         //   2 = player needs to ready up
  37         //   4 = vote
  38         //   8 = player needs to vote
  39         //  16 = warmup
  40         // sendflags:
  41         //  64 = vote counts
  42         // 128 = vote string
  43
  44         nags = 0;
  45         if (readycount)
  46         {
  47                 nags |= BIT(0);
  48                 if (to.ready == 0) nags |= BIT(1);
  49         }
  50         if (vote_called)
  51         {
  52                 nags |= BIT(2);
  53                 if (to.vote_selection == 0) nags |= BIT(3);
  54         }
  55         if (warmup_stage) nags |= BIT(4);
  56
  57         if (sendflags & BIT(6)) nags |= BIT(6);
  58
  59         if (sendflags & BIT(7)) nags |= BIT(7);
  60
  61         if (!(nags & 4))  // no vote called? send no string
  62                 nags &= ~(BIT(6) | BIT(7));
  63
  64         WriteByte(MSG_ENTITY, nags);
  65
  66         if (nags & BIT(6))
  67         {
  68                 WriteByte(MSG_ENTITY, vote_accept_count);
  69                 WriteByte(MSG_ENTITY, vote_reject_count);
  70                 WriteByte(MSG_ENTITY, vote_needed_overall);
  71                 WriteChar(MSG_ENTITY, to.vote_selection);
  72         }
  73
  74         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  75
  76         if (nags & 1)
  77         {
  78                 for (i = 1; i <= maxclients; i += 8)
  79                 {
  80                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  81                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  82                         WriteByte(MSG_ENTITY, f);
  83                 }
  84         }
  85
  86         return true;
  87 }
  88
  89 void Nagger_Init()
  90 {
  91         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  92 }
  93
  94 void Nagger_VoteChanged()
  95 {
  96         if (nagger) nagger.SendFlags |= BIT(7);
  97 }
  98
  99 void Nagger_VoteCountChanged()
 100 {
 101         if (nagger) nagger.SendFlags |= BIT(6);
 102 }
 103
 104 void Nagger_ReadyCounted()
 105 {
 106         if (nagger) nagger.SendFlags |= BIT(0);
 107 }
 108
 109 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 110 string OriginalCallerName()
 111 {
 112         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 113         return vote_caller_name;
 114 }
 115
 116 // =======================
 117 //  Game logic for voting
 118 // =======================
 119
 120 void VoteReset()
 121 {
 122         FOREACH_CLIENT(true, LAMBDA(it.vote_selection = 0));
 123
 124         if (vote_called)
 125         {
 126                 strunzone(vote_called_command);
 127                 strunzone(vote_called_display);
 128                 strunzone(vote_caller_name);
 129         }
 130
 131         vote_called = VOTE_NULL;
 132         vote_caller = NULL;
 133         vote_caller_name = string_null;
 134         vote_endtime = 0;
 135
 136         vote_called_command = string_null;
 137         vote_called_display = string_null;
 138
 139         vote_parsed_command = string_null;
 140         vote_parsed_display = string_null;
 141
 142         Nagger_VoteChanged();
 143 }
 144
 145 void VoteStop(entity stopper)
 146 {
 147         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 148         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 149         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 150         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 151         VoteReset();
 152 }
 153
 154 void VoteAccept()
 155 {
 156         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 157
 158         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 159         else localcmd(strcat(vote_called_command, "\n"));
 160
 161         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 162
 163         VoteReset();
 164         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 165 }
 166
 167 void VoteReject()
 168 {
 169         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 170         VoteReset();
 171         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 172 }
 173
 174 void VoteTimeout()
 175 {
 176         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 177         VoteReset();
 178         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 179 }
 180
 181 void VoteSpam(float notvoters, float mincount, string result)
 182 {
 183         bprint(strcat(
 184                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 185                 strcat("^2:^1", ftos(vote_reject_count)),
 186                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 187                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 188                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 189
 190         if (autocvar_sv_eventlog)
 191         {
 192                 GameLogEcho(strcat(
 193                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 194                         strcat(":", ftos(vote_reject_count)),
 195                         strcat(":", ftos(vote_abstain_count)),
 196                         strcat(":", ftos(notvoters)),
 197                         strcat(":", ftos(mincount))));
 198         }
 199 }
 200
 201 void VoteCount(float first_count)
 202 {
 203         // declarations
 204         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 205
 206         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 207
 208         float vote_player_count = 0, notvoters = 0;
 209         float vote_real_player_count = 0, vote_real_accept_count = 0;
 210         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 211         float vote_needed_of_voted, final_needed_votes;
 212         float vote_factor_overall, vote_factor_of_voted;
 213
 214         Nagger_VoteCountChanged();
 215
 216         // add up all the votes from each connected client
 217         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), LAMBDA(
 218                 ++vote_player_count;
 219                 if (IS_PLAYER(it))   ++vote_real_player_count;
 220                 switch (it.vote_selection)
 221                 {
 222                         case VOTE_SELECT_REJECT:
 223                         { ++vote_reject_count;
 224                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 225                         }
 226                         case VOTE_SELECT_ACCEPT:
 227                         { ++vote_accept_count;
 228                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 229                         }
 230                         case VOTE_SELECT_ABSTAIN:
 231                         { ++vote_abstain_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 233                         }
 234                         default: break;
 235                 }
 236         ));
 237
 238         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 239         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 240         {
 241                 if (vote_caller)   vote_caller.vote_waittime = 0;
 242                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 243                 VoteReset();
 244                 return;
 245         }
 246
 247         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 248         if (!spectators_allowed && (vote_real_player_count > 0))
 249         {
 250                 vote_accept_count = vote_real_accept_count;
 251                 vote_reject_count = vote_real_reject_count;
 252                 vote_abstain_count = vote_real_abstain_count;
 253                 vote_player_count = vote_real_player_count;
 254         }
 255
 256         // people who have no opinion in any way :D
 257         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 258
 259         // determine the goal for the vote to be passed or rejected normally
 260         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 261         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 262
 263         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 264         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 265         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 266
 267         // are there any players at all on the server? it could be an admin vote
 268         if (vote_player_count == 0 && first_count)
 269         {
 270                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 271                 VoteAccept();
 272                 return;
 273         }
 274
 275         // since there ARE players, finally calculate the result of the vote
 276         if (vote_accept_count >= vote_needed_overall)
 277         {
 278                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 279                 VoteAccept();
 280                 return;
 281         }
 282
 283         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 284         {
 285                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 286                 VoteReject();
 287                 return;
 288         }
 289
 290         // there is not enough votes in either direction, now lets just calculate what the voters have said
 291         if (time > vote_endtime)
 292         {
 293                 final_needed_votes = vote_needed_overall;
 294
 295                 if (autocvar_sv_vote_majority_factor_of_voted)
 296                 {
 297                         if (vote_accept_count >= vote_needed_of_voted)
 298                         {
 299                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 300                                 VoteAccept();
 301                                 return;
 302                         }
 303
 304                         if (vote_accept_count + vote_reject_count > 0)
 305                         {
 306                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 307                                 VoteReject();
 308                                 return;
 309                         }
 310
 311                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 312                 }
 313
 314                 // it didn't pass or fail, so not enough votes to even make a decision.
 315                 VoteSpam(notvoters, final_needed_votes, "timeout");
 316                 VoteTimeout();
 317         }
 318 }
 319
 320 void VoteThink()
 321 {
 322         if (vote_endtime > 0)        // a vote was called
 323         {
 324                 if (time > vote_endtime) // time is up
 325                         VoteCount(false);
 326         }
 327 }
 328
 329
 330 // =======================
 331 //  Game logic for warmup
 332 // =======================
 333
 334 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 335 void reset_map(bool dorespawn)
 336 {
 337         if (time <= game_starttime)
 338         {
 339                 if (gameover)
 340                         return;
 341                 if (round_handler_IsActive())
 342                         round_handler_Reset(game_starttime);
 343         }
 344
 345         MUTATOR_CALLHOOK(reset_map_global);
 346
 347         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 348                 if (it.reset)
 349                 {
 350                         it.reset(it);
 351                         continue;
 352                 }
 353                 if (it.team_saved) it.team = it.team_saved;
 354                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 355         });
 356
 357         // Waypoints and assault start come LAST
 358         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 359                 if (it.reset2) it.reset2(it);
 360         });
 361
 362         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), LAMBDA(Unfreeze(it)));
 363
 364         // Moving the player reset code here since the player-reset depends
 365         // on spawnpoint entities which have to be reset first --blub
 366         if (dorespawn)
 367         {
 368                 if (!MUTATOR_CALLHOOK(reset_map_players))
 369                 {
 370                         FOREACH_CLIENT(true, LAMBDA(
 371                                 /*
 372                                 only reset players if a restart countdown is active
 373                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 374                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 375                                 sv_ready_restart_after_countdown is not used and countdown is still running
 376                                 */
 377                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 378                                 {
 379                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 380                                         if (IS_PLAYER(it))
 381                                         {
 382                                                 // PlayerScore_Clear(it);
 383                                                 it.killcount = 0;
 384                                                 // stop the player from moving so that he stands still once he gets respawned
 385                                                 it.velocity = '0 0 0';
 386                                                 it.avelocity = '0 0 0';
 387                                                 it.movement = '0 0 0';
 388                                                 PutClientInServer(it);
 389                                         }
 390                                 }
 391                         ));
 392                 }
 393         }
 394 }
 395
 396 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 397 void ReadyRestart_think(entity this)
 398 {
 399         restart_mapalreadyrestarted = true;
 400         reset_map(true);
 401         Score_ClearAll();
 402         delete(this);
 403 }
 404
 405 // Forces a restart of the game without actually reloading the map // this is a mess...
 406 void ReadyRestart_force()
 407 {
 408         if (time <= game_starttime && gameover)
 409                 return;
 410
 411         bprint("^1Server is restarting...\n");
 412
 413         VoteReset();
 414
 415         // clear overtime, we have to decrease timelimit to its original value again.
 416         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 417                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 418         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 419
 420         readyrestart_happened = true;
 421         game_starttime = time + RESTART_COUNTDOWN;
 422
 423         // clear player attributes
 424         FOREACH_CLIENT(true, LAMBDA(
 425                 it.alivetime = 0;
 426                 it.killcount = 0;
 427                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
 428         ));
 429
 430         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 431
 432         // disable the warmup global for the server
 433         warmup_stage = 0;                // once the game is restarted the game is in match stage
 434
 435         // reset the .ready status of all players (also spectators)
 436         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(it.ready = false));
 437         readycount = 0;
 438         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 439
 440         // lock teams with lockonrestart
 441         if (autocvar_teamplay_lockonrestart && teamplay)
 442         {
 443                 lockteams = true;
 444                 bprint("^1The teams are now locked.\n");
 445         }
 446
 447         // initiate the restart-countdown-announcer entity
 448         if (autocvar_sv_ready_restart_after_countdown)
 449         {
 450                 entity restart_timer = new_pure(restart_timer);
 451                 setthink(restart_timer, ReadyRestart_think);
 452                 restart_timer.nextthink = game_starttime;
 453         }
 454
 455         // after a restart every players number of allowed timeouts gets reset, too
 456         if (autocvar_sv_timeout)
 457         {
 458                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(it.allowed_timeouts = autocvar_sv_timeout_number));
 459         }
 460     // reset map immediately if this cvar is not set
 461     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 462         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 463 }
 464
 465 void ReadyRestart()
 466 {
 467         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || gameover || race_completing) localcmd("restart\n");
 468         else localcmd("\nsv_hook_gamerestart\n");
 469
 470         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 471         // Otherwise scores could be manipulated during the countdown.
 472         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 473         ReadyRestart_force();
 474 }
 475
 476 // Count the players who are ready and determine whether or not to restart the match
 477 void ReadyCount()
 478 {
 479         float ready_needed_factor, ready_needed_count;
 480         float t_ready = 0, t_players = 0;
 481
 482         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), LAMBDA(
 483                 ++t_players;
 484                 if (it.ready) ++t_ready;
 485         ));
 486
 487         readycount = t_ready;
 488
 489         Nagger_ReadyCounted();
 490
 491         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 492         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 493
 494         if (readycount >= ready_needed_count) ReadyRestart();
 495 }
 496
 497
 498 // ======================================
 499 //  Supporting functions for VoteCommand
 500 // ======================================
 501
 502 float Votecommand_check_assignment(entity caller, float assignment)
 503 {
 504         float from_server = (!caller);
 505
 506         if ((assignment == VC_ASGNMNT_BOTH)
 507             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 508             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 509
 510         return false;
 511 }
 512
 513 string VoteCommand_extractcommand(string input, float startpos, float argc)
 514 {
 515         string output;
 516
 517         if ((argc - 1) < startpos) output = "";
 518         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 519
 520         return output;
 521 }
 522
 523 float VoteCommand_checknasty(string vote_command)
 524 {
 525         if ((strstrofs(vote_command, ";", 0) >= 0)
 526             || (strstrofs(vote_command, "\n", 0) >= 0)
 527             || (strstrofs(vote_command, "\r", 0) >= 0)
 528             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 529
 530         return true;
 531 }
 532
 533 float VoteCommand_checkinlist(string vote_command, string list)
 534 {
 535         string l = strcat(" ", list, " ");
 536
 537         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 538
 539         return false;
 540 }
 541
 542 string ValidateMap(string validated_map, entity caller)
 543 {
 544         validated_map = MapInfo_FixName(validated_map);
 545
 546         if (!validated_map)
 547         {
 548                 print_to(caller, "This map is not available on this server.");
 549                 return string_null;
 550         }
 551
 552         if (!autocvar_sv_vote_override_mostrecent && caller)
 553         {
 554                 if (Map_IsRecent(validated_map))
 555                 {
 556                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 557                         return string_null;
 558                 }
 559         }
 560
 561         if (!MapInfo_CheckMap(validated_map))
 562         {
 563                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 564                 return string_null;
 565         }
 566
 567         return validated_map;
 568 }
 569
 570 float VoteCommand_checkargs(float startpos, float argc)
 571 {
 572         float p, q, check, minargs;
 573         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 574         string cmdrestriction = "";  // No we don't.
 575         string charlist, arg;
 576         float checkmate;
 577
 578         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 579                 cmdrestriction = cvar_string(cvarname);
 580         else
 581                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.\n");
 582
 583         if (cmdrestriction == "") return true;
 584
 585         ++startpos;  // skip command name
 586
 587         // check minimum arg count
 588
 589         // 0 args: argc == startpos
 590         // 1 args: argc == startpos + 1
 591         // ...
 592
 593         minargs = stof(cmdrestriction);
 594         if (argc - startpos < minargs) return false;
 595
 596         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 597
 598         for ( ; ; )
 599         {
 600                 // we know that at any time, startpos <= argc - minargs
 601                 // so this means: argc-minargs >= startpos >= argc, thus
 602                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 603                 // have been seen already
 604
 605                 if (startpos >= argc) // all args checked? GOOD
 606                         break;
 607
 608                 if (p < 0)            // no more args? FAIL
 609                 {
 610                         // exception: exactly minargs left, this one included
 611                         if (argc - startpos == minargs) break;
 612
 613                         // otherwise fail
 614                         return false;
 615                 }
 616
 617                 // cut to next semicolon
 618                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 619                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 620                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 621
 622                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 623                 // charlist = strreplace("^^", ";", charlist);
 624
 625                 if (charlist != "")
 626                 {
 627                         // verify the arg only contains allowed chars
 628                         arg = argv(startpos);
 629                         checkmate = strlen(arg);
 630                         for (check = 0; check < checkmate; ++check)
 631                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 632                         // not allowed character
 633                         // all characters are allowed. FINE.
 634                 }
 635
 636                 ++startpos;
 637                 --minargs;
 638                 p = q;
 639         }
 640
 641         return true;
 642 }
 643
 644 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 645 {
 646         string first_command;
 647
 648         first_command = argv(startpos);
 649
 650         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 651             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 652             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 653         );*/
 654
 655         if (
 656             (autocvar_sv_vote_limit > 0)
 657             &&
 658             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 659            )   return false;
 660
 661         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 662
 663         if (!VoteCommand_checkargs(startpos, argc)) return false;
 664
 665         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 666         {
 667                 case "kick":
 668                 case "kickban":    // catch all kick/kickban commands
 669                 {
 670                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 671                         float accepted = VerifyClientEntity(victim, true, false);
 672
 673                         if (accepted > 0)
 674                         {
 675                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 676                                 string command_arguments;
 677
 678                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 679                                 else command_arguments = reason;
 680
 681                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 682                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 683                         }
 684                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 685
 686                         break;
 687                 }
 688
 689                 case "map":
 690                 case "chmap":
 691                 case "gotomap":  // re-direct all map selection commands to gotomap
 692                 {
 693                         vote_command = ValidateMap(argv(startpos + 1), caller);
 694                         if (!vote_command)   return false;
 695                         vote_parsed_command = strcat("gotomap ", vote_command);
 696                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 697
 698                         break;
 699                 }
 700
 701                 default:
 702                 {
 703                         vote_parsed_command = vote_command;
 704                         vote_parsed_display = strzone(strcat("^1", vote_command));
 705
 706                         break;
 707                 }
 708         }
 709
 710         return true;
 711 }
 712
 713
 714 // =======================
 715 //  Command Sub-Functions
 716 // =======================
 717
 718 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 719 {
 720         switch (request)
 721         {
 722                 case CMD_REQUEST_COMMAND:
 723                 {
 724                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 725                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 726                         {
 727                                 print_to(caller, "^1You have already voted.");
 728                         }
 729
 730                         else  // everything went okay, continue changing vote
 731                         {
 732                                 print_to(caller, "^1You abstained from your vote.");
 733                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 734                                 msg_entity = caller;
 735                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 736
 737                         return;
 738                 }
 739
 740                 default:
 741                 case CMD_REQUEST_USAGE:
 742                 {
 743                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 744                         print_to(caller, "  No arguments required.");
 745                         return;
 746                 }
 747         }
 748 }
 749
 750 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 751 {
 752         switch (request)
 753         {
 754                 case CMD_REQUEST_COMMAND:
 755                 {
 756                         bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 757
 758                         float tmp_playercount = 0;
 759
 760                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 761
 762                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 763                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 764                         {
 765                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 766                         }
 767                         else if (vote_called)
 768                         {
 769                                 print_to(caller, "^1There is already a vote called.");
 770                         }
 771                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 772                         {
 773                                 print_to(caller, "^1Only players can call a vote.");
 774                         }
 775                         else if (caller && !IS_CLIENT(caller))
 776                         {
 777                                 print_to(caller, "^1Only connected clients can vote.");
 778                         }
 779                         else if (timeout_status)
 780                         {
 781                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 782                         }
 783                         else if (caller && (time < caller.vote_waittime))
 784                         {
 785                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 786                         }
 787                         else if (!VoteCommand_checknasty(vote_command))
 788                         {
 789                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 790                         }
 791                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 792                         {
 793                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 794                         }
 795
 796                         else  // everything went okay, continue with calling the vote
 797                         {
 798                                 vote_caller = caller;  // remember who called the vote
 799                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 800                                 vote_called = VOTE_NORMAL;
 801                                 vote_called_command = strzone(vote_parsed_command);
 802                                 vote_called_display = strzone(vote_parsed_display);
 803                                 vote_endtime = time + autocvar_sv_vote_timeout;
 804
 805                                 if (caller)
 806                                 {
 807                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 808                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 809                                         msg_entity = caller;
 810                                 }
 811
 812                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(++tmp_playercount));
 813                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 814
 815                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 816                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 817                                 Nagger_VoteChanged();
 818                                 VoteCount(true);  // needed if you are the only one
 819                         }
 820
 821                         return;
 822                 }
 823
 824                 default:
 825                 case CMD_REQUEST_USAGE:
 826                 {
 827                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 828                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 829                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 830                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 831                         return;
 832                 }
 833         }
 834 }
 835
 836 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 837 {
 838         switch (request)
 839         {
 840                 case CMD_REQUEST_COMMAND:
 841                 {
 842                         if (autocvar_sv_vote_master)
 843                         {
 844                                 switch (strtolower(argv(2)))
 845                                 {
 846                                         case "do":
 847                                         {
 848                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 849
 850                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 851                                                 else if (!VoteCommand_checknasty(vote_command))
 852                                                 {
 853                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 854                                                 }
 855                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 856                                                 {
 857                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 858                                                 }
 859
 860                                                 else  // everything went okay, proceed with command
 861                                                 {
 862                                                         localcmd(strcat(vote_parsed_command, "\n"));
 863                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 864                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 865                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 866
 867                                                 return;
 868                                         }
 869
 870                                         case "login":
 871                                         {
 872                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 873                                                 else if (caller.vote_master)
 874                                                 {
 875                                                         print_to(caller, "^1You are already logged in as vote master.");
 876                                                 }
 877                                                 else if (autocvar_sv_vote_master_password != argv(3))
 878                                                 {
 879                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 880                                                 }
 881
 882                                                 else  // everything went okay, proceed with giving this player master privilages
 883                                                 {
 884                                                         caller.vote_master = true;
 885                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 886                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 887                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 888
 889                                                 return;
 890                                         }
 891
 892                                         default:  // calling a vote for master
 893                                         {
 894                                                 bool spectators_allowed = (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || gameover)));
 895
 896                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 897                                                 else if (vote_called)
 898                                                 {
 899                                                         print_to(caller, "^1There is already a vote called.");
 900                                                 }
 901                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 902                                                 {
 903                                                         print_to(caller, "^1Only players can call a vote.");
 904                                                 }
 905                                                 else if (timeout_status)
 906                                                 {
 907                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 908                                                 }
 909
 910                                                 else  // everything went okay, continue with creating vote
 911                                                 {
 912                                                         vote_caller = caller;
 913                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 914                                                         vote_called = VOTE_MASTER;
 915                                                         vote_called_command = strzone("XXX");
 916                                                         vote_called_display = strzone("^3master");
 917                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 918
 919                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 920                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 921
 922                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 923                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 924                                                         Nagger_VoteChanged();
 925                                                         VoteCount(true);  // needed if you are the only one
 926                                                 }
 927
 928                                                 return;
 929                                         }
 930                                 }
 931                         }
 932                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 933
 934                         return;
 935                 }
 936
 937                 default:
 938                 case CMD_REQUEST_USAGE:
 939                 {
 940                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 941                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 942                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 943                         return;
 944                 }
 945         }
 946 }
 947
 948 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 949 {
 950         switch (request)
 951         {
 952                 case CMD_REQUEST_COMMAND:
 953                 {
 954                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 955                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 956                         {
 957                                 print_to(caller, "^1You have already voted.");
 958                         }
 959                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 960                         {
 961                                 VoteStop(caller);
 962                         }
 963
 964                         else  // everything went okay, continue changing vote
 965                         {
 966                                 print_to(caller, "^1You rejected the vote.");
 967                                 caller.vote_selection = VOTE_SELECT_REJECT;
 968                                 msg_entity = caller;
 969                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 970
 971                         return;
 972                 }
 973
 974                 default:
 975                 case CMD_REQUEST_USAGE:
 976                 {
 977                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 978                         print_to(caller, "  No arguments required.");
 979                         return;
 980                 }
 981         }
 982 }
 983
 984 void VoteCommand_status(float request, entity caller)  // BOTH
 985 {
 986         switch (request)
 987         {
 988                 case CMD_REQUEST_COMMAND:
 989                 {
 990                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
 991                         else print_to(caller, "^1No vote called.");
 992
 993                         return;
 994                 }
 995
 996                 default:
 997                 case CMD_REQUEST_USAGE:
 998                 {
 999                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1000                         print_to(caller, "  No arguments required.");
1001                         return;
1002                 }
1003         }
1004 }
1005
1006 void VoteCommand_stop(float request, entity caller)  // BOTH
1007 {
1008         switch (request)
1009         {
1010                 case CMD_REQUEST_COMMAND:
1011                 {
1012                         if (!vote_called)   print_to(caller, "^1No vote called.");
1013                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1014                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1015                         return;
1016                 }
1017
1018                 default:
1019                 case CMD_REQUEST_USAGE:
1020                 {
1021                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1022                         print_to(caller, "  No arguments required.");
1023                         return;
1024                 }
1025         }
1026 }
1027
1028 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1029 {
1030         switch (request)
1031         {
1032                 case CMD_REQUEST_COMMAND:
1033                 {
1034                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1035                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1036                         {
1037                                 print_to(caller, "^1You have already voted.");
1038                         }
1039
1040                         else  // everything went okay, continue changing vote
1041                         {
1042                                 print_to(caller, "^1You accepted the vote.");
1043                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1044                                 msg_entity = caller;
1045                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1046
1047                         return;
1048                 }
1049
1050                 default:
1051                 case CMD_REQUEST_USAGE:
1052                 {
1053                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1054                         print_to(caller, "  No arguments required.");
1055                         return;
1056                 }
1057         }
1058 }
1059
1060 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1061 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1062 void VoteCommand_(float request)
1063 {
1064     switch(request)
1065     {
1066         case CMD_REQUEST_COMMAND:
1067         {
1068
1069             return;
1070         }
1071
1072         default:
1073         case CMD_REQUEST_USAGE:
1074         {
1075             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1076             print_to(caller, "  No arguments required.");
1077             return;
1078         }
1079     }
1080 }
1081 */
1082
1083
1084 // ================================
1085 //  Macro system for vote commands
1086 // ================================
1087
1088 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1089 #define VOTE_COMMANDS(request, caller, arguments, command) \
1090         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1091         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1092         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1093         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1094         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1095         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1096         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1097         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1098         /* nothing */
1099
1100 void VoteCommand_macro_help(entity caller, float argc)
1101 {
1102         string command_origin = GetCommandPrefix(caller);
1103
1104         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1105         {
1106                 print_to(caller, "\nVoting commands:\n");
1107                 #define VOTE_COMMAND(name, function, description, assignment) \
1108                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1109
1110                 VOTE_COMMANDS(0, caller, 0, "");
1111 #undef VOTE_COMMAND
1112
1113                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1114                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1115                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1116         }
1117         else  // usage for individual command
1118         {
1119                 #define VOTE_COMMAND(name, function, description, assignment) \
1120                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1121
1122                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1123 #undef VOTE_COMMAND
1124         }
1125 }
1126
1127 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1128 {
1129         #define VOTE_COMMAND(name, function, description, assignment) \
1130                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1131
1132         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1133 #undef VOTE_COMMAND
1134
1135         return false;
1136 }
1137
1138
1139 // ======================================
1140 //  Main function handling vote commands
1141 // ======================================
1142
1143 void VoteCommand(float request, entity caller, float argc, string vote_command)
1144 {
1145         // Guide for working with argc arguments by example:
1146         // argc:   1    - 2      - 3     - 4
1147         // argv:   0    - 1      - 2     - 3
1148         // cmd     vote - master - login - password
1149
1150         switch (request)
1151         {
1152                 case CMD_REQUEST_COMMAND:
1153                 {
1154                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1155                 }
1156
1157                 default:
1158                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1159                 case CMD_REQUEST_USAGE:
1160                 {
1161                         VoteCommand_macro_help(caller, argc);
1162                         return;
1163                 }
1164         }
1165 }