qcsrc/server/compat/quake3.qc

   1 #include "quake3.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <server/items.qh>
   6 #include <server/resources.qh>
   7 #include <common/t_items.qh>
   8 #include <common/mapobjects/triggers.qh>
   9 #include <common/mapobjects/trigger/counter.qh>
  10 #include <common/weapons/_all.qh>
  11
  12 //***********************
  13 //QUAKE 3 ENTITIES - So people can play quake3 maps with the xonotic weapons
  14 //***********************
  15
  16 // NOTE: for best experience, you need to swap MGs with SGs in the map or it won't have a MG
  17
  18 // SG -> SG
  19 SPAWNFUNC_ITEM(ammo_shells, ITEM_Shells)
  20
  21 // MG -> MG
  22 SPAWNFUNC_ITEM(ammo_bullets, ITEM_Bullets)
  23
  24 // GL -> Mortar
  25 SPAWNFUNC_ITEM(ammo_grenades, ITEM_Rockets)
  26
  27 // Mines -> Rockets
  28 SPAWNFUNC_WEAPON(weapon_prox_launcher, WEP_MINE_LAYER)
  29 SPAWNFUNC_ITEM(ammo_mines, ITEM_Rockets)
  30
  31 // LG -> Lightning
  32 SPAWNFUNC_WEAPON(weapon_lightning, WEP_ELECTRO)
  33 SPAWNFUNC_ITEM(ammo_lightning, ITEM_Cells)
  34
  35 // Plasma -> Hagar
  36 SPAWNFUNC_WEAPON(weapon_plasmagun, WEP_HAGAR)
  37 SPAWNFUNC_ITEM(ammo_cells, ITEM_Rockets)
  38
  39 // Rail -> Vortex
  40 SPAWNFUNC_WEAPON(weapon_railgun, WEP_VORTEX)
  41 SPAWNFUNC_ITEM(ammo_slugs, ITEM_Cells)
  42
  43 // BFG -> Crylink
  44 SPAWNFUNC_WEAPON(weapon_bfg, WEP_CRYLINK)
  45 SPAWNFUNC_ITEM(ammo_bfg, ITEM_Cells)
  46
  47 // grappling hook -> hook
  48 SPAWNFUNC_WEAPON(weapon_grapplinghook, WEP_HOOK)
  49
  50 // RL -> RL
  51 SPAWNFUNC_ITEM(ammo_rockets, ITEM_Rockets)
  52
  53 // Armor
  54 SPAWNFUNC_ITEM(item_armor_body, ITEM_ArmorMega)
  55 SPAWNFUNC_ITEM(item_armor_combat, ITEM_ArmorBig)
  56 SPAWNFUNC_ITEM(item_armor_shard, ITEM_ArmorSmall)
  57 SPAWNFUNC_ITEM(item_enviro, ITEM_Shield)
  58
  59 // medkit -> armor (we have no holdables)
  60 SPAWNFUNC_ITEM(holdable_medkit, ITEM_ArmorMega)
  61
  62 // doubler -> strength
  63 SPAWNFUNC_ITEM(item_doubler, ITEM_Strength)
  64
  65 .float wait;
  66 .float delay;
  67
  68 // weapon remove ent from df
  69 void target_init_verify(entity this)
  70 {
  71         entity trigger, targ;
  72         for(trigger = NULL; (trigger = find(trigger, classname, "trigger_multiple")); )
  73                 for(targ = NULL; (targ = find(targ, targetname, trigger.target)); )
  74                         if (targ.classname == "target_init" || targ.classname == "target_give" || targ.classname == "target_items")
  75                         {
  76                                 trigger.wait = 0;
  77                                 trigger.delay = 0;
  78                                 targ.wait = 0;
  79                                 targ.delay = 0;
  80
  81                                 //setsize(targ, trigger.mins, trigger.maxs);
  82                                 //setorigin(targ, trigger.origin);
  83                                 //remove(trigger);
  84                         }
  85 }
  86
  87 void target_init_use(entity this, entity actor, entity trigger)
  88 {
  89         if (!(this.spawnflags & 1))
  90         {
  91                 SetResource(actor, RES_ARMOR, start_armorvalue);
  92                 actor.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot;
  93         }
  94
  95         if (!(this.spawnflags & 2))
  96         {
  97                 SetResource(actor, RES_HEALTH, start_health);
  98                 actor.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot;
  99                 actor.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 100         }
 101
 102         if (!(this.spawnflags & 4))
 103         {
 104                 SetResource(actor, RES_SHELLS, start_ammo_shells);
 105                 SetResource(actor, RES_BULLETS, start_ammo_nails);
 106                 SetResource(actor, RES_ROCKETS, start_ammo_rockets);
 107                 SetResource(actor, RES_CELLS, start_ammo_cells);
 108                 SetResource(actor, RES_PLASMA, start_ammo_plasma);
 109                 SetResource(actor, RES_FUEL, start_ammo_fuel);
 110
 111                 STAT(WEAPONS, actor) = start_weapons;
 112                 if (this.spawnflags & 32)
 113                 {
 114                         // TODO
 115                 }
 116         }
 117
 118         if (!(this.spawnflags & 8))
 119         {
 120                 actor.strength_finished = 0;
 121                 actor.invincible_finished = 0;
 122                 if(STAT(BUFFS, actor)) // TODO: make a dropbuffs function to handle this
 123                 {
 124                         int buffid = buff_FirstFromFlags(STAT(BUFFS, actor)).m_id;
 125                         Send_Notification(NOTIF_ONE, actor, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 126                         sound(actor, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 127                         if(!IS_INDEPENDENT_PLAYER(actor))
 128                                 Send_Notification(NOTIF_ALL_EXCEPT, actor, MSG_INFO, INFO_ITEM_BUFF_LOST, actor.netname, buffid);
 129                         STAT(BUFFS, actor) = 0;
 130                         STAT(BUFF_TIME, actor) = 0;
 131                 }
 132         }
 133
 134         if (!(this.spawnflags & 16))
 135         {
 136                 // We don't have holdables.
 137         }
 138
 139         SUB_UseTargets(this, actor, trigger);
 140 }
 141
 142 spawnfunc(target_init)
 143 {
 144         this.use = target_init_use;
 145         InitializeEntity(this, target_init_verify, INITPRIO_FINDTARGET);
 146 }
 147
 148 // weapon give ent from defrag
 149 void target_give_init(entity this)
 150 {
 151         IL_EACH(g_items, it.targetname == this.target,
 152         {
 153                 if (it.classname == "weapon_devastator") {
 154                         SetResourceExplicit(this, RES_ROCKETS, GetResource(this, RES_ROCKETS) + it.count * WEP_CVAR_PRI(devastator, ammo)); // WEAPONTODO
 155                         this.netname = cons(this.netname, "devastator");
 156                 }
 157                 else if (it.classname == "weapon_vortex") {
 158                         SetResourceExplicit(this, RES_CELLS, GetResource(this, RES_CELLS) + it.count * WEP_CVAR_PRI(vortex, ammo)); // WEAPONTODO
 159                         this.netname = cons(this.netname, "vortex");
 160                 }
 161                 else if (it.classname == "weapon_electro") {
 162                         SetResourceExplicit(this, RES_CELLS, GetResource(this, RES_CELLS) + it.count * WEP_CVAR_PRI(electro, ammo)); // WEAPONTODO
 163                         this.netname = cons(this.netname, "electro");
 164                 }
 165                 else if (it.classname == "weapon_hagar") {
 166                         SetResourceExplicit(this, RES_ROCKETS, GetResource(this, RES_ROCKETS) + it.count * WEP_CVAR_PRI(hagar, ammo)); // WEAPONTODO
 167                         this.netname = cons(this.netname, "hagar");
 168                 }
 169                 else if (it.classname == "weapon_crylink") {
 170                         SetResourceExplicit(this, RES_CELLS, GetResource(this, RES_CELLS) + it.count * WEP_CVAR_PRI(crylink, ammo)); // WEAPONTODO
 171                         this.netname = cons(this.netname, "crylink");
 172                 }
 173                 else if (it.classname == "weapon_mortar") {
 174                         SetResourceExplicit(this, RES_ROCKETS, GetResource(this, RES_ROCKETS) + it.count * WEP_CVAR_PRI(mortar, ammo)); // WEAPONTODO
 175                         this.netname = cons(this.netname, "mortar");
 176                 }
 177                 else if (it.classname == "item_armor_mega")
 178                         SetResourceExplicit(this, RES_ARMOR, 100);
 179                 else if (it.classname == "item_health_mega")
 180                         SetResourceExplicit(this, RES_HEALTH, 200);
 181                 else if (it.classname == "item_buff") {
 182                         entity buff = buff_FirstFromFlags(STAT(BUFFS, it));
 183                         this.netname = cons(this.netname, buff.netname);
 184                         STAT(BUFF_TIME, this) = it.count;
 185                 }
 186
 187                 //remove(it); // removing ents in init functions causes havoc, workaround:
 188         setthink(it, SUB_Remove);
 189         it.nextthink = time;
 190         });
 191         this.spawnflags = 2;
 192         this.spawnfunc_checked = true;
 193         spawnfunc_target_items(this);
 194         InitializeEntity(this, target_init_verify, INITPRIO_FINDTARGET);
 195 }
 196
 197 spawnfunc(target_give)
 198 {
 199         InitializeEntity(this, target_give_init, INITPRIO_FINDTARGET);
 200 }
 201
 202 void score_use(entity this, entity actor, entity trigger)
 203 {
 204         if(!IS_PLAYER(actor))
 205                 return;
 206         actor.fragsfilter_cnt += this.count;
 207 }
 208 spawnfunc(target_score)
 209 {
 210         if(!g_cts) { delete(this); return; }
 211
 212         if(!this.count)
 213                 this.count = 1;
 214         this.use = score_use;
 215 }
 216
 217 void fragsfilter_use(entity this, entity actor, entity trigger)
 218 {
 219         if(!IS_PLAYER(actor))
 220                 return;
 221         if(actor.fragsfilter_cnt >= this.frags)
 222                 SUB_UseTargets(this, actor, trigger);
 223 }
 224 spawnfunc(target_fragsFilter)
 225 {
 226         if(!g_cts) { delete(this); return; }
 227
 228         if(!this.frags)
 229                 this.frags = 1;
 230         this.use = fragsfilter_use;
 231 }
 232
 233 //spawnfunc(item_flight)       /* handled by buffs mutator */
 234 //spawnfunc(item_haste)        /* handled by buffs mutator */
 235 //spawnfunc(item_health)       /* handled in t_quake.qc */
 236 //spawnfunc(item_health_large) /* handled in t_items.qc */
 237 //spawnfunc(item_health_small) /* handled in t_items.qc */
 238 //spawnfunc(item_health_mega)  /* handled in t_items.qc */
 239 //spawnfunc(item_invis)        /* handled by buffs mutator */
 240 //spawnfunc(item_regen)        /* handled by buffs mutator */
 241
 242 // CTF spawnfuncs handled in mutators/gamemode_ctf.qc now
 243
 244 .float notteam;
 245 .float notsingle;
 246 .float notfree;
 247 .float notq3a;
 248 .float notta;
 249 .string gametype;
 250 bool DoesQ3ARemoveThisEntity(entity this)
 251 {
 252         // Q3 style filters (DO NOT USE, THIS IS COMPAT ONLY)
 253
 254         if(this.notq3a)
 255                 if(!teamplay || g_tdm || g_ctf)
 256                         return true;
 257
 258         if(this.notta)
 259                 if (!(!teamplay || g_tdm || g_ctf))
 260                         return true;
 261
 262         if(this.notsingle)
 263                 if(maxclients == 1)
 264                         return true;
 265
 266         if(this.notteam)
 267                 if(teamplay)
 268                         return true;
 269
 270         if(this.notfree)
 271                 if(!teamplay)
 272                         return true;
 273
 274         if(this.gametype)
 275         {
 276                 string gametypename;
 277                 // static char *gametypeNames[] = {"ffa", "tournament", "single", "team", "ctf", "oneflag", "obelisk", "harvester", "teamtournament"}
 278                 gametypename = "ffa";
 279                 if(teamplay)
 280                         gametypename = "team";
 281                 if(g_ctf)
 282                         gametypename = "ctf";
 283                 if(g_duel)
 284                         gametypename = "tournament";
 285                 if(maxclients == 1)
 286                         gametypename = "single";
 287                 // we do not have the other types (oneflag, obelisk, harvester, teamtournament)
 288                 if(strstrofs(this.gametype, gametypename, 0) < 0)
 289                         return true;
 290         }
 291
 292         return false;
 293 }