qcsrc/server/func_breakable.qc

   1 #include "_all.qh"
   2
   3 #include "g_subs.qh"
   4 #include "waypointsprites.qh"
   5 #include "g_damage.qh"
   6 #include "bot/bot.qh"
   7 #include "../common/csqcmodel_settings.qh"
   8 #include "../csqcmodellib/sv_model.qh"
   9 #include "weapons/common.qh"
  10
  11 .entity sprite;
  12
  13 .float dmg;
  14 .float dmg_edge;
  15 .float dmg_radius;
  16 .float dmg_force;
  17 .float debrismovetype;
  18 .float debrissolid;
  19 .vector debrisvelocity;
  20 .vector debrisvelocityjitter;
  21 .vector debrisavelocityjitter;
  22 .float debristime;
  23 .float debristimejitter;
  24 .float debrisfadetime;
  25 .float debrisdamageforcescale;
  26 .float debrisskin;
  27
  28 .string mdl_dead; // or "" to hide when broken
  29 .string debris; // space separated list of debris models
  30 // other fields:
  31 //   mdl = particle effect name
  32 //   count = particle effect multiplier
  33 //   targetname = target to trigger to unbreak the model
  34 //   target = targets to trigger when broken
  35 //   health = amount of damage it can take
  36 //   spawnflags:
  37 //     1 = start disabled (needs to be triggered to activate)
  38 //     2 = indicate damage
  39 // notes:
  40 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  41 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  42 //   want that!
  43
  44 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  45
  46 //
  47 // func_breakable
  48 // - basically func_assault_destructible for general gameplay use
  49 //
  50 void LaunchDebris (string debrisname, vector force)
  51 {
  52         entity dbr = spawn();
  53         setorigin(dbr, self.absmin
  54                    + '1 0 0' * random() * (self.absmax.x - self.absmin.x)
  55                    + '0 1 0' * random() * (self.absmax.y - self.absmin.y)
  56                    + '0 0 1' * random() * (self.absmax.z - self.absmin.z));
  57         setmodel (dbr, debrisname );
  58         dbr.skin = self.debrisskin;
  59         dbr.colormap = self.colormap; // inherit team colors
  60         dbr.owner = self; // do not be affected by our own explosion
  61         dbr.movetype = self.debrismovetype;
  62         dbr.solid = self.debrissolid;
  63         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  64                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  65         dbr.velocity_x = self.debrisvelocity.x + self.debrisvelocityjitter.x * crandom();
  66         dbr.velocity_y = self.debrisvelocity.y + self.debrisvelocityjitter.y * crandom();
  67         dbr.velocity_z = self.debrisvelocity.z + self.debrisvelocityjitter.z * crandom();
  68         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  69         dbr.avelocity_x = random()*self.debrisavelocityjitter.x;
  70         dbr.avelocity_y = random()*self.debrisavelocityjitter.y;
  71         dbr.avelocity_z = random()*self.debrisavelocityjitter.z;
  72         dbr.damageforcescale = self.debrisdamageforcescale;
  73         if(dbr.damageforcescale)
  74                 dbr.takedamage = DAMAGE_YES;
  75         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  76 }
  77
  78 void func_breakable_colormod()
  79 {
  80         float h;
  81         if (!(self.spawnflags & 2))
  82                 return;
  83         h = self.health / self.max_health;
  84         if(h < 0.25)
  85                 self.colormod = '1 0 0';
  86         else if(h <= 0.75)
  87                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  88         else
  89                 self.colormod = '1 1 1';
  90
  91         CSQCMODEL_AUTOUPDATE();
  92 }
  93
  94 void func_breakable_look_destroyed()
  95 {
  96         float floorZ;
  97
  98         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
  99                 self.dropped_origin = self.origin;
 100
 101         if(self.mdl_dead == "")
 102                 self.effects |= EF_NODRAW;
 103         else {
 104                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
 105                         floorZ = self.absmin.z;
 106                         setorigin(self,((self.absmax+self.absmin)*.5));
 107                         self.origin_z = floorZ;
 108                 }
 109                 setmodel(self, self.mdl_dead);
 110                 self.effects &= ~EF_NODRAW;
 111         }
 112
 113         CSQCMODEL_AUTOUPDATE();
 114
 115         self.solid = SOLID_NOT;
 116 }
 117
 118 void func_breakable_look_restore()
 119 {
 120         setmodel(self, self.mdl);
 121         self.effects &= ~EF_NODRAW;
 122
 123         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 124                 setorigin(self, self.dropped_origin);
 125
 126         CSQCMODEL_AUTOUPDATE();
 127
 128         self.solid = SOLID_BSP;
 129 }
 130
 131 void func_breakable_behave_destroyed()
 132 {
 133         self.health = self.max_health;
 134         self.takedamage = DAMAGE_NO;
 135         self.bot_attack = false;
 136         self.event_damage = func_null;
 137         self.state = 1;
 138         func_breakable_colormod();
 139         if (self.noise1)
 140                 stopsound (self, CH_TRIGGER_SINGLE);
 141 }
 142
 143 void func_breakable_behave_restore()
 144 {
 145         self.health = self.max_health;
 146         if(self.sprite)
 147         {
 148                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 149                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 150         }
 151         self.takedamage = DAMAGE_AIM;
 152         self.bot_attack = true;
 153         self.event_damage = func_breakable_damage;
 154         self.state = 0;
 155         self.nextthink = 0; // cancel auto respawn
 156         func_breakable_colormod();
 157         if (self.noise1)
 158                 sound (self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 159 }
 160
 161 void func_breakable_init_for_player(entity player)
 162 {
 163         if (self.noise1 && self.state == 0 && clienttype(player) == CLIENTTYPE_REAL)
 164         {
 165                 msg_entity = player;
 166                 soundto (MSG_ONE, self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 167         }
 168 }
 169
 170 void func_breakable_destroyed()
 171 {
 172         func_breakable_look_destroyed();
 173         func_breakable_behave_destroyed();
 174
 175         CSQCMODEL_AUTOUPDATE();
 176 }
 177
 178 void func_breakable_restore()
 179 {
 180         func_breakable_look_restore();
 181         func_breakable_behave_restore();
 182
 183         CSQCMODEL_AUTOUPDATE();
 184 }
 185
 186 vector debrisforce; // global, set before calling this
 187 void func_breakable_destroy() {
 188         float n, i;
 189         string oldmsg;
 190
 191         activator = self.owner;
 192         self.owner = world; // set by W_PrepareExplosionByDamage
 193
 194         // now throw around the debris
 195         n = tokenize_console(self.debris);
 196         for(i = 0; i < n; ++i)
 197                 LaunchDebris(argv(i), debrisforce);
 198
 199         func_breakable_destroyed();
 200
 201         if(self.noise)
 202                 sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 203
 204         if(self.dmg)
 205                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, world, self.dmg_force, DEATH_HURTTRIGGER, world);
 206
 207         if(self.cnt)
 208                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 209
 210         if(self.respawntime)
 211         {
 212                 self.think = func_breakable_restore;
 213                 self.nextthink = time + self.respawntime + crandom() * self.respawntimejitter;
 214         }
 215
 216         oldmsg = self.message;
 217         self.message = "";
 218         SUB_UseTargets();
 219         self.message = oldmsg;
 220 }
 221
 222 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 223 {
 224         if(self.state == 1)
 225                 return;
 226         if(self.spawnflags & DOOR_NOSPLASH)
 227                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 228                         return;
 229         if(self.team)
 230                 if(attacker.team == self.team)
 231                         return;
 232         self.health = self.health - damage;
 233         if(self.sprite)
 234         {
 235                 WaypointSprite_Ping(self.sprite);
 236                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 237         }
 238         func_breakable_colormod();
 239
 240         if(self.health <= 0)
 241         {
 242                 debrisforce = force;
 243                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 244         }
 245 }
 246
 247 void func_breakable_reset()
 248 {
 249         self.team = self.team_saved;
 250         func_breakable_look_restore();
 251         if(self.spawnflags & 1)
 252                 func_breakable_behave_destroyed();
 253         else
 254                 func_breakable_behave_restore();
 255
 256         CSQCMODEL_AUTOUPDATE();
 257 }
 258
 259 // destructible walls that can be used to trigger target_objective_decrease
 260 void spawnfunc_func_breakable() {
 261         float n, i;
 262         if(!self.health)
 263                 self.health = 100;
 264         self.max_health = self.health;
 265
 266         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 267         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 268         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 269         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 270         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 271         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 272         if(!self.debristime) self.debristime = 3.5;
 273         if(!self.debristimejitter) self.debristime = 2.5;
 274
 275         if(self.mdl != "")
 276                 self.cnt = particleeffectnum(self.mdl);
 277         if(self.count == 0)
 278                 self.count = 1;
 279
 280         if(self.message == "")
 281                 self.message = "got too close to an explosion";
 282         if(self.message2 == "")
 283                 self.message2 = "was pushed into an explosion by";
 284         if(!self.dmg_radius)
 285                 self.dmg_radius = 150;
 286         if(!self.dmg_force)
 287                 self.dmg_force = 200;
 288
 289         self.mdl = self.model;
 290         SetBrushEntityModel();
 291
 292         self.use = func_breakable_restore;
 293
 294         // precache all the models
 295         if (self.mdl_dead)
 296                 precache_model(self.mdl_dead);
 297         n = tokenize_console(self.debris);
 298         for(i = 0; i < n; ++i)
 299                 precache_model(argv(i));
 300         if(self.noise)
 301                 precache_sound(self.noise);
 302         if(self.noise1)
 303                 precache_sound(self.noise1);
 304
 305         self.team_saved = self.team;
 306         self.dropped_origin = self.origin;
 307
 308         self.reset = func_breakable_reset;
 309         func_breakable_reset();
 310
 311         self.init_for_player_needed = 1;
 312         self.init_for_player = func_breakable_init_for_player;
 313
 314         CSQCMODEL_AUTOINIT();
 315 }
 316
 317 // for use in maps with a "model" key set
 318 void spawnfunc_misc_breakablemodel() {
 319         spawnfunc_func_breakable();
 320 }