qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 27th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(inWarmupStage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &~= (64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_caller = world;
 117         vote_endtime = 0;
 118
 119         vote_called_command = string_null;
 120         vote_called_display = string_null;
 121
 122         vote_parsed_command = string_null;
 123         vote_parsed_display = string_null;
 124
 125         Nagger_VoteChanged();
 126 }
 127
 128 void VoteStop(entity stopper)
 129 {
 130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 132
 133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 135
 136         VoteReset();
 137 }
 138
 139 void VoteAccept()
 140 {
 141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 142
 143         if((vote_called == VOTE_MASTER) && vote_caller)
 144                 vote_caller.vote_master = 1;
 145         else
 146                 localcmd(strcat(vote_called_command, "\n"));
 147
 148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 149
 150         VoteReset();
 151         Announce("voteaccept");
 152 }
 153
 154 void VoteReject()
 155 {
 156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 157         VoteReset();
 158         Announce("votefail");
 159 }
 160
 161 void VoteTimeout()
 162 {
 163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 164         VoteReset();
 165         Announce("votefail");
 166 }
 167
 168 void VoteSpam(float notvoters, float mincount, string result)
 169 {
 170         bprint(strcat(
 171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 172                 strcat("^2:^1", ftos(vote_reject_count)),
 173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? string_null : "have to "), "vote\n"))));
 176
 177         if(autocvar_sv_eventlog)
 178         {
 179                 GameLogEcho(strcat(
 180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 181                         strcat(":", ftos(vote_reject_count)),
 182                         strcat(":", ftos(vote_abstain_count)),
 183                         strcat(":", ftos(notvoters)),
 184                         strcat(":", ftos(mincount))));
 185         }
 186 }
 187
 188 void VoteCount(float first_count)
 189 {
 190         // declarations
 191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 192
 193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
 195                                 || (autocvar_sv_vote_nospectators == 0));
 196
 197         float vote_player_count = 0, is_player, notvoters = 0;
 198         float vote_real_player_count = 0, vote_real_accept_count = 0;
 199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 200         float vote_needed_of_voted, final_needed_votes;
 201         float vote_factor_overall, vote_factor_of_voted;
 202
 203         entity tmp_player;
 204
 205         Nagger_VoteCountChanged();
 206
 207         // add up all the votes from each connected client
 208         FOR_EACH_REALCLIENT(tmp_player)
 209         {
 210                 is_player = (tmp_player.classname == "player");
 211
 212                 ++vote_player_count;
 213                 if(is_player) { ++vote_real_player_count; }
 214
 215                 switch(tmp_player.vote_selection)
 216                 {
 217                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
 218                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
 219                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
 220                         default: break;
 221                 }
 222         }
 223
 224         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 225         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 226         {
 227                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 228                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 229                 VoteReset();
 230                 return;
 231         }
 232
 233         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 234         if(!spectators_allowed && (vote_real_player_count > 0))
 235         {
 236                 vote_accept_count = vote_real_accept_count;
 237                 vote_reject_count = vote_real_reject_count;
 238                 vote_abstain_count = vote_real_abstain_count;
 239                 vote_player_count = vote_real_player_count;
 240         }
 241
 242         // people who have no opinion in any way :D
 243         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 244
 245         // determine the goal for the vote to be passed or rejected normally
 246         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 247         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 248
 249         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 250         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 251         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 252
 253         // are there any players at all on the server? it could be an admin vote
 254         if(vote_player_count == 0 && first_count)
 255         {
 256                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 257                 VoteAccept();
 258                 return;
 259         }
 260
 261         // since there ARE players, finally calculate the result of the vote
 262         if(vote_accept_count >= vote_needed_overall)
 263         {
 264                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 265                 VoteAccept();
 266                 return;
 267         }
 268
 269         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 270         {
 271                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 272                 VoteReject();
 273                 return;
 274         }
 275
 276         // there is not enough votes in either direction, now lets just calculate what the voters have said
 277         if(time > vote_endtime)
 278         {
 279                 final_needed_votes = vote_needed_overall;
 280
 281                 if(autocvar_sv_vote_majority_factor_of_voted)
 282                 {
 283                         if(vote_accept_count >= vote_needed_of_voted)
 284                         {
 285                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 286                                 VoteAccept();
 287                                 return;
 288                         }
 289
 290                         if(vote_accept_count + vote_reject_count > 0)
 291                         {
 292                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 293                                 VoteReject();
 294                                 return;
 295                         }
 296
 297                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 298                 }
 299
 300                 // it didn't pass or fail, so not enough votes to even make a decision.
 301                 VoteSpam(notvoters, final_needed_votes, "timeout");
 302                 VoteTimeout();
 303         }
 304 }
 305
 306 void VoteThink()
 307 {
 308         if(vote_endtime > 0) // a vote was called
 309         if(time > vote_endtime) // time is up
 310         {
 311                 VoteCount(FALSE);
 312         }
 313
 314         return;
 315 }
 316
 317
 318 // =======================
 319 //  Game logic for warmup
 320 // =======================
 321
 322 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 323 void ReadyRestart_think()
 324 {
 325         restart_mapalreadyrestarted = 1;
 326         reset_map(TRUE);
 327         Score_ClearAll();
 328         remove(self);
 329
 330         return;
 331 }
 332
 333 // Forces a restart of the game without actually reloading the map // this is a mess...
 334 void ReadyRestart_force()
 335 {
 336         entity tmp_player, restart_timer;
 337
 338         bprint("^1Server is restarting...\n");
 339
 340         VoteReset();
 341
 342         // clear overtime, we have to decrease timelimit to its original value again.
 343         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 344
 345         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 346
 347         readyrestart_happened = 1;
 348         game_starttime = time;
 349         if(!g_ca && !g_arena) { game_starttime += RESTART_COUNTDOWN; }
 350
 351         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 352
 353         // disable the warmup global for the server
 354         inWarmupStage = 0; // once the game is restarted the game is in match stage
 355
 356         // reset the .ready status of all players (also spectators)
 357         FOR_EACH_CLIENTSLOT(tmp_player) { tmp_player.ready = 0; }
 358         readycount = 0;
 359         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 360
 361         // lock teams with lockonrestart
 362         if(autocvar_teamplay_lockonrestart && teamplay)
 363         {
 364                 lockteams = 1;
 365                 bprint("^1The teams are now locked.\n");
 366         }
 367
 368         //initiate the restart-countdown-announcer entity
 369         if(autocvar_sv_ready_restart_after_countdown && !g_ca && !g_arena)
 370         {
 371                 restart_timer = spawn();
 372                 restart_timer.think = ReadyRestart_think;
 373                 restart_timer.nextthink = game_starttime;
 374         }
 375
 376         // after a restart every players number of allowed timeouts gets reset, too
 377         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 378
 379         //reset map immediately if this cvar is not set
 380         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 381
 382         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 383 }
 384
 385 void ReadyRestart()
 386 {
 387         // no arena, assault support yet...
 388         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 389                 localcmd("restart\n");
 390         else
 391                 localcmd("\nsv_hook_gamerestart\n");
 392
 393         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 394         // Otherwise scores could be manipulated during the countdown.
 395         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 396
 397         ReadyRestart_force();
 398
 399         return;
 400 }
 401
 402 // Count the players who are ready and determine whether or not to restart the match
 403 void ReadyCount()
 404 {
 405         entity tmp_player;
 406         float ready_needed_factor, ready_needed_count;
 407         float t_ready = 0, t_players = 0;
 408
 409         FOR_EACH_REALPLAYER(tmp_player)
 410         {
 411                 ++t_players;
 412                 if(tmp_player.ready) { ++t_ready; }
 413         }
 414
 415         readycount = t_ready;
 416
 417         Nagger_ReadyCounted();
 418
 419         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 420         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 421
 422         if(readycount >= ready_needed_count)
 423         {
 424                 ReadyRestart();
 425         }
 426
 427         return;
 428 }
 429
 430
 431 // ======================================
 432 //  Supporting functions for VoteCommand
 433 // ======================================
 434
 435 float Votecommand_check_assignment(entity caller, float assignment)
 436 {
 437         float from_server = (!caller);
 438
 439         if((assignment == VC_ASGNMNT_BOTH)
 440                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 441                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 442         {
 443                 return TRUE;
 444         }
 445
 446         return FALSE;
 447 }
 448
 449 string VoteCommand_extractcommand(string input, float startpos, float argc)
 450 {
 451         string output;
 452
 453         if((argc - 1) < startpos)
 454                 output = "";
 455         else
 456                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 457
 458         return output;
 459 }
 460
 461 float VoteCommand_checknasty(string vote_command)
 462 {
 463         if((strstrofs(vote_command, ";", 0) >= 0)
 464                 || (strstrofs(vote_command, "\n", 0) >= 0)
 465                 || (strstrofs(vote_command, "\r", 0) >= 0)
 466                 || (strstrofs(vote_command, "$", 0) >= 0))
 467                 return FALSE;
 468
 469         return TRUE;
 470 }
 471
 472 float VoteCommand_checkinlist(string vote_command, string list)
 473 {
 474         string l = strcat(" ", list, " ");
 475
 476         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 477                 return TRUE;
 478
 479         // if gotomap is allowed, chmap is too, and vice versa
 480         if(vote_command == "gotomap")
 481                 if(strstrofs(l, " chmap ", 0) >= 0)
 482                         return TRUE;
 483
 484         if(vote_command == "chmap")
 485                 if(strstrofs(l, " gotomap ", 0) >= 0)
 486                         return TRUE;
 487
 488         return FALSE;
 489 }
 490
 491 string ValidateMap(string validated_map, entity caller)
 492 {
 493         validated_map = MapInfo_FixName(validated_map);
 494
 495         if(!validated_map)
 496         {
 497                 print_to(caller, "This map is not available on this server.");
 498                 return string_null;
 499         }
 500
 501         if(!autocvar_sv_vote_override_mostrecent && caller)
 502         {
 503                 if(Map_IsRecent(validated_map))
 504                 {
 505                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 506                         return string_null;
 507                 }
 508         }
 509
 510         if(!MapInfo_CheckMap(validated_map))
 511         {
 512                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 513                 return string_null;
 514         }
 515
 516         return validated_map;
 517 }
 518
 519 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 520 {
 521         string first_command;
 522
 523         first_command = argv(startpos);
 524
 525         if not(VoteCommand_checkinlist(first_command, vote_list))
 526                 return FALSE;
 527
 528         if(argc < startpos) // These commands won't work without arguments
 529         {
 530                 switch(first_command)
 531                 {
 532                         case "map":
 533                         case "chmap":
 534                         case "gotomap":
 535                         case "kick":
 536                         case "kickban":
 537                                 return FALSE;
 538
 539                         default: { break; }
 540                 }
 541         }
 542
 543         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 544         {
 545                 case "kick":
 546                 case "kickban": // catch all kick/kickban commands
 547                 {
 548                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 549                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
 550
 551                         if(accepted > 0)
 552                         {
 553                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)) : "No reason provided");
 554                                 string command_arguments;
 555
 556                                 if(first_command == "kickban")
 557                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 558                                 else
 559                                         command_arguments = reason;
 560
 561                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 562                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 563                         }
 564                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
 565
 566                         break;
 567                 }
 568
 569                 case "map":
 570                 case "chmap":
 571                 case "gotomap": // re-direct all map selection commands to gotomap
 572                 {
 573                         vote_command = ValidateMap(argv(startpos + 1), caller);
 574                         if not(vote_command) { return FALSE; }
 575                         vote_parsed_command = strcat("gotomap ", vote_command);
 576                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 577
 578                         break;
 579                 }
 580
 581                 default:
 582                 {
 583                         vote_parsed_command = vote_command;
 584                         vote_parsed_display = strzone(strcat("^1", vote_command));
 585
 586                         break;
 587                 }
 588         }
 589
 590         return TRUE;
 591 }
 592
 593
 594 // =======================
 595 //  Command Sub-Functions
 596 // =======================
 597
 598 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 599 {
 600         switch(request)
 601         {
 602                 case CMD_REQUEST_COMMAND:
 603                 {
 604                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 605                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 606
 607                         else // everything went okay, continue changing vote
 608                         {
 609                                 print_to(caller, "^1You abstained from your vote.");
 610                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 611                                 msg_entity = caller;
 612                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 613                         }
 614
 615                         return;
 616                 }
 617
 618                 default:
 619                 case CMD_REQUEST_USAGE:
 620                 {
 621                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 622                         print_to(caller, "  No arguments required.");
 623                         return;
 624                 }
 625         }
 626 }
 627
 628 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 629 {
 630         switch(request)
 631         {
 632                 case CMD_REQUEST_COMMAND:
 633                 {
 634                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 635                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 636                                 || (autocvar_sv_vote_nospectators == 0));
 637
 638                         float tmp_playercount = 0;
 639                         entity tmp_player;
 640
 641                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 642
 643                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
 644                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 645                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 646                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 647                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 648                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 649                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 650
 651                         else // everything went okay, continue with calling the vote
 652                         {
 653                                 vote_caller = caller; // remember who called the vote
 654                                 vote_called = VOTE_NORMAL;
 655                                 vote_called_command = strzone(vote_parsed_command);
 656                                 vote_called_display = strzone(vote_parsed_display);
 657                                 vote_endtime = time + autocvar_sv_vote_timeout;
 658
 659                                 if(caller)
 660                                 {
 661                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 662                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 663                                         msg_entity = caller;
 664                                 }
 665
 666                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 667                                 if(tmp_playercount > 1) { Announce("votecall"); } // don't announce a "vote now" sound if player is alone
 668
 669                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 670                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 671                                 Nagger_VoteChanged();
 672                                 VoteCount(TRUE); // needed if you are the only one
 673                         }
 674
 675                         return;
 676                 }
 677
 678                 default:
 679                 case CMD_REQUEST_USAGE:
 680                 {
 681                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 682                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 683                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 684                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 685                         return;
 686                 }
 687         }
 688 }
 689
 690 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 691 {
 692         switch(request)
 693         {
 694                 case CMD_REQUEST_COMMAND:
 695                 {
 696                         if(autocvar_sv_vote_master)
 697                         {
 698                                 switch(strtolower(argv(2)))
 699                                 {
 700                                         case "do":
 701                                         {
 702                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 703
 704                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 705                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 706                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 707
 708                                                 else // everything went okay, proceed with command
 709                                                 {
 710                                                         localcmd(strcat(vote_parsed_command, "\n"));
 711                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 712                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 713                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 714                                                 }
 715
 716                                                 return;
 717                                         }
 718
 719                                         case "login":
 720                                         {
 721                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
 722                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 723                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 724
 725                                                 else // everything went okay, proceed with giving this player master privilages
 726                                                 {
 727                                                         caller.vote_master = TRUE;
 728                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 729                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 730                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 731                                                 }
 732
 733                                                 return;
 734                                         }
 735
 736                                         default: // calling a vote for master
 737                                         {
 738                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 739                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 740                                                         || (autocvar_sv_vote_nospectators == 0));
 741
 742                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 743                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 744                                                 else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 745                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 746
 747                                                 else // everything went okay, continue with creating vote
 748                                                 {
 749                                                         vote_caller = caller;
 750                                                         vote_called = VOTE_MASTER;
 751                                                         vote_called_command = strzone("XXX");
 752                                                         vote_called_display = strzone("^3master");
 753                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 754
 755                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 756                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 757
 758                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 759                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 760                                                         Nagger_VoteChanged();
 761                                                         VoteCount(TRUE); // needed if you are the only one
 762                                                 }
 763
 764                                                 return;
 765                                         }
 766                                 }
 767                         }
 768                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 769
 770                         return;
 771                 }
 772
 773                 default:
 774                 case CMD_REQUEST_USAGE:
 775                 {
 776                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 777                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 778                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 779                         return;
 780                 }
 781         }
 782 }
 783
 784 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 785 {
 786         switch(request)
 787         {
 788                 case CMD_REQUEST_COMMAND:
 789                 {
 790                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 791                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 792                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 793
 794                         else // everything went okay, continue changing vote
 795                         {
 796                                 print_to(caller, "^1You rejected the vote.");
 797                                 caller.vote_selection = VOTE_SELECT_REJECT;
 798                                 msg_entity = caller;
 799                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 800                         }
 801
 802                         return;
 803                 }
 804
 805                 default:
 806                 case CMD_REQUEST_USAGE:
 807                 {
 808                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 809                         print_to(caller, "  No arguments required.");
 810                         return;
 811                 }
 812         }
 813 }
 814
 815 void VoteCommand_status(float request, entity caller) // BOTH
 816 {
 817         switch(request)
 818         {
 819                 case CMD_REQUEST_COMMAND:
 820                 {
 821                         if(vote_called)
 822                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 823                         else
 824                                 print_to(caller, "^1No vote called.");
 825
 826                         return;
 827                 }
 828
 829                 default:
 830                 case CMD_REQUEST_USAGE:
 831                 {
 832                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 833                         print_to(caller, "  No arguments required.");
 834                         return;
 835                 }
 836         }
 837 }
 838
 839 void VoteCommand_stop(float request, entity caller) // BOTH
 840 {
 841         switch(request)
 842         {
 843                 case CMD_REQUEST_COMMAND:
 844                 {
 845                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 846                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 847                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 848
 849                         return;
 850                 }
 851
 852                 default:
 853                 case CMD_REQUEST_USAGE:
 854                 {
 855                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
 856                         print_to(caller, "  No arguments required.");
 857                         return;
 858                 }
 859         }
 860 }
 861
 862 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
 863 {
 864         switch(request)
 865         {
 866                 case CMD_REQUEST_COMMAND:
 867                 {
 868                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 869                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 870
 871                         else // everything went okay, continue changing vote
 872                         {
 873                                 print_to(caller, "^1You accepted the vote.");
 874                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
 875                                 msg_entity = caller;
 876                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 877                         }
 878
 879                         return;
 880                 }
 881
 882                 default:
 883                 case CMD_REQUEST_USAGE:
 884                 {
 885                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
 886                         print_to(caller, "  No arguments required.");
 887                         return;
 888                 }
 889         }
 890 }
 891
 892 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 893 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 894 void VoteCommand_(float request)
 895 {
 896         switch(request)
 897         {
 898                 case CMD_REQUEST_COMMAND:
 899                 {
 900
 901                         return;
 902                 }
 903
 904                 default:
 905                 case CMD_REQUEST_USAGE:
 906                 {
 907                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
 908                         print_to(caller, "  No arguments required.");
 909                         return;
 910                 }
 911         }
 912 }
 913 */
 914
 915
 916 // ================================
 917 //  Macro system for vote commands
 918 // ================================
 919
 920 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 921 #define VOTE_COMMANDS(request,caller,arguments,command) \
 922         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
 923         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
 924         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
 925         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
 926         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
 927         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
 928         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
 929         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
 930         /* nothing */
 931
 932 void VoteCommand_macro_help(entity caller, float argc)
 933 {
 934         string command_origin = GetCommandPrefix(caller);
 935
 936         if(argc == 2) // help display listing all commands
 937         {
 938                 print_to(caller, "\nVoting commands:\n");
 939                 #define VOTE_COMMAND(name,function,description,assignment) \
 940                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
 941
 942                 VOTE_COMMANDS(0, caller, 0, "")
 943                 #undef VOTE_COMMAND
 944
 945                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
 946                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
 947                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 948         }
 949         else // usage for individual command
 950         {
 951                 #define VOTE_COMMAND(name,function,description,assignment) \
 952                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
 953
 954                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
 955                 #undef VOTE_COMMAND
 956         }
 957
 958         return;
 959 }
 960
 961 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
 962 {
 963         #define VOTE_COMMAND(name,function,description,assignment) \
 964                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
 965
 966         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
 967         #undef VOTE_COMMAND
 968
 969         return FALSE;
 970 }
 971
 972
 973 // ======================================
 974 //  Main function handling vote commands
 975 // ======================================
 976
 977 void VoteCommand(float request, entity caller, float argc, string vote_command)
 978 {
 979         // Guide for working with argc arguments by example:
 980         // argc:   1    - 2      - 3     - 4
 981         // argv:   0    - 1      - 2     - 3
 982         // cmd     vote - master - login - password
 983
 984         switch(request)
 985         {
 986                 case CMD_REQUEST_COMMAND:
 987                 {
 988                         if(VoteCommand_macro_command(caller, argc, vote_command))
 989                                 return;
 990                 }
 991
 992                 default:
 993                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
 994                 case CMD_REQUEST_USAGE:
 995                 {
 996                         VoteCommand_macro_help(caller, argc);
 997                         return;
 998                 }
 999         }
1000 }