qcsrc/server/func_breakable.qc

   1 .entity sprite;
   2
   3 .float dmg;
   4 .float dmg_edge;
   5 .float dmg_radius;
   6 .float dmg_force;
   7 .float debrismovetype;
   8 .float debrissolid;
   9 .vector debrisvelocity;
  10 .vector debrisvelocityjitter;
  11 .vector debrisavelocityjitter;
  12 .float debristime;
  13 .float debristimejitter;
  14 .float debrisfadetime;
  15 .float debrisdamageforcescale;
  16 .float debrisskin;
  17
  18 .string mdl_dead; // or "" to hide when broken
  19 .string debris; // space separated list of debris models
  20 // other fields:
  21 //   mdl = particle effect name
  22 //   count = particle effect multiplier
  23 //   targetname = target to trigger to unbreak the model
  24 //   target = targets to trigger when broken
  25 //   health = amount of damage it can take
  26 //   spawnflags:
  27 //     1 = start disabled (needs to be triggered to activate)
  28 //     2 = indicate damage
  29 // notes:
  30 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  31 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  32 //   want that!
  33
  34 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  35
  36 //
  37 // func_breakable
  38 // - basically func_assault_destructible for general gameplay use
  39 //
  40 void LaunchDebris (string debrisname, vector force)
  41 {
  42         entity dbr = spawn();
  43         setorigin(dbr, self.absmin
  44                    + '1 0 0' * random() * (self.absmax_x - self.absmin_x)
  45                    + '0 1 0' * random() * (self.absmax_y - self.absmin_y)
  46                    + '0 0 1' * random() * (self.absmax_z - self.absmin_z));
  47         setmodel (dbr, debrisname );
  48         dbr.skin = self.debrisskin;
  49         dbr.colormap = self.colormap; // inherit team colors
  50         dbr.owner = self; // do not be affected by our own explosion
  51         dbr.movetype = self.debrismovetype;
  52         dbr.solid = self.debrissolid;
  53         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  54                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  55         dbr.velocity_x = self.debrisvelocity_x + self.debrisvelocityjitter_x * crandom();
  56         dbr.velocity_y = self.debrisvelocity_y + self.debrisvelocityjitter_y * crandom();
  57         dbr.velocity_z = self.debrisvelocity_z + self.debrisvelocityjitter_z * crandom();
  58         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  59         dbr.avelocity_x = random()*self.debrisavelocityjitter_x;
  60         dbr.avelocity_y = random()*self.debrisavelocityjitter_y;
  61         dbr.avelocity_z = random()*self.debrisavelocityjitter_z;
  62         dbr.damageforcescale = self.debrisdamageforcescale;
  63         if(dbr.damageforcescale)
  64                 dbr.takedamage = DAMAGE_YES;
  65         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  66 }
  67
  68 void func_breakable_colormod()
  69 {
  70         float h;
  71         if (!(self.spawnflags & 2))
  72                 return;
  73         h = self.health / self.max_health;
  74         if(h < 0.25)
  75                 self.colormod = '1 0 0';
  76         else if(h <= 0.75)
  77                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  78         else
  79                 self.colormod = '1 1 1';
  80
  81         CSQCMODEL_AUTOUPDATE();
  82 }
  83
  84 void func_breakable_look_destroyed()
  85 {
  86         float floor_z;
  87
  88         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
  89                 self.dropped_origin = self.origin;
  90
  91         if(self.mdl_dead == "")
  92                 self.model = "";
  93         else {
  94                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
  95                         floor_z = self.absmin_z;
  96                         setorigin(self,((self.absmax+self.absmin)*.5));
  97                         self.origin_z = floor_z;
  98                 }
  99                 setmodel(self, self.mdl_dead);
 100         }
 101
 102         self.solid = SOLID_NOT;
 103 }
 104
 105 void func_breakable_look_restore()
 106 {
 107         setmodel(self, self.mdl);
 108         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 109                 setorigin(self, self.dropped_origin);
 110         self.solid = SOLID_BSP;
 111 }
 112
 113 void func_breakable_behave_destroyed()
 114 {
 115         self.health = self.max_health;
 116         self.takedamage = DAMAGE_NO;
 117         self.bot_attack = FALSE;
 118         self.event_damage = func_null;
 119         self.state = 1;
 120         func_breakable_colormod();
 121 }
 122
 123 void func_breakable_behave_restore()
 124 {
 125         self.health = self.max_health;
 126         if(self.sprite)
 127         {
 128                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 129                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 130         }
 131         self.takedamage = DAMAGE_AIM;
 132         self.bot_attack = TRUE;
 133         self.event_damage = func_breakable_damage;
 134         self.state = 0;
 135         self.nextthink = 0; // cancel auto respawn
 136         func_breakable_colormod();
 137 }
 138
 139 void func_breakable_destroyed()
 140 {
 141         func_breakable_look_destroyed();
 142         func_breakable_behave_destroyed();
 143
 144         CSQCMODEL_AUTOUPDATE();
 145 }
 146
 147 void func_breakable_restore()
 148 {
 149         func_breakable_look_restore();
 150         func_breakable_behave_restore();
 151
 152         CSQCMODEL_AUTOUPDATE();
 153 }
 154
 155 vector debrisforce; // global, set before calling this
 156 void func_breakable_destroy() {
 157         float n, i;
 158         string oldmsg;
 159
 160         activator = self.owner;
 161         self.owner = world; // set by W_PrepareExplosionByDamage
 162
 163         // now throw around the debris
 164         n = tokenize_console(self.debris);
 165         for(i = 0; i < n; ++i)
 166                 LaunchDebris(argv(i), debrisforce);
 167
 168         func_breakable_destroyed();
 169
 170         if(self.noise)
 171                 sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 172
 173         if(self.dmg)
 174                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, world, self.dmg_force, DEATH_HURTTRIGGER, world);
 175
 176         if(self.cnt)
 177                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 178
 179         if(self.respawntime)
 180         {
 181                 self.think = func_breakable_restore;
 182                 self.nextthink = time + self.respawntime + crandom() * self.respawntimejitter;
 183         }
 184
 185         oldmsg = self.message;
 186         self.message = "";
 187         SUB_UseTargets();
 188         self.message = oldmsg;
 189 }
 190
 191 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 192 {
 193         if(self.state == 1)
 194                 return;
 195         if(self.spawnflags & DOOR_NOSPLASH)
 196                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 197                         return;
 198         if(self.team)
 199                 if(attacker.team == self.team)
 200                         return;
 201         self.health = self.health - damage;
 202         if(self.sprite)
 203         {
 204                 WaypointSprite_Ping(self.sprite);
 205                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 206         }
 207         func_breakable_colormod();
 208
 209         if(self.health <= 0)
 210         {
 211                 debrisforce = force;
 212                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 213         }
 214 }
 215
 216 void func_breakable_reset()
 217 {
 218         self.team = self.team_saved;
 219         func_breakable_look_restore();
 220         if(self.spawnflags & 1)
 221                 func_breakable_behave_destroyed();
 222         else
 223                 func_breakable_behave_restore();
 224
 225         CSQCMODEL_AUTOUPDATE();
 226 }
 227
 228 // destructible walls that can be used to trigger target_objective_decrease
 229 void spawnfunc_func_breakable() {
 230         float n, i;
 231         if(!self.health)
 232                 self.health = 100;
 233         self.max_health = self.health;
 234
 235         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 236         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 237         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 238         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 239         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 240         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 241         if(!self.debristime) self.debristime = 3.5;
 242         if(!self.debristimejitter) self.debristime = 2.5;
 243
 244         if(self.mdl != "")
 245                 self.cnt = particleeffectnum(self.mdl);
 246         if(self.count == 0)
 247                 self.count = 1;
 248
 249         if(self.message == "")
 250                 self.message = "got too close to an explosion";
 251         if(self.message2 == "")
 252                 self.message2 = "was pushed into an explosion by";
 253         if(!self.dmg_radius)
 254                 self.dmg_radius = 150;
 255         if(!self.dmg_force)
 256                 self.dmg_force = 200;
 257
 258         self.mdl = self.model;
 259         SetBrushEntityModel();
 260
 261         self.use = func_breakable_restore;
 262
 263         // precache all the models
 264         if (self.mdl_dead)
 265                 precache_model(self.mdl_dead);
 266         n = tokenize_console(self.debris);
 267         for(i = 0; i < n; ++i)
 268                 precache_model(argv(i));
 269         if(self.noise)
 270                 precache_sound(self.noise);
 271
 272         self.team_saved = self.team;
 273         self.dropped_origin = self.origin;
 274
 275         self.reset = func_breakable_reset;
 276         func_breakable_reset();
 277
 278         CSQCMODEL_AUTOINIT();
 279 }
 280
 281 // for use in maps with a "model" key set
 282 void spawnfunc_misc_breakablemodel() {
 283         spawnfunc_func_breakable();
 284 }