qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59 float IsFlying(entity a)
  60 {
  61         if(a.flags & FL_ONGROUND)
  62                 return 0;
  63         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  64                 return 0;
  65         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  66         if(trace_fraction < 1)
  67                 return 0;
  68         return 1;
  69 }
  70
  71 void UpdateFrags(entity player, float f)
  72 {
  73         PlayerTeamScore_AddScore(player, f);
  74 }
  75
  76 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  77 void W_SwitchWeapon_Force(entity e, float w);
  78 entity GiveFrags_randomweapons;
  79 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  80 {
  81         // TODO route through PlayerScores instead
  82         if(gameover) return;
  83
  84         if(f < 0)
  85         {
  86                 if(targ == attacker)
  87                 {
  88                         // suicide
  89                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
  90                 }
  91                 else
  92                 {
  93                         // teamkill
  94                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
  95                 }
  96         }
  97         else
  98         {
  99                 // regular frag
 100                 PlayerScore_Add(attacker, SP_KILLS, 1);
 101                 if(targ.playerid)
 102                         PS_GR_P_ADDVAL(attacker, sprintf("kills-%d", targ.playerid), 1);
 103         }
 104
 105         PlayerScore_Add(targ, SP_DEATHS, 1);
 106
 107         if(targ != attacker) // not for suicides
 108         if(g_weaponarena_random)
 109         {
 110                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 111                 float culprit;
 112                 culprit = DEATH_WEAPONOF(deathtype);
 113                 if(!culprit)
 114                         culprit = attacker.weapon;
 115                 else if(!(attacker.weapons & WepSet_FromWeapon(culprit)))
 116                         culprit = attacker.weapon;
 117
 118                 if(g_weaponarena_random_with_blaster && culprit == WEP_BLASTER) // WEAPONTODO: Shouldn't this be in a mutator?
 119                 {
 120                         // no exchange
 121                 }
 122                 else
 123                 {
 124                         if(!GiveFrags_randomweapons)
 125                         {
 126                                 GiveFrags_randomweapons = spawn();
 127                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 128                         }
 129
 130                         if(warmup_stage)
 131                                 GiveFrags_randomweapons.weapons = WARMUP_START_WEAPONS;
 132                         else
 133                                 GiveFrags_randomweapons.weapons = start_weapons;
 134
 135                         // all others (including the culprit): remove
 136                         GiveFrags_randomweapons.weapons &= ~attacker.weapons;
 137                         GiveFrags_randomweapons.weapons &= ~WepSet_FromWeapon(culprit);
 138
 139                         // among the remaining ones, choose one by random
 140                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 141
 142                         if(GiveFrags_randomweapons.weapons)
 143                         {
 144                                 attacker.weapons |= GiveFrags_randomweapons.weapons;
 145                                 attacker.weapons &= ~WepSet_FromWeapon(culprit);
 146                         }
 147                 }
 148
 149                 // after a frag, choose another random weapon set
 150                 if (!(attacker.weapons & WepSet_FromWeapon(attacker.weapon)))
 151                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 152         }
 153
 154         // FIXME fix the mess this is (we have REAL points now!)
 155         entity oldself;
 156         oldself = self;
 157         self = attacker;
 158         frag_attacker = attacker;
 159         frag_target = targ;
 160         frag_score = f;
 161         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 162         {
 163                 f = frag_score;
 164                 self = oldself;
 165         }
 166         else
 167         {
 168                 self = oldself;
 169         }
 170
 171         attacker.totalfrags += f;
 172
 173         if(f)
 174                 UpdateFrags(attacker, f);
 175 }
 176
 177 string AppendItemcodes(string s, entity player)
 178 {
 179         float w;
 180         w = player.weapon;
 181         //if(w == 0)
 182         //      w = player.switchweapon;
 183         if(w == 0)
 184                 w = player.cnt; // previous weapon!
 185         s = strcat(s, ftos(w));
 186         if(time < player.strength_finished)
 187                 s = strcat(s, "S");
 188         if(time < player.invincible_finished)
 189                 s = strcat(s, "I");
 190         if(player.flagcarried != world)
 191                 s = strcat(s, "F");
 192         if(player.BUTTON_CHAT)
 193                 s = strcat(s, "T");
 194         if(player.kh_next)
 195                 s = strcat(s, "K");
 196         return s;
 197 }
 198
 199 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 200 {
 201         string s;
 202         if(!autocvar_sv_eventlog)
 203                 return;
 204         s = strcat(":kill:", mode);
 205         s = strcat(s, ":", ftos(killer.playerid));
 206         s = strcat(s, ":", ftos(killed.playerid));
 207         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 208         s = strcat(s, ":items=");
 209         s = AppendItemcodes(s, killer);
 210         if(killed != killer)
 211         {
 212                 s = strcat(s, ":victimitems=");
 213                 s = AppendItemcodes(s, killed);
 214         }
 215         GameLogEcho(s);
 216 }
 217
 218 void Obituary_SpecialDeath(
 219         entity notif_target,
 220         float murder,
 221         float deathtype,
 222         string s1, string s2, string s3,
 223         float f1, float f2, float f3)
 224 {
 225         if(DEATH_ISSPECIAL(deathtype))
 226         {
 227                 entity deathent = deathtypes[(deathtype - DT_FIRST)];
 228                 if (!deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 229
 230                 if(murder)
 231                 {
 232                         if(deathent.death_msgmurder)
 233                         {
 234                                 Send_Notification_WOCOVA(
 235                                         NOTIF_ONE,
 236                                         notif_target,
 237                                         MSG_MULTI,
 238                                         deathent.death_msgmurder.nent_id,
 239                                         s1, s2, s3, "",
 240                                         f1, f2, f3, 0
 241                                 );
 242                                 Send_Notification_WOCOVA(
 243                                         NOTIF_ALL_EXCEPT,
 244                                         notif_target,
 245                                         MSG_INFO,
 246                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 247                                         s1, s2, s3, "",
 248                                         f1, f2, f3, 0
 249                                 );
 250                         }
 251                 }
 252                 else
 253                 {
 254                         if(deathent.death_msgself)
 255                         {
 256                                 Send_Notification_WOCOVA(
 257                                         NOTIF_ONE,
 258                                         notif_target,
 259                                         MSG_MULTI,
 260                                         deathent.death_msgself.nent_id,
 261                                         s1, s2, s3, "",
 262                                         f1, f2, f3, 0
 263                                 );
 264                                 Send_Notification_WOCOVA(
 265                                         NOTIF_ALL_EXCEPT,
 266                                         notif_target,
 267                                         MSG_INFO,
 268                                         deathent.death_msgself.nent_msginfo.nent_id,
 269                                         s1, s2, s3, "",
 270                                         f1, f2, f3, 0
 271                                 );
 272                         }
 273                 }
 274         }
 275         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 276 }
 277
 278 float w_deathtype;
 279 float Obituary_WeaponDeath(
 280         entity notif_target,
 281         float murder,
 282         float deathtype,
 283         string s1, string s2, string s3,
 284         float f1, float f2)
 285 {
 286         float death_weapon = DEATH_WEAPONOF(deathtype);
 287         if(death_weapon)
 288         {
 289                 w_deathtype = deathtype;
 290                 float death_message = WEP_ACTION(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 291                 w_deathtype = FALSE;
 292
 293                 if(death_message)
 294                 {
 295                         Send_Notification_WOCOVA(
 296                                 NOTIF_ONE,
 297                                 notif_target,
 298                                 MSG_MULTI,
 299                                 death_message,
 300                                 s1, s2, s3, "",
 301                                 f1, f2, 0, 0
 302                         );
 303                         Send_Notification_WOCOVA(
 304                                 NOTIF_ALL_EXCEPT,
 305                                 notif_target,
 306                                 MSG_INFO,
 307                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 308                                 s1, s2, s3, "",
 309                                 f1, f2, 0, 0
 310                         );
 311                 }
 312                 else
 313                 {
 314                         dprintf(
 315                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 316                                 deathtype,
 317                                 death_weapon
 318                         );
 319                 }
 320
 321                 return TRUE;
 322         }
 323         return FALSE;
 324 }
 325
 326 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 327 {
 328         // Sanity check
 329         if (!IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 330
 331         // Declarations
 332         float notif_firstblood = FALSE;
 333         float kill_count_to_attacker, kill_count_to_target;
 334
 335         // Set final information for the death
 336         targ.death_origin = targ.origin;
 337         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 338         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 339
 340         #ifdef NOTIFICATIONS_DEBUG
 341         Debug_Notification(
 342                 sprintf(
 343                         "Obituary(%s, %s, %s, %s = %d);\n",
 344                         attacker.netname,
 345                         inflictor.netname,
 346                         targ.netname,
 347                         Deathtype_Name(deathtype),
 348                         deathtype
 349                 )
 350         );
 351         #endif
 352
 353         // =======
 354         // SUICIDE
 355         // =======
 356         if(targ == attacker)
 357         {
 358                 if(DEATH_ISSPECIAL(deathtype))
 359                 {
 360                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 361                         {
 362                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 363                         }
 364                         else
 365                         {
 366                                 switch(deathtype)
 367                                 {
 368                                         case DEATH_MIRRORDAMAGE:
 369                                         {
 370                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 371                                                 break;
 372                                         }
 373
 374                                         default:
 375                                         {
 376                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 377                                                 break;
 378                                         }
 379                                 }
 380                         }
 381                 }
 382                 else if (!Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 383                 {
 384                         backtrace("SUICIDE: what the hell happened here?\n");
 385                         return;
 386                 }
 387                 LogDeath("suicide", deathtype, targ, targ);
 388                 GiveFrags(attacker, targ, -1, deathtype);
 389         }
 390
 391         // ======
 392         // MURDER
 393         // ======
 394         else if(IS_PLAYER(attacker))
 395         {
 396                 if(SAME_TEAM(attacker, targ))
 397                 {
 398                         LogDeath("tk", deathtype, attacker, targ);
 399                         GiveFrags(attacker, targ, -1, deathtype);
 400
 401                         attacker.killcount = 0;
 402
 403                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 404                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 405                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 406
 407                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 408                         // No need for specific death/weapon messages...
 409                 }
 410                 else
 411                 {
 412                         LogDeath("frag", deathtype, attacker, targ);
 413                         GiveFrags(attacker, targ, 1, deathtype);
 414
 415                         attacker.taunt_soundtime = time + 1;
 416                         attacker.killcount = attacker.killcount + 1;
 417
 418                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 419                                 case counta: \
 420                                 { \
 421                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 422                                         PS_GR_P_ADDVAL(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 423                                         break; \
 424                                 }
 425                         switch(attacker.killcount)
 426                         {
 427                                 KILL_SPREE_LIST
 428                                 default: break;
 429                         }
 430                         #undef SPREE_ITEM
 431
 432                         if(!checkrules_firstblood)
 433                         {
 434                                 checkrules_firstblood = TRUE;
 435                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 436                                 PS_GR_P_ADDVAL(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 437                                 PS_GR_P_ADDVAL(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 438
 439                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 440                                 kill_count_to_attacker = -1;
 441                                 kill_count_to_target = -2;
 442                         }
 443                         else
 444                         {
 445                                 kill_count_to_attacker = attacker.killcount;
 446                                 kill_count_to_target = 0;
 447                         }
 448
 449                         if(targ.istypefrag)
 450                         {
 451                                 Send_Notification(
 452                                         NOTIF_ONE,
 453                                         attacker,
 454                                         MSG_CHOICE,
 455                                         CHOICE_TYPEFRAG,
 456                                         targ.netname,
 457                                         kill_count_to_attacker,
 458                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
 459                                 );
 460                                 Send_Notification(
 461                                         NOTIF_ONE,
 462                                         targ,
 463                                         MSG_CHOICE,
 464                                         CHOICE_TYPEFRAGGED,
 465                                         attacker.netname,
 466                                         kill_count_to_target,
 467                                         attacker.health,
 468                                         attacker.armorvalue,
 469                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
 470                                 );
 471                         }
 472                         else
 473                         {
 474                                 Send_Notification(
 475                                         NOTIF_ONE,
 476                                         attacker,
 477                                         MSG_CHOICE,
 478                                         CHOICE_FRAG,
 479                                         targ.netname,
 480                                         kill_count_to_attacker,
 481                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
 482                                 );
 483                                 Send_Notification(
 484                                         NOTIF_ONE,
 485                                         targ,
 486                                         MSG_CHOICE,
 487                                         CHOICE_FRAGGED,
 488                                         attacker.netname,
 489                                         kill_count_to_target,
 490                                         attacker.health,
 491                                         attacker.armorvalue,
 492                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
 493                                 );
 494                         }
 495
 496                         if (!Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 497                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 498                 }
 499         }
 500
 501         // =============
 502         // ACCIDENT/TRAP
 503         // =============
 504         else
 505         {
 506                 switch(deathtype)
 507                 {
 508                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 509                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 510                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 511                         /*case DEATH_HURTTRIGGER:
 512                         {
 513                                 s1 = targ.netname;
 514                                 s2 = inflictor.message;
 515                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 516                                 break;
 517                         }*/
 518
 519                         case DEATH_CUSTOM:
 520                         {
 521                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 522                                         targ.netname,
 523                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 524                                         deathlocation,
 525                                         targ.killcount,
 526                                         0,
 527                                         0);
 528                                 break;
 529                         }
 530
 531                         default:
 532                         {
 533                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 534                                 break;
 535                         }
 536                 }
 537
 538                 LogDeath("accident", deathtype, targ, targ);
 539                 GiveFrags(targ, targ, -1, deathtype);
 540
 541                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 542                 {
 543                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 544                         PS_GR_P_ADDVAL(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 545                 }
 546         }
 547
 548         // reset target kill count
 549         if(targ.killcount) { targ.killcount = 0; }
 550 }
 551
 552 void Ice_Think()
 553 {
 554         if(!self.owner.frozen || self.owner.iceblock != self)
 555         {
 556                 remove(self);
 557                 return;
 558         }
 559         setorigin(self, self.owner.origin - '0 0 16');
 560         self.nextthink = time;
 561 }
 562
 563 void Freeze (entity targ, float freeze_time, float frozen_type, float show_waypoint)
 564 {
 565         if(!IS_PLAYER(targ) && !(targ.flags & FL_MONSTER)) // only specified entities can be freezed
 566                 return;
 567
 568         if(targ.frozen)
 569                 return;
 570
 571         float targ_maxhealth = ((targ.flags & FL_MONSTER) ? targ.max_health : start_health);
 572
 573         targ.frozen = frozen_type;
 574         targ.revive_progress = ((frozen_type == 3) ? 1 : 0);
 575         targ.health = ((frozen_type == 3) ? targ_maxhealth : 1);
 576         targ.revive_speed = freeze_time;
 577
 578         entity ice, head;
 579         ice = spawn();
 580         ice.owner = targ;
 581         ice.classname = "ice";
 582         ice.scale = targ.scale;
 583         ice.think = Ice_Think;
 584         ice.nextthink = time;
 585         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 586         setmodel(ice, "models/ice/ice.md3");
 587         ice.alpha = 1;
 588         ice.colormod = Team_ColorRGB(targ.team);
 589         ice.glowmod = ice.colormod;
 590         targ.iceblock = ice;
 591         targ.revival_time = 0;
 592
 593         entity oldself;
 594         oldself = self;
 595         self = ice;
 596         Ice_Think();
 597         self = oldself;
 598
 599         RemoveGrapplingHook(targ);
 600
 601         FOR_EACH_PLAYER(head)
 602         if(head.hook.aiment == targ)
 603                 RemoveGrapplingHook(head);
 604
 605         // add waypoint
 606         if(show_waypoint)
 607                 WaypointSprite_Spawn("frozen", 0, 0, targ, '0 0 64', world, targ.team, targ, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 608 }
 609
 610 void Unfreeze (entity targ)
 611 {
 612         if(targ.frozen && targ.frozen != 3) // only reset health if target was frozen
 613                 targ.health = ((IS_PLAYER(targ)) ? start_health : targ.max_health);
 614
 615         entity head;
 616         targ.frozen = 0;
 617         targ.revive_progress = 0;
 618         targ.revival_time = time;
 619
 620         WaypointSprite_Kill(targ.waypointsprite_attached);
 621
 622         FOR_EACH_PLAYER(head)
 623         if(head.hook.aiment == targ)
 624                 RemoveGrapplingHook(head);
 625
 626         // remove the ice block
 627         if(targ.iceblock)
 628                 remove(targ.iceblock);
 629         targ.iceblock = world;
 630 }
 631
 632 // these are updated by each Damage call for use in button triggering and such
 633 entity damage_targ;
 634 entity damage_inflictor;
 635 entity damage_attacker;
 636
 637 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 638 {
 639         float mirrordamage;
 640         float mirrorforce;
 641         float complainteamdamage = 0;
 642         entity attacker_save;
 643         mirrordamage = 0;
 644         mirrorforce = 0;
 645
 646         if (gameover || targ.killcount == -666)
 647                 return;
 648
 649         entity oldself;
 650         oldself = self;
 651         self = targ;
 652         damage_targ = targ;
 653         damage_inflictor = inflictor;
 654         damage_attacker = attacker;
 655                 attacker_save = attacker;
 656
 657         if(IS_PLAYER(targ))
 658                 if(targ.hook)
 659                         if(targ.hook.aiment)
 660                                 if(targ.hook.aiment == attacker)
 661                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 662
 663         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 664         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 665         {
 666                 if(IS_PLAYER(targ))
 667                         if(SAME_TEAM(targ, attacker))
 668                         {
 669                                 self = oldself;
 670                                 return;
 671                         }
 672         }
 673
 674         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 675         {
 676                 // exit the vehicle before killing (fixes a crash)
 677                 if(IS_PLAYER(targ) && targ.vehicle)
 678                         vehicles_exit(VHEF_RELESE);
 679
 680                 // These are ALWAYS lethal
 681                 // No damage modification here
 682                 // Instead, prepare the victim for his death...
 683                 targ.armorvalue = 0;
 684                 targ.spawnshieldtime = 0;
 685                 targ.health = 0.9; // this is < 1
 686                 targ.flags -= targ.flags & FL_GODMODE;
 687                 damage = 100000;
 688         }
 689         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 690         {
 691                 // no processing
 692         }
 693         else
 694         {
 695                 // nullify damage if teamplay is on
 696                 if(deathtype != DEATH_TELEFRAG)
 697                 if(IS_PLAYER(attacker))
 698                 {
 699                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 700                         {
 701                                 damage = 0;
 702                                 force = '0 0 0';
 703                         }
 704                         else if(SAME_TEAM(attacker, targ))
 705                         {
 706                                 if(autocvar_teamplay_mode == 1)
 707                                         damage = 0;
 708                                 else if(attacker != targ)
 709                                 {
 710                                         if(autocvar_teamplay_mode == 3)
 711                                                 damage = 0;
 712                                         else if(autocvar_teamplay_mode == 4)
 713                                         {
 714                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
 715                                                 {
 716                                                         attacker.dmg_team = attacker.dmg_team + damage;
 717                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 718                                                         if(complainteamdamage > 0)
 719                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 720                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 721                                                         damage = autocvar_g_friendlyfire * damage;
 722                                                         // mirrordamage will be used LATER
 723
 724                                                         if(autocvar_g_mirrordamage_virtual)
 725                                                         {
 726                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, mirrordamage);
 727                                                                 attacker.dmg_take += v_x;
 728                                                                 attacker.dmg_save += v_y;
 729                                                                 attacker.dmg_inflictor = inflictor;
 730                                                                 mirrordamage = v_z;
 731                                                                 mirrorforce = 0;
 732                                                         }
 733
 734                                                         if(autocvar_g_friendlyfire_virtual)
 735                                                         {
 736                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 737                                                                 targ.dmg_take += v_x;
 738                                                                 targ.dmg_save += v_y;
 739                                                                 targ.dmg_inflictor = inflictor;
 740                                                                 damage = 0;
 741                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 742                                                                         force = '0 0 0';
 743                                                         }
 744                                                 }
 745                                                 else
 746                                                         damage = 0;
 747                                         }
 748                                 }
 749                         }
 750                 }
 751
 752                 if (!DEATH_ISSPECIAL(deathtype))
 753                 {
 754                         damage *= g_weapondamagefactor;
 755                         mirrordamage *= g_weapondamagefactor;
 756                         complainteamdamage *= g_weapondamagefactor;
 757                         force = force * g_weaponforcefactor;
 758                         mirrorforce *= g_weaponforcefactor;
 759                 }
 760
 761                 // should this be changed at all? If so, in what way?
 762                 frag_attacker = attacker;
 763                 frag_target = targ;
 764                 frag_damage = damage;
 765                 frag_force = force;
 766                 frag_deathtype = deathtype;
 767                 frag_mirrordamage = mirrordamage;
 768                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 769                 damage = frag_damage;
 770                 mirrordamage = frag_mirrordamage;
 771                 force = frag_force;
 772
 773                 if(targ.frozen)
 774                 if(deathtype != DEATH_HURTTRIGGER && deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_AUTOTEAMCHANGE)
 775                 {
 776                         if(autocvar_g_freezetag_revive_falldamage > 0)
 777                         if(deathtype == DEATH_FALL)
 778                         if(damage >= autocvar_g_freezetag_revive_falldamage)
 779                         {
 780                                 Unfreeze(targ);
 781                                 targ.health = autocvar_g_freezetag_revive_falldamage_health;
 782                                 pointparticles(particleeffectnum("iceorglass"), targ.origin, '0 0 0', 3);
 783                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_FALL, targ.netname);
 784                                 Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
 785                         }
 786
 787                         damage = 0;
 788                         force *= autocvar_g_freezetag_frozen_force;
 789                 }
 790
 791                 if(targ.frozen && deathtype == DEATH_HURTTRIGGER && !autocvar_g_freezetag_frozen_damage_trigger)
 792                 {
 793                         pointparticles(particleeffectnum("teleport"), targ.origin, '0 0 0', 1);
 794
 795                         entity oldself = self;
 796                         self = targ;
 797                         entity spot = SelectSpawnPoint (FALSE);
 798
 799                         if(spot)
 800                         {
 801                                 damage = 0;
 802                                 self.deadflag = DEAD_NO;
 803
 804                                 self.angles = spot.angles;
 805
 806                                 self.effects = 0;
 807                                 self.effects |= EF_TELEPORT_BIT;
 808
 809                                 self.angles_z = 0; // never spawn tilted even if the spot says to
 810                                 self.fixangle = TRUE; // turn this way immediately
 811                                 self.velocity = '0 0 0';
 812                                 self.avelocity = '0 0 0';
 813                                 self.punchangle = '0 0 0';
 814                                 self.punchvector = '0 0 0';
 815                                 self.oldvelocity = self.velocity;
 816
 817                                 self.spawnorigin = spot.origin;
 818                                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 819                                 // don't reset back to last position, even if new position is stuck in solid
 820                                 self.oldorigin = self.origin;
 821                                 self.prevorigin = self.origin;
 822
 823                                 pointparticles(particleeffectnum("teleport"), self.origin, '0 0 0', 1);
 824                         }
 825
 826                         self = oldself;
 827                 }
 828
 829                 if(!g_instagib)
 830                 {
 831                         // apply strength multiplier
 832                         if (attacker.items & IT_STRENGTH)
 833                         {
 834                                 if(targ == attacker)
 835                                 {
 836                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 837                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 838                                 }
 839                                 else
 840                                 {
 841                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 842                                         force = force * autocvar_g_balance_powerup_strength_force;
 843                                 }
 844                         }
 845
 846                         // apply invincibility multiplier
 847                         if (targ.items & IT_INVINCIBLE)
 848                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 849                 }
 850
 851                 if (targ == attacker)
 852                         damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 853
 854                 // count the damage
 855                 if(attacker)
 856                 if(!targ.deadflag)
 857                 if(deathtype != DEATH_BUFF_VENGEANCE)
 858                 if(targ.takedamage == DAMAGE_AIM)
 859                 if(targ != attacker)
 860                 {
 861                         entity victim;
 862                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 863                                 victim = targ.owner;
 864                         else
 865                                 victim = targ;
 866
 867                         if(IS_PLAYER(victim) || (victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET) || (victim.flags & FL_MONSTER))
 868                         {
 869                                 if(DIFF_TEAM(victim, attacker) && !victim.frozen)
 870                                 {
 871                                         if(damage > 0)
 872                                         {
 873                                                 if(deathtype != DEATH_FIRE)
 874                                                 {
 875                                                         if(victim.BUTTON_CHAT)
 876                                                                 attacker.typehitsound += 1;
 877                                                         else
 878                                                                 attacker.damage_dealt += damage;
 879                                                 }
 880
 881                                                 damage_goodhits += 1;
 882                                                 damage_gooddamage += damage;
 883
 884                                                 if (!DEATH_ISSPECIAL(deathtype))
 885                                                 {
 886                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
 887                                                         if(IsFlying(victim))
 888                                                                 yoda = 1;
 889                                                 }
 890                                         }
 891                                 }
 892                                 else
 893                                 {
 894                                         if(deathtype != DEATH_FIRE)
 895                                         {
 896                                                 attacker.typehitsound += 1;
 897                                         }
 898                                         if(complainteamdamage > 0)
 899                                                 if(time > attacker.teamkill_complain)
 900                                                 {
 901                                                         attacker.teamkill_complain = time + 5;
 902                                                         attacker.teamkill_soundtime = time + 0.4;
 903                                                         attacker.teamkill_soundsource = targ;
 904                                                 }
 905                                 }
 906                         }
 907                 }
 908         }
 909
 910         // apply push
 911         if (self.damageforcescale)
 912         if (vlen(force))
 913         if (!IS_PLAYER(self) || time >= self.spawnshieldtime)
 914         {
 915                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 916                 if(self.movetype == MOVETYPE_PHYSICS)
 917                 {
 918                         entity farcent;
 919                         farcent = spawn();
 920                         farcent.classname = "farce";
 921                         farcent.enemy = self;
 922                         farcent.movedir = farce * 10;
 923                         if(self.mass)
 924                                 farcent.movedir = farcent.movedir * self.mass;
 925                         farcent.origin = hitloc;
 926                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 927                         farcent.nextthink = time + 0.1;
 928                         farcent.think = SUB_Remove;
 929                 }
 930                 else
 931                         self.velocity = self.velocity + farce;
 932                 self.flags &= ~FL_ONGROUND;
 933                 UpdateCSQCProjectile(self);
 934         }
 935         // apply damage
 936         if (damage != 0 || (self.damageforcescale && vlen(force)))
 937         if (self.event_damage)
 938                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 939         self = oldself;
 940
 941         // apply mirror damage if any
 942         if(mirrordamage > 0 || mirrorforce > 0)
 943         {
 944                 attacker = attacker_save;
 945
 946                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 947                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 948         }
 949 }
 950
 951 float RadiusDamage_running;
 952 float RadiusDamageForSource (entity inflictor, vector inflictororigin, vector inflictorvelocity, entity attacker, float coredamage, float edgedamage, float rad, entity cantbe, entity mustbe, float inflictorselfdamage, float forceintensity, float deathtype, entity directhitentity)
 953         // Returns total damage applies to creatures
 954 {
 955         entity  targ;
 956         vector  force;
 957         float   total_damage_to_creatures;
 958         entity  next;
 959         float   tfloordmg;
 960         float   tfloorforce;
 961
 962         float stat_damagedone;
 963
 964         if(RadiusDamage_running)
 965         {
 966                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 967                 return 0;
 968         }
 969
 970         RadiusDamage_running = 1;
 971
 972         tfloordmg = autocvar_g_throughfloor_damage;
 973         tfloorforce = autocvar_g_throughfloor_force;
 974
 975         total_damage_to_creatures = 0;
 976
 977         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 978                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 979                 {
 980                         force = inflictorvelocity;
 981                         if(vlen(force) == 0)
 982                                 force = '0 0 -1';
 983                         else
 984                                 force = normalize(force);
 985                         if(forceintensity >= 0)
 986                                 Damage_DamageInfo(inflictororigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 987                         else
 988                                 Damage_DamageInfo(inflictororigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 989                 }
 990
 991         stat_damagedone = 0;
 992
 993         targ = WarpZone_FindRadius (inflictororigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 994         while (targ)
 995         {
 996                 next = targ.chain;
 997                 if ((targ != inflictor) || inflictorselfdamage)
 998                 if (((cantbe != targ) && !mustbe) || (mustbe == targ))
 999                 if (targ.takedamage)
1000                 {
1001                         vector nearest;
1002                         vector diff;
1003                         float power;
1004
1005                         // LordHavoc: measure distance to nearest point on target (not origin)
1006                         // (this guarentees 100% damage on a touch impact)
1007                         nearest = targ.WarpZone_findradius_nearest;
1008                         diff = targ.WarpZone_findradius_dist;
1009                         // round up a little on the damage to ensure full damage on impacts
1010                         // and turn the distance into a fraction of the radius
1011                         power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1012                         //bprint(" ");
1013                         //bprint(ftos(power));
1014                         //if (targ == attacker)
1015                         //      print(ftos(power), "\n");
1016                         if (power > 0)
1017                         {
1018                                 float finaldmg;
1019                                 if (power > 1)
1020                                         power = 1;
1021                                 finaldmg = coredamage * power + edgedamage * (1 - power);
1022                                 if (finaldmg > 0)
1023                                 {
1024                                         float a;
1025                                         float c;
1026                                         vector hitloc;
1027                                         vector myblastorigin;
1028                                         vector center;
1029
1030                                         myblastorigin = WarpZone_TransformOrigin(targ, inflictororigin);
1031
1032                                         // if it's a player, use the view origin as reference
1033                                         center = CENTER_OR_VIEWOFS(targ);
1034
1035                                         force = normalize(center - myblastorigin);
1036                                         force = force * (finaldmg / coredamage) * forceintensity;
1037                                         hitloc = nearest;
1038
1039                                         if(deathtype & WEP_BLASTER)
1040                                                 force *= WEP_CVAR_BOTH(blaster, !(deathtype & HITTYPE_SECONDARY), force_zscale);
1041
1042                                         if(targ != directhitentity)
1043                                         {
1044                                                 float hits;
1045                                                 float total;
1046                                                 float hitratio;
1047                                                 float mininv_f, mininv_d;
1048
1049                                                 // test line of sight to multiple positions on box,
1050                                                 // and do damage if any of them hit
1051                                                 hits = 0;
1052
1053                                                 // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1054                                                 // so for a given max stddev:
1055                                                 // n = (1 / (2 * max stddev of hitratio))^2
1056
1057                                                 mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1058                                                 mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1059
1060                                                 if(autocvar_g_throughfloor_debug)
1061                                                         printf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f);
1062
1063
1064                                                 total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1065
1066                                                 if(autocvar_g_throughfloor_debug)
1067                                                         printf(" steps=%f", total);
1068
1069
1070                                                 if (IS_PLAYER(targ))
1071                                                         total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1072                                                 else
1073                                                         total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1074
1075                                                 if(autocvar_g_throughfloor_debug)
1076                                                         printf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total)));
1077
1078                                                 for(c = 0; c < total; ++c)
1079                                                 {
1080                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1081                                                         WarpZone_TraceLine(inflictororigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1082                                                         if (trace_fraction == 1 || trace_ent == targ)
1083                                                         {
1084                                                                 ++hits;
1085                                                                 if (hits > 1)
1086                                                                         hitloc = hitloc + nearest;
1087                                                                 else
1088                                                                         hitloc = nearest;
1089                                                         }
1090                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1091                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1092                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1093                                                 }
1094
1095                                                 nearest = hitloc * (1 / max(1, hits));
1096                                                 hitratio = (hits / total);
1097                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1098                                                 finaldmg = finaldmg * a;
1099                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1100                                                 force = force * a;
1101
1102                                                 if(autocvar_g_throughfloor_debug)
1103                                                         printf(" D=%f F=%f\n", finaldmg, vlen(force));
1104                                         }
1105
1106                                         //if (targ == attacker)
1107                                         //{
1108                                         //      print("hits ", ftos(hits), " / ", ftos(total));
1109                                         //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1110                                         //      print(" (", ftos(a), ")\n");
1111                                         //}
1112                                         if(finaldmg || vlen(force))
1113                                         {
1114                                                 if(targ.iscreature)
1115                                                 {
1116                                                         total_damage_to_creatures += finaldmg;
1117
1118                                                         if(accuracy_isgooddamage(attacker, targ))
1119                                                                 stat_damagedone += finaldmg;
1120                                                 }
1121
1122                                                 if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1123                                                         Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1124                                                 else
1125                                                         Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1126                                         }
1127                                 }
1128                         }
1129                 }
1130                 targ = next;
1131         }
1132
1133         RadiusDamage_running = 0;
1134
1135         if(!DEATH_ISSPECIAL(deathtype))
1136                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1137
1138         return total_damage_to_creatures;
1139 }
1140
1141 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity cantbe, entity mustbe, float forceintensity, float deathtype, entity directhitentity)
1142 {
1143         return RadiusDamageForSource (inflictor, (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5), inflictor.velocity, attacker, coredamage, edgedamage, rad, cantbe, mustbe, FALSE, forceintensity, deathtype, directhitentity);
1144 }
1145
1146 .float fire_damagepersec;
1147 .float fire_endtime;
1148 .float fire_deathtype;
1149 .entity fire_owner;
1150 .float fire_hitsound;
1151 .entity fire_burner;
1152
1153 void fireburner_think();
1154
1155 float Fire_IsBurning(entity e)
1156 {
1157         return (time < e.fire_endtime);
1158 }
1159
1160 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1161 {
1162         float dps;
1163         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1164
1165         if(IS_PLAYER(e))
1166         {
1167                 if(e.deadflag)
1168                         return -1;
1169         }
1170         else
1171         {
1172                 if(!e.fire_burner)
1173                 {
1174                         // print("adding a fire burner to ", e.classname, "\n");
1175                         e.fire_burner = spawn();
1176                         e.fire_burner.classname = "fireburner";
1177                         e.fire_burner.think = fireburner_think;
1178                         e.fire_burner.nextthink = time;
1179                         e.fire_burner.owner = e;
1180                 }
1181         }
1182
1183         t = max(t, 0.1);
1184         dps = d / t;
1185         if(Fire_IsBurning(e))
1186         {
1187                 mintime = e.fire_endtime - time;
1188                 maxtime = max(mintime, t);
1189
1190                 mindps = e.fire_damagepersec;
1191                 maxdps = max(mindps, dps);
1192
1193                 if(maxtime > mintime || maxdps > mindps)
1194                 {
1195                         // Constraints:
1196
1197                         // damage we have right now
1198                         mindamage = mindps * mintime;
1199
1200                         // damage we want to get
1201                         maxdamage = mindamage + d;
1202
1203                         // but we can't exceed maxtime * maxdps!
1204                         totaldamage = min(maxdamage, maxtime * maxdps);
1205
1206                         // LEMMA:
1207                         // Look at:
1208                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1209                         // We see:
1210                         // totaldamage <= maxtime * maxdps
1211                         // ==> totaldamage / maxdps <= maxtime.
1212                         // We also see:
1213                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1214                         //                     >= min(mintime, maxtime)
1215                         // ==> totaldamage / maxdps >= mintime.
1216
1217                         /*
1218                         // how long do we damage then?
1219                         // at least as long as before
1220                         // but, never exceed maxdps
1221                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1222                         */
1223
1224                         // alternate:
1225                         // at most as long as maximum allowed
1226                         // but, never below mindps
1227                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1228
1229                         // assuming t > mintime, dps > mindps:
1230                         // we get d = t * dps = maxtime * maxdps
1231                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1232                         // totaldamage / maxdps = maxtime
1233                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1234                         // FROM THIS:
1235                         // a) totaltime = max(mintime, maxtime) = maxtime
1236                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1237
1238                         // assuming t <= mintime:
1239                         // we get maxtime = mintime
1240                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1241                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1242
1243                         // assuming dps <= mindps:
1244                         // we get mindps = maxdps.
1245                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1246                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1247                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1248
1249                         e.fire_damagepersec = totaldamage / totaltime;
1250                         e.fire_endtime = time + totaltime;
1251                         if(totaldamage > 1.2 * mindamage)
1252                         {
1253                                 e.fire_deathtype = dt;
1254                                 if(e.fire_owner != o)
1255                                 {
1256                                         e.fire_owner = o;
1257                                         e.fire_hitsound = FALSE;
1258                                 }
1259                         }
1260                         if(accuracy_isgooddamage(o, e))
1261                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1262                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1263                 }
1264                 else
1265                         return 0;
1266         }
1267         else
1268         {
1269                 e.fire_damagepersec = dps;
1270                 e.fire_endtime = time + t;
1271                 e.fire_deathtype = dt;
1272                 e.fire_owner = o;
1273                 e.fire_hitsound = FALSE;
1274                 if(accuracy_isgooddamage(o, e))
1275                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1276                 return d;
1277         }
1278 }
1279
1280 void Fire_ApplyDamage(entity e)
1281 {
1282         float t, d, hi, ty;
1283         entity o;
1284
1285         if (!Fire_IsBurning(e))
1286                 return;
1287
1288         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1289         if(IS_NOT_A_CLIENT(o))
1290                 o = e.fire_owner;
1291
1292         // water and slime stop fire
1293         if(e.waterlevel)
1294         if(e.watertype != CONTENT_LAVA)
1295                 e.fire_endtime = 0;
1296
1297         // ice stops fire
1298         if(e.frozen)
1299                 e.fire_endtime = 0;
1300
1301         t = min(frametime, e.fire_endtime - time);
1302         d = e.fire_damagepersec * t;
1303
1304         hi = e.fire_owner.damage_dealt;
1305         ty = e.fire_owner.typehitsound;
1306         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1307         if(e.fire_hitsound && e.fire_owner)
1308         {
1309                 e.fire_owner.damage_dealt = hi;
1310                 e.fire_owner.typehitsound = ty;
1311         }
1312         e.fire_hitsound = TRUE;
1313
1314         if (!IS_INDEPENDENT_PLAYER(e))
1315         if(!e.frozen)
1316         FOR_EACH_PLAYER(other) if(e != other)
1317         {
1318                 if(IS_PLAYER(other))
1319                 if(other.deadflag == DEAD_NO)
1320                 if (!IS_INDEPENDENT_PLAYER(other))
1321                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1322                 {
1323                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1324                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1325                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1326                 }
1327         }
1328 }
1329
1330 void Fire_ApplyEffect(entity e)
1331 {
1332         if(Fire_IsBurning(e))
1333                 e.effects |= EF_FLAME;
1334         else
1335                 e.effects &= ~EF_FLAME;
1336 }
1337
1338 void fireburner_think()
1339 {
1340         // for players, this is done in the regular loop
1341         if(wasfreed(self.owner))
1342         {
1343                 remove(self);
1344                 return;
1345         }
1346         Fire_ApplyEffect(self.owner);
1347         if(!Fire_IsBurning(self.owner))
1348         {
1349                 self.owner.fire_burner = world;
1350                 remove(self);
1351                 return;
1352         }
1353         Fire_ApplyDamage(self.owner);
1354         self.nextthink = time;
1355 }