Fix extra life powerup giving infinite lives in lms & minstagib
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / vote.qc
1 // =============================================
2 //  Server side voting code, reworked by Samual
3 //  Last updated: December 27th, 2011
4 // =============================================
5
6 //  Nagger for players to know status of voting
7 float Nagger_SendEntity(entity to, float sendflags)
8 {
9         float nags, i, f, b;
10         entity e;
11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
12
13         // bits:
14         //   1 = ready
15         //   2 = player needs to ready up
16         //   4 = vote
17         //   8 = player needs to vote
18         //  16 = warmup
19         // sendflags:
20         //  64 = vote counts
21         // 128 = vote string
22
23         nags = 0;
24         if(readycount)
25         {
26                 nags |= 1;
27                 if(to.ready == 0)
28                         nags |= 2;
29         }
30         if(vote_called)
31         {
32                 nags |= 4;
33                 if(to.vote_selection == 0)
34                         nags |= 8;
35         }
36         if(inWarmupStage)
37                 nags |= 16;
38
39         if(sendflags & 64)
40                 nags |= 64;
41
42         if(sendflags & 128)
43                 nags |= 128;
44
45         if(!(nags & 4)) // no vote called? send no string
46                 nags &~= (64 | 128);
47
48         WriteByte(MSG_ENTITY, nags);
49
50         if(nags & 64)
51         {
52                 WriteByte(MSG_ENTITY, vote_accept_count);
53                 WriteByte(MSG_ENTITY, vote_reject_count);
54                 WriteByte(MSG_ENTITY, vote_needed_overall);
55                 WriteChar(MSG_ENTITY, to.vote_selection);
56         }
57
58         if(nags & 128)
59                 WriteString(MSG_ENTITY, vote_called_display);
60
61         if(nags & 1)
62         {
63                 for(i = 1; i <= maxclients; i += 8)
64                 {
65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
67                                         f |= b;
68                         WriteByte(MSG_ENTITY, f);
69                 }
70         }
71
72         return TRUE;
73 }
74
75 void Nagger_Init()
76 {
77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
78 }
79
80 void Nagger_VoteChanged()
81 {
82         if(nagger)
83                 nagger.SendFlags |= 128;
84 }
85
86 void Nagger_VoteCountChanged()
87 {
88         if(nagger)
89                 nagger.SendFlags |= 64;
90 }
91
92 void Nagger_ReadyCounted()
93 {
94         if(nagger)
95                 nagger.SendFlags |= 1;
96 }
97
98
99 // =======================
100 //  Game logic for voting
101 // =======================
102
103 void VoteReset() 
104 {
105         entity tmp_player;
106
107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
108
109         if(vote_called)
110         {
111                 strunzone(vote_called_command);
112                 strunzone(vote_called_display);
113         }
114
115         vote_called = VOTE_NULL;
116         vote_caller = world;
117         vote_endtime = 0;
118         
119         vote_called_command = string_null;
120         vote_called_display = string_null;
121         
122         vote_parsed_command = string_null;
123         vote_parsed_display = string_null;
124
125         Nagger_VoteChanged();
126 }
127
128 void VoteStop(entity stopper) 
129 {
130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
132         
133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
135
136         VoteReset();
137 }
138
139 void VoteAccept() 
140 {
141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
142         
143         if((vote_called == VOTE_MASTER) && vote_caller)
144                 vote_caller.vote_master = 1;
145         else
146                 localcmd(strcat(vote_called_command, "\n"));
147         
148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
149
150         VoteReset();
151         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
152 }
153
154 void VoteReject() 
155 {
156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
157         VoteReset();
158         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
159 }
160
161 void VoteTimeout() 
162 {
163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
164         VoteReset();
165         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
166 }
167
168 void VoteSpam(float notvoters, float mincount, string result)
169 {
170         bprint(strcat(
171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
172                 strcat("^2:^1", ftos(vote_reject_count)),
173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
176         
177         if(autocvar_sv_eventlog)
178         {
179                 GameLogEcho(strcat(
180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
181                         strcat(":", ftos(vote_reject_count)),
182                         strcat(":", ftos(vote_abstain_count)),
183                         strcat(":", ftos(notvoters)),
184                         strcat(":", ftos(mincount))));
185         }
186 }
187
188 void VoteCount(float first_count) 
189 {
190         // declarations
191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
192         
193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2) 
194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
195                                 || (autocvar_sv_vote_nospectators == 0));
196                                 
197         float vote_player_count = 0, is_player, notvoters = 0;
198         float vote_real_player_count = 0, vote_real_accept_count = 0;
199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
200         float vote_needed_of_voted, final_needed_votes;
201         float vote_factor_overall, vote_factor_of_voted;
202         
203         entity tmp_player;
204
205         Nagger_VoteCountChanged();
206         
207         // add up all the votes from each connected client
208         FOR_EACH_REALCLIENT(tmp_player)
209         {
210                 is_player = (tmp_player.classname == "player");
211                 
212                 ++vote_player_count;
213                 if(is_player) { ++vote_real_player_count; }
214                 
215                 switch(tmp_player.vote_selection)
216                 {
217                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
218                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
219                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
220                         default: break;
221                 }
222         }
223         
224         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
225         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count) 
226         {
227                 if(vote_caller) { vote_caller.vote_waittime = 0; }
228                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
229                 VoteReset();
230                 return;
231         }
232         
233         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators. 
234         if(!spectators_allowed && (vote_real_player_count > 0))
235         {
236                 vote_accept_count = vote_real_accept_count;
237                 vote_reject_count = vote_real_reject_count;
238                 vote_abstain_count = vote_real_abstain_count;
239                 vote_player_count = vote_real_player_count;
240         }
241         
242         // people who have no opinion in any way :D
243         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
244
245         // determine the goal for the vote to be passed or rejected normally
246         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
247         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
248         
249         // if the vote times out, determine the amount of votes needed of the people who actually already voted
250         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
251         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
252         
253         // are there any players at all on the server? it could be an admin vote
254         if(vote_player_count == 0 && first_count)
255         {
256                 VoteSpam(0, -1, "yes"); // no players at all, just accept it 
257                 VoteAccept();
258                 return;
259         }
260         
261         // since there ARE players, finally calculate the result of the vote    
262         if(vote_accept_count >= vote_needed_overall)
263         {
264                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
265                 VoteAccept();
266                 return;
267         }
268         
269         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
270         {
271                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
272                 VoteReject();
273                 return;
274         }
275         
276         // there is not enough votes in either direction, now lets just calculate what the voters have said
277         if(time > vote_endtime)
278         {
279                 final_needed_votes = vote_needed_overall;
280                 
281                 if(autocvar_sv_vote_majority_factor_of_voted)
282                 {
283                         if(vote_accept_count >= vote_needed_of_voted)
284                         {
285                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
286                                 VoteAccept();
287                                 return;
288                         }
289                         
290                         if(vote_accept_count + vote_reject_count > 0)
291                         {
292                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
293                                 VoteReject();
294                                 return;
295                         }
296                         
297                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
298                 }
299
300                 // it didn't pass or fail, so not enough votes to even make a decision. 
301                 VoteSpam(notvoters, final_needed_votes, "timeout");
302                 VoteTimeout();
303         }
304 }
305
306 void VoteThink() 
307 {
308         if(vote_endtime > 0) // a vote was called
309         if(time > vote_endtime) // time is up
310         {
311                 VoteCount(FALSE);
312         }
313         
314         return;
315 }
316
317
318 // =======================
319 //  Game logic for warmup
320 // =======================
321
322 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
323 void reset_map(float dorespawn)
324 {
325         entity oldself;
326         oldself = self;
327
328         if(time <= game_starttime && round_handler_IsActive())
329                 round_handler_Reset(game_starttime);
330
331         if(g_race || g_cts)
332                 race_ReadyRestart();
333         else MUTATOR_CALLHOOK(reset_map_global);
334
335         for(self = world; (self = nextent(self)); )
336         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
337         {
338                 if(self.reset)
339                 {
340                         self.reset();
341                         continue;
342                 }
343
344                 if(self.team_saved)
345                         self.team = self.team_saved;
346
347                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
348                         remove(self);
349         }
350
351         // Waypoints and assault start come LAST
352         for(self = world; (self = nextent(self)); )
353         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
354         {
355                 if(self.reset2)
356                 {
357                         self.reset2();
358                         continue;
359                 }
360         }
361
362         // Moving the player reset code here since the player-reset depends
363         // on spawnpoint entities which have to be reset first --blub
364         if(dorespawn)
365         if(!MUTATOR_CALLHOOK(reset_map_players))
366         FOR_EACH_CLIENT(self) // reset all players
367         {
368                 /*
369                 only reset players if a restart countdown is active
370                 this can either be due to cvar sv_ready_restart_after_countdown having set
371                 restart_mapalreadyrestarted to 1 after the countdown ended or when
372                 sv_ready_restart_after_countdown is not used and countdown is still running
373                 */
374                 if (restart_mapalreadyrestarted || (time < game_starttime))
375                 {
376                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
377                         if (IS_PLAYER(self)) {
378                                 //PlayerScore_Clear(self);
379                                 self.killcount = 0;
380                                 //stop the player from moving so that he stands still once he gets respawned
381                                 self.velocity = '0 0 0';
382                                 self.avelocity = '0 0 0';
383                                 self.movement = '0 0 0';
384                                 PutClientInServer();
385                         }
386                 }
387         }
388
389         if(g_keyhunt)
390                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
391
392         self = oldself;
393 }
394
395 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
396 void ReadyRestart_think() 
397 {
398         restart_mapalreadyrestarted = 1;
399         reset_map(TRUE);
400         Score_ClearAll();
401         remove(self);
402         
403         return;
404 }
405
406 // Forces a restart of the game without actually reloading the map // this is a mess...
407 void ReadyRestart_force()
408 {
409         entity tmp_player, restart_timer;
410
411         bprint("^1Server is restarting...\n");
412
413         VoteReset();
414
415         // clear overtime, we have to decrease timelimit to its original value again.
416         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
417
418         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
419
420         readyrestart_happened = 1;
421         game_starttime = time + RESTART_COUNTDOWN;
422
423         // clear player attributes
424         FOR_EACH_CLIENT(tmp_player)
425         {
426                 tmp_player.alivetime = 0;
427                 tmp_player.killcount = 0;
428                 PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, -PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, 0));
429         }
430
431         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
432
433         // disable the warmup global for the server
434         inWarmupStage = 0; // once the game is restarted the game is in match stage
435
436         // reset the .ready status of all players (also spectators)
437         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
438         readycount = 0;
439         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
440
441         // lock teams with lockonrestart
442         if(autocvar_teamplay_lockonrestart && teamplay)
443         {
444                 lockteams = 1;
445                 bprint("^1The teams are now locked.\n");
446         }
447
448         //initiate the restart-countdown-announcer entity
449         if(autocvar_sv_ready_restart_after_countdown)
450         {
451                 restart_timer = spawn();
452                 restart_timer.think = ReadyRestart_think;
453                 restart_timer.nextthink = game_starttime;
454         }
455
456         // after a restart every players number of allowed timeouts gets reset, too
457         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
458
459         //reset map immediately if this cvar is not set
460         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
461
462         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
463 }
464
465 void ReadyRestart()
466 {
467         // no arena, assault support yet...
468         if(g_arena | g_assault | gameover | intermission_running | race_completing)
469                 localcmd("restart\n");
470         else
471                 localcmd("\nsv_hook_gamerestart\n");
472
473         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
474         // Otherwise scores could be manipulated during the countdown.
475         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
476
477         ReadyRestart_force();
478         
479         return;
480 }
481
482 // Count the players who are ready and determine whether or not to restart the match
483 void ReadyCount()
484 {
485         entity tmp_player;
486         float ready_needed_factor, ready_needed_count;
487         float t_ready = 0, t_players = 0;
488
489         FOR_EACH_REALCLIENT(tmp_player)
490         {
491                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
492                 {
493                         ++t_players;
494                         if(tmp_player.ready) { ++t_ready; }
495                 }
496         }
497
498         readycount = t_ready;
499
500         Nagger_ReadyCounted();
501
502         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
503         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
504         
505         if(readycount >= ready_needed_count)
506         {
507                 ReadyRestart();
508         }
509                 
510         return;
511 }
512
513
514 // ======================================
515 //  Supporting functions for VoteCommand
516 // ======================================
517
518 float Votecommand_check_assignment(entity caller, float assignment)
519 {
520         float from_server = (!caller);
521         
522         if((assignment == VC_ASGNMNT_BOTH) 
523                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY) 
524                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
525         {
526                 return TRUE;
527         }
528
529         return FALSE;
530 }
531
532 string VoteCommand_extractcommand(string input, float startpos, float argc) 
533 {
534         string output;
535         
536         if((argc - 1) < startpos)
537                 output = "";
538         else
539                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
540                 
541         return output;
542 }
543
544 float VoteCommand_checknasty(string vote_command)
545 {
546         if((strstrofs(vote_command, ";", 0) >= 0)
547                 || (strstrofs(vote_command, "\n", 0) >= 0)
548                 || (strstrofs(vote_command, "\r", 0) >= 0)
549                 || (strstrofs(vote_command, "$", 0) >= 0))
550                 return FALSE;
551                 
552         return TRUE;
553 }
554
555 float VoteCommand_checkinlist(string vote_command, string list)
556 {
557         string l = strcat(" ", list, " ");
558         
559         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
560                 return TRUE;
561         
562         return FALSE;
563 }
564
565 string ValidateMap(string validated_map, entity caller)
566 {
567         validated_map = MapInfo_FixName(validated_map);
568         
569         if not(validated_map)
570         {
571                 print_to(caller, "This map is not available on this server.");
572                 return string_null;
573         }
574         
575         if(!autocvar_sv_vote_override_mostrecent && caller)
576         {
577                 if(Map_IsRecent(validated_map))
578                 {
579                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
580                         return string_null;
581                 }
582         }
583         
584         if(!MapInfo_CheckMap(validated_map))
585         {
586                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
587                 return string_null;
588         }
589
590         return validated_map;
591 }
592
593 float VoteCommand_checkargs(float startpos, float argc)
594 {
595         float p, q, check, minargs;
596         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
597         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
598         string charlist, arg;
599         float checkmate;
600
601         if(cmdrestriction == "")
602                 return TRUE;
603
604         ++startpos; // skip command name
605
606         // check minimum arg count
607
608         // 0 args: argc == startpos
609         // 1 args: argc == startpos + 1
610         // ...
611
612         minargs = stof(cmdrestriction);
613         if(argc - startpos < minargs)
614                 return FALSE;
615
616         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
617
618         for(;;)
619         {
620                 // we know that at any time, startpos <= argc - minargs
621                 // so this means: argc-minargs >= startpos >= argc, thus
622                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
623                 // have been seen already
624
625                 if(startpos >= argc) // all args checked? GOOD
626                         break;
627
628                 if(p < 0) // no more args? FAIL
629                 {
630                         // exception: exactly minargs left, this one included
631                         if(argc - startpos == minargs)
632                                 break;
633
634                         // otherwise fail
635                         return FALSE;
636                 }
637
638                 // cut to next semicolon
639                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
640                 if(q < 0)
641                         charlist = substring(cmdrestriction, p+1, -1);
642                 else
643                         charlist = substring(cmdrestriction, p+1, q - (p+1));
644
645                 // in case we ever want to allow semicolons in VoteCommand_checknasty
646                 // charlist = strreplace("^^", ";", charlist);
647
648                 if(charlist != "")
649                 {
650                         // verify the arg only contains allowed chars
651                         arg = argv(startpos);
652                         checkmate = strlen(arg);
653                         for(check = 0; check < checkmate; ++check)
654                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
655                                         return FALSE; // not allowed character
656                         // all characters are allowed. FINE.
657                 }
658
659                 ++startpos;
660                 --minargs;
661                 p = q;
662         }
663
664         return TRUE;
665 }
666
667 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
668 {
669         string first_command;
670         
671         first_command = argv(startpos);
672
673         if not(VoteCommand_checkinlist(first_command, vote_list))
674                 return FALSE;
675
676         if not(VoteCommand_checkargs(startpos, argc))
677                 return FALSE;
678
679         switch(first_command) // now go through and parse the proper commands to adjust as needed.
680         {
681                 case "kick":
682                 case "kickban": // catch all kick/kickban commands
683                 {
684                         entity victim = GetIndexedEntity(argc, (startpos + 1));
685                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
686                         
687                         if(accepted > 0)
688                         {
689                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
690                                 string command_arguments;
691                                 
692                                 if(first_command == "kickban")
693                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
694                                 else
695                                         command_arguments = reason;
696                                 
697                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
698                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
699                         }
700                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
701                         
702                         break;
703                 }
704                 
705                 case "map":
706                 case "chmap":
707                 case "gotomap": // re-direct all map selection commands to gotomap
708                 {
709                         vote_command = ValidateMap(argv(startpos + 1), caller);
710                         if not(vote_command) { return FALSE; }
711                         vote_parsed_command = strcat("gotomap ", vote_command);
712                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
713                         
714                         break;
715                 }
716                 
717                 default: 
718                 { 
719                         vote_parsed_command = vote_command;
720                         vote_parsed_display = strzone(strcat("^1", vote_command));
721                         
722                         break; 
723                 }
724         }
725
726         return TRUE;
727 }
728
729
730 // =======================
731 //  Command Sub-Functions
732 // =======================
733
734 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
735 {
736         switch(request)
737         {
738                 case CMD_REQUEST_COMMAND:
739                 {
740                         if not(vote_called) { print_to(caller, "^1No vote called."); }
741                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
742                         
743                         else // everything went okay, continue changing vote
744                         {
745                                 print_to(caller, "^1You abstained from your vote.");
746                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
747                                 msg_entity = caller;
748                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
749                         }
750                         
751                         return;
752                 }
753                         
754                 default:
755                 case CMD_REQUEST_USAGE:
756                 {
757                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
758                         print_to(caller, "  No arguments required.");
759                         return;
760                 }
761         }
762 }
763
764 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
765 {
766         switch(request)
767         {
768                 case CMD_REQUEST_COMMAND:
769                 {
770                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2) 
771                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage) 
772                                 || (autocvar_sv_vote_nospectators == 0));
773                                 
774                         float tmp_playercount = 0;
775                         entity tmp_player;
776                         
777                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
778                         
779                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
780                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
781                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
782                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
783                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
784                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
785                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
786                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
787
788                         else // everything went okay, continue with calling the vote
789                         {
790                                 vote_caller = caller; // remember who called the vote
791                                 vote_called = VOTE_NORMAL;
792                                 vote_called_command = strzone(vote_parsed_command);
793                                 vote_called_display = strzone(vote_parsed_display);
794                                 vote_endtime = time + autocvar_sv_vote_timeout;
795                                 
796                                 if(caller)
797                                 {
798                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
799                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
800                                         msg_entity = caller;
801                                 }
802                                 
803                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
804                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
805                                 
806                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
807                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
808                                 Nagger_VoteChanged();
809                                 VoteCount(TRUE); // needed if you are the only one
810                         }
811                         
812                         return;
813                 }
814                         
815                 default:
816                 case CMD_REQUEST_USAGE:
817                 {
818                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
819                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
820                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
821                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
822                         return;
823                 }
824         }
825 }
826
827 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
828 {
829         switch(request)
830         {
831                 case CMD_REQUEST_COMMAND:
832                 {
833                         if(autocvar_sv_vote_master)
834                         {
835                                 switch(strtolower(argv(2)))
836                                 {
837                                         case "do":
838                                         {
839                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
840                                                 
841                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
842                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
843                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
844                                                 
845                                                 else // everything went okay, proceed with command
846                                                 {
847                                                         localcmd(strcat(vote_parsed_command, "\n"));
848                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
849                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
850                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
851                                                 }
852                                                 
853                                                 return;
854                                         }
855                                         
856                                         case "login":
857                                         {
858                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
859                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
860                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
861
862                                                 else // everything went okay, proceed with giving this player master privilages
863                                                 {
864                                                         caller.vote_master = TRUE;
865                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
866                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
867                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
868                                                 }
869                                                 
870                                                 return;
871                                         }
872                                         
873                                         default: // calling a vote for master
874                                         {
875                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2) 
876                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage) 
877                                                         || (autocvar_sv_vote_nospectators == 0));
878                                                 
879                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
880                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
881                                                 else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
882                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
883                                                 
884                                                 else // everything went okay, continue with creating vote
885                                                 {
886                                                         vote_caller = caller;
887                                                         vote_called = VOTE_MASTER;
888                                                         vote_called_command = strzone("XXX");
889                                                         vote_called_display = strzone("^3master");
890                                                         vote_endtime = time + autocvar_sv_vote_timeout;
891                                                         
892                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
893                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
894                                                         
895                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
896                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
897                                                         Nagger_VoteChanged();
898                                                         VoteCount(TRUE); // needed if you are the only one
899                                                 }
900                                                 
901                                                 return;
902                                         }
903                                 }
904                         }
905                         else { print_to(caller, "^1Master control of voting is not allowed."); }
906                         
907                         return;
908                 }
909                         
910                 default:
911                 case CMD_REQUEST_USAGE:
912                 {
913                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
914                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
915                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
916                         return;
917                 }
918         }
919 }
920
921 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
922 {
923         switch(request)
924         {
925                 case CMD_REQUEST_COMMAND:
926                 {
927                         if not(vote_called) { print_to(caller, "^1No vote called."); }
928                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
929                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
930                         
931                         else // everything went okay, continue changing vote
932                         {
933                                 print_to(caller, "^1You rejected the vote.");
934                                 caller.vote_selection = VOTE_SELECT_REJECT;
935                                 msg_entity = caller;
936                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
937                         }
938                         
939                         return;
940                 }
941                         
942                 default:
943                 case CMD_REQUEST_USAGE:
944                 {
945                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
946                         print_to(caller, "  No arguments required.");
947                         return;
948                 }
949         }
950 }
951
952 void VoteCommand_status(float request, entity caller) // BOTH
953 {
954         switch(request)
955         {
956                 case CMD_REQUEST_COMMAND:
957                 {
958                         if(vote_called)
959                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
960                         else
961                                 print_to(caller, "^1No vote called.");
962                                 
963                         return;
964                 }
965                         
966                 default:
967                 case CMD_REQUEST_USAGE:
968                 {
969                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
970                         print_to(caller, "  No arguments required.");
971                         return;
972                 }
973         }
974 }
975
976 void VoteCommand_stop(float request, entity caller) // BOTH
977 {
978         switch(request)
979         {
980                 case CMD_REQUEST_COMMAND:
981                 {
982                         if not(vote_called) { print_to(caller, "^1No vote called."); }
983                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
984                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
985                         
986                         return;
987                 }
988                         
989                 default:
990                 case CMD_REQUEST_USAGE:
991                 {
992                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
993                         print_to(caller, "  No arguments required.");
994                         return;
995                 }
996         }
997 }
998
999 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1000 {
1001         switch(request)
1002         {
1003                 case CMD_REQUEST_COMMAND:
1004                 {
1005                         if not(vote_called) { print_to(caller, "^1No vote called."); }
1006                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1007                         
1008                         else // everything went okay, continue changing vote
1009                         {
1010                                 print_to(caller, "^1You accepted the vote.");
1011                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1012                                 msg_entity = caller;
1013                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
1014                         }
1015                         
1016                         return;
1017                 }
1018                         
1019                 default:
1020                 case CMD_REQUEST_USAGE:
1021                 {
1022                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1023                         print_to(caller, "  No arguments required.");
1024                         return;
1025                 }
1026         }
1027 }
1028
1029 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1030 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1031 void VoteCommand_(float request)
1032 {
1033         switch(request)
1034         {
1035                 case CMD_REQUEST_COMMAND:
1036                 {
1037                         
1038                         return;
1039                 }
1040                         
1041                 default:
1042                 case CMD_REQUEST_USAGE:
1043                 {
1044                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1045                         print_to(caller, "  No arguments required.");
1046                         return;
1047                 }
1048         }
1049 }
1050 */
1051
1052
1053 // ================================
1054 //  Macro system for vote commands
1055 // ================================
1056
1057 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1058 #define VOTE_COMMANDS(request,caller,arguments,command) \
1059         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1060         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1061         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1062         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1063         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1064         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1065         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1066         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1067         /* nothing */
1068
1069 void VoteCommand_macro_help(entity caller, float argc)
1070 {
1071         string command_origin = GetCommandPrefix(caller);
1072         
1073         if(argc == 2) // help display listing all commands
1074         {
1075                 print_to(caller, "\nVoting commands:\n");
1076                 #define VOTE_COMMAND(name,function,description,assignment) \
1077                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1078                         
1079                 VOTE_COMMANDS(0, caller, 0, "")
1080                 #undef VOTE_COMMAND
1081                 
1082                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1083                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1084                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1085         }
1086         else // usage for individual command
1087         {
1088                 #define VOTE_COMMAND(name,function,description,assignment) \
1089                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1090                         
1091                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1092                 #undef VOTE_COMMAND
1093         }
1094         
1095         return;
1096 }
1097
1098 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1099 {
1100         #define VOTE_COMMAND(name,function,description,assignment) \
1101                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1102                 
1103         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1104         #undef VOTE_COMMAND
1105         
1106         return FALSE;
1107 }
1108
1109
1110 // ======================================
1111 //  Main function handling vote commands
1112 // ======================================
1113
1114 void VoteCommand(float request, entity caller, float argc, string vote_command) 
1115 {
1116         // Guide for working with argc arguments by example:
1117         // argc:   1    - 2      - 3     - 4
1118         // argv:   0    - 1      - 2     - 3 
1119         // cmd     vote - master - login - password
1120         
1121         switch(request)
1122         {
1123                 case CMD_REQUEST_COMMAND:
1124                 {
1125                         if(VoteCommand_macro_command(caller, argc, vote_command))
1126                                 return;
1127                 }
1128                         
1129                 default:
1130                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1131                 case CMD_REQUEST_USAGE:
1132                 {
1133                         VoteCommand_macro_help(caller, argc);
1134                         return;
1135                 }
1136         }
1137 }