qcsrc/server/command/vote.qc

   1 // =============================================
   2 //  Server side voting code, reworked by Samual
   3 //  Last updated: December 27th, 2011
   4 // =============================================
   5
   6 //  Nagger for players to know status of voting
   7 float Nagger_SendEntity(entity to, float sendflags)
   8 {
   9         float nags, i, f, b;
  10         entity e;
  11         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  12
  13         // bits:
  14         //   1 = ready
  15         //   2 = player needs to ready up
  16         //   4 = vote
  17         //   8 = player needs to vote
  18         //  16 = warmup
  19         // sendflags:
  20         //  64 = vote counts
  21         // 128 = vote string
  22
  23         nags = 0;
  24         if(readycount)
  25         {
  26                 nags |= 1;
  27                 if(to.ready == 0)
  28                         nags |= 2;
  29         }
  30         if(vote_called)
  31         {
  32                 nags |= 4;
  33                 if(to.vote_selection == 0)
  34                         nags |= 8;
  35         }
  36         if(inWarmupStage)
  37                 nags |= 16;
  38
  39         if(sendflags & 64)
  40                 nags |= 64;
  41
  42         if(sendflags & 128)
  43                 nags |= 128;
  44
  45         if(!(nags & 4)) // no vote called? send no string
  46                 nags &~= (64 | 128);
  47
  48         WriteByte(MSG_ENTITY, nags);
  49
  50         if(nags & 64)
  51         {
  52                 WriteByte(MSG_ENTITY, vote_accept_count);
  53                 WriteByte(MSG_ENTITY, vote_reject_count);
  54                 WriteByte(MSG_ENTITY, vote_needed_overall);
  55                 WriteChar(MSG_ENTITY, to.vote_selection);
  56         }
  57
  58         if(nags & 128)
  59                 WriteString(MSG_ENTITY, vote_called_display);
  60
  61         if(nags & 1)
  62         {
  63                 for(i = 1; i <= maxclients; i += 8)
  64                 {
  65                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  66                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  67                                         f |= b;
  68                         WriteByte(MSG_ENTITY, f);
  69                 }
  70         }
  71
  72         return TRUE;
  73 }
  74
  75 void Nagger_Init()
  76 {
  77         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  78 }
  79
  80 void Nagger_VoteChanged()
  81 {
  82         if(nagger)
  83                 nagger.SendFlags |= 128;
  84 }
  85
  86 void Nagger_VoteCountChanged()
  87 {
  88         if(nagger)
  89                 nagger.SendFlags |= 64;
  90 }
  91
  92 void Nagger_ReadyCounted()
  93 {
  94         if(nagger)
  95                 nagger.SendFlags |= 1;
  96 }
  97
  98
  99 // =======================
 100 //  Game logic for voting
 101 // =======================
 102
 103 void VoteReset()
 104 {
 105         entity tmp_player;
 106
 107         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 108
 109         if(vote_called)
 110         {
 111                 strunzone(vote_called_command);
 112                 strunzone(vote_called_display);
 113         }
 114
 115         vote_called = VOTE_NULL;
 116         vote_caller = world;
 117         vote_endtime = 0;
 118
 119         vote_called_command = string_null;
 120         vote_called_display = string_null;
 121
 122         vote_parsed_command = string_null;
 123         vote_parsed_display = string_null;
 124
 125         Nagger_VoteChanged();
 126 }
 127
 128 void VoteStop(entity stopper)
 129 {
 130         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 131         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 132
 133         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 134         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 135
 136         VoteReset();
 137 }
 138
 139 void VoteAccept()
 140 {
 141         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 142
 143         if((vote_called == VOTE_MASTER) && vote_caller)
 144                 vote_caller.vote_master = 1;
 145         else
 146                 localcmd(strcat(vote_called_command, "\n"));
 147
 148         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 149
 150         VoteReset();
 151         Announce("voteaccept");
 152 }
 153
 154 void VoteReject()
 155 {
 156         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 157         VoteReset();
 158         Announce("votefail");
 159 }
 160
 161 void VoteTimeout()
 162 {
 163         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 164         VoteReset();
 165         Announce("votefail");
 166 }
 167
 168 void VoteSpam(float notvoters, float mincount, string result)
 169 {
 170         bprint(strcat(
 171                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 172                 strcat("^2:^1", ftos(vote_reject_count)),
 173                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 174                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 175                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 176
 177         if(autocvar_sv_eventlog)
 178         {
 179                 GameLogEcho(strcat(
 180                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 181                         strcat(":", ftos(vote_reject_count)),
 182                         strcat(":", ftos(vote_abstain_count)),
 183                         strcat(":", ftos(notvoters)),
 184                         strcat(":", ftos(mincount))));
 185         }
 186 }
 187
 188 void VoteCount(float first_count)
 189 {
 190         // declarations
 191         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 192
 193         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 194                                 || ((autocvar_sv_vote_nospectators == 1) && (inWarmupStage || gameover))
 195                                 || (autocvar_sv_vote_nospectators == 0));
 196
 197         float vote_player_count = 0, is_player, notvoters = 0;
 198         float vote_real_player_count = 0, vote_real_accept_count = 0;
 199         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 200         float vote_needed_of_voted, final_needed_votes;
 201         float vote_factor_overall, vote_factor_of_voted;
 202
 203         entity tmp_player;
 204
 205         Nagger_VoteCountChanged();
 206
 207         // add up all the votes from each connected client
 208         FOR_EACH_REALCLIENT(tmp_player)
 209         {
 210                 is_player = (tmp_player.classname == "player");
 211
 212                 ++vote_player_count;
 213                 if(is_player) { ++vote_real_player_count; }
 214
 215                 switch(tmp_player.vote_selection)
 216                 {
 217                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(is_player) ++vote_real_reject_count; } break; }
 218                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(is_player) ++vote_real_reject_count; } break; }
 219                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(is_player) ++vote_real_abstain_count; } break; }
 220                         default: break;
 221                 }
 222         }
 223
 224         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 225         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 226         {
 227                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 228                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 229                 VoteReset();
 230                 return;
 231         }
 232
 233         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 234         if(!spectators_allowed && (vote_real_player_count > 0))
 235         {
 236                 vote_accept_count = vote_real_accept_count;
 237                 vote_reject_count = vote_real_reject_count;
 238                 vote_abstain_count = vote_real_abstain_count;
 239                 vote_player_count = vote_real_player_count;
 240         }
 241
 242         // people who have no opinion in any way :D
 243         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 244
 245         // determine the goal for the vote to be passed or rejected normally
 246         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 247         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 248
 249         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 250         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 251         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 252
 253         // are there any players at all on the server? it could be an admin vote
 254         if(vote_player_count == 0 && first_count)
 255         {
 256                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 257                 VoteAccept();
 258                 return;
 259         }
 260
 261         // since there ARE players, finally calculate the result of the vote
 262         if(vote_accept_count >= vote_needed_overall)
 263         {
 264                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 265                 VoteAccept();
 266                 return;
 267         }
 268
 269         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 270         {
 271                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 272                 VoteReject();
 273                 return;
 274         }
 275
 276         // there is not enough votes in either direction, now lets just calculate what the voters have said
 277         if(time > vote_endtime)
 278         {
 279                 final_needed_votes = vote_needed_overall;
 280
 281                 if(autocvar_sv_vote_majority_factor_of_voted)
 282                 {
 283                         if(vote_accept_count >= vote_needed_of_voted)
 284                         {
 285                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 286                                 VoteAccept();
 287                                 return;
 288                         }
 289
 290                         if(vote_accept_count + vote_reject_count > 0)
 291                         {
 292                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 293                                 VoteReject();
 294                                 return;
 295                         }
 296
 297                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 298                 }
 299
 300                 // it didn't pass or fail, so not enough votes to even make a decision.
 301                 VoteSpam(notvoters, final_needed_votes, "timeout");
 302                 VoteTimeout();
 303         }
 304 }
 305
 306 void VoteThink()
 307 {
 308         if(vote_endtime > 0) // a vote was called
 309         if(time > vote_endtime) // time is up
 310         {
 311                 VoteCount(FALSE);
 312         }
 313
 314         return;
 315 }
 316
 317
 318 // =======================
 319 //  Game logic for warmup
 320 // =======================
 321
 322 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 323 void reset_map(float dorespawn)
 324 {
 325         entity oldself;
 326         oldself = self;
 327
 328         if(time <= game_starttime && round_handler_IsActive())
 329                 round_handler_Reset(game_starttime);
 330
 331         if(g_race || g_cts)
 332                 race_ReadyRestart();
 333         else MUTATOR_CALLHOOK(reset_map_global);
 334
 335         lms_lowest_lives = 999;
 336         lms_next_place = player_count;
 337
 338         for(self = world; (self = nextent(self)); )
 339         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
 340         {
 341                 if(self.reset)
 342                 {
 343                         self.reset();
 344                         continue;
 345                 }
 346
 347                 if(self.team_saved)
 348                         self.team = self.team_saved;
 349
 350                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
 351                         remove(self);
 352         }
 353
 354         // Waypoints and assault start come LAST
 355         for(self = world; (self = nextent(self)); )
 356         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
 357         {
 358                 if(self.reset2)
 359                 {
 360                         self.reset2();
 361                         continue;
 362                 }
 363         }
 364
 365         // Moving the player reset code here since the player-reset depends
 366         // on spawnpoint entities which have to be reset first --blub
 367         if(dorespawn)
 368         if(!MUTATOR_CALLHOOK(reset_map_players))
 369         FOR_EACH_CLIENT(self) // reset all players
 370         {
 371                 /*
 372                 only reset players if a restart countdown is active
 373                 this can either be due to cvar sv_ready_restart_after_countdown having set
 374                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 375                 sv_ready_restart_after_countdown is not used and countdown is still running
 376                 */
 377                 if (restart_mapalreadyrestarted || (time < game_starttime))
 378                 {
 379                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 380                         if (IS_PLAYER(self)) {
 381                                 //PlayerScore_Clear(self);
 382                                 if(g_lms)
 383                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
 384                                 self.killcount = 0;
 385                                 //stop the player from moving so that he stands still once he gets respawned
 386                                 self.velocity = '0 0 0';
 387                                 self.avelocity = '0 0 0';
 388                                 self.movement = '0 0 0';
 389                                 PutClientInServer();
 390                         }
 391                 }
 392         }
 393
 394         if(g_keyhunt)
 395                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
 396
 397         self = oldself;
 398 }
 399
 400 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 401 void ReadyRestart_think()
 402 {
 403         restart_mapalreadyrestarted = 1;
 404         reset_map(TRUE);
 405         Score_ClearAll();
 406         remove(self);
 407
 408         return;
 409 }
 410
 411 // Forces a restart of the game without actually reloading the map // this is a mess...
 412 void ReadyRestart_force()
 413 {
 414         entity tmp_player, restart_timer;
 415
 416         bprint("^1Server is restarting...\n");
 417
 418         VoteReset();
 419
 420         // clear overtime, we have to decrease timelimit to its original value again.
 421         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 422
 423         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 424
 425         readyrestart_happened = 1;
 426         game_starttime = time + RESTART_COUNTDOWN;
 427
 428         // clear alivetime
 429         FOR_EACH_CLIENT(tmp_player)
 430         {
 431                 tmp_player.alivetime = 0;
 432                 PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, -PlayerStats_Event(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 433         }
 434
 435         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 436
 437         // disable the warmup global for the server
 438         inWarmupStage = 0; // once the game is restarted the game is in match stage
 439
 440         // reset the .ready status of all players (also spectators)
 441         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
 442         readycount = 0;
 443         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 444
 445         // lock teams with lockonrestart
 446         if(autocvar_teamplay_lockonrestart && teamplay)
 447         {
 448                 lockteams = 1;
 449                 bprint("^1The teams are now locked.\n");
 450         }
 451
 452         //initiate the restart-countdown-announcer entity
 453         if(autocvar_sv_ready_restart_after_countdown)
 454         {
 455                 restart_timer = spawn();
 456                 restart_timer.think = ReadyRestart_think;
 457                 restart_timer.nextthink = game_starttime;
 458         }
 459
 460         // after a restart every players number of allowed timeouts gets reset, too
 461         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 462
 463         //reset map immediately if this cvar is not set
 464         if not(autocvar_sv_ready_restart_after_countdown) { reset_map(TRUE); }
 465
 466         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 467 }
 468
 469 void ReadyRestart()
 470 {
 471         // no arena, assault support yet...
 472         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 473                 localcmd("restart\n");
 474         else
 475                 localcmd("\nsv_hook_gamerestart\n");
 476
 477         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 478         // Otherwise scores could be manipulated during the countdown.
 479         if not(autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 480
 481         ReadyRestart_force();
 482
 483         return;
 484 }
 485
 486 // Count the players who are ready and determine whether or not to restart the match
 487 void ReadyCount()
 488 {
 489         entity tmp_player;
 490         float ready_needed_factor, ready_needed_count;
 491         float t_ready = 0, t_players = 0;
 492
 493         FOR_EACH_REALCLIENT(tmp_player)
 494         {
 495                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 496                 {
 497                         ++t_players;
 498                         if(tmp_player.ready) { ++t_ready; }
 499                 }
 500         }
 501
 502         readycount = t_ready;
 503
 504         Nagger_ReadyCounted();
 505
 506         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 507         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 508
 509         if(readycount >= ready_needed_count)
 510         {
 511                 ReadyRestart();
 512         }
 513
 514         return;
 515 }
 516
 517
 518 // ======================================
 519 //  Supporting functions for VoteCommand
 520 // ======================================
 521
 522 float Votecommand_check_assignment(entity caller, float assignment)
 523 {
 524         float from_server = (!caller);
 525
 526         if((assignment == VC_ASGNMNT_BOTH)
 527                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 528                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 529         {
 530                 return TRUE;
 531         }
 532
 533         return FALSE;
 534 }
 535
 536 string VoteCommand_extractcommand(string input, float startpos, float argc)
 537 {
 538         string output;
 539
 540         if((argc - 1) < startpos)
 541                 output = "";
 542         else
 543                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 544
 545         return output;
 546 }
 547
 548 float VoteCommand_checknasty(string vote_command)
 549 {
 550         if((strstrofs(vote_command, ";", 0) >= 0)
 551                 || (strstrofs(vote_command, "\n", 0) >= 0)
 552                 || (strstrofs(vote_command, "\r", 0) >= 0)
 553                 || (strstrofs(vote_command, "$", 0) >= 0))
 554                 return FALSE;
 555
 556         return TRUE;
 557 }
 558
 559 float VoteCommand_checkinlist(string vote_command, string list)
 560 {
 561         string l = strcat(" ", list, " ");
 562
 563         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 564                 return TRUE;
 565
 566         return FALSE;
 567 }
 568
 569 string ValidateMap(string validated_map, entity caller)
 570 {
 571         validated_map = MapInfo_FixName(validated_map);
 572
 573         if not(validated_map)
 574         {
 575                 print_to(caller, "This map is not available on this server.");
 576                 return string_null;
 577         }
 578
 579         if(!autocvar_sv_vote_override_mostrecent && caller)
 580         {
 581                 if(Map_IsRecent(validated_map))
 582                 {
 583                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 584                         return string_null;
 585                 }
 586         }
 587
 588         if(!MapInfo_CheckMap(validated_map))
 589         {
 590                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 591                 return string_null;
 592         }
 593
 594         return validated_map;
 595 }
 596
 597 float VoteCommand_checkargs(float startpos, float argc)
 598 {
 599         float p, q, check, minargs;
 600         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 601         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 602         string charlist, arg;
 603         float checkmate;
 604
 605         if(cmdrestriction == "")
 606                 return TRUE;
 607
 608         ++startpos; // skip command name
 609
 610         // check minimum arg count
 611
 612         // 0 args: argc == startpos
 613         // 1 args: argc == startpos + 1
 614         // ...
 615
 616         minargs = stof(cmdrestriction);
 617         if(argc - startpos < minargs)
 618                 return FALSE;
 619
 620         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 621
 622         for(;;)
 623         {
 624                 // we know that at any time, startpos <= argc - minargs
 625                 // so this means: argc-minargs >= startpos >= argc, thus
 626                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 627                 // have been seen already
 628
 629                 if(startpos >= argc) // all args checked? GOOD
 630                         break;
 631
 632                 if(p < 0) // no more args? FAIL
 633                 {
 634                         // exception: exactly minargs left, this one included
 635                         if(argc - startpos == minargs)
 636                                 break;
 637
 638                         // otherwise fail
 639                         return FALSE;
 640                 }
 641
 642                 // cut to next semicolon
 643                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 644                 if(q < 0)
 645                         charlist = substring(cmdrestriction, p+1, -1);
 646                 else
 647                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 648
 649                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 650                 // charlist = strreplace("^^", ";", charlist);
 651
 652                 if(charlist != "")
 653                 {
 654                         // verify the arg only contains allowed chars
 655                         arg = argv(startpos);
 656                         checkmate = strlen(arg);
 657                         for(check = 0; check < checkmate; ++check)
 658                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 659                                         return FALSE; // not allowed character
 660                         // all characters are allowed. FINE.
 661                 }
 662
 663                 ++startpos;
 664                 --minargs;
 665                 p = q;
 666         }
 667
 668         return TRUE;
 669 }
 670
 671 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 672 {
 673         string first_command;
 674
 675         first_command = argv(startpos);
 676
 677         if not(VoteCommand_checkinlist(first_command, vote_list))
 678                 return FALSE;
 679
 680         if not(VoteCommand_checkargs(startpos, argc))
 681                 return FALSE;
 682
 683         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 684         {
 685                 case "kick":
 686                 case "kickban": // catch all kick/kickban commands
 687                 {
 688                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 689                         float accepted = VerifyClientEntity(victim, TRUE, FALSE);
 690
 691                         if(accepted > 0)
 692                         {
 693                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)) : "No reason provided");
 694                                 string command_arguments;
 695
 696                                 if(first_command == "kickban")
 697                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 698                                 else
 699                                         command_arguments = reason;
 700
 701                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 702                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 703                         }
 704                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return FALSE; }
 705
 706                         break;
 707                 }
 708
 709                 case "map":
 710                 case "chmap":
 711                 case "gotomap": // re-direct all map selection commands to gotomap
 712                 {
 713                         vote_command = ValidateMap(argv(startpos + 1), caller);
 714                         if not(vote_command) { return FALSE; }
 715                         vote_parsed_command = strcat("gotomap ", vote_command);
 716                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 717
 718                         break;
 719                 }
 720
 721                 default:
 722                 {
 723                         vote_parsed_command = vote_command;
 724                         vote_parsed_display = strzone(strcat("^1", vote_command));
 725
 726                         break;
 727                 }
 728         }
 729
 730         return TRUE;
 731 }
 732
 733
 734 // =======================
 735 //  Command Sub-Functions
 736 // =======================
 737
 738 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 739 {
 740         switch(request)
 741         {
 742                 case CMD_REQUEST_COMMAND:
 743                 {
 744                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 745                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 746
 747                         else // everything went okay, continue changing vote
 748                         {
 749                                 print_to(caller, "^1You abstained from your vote.");
 750                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 751                                 msg_entity = caller;
 752                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 753                         }
 754
 755                         return;
 756                 }
 757
 758                 default:
 759                 case CMD_REQUEST_USAGE:
 760                 {
 761                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 762                         print_to(caller, "  No arguments required.");
 763                         return;
 764                 }
 765         }
 766 }
 767
 768 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 769 {
 770         switch(request)
 771         {
 772                 case CMD_REQUEST_COMMAND:
 773                 {
 774                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 775                                 || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 776                                 || (autocvar_sv_vote_nospectators == 0));
 777
 778                         float tmp_playercount = 0;
 779                         entity tmp_player;
 780
 781                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 782
 783                         if not(autocvar_sv_vote_call || !caller) { print_to(caller, "^1Vote calling is not allowed."); }
 784                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 785                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 786                         else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 787                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 788                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 789                         else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 790                         else if not(VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 791
 792                         else // everything went okay, continue with calling the vote
 793                         {
 794                                 vote_caller = caller; // remember who called the vote
 795                                 vote_called = VOTE_NORMAL;
 796                                 vote_called_command = strzone(vote_parsed_command);
 797                                 vote_called_display = strzone(vote_parsed_display);
 798                                 vote_endtime = time + autocvar_sv_vote_timeout;
 799
 800                                 if(caller)
 801                                 {
 802                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 803                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 804                                         msg_entity = caller;
 805                                 }
 806
 807                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 808                                 if(tmp_playercount > 1) { Announce("votecall"); } // don't announce a "vote now" sound if player is alone
 809
 810                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 811                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 812                                 Nagger_VoteChanged();
 813                                 VoteCount(TRUE); // needed if you are the only one
 814                         }
 815
 816                         return;
 817                 }
 818
 819                 default:
 820                 case CMD_REQUEST_USAGE:
 821                 {
 822                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 823                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 824                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 825                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 826                         return;
 827                 }
 828         }
 829 }
 830
 831 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 832 {
 833         switch(request)
 834         {
 835                 case CMD_REQUEST_COMMAND:
 836                 {
 837                         if(autocvar_sv_vote_master)
 838                         {
 839                                 switch(strtolower(argv(2)))
 840                                 {
 841                                         case "do":
 842                                         {
 843                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 844
 845                                                 if not(caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 846                                                 else if not(VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 847                                                 else if not(VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 848
 849                                                 else // everything went okay, proceed with command
 850                                                 {
 851                                                         localcmd(strcat(vote_parsed_command, "\n"));
 852                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 853                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 854                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 855                                                 }
 856
 857                                                 return;
 858                                         }
 859
 860                                         case "login":
 861                                         {
 862                                                 if not(autocvar_sv_vote_master_password != "") { print_to(caller, "^1Login to vote master is not allowed."); }
 863                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 864                                                 else if not(autocvar_sv_vote_master_password == argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 865
 866                                                 else // everything went okay, proceed with giving this player master privilages
 867                                                 {
 868                                                         caller.vote_master = TRUE;
 869                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 870                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 871                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 872                                                 }
 873
 874                                                 return;
 875                                         }
 876
 877                                         default: // calling a vote for master
 878                                         {
 879                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 880                                                         || ((autocvar_sv_vote_nospectators == 1) && inWarmupStage)
 881                                                         || (autocvar_sv_vote_nospectators == 0));
 882
 883                                                 if not(autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 884                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 885                                                 else if(!spectators_allowed && (caller && (caller.classname != "player"))) { print_to(caller, "^1Only players can call a vote."); }
 886                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 887
 888                                                 else // everything went okay, continue with creating vote
 889                                                 {
 890                                                         vote_caller = caller;
 891                                                         vote_called = VOTE_MASTER;
 892                                                         vote_called_command = strzone("XXX");
 893                                                         vote_called_display = strzone("^3master");
 894                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 895
 896                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 897                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 898
 899                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 900                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 901                                                         Nagger_VoteChanged();
 902                                                         VoteCount(TRUE); // needed if you are the only one
 903                                                 }
 904
 905                                                 return;
 906                                         }
 907                                 }
 908                         }
 909                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 910
 911                         return;
 912                 }
 913
 914                 default:
 915                 case CMD_REQUEST_USAGE:
 916                 {
 917                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 918                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 919                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 920                         return;
 921                 }
 922         }
 923 }
 924
 925 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 926 {
 927         switch(request)
 928         {
 929                 case CMD_REQUEST_COMMAND:
 930                 {
 931                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 932                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 933                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 934
 935                         else // everything went okay, continue changing vote
 936                         {
 937                                 print_to(caller, "^1You rejected the vote.");
 938                                 caller.vote_selection = VOTE_SELECT_REJECT;
 939                                 msg_entity = caller;
 940                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
 941                         }
 942
 943                         return;
 944                 }
 945
 946                 default:
 947                 case CMD_REQUEST_USAGE:
 948                 {
 949                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 950                         print_to(caller, "  No arguments required.");
 951                         return;
 952                 }
 953         }
 954 }
 955
 956 void VoteCommand_status(float request, entity caller) // BOTH
 957 {
 958         switch(request)
 959         {
 960                 case CMD_REQUEST_COMMAND:
 961                 {
 962                         if(vote_called)
 963                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 964                         else
 965                                 print_to(caller, "^1No vote called.");
 966
 967                         return;
 968                 }
 969
 970                 default:
 971                 case CMD_REQUEST_USAGE:
 972                 {
 973                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
 974                         print_to(caller, "  No arguments required.");
 975                         return;
 976                 }
 977         }
 978 }
 979
 980 void VoteCommand_stop(float request, entity caller) // BOTH
 981 {
 982         switch(request)
 983         {
 984                 case CMD_REQUEST_COMMAND:
 985                 {
 986                         if not(vote_called) { print_to(caller, "^1No vote called."); }
 987                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
 988                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
 989
 990                         return;
 991                 }
 992
 993                 default:
 994                 case CMD_REQUEST_USAGE:
 995                 {
 996                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
 997                         print_to(caller, "  No arguments required.");
 998                         return;
 999                 }
1000         }
1001 }
1002
1003 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1004 {
1005         switch(request)
1006         {
1007                 case CMD_REQUEST_COMMAND:
1008                 {
1009                         if not(vote_called) { print_to(caller, "^1No vote called."); }
1010                         else if not(caller.vote_selection == VOTE_SELECT_NULL || autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1011
1012                         else // everything went okay, continue changing vote
1013                         {
1014                                 print_to(caller, "^1You accepted the vote.");
1015                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1016                                 msg_entity = caller;
1017                                 if(!autocvar_sv_vote_singlecount) { VoteCount(FALSE); }
1018                         }
1019
1020                         return;
1021                 }
1022
1023                 default:
1024                 case CMD_REQUEST_USAGE:
1025                 {
1026                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1027                         print_to(caller, "  No arguments required.");
1028                         return;
1029                 }
1030         }
1031 }
1032
1033 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1034 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1035 void VoteCommand_(float request)
1036 {
1037         switch(request)
1038         {
1039                 case CMD_REQUEST_COMMAND:
1040                 {
1041
1042                         return;
1043                 }
1044
1045                 default:
1046                 case CMD_REQUEST_USAGE:
1047                 {
1048                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1049                         print_to(caller, "  No arguments required.");
1050                         return;
1051                 }
1052         }
1053 }
1054 */
1055
1056
1057 // ================================
1058 //  Macro system for vote commands
1059 // ================================
1060
1061 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1062 #define VOTE_COMMANDS(request,caller,arguments,command) \
1063         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1064         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1065         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1066         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1067         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1068         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1069         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1070         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1071         /* nothing */
1072
1073 void VoteCommand_macro_help(entity caller, float argc)
1074 {
1075         string command_origin = GetCommandPrefix(caller);
1076
1077         if(argc == 2) // help display listing all commands
1078         {
1079                 print_to(caller, "\nVoting commands:\n");
1080                 #define VOTE_COMMAND(name,function,description,assignment) \
1081                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1082
1083                 VOTE_COMMANDS(0, caller, 0, "")
1084                 #undef VOTE_COMMAND
1085
1086                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1087                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1088                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1089         }
1090         else // usage for individual command
1091         {
1092                 #define VOTE_COMMAND(name,function,description,assignment) \
1093                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1094
1095                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "")
1096                 #undef VOTE_COMMAND
1097         }
1098
1099         return;
1100 }
1101
1102 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1103 {
1104         #define VOTE_COMMAND(name,function,description,assignment) \
1105                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return TRUE; } } }
1106
1107         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command)
1108         #undef VOTE_COMMAND
1109
1110         return FALSE;
1111 }
1112
1113
1114 // ======================================
1115 //  Main function handling vote commands
1116 // ======================================
1117
1118 void VoteCommand(float request, entity caller, float argc, string vote_command)
1119 {
1120         // Guide for working with argc arguments by example:
1121         // argc:   1    - 2      - 3     - 4
1122         // argv:   0    - 1      - 2     - 3
1123         // cmd     vote - master - login - password
1124
1125         switch(request)
1126         {
1127                 case CMD_REQUEST_COMMAND:
1128                 {
1129                         if(VoteCommand_macro_command(caller, argc, vote_command))
1130                                 return;
1131                 }
1132
1133                 default:
1134                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1135                 case CMD_REQUEST_USAGE:
1136                 {
1137                         VoteCommand_macro_help(caller, argc);
1138                         return;
1139                 }
1140         }
1141 }