qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/banning.qh>
  17 #include <server/command/common.qh>
  18 #include <server/command/vote.qh>
  19 #include <server/damage.qh>
  20 #include <server/gamelog.qh>
  21 #include <server/intermission.qh>
  22 #include <server/mutators/_mod.qh>
  23 #include <server/race.qh>
  24 #include <server/round_handler.qh>
  25 #include <server/scores.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/accuracy.qh>
  28 #include <server/weapons/selection.qh>
  29 #include <server/world.qh>
  30
  31 // =============================================
  32 //  Server side voting code, reworked by Samual
  33 //  Last updated: December 27th, 2011
  34 // =============================================
  35
  36 //  Nagger for players to know status of voting
  37 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  38 {
  39         int nags = 0;
  40         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  41
  42         // bits:
  43         //   1 = ready
  44         //   2 = player needs to ready up
  45         //   4 = vote
  46         //   8 = player needs to vote
  47         //  16 = warmup
  48         // sendflags:
  49         //  64 = vote counts
  50         // 128 = vote string
  51
  52         if (warmup_stage)
  53         {
  54                 if (readycount)
  55                 {
  56                         nags |= BIT(0);
  57                         if (!to.ready) nags |= BIT(1);
  58                 }
  59                 nags |= BIT(4);
  60         }
  61
  62         if (vote_called)
  63         {
  64                 nags |= BIT(2);
  65                 if (to.vote_selection == 0) nags |= BIT(3);
  66                 nags |= sendflags & BIT(6);
  67                 nags |= sendflags & BIT(7);
  68         }
  69
  70         WriteByte(MSG_ENTITY, nags);
  71
  72         if (nags & BIT(6))
  73         {
  74                 WriteByte(MSG_ENTITY, vote_accept_count);
  75                 WriteByte(MSG_ENTITY, vote_reject_count);
  76                 WriteByte(MSG_ENTITY, vote_needed_overall);
  77                 WriteChar(MSG_ENTITY, to.vote_selection);
  78         }
  79
  80         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  81
  82         if (nags & BIT(0))
  83         {
  84                 for (int i = 1; i <= maxclients;)
  85                 {
  86                         int f = 0;
  87                         for (int b = 0; b < 8 && i <= maxclients; ++b, ++i)
  88                                 if (edict_num(i).ready)
  89                                         f |= BIT(b);
  90                         WriteByte(MSG_ENTITY, f);
  91                 }
  92         }
  93
  94         return true;
  95 }
  96
  97 void Nagger_Init()
  98 {
  99         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 100 }
 101
 102 void Nagger_VoteChanged()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(7);
 105 }
 106
 107 void Nagger_VoteCountChanged()
 108 {
 109         if (nagger) nagger.SendFlags |= BIT(6);
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if (nagger) nagger.SendFlags |= BIT(0);
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 121         return vote_caller_name;
 122 }
 123
 124 // =======================
 125 //  Game logic for voting
 126 // =======================
 127
 128 void VoteStop(entity stopper, bool show_name);
 129 void VoteReset(bool verbose)
 130 {
 131         if (verbose && vote_called)
 132         {
 133                 VoteStop(NULL, true);
 134                 return;
 135         }
 136
 137         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 138
 139         if (vote_called)
 140         {
 141                 strfree(vote_called_command);
 142                 strfree(vote_called_display);
 143                 strfree(vote_caller_name);
 144         }
 145
 146         vote_called = VOTE_NULL;
 147         vote_caller = NULL;
 148         vote_endtime = 0;
 149
 150         vote_parsed_command = string_null;
 151         vote_parsed_display = string_null;
 152
 153         Nagger_VoteChanged();
 154 }
 155
 156 void VoteStop(entity stopper, bool canceled)
 157 {
 158         if (canceled)
 159                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote was canceled\n");
 160         else
 161                 bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 162         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 163         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 164         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 165         VoteReset(false);
 166 }
 167
 168 void VoteAccept()
 169 {
 170         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 171
 172         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = true;
 173         else localcmd(strcat(vote_called_command, "\n"));
 174
 175         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 176
 177         VoteReset(false);
 178         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 179 }
 180
 181 void VoteReject()
 182 {
 183         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 184         VoteReset(false);
 185         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 186 }
 187
 188 void VoteTimeout()
 189 {
 190         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 191         VoteReset(false);
 192         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 193 }
 194
 195 void VoteSpam(float notvoters, float mincount, string result)
 196 {
 197         bprint(strcat(
 198                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 199                 strcat("^2:^1", ftos(vote_reject_count)),
 200                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 201                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 202                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 203
 204         if (autocvar_sv_eventlog)
 205         {
 206                 GameLogEcho(strcat(
 207                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 208                         strcat(":", ftos(vote_reject_count)),
 209                         strcat(":", ftos(vote_abstain_count)),
 210                         strcat(":", ftos(notvoters)),
 211                         strcat(":", ftos(mincount))));
 212         }
 213 }
 214
 215 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 216
 217 void VoteCount(float first_count)
 218 {
 219         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 220
 221         float vote_player_count = 0, notvoters = 0;
 222         float vote_real_player_count = 0, vote_real_accept_count = 0;
 223         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 224         float vote_needed_of_voted, final_needed_votes;
 225         float vote_factor_overall, vote_factor_of_voted;
 226
 227         Nagger_VoteCountChanged();
 228
 229         // add up all the votes from each connected client
 230         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_vote_debug, {
 231                 ++vote_player_count;
 232                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_player_count;
 233                 switch (it.vote_selection)
 234                 {
 235                         case VOTE_SELECT_REJECT:
 236                                 ++vote_reject_count;
 237                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_reject_count;
 238                                 break;
 239                         case VOTE_SELECT_ACCEPT:
 240                                 ++vote_accept_count;
 241                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_accept_count;
 242                                 break;
 243                         case VOTE_SELECT_ABSTAIN:
 244                                 ++vote_abstain_count;
 245                                 if (IS_PLAYER(it) || INGAME(it)) ++vote_real_abstain_count;
 246                                 break;
 247                         default: break;
 248                 }
 249         });
 250
 251         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 252         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 253         {
 254                 if (vote_caller)   vote_caller.vote_waittime = 0;
 255                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 256                 VoteReset(false);
 257                 return;
 258         }
 259
 260         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 261         if (!spectators_allowed && (vote_real_player_count > 0))
 262         {
 263                 vote_accept_count = vote_real_accept_count;
 264                 vote_reject_count = vote_real_reject_count;
 265                 vote_abstain_count = vote_real_abstain_count;
 266                 vote_player_count = vote_real_player_count;
 267         }
 268
 269         // people who have no opinion in any way :D
 270         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 271
 272         // determine the goal for the vote to be passed or rejected normally
 273         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 274         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 275
 276         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 277         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 278         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 279
 280         // are there any players at all on the server? it could be an admin vote
 281         if (vote_player_count == 0 && first_count)
 282         {
 283                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         // since there ARE players, finally calculate the result of the vote
 289         if (vote_accept_count >= vote_needed_overall)
 290         {
 291                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 292                 VoteAccept();
 293                 return;
 294         }
 295
 296         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 297         {
 298                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 299                 VoteReject();
 300                 return;
 301         }
 302
 303         // there is not enough votes in either direction, now lets just calculate what the voters have said
 304         if (time > vote_endtime)
 305         {
 306                 final_needed_votes = vote_needed_overall;
 307
 308                 if (autocvar_sv_vote_majority_factor_of_voted)
 309                 {
 310                         if (vote_accept_count >= vote_needed_of_voted)
 311                         {
 312                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 313                                 VoteAccept();
 314                                 return;
 315                         }
 316
 317                         if (vote_accept_count + vote_reject_count > 0)
 318                         {
 319                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 320                                 VoteReject();
 321                                 return;
 322                         }
 323
 324                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 325                 }
 326
 327                 // it didn't pass or fail, so not enough votes to even make a decision.
 328                 VoteSpam(notvoters, final_needed_votes, "timeout");
 329                 VoteTimeout();
 330         }
 331 }
 332
 333 void VoteThink()
 334 {
 335         if (vote_endtime > 0)        // a vote was called
 336         {
 337                 if (time > vote_endtime) // time is up
 338                         VoteCount(false);
 339         }
 340 }
 341
 342
 343 // =======================
 344 //  Game logic for warmup
 345 // =======================
 346
 347 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 348 void reset_map(bool is_fake_round_start)
 349 {
 350         if (time <= game_starttime)
 351         {
 352                 if (game_stopped)
 353                         return;
 354
 355                 if (!is_fake_round_start)
 356                 {
 357                         Score_ClearAll();
 358                         PlayerStats_GameReport_Reset_All();
 359                 }
 360
 361                 if (round_handler_IsActive())
 362                         round_handler_Reset(game_starttime);
 363         }
 364
 365         if (shuffleteams_on_reset_map)
 366         {
 367                 shuffleteams();
 368                 shuffleteams_on_reset_map = false;
 369         }
 370
 371         FOREACH_CLIENT(true, {
 372                 if (time <= game_starttime)
 373                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 374                 if (!IS_PLAYER(it))
 375                         continue;
 376                 if (STAT(FROZEN, it))
 377                         Unfreeze(it, false);
 378                 player_powerups_remove_all(it);
 379                 entity store = PS(it);
 380                 if (store)
 381                 {
 382                         Inventory_clear(store.inventory);
 383                         Inventory_update(store);
 384                 }
 385         });
 386
 387         MUTATOR_CALLHOOK(reset_map_global);
 388
 389         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 390         {
 391                 if(IS_CLIENT(it))
 392                         continue;
 393                 if (it.reset)
 394                 {
 395                         it.reset(it);
 396                         continue;
 397                 }
 398                 if (it.team_saved) it.team = it.team_saved;
 399                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 400         });
 401
 402         // Waypoints and assault start come LAST
 403         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 404                 if (it.reset2) it.reset2(it);
 405         });
 406
 407         // Moving the player reset code here since the player-reset depends
 408         // on spawnpoint entities which have to be reset first --blub
 409         if (!MUTATOR_CALLHOOK(reset_map_players))
 410         {
 411                 FOREACH_CLIENT(IS_PLAYER(it),
 412                 {
 413                         // PlayerScore_Clear(it);
 414                         CS(it).killcount = 0;
 415                         // stop the player from moving so that they stand still once they get respawned
 416                         it.velocity = '0 0 0';
 417                         it.avelocity = '0 0 0';
 418                         CS(it).movement = '0 0 0';
 419                         PutClientInServer(it);
 420
 421                         if(IS_BOT_CLIENT(it))
 422                         {
 423                                 .entity weaponentity = weaponentities[0];
 424                                 if(it.(weaponentity).m_weapon == WEP_Null)
 425                                         W_NextWeapon(it, 0, weaponentity);
 426                         }
 427                 });
 428         }
 429 }
 430
 431 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 432 void ReadyRestart_think(entity this)
 433 {
 434         if (!warmup_stage) // if the countdown was not aborted
 435                 reset_map(false);
 436         delete(this);
 437 }
 438
 439 // Forces a restart of the game without actually reloading the map // this is a mess...
 440 void ReadyRestart_force(bool is_fake_round_start)
 441 {
 442         if (time <= game_starttime && game_stopped)
 443                 return;
 444         if (!is_fake_round_start && !autocvar_g_campaign)
 445                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_COUNTDOWN_RESTART);
 446
 447         VoteReset(true);
 448
 449         // clear overtime, we have to decrease timelimit to its original value again.
 450         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 451                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 452         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = overtimes = 0;
 453
 454         if(warmup_stage)
 455                 game_starttime = time; // Warmup: No countdown in warmup
 456         else if (autocvar_g_campaign)
 457                 game_starttime = time + 3;
 458         else
 459                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 460
 461         // clear player attributes
 462         FOREACH_CLIENT(IS_PLAYER(it), {
 463                 it.alivetime = 0;
 464                 CS(it).killcount = 0;
 465         });
 466
 467         // if we're ending the warmup stage call the corresponding hook
 468         if(!is_fake_round_start && !warmup_stage)
 469                 localcmd("\nsv_hook_warmupend\n");
 470
 471         // reset the .ready status of all clients (including spectators and bots)
 472         FOREACH_CLIENT(true, { it.ready = false; });
 473         readycount = 0;
 474         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 475
 476         // lock teams with lockonrestart
 477         if (autocvar_teamplay_lockonrestart && teamplay)
 478                 lockteams = !warmup_stage;
 479
 480         // initiate the restart-countdown-announcer entity
 481         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 482         {
 483                 entity restart_timer = new_pure(restart_timer);
 484                 setthink(restart_timer, ReadyRestart_think);
 485                 restart_timer.nextthink = game_starttime;
 486         }
 487
 488         // after a restart every players number of allowed timeouts gets reset, too
 489         if (autocvar_sv_timeout)
 490         {
 491                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 492         }
 493
 494         if (!sv_ready_restart_after_countdown || warmup_stage)
 495                 reset_map(is_fake_round_start);
 496
 497         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 498 }
 499
 500 void ReadyRestart(bool forceWarmupEnd)
 501 {
 502         if (MUTATOR_CALLHOOK(ReadyRestart_Deny))
 503         {
 504                 // NOTE: ReadyRestart support is mandatory in campaign
 505                 if (autocvar_g_campaign)
 506                         error("ReadyRestart must be supported in campaign mode!");
 507                 localcmd("restart\n"); // if ReadyRestart is denied, restart the server
 508         }
 509         else if (intermission_running || race_completing) // game is over, ReadyRestart no longer available
 510                 localcmd("restart\n");
 511         else
 512                 localcmd("\nsv_hook_readyrestart\n");
 513
 514         if(forceWarmupEnd || autocvar_g_campaign)
 515                 warmup_stage = 0; // forcefully end warmup and go to match stage
 516         else
 517                 warmup_stage = autocvar_g_warmup; // go into warmup if it's enabled, otherwise restart into match stage
 518
 519         ReadyRestart_force(false);
 520 }
 521
 522 /* Count the players who are ready and determine whether or not to restart the match when:
 523  * a player presses F4                      server/command/cmd.qc  ClientCommand_ready()
 524  * a player switches from players to specs  server/client.qc       PutObserverInServer()
 525  * a player joins (from specs or directly)  server/client.qc       PutPlayerInServer()
 526  * a player disconnects                     server/client.qc       ClientDisconnect()   */
 527 void ReadyCount()
 528 {
 529         // cannot reset the game while a timeout is active or pending
 530         if (timeout_status) return;
 531
 532         int total_players = 0, human_players = 0, humans_ready = 0;
 533         readycount = 0;
 534
 535         FOREACH_CLIENT(IS_PLAYER(it) || INGAME_JOINED(it), {
 536                 ++total_players;
 537                 if (it.ready) ++readycount;
 538                 if (IS_REAL_CLIENT(it))
 539                 {
 540                         ++human_players;
 541                         if (it.ready) ++humans_ready;
 542                 }
 543         });
 544
 545         Nagger_ReadyCounted();
 546
 547         // can't read warmup_stage here as it could have been set to 0 by ReadyRestart()
 548         // and we need to use this when checking if we should abort the countdown
 549         // map_minplayers can only be > 0 if g_warmup was -1 at worldspawn
 550         int minplayers = autocvar_g_warmup > 1 ? autocvar_g_warmup : map_minplayers;
 551
 552         if (total_players < minplayers)
 553         {
 554                 if (game_starttime > time) // someone bailed during countdown, back to warmup
 555                 {
 556                         warmup_stage = autocvar_g_warmup; // CAN change it AFTER calling Nagger_ReadyCounted() this frame
 557                         game_starttime = time;
 558                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, COUNTDOWN_STOP, minplayers);
 559                         if (!sv_ready_restart_after_countdown) // if we ran reset_map() at start of countdown
 560                                 FOREACH_CLIENT(IS_PLAYER(it), { GiveWarmupResources(it); });
 561                 }
 562                 if (warmup_limit > 0)
 563                         warmup_limit = -1;
 564                 return; // don't ReadyRestart if players are ready but too few
 565         }
 566         else if (minplayers && warmup_limit <= 0)
 567         {
 568                 // there's enough players now but we're still in infinite warmup
 569                 warmup_limit = cvar("g_warmup_limit");
 570                 if (warmup_limit == 0)
 571                         warmup_limit = autocvar_timelimit * 60;
 572                 if (warmup_limit > 0)
 573                         game_starttime = time;
 574                 // implicit else: g_warmup -1 && g_warmup_limit -1 means
 575                 // warmup continues until enough players AND enough RUPs (no time limit)
 576         }
 577
 578         if (humans_ready && humans_ready >= rint(human_players * bound(0.5, cvar("g_warmup_majority_factor"), 1)))
 579                 ReadyRestart(true);
 580 }
 581
 582
 583 // ======================================
 584 //  Supporting functions for VoteCommand
 585 // ======================================
 586
 587 bool Votecommand_check_assignment(entity caller, float assignment)
 588 {
 589         bool from_server = (!caller);
 590
 591         if ((assignment == VC_ASGNMNT_BOTH)
 592             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 593             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 594
 595         return false;
 596 }
 597
 598 string VoteCommand_extractcommand(string input, float startpos, int argc)
 599 {
 600         string output;
 601
 602         if ((argc - 1) < startpos) output = "";
 603         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 604
 605         return output;
 606 }
 607
 608 bool VoteCommand_checknasty(string vote_command)
 609 {
 610         return !((strstrofs(vote_command, ";", 0) >= 0)
 611             || (strstrofs(vote_command, "\n", 0) >= 0)
 612             || (strstrofs(vote_command, "\r", 0) >= 0)
 613             || (strstrofs(vote_command, "$", 0) >= 0));
 614 }
 615
 616 // NOTE: requires input to be surrounded by spaces
 617 string VoteCommand_checkreplacements(string input)
 618 {
 619         // add a space around the input so the start and end of the list is captured
 620         string output = strcat(" ", input, " ");
 621         // allow gotomap replacements
 622         output = strreplace(" map ", " gotomap ", output);
 623         output = strreplace(" chmap ", " gotomap ", output);
 624         return output;
 625 }
 626
 627 bool VoteCommand_checkinlist(string vote_command, string list)
 628 {
 629         if (vote_command == "" || list == "")
 630                 return false;
 631
 632         string l = VoteCommand_checkreplacements(list);
 633         return (strstrofs(l, VoteCommand_checkreplacements(vote_command), 0) >= 0);
 634 }
 635
 636 string ValidateMap(string validated_map, entity caller)
 637 {
 638         validated_map = MapInfo_FixName(validated_map);
 639
 640         if (!validated_map)
 641         {
 642                 print_to(caller, "This map is not available on this server.");
 643                 return string_null;
 644         }
 645
 646         if (!autocvar_sv_vote_override_mostrecent && caller)
 647         {
 648                 if (Map_IsRecent(validated_map))
 649                 {
 650                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 651                         return string_null;
 652                 }
 653         }
 654
 655         if (!MapInfo_CheckMap(validated_map))
 656         {
 657                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 658                 return string_null;
 659         }
 660
 661         return validated_map;
 662 }
 663
 664 float VoteCommand_checkargs(float startpos, int argc)
 665 {
 666         float p, q, check, minargs;
 667         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 668         string cmdrestriction = "";  // No we don't.
 669         string charlist, arg;
 670         float checkmate;
 671
 672         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 673                 cmdrestriction = cvar_string(cvarname);
 674         else
 675                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 676
 677         if (cmdrestriction == "") return true;
 678
 679         ++startpos;  // skip command name
 680
 681         // check minimum arg count
 682
 683         // 0 args: argc == startpos
 684         // 1 args: argc == startpos + 1
 685         // ...
 686
 687         minargs = stof(cmdrestriction);
 688         if (argc - startpos < minargs) return false;
 689
 690         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 691
 692         for ( ; ; )
 693         {
 694                 // we know that at any time, startpos <= argc - minargs
 695                 // so this means: argc-minargs >= startpos >= argc, thus
 696                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 697                 // have been seen already
 698
 699                 if (startpos >= argc) // all args checked? GOOD
 700                         break;
 701
 702                 if (p < 0)            // no more args? FAIL
 703                 {
 704                         // exception: exactly minargs left, this one included
 705                         if (argc - startpos == minargs) break;
 706
 707                         // otherwise fail
 708                         return false;
 709                 }
 710
 711                 // cut to next semicolon
 712                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 713                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 714                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 715
 716                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 717                 // charlist = strreplace("^^", ";", charlist);
 718
 719                 if (charlist != "")
 720                 {
 721                         // verify the arg only contains allowed chars
 722                         arg = argv(startpos);
 723                         checkmate = strlen(arg);
 724                         for (check = 0; check < checkmate; ++check)
 725                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 726                         // not allowed character
 727                         // all characters are allowed. FINE.
 728                 }
 729
 730                 ++startpos;
 731                 --minargs;
 732                 p = q;
 733         }
 734
 735         return true;
 736 }
 737
 738 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 739 {
 740         string first_command = argv(startpos);
 741         int missing_chars = argv_start_index(startpos);
 742
 743         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 744                 return 0;
 745
 746         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 747
 748         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 749
 750         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 751         {
 752                 case MUT_VOTEPARSE_CONTINUE: { break; }
 753                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 754                 case MUT_VOTEPARSE_INVALID: { return -1; }
 755                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 756         }
 757
 758         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 759         {
 760                 case "movetoauto":
 761                 case "movetored":
 762                 case "movetoblue":
 763                 case "movetoyellow":
 764                 case "movetopink":
 765                 case "movetospec":
 766                 {
 767                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 768                         float accepted = VerifyClientEntity(victim, true, false);
 769                         if (accepted > 0)
 770                         {
 771                                 vote_parsed_command = vote_command;
 772                                 vote_parsed_display = sprintf("^1%s #%d ^7%s", first_command, etof(victim), victim.netname);
 773                         }
 774                         else
 775                         {
 776                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 777                                 return 0;
 778                         }
 779
 780                         break;
 781                 }
 782
 783                 case "kick":
 784                 case "kickban":    // catch all kick/kickban commands
 785                 {
 786                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 787                         float accepted = VerifyClientEntity(victim, true, false);
 788
 789                         if (accepted > 0)
 790                         {
 791                                 string reason = "No reason provided";
 792                                 if(argc > next_token)
 793                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 794
 795                                 string command_arguments = reason;
 796                                 if (first_command == "kickban")
 797                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 798
 799                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 800                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 801                         }
 802                         else
 803                         {
 804                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 805                                 return 0;
 806                         }
 807
 808                         break;
 809                 }
 810
 811                 case "map":
 812                 case "chmap":
 813                 case "gotomap":  // re-direct all map selection commands to gotomap
 814                 {
 815                         vote_command = ValidateMap(argv(startpos + 1), caller);
 816                         if (!vote_command)  return -1;
 817                         vote_parsed_command = strcat("gotomap ", vote_command);
 818                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 819
 820                         break;
 821                 }
 822
 823                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 824                 // maybe fallback instead of aborting if map name is invalid?
 825                 case "nextmap":
 826                 {
 827                         vote_command = ValidateMap(argv(startpos + 1), caller);
 828                         if (!vote_command)  return -1;
 829                         vote_parsed_command = strcat("nextmap ", vote_command);
 830                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 831
 832                         break;
 833                 }
 834
 835                 case "fraglimit": // include restrictions on the maximum votable frag limit
 836                 {
 837                         float fraglimit_vote = stof(argv(startpos + 1));
 838                         float fraglimit_min = 0;
 839                         float fraglimit_max = 999999;
 840                         if(fraglimit_vote > fraglimit_max || fraglimit_vote < fraglimit_min)
 841                         {
 842                                 print_to(caller, strcat("Invalid fraglimit vote, accepted values are between ", ftos(fraglimit_min), " and ", ftos(fraglimit_max), "."));
 843                                 return -1;
 844                         }
 845                         vote_parsed_command = strcat("fraglimit ", ftos(fraglimit_vote));
 846                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 847
 848                         break;
 849                 }
 850
 851                 case "timelimit": // include restrictions on the maximum votable time limit
 852                 {
 853                         float timelimit_vote = stof(argv(startpos + 1));
 854                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 855                         {
 856                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 857                                 return -1;
 858                         }
 859                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 860                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 861
 862                         break;
 863                 }
 864
 865                 case "restart":
 866                 {
 867                         // add a delay so that vote result can be seen and announcer can be heard
 868                         // if the vote is accepted
 869                         vote_parsed_command = strcat("defer 1 ", vote_command);
 870                         vote_parsed_display = strzone(strcat("^1", vote_command));
 871
 872                         break;
 873                 }
 874
 875                 case "allready":
 876                 {
 877                         if(!warmup_stage) {
 878                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 879                                 return -1;
 880                         }
 881
 882                         vote_parsed_command = vote_command;
 883                         vote_parsed_display = strzone(strcat("^1", vote_command));
 884                         break;
 885                 }
 886
 887                 default:
 888                 {
 889                         vote_parsed_command = vote_command;
 890                         vote_parsed_display = strzone(strcat("^1", vote_command));
 891
 892                         break;
 893                 }
 894         }
 895
 896         return 1;
 897 }
 898
 899
 900 // =======================
 901 //  Command Sub-Functions
 902 // =======================
 903
 904 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 905 {
 906         switch (request)
 907         {
 908                 case CMD_REQUEST_COMMAND:
 909                 {
 910                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 911                         {
 912                                 print_to(caller, "^1You are banned from voting.");
 913                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
 914                                 return;
 915                         }
 916
 917                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 918                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 919                         {
 920                                 print_to(caller, "^1You have already voted.");
 921                         }
 922
 923                         else  // everything went okay, continue changing vote
 924                         {
 925                                 print_to(caller, "^1You abstained from your vote.");
 926                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 927                                 msg_entity = caller;
 928                                 if (!autocvar_sv_vote_singlecount)
 929                                         VoteCount(false);
 930                         }
 931
 932                         return;
 933                 }
 934
 935                 default:
 936                 case CMD_REQUEST_USAGE:
 937                 {
 938                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 939                         print_to(caller, "  No arguments required.");
 940                         return;
 941                 }
 942         }
 943 }
 944
 945 void print_available_commands_to(entity caller)
 946 {
 947         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 948 }
 949
 950 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 951 {
 952         switch (request)
 953         {
 954                 case CMD_REQUEST_COMMAND:
 955                 {
 956                         float tmp_playercount = 0;
 957                         int parse_error;
 958
 959                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
 960                         {
 961                                 print_to(caller, "^1You are banned from calling a vote.");
 962                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBAN);
 963                                 return;
 964                         }
 965
 966                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 967
 968                         if (!autocvar_sv_vote_call && caller)
 969                         {
 970                                 print_to(caller, "^1Vote calling is not allowed.");
 971                         }
 972                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 973                         {
 974                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 975                         }
 976                         else if (vote_called)
 977                         {
 978                                 print_to(caller, "^1There is already a vote called.");
 979                         }
 980                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 981                         {
 982                                 print_to(caller, "^1Only players can call a vote.");
 983                         }
 984                         else if (caller && !IS_CLIENT(caller))
 985                         {
 986                                 print_to(caller, "^1Only connected clients can vote.");
 987                         }
 988                         else if (timeout_status && vote_command != "timein")
 989                         {
 990                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 991                         }
 992                         else if (caller && (time < caller.vote_waittime))
 993                         {
 994                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 995                         }
 996                         else if (!VoteCommand_checknasty(vote_command))
 997                         {
 998                                 print_to(caller, "^1Syntax error in command.");
 999                         }
1000                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
1001                         {
1002                                 if(parse_error == 0)
1003                                 {
1004                                         if (vote_called_command == "")
1005                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
1006                                         else
1007                                                 print_to(caller, "^1This command is not acceptable or not available.");
1008                                 }
1009                         }
1010                         else  // everything went okay, continue with calling the vote
1011                         {
1012                                 vote_caller = caller;  // remember who called the vote
1013                                 vote_caller_name = strzone(GetCallerName(vote_caller));
1014                                 vote_called = VOTE_NORMAL;
1015                                 vote_called_command = strzone(vote_parsed_command);
1016                                 vote_called_display = strzone(vote_parsed_display);
1017                                 vote_endtime = time + autocvar_sv_vote_timeout;
1018
1019                                 if (caller)
1020                                 {
1021                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1022                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1023                                         msg_entity = caller;
1024                                 }
1025
1026                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
1027
1028                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
1029                                 if (autocvar_sv_vote_debug)
1030                                         bprint("\{1}^2* ^3", "^6DEBUG MODE ACTIVE: bots can vote too\n"); // so servers don't forget it on
1031                                 if (autocvar_sv_eventlog)
1032                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1033                                 Nagger_VoteChanged();
1034                                 VoteCount(true);  // needed if you are the only one
1035
1036                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
1037                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
1038                         }
1039
1040                         return;
1041                 }
1042
1043                 default:
1044                 case CMD_REQUEST_USAGE:
1045                 {
1046                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
1047                         print_to(caller, "  Where <command> is the command to request a vote upon.");
1048                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
1049                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
1050                         print_available_commands_to(caller);
1051                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
1052                         return;
1053                 }
1054         }
1055 }
1056
1057 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
1058 {
1059         switch (request)
1060         {
1061                 case CMD_REQUEST_COMMAND:
1062                 {
1063                         if (autocvar_sv_vote_master)
1064                         {
1065                                 switch (strtolower(argv(2)))
1066                                 {
1067                                         case "do":
1068                                         {
1069                                                 int parse_error;
1070                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
1071
1072                                                 if (!caller.vote_master)
1073                                                         print_to(caller, "^1You do not have vote master privileges.");
1074                                                 else if (!VoteCommand_checknasty(vote_command))
1075                                                 {
1076                                                         print_to(caller, "^1Syntax error in command.");
1077                                                 }
1078                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
1079                                                 {
1080                                                         if(parse_error == 0)
1081                                                         {
1082                                                                 if (vote_called_command == "")
1083                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
1084                                                                 else
1085                                                                         print_to(caller, "^1This command is not acceptable or not available.");
1086                                                         }
1087                                                 }
1088                                                 else  // everything went okay, proceed with command
1089                                                 {
1090                                                         localcmd(strcat(vote_parsed_command, "\n"));
1091                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1092                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1093                                                         if (autocvar_sv_eventlog)
1094                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1095                                                 }
1096
1097                                                 return;
1098                                         }
1099
1100                                         case "login":
1101                                         {
1102                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1103                                                 else if (caller.vote_master)
1104                                                 {
1105                                                         print_to(caller, "^1You are already logged in as vote master.");
1106                                                 }
1107                                                 else if (autocvar_sv_vote_master_password != argv(3))
1108                                                 {
1109                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1110                                                 }
1111                                                 else  // everything went okay, proceed with giving this player master privilages
1112                                                 {
1113                                                         caller.vote_master = true;
1114                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1115                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1116                                                         if (autocvar_sv_eventlog)
1117                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1118                                                 }
1119
1120                                                 return;
1121                                         }
1122
1123                                         default:  // calling a vote for master
1124                                         {
1125                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1126                                                 else if (vote_called)
1127                                                 {
1128                                                         print_to(caller, "^1There is already a vote called.");
1129                                                 }
1130                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1131                                                 {
1132                                                         print_to(caller, "^1Only players can call a vote.");
1133                                                 }
1134                                                 else if (timeout_status)
1135                                                 {
1136                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1137                                                 }
1138                                                 else  // everything went okay, continue with creating vote
1139                                                 {
1140                                                         vote_caller = caller;
1141                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1142                                                         vote_called = VOTE_MASTER;
1143                                                         vote_called_command = strzone("XXX");
1144                                                         vote_called_display = strzone("^3master");
1145                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1146
1147                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1148                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1149
1150                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1151                                                         if (autocvar_sv_eventlog)
1152                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1153                                                         Nagger_VoteChanged();
1154                                                         VoteCount(true);  // needed if you are the only one
1155                                                 }
1156
1157                                                 return;
1158                                         }
1159                                 }
1160                         }
1161                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1162
1163                         return;
1164                 }
1165
1166                 default:
1167                 case CMD_REQUEST_USAGE:
1168                 {
1169                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1170                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1171                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1172                         return;
1173                 }
1174         }
1175 }
1176
1177 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1178 {
1179         switch (request)
1180         {
1181                 case CMD_REQUEST_COMMAND:
1182                 {
1183                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1184                         {
1185                                 print_to(caller, "^1You are banned from voting.");
1186                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1187                                 return;
1188                         }
1189
1190                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1191                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1192                         {
1193                                 print_to(caller, "^1You have already voted.");
1194                         }
1195                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1196                         {
1197                                 VoteStop(caller, true);
1198                         }
1199
1200                         else  // everything went okay, continue changing vote
1201                         {
1202                                 print_to(caller, "^1You rejected the vote.");
1203                                 caller.vote_selection = VOTE_SELECT_REJECT;
1204                                 msg_entity = caller;
1205                                 if (!autocvar_sv_vote_singlecount)
1206                                         VoteCount(false);
1207                         }
1208
1209                         return;
1210                 }
1211
1212                 default:
1213                 case CMD_REQUEST_USAGE:
1214                 {
1215                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1216                         print_to(caller, "  No arguments required.");
1217                         return;
1218                 }
1219         }
1220 }
1221
1222 void VoteCommand_status(int request, entity caller)  // BOTH
1223 {
1224         switch (request)
1225         {
1226                 case CMD_REQUEST_COMMAND:
1227                 {
1228                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1229                         else print_to(caller, "^1No vote called.");
1230
1231                         return;
1232                 }
1233
1234                 default:
1235                 case CMD_REQUEST_USAGE:
1236                 {
1237                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1238                         print_to(caller, "  No arguments required.");
1239                         return;
1240                 }
1241         }
1242 }
1243
1244 void VoteCommand_stop(int request, entity caller)  // BOTH
1245 {
1246         switch (request)
1247         {
1248                 case CMD_REQUEST_COMMAND:
1249                 {
1250                         if (!vote_called)   print_to(caller, "^1No vote called.");
1251                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller, false);
1252                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1253                         return;
1254                 }
1255
1256                 default:
1257                 case CMD_REQUEST_USAGE:
1258                 {
1259                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1260                         print_to(caller, "  No arguments required.");
1261                         return;
1262                 }
1263         }
1264 }
1265
1266 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1267 {
1268         switch (request)
1269         {
1270                 case CMD_REQUEST_COMMAND:
1271                 {
1272                         if (PlayerInList(caller, autocvar_g_voteban_list)) // voteban
1273                         {
1274                                 print_to(caller, "^1You are banned from voting.");
1275                                 Send_Notification(NOTIF_ONE, caller, MSG_CENTER, CENTER_VOTEBANYN);
1276                                 return;
1277                         }
1278
1279                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1280                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1281                         {
1282                                 print_to(caller, "^1You have already voted.");
1283                         }
1284                         else  // everything went okay, continue changing vote
1285                         {
1286                                 print_to(caller, "^1You accepted the vote.");
1287                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1288                                 msg_entity = caller;
1289                                 if (!autocvar_sv_vote_singlecount)
1290                                         VoteCount(false);
1291                         }
1292
1293                         return;
1294                 }
1295
1296                 default:
1297                 case CMD_REQUEST_USAGE:
1298                 {
1299                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1300                         print_to(caller, "  No arguments required.");
1301                         return;
1302                 }
1303         }
1304 }
1305
1306 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1307 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1308 void VoteCommand_(int request)
1309 {
1310     switch(request)
1311     {
1312         case CMD_REQUEST_COMMAND:
1313         {
1314
1315             return;
1316         }
1317
1318         default:
1319         case CMD_REQUEST_USAGE:
1320         {
1321             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1322             print_to(caller, "  No arguments required.");
1323             return;
1324         }
1325     }
1326 }
1327 */
1328
1329
1330 // ================================
1331 //  Macro system for vote commands
1332 // ================================
1333
1334 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1335 #define VOTE_COMMANDS(request, caller, arguments, command) \
1336         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1337         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1338         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1339         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1340         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1341         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1342         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1343         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1344         /* nothing */
1345
1346 void VoteCommand_macro_help(entity caller, int argc)
1347 {
1348         string command_origin = GetCommandPrefix(caller);
1349
1350         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1351         {
1352                 print_to(caller, "\nVoting commands:\n");
1353                 #define VOTE_COMMAND(name, function, description, assignment) \
1354                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1355
1356                 VOTE_COMMANDS(0, caller, 0, "");
1357                 #undef VOTE_COMMAND
1358
1359                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1360                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1361                 print_available_commands_to(caller);
1362         }
1363         else  // usage for individual command
1364         {
1365                 #define VOTE_COMMAND(name, function, description, assignment) \
1366                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1367
1368                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1369                 #undef VOTE_COMMAND
1370
1371                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1372                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1373                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1374                 else if (argv(2) != "")
1375                         print_to(caller, "No documentation exists for this vote");
1376         }
1377 }
1378
1379 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1380 {
1381         #define VOTE_COMMAND(name, function, description, assignment) \
1382                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1383
1384         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1385         #undef VOTE_COMMAND
1386
1387         return false;
1388 }
1389
1390
1391 // ======================================
1392 //  Main function handling vote commands
1393 // ======================================
1394
1395 void VoteCommand(int request, entity caller, int argc, string vote_command)
1396 {
1397         // Guide for working with argc arguments by example:
1398         // argc:   1    - 2      - 3     - 4
1399         // argv:   0    - 1      - 2     - 3
1400         // cmd     vote - master - login - password
1401
1402         switch (request)
1403         {
1404                 case CMD_REQUEST_COMMAND:
1405                 {
1406                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1407                 }
1408
1409                 default:
1410                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1411                 case CMD_REQUEST_USAGE:
1412                 {
1413                         VoteCommand_macro_help(caller, argc);
1414                         return;
1415                 }
1416         }
1417 }