qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", ftos(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 312 {
 313         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 314         WriteByte(MSG_ALL, TE_CSQC_KILLNOTIFY);
 315         WriteString(MSG_ALL, s1);
 316         WriteString(MSG_ALL, s2);
 317         WriteString(MSG_ALL, s3);
 318         WriteShort(MSG_ALL, msg);
 319         WriteByte(MSG_ALL, type);
 320 }
 321
 322 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 323 void Send_CSQC_KillCenterprint(entity e, string s1, string s2, float msg, float type)
 324 {
 325         if (clienttype(e) == CLIENTTYPE_REAL)
 326         {
 327                 msg_entity = e;
 328                 WRITESPECTATABLE_MSG_ONE({
 329                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 330                         WriteByte(MSG_ONE, TE_CSQC_KILLCENTERPRINT);
 331                         WriteString(MSG_ONE, s1);
 332                         WriteString(MSG_ONE, s2);
 333                         WriteShort(MSG_ONE, msg);
 334                         WriteByte(MSG_ONE, type);
 335                 });
 336         }
 337 }
 338
 339 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 340 {
 341         string  s, a, msg;
 342         float w, type;
 343
 344         if (targ.classname == "player")
 345         {
 346                 s = targ.netname;
 347                 a = attacker.netname;
 348
 349                 if (targ == attacker) // suicides
 350                 {
 351                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 352                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 353                         else
 354                                 msg = "";
 355             if(!g_cts) // no "killed your own dumb self" message in CTS
 356                 Send_CSQC_KillCenterprint(targ, msg, "", deathtype, MSG_SUICIDE);
 357
 358                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 359                         {
 360                                 LogDeath("suicide", deathtype, targ, targ);
 361                                 GiveFrags(attacker, targ, -1, deathtype);
 362                         }
 363
 364                         if (targ.killcount > 2)
 365                                 msg = ftos(targ.killcount);
 366                         else
 367                                 msg = "";
 368                         if(teamplay && deathtype == DEATH_MIRRORDAMAGE)
 369                         {
 370                                 if(attacker.team == COLOR_TEAM1)
 371                                         deathtype = KILL_TEAM_RED;
 372                                 else
 373                                         deathtype = KILL_TEAM_BLUE;
 374                         }
 375
 376                         Send_KillNotification(s, msg, "", deathtype, MSG_SUICIDE);
 377                 }
 378                 else if (attacker.classname == "player")
 379                 {
 380                         if(!IsDifferentTeam(attacker, targ))
 381                         {
 382                                 if(attacker.team == COLOR_TEAM1)
 383                                         type = KILL_TEAM_RED;
 384                                 else
 385                                         type = KILL_TEAM_BLUE;
 386
 387                                 GiveFrags(attacker, targ, -1, deathtype);
 388
 389                                 Send_CSQC_KillCenterprint(attacker, s, "", type, MSG_KILL);
 390
 391                                 if (targ.killcount > 2)
 392                                         msg = ftos(targ.killcount);
 393                                 else
 394                                         msg = "";
 395
 396                                 if (attacker.killcount > 2) {
 397                                         msg = ftos(attacker.killcount);
 398                                         type = KILL_TEAM_SPREE;
 399                                 }
 400                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 401
 402                                 attacker.killcount = 0;
 403
 404                                 LogDeath("tk", deathtype, attacker, targ);
 405                         }
 406                         else
 407                         {
 408                                 if (!checkrules_firstblood)
 409                                 {
 410                                         checkrules_firstblood = TRUE;
 411                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 412                                         // TODO: make these print a newline if they dont
 413                                         Send_CSQC_KillCenterprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 414                                         Send_CSQC_KillCenterprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 415                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 416                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 417                                 }
 418
 419                                 if(targ.istypefrag) {
 420                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_TYPEFRAG, MSG_KILL);
 421                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 422                                 } else {
 423                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_FRAG, MSG_KILL);
 424                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_FRAGGED, MSG_KILL);
 425                                 }
 426
 427                                 attacker.taunt_soundtime = time + 1;
 428
 429                                 if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
 430                                         msg = inflictor.message2;
 431                                 else if (deathtype == DEATH_CUSTOM)
 432                                         msg = deathmessage;
 433                                 else
 434                                         msg = "";
 435
 436                                 if(strstrofs(msg, "%", 0) < 0)
 437                                         msg = strcat("%s ", msg, " by %s");
 438
 439                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 440
 441                                 GiveFrags(attacker, targ, 1, deathtype);
 442
 443                                 if (targ.killcount > 2) {
 444                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 445                                 }
 446
 447                                 attacker.killcount = attacker.killcount + 1;
 448
 449                                 if (attacker.killcount == 3)
 450                                 {
 451                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 452                                         AnnounceTo(attacker, "03kills");
 453                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 454                                 }
 455                                 else if (attacker.killcount == 5)
 456                                 {
 457                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 458                                         AnnounceTo(attacker, "05kills");
 459                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 460                                 }
 461                                 else if (attacker.killcount == 10)
 462                                 {
 463                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 464                                         AnnounceTo(attacker, "10kills");
 465                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 466                                 }
 467                                 else if (attacker.killcount == 15)
 468                                 {
 469                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 470                                         AnnounceTo(attacker, "15kills");
 471                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 472                                 }
 473                                 else if (attacker.killcount == 20)
 474                                 {
 475                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 476                                         AnnounceTo(attacker, "20kills");
 477                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 478                                 }
 479                                 else if (attacker.killcount == 25)
 480                                 {
 481                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 482                                         AnnounceTo(attacker, "25kills");
 483                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 484                                 }
 485                                 else if (attacker.killcount == 30)
 486                                 {
 487                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 488                                         AnnounceTo(attacker, "30kills");
 489                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 490                                 }
 491                                 else if (attacker.killcount > 2) {
 492                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 493                                 }
 494                                 LogDeath("frag", deathtype, attacker, targ);
 495                         }
 496                 }
 497                 else
 498                 {
 499                         Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 500                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 501                                 msg = inflictor.message;
 502                         else if (deathtype == DEATH_CUSTOM)
 503                                 msg = deathmessage;
 504                         else
 505                                 msg = "";
 506                         if(strstrofs(msg, "%", 0) < 0)
 507                                 msg = strcat("%s ", msg);
 508
 509                         GiveFrags(targ, targ, -1, deathtype);
 510                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 511                                 AnnounceTo(targ, "botlike");
 512                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 513                         }
 514                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 515
 516                         if (targ.killcount > 2)
 517                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 518
 519                         LogDeath("accident", deathtype, targ, targ);
 520                 }
 521
 522                 targ.death_origin = targ.origin;
 523                 if(targ != attacker)
 524                         targ.killer_origin = attacker.origin;
 525
 526                 // FIXME: this should go in PutClientInServer
 527                 if (targ.killcount)
 528                         targ.killcount = 0;
 529         }
 530 }
 531
 532 // these are updated by each Damage call for use in button triggering and such
 533 entity damage_targ;
 534 entity damage_inflictor;
 535 entity damage_attacker;
 536
 537 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 538 {
 539         float mirrordamage;
 540         float mirrorforce;
 541         float teamdamage0;
 542         entity attacker_save;
 543         mirrordamage = 0;
 544         mirrorforce = 0;
 545
 546         if (gameover || targ.killcount == -666)
 547                 return;
 548
 549         entity oldself;
 550         oldself = self;
 551         self = targ;
 552         damage_targ = targ;
 553         damage_inflictor = inflictor;
 554         damage_attacker = attacker;
 555                 attacker_save = attacker;
 556
 557         if(targ.classname == "player")
 558                 if(targ.hook)
 559                         if(targ.hook.aiment)
 560                                 if(targ.hook.aiment == attacker)
 561                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 562
 563         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 564         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 565         {
 566                 if(targ.classname == "player")
 567                         if not(IsDifferentTeam(targ, attacker))
 568                         {
 569                                 self = oldself;
 570                                 return;
 571                         }
 572         }
 573
 574         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 575         {
 576                 // These are ALWAYS lethal
 577                 // No damage modification here
 578                 // Instead, prepare the victim for his death...
 579                 targ.armorvalue = 0;
 580                 targ.spawnshieldtime = 0;
 581                 targ.health = 0.9; // this is < 1
 582                 targ.flags -= targ.flags & FL_GODMODE;
 583                 damage = 100000;
 584         }
 585         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 586         {
 587                 // no processing
 588         }
 589         else
 590         {
 591                 /*
 592                 skill based bot damage? gtfo. (tZork)
 593                 if (targ.classname == "player")
 594                 if (attacker.classname == "player")
 595                 if (!targ.isbot)
 596                 if (attacker.isbot)
 597                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 598         */
 599
 600                 // nullify damage if teamplay is on
 601                 if(deathtype != DEATH_TELEFRAG)
 602                 if(attacker.classname == "player")
 603                 {
 604                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 605                         {
 606                                 damage = 0;
 607                                 force = '0 0 0';
 608                         }
 609                         else if(!IsDifferentTeam(attacker, targ))
 610                         {
 611                                 if(autocvar_teamplay_mode == 1)
 612                                         damage = 0;
 613                                 else if(attacker != targ)
 614                                 {
 615                                         if(autocvar_teamplay_mode == 3)
 616                                                 damage = 0;
 617                                         else if(autocvar_teamplay_mode == 4)
 618                                         {
 619                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 620                                                 {
 621                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 622                                                         attacker.dmg_team = attacker.dmg_team + damage;
 623                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 624                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 625                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 626                                                         if(g_minstagib)
 627                                                         {
 628                                                                 if(autocvar_g_friendlyfire == 0)
 629                                                                         damage = 0;
 630                                                         }
 631                                                         else if(g_ca)
 632                                                                 damage = 0;
 633                                                         else
 634                                                                 damage = autocvar_g_friendlyfire * damage;
 635                                                         // mirrordamage will be used LATER
 636
 637                                                         if(autocvar_g_mirrordamage_virtual)
 638                                                         {
 639                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 640                                                                 attacker.dmg_take += v_x;
 641                                                                 attacker.dmg_save += v_y;
 642                                                                 attacker.dmg_inflictor = inflictor;
 643                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 644                                                                 mirrorforce = 0;
 645                                                         }
 646
 647                                                         if(autocvar_g_friendlyfire_virtual)
 648                                                         {
 649                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 650                                                                 targ.dmg_take += v_x;
 651                                                                 targ.dmg_save += v_y;
 652                                                                 targ.dmg_inflictor = inflictor;
 653                                                                 damage = 0;
 654                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 655                                                                         force = '0 0 0';
 656                                                         }
 657                                                 }
 658                                                 else
 659                                                         damage = 0;
 660                                         }
 661                                 }
 662                         }
 663                 }
 664
 665                 if(targ.classname == "player")
 666                 if(attacker.classname == "player")
 667                 if(attacker != targ)
 668                 {
 669                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 670                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 671                 }
 672
 673                 if(targ.classname == "player")
 674                 if (g_minstagib)
 675                 {
 676                         if ((deathtype == DEATH_FALL)  ||
 677                                 (deathtype == DEATH_DROWN) ||
 678                                 (deathtype == DEATH_SLIME) ||
 679                                 (deathtype == DEATH_LAVA)  ||
 680                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 681                         {
 682                                 self = oldself;
 683                                 return;
 684                         }
 685                         if(damage > 0)
 686                             damage = 10000;
 687                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 688                         {
 689                                 targ.armorvalue -= 1;
 690                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 691                                 damage = 0;
 692                                 targ.hitsound += 1;
 693                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 694                         }
 695                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 696                         {
 697                                 damage = 0;
 698                                 mirrordamage = 0;
 699                                 if (targ != attacker)
 700                                 {
 701                                         if ((targ.health >= 1) && (targ.classname == "player"))
 702                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 703                                         force = '0 0 0';
 704                                         // keep mirrorforce
 705                                         attacker = targ;
 706                                 }
 707                         }
 708                 }
 709
 710                 if not(DEATH_ISSPECIAL(deathtype))
 711                 {
 712                         damage *= g_weapondamagefactor;
 713                         mirrordamage *= g_weapondamagefactor;
 714                         force = force * g_weaponforcefactor;
 715                         mirrorforce *= g_weaponforcefactor;
 716                 }
 717
 718                 // should this be changed at all? If so, in what way?
 719                 frag_attacker = attacker;
 720                 frag_target = targ;
 721                 frag_damage = damage;
 722                 frag_force = force;
 723         frag_deathtype = deathtype;
 724                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 725                 damage = frag_damage;
 726                 force = frag_force;
 727
 728                 // apply strength multiplier
 729                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 730                 {
 731                         if(targ == attacker)
 732                         {
 733                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 734                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 735                         }
 736                         else
 737                         {
 738                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 739                                 force = force * autocvar_g_balance_powerup_strength_force;
 740                         }
 741                 }
 742
 743                 // apply invincibility multiplier
 744                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 745                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 746
 747                 if (targ == attacker)
 748                 {
 749                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 750                                 damage = 0;
 751                         else
 752                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 753                 }
 754
 755                 if(g_runematch)
 756                 {
 757                         // apply strength rune
 758                         if (attacker.runes & RUNE_STRENGTH)
 759                         {
 760                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 761                                 {
 762                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 763                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 764                                 }
 765                                 else
 766                                 {
 767                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 768                                         force = force * autocvar_g_balance_rune_strength_force;
 769                                 }
 770                         }
 771                         else if (attacker.runes & CURSE_WEAK)
 772                         {
 773                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 774                                 force = force * autocvar_g_balance_curse_weak_force;
 775                         }
 776
 777                         // apply defense rune
 778                         if (targ.runes & RUNE_DEFENSE)
 779                         {
 780                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 781                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 782                                 else
 783                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 784                         }
 785                         else if (targ.runes & CURSE_VULNER)
 786                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 787                 }
 788
 789                 // count the damage
 790                 if(attacker)
 791                 if(!targ.deadflag)
 792                 if(targ.takedamage == DAMAGE_AIM)
 793                 if(targ != attacker)
 794                 {
 795                         if(damage_headshotbonus)
 796                         {
 797                                 if(targ.classname == "player")
 798                                 {
 799                                         // HEAD SHOT:
 800                                         // find height of hit on player axis
 801                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 802                                         vector headmins, headmaxs, org;
 803                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 804                                         headmins = org + GetHeadshotMins(targ);
 805                                         headmaxs = org + GetHeadshotMaxs(targ);
 806                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 807                                         {
 808                                                 deathtype |= HITTYPE_HEADSHOT;
 809                                         }
 810                                 }
 811                                 else if(targ.classname == "turret_head")
 812                                 {
 813                                         deathtype |= HITTYPE_HEADSHOT;
 814                                 }
 815                                 if(deathtype & HITTYPE_HEADSHOT)
 816                                         if(damage_headshotbonus > 0)
 817                                                 damage *= 1 + damage_headshotbonus;
 818                         }
 819
 820                         entity victim;
 821                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 822                                 victim = targ.owner;
 823                         else
 824                                 victim = targ;
 825
 826                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 827                         {
 828                                 if(IsDifferentTeam(victim, attacker))
 829                                 {
 830                                         if(damage > 0)
 831                                         {
 832                                                 if(deathtype != DEATH_FIRE)
 833                                                 {
 834                                                         if(victim.BUTTON_CHAT)
 835                                                                 attacker.typehitsound += 1;
 836                                                         else
 837                                                                 attacker.hitsound += 1;
 838                                                 }
 839
 840                                                 damage_goodhits += 1;
 841                                                 damage_gooddamage += damage;
 842
 843                                                 if not(DEATH_ISSPECIAL(deathtype))
 844                                                 {
 845                                                         if(targ.classname == "player") // don't do this for vehicles
 846                                                         if(!g_minstagib)
 847                                                         if(IsFlying(victim))
 848                                                                 yoda = 1;
 849
 850                                                         if(g_minstagib)
 851                                                         if(victim.items & IT_STRENGTH)
 852                                                                 yoda = 1;
 853
 854                                                         if(deathtype & HITTYPE_HEADSHOT)
 855                                                                 headshot = 1;
 856                                                 }
 857                                         }
 858                                 }
 859                                 else
 860                                 {
 861                                         if(deathtype != DEATH_FIRE)
 862                                         {
 863                                                 attacker.typehitsound += 1;
 864                                         }
 865                                         if(mirrordamage > 0)
 866                                                 if(time > attacker.teamkill_complain)
 867                                                 {
 868                                                         attacker.teamkill_complain = time + 5;
 869                                                         attacker.teamkill_soundtime = time + 0.4;
 870                                                         attacker.teamkill_soundsource = targ;
 871                                                 }
 872                                 }
 873                         }
 874                 }
 875         }
 876
 877         // apply push
 878         if (self.damageforcescale)
 879         if (vlen(force))
 880         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 881         {
 882                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 883                 if(self.movetype == MOVETYPE_PHYSICS)
 884                 {
 885                         entity farcent;
 886                         farcent = spawn();
 887                         farcent.classname = "farce";
 888                         farcent.enemy = self;
 889                         farcent.movedir = farce * 10;
 890                         if(self.mass)
 891                                 farcent.movedir = farcent.movedir * self.mass;
 892                         farcent.origin = hitloc;
 893                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 894                         farcent.nextthink = time + 0.1;
 895                         farcent.think = SUB_Remove;
 896                 }
 897                 else
 898                         self.velocity = self.velocity + farce;
 899                 self.flags &~= FL_ONGROUND;
 900                 UpdateCSQCProjectile(self);
 901         }
 902         // apply damage
 903         if (damage != 0 || (self.damageforcescale && vlen(force)))
 904         if (self.event_damage)
 905                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 906         self = oldself;
 907
 908         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 909         {
 910                 if(g_runematch)
 911                 {
 912                         if (attacker.runes & RUNE_VAMPIRE)
 913                         {
 914                         // apply vampire rune
 915                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 916                                 {
 917                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 918                                         attacker.health = bound(
 919                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 920                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 921                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 922                                 }
 923                                 else
 924                                 {
 925                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 926                                         attacker.health = bound(
 927                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 928                                                                                         // empathy won't let you gain health in the same way...
 929                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 930                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 931                                         }
 932                         }
 933                         // apply empathy curse
 934                         else if (attacker.runes & CURSE_EMPATHY)
 935                         {
 936                                 attacker.health = bound(
 937                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 938                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 939                                         attacker.health);
 940                         }
 941                 }
 942         }
 943
 944         // apply mirror damage if any
 945         if(mirrordamage > 0 || mirrorforce > 0)
 946         {
 947                 attacker = attacker_save;
 948                 if(g_minstagib)
 949                 if(mirrordamage > 0)
 950                 {
 951                         // just lose extra LIVES, don't kill the player for mirror damage
 952                         if(attacker.armorvalue > 0)
 953                         {
 954                                 attacker.armorvalue = attacker.armorvalue - 1;
 955                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 956                                 attacker.hitsound += 1;
 957                         }
 958                         mirrordamage = 0;
 959                 }
 960
 961                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 962                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 963         }
 964 }
 965
 966 float RadiusDamage_running;
 967 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 968         // Returns total damage applies to creatures
 969 {
 970         entity  targ;
 971         vector  blastorigin;
 972         vector  force;
 973         float   total_damage_to_creatures;
 974         entity  next;
 975         float   tfloordmg;
 976         float   tfloorforce;
 977
 978         float stat_damagedone;
 979
 980         if(RadiusDamage_running)
 981         {
 982                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 983                 return 0;
 984         }
 985
 986         RadiusDamage_running = 1;
 987
 988         tfloordmg = autocvar_g_throughfloor_damage;
 989         tfloorforce = autocvar_g_throughfloor_force;
 990
 991         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 992         total_damage_to_creatures = 0;
 993
 994         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 995                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 996                 {
 997                         force = inflictor.velocity;
 998                         if(vlen(force) == 0)
 999                                 force = '0 0 -1';
1000                         else
1001                                 force = normalize(force);
1002                         if(forceintensity >= 0)
1003                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1004                         else
1005                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1006                 }
1007
1008         stat_damagedone = 0;
1009
1010         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1011         while (targ)
1012         {
1013                 next = targ.chain;
1014                 if (targ != inflictor)
1015                         if (ignore != targ) if(targ.takedamage)
1016                         {
1017                                 vector nearest;
1018                                 vector diff;
1019                                 float power;
1020
1021                                 // LordHavoc: measure distance to nearest point on target (not origin)
1022                                 // (this guarentees 100% damage on a touch impact)
1023                                 nearest = targ.WarpZone_findradius_nearest;
1024                                 diff = targ.WarpZone_findradius_dist;
1025                                 // round up a little on the damage to ensure full damage on impacts
1026                                 // and turn the distance into a fraction of the radius
1027                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1028                                 //bprint(" ");
1029                                 //bprint(ftos(power));
1030                                 //if (targ == attacker)
1031                                 //      print(ftos(power), "\n");
1032                                 if (power > 0)
1033                                 {
1034                                         float finaldmg;
1035                                         if (power > 1)
1036                                                 power = 1;
1037                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1038                                         if (finaldmg > 0)
1039                                         {
1040                                                 float a;
1041                                                 float c;
1042                                                 vector hitloc;
1043                                                 vector myblastorigin;
1044                                                 vector center;
1045
1046                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1047
1048                                                 // if it's a player, use the view origin as reference
1049                                                 center = CENTER_OR_VIEWOFS(targ);
1050
1051                                                 force = normalize(center - myblastorigin);
1052                                                 force = force * (finaldmg / coredamage) * forceintensity;
1053                                                 hitloc = nearest;
1054
1055                                                 if(targ != directhitentity)
1056                                                 {
1057                                                         float hits;
1058                                                         float total;
1059                                                         float hitratio;
1060                                                         float mininv_f, mininv_d;
1061
1062                                                         // test line of sight to multiple positions on box,
1063                                                         // and do damage if any of them hit
1064                                                         hits = 0;
1065
1066                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1067                                                         // so for a given max stddev:
1068                                                         // n = (1 / (2 * max stddev of hitratio))^2
1069
1070                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1071                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1072
1073                                                         if(autocvar_g_throughfloor_debug)
1074                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1075
1076                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1077
1078                                                         if(autocvar_g_throughfloor_debug)
1079                                                                 print(sprintf(" steps=%f", total));
1080
1081                                                         if (targ.classname == "player")
1082                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1083                                                         else
1084                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1085
1086                                                         if(autocvar_g_throughfloor_debug)
1087                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1088
1089                                                         for(c = 0; c < total; ++c)
1090                                                         {
1091                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1092                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1093                                                                 if (trace_fraction == 1 || trace_ent == targ)
1094                                                                 {
1095                                                                         ++hits;
1096                                                                         if (hits > 1)
1097                                                                                 hitloc = hitloc + nearest;
1098                                                                         else
1099                                                                                 hitloc = nearest;
1100                                                                 }
1101                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1102                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1103                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1104                                                         }
1105
1106                                                         nearest = hitloc * (1 / max(1, hits));
1107                                                         hitratio = (hits / total);
1108                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1109                                                         finaldmg = finaldmg * a;
1110                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1111                                                         force = force * a;
1112
1113                                                         if(autocvar_g_throughfloor_debug)
1114                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1115                                                 }
1116
1117                                                 // laser force adjustments :P
1118                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1119                                                 {
1120                                                         if (targ == attacker)
1121                                                         {
1122                                                                 vector vel;
1123
1124                                                                 float force_zscale;
1125                                                                 float force_velocitybiasramp;
1126                                                                 float force_velocitybias;
1127
1128                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1129                                                                 if(deathtype & HITTYPE_SECONDARY)
1130                                                                 {
1131                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1132                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1133                                                                 }
1134                                                                 else
1135                                                                 {
1136                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1137                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1138                                                                 }
1139
1140                                                                 vel = targ.velocity;
1141                                                                 vel_z = 0;
1142                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1143                                                                 force =
1144                                                                         vlen(force)
1145                                                                         *
1146                                                                         normalize(normalize(force) + vel);
1147
1148                                                                 force_z *= force_zscale;
1149                                                         }
1150                                                         else
1151                                                         {
1152                                                                 if(deathtype & HITTYPE_SECONDARY)
1153                                                                 {
1154                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1155                                                                 }
1156                                                                 else
1157                                                                 {
1158                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1159                                                                 }
1160                                                         }
1161                                                 }
1162
1163                                                 //if (targ == attacker)
1164                                                 //{
1165                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1166                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1167                                                 //      print(" (", ftos(a), ")\n");
1168                                                 //}
1169                                                 if(finaldmg || vlen(force))
1170                                                 {
1171                                                         if(targ.iscreature)
1172                                                         {
1173                                                                 total_damage_to_creatures += finaldmg;
1174
1175                                                                 if(accuracy_isgooddamage(attacker, targ))
1176                                                                         stat_damagedone += finaldmg;
1177                                                         }
1178
1179                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1180                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1181                                                         else
1182                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1183                                                 }
1184                                         }
1185                                 }
1186                         }
1187                 targ = next;
1188         }
1189
1190         RadiusDamage_running = 0;
1191
1192         if(!DEATH_ISSPECIAL(deathtype))
1193                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1194
1195         return total_damage_to_creatures;
1196 }
1197
1198 .float fire_damagepersec;
1199 .float fire_endtime;
1200 .float fire_deathtype;
1201 .entity fire_owner;
1202 .float fire_hitsound;
1203 .entity fire_burner;
1204
1205 void fireburner_think();
1206
1207 float Fire_IsBurning(entity e)
1208 {
1209         return (time < e.fire_endtime);
1210 }
1211
1212 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1213 {
1214         float dps;
1215         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1216
1217         if(e.classname == "player")
1218         {
1219                 if(e.deadflag)
1220                         return -1;
1221         }
1222         else
1223         {
1224                 if(!e.fire_burner)
1225                 {
1226                         // print("adding a fire burner to ", e.classname, "\n");
1227                         e.fire_burner = spawn();
1228                         e.fire_burner.classname = "fireburner";
1229                         e.fire_burner.think = fireburner_think;
1230                         e.fire_burner.nextthink = time;
1231                         e.fire_burner.owner = e;
1232                 }
1233         }
1234
1235         t = max(t, 0.1);
1236         dps = d / t;
1237         if(Fire_IsBurning(e))
1238         {
1239                 mintime = e.fire_endtime - time;
1240                 maxtime = max(mintime, t);
1241
1242                 mindps = e.fire_damagepersec;
1243                 maxdps = max(mindps, dps);
1244
1245                 if(maxtime > mintime || maxdps > mindps)
1246                 {
1247                         // Constraints:
1248
1249                         // damage we have right now
1250                         mindamage = mindps * mintime;
1251
1252                         // damage we want to get
1253                         maxdamage = mindamage + d;
1254
1255                         // but we can't exceed maxtime * maxdps!
1256                         totaldamage = min(maxdamage, maxtime * maxdps);
1257
1258                         // LEMMA:
1259                         // Look at:
1260                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1261                         // We see:
1262                         // totaldamage <= maxtime * maxdps
1263                         // ==> totaldamage / maxdps <= maxtime.
1264                         // We also see:
1265                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1266                         //                     >= min(mintime, maxtime)
1267                         // ==> totaldamage / maxdps >= mintime.
1268
1269                         /*
1270                         // how long do we damage then?
1271                         // at least as long as before
1272                         // but, never exceed maxdps
1273                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1274                         */
1275
1276                         // alternate:
1277                         // at most as long as maximum allowed
1278                         // but, never below mindps
1279                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1280
1281                         // assuming t > mintime, dps > mindps:
1282                         // we get d = t * dps = maxtime * maxdps
1283                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1284                         // totaldamage / maxdps = maxtime
1285                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1286                         // FROM THIS:
1287                         // a) totaltime = max(mintime, maxtime) = maxtime
1288                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1289
1290                         // assuming t <= mintime:
1291                         // we get maxtime = mintime
1292                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1293                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1294
1295                         // assuming dps <= mindps:
1296                         // we get mindps = maxdps.
1297                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1298                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1299                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1300
1301                         e.fire_damagepersec = totaldamage / totaltime;
1302                         e.fire_endtime = time + totaltime;
1303                         if(totaldamage > 1.2 * mindamage)
1304                         {
1305                                 e.fire_deathtype = dt;
1306                                 if(e.fire_owner != o)
1307                                 {
1308                                         e.fire_owner = o;
1309                                         e.fire_hitsound = FALSE;
1310                                 }
1311                         }
1312                         if(accuracy_isgooddamage(o, e))
1313                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1314                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1315                 }
1316                 else
1317                         return 0;
1318         }
1319         else
1320         {
1321                 e.fire_damagepersec = dps;
1322                 e.fire_endtime = time + t;
1323                 e.fire_deathtype = dt;
1324                 e.fire_owner = o;
1325                 e.fire_hitsound = FALSE;
1326                 if(accuracy_isgooddamage(o, e))
1327                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1328                 return d;
1329         }
1330 }
1331
1332 void Fire_ApplyDamage(entity e)
1333 {
1334         float t, d, hi, ty;
1335         entity o;
1336
1337         if not(Fire_IsBurning(e))
1338                 return;
1339
1340         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1341         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1342                 o = e.fire_owner;
1343
1344         // water and slime stop fire
1345         if(e.waterlevel)
1346         if(e.watertype != CONTENT_LAVA)
1347                 e.fire_endtime = 0;
1348
1349         // ice stops fire
1350         if(e.freezetag_frozen)
1351                 e.fire_endtime = 0;
1352
1353         t = min(frametime, e.fire_endtime - time);
1354         d = e.fire_damagepersec * t;
1355
1356         hi = e.fire_owner.hitsound;
1357         ty = e.fire_owner.typehitsound;
1358         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1359         if(e.fire_hitsound && e.fire_owner)
1360         {
1361                 e.fire_owner.hitsound = hi;
1362                 e.fire_owner.typehitsound = ty;
1363         }
1364         e.fire_hitsound = TRUE;
1365
1366         if not(IS_INDEPENDENT_PLAYER(e))
1367         FOR_EACH_PLAYER(other) if(e != other)
1368         {
1369                 if(other.classname == "player")
1370                 if(other.deadflag == DEAD_NO)
1371                 if not(IS_INDEPENDENT_PLAYER(other))
1372                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1373                 {
1374                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1375                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1376                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1377                 }
1378         }
1379 }
1380
1381 void Fire_ApplyEffect(entity e)
1382 {
1383         if(Fire_IsBurning(e))
1384                 e.effects |= EF_FLAME;
1385         else
1386                 e.effects &~= EF_FLAME;
1387 }
1388
1389 void fireburner_think()
1390 {
1391         // for players, this is done in the regular loop
1392         if(wasfreed(self.owner))
1393         {
1394                 remove(self);
1395                 return;
1396         }
1397         Fire_ApplyEffect(self.owner);
1398         if(!Fire_IsBurning(self.owner))
1399         {
1400                 self.owner.fire_burner = world;
1401                 remove(self);
1402                 return;
1403         }
1404         Fire_ApplyDamage(self.owner);
1405         self.nextthink = time;
1406 }