qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 27th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(warmup_stage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &= ~(64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(!IS_REAL_CLIENT(e) || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_caller = world;
 117         vote_endtime = 0;
 118
 119         vote_called_command = string_null;
 120         vote_called_display = string_null;
 121
 122         vote_parsed_command = string_null;
 123         vote_parsed_display = string_null;
 124
 125         Nagger_VoteChanged();
 126 }
 127
 128 void VoteStop(entity stopper)
 129 {
 130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 132
 133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 135
 136         VoteReset();
 137 }
 138
 139 void VoteAccept()
 140 {
 141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 142
 143         if((vote_called == VOTE_MASTER) && vote_caller)
 144                 vote_caller.vote_master = 1;
 145         else
 146                 localcmd(strcat(vote_called_command, "\n"));
 147
 148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 149
 150         VoteReset();
 151         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 152 }
 153
 154 void VoteReject()
 155 {
 156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 157         VoteReset();
 158         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 159 }
 160
 161 void VoteTimeout()
 162 {
 163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 164         VoteReset();
 165         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 166 }
 167
 168 void VoteSpam(float notvoters, float mincount, string result)
 169 {
 170         bprint(strcat(
 171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 172                 strcat("^2:^1", ftos(vote_reject_count)),
 173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 176
 177         if(autocvar_sv_eventlog)
 178         {
 179                 GameLogEcho(strcat(
 180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 181                         strcat(":", ftos(vote_reject_count)),
 182                         strcat(":", ftos(vote_abstain_count)),
 183                         strcat(":", ftos(notvoters)),
 184                         strcat(":", ftos(mincount))));
 185         }
 186 }
 187
 188 void VoteCount(float first_count)
 189 {
 190         // declarations
 191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 192
 193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 194                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 195                                 || (autocvar_sv_vote_nospectators == 0));
 196
 197         float vote_player_count = 0, notvoters = 0;
 198         float vote_real_player_count = 0, vote_real_accept_count = 0;
 199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 200         float vote_needed_of_voted, final_needed_votes;
 201         float vote_factor_overall, vote_factor_of_voted;
 202
 203         entity tmp_player;
 204
 205         Nagger_VoteCountChanged();
 206
 207         // add up all the votes from each connected client
 208         FOR_EACH_REALCLIENT(tmp_player)
 209         {
 210                 ++vote_player_count;
 211                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
 212
 213                 switch(tmp_player.vote_selection)
 214                 {
 215                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 216                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 217                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
 218                         default: break;
 219                 }
 220         }
 221
 222         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 223         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 224         {
 225                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 226                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 227                 VoteReset();
 228                 return;
 229         }
 230
 231         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 232         if(!spectators_allowed && (vote_real_player_count > 0))
 233         {
 234                 vote_accept_count = vote_real_accept_count;
 235                 vote_reject_count = vote_real_reject_count;
 236                 vote_abstain_count = vote_real_abstain_count;
 237                 vote_player_count = vote_real_player_count;
 238         }
 239
 240         // people who have no opinion in any way :D
 241         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 242
 243         // determine the goal for the vote to be passed or rejected normally
 244         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 245         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 246
 247         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 248         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 249         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 250
 251         // are there any players at all on the server? it could be an admin vote
 252         if(vote_player_count == 0 && first_count)
 253         {
 254                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 255                 VoteAccept();
 256                 return;
 257         }
 258
 259         // since there ARE players, finally calculate the result of the vote
 260         if(vote_accept_count >= vote_needed_overall)
 261         {
 262                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 263                 VoteAccept();
 264                 return;
 265         }
 266
 267         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 268         {
 269                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 270                 VoteReject();
 271                 return;
 272         }
 273
 274         // there is not enough votes in either direction, now lets just calculate what the voters have said
 275         if(time > vote_endtime)
 276         {
 277                 final_needed_votes = vote_needed_overall;
 278
 279                 if(autocvar_sv_vote_majority_factor_of_voted)
 280                 {
 281                         if(vote_accept_count >= vote_needed_of_voted)
 282                         {
 283                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 284                                 VoteAccept();
 285                                 return;
 286                         }
 287
 288                         if(vote_accept_count + vote_reject_count > 0)
 289                         {
 290                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 291                                 VoteReject();
 292                                 return;
 293                         }
 294
 295                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 296                 }
 297
 298                 // it didn't pass or fail, so not enough votes to even make a decision.
 299                 VoteSpam(notvoters, final_needed_votes, "timeout");
 300                 VoteTimeout();
 301         }
 302 }
 303
 304 void VoteThink()
 305 {
 306         if(vote_endtime > 0) // a vote was called
 307         if(time > vote_endtime) // time is up
 308         {
 309                 VoteCount(FALSE);
 310         }
 311
 312         return;
 313 }
 314
 315
 316 // =======================
 317 //  Game logic for warmup
 318 // =======================
 319
 320 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 321 void reset_map(float dorespawn)
 322 {
 323         entity oldself;
 324         oldself = self;
 325
 326         if(time <= game_starttime && round_handler_IsActive())
 327                 round_handler_Reset(game_starttime);
 328
 329         MUTATOR_CALLHOOK(reset_map_global);
 330
 331         for(self = world; (self = nextent(self)); )
 332         if(IS_NOT_A_CLIENT(self))
 333         {
 334                 if(self.reset)
 335                 {
 336                         self.reset();
 337                         continue;
 338                 }
 339
 340                 if(self.team_saved)
 341                         self.team = self.team_saved;
 342
 343                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
 344                         remove(self);
 345         }
 346
 347         // Waypoints and assault start come LAST
 348         for(self = world; (self = nextent(self)); )
 349         if(IS_NOT_A_CLIENT(self))
 350         {
 351                 if(self.reset2)
 352                 {
 353                         self.reset2();
 354                         continue;
 355                 }
 356         }
 357
 358         // Moving the player reset code here since the player-reset depends
 359         // on spawnpoint entities which have to be reset first --blub
 360         if(dorespawn)
 361         if(!MUTATOR_CALLHOOK(reset_map_players))
 362         FOR_EACH_CLIENT(self) // reset all players
 363         {
 364                 /*
 365                 only reset players if a restart countdown is active
 366                 this can either be due to cvar sv_ready_restart_after_countdown having set
 367                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 368                 sv_ready_restart_after_countdown is not used and countdown is still running
 369                 */
 370                 if (restart_mapalreadyrestarted || (time < game_starttime))
 371                 {
 372                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 373                         if (IS_PLAYER(self)) {
 374                                 //PlayerScore_Clear(self);
 375                                 self.killcount = 0;
 376                                 //stop the player from moving so that he stands still once he gets respawned
 377                                 self.velocity = '0 0 0';
 378                                 self.avelocity = '0 0 0';
 379                                 self.movement = '0 0 0';
 380                                 PutClientInServer();
 381                         }
 382                 }
 383         }
 384
 385         if(g_keyhunt)
 386                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
 387
 388         self = oldself;
 389 }
 390
 391 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 392 void ReadyRestart_think()
 393 {
 394         restart_mapalreadyrestarted = 1;
 395         reset_map(TRUE);
 396         Score_ClearAll();
 397         remove(self);
 398
 399         return;
 400 }
 401
 402 // Forces a restart of the game without actually reloading the map // this is a mess...
 403 void ReadyRestart_force()
 404 {
 405         entity tmp_player, restart_timer;
 406
 407         bprint("^1Server is restarting...\n");
 408
 409         VoteReset();
 410
 411         // clear overtime, we have to decrease timelimit to its original value again.
 412         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 413
 414         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 415
 416         readyrestart_happened = 1;
 417         game_starttime = time + RESTART_COUNTDOWN;
 418
 419         // clear player attributes
 420         FOR_EACH_CLIENT(tmp_player)
 421         {
 422                 tmp_player.alivetime = 0;
 423                 tmp_player.killcount = 0;
 424                 PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, -PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 425         }
 426
 427         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 428
 429         // disable the warmup global for the server
 430         warmup_stage = 0; // once the game is restarted the game is in match stage
 431
 432         // reset the .ready status of all players (also spectators)
 433         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
 434         readycount = 0;
 435         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 436
 437         // lock teams with lockonrestart
 438         if(autocvar_teamplay_lockonrestart && teamplay)
 439         {
 440                 lockteams = 1;
 441                 bprint("^1The teams are now locked.\n");
 442         }
 443
 444         //initiate the restart-countdown-announcer entity
 445         if(autocvar_sv_ready_restart_after_countdown)
 446         {
 447                 restart_timer = spawn();
 448                 restart_timer.think = ReadyRestart_think;
 449                 restart_timer.nextthink = game_starttime;
 450         }
 451
 452         // after a restart every players number of allowed timeouts gets reset, too
 453         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 454
 455         //reset map immediately if this cvar is not set
 456         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 457
 458         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 459 }
 460
 461 void ReadyRestart()
 462 {
 463         // no arena, assault support yet...
 464         if(g_assault | gameover | intermission_running | race_completing)
 465                 localcmd("restart\n");
 466         else
 467                 localcmd("\nsv_hook_gamerestart\n");
 468
 469         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 470         // Otherwise scores could be manipulated during the countdown.
 471         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 472
 473         ReadyRestart_force();
 474
 475         return;
 476 }
 477
 478 // Count the players who are ready and determine whether or not to restart the match
 479 void ReadyCount()
 480 {
 481         entity tmp_player;
 482         float ready_needed_factor, ready_needed_count;
 483         float t_ready = 0, t_players = 0;
 484
 485         FOR_EACH_REALCLIENT(tmp_player)
 486         {
 487                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 488                 {
 489                         ++t_players;
 490                         if(tmp_player.ready) { ++t_ready; }
 491                 }
 492         }
 493
 494         readycount = t_ready;
 495
 496         Nagger_ReadyCounted();
 497
 498         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 499         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 500
 501         if(readycount >= ready_needed_count)
 502         {
 503                 ReadyRestart();
 504         }
 505
 506         return;
 507 }
 508
 509
 510 // ======================================
 511 //  Supporting functions for VoteCommand
 512 // ======================================
 513
 514 float Votecommand_check_assignment(entity caller, float assignment)
 515 {
 516         float from_server = (!caller);
 517
 518         if((assignment == VC_ASGNMNT_BOTH)
 519                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 520                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 521         {
 522                 return TRUE;
 523         }
 524
 525         return FALSE;
 526 }
 527
 528 string VoteCommand_extractcommand(string input, float startpos, float argc)
 529 {
 530         string output;
 531
 532         if((argc - 1) < startpos)
 533                 output = "";
 534         else
 535                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 536
 537         return output;
 538 }
 539
 540 float VoteCommand_checknasty(string vote_command)
 541 {
 542         if((strstrofs(vote_command, ";", 0) >= 0)
 543                 || (strstrofs(vote_command, "\n", 0) >= 0)
 544                 || (strstrofs(vote_command, "\r", 0) >= 0)
 545                 || (strstrofs(vote_command, "$", 0) >= 0))
 546                 return FALSE;
 547
 548         return TRUE;
 549 }
 550
 551 float VoteCommand_checkinlist(string vote_command, string list)
 552 {
 553         string l = strcat(" ", list, " ");
 554
 555         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 556                 return TRUE;
 557
 558         return FALSE;
 559 }
 560
 561 string ValidateMap(string validated_map, entity caller)
 562 {
 563         validated_map = MapInfo_FixName(validated_map);
 564
 565         if (!validated_map)
 566         {
 567                 print_to(caller, "This map is not available on this server.");
 568                 return string_null;
 569         }
 570
 571         if(!autocvar_sv_vote_override_mostrecent && caller)
 572         {
 573                 if(Map_IsRecent(validated_map))
 574                 {
 575                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 576                         return string_null;
 577                 }
 578         }
 579
 580         if(!MapInfo_CheckMap(validated_map))
 581         {
 582                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 583                 return string_null;
 584         }
 585
 586         return validated_map;
 587 }
 588
 589 float VoteCommand_checkargs(float startpos, float argc)
 590 {
 591         float p, q, check, minargs;
 592         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 593         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 594         string charlist, arg;
 595         float checkmate;
 596
 597         if(cmdrestriction == "")
 598                 return TRUE;
 599
 600         ++startpos; // skip command name
 601
 602         // check minimum arg count
 603
 604         // 0 args: argc == startpos
 605         // 1 args: argc == startpos + 1
 606         // ...
 607
 608         minargs = stof(cmdrestriction);
 609         if(argc - startpos < minargs)
 610                 return FALSE;
 611
 612         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 613
 614         for(;;)
 615         {
 616                 // we know that at any time, startpos <= argc - minargs
 617                 // so this means: argc-minargs >= startpos >= argc, thus
 618                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 619                 // have been seen already
 620
 621                 if(startpos >= argc) // all args checked? GOOD
 622                         break;
 623
 624                 if(p < 0) // no more args? FAIL
 625                 {
 626                         // exception: exactly minargs left, this one included
 627                         if(argc - startpos == minargs)
 628                                 break;
 629
 630                         // otherwise fail
 631                         return FALSE;
 632                 }
 633
 634                 // cut to next semicolon
 635                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 636                 if(q < 0)
 637                         charlist = substring(cmdrestriction, p+1, -1);
 638                 else
 639                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 640
 641                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 642                 // charlist = strreplace("^^", ";", charlist);
 643
 644                 if(charlist != "")
 645                 {
 646                         // verify the arg only contains allowed chars
 647                         arg = argv(startpos);
 648                         checkmate = strlen(arg);
 649                         for(check = 0; check < checkmate; ++check)
 650                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 651                                         return FALSE; // not allowed character
 652                         // all characters are allowed. FINE.
 653                 }
 654
 655                 ++startpos;
 656                 --minargs;
 657                 p = q;
 658         }
 659
 660         return TRUE;
 661 }
 662
 663 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 664 {
 665         string first_command;
 666
 667         first_command = argv(startpos);
 668
 669         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 670                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 671                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 672         );*/
 673
 674         if(
 675                 (autocvar_sv_vote_limit > 0)
 676                 &&
 677                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 678         )
 679                 return FALSE;
 680
 681         if (!VoteCommand_checkinlist(first_command, vote_list))
 682                 return FALSE;
 683
 684         if (!VoteCommand_checkargs(startpos, argc))
 685                 return FALSE;
 686
 687         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 688         {
 689                 case "kick":
 690                 case "kickban": // catch all kick/kickban commands
 691                 {
 692                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 693                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
 694
 695                         if(accepted > 0)
 696                         {
 697                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 698                                 string command_arguments;
 699
 700                                 if(first_command == "kickban")
 701                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 702                                 else
 703                                         command_arguments = reason;
 704
 705                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 706                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 707                         }
 708                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
 709
 710                         break;
 711                 }
 712
 713                 case "map":
 714                 case "chmap":
 715                 case "gotomap": // re-direct all map selection commands to gotomap
 716                 {
 717                         vote_command = ValidateMap(argv(startpos + 1), caller);
 718                         if (!vote_command) { return FALSE; }
 719                         vote_parsed_command = strcat("gotomap ", vote_command);
 720                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 721
 722                         break;
 723                 }
 724
 725                 default:
 726                 {
 727                         vote_parsed_command = vote_command;
 728                         vote_parsed_display = strzone(strcat("^1", vote_command));
 729
 730                         break;
 731                 }
 732         }
 733
 734         return TRUE;
 735 }
 736
 737
 738 // =======================
 739 //  Command Sub-Functions
 740 // =======================
 741
 742 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 743 {
 744         switch(request)
 745         {
 746                 case CMD_REQUEST_COMMAND:
 747                 {
 748                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 749                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 750
 751                         else // everything went okay, continue changing vote
 752                         {
 753                                 print_to(caller, "^1You abstained from your vote.");
 754                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 755                                 msg_entity = caller;
 756                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 757                         }
 758
 759                         return;
 760                 }
 761
 762                 default:
 763                 case CMD_REQUEST_USAGE:
 764                 {
 765                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 766                         print_to(caller, "  No arguments required.");
 767                         return;
 768                 }
 769         }
 770 }
 771
 772 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 773 {
 774         switch(request)
 775         {
 776                 case CMD_REQUEST_COMMAND:
 777                 {
 778                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 779                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 780                                 || (autocvar_sv_vote_nospectators == 0));
 781
 782                         float tmp_playercount = 0;
 783                         entity tmp_player;
 784
 785                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 786
 787                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 788                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 789                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 790                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 791                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 792                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 793                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 794                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 795
 796                         else // everything went okay, continue with calling the vote
 797                         {
 798                                 vote_caller = caller; // remember who called the vote
 799                                 vote_called = VOTE_NORMAL;
 800                                 vote_called_command = strzone(vote_parsed_command);
 801                                 vote_called_display = strzone(vote_parsed_display);
 802                                 vote_endtime = time + autocvar_sv_vote_timeout;
 803
 804                                 if(caller)
 805                                 {
 806                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 807                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 808                                         msg_entity = caller;
 809                                 }
 810
 811                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 812                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
 813
 814                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 815                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 816                                 Nagger_VoteChanged();
 817                                 VoteCount(TRUE); // needed if you are the only one
 818                         }
 819
 820                         return;
 821                 }
 822
 823                 default:
 824                 case CMD_REQUEST_USAGE:
 825                 {
 826                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 827                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 828                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 829                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 830                         return;
 831                 }
 832         }
 833 }
 834
 835 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 836 {
 837         switch(request)
 838         {
 839                 case CMD_REQUEST_COMMAND:
 840                 {
 841                         if(autocvar_sv_vote_master)
 842                         {
 843                                 switch(strtolower(argv(2)))
 844                                 {
 845                                         case "do":
 846                                         {
 847                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 848
 849                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 850                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 851                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 852
 853                                                 else // everything went okay, proceed with command
 854                                                 {
 855                                                         localcmd(strcat(vote_parsed_command, "\n"));
 856                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 857                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 858                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 859                                                 }
 860
 861                                                 return;
 862                                         }
 863
 864                                         case "login":
 865                                         {
 866                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 867                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 868                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 869
 870                                                 else // everything went okay, proceed with giving this player master privilages
 871                                                 {
 872                                                         caller.vote_master = TRUE;
 873                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 874                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 875                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 876                                                 }
 877
 878                                                 return;
 879                                         }
 880
 881                                         default: // calling a vote for master
 882                                         {
 883                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 884                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 885                                                         || (autocvar_sv_vote_nospectators == 0));
 886
 887                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 888                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 889                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 890                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 891
 892                                                 else // everything went okay, continue with creating vote
 893                                                 {
 894                                                         vote_caller = caller;
 895                                                         vote_called = VOTE_MASTER;
 896                                                         vote_called_command = strzone("XXX");
 897                                                         vote_called_display = strzone("^3master");
 898                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 899
 900                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 901                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 902
 903                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 904                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 905                                                         Nagger_VoteChanged();
 906                                                         VoteCount(TRUE); // needed if you are the only one
 907                                                 }
 908
 909                                                 return;
 910                                         }
 911                                 }
 912                         }
 913                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 914
 915                         return;
 916                 }
 917
 918                 default:
 919                 case CMD_REQUEST_USAGE:
 920                 {
 921                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 922                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 923                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 924                         return;
 925                 }
 926         }
 927 }
 928
 929 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 930 {
 931         switch(request)
 932         {
 933                 case CMD_REQUEST_COMMAND:
 934                 {
 935                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 936                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 937                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 938
 939                         else // everything went okay, continue changing vote
 940                         {
 941                                 print_to(caller, "^1You rejected the vote.");
 942                                 caller.vote_selection = VOTE_SELECT_REJECT;
 943                                 msg_entity = caller;
 944                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 945                         }
 946
 947                         return;
 948                 }
 949
 950                 default:
 951                 case CMD_REQUEST_USAGE:
 952                 {
 953                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 954                         print_to(caller, "  No arguments required.");
 955                         return;
 956                 }
 957         }
 958 }
 959
 960 void VoteCommand_status(float request, entity caller) // BOTH
 961 {
 962         switch(request)
 963         {
 964                 case CMD_REQUEST_COMMAND:
 965                 {
 966                         if(vote_called)
 967                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 968                         else
 969                                 print_to(caller, "^1No vote called.");
 970
 971                         return;
 972                 }
 973
 974                 default:
 975                 case CMD_REQUEST_USAGE:
 976                 {
 977                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 978                         print_to(caller, "  No arguments required.");
 979                         return;
 980                 }
 981         }
 982 }
 983
 984 void VoteCommand_stop(float request, entity caller) // BOTH
 985 {
 986         switch(request)
 987         {
 988                 case CMD_REQUEST_COMMAND:
 989                 {
 990                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 991                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 992                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 993
 994                         return;
 995                 }
 996
 997                 default:
 998                 case CMD_REQUEST_USAGE:
 999                 {
1000                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1001                         print_to(caller, "  No arguments required.");
1002                         return;
1003                 }
1004         }
1005 }
1006
1007 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1008 {
1009         switch(request)
1010         {
1011                 case CMD_REQUEST_COMMAND:
1012                 {
1013                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1014                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1015
1016                         else // everything went okay, continue changing vote
1017                         {
1018                                 print_to(caller, "^1You accepted the vote.");
1019                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1020                                 msg_entity = caller;
1021                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
1022                         }
1023
1024                         return;
1025                 }
1026
1027                 default:
1028                 case CMD_REQUEST_USAGE:
1029                 {
1030                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1031                         print_to(caller, "  No arguments required.");
1032                         return;
1033                 }
1034         }
1035 }
1036
1037 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1038 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1039 void VoteCommand_(float request)
1040 {
1041         switch(request)
1042         {
1043                 case CMD_REQUEST_COMMAND:
1044                 {
1045
1046                         return;
1047                 }
1048
1049                 default:
1050                 case CMD_REQUEST_USAGE:
1051                 {
1052                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1053                         print_to(caller, "  No arguments required.");
1054                         return;
1055                 }
1056         }
1057 }
1058 */
1059
1060
1061 // ================================
1062 //  Macro system for vote commands
1063 // ================================
1064
1065 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1066 #define VOTE_COMMANDS(request,caller,arguments,command) \
1067         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1068         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1069         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1070         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1071         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1072         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1073         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1074         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1075         /* nothing */
1076
1077 void VoteCommand_macro_help(entity caller, float argc)
1078 {
1079         string command_origin = GetCommandPrefix(caller);
1080
1081         if(argc == 2 || argv(2) == "help") // help display listing all commands
1082         {
1083                 print_to(caller, "\nVoting commands:\n");
1084                 #define VOTE_COMMAND(name,function,description,assignment) \
1085                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1086
1087                 VOTE_COMMANDS(0, caller, 0, "")
1088                 #undef VOTE_COMMAND
1089
1090                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1091                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1092                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1093         }
1094         else // usage for individual command
1095         {
1096                 #define VOTE_COMMAND(name,function,description,assignment) \
1097                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1098
1099                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1100                 #undef VOTE_COMMAND
1101         }
1102
1103         return;
1104 }
1105
1106 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1107 {
1108         #define VOTE_COMMAND(name,function,description,assignment) \
1109                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1110
1111         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1112         #undef VOTE_COMMAND
1113
1114         return FALSE;
1115 }
1116
1117
1118 // ======================================
1119 //  Main function handling vote commands
1120 // ======================================
1121
1122 void VoteCommand(float request, entity caller, float argc, string vote_command)
1123 {
1124         // Guide for working with argc arguments by example:
1125         // argc:   1    - 2      - 3     - 4
1126         // argv:   0    - 1      - 2     - 3
1127         // cmd     vote - master - login - password
1128
1129         switch(request)
1130         {
1131                 case CMD_REQUEST_COMMAND:
1132                 {
1133                         if(VoteCommand_macro_command(caller, argc, vote_command))
1134                                 return;
1135                 }
1136
1137                 default:
1138                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1139                 case CMD_REQUEST_USAGE:
1140                 {
1141                         VoteCommand_macro_help(caller, argc);
1142                         return;
1143                 }
1144         }
1145 }