qcsrc/server/ctf.qc

   1 #define FLAG_MIN (PL_MIN + '0 0 -13')
   2 #define FLAG_MAX (PL_MAX + '0 0 -13')
   3
   4 .entity basewaypoint;
   5 .entity sprite;
   6 entity ctf_worldflaglist; // CTF flags in the map
   7 .entity ctf_worldflagnext;
   8 .float dropperid;
   9 .float ctf_droptime;
  10
  11 .float next_take_time;                  // the next time a player can pick up a flag (time + blah)
  12                                                                 /// I used this, in part, to fix the looping score bug. - avirox
  13 //float FLAGSCORE_PICKUP        =  1;
  14 //float FLAGSCORE_RETURN        =  5; // returned by owner team
  15 //float FLAGSCORE_RETURNROGUE   = 10; // returned by rogue team
  16 //float FLAGSCORE_CAPTURE       =  5;
  17
  18 #define FLAG_CARRY_POS '-15 0 7'
  19
  20 .float ctf_captureshielded; // set to 1 if the player is too bad to be allowed to capture
  21
  22 float captureshield_min_negscore; // punish at -20 points
  23 float captureshield_max_ratio; // punish at most 30% of each team
  24 float captureshield_force; // push force of the shield
  25
  26 float ctf_captureshield_shielded(entity p)
  27 {
  28         float s, se;
  29         entity e;
  30         float players_worseeq, players_total;
  31
  32         if(captureshield_max_ratio <= 0)
  33                 return FALSE;
  34
  35         s = PlayerScore_Add(p, SP_SCORE, 0);
  36         if(s >= -captureshield_min_negscore)
  37                 return FALSE;
  38
  39         players_total = players_worseeq = 0;
  40         FOR_EACH_PLAYER(e)
  41         {
  42                 if(e.team != p.team)
  43                         continue;
  44                 se = PlayerScore_Add(e, SP_SCORE, 0);
  45                 if(se <= s)
  46                         ++players_worseeq;
  47                 ++players_total;
  48         }
  49
  50         // player is in the worse half, if >= half the players are better than him, or consequently, if < half of the players are worse
  51         // use this rule here
  52
  53         if(players_worseeq >= players_total * captureshield_max_ratio)
  54                 return FALSE;
  55
  56         return TRUE;
  57 }
  58
  59 void ctf_captureshield_update(entity p, float dir)
  60 {
  61         float should;
  62         if(dir == p.ctf_captureshielded) // 0: shield only, 1: unshield only
  63         {
  64                 should = ctf_captureshield_shielded(p);
  65                 if(should != dir)
  66                 {
  67                         if(should)
  68                         {
  69                                 centerprint_atprio(p, CENTERPRIO_SHIELDING, "^3You are now ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Make some defensive scores before trying again.");
  70                                 // TODO csqc notifier for this
  71                         }
  72                         else
  73                         {
  74                                 centerprint_atprio(p, CENTERPRIO_SHIELDING, "^3You are now free.\n\n^3Feel free to ^1try to capture^3 the flag again\n^3if you think you will succeed.");
  75                                 // TODO csqc notifier for this
  76                         }
  77                         p.ctf_captureshielded = should;
  78                 }
  79         }
  80 }
  81
  82 float ctf_captureshield_customize()
  83 {
  84         if not(other.ctf_captureshielded)
  85                 return FALSE;
  86         if(self.team == other.team)
  87                 return FALSE;
  88         return TRUE;
  89 }
  90
  91 void ctf_captureshield_touch()
  92 {
  93         if not(other.ctf_captureshielded)
  94                 return;
  95         if(self.team == other.team)
  96                 return;
  97         vector mymid;
  98         vector othermid;
  99         mymid = (self.absmin + self.absmax) * 0.5;
 100         othermid = (other.absmin + other.absmax) * 0.5;
 101         Damage(other, self, self, 0, DEATH_HURTTRIGGER, mymid, normalize(othermid - mymid) * captureshield_force);
 102         centerprint_atprio(other, CENTERPRIO_SHIELDING, "^3You are ^4shielded^3 from the flag\n^3for ^1too many unsuccessful attempts^3 to capture.\n\n^3Get some defensive scores before trying again.");
 103 }
 104
 105 void ctf_flag_spawnstuff()
 106 {
 107         entity e;
 108         e = spawn();
 109         e.enemy = self;
 110         e.team = self.team;
 111         e.touch = ctf_captureshield_touch;
 112         e.customizeentityforclient = ctf_captureshield_customize;
 113         e.classname = "ctf_captureshield";
 114         e.effects = EF_ADDITIVE;
 115         e.movetype = MOVETYPE_NOCLIP;
 116         e.solid = SOLID_TRIGGER;
 117         e.avelocity = '7 0 11';
 118         setorigin(e, self.origin);
 119         setmodel(e, "models/ctf/shield.md3");
 120         e.scale = 0.5;
 121         setsize(e, e.scale * e.mins, e.scale * e.maxs);
 122
 123         waypoint_spawnforitem_force(self, self.origin);
 124         self.nearestwaypointtimeout = 0; // activate waypointing again
 125         self.basewaypoint = self.nearestwaypoint;
 126
 127         if(self.team == COLOR_TEAM1)
 128         {
 129                 WaypointSprite_SpawnFixed("redbase", self.origin + '0 0 61', self, sprite);
 130                 WaypointSprite_UpdateTeamRadar(self.sprite, RADARICON_FLAG, colormapPaletteColor(COLOR_TEAM1 - 1, FALSE));
 131         }
 132         else
 133         {
 134                 WaypointSprite_SpawnFixed("bluebase", self.origin + '0 0 61', self, sprite);
 135                 WaypointSprite_UpdateTeamRadar(self.sprite, RADARICON_FLAG, colormapPaletteColor(COLOR_TEAM2 - 1, FALSE));
 136         }
 137 }
 138
 139 float ctf_score_value(string parameter)
 140 {
 141         if(g_ctf_win_mode != 2)
 142                 return cvar(strcat("g_ctf_personal", parameter));
 143         else
 144                 return cvar(strcat("g_ctf_flag", parameter));
 145 }
 146
 147 void FakeTimeLimit(entity e, float t)
 148 {
 149         msg_entity = e;
 150         WriteByte(MSG_ONE, 3); // svc_updatestat
 151         WriteByte(MSG_ONE, 236); // STAT_TIMELIMIT
 152         if(t < 0)
 153                 WriteCoord(MSG_ONE, cvar("timelimit"));
 154         else
 155                 WriteCoord(MSG_ONE, (t + 1) / 60);
 156 }
 157
 158 float   flagcaptimerecord;
 159 .float  flagpickuptime;
 160 //.float  iscommander;
 161 //.float  ctf_state;
 162
 163 void() FlagThink;
 164 void() FlagTouch;
 165
 166 void place_flag()
 167 {
 168         if(self.classname != "item_flag_team")
 169         {
 170                 backtrace("PlaceFlag a non-flag");
 171                 return;
 172         }
 173
 174         if(!self.t_width)
 175                 self.t_width = 0.1; // frame animation rate
 176         if(!self.t_length)
 177                 self.t_length = 58; // maximum frame
 178
 179         setattachment(self, world, "");
 180         self.mdl = self.model;
 181         self.flags = FL_ITEM;
 182         self.solid = SOLID_TRIGGER;
 183         self.movetype = MOVETYPE_NONE;
 184         self.velocity = '0 0 0';
 185         self.origin_z = self.origin_z + 6;
 186         self.think = FlagThink;
 187         self.touch = FlagTouch;
 188         self.nextthink = time + 0.1;
 189         self.cnt = FLAG_BASE;
 190         self.mangle = self.angles;
 191         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 192         //self.effects = self.effects | EF_DIMLIGHT;
 193         if(self.noalign)
 194         {
 195                 self.dropped_origin = self.origin;
 196         }
 197         else
 198         {
 199                 droptofloor();
 200                 self.movetype = MOVETYPE_TOSS;
 201         }
 202
 203         InitializeEntity(self, ctf_flag_spawnstuff, INITPRIO_SETLOCATION);
 204 };
 205
 206 void LogCTF(string mode, float flagteam, entity actor)
 207 {
 208         string s;
 209         if(!cvar("sv_eventlog"))
 210                 return;
 211         s = strcat(":ctf:", mode);
 212         s = strcat(s, ":", ftos(flagteam));
 213         if(actor != world)
 214                 s = strcat(s, ":", ftos(actor.playerid));
 215         GameLogEcho(s);
 216 }
 217
 218 void RegenFlag(entity e)
 219 {
 220         if(e.classname != "item_flag_team")
 221         {
 222                 backtrace("RegenFlag a non-flag");
 223                 return;
 224         }
 225
 226         if(e.waypointsprite_attachedforcarrier)
 227                 WaypointSprite_DetachCarrier(e);
 228
 229         setattachment(e, world, "");
 230         e.damageforcescale = 0;
 231         e.takedamage = DAMAGE_NO;
 232         e.movetype = MOVETYPE_NONE;
 233         if(!e.noalign)
 234                 e.movetype = MOVETYPE_TOSS;
 235         e.velocity = '0 0 0';
 236         e.solid = SOLID_TRIGGER;
 237         // TODO: play a sound here
 238         setorigin(e, e.dropped_origin);
 239         e.angles = e.mangle;
 240         e.cnt = FLAG_BASE;
 241         e.owner = world;
 242         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 243 };
 244
 245 void ReturnFlag(entity e)
 246 {
 247         if(e.classname != "item_flag_team")
 248         {
 249                 backtrace("ReturnFlag a non-flag");
 250                 return;
 251         }
 252
 253         if (e.owner)
 254         if (e.owner.flagcarried == e)
 255         {
 256                 WaypointSprite_DetachCarrier(e.owner);
 257                 e.owner.flagcarried = world;
 258
 259                 if(e.speedrunning)
 260                         FakeTimeLimit(e.owner, -1);
 261         }
 262         e.owner = world;
 263         RegenFlag(e);
 264 };
 265
 266 void DropFlag(entity e, entity penalty_receiver, entity attacker)
 267 {
 268         local entity p;
 269
 270         if(e.classname != "item_flag_team")
 271         {
 272                 backtrace("DropFlag a non-flag");
 273                 return;
 274         }
 275
 276         if(e.speedrunning)
 277         {
 278                 ReturnFlag(e);
 279                 return;
 280         }
 281
 282         if (!e.owner)
 283         {
 284                 dprint("FLAG: drop - no owner?!?!\n");
 285                 return;
 286         }
 287         p = e.owner;
 288         if (p.flagcarried != e)
 289         {
 290                 dprint("FLAG: drop - owner is not carrying this flag??\n");
 291                 return;
 292         }
 293         //bprint(p.netname, "^7 lost the ", e.netname, "\n");
 294         Send_KillNotification (p.netname, e.netname, "", INFO_LOSTFLAG, MSG_INFO);
 295
 296         if(penalty_receiver)
 297                 UpdateFrags(penalty_receiver, -ctf_score_value("penalty_suicidedrop"));
 298         else
 299                 UpdateFrags(p, -ctf_score_value("penalty_drop"));
 300         PlayerScore_Add(p, SP_CTF_DROPS, +1);
 301         ctf_captureshield_update(p, 0); // shield only
 302         e.playerid = attacker.playerid;
 303         e.ctf_droptime = time;
 304         WaypointSprite_Spawn("flagdropped", 0, 0, e, '0 0 1' * 61, world, COLOR_TEAM1 + COLOR_TEAM2 - e.team, e, waypointsprite_attachedforcarrier, FALSE);
 305
 306         if(p.waypointsprite_attachedforcarrier)
 307         {
 308                 WaypointSprite_Ping(p.waypointsprite_attachedforcarrier);
 309                 WaypointSprite_DetachCarrier(p);
 310         }
 311         else
 312         {
 313                 bprint("\{1}^1Flag carrier had no flag sprite?!?\n");
 314                 backtrace("Flag carrier had no flag sprite?!?");
 315         }
 316         LogCTF("dropped", p.team, p);
 317         sound (self, CHAN_TRIGGER, self.noise4, VOL_BASE, ATTN_NONE);
 318
 319         setattachment(e, world, "");
 320         e.damageforcescale = cvar("g_balance_ctf_damageforcescale");
 321         e.takedamage = DAMAGE_YES;
 322
 323         if (p.flagcarried == e)
 324                 p.flagcarried = world;
 325         e.owner = world;
 326
 327         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 328         e.solid = SOLID_TRIGGER;
 329         e.movetype = MOVETYPE_TOSS;
 330         // setsize(e, '-16 -16 0', '16 16 74');
 331         setorigin(e, p.origin - '0 0 24' + '0 0 37');
 332         e.cnt = FLAG_DROPPED;
 333         e.velocity = '0 0 300';
 334         e.pain_finished = time + cvar("g_ctf_flag_returntime");//30;
 335
 336         trace_startsolid = FALSE;
 337         tracebox(e.origin, e.mins, e.maxs, e.origin, TRUE, e);
 338         if(trace_startsolid)
 339                 dprint("FLAG FALLTHROUGH will happen SOON\n");
 340 };
 341
 342 void AnimateFlag()
 343 {
 344         if(self.delay > time)
 345                 return;
 346         self.delay = time + self.t_width;
 347         if(self.nextthink > self.delay)
 348                 self.nextthink = self.delay;
 349
 350         self.frame = self.frame + 1;
 351         if(self.frame > self.t_length)
 352                 self.frame = 0;
 353 }
 354
 355 void FlagThink()
 356 {
 357         local entity e;
 358
 359         self.nextthink = time + 0.1;
 360
 361         // sorry, we have to reset the flag size if it got squished by something
 362         if(self.mins != FLAG_MIN || self.maxs != FLAG_MAX)
 363         {
 364                 // if we can grow back, grow back
 365                 tracebox(self.origin, FLAG_MIN, FLAG_MAX, self.origin, MOVE_NOMONSTERS, self);
 366                 if(!trace_startsolid)
 367                         setsize(self, FLAG_MIN, FLAG_MAX);
 368         }
 369
 370         if(self == ctf_worldflaglist) // only for the first flag
 371         {
 372                 FOR_EACH_CLIENT(e)
 373                         ctf_captureshield_update(e, 1); // release shield only
 374         }
 375
 376         AnimateFlag();
 377
 378         if(self.speedrunning)
 379         if(self.cnt == FLAG_CARRY)
 380         {
 381                 if(self.owner)
 382                 if(flagcaptimerecord)
 383                 if(time >= self.flagpickuptime + flagcaptimerecord)
 384                 {
 385                         bprint("The ", self.netname, " became impatient after ", ftos_decimals(flagcaptimerecord, 2), " seconds and returned itself\n");
 386
 387                         sound (self, CHAN_TRIGGER, self.noise3, VOL_BASE, ATTN_NONE);
 388                         self.owner.impulse = 141; // returning!
 389
 390                         e = self;
 391                         self = self.owner;
 392                         ReturnFlag(e);
 393                         ImpulseCommands();
 394                         self = e;
 395                         return;
 396                 }
 397         }
 398
 399         if (self.cnt == FLAG_BASE)
 400                 return;
 401
 402         if (self.cnt == FLAG_DROPPED)
 403         {
 404                 // flag fallthrough? FIXME remove this if bug is really fixed now
 405                 if(self.origin_z < -131072)
 406                 {
 407                         dprint("FLAG FALLTHROUGH just happened\n");
 408                         self.pain_finished = 0;
 409                 }
 410                 setattachment(self, world, "");
 411                 if (time > self.pain_finished)
 412                 {
 413                         bprint("The ", self.netname, " has returned to base\n");
 414                         sound (self, CHAN_TRIGGER, self.noise3, VOL_BASE, ATTN_NONE);
 415                         LogCTF("returned", self.team, world);
 416                         ReturnFlag(self);
 417                 }
 418                 return;
 419         }
 420
 421         e = self.owner;
 422         if (e.classname != "player" || (e.deadflag) || (e.flagcarried != self))
 423         {
 424                 dprint("CANNOT HAPPEN - player dead and STILL had a flag!\n");
 425                 DropFlag(self, world, world);
 426                 return;
 427         }
 428
 429         if(cvar("g_ctf_allow_drop"))
 430         if(e.BUTTON_USE)
 431                 DropFlag(self, e, world);
 432 };
 433
 434 void flag_cap_ring_spawn(vector org)
 435 {
 436         shockwave_spawn("models/ctf/shockwavetransring.md3", org - '0 0 15', -0.8, 0, 1);
 437 };
 438
 439 void FlagTouch()
 440 {
 441         if(gameover) return;
 442
 443         local float t;
 444         local entity player;
 445         local string s, s0, h0, h1;
 446         if (other.classname != "player")
 447                 return;
 448         if (other.health < 1) // ignore dead players
 449                 return;
 450
 451         if (self.cnt == FLAG_CARRY)
 452                 return;
 453
 454         if (self.cnt == FLAG_BASE)
 455         if (other.team == self.team)
 456         if (other.flagcarried) // he's got a flag
 457         if (other.flagcarried.team != self.team) // capture
 458         {
 459                 if (other.flagcarried == world)
 460                 {
 461                         return;
 462                 }
 463                 if(cvar("g_ctf_captimerecord_always") || player_count - currentbots <= 1) // at most one human
 464                 {
 465                         t = time - other.flagcarried.flagpickuptime;
 466                         s = ftos_decimals(t, 2);
 467                         s0 = ftos_decimals(flagcaptimerecord, 2);
 468                         h0 = db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"));
 469                         h1 = other.netname;
 470                         if(h0 == h1)
 471                                 h0 = "their";
 472                         else
 473                                 h0 = strcat(h0, "^7's"); // h0: display text for previous netname
 474                         if (flagcaptimerecord == 0)
 475                         {
 476                                 s = strcat(" in ", s, " seconds");
 477                                 flagcaptimerecord = t;
 478                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 479                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 480                                 write_recordmarker(other, time - t, t);
 481                         }
 482                         else if (t < flagcaptimerecord)
 483                         {
 484                                 s = strcat(" in ", s, " seconds, breaking ", h0, " previous record of ", s0, " seconds");
 485                                 flagcaptimerecord = t;
 486                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 487                                 db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 488                                 write_recordmarker(other, time - t, t);
 489                         }
 490                         else
 491                         {
 492                                 s = strcat(" in ", s, " seconds, failing to break ", h0, " record of ", s0, " seconds");
 493                         }
 494                 }
 495                 else
 496                         s = "";
 497
 498                 Send_KillNotification (other.netname, other.flagcarried.netname, s, INFO_CAPTUREFLAG, MSG_INFO);
 499
 500                 PlayerTeamScore_Add(other, SP_CTF_CAPS, ST_CTF_CAPS, 1);
 501                 LogCTF("capture", other.flagcarried.team, other);
 502                 // give credit to the individual player
 503                 UpdateFrags(other, ctf_score_value("score_capture"));
 504
 505                 if (cvar("g_ctf_flag_capture_effects")) {
 506                         if (other.team == COLOR_TEAM1) { // red team scores effect
 507                                 pointparticles(particleeffectnum("red_ground_quake"), self.origin, '0 0 0', 1);
 508                                 flag_cap_ring_spawn(self.origin);
 509                         }
 510                         if (other.team == COLOR_TEAM2) { // blue team scores effect
 511                                 pointparticles(particleeffectnum("blue_ground_quake"), self.origin, '0 0 0', 1);
 512                                 flag_cap_ring_spawn(self.origin);
 513                         }
 514                 }
 515
 516                 sound (other, CHAN_AUTO, self.noise2, VOL_BASE, ATTN_NONE);
 517                 WaypointSprite_DetachCarrier(other);
 518                 if(self.speedrunning)
 519                         FakeTimeLimit(other, -1);
 520                 RegenFlag (other.flagcarried);
 521                 other.flagcarried = world;
 522                 other.next_take_time = time + 1;
 523         }
 524         if (self.cnt == FLAG_BASE)
 525         if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2) // only red and blue team can steal flags
 526         if (other.team != self.team)
 527         if (!other.flagcarried)
 528         if (!other.ctf_captureshielded)
 529         {
 530                 if (other.next_take_time > time)
 531                         return;
 532
 533                 if (cvar("g_ctf_flag_pickup_effects")) // pickup effect
 534                         pointparticles(particleeffectnum("smoke_ring"), 0.5 * (self.absmin + self.absmax), '0 0 0', 1);
 535
 536                 // pick up
 537                 self.flagpickuptime = time; // used for timing runs
 538                 self.speedrunning = other.speedrunning; // if speedrunning, flag will self-return and teleport the owner back after the record
 539                 if(other.speedrunning)
 540                 if(flagcaptimerecord)
 541                         FakeTimeLimit(other, time + flagcaptimerecord);
 542                 self.solid = SOLID_NOT;
 543                 setorigin(self, self.origin); // relink
 544                 self.owner = other;
 545                 other.flagcarried = self;
 546                 self.cnt = FLAG_CARRY;
 547                 self.angles = '0 0 0';
 548                 //bprint(other.netname, "^7 got the ", self.netname, "\n");
 549                 Send_KillNotification (other.netname, self.netname, "", INFO_GOTFLAG, MSG_INFO);
 550                 UpdateFrags(other, ctf_score_value("score_pickup_base"));
 551                 self.dropperid = other.playerid;
 552                 PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 553                 LogCTF("steal", self.team, other);
 554                 sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 555
 556                 FOR_EACH_PLAYER(player)
 557                         if(player.team == self.team)
 558                                 centerprint(player, "The enemy got your flag! Retrieve it!");
 559
 560                 self.movetype = MOVETYPE_NONE;
 561                 setorigin(self, FLAG_CARRY_POS);
 562                 setattachment(self, other, "");
 563                 WaypointSprite_AttachCarrier("flagcarrier", other);
 564                 WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 1 0');
 565                 WaypointSprite_Ping(self.sprite);
 566
 567                 return;
 568         }
 569
 570         if (self.cnt == FLAG_DROPPED)
 571         {
 572                 self.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 573                 if (other.team == self.team || (other.team != COLOR_TEAM1 && other.team != COLOR_TEAM2))
 574                 {
 575                         // return flag
 576                         Send_KillNotification (other.netname, self.netname, "", INFO_RETURNFLAG, MSG_INFO);
 577                         //bprint(other.netname, "^7 returned the ", self.netname, "\n");
 578
 579                         // punish the player who last had it
 580                         FOR_EACH_PLAYER(player)
 581                                 if(player.playerid == self.dropperid)
 582                                 {
 583                                         PlayerScore_Add(player, SP_SCORE, -ctf_score_value("penalty_returned"));
 584                                         ctf_captureshield_update(player, 0); // shield only
 585                                 }
 586
 587                         // punish the team who was last carrying it
 588                         if(self.team == COLOR_TEAM1)
 589                                 TeamScore_AddToTeam(COLOR_TEAM2, ST_SCORE, -ctf_score_value("penalty_returned"));
 590                         else
 591                                 TeamScore_AddToTeam(COLOR_TEAM1, ST_SCORE, -ctf_score_value("penalty_returned"));
 592
 593                         // reward the player who returned it
 594                         if(other.playerid == self.playerid) // is this the guy who killed the FC last?
 595                         {
 596                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 597                                         UpdateFrags(other, ctf_score_value("score_return_by_killer"));
 598                                 else
 599                                         UpdateFrags(other, ctf_score_value("score_return_rogue_by_killer"));
 600                         }
 601                         else
 602                         {
 603                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 604                                         UpdateFrags(other, ctf_score_value("score_return"));
 605                                 else
 606                                         UpdateFrags(other, ctf_score_value("score_return_rogue"));
 607                         }
 608                         PlayerScore_Add(other, SP_CTF_RETURNS, 1);
 609                         LogCTF("return", self.team, other);
 610                         sound (other, CHAN_AUTO, self.noise1, VOL_BASE, ATTN_NONE);
 611                         ReturnFlag(self);
 612                 }
 613                 else if (!other.flagcarried && (other.playerid != self.dropperid || time > self.ctf_droptime + cvar("g_balance_ctf_delay_collect")))
 614                 {
 615                         if(self.waypointsprite_attachedforcarrier)
 616                                 WaypointSprite_DetachCarrier(self);
 617
 618                         if (cvar("g_ctf_flag_pickup_effects")) // field pickup effect
 619                                 pointparticles(particleeffectnum("smoke_ring"), 0.5 * (self.absmin + self.absmax), '0 0 0', 1);
 620
 621                         // pick up
 622                         self.solid = SOLID_NOT;
 623                         setorigin(self, self.origin); // relink
 624                         self.owner = other;
 625                         other.flagcarried = self;
 626                         self.cnt = FLAG_CARRY;
 627                         Send_KillNotification (other.netname, self.netname, "", INFO_PICKUPFLAG, MSG_INFO);
 628                         //bprint(other.netname, "^7 picked up the ", self.netname, "\n");
 629
 630                         float f;
 631                         f = bound(0, (self.pain_finished - time) / cvar("g_ctf_flag_returntime"), 1);
 632                         //print("factor is ", ftos(f), "\n");
 633                         f = ctf_score_value("score_pickup_dropped_late") * (1-f)
 634                           + ctf_score_value("score_pickup_dropped_early") * f;
 635                         f = floor(f + 0.5);
 636                         self.dropperid = other.playerid;
 637                         //print("score is ", ftos(f), "\n");
 638
 639                         UpdateFrags(other, f);
 640                         PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 641                         LogCTF("pickup", self.team, other);
 642                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 643
 644                         FOR_EACH_PLAYER(player)
 645                                 if(player.team == self.team)
 646                                         centerprint(player, "The enemy got your flag! Retrieve it!");
 647
 648                         self.movetype = MOVETYPE_NONE;  // flag must have MOVETYPE_NONE here, otherwise it will drop through the floor...
 649                         setorigin(self, FLAG_CARRY_POS);
 650                         setattachment(self, other, "");
 651                         self.damageforcescale = 0;
 652                         self.takedamage = DAMAGE_NO;
 653                         WaypointSprite_AttachCarrier("flagcarrier", other);
 654                         WaypointSprite_UpdateTeamRadar(other.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, '1 1 0');
 655                 }
 656         }
 657 };
 658
 659 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 660 CTF Starting point for a player
 661 in team one (Red).
 662
 663 Keys:
 664 "angle"
 665  viewing angle when spawning
 666 */
 667 void spawnfunc_info_player_team1()
 668 {
 669         if(g_assault)
 670         {
 671                 remove(self);
 672                 return;
 673         }
 674         self.team = COLOR_TEAM1; // red
 675         spawnfunc_info_player_deathmatch();
 676 };
 677 //self.team = 4;self.classname = "info_player_start";spawnfunc_info_player_start();};
 678
 679 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 680 CTF Starting point for a player in
 681 team two (Blue).
 682
 683 Keys:
 684 "angle"
 685  viewing angle when spawning
 686 */
 687 void spawnfunc_info_player_team2()
 688 {
 689         if(g_assault)
 690         {
 691                 remove(self);
 692                 return;
 693         }
 694         self.team = COLOR_TEAM2; // blue
 695         spawnfunc_info_player_deathmatch();
 696 };
 697 //self.team = 13;self.classname = "info_player_start";spawnfunc_info_player_start();};
 698
 699 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 700 CTF Starting point for a player in
 701 team three (Yellow).
 702
 703 Keys:
 704 "angle"
 705  viewing angle when spawning
 706 */
 707 void spawnfunc_info_player_team3()
 708 {
 709         if(g_assault)
 710         {
 711                 remove(self);
 712                 return;
 713         }
 714         self.team = COLOR_TEAM3; // yellow
 715         spawnfunc_info_player_deathmatch();
 716 };
 717
 718
 719 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 720 CTF Starting point for a player in
 721 team four (Magenta).
 722
 723 Keys:
 724 "angle"
 725  viewing angle when spawning
 726 */
 727 void spawnfunc_info_player_team4()
 728 {
 729         if(g_assault)
 730         {
 731                 remove(self);
 732                 return;
 733         }
 734         self.team = COLOR_TEAM4; // purple
 735         spawnfunc_info_player_deathmatch();
 736 };
 737
 738 void item_flag_reset()
 739 {
 740         DropFlag(self, world, world);
 741         if(self.waypointsprite_attachedforcarrier)
 742                 WaypointSprite_DetachCarrier(self);
 743         ReturnFlag(self);
 744 }
 745
 746 void item_flag_postspawn()
 747 { // Check CTF Item Flag Post Spawn
 748
 749         // Flag Glow Trail Support
 750         if(cvar("g_ctf_flag_glowtrails"))
 751         { // Provide Flag Glow Trail
 752                 if(self.team == COLOR_TEAM1)
 753                         // Red
 754                         self.glow_color = 251;
 755                 else
 756                 if(self.team == COLOR_TEAM2)
 757                         // Blue
 758                         self.glow_color = 210;
 759
 760                 self.glow_size = 25;
 761                 self.glow_trail = 1;
 762         }
 763 };
 764
 765 /*QUAKED spawnfunc_item_flag_team1 (0 0.5 0.8) (-48 -48 -37) (48 48 37)
 766 CTF flag for team one (Red).
 767 Multiple are allowed.
 768
 769 Keys:
 770 "angle"
 771  Angle the flag will point
 772 (minus 90 degrees)
 773 "model"
 774  model to use, note this needs red and blue as skins 0 and 1
 775  (default models/ctf/flag.md3)
 776 "noise"
 777  sound played when flag is picked up
 778  (default ctf/take.wav)
 779 "noise1"
 780  sound played when flag is returned by a teammate
 781  (default ctf/return.wav)
 782 "noise2"
 783  sound played when flag is captured
 784  (default ctf/redcapture.wav)
 785 "noise3"
 786  sound played when flag is lost in the field and respawns itself
 787  (default ctf/respawn.wav)
 788 */
 789
 790 void spawnfunc_item_flag_team1()
 791 {
 792         if (!g_ctf)
 793         {
 794                 remove(self);
 795                 return;
 796         }
 797
 798         //if(!cvar("teamplay"))
 799         //      cvar_set("teamplay", "3");
 800
 801         // link flag into ctf_worldflaglist
 802         self.ctf_worldflagnext = ctf_worldflaglist;
 803         ctf_worldflaglist = self;
 804
 805         self.classname = "item_flag_team";
 806         if(g_ctf_reverse)
 807         {
 808                 self.team = COLOR_TEAM2; // color 13 team (blue)
 809                 self.items = IT_KEY1; // silver key (bluish enough)
 810         }
 811         else
 812         {
 813                 self.team = COLOR_TEAM1; // color 4 team (red)
 814                 self.items = IT_KEY2; // gold key (redish enough)
 815         }
 816         self.netname = "^1RED^7 flag";
 817         self.target = "###item###";
 818         self.skin = cvar("g_ctf_flag_red_skin");
 819         if(self.spawnflags & 1)
 820                 self.noalign = 1;
 821         if (!self.model)
 822                 self.model = cvar_string("g_ctf_flag_red_model");
 823         if (!self.noise)
 824                 self.noise = "ctf/red_taken.wav";
 825         if (!self.noise1)
 826                 self.noise1 = "ctf/red_returned.wav";
 827         if (!self.noise2)
 828                 self.noise2 = "ctf/red_capture.wav"; // blue team scores by capturing the red flag
 829         if (!self.noise3)
 830                 self.noise3 = "ctf/flag_respawn.wav";
 831         if (!self.noise4)
 832                 self.noise4 = "ctf/red_dropped.wav";
 833         precache_model (self.model);
 834         setmodel (self, self.model); // precision set below
 835         precache_sound (self.noise);
 836         precache_sound (self.noise1);
 837         precache_sound (self.noise2);
 838         precache_sound (self.noise3);
 839         precache_sound (self.noise4);
 840         //setsize(self, '-16 -16 -37', '16 16 37');
 841         setsize(self, FLAG_MIN, FLAG_MAX);
 842         setorigin(self, self.origin + '0 0 37');
 843         self.nextthink = time + 0.2; // start after doors etc
 844         self.think = place_flag;
 845
 846         if(!self.scale)
 847                 self.scale = 0.6;
 848         //if(!self.glow_size)
 849         //      self.glow_size = 50;
 850
 851         self.effects = self.effects | EF_LOWPRECISION;
 852         if(cvar("g_ctf_fullbrightflags"))
 853                 self.effects |= EF_FULLBRIGHT;
 854         if(cvar("g_ctf_dynamiclights"))
 855                 self.effects |= EF_RED;
 856
 857         // From Spidflisk
 858         item_flag_postspawn();
 859
 860         precache_model("models/ctf/shield.md3");
 861         precache_model("models/ctf/shockwavetransring.md3");
 862
 863         self.reset = item_flag_reset;
 864 };
 865
 866 /*QUAKED spawnfunc_item_flag_team2 (0 0.5 0.8) (-48 -48 -24) (48 48 64)
 867 CTF flag for team two (Blue).
 868 Multiple are allowed.
 869
 870 Keys:
 871 "angle"
 872  Angle the flag will point
 873 (minus 90 degrees)
 874 "model"
 875  model to use, note this needs red and blue as skins 0 and 1
 876  (default models/ctf/flag.md3)
 877 "noise"
 878  sound played when flag is picked up
 879  (default ctf/take.wav)
 880 "noise1"
 881  sound played when flag is returned by a teammate
 882  (default ctf/return.wav)
 883 "noise2"
 884  sound played when flag is captured
 885  (default ctf/bluecapture.wav)
 886 "noise3"
 887  sound played when flag is lost in the field and respawns itself
 888  (default ctf/respawn.wav)
 889 */
 890
 891 void spawnfunc_item_flag_team2()
 892 {
 893         if (!g_ctf)
 894         {
 895                 remove(self);
 896                 return;
 897         }
 898         //if(!cvar("teamplay"))
 899         //      cvar_set("teamplay", "3");
 900
 901         // link flag into ctf_worldflaglist
 902         self.ctf_worldflagnext = ctf_worldflaglist;
 903         ctf_worldflaglist = self;
 904
 905         self.classname = "item_flag_team";
 906         if(g_ctf_reverse)
 907         {
 908                 self.team = COLOR_TEAM1; // color 4 team (red)
 909                 self.items = IT_KEY2; // gold key (redish enough)
 910         }
 911         else
 912         {
 913                 self.team = COLOR_TEAM2; // color 13 team (blue)
 914                 self.items = IT_KEY1; // silver key (bluish enough)
 915         }
 916         self.netname = "^4BLUE^7 flag";
 917         self.target = "###item###";
 918         self.skin = cvar("g_ctf_flag_blue_skin");
 919         if(self.spawnflags & 1)
 920                 self.noalign = 1;
 921         if (!self.model)
 922                 self.model = cvar_string("g_ctf_flag_blue_model");
 923         if (!self.noise)
 924                 self.noise = "ctf/blue_taken.wav";
 925         if (!self.noise1)
 926                 self.noise1 = "ctf/blue_returned.wav";
 927         if (!self.noise2)
 928                 self.noise2 = "ctf/blue_capture.wav"; // blue team scores by capturing the red flag
 929         if (!self.noise3)
 930                 self.noise3 = "ctf/flag_respawn.wav";
 931         if (!self.noise4)
 932                 self.noise4 = "ctf/blue_dropped.wav";
 933         precache_model (self.model);
 934         setmodel (self, self.model); // precision set below
 935         precache_sound (self.noise);
 936         precache_sound (self.noise1);
 937         precache_sound (self.noise2);
 938         precache_sound (self.noise3);
 939         precache_sound (self.noise4);
 940         //setsize(self, '-16 -16 -37', '16 16 37');
 941         setsize(self, FLAG_MIN, FLAG_MAX);
 942         setorigin(self, self.origin + '0 0 37');
 943         self.nextthink = time + 0.2; // start after doors etc
 944         self.think = place_flag;
 945
 946         if(!self.scale)
 947                 self.scale = 0.6;
 948         //if(!self.glow_size)
 949         //      self.glow_size = 50;
 950
 951         self.effects = self.effects | EF_LOWPRECISION;
 952         if(cvar("g_ctf_fullbrightflags"))
 953                 self.effects |= EF_FULLBRIGHT;
 954         if(cvar("g_ctf_dynamiclights"))
 955                 self.effects |= EF_BLUE;
 956
 957         // From Spidflisk
 958         item_flag_postspawn();
 959
 960         precache_model("models/ctf/shield.md3");
 961         precache_model("models/ctf/shockwavetransring.md3");
 962
 963         self.reset = item_flag_reset;
 964 };
 965
 966
 967 /*QUAKED spawnfunc_ctf_team (0 .5 .8) (-16 -16 -24) (16 16 32)
 968 Team declaration for CTF gameplay, this allows you to decide what team
 969 names and control point models are used in your map.
 970
 971 Note: If you use spawnfunc_ctf_team entities you must define at least 2!  However, unlike
 972 domination, you don't need to make a blank one too.
 973
 974 Keys:
 975 "netname"
 976  Name of the team (for example Red, Blue, Green, Yellow, Life, Death, Offense, Defense, etc)
 977 "cnt"
 978  Scoreboard color of the team (for example 4 is red and 13 is blue)
 979
 980 */
 981
 982 void spawnfunc_ctf_team()
 983 {
 984         if (!g_ctf)
 985         {
 986                 remove(self);
 987                 return;
 988         }
 989         self.classname = "ctf_team";
 990         self.team = self.cnt + 1;
 991 };
 992
 993 // code from here on is just to support maps that don't have control point and team entities
 994 void ctf_spawnteam (string teamname, float teamcolor)
 995 {
 996         local entity oldself;
 997         oldself = self;
 998         self = spawn();
 999         self.classname = "ctf_team";
1000         self.netname = teamname;
1001         self.cnt = teamcolor;
1002
1003         spawnfunc_ctf_team();
1004
1005         self = oldself;
1006 };
1007
1008 // spawn some default teams if the map is not set up for ctf
1009 void ctf_spawnteams()
1010 {
1011         float numteams;
1012
1013         numteams = 2;//cvar("g_ctf_default_teams");
1014
1015         ctf_spawnteam("Red", COLOR_TEAM1 - 1);
1016         ctf_spawnteam("Blue", COLOR_TEAM2 - 1);
1017 };
1018
1019 void ctf_delayedinit()
1020 {
1021         // if no teams are found, spawn defaults
1022         if (find(world, classname, "ctf_team") == world)
1023                 ctf_spawnteams();
1024
1025         ScoreRules_ctf();
1026 };
1027
1028 void ctf_init()
1029 {
1030         InitializeEntity(world, ctf_delayedinit, INITPRIO_GAMETYPE);
1031         flagcaptimerecord = stof(db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time")));
1032
1033         captureshield_min_negscore = cvar("g_ctf_shield_min_negscore");
1034         captureshield_max_ratio = cvar("g_ctf_shield_max_ratio");
1035         captureshield_force = cvar("g_ctf_shield_force");
1036 };
1037
1038 void ctf_setstatus2(entity flag, float shift)
1039 {
1040         if (flag.cnt == FLAG_CARRY)
1041                 if (flag.owner == self)
1042                         self.items |= shift * 3;
1043                 else
1044                         self.items |= shift * 1;
1045         else if (flag.cnt == FLAG_DROPPED)
1046                 self.items |= shift * 2;
1047         else
1048         {
1049                 // no status bits
1050         }
1051 };
1052
1053 void ctf_setstatus()
1054 {
1055         self.items &~= IT_RED_FLAG_TAKEN;
1056         self.items &~= IT_RED_FLAG_LOST;
1057         self.items &~= IT_BLUE_FLAG_TAKEN;
1058         self.items &~= IT_BLUE_FLAG_LOST;
1059         self.items &~= IT_CTF_SHIELDED;
1060
1061         local entity flag;
1062         float redflags, blueflags;
1063
1064         if(self.ctf_captureshielded)
1065                 self.items |= IT_CTF_SHIELDED;
1066
1067         redflags = 0;
1068         blueflags = 0;
1069
1070         for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
1071         {
1072                 if(flag.items & IT_KEY2) // blue
1073                         ++redflags;
1074                 else if(flag.items & IT_KEY1) // red
1075                         ++blueflags;
1076         }
1077
1078         // blinking magic: if there is more than one flag, show one of these in a clever way
1079         if(redflags)
1080                 redflags = mod(floor(time * redflags * 0.75), redflags);
1081         if(blueflags)
1082                 blueflags = mod(floor(time * blueflags * 0.75), blueflags);
1083
1084         for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
1085         {
1086                 if(flag.items & IT_KEY2) // blue
1087                 {
1088                         if(--redflags == -1) // happens exactly once (redflags is in 0..count-1, and will --'ed count times)
1089                                 ctf_setstatus2(flag, IT_RED_FLAG_TAKEN);
1090                 }
1091                 else if(flag.items & IT_KEY1) // red
1092                 {
1093                         if(--blueflags == -1) // happens exactly once
1094                                 ctf_setstatus2(flag, IT_BLUE_FLAG_TAKEN);
1095                 }
1096         }
1097 };
1098 /*
1099 entity(float cteam) ctf_team_has_commander =
1100 {
1101         entity pl;
1102         if(cteam != COLOR_TEAM1 || cteam != COLOR_TEAM2)
1103                 return world;
1104
1105         FOR_EACH_REALPLAYER(pl) {
1106                 if(pl.team == cteam && pl.iscommander) {
1107                         return pl;
1108                 }
1109         }
1110         return world;
1111 };
1112
1113 void(entity e, float st) ctf_setstate =
1114 {
1115         e.ctf_state = st;
1116         ++e.version;
1117 };
1118
1119 void(float cteam) ctf_new_commander =
1120 {
1121         entity pl, plmax;
1122
1123         plmax = world;
1124         FOR_EACH_REALPLAYER(pl) {
1125                 if(pl.team == cteam) {
1126                         if(pl.iscommander) { // don't reassign if alreay there
1127                                 return;
1128                         }
1129                         if(plmax == world || plmax.frags < pl.frags) <<<<<<<<<<<<<<<<< BROKEN in new scoring system
1130                                 plmax = pl;
1131                 }
1132         }
1133         if(plmax == world) {
1134                 bprint(strcat(ColoredTeamName(cteam), " Team has no Commander!\n"));
1135                 return;
1136         }
1137
1138         plmax.iscommander = TRUE;
1139         ctf_setstate(plmax, 3);
1140         sprint(plmax, "^3You're the commander now!\n");
1141         centerprint(plmax, "^3You're the commander now!\n");
1142 };
1143
1144 void() ctf_clientconnect =
1145 {
1146         self.iscommander = FALSE;
1147
1148         if(!self.team || self.classname != "player") {
1149                 ctf_setstate(self, -1);
1150         } else
1151                 ctf_setstate(self, 0);
1152
1153         self.team_saved = self.team;
1154
1155         if(self.team != 0 && self.classname == "player" && !ctf_team_has_commander(self.team)) {
1156                 ctf_new_commander(self.team);
1157         }
1158 };
1159
1160 void() ctf_playerchanged =
1161 {
1162         if(!self.team || self.classname != "player") {
1163                 ctf_setstate(self, -1);
1164         } else if(self.ctf_state < 0 && self.classname == "player") {
1165                 ctf_setstate(self, 0);
1166         }
1167
1168         if(self.iscommander &&
1169            (self.classname != "player" || self.team != self.team_saved)
1170                 )
1171         {
1172                 self.iscommander = FALSE;
1173                 if(self.classname == "player")
1174                         ctf_setstate(self, 0);
1175                 else
1176                         ctf_setstate(self, -1);
1177                 ctf_new_commander(self.team_saved);
1178         }
1179
1180         self.team_saved = self.team;
1181
1182         ctf_new_commander(self.team);
1183 };
1184
1185 void() ctf_clientdisconnect =
1186 {
1187         if(self.iscommander)
1188         {
1189                 ctf_new_commander(self.team);
1190         }
1191 };
1192
1193 entity GetPlayer(string);
1194 float() ctf_clientcommand =
1195 {
1196         entity e;
1197         if(argv(0) == "order") {
1198                 if(!g_ctf) {
1199                         sprint(self, "This command is not supported in this gamemode.\n");
1200                         return TRUE;
1201                 }
1202                 if(!self.iscommander) {
1203                         sprint(self, "^1You are not the commander!\n");
1204                         return TRUE;
1205                 }
1206                 if(argv(2) == "") {
1207                         sprint(self, "Usage: order #player status   - (playernumber as in status)\n");
1208                         return TRUE;
1209                 }
1210                 e = GetPlayer(argv(1));
1211                 if(e == world) {
1212                         sprint(self, "Invalid player.\nUsage: order #player status   - (playernumber as in status)\n");
1213                         return TRUE;
1214                 }
1215                 if(e.team != self.team) {
1216                         sprint(self, "^3You can only give orders to your own team!\n");
1217                         return TRUE;
1218                 }
1219                 if(argv(2) == "attack") {
1220                         sprint(self, strcat("Ordering ", e.netname, " to attack!\n"));
1221                         sprint(e, "^1Attack!\n");
1222                         centerprint(e, "^7You've been ordered to^9\n^1Attack!\n");
1223                         ctf_setstate(e, 1);
1224                 } else if(argv(2) == "defend") {
1225                         sprint(self, strcat("Ordering ", e.netname, " to defend!\n"));
1226                         sprint(e, "^Defend!\n");
1227                         centerprint(e, "^7You've been ordered to^9\n^2Defend!\n");
1228                         ctf_setstate(e, 2);
1229                 } else {
1230                         sprint(self, "^7Invalid command, use ^3attack^7, or ^3defend^7.\n");
1231                 }
1232                 return TRUE;
1233         }
1234         return FALSE;
1235 };
1236 */