qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         return TRUE;
  18 }
  19
  20 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, entity dmgowner)
  21 {
  22         // TODO maybe call this from non-edgedamage too?
  23         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  24
  25         entity e;
  26
  27         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  28                 deathtype |= 0x8000;
  29
  30         e = spawn();
  31         setorigin(e, org);
  32         e.projectiledeathtype = deathtype;
  33         e.dmg = coredamage;
  34         e.dmg_edge = edgedamage;
  35         e.dmg_radius = rad;
  36         e.dmg_force = vlen(force);
  37         e.velocity = force;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  42 }
  43
  44 #define DAMAGE_CENTERPRINT_SPACER NEWLINES
  45
  46 float checkrules_firstblood;
  47
  48 float yoda;
  49 float damage_goodhits;
  50 float damage_gooddamage;
  51 float headshot;
  52 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  53
  54 .float dmg_team;
  55 .float teamkill_complain;
  56 .float teamkill_soundtime;
  57 .entity teamkill_soundsource;
  58 .entity pusher;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teams_matter)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '0.6 0 0' * targ.mins_x + '0 0.6 0' * targ.mins_y + '0 0 1' * (1.3 * targ.view_ofs_z - 0.3 * targ.maxs_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.6 0 0' * targ.maxs_x + '0 0.6 0' * targ.maxs_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 void GiveFrags (entity attacker, entity targ, float f)
 106 {
 107         float w;
 108
 109         // TODO route through PlayerScores instead
 110         if(gameover) return;
 111
 112         if(f < 0)
 113         {
 114                 if(targ == attacker)
 115                 {
 116                         // suicide
 117                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 118                 }
 119                 else
 120                 {
 121                         // teamkill
 122                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 123                 }
 124         }
 125         else
 126         {
 127                 // regular frag
 128                 PlayerScore_Add(attacker, SP_KILLS, 1);
 129         }
 130
 131         PlayerScore_Add(targ, SP_DEATHS, 1);
 132
 133         if(g_arena || g_ca)
 134                 if(cvar("g_arena_roundbased"))
 135                         return;
 136
 137         if(targ != attacker) // not for suicides
 138         if(g_weaponarena_random)
 139         {
 140                 // after a frag, choose another random weapon set
 141                 if(inWarmupStage)
 142                         w = warmup_start_weapons;
 143                 else
 144                         w = start_weapons;
 145
 146                 attacker.weapons = randombits(w - (w & W_WeaponBit(attacker.weapon)), g_weaponarena_random, TRUE);
 147                 if(attacker.weapons < 0)
 148                 {
 149                         // error from randombits: no weapon available
 150                         // this means we can just give ALL weapons
 151                         attacker.weapons = w;
 152                 }
 153                 if not(attacker.weapons & W_WeaponBit(attacker.weapon))
 154                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 155         }
 156
 157         // FIXME fix the mess this is (we have REAL points now!)
 158         entity oldself;
 159         oldself = self;
 160         self = attacker;
 161         frag_attacker = attacker;
 162         frag_target = targ;
 163         frag_score = f;
 164         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 165         {
 166                 f = frag_score;
 167                 self = oldself;
 168         }
 169         else
 170         {
 171                 self = oldself;
 172                 if(g_runematch)
 173                 {
 174                         f = RunematchHandleFrags(attacker, targ, f);
 175                 }
 176                 else if(g_lms)
 177                 {
 178                         // remove a life
 179                         float tl;
 180                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 181                         if(tl < lms_lowest_lives)
 182                                 lms_lowest_lives = tl;
 183                         if(tl <= 0)
 184                         {
 185                                 if(!lms_next_place)
 186                                         lms_next_place = player_count;
 187                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 188                                 --lms_next_place;
 189                         }
 190                         f = 0;
 191                 }
 192                 else if(g_ctf)
 193                 {
 194                         if(g_ctf_ignore_frags)
 195                                 f = 0;
 196                 }
 197         }
 198
 199         attacker.totalfrags += f;
 200
 201         if(f)
 202                 UpdateFrags(attacker, f);
 203 }
 204
 205 string AppendItemcodes(string s, entity player)
 206 {
 207         float w;
 208         w = player.weapon;
 209         //if(w == 0)
 210         //      w = player.switchweapon;
 211         if(w == 0)
 212                 w = player.cnt; // previous weapon!
 213         s = strcat(s, ftos(w));
 214         if(time < player.strength_finished)
 215                 s = strcat(s, "S");
 216         if(time < player.invincible_finished)
 217                 s = strcat(s, "I");
 218         if(player.flagcarried != world)
 219                 s = strcat(s, "F");
 220         if(player.BUTTON_CHAT)
 221                 s = strcat(s, "T");
 222         if(player.kh_next)
 223                 s = strcat(s, "K");
 224         if(player.runes)
 225                 s = strcat(s, "|", ftos(player.runes));
 226         return s;
 227 }
 228
 229 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 230 {
 231         string s;
 232         if(!cvar("sv_eventlog"))
 233                 return;
 234         s = strcat(":kill:", mode);
 235         s = strcat(s, ":", ftos(killer.playerid));
 236         s = strcat(s, ":", ftos(killed.playerid));
 237         s = strcat(s, ":type=", ftos(deathtype));
 238         s = strcat(s, ":items=");
 239         s = AppendItemcodes(s, killer);
 240         if(killed != killer)
 241         {
 242                 s = strcat(s, ":victimitems=");
 243                 s = AppendItemcodes(s, killed);
 244         }
 245         GameLogEcho(s);
 246 }
 247
 248 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 249 {
 250         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 251         WriteByte(MSG_ALL, TE_CSQC_NOTIFY);
 252         WriteByte(MSG_ALL, CSQC_KILLNOTIFY);
 253         WriteString(MSG_ALL, s1);
 254         WriteString(MSG_ALL, s2);
 255         WriteString(MSG_ALL, s3);
 256         WriteShort(MSG_ALL, msg);
 257         WriteByte(MSG_ALL, type);
 258 }
 259
 260 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 261 void Send_CSQC_Centerprint(entity e, string s1, string s2, float msg, float type)
 262 {
 263         if (clienttype(e) == CLIENTTYPE_REAL)
 264         {
 265                 msg_entity = e;
 266                 WRITESPECTATABLE_MSG_ONE({
 267                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 268                         WriteByte(MSG_ONE, TE_CSQC_NOTIFY);
 269                         WriteByte(MSG_ONE, CSQC_CENTERPRINT);
 270                         WriteString(MSG_ONE, s1);
 271                         WriteString(MSG_ONE, s2);
 272                         WriteShort(MSG_ONE, msg);
 273                         WriteByte(MSG_ONE, type);
 274                 });
 275         }
 276 }
 277
 278 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 279 {
 280         string  s, a, msg;
 281         float p, w, type;
 282
 283         if (targ.classname == "player" || targ.classname == "corpse")
 284         {
 285                 if (targ.classname == "corpse")
 286                         s = "A corpse";
 287                 else
 288                         s = targ.netname;
 289
 290                 a = attacker.netname;
 291
 292                 if (targ == attacker) // suicides
 293                 {
 294                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 295                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 296                         Send_CSQC_Centerprint(targ, msg, "", deathtype, MSG_SUICIDE);
 297
 298                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 299                         {
 300                                 LogDeath("suicide", deathtype, targ, targ);
 301                                 GiveFrags(attacker, targ, -1);
 302                         }
 303
 304                         if (targ.killcount > 2)
 305                                 msg = ftos(targ.killcount);
 306                         if(teams_matter && deathtype == DEATH_MIRRORDAMAGE)
 307                         {
 308                                 if(attacker.team == COLOR_TEAM1)
 309                                         deathtype = KILL_TEAM_RED;
 310                                 else
 311                                         deathtype = KILL_TEAM_BLUE;
 312                         }
 313
 314                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 315                 }
 316                 else if (attacker.classname == "player" || attacker.classname == "gib")
 317                 {
 318                         if(teams_matter && attacker.team == targ.team)
 319                         {
 320                                 if(attacker.team == COLOR_TEAM1)
 321                                         type = KILL_TEAM_RED;
 322                                 else
 323                                         type = KILL_TEAM_BLUE;
 324
 325                                 GiveFrags(attacker, targ, -1);
 326
 327                                 Send_CSQC_Centerprint(attacker, s, "", type, MSG_KILL);
 328
 329                                 if (targ.killcount > 2) {
 330                                         msg = ftos(targ.killcount);
 331                                 }
 332
 333                                 if (attacker.killcount > 2) {
 334                                         msg = ftos(attacker.killcount);
 335                                         type = KILL_TEAM_SPREE;
 336                                 }
 337                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 338
 339                                 attacker.killcount = 0;
 340
 341                                 LogDeath("tk", deathtype, attacker, targ);
 342                         }
 343                         else
 344                         {
 345                                 string blood_message, victim_message;
 346                                 if (!checkrules_firstblood)
 347                                 {
 348                                         checkrules_firstblood = TRUE;
 349                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 350                                         // TODO: make these print a newline if they dont
 351                                         Send_CSQC_Centerprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 352                                         Send_CSQC_Centerprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 353                                 }
 354
 355                                 if((cvar("sv_fragmessage_information_typefrag")) && (targ.BUTTON_CHAT)) {
 356                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_TYPEFRAG, MSG_KILL);
 357                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 358                                 } else {
 359                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_FRAG, MSG_KILL);
 360                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_FRAGGED, MSG_KILL);
 361                                 }
 362
 363                                 attacker.taunt_soundtime = time + 1;
 364
 365                                 // TODO: fix this?
 366                                 if (deathtype == DEATH_CUSTOM)
 367                                         msg = strcat(deathmessage, " by ^1", msg);
 368                                 else if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
 369                                 {
 370                                         msg = ftos(strstrofs(inflictor.message2, "#", 0));
 371                                 }
 372
 373                                 float msgtype;
 374                                 w = DEATH_WEAPONOF(deathtype);
 375                                 if(w == WEP_LASER && ((cvar("g_balance_laser_secondary_gauntlet") && w & HITTYPE_SECONDARY) || (cvar("g_balance_laser_primary_gauntlet") && !(w & HITTYPE_SECONDARY))))
 376                                 {
 377                                         msgtype = MSG_KILL_MELEE;
 378                                         deathtype = KILL_FRAG_GAUNTLET;
 379                                 }
 380                                 else if(w == WEP_SHOTGUN && (cvar("g_balance_shotgun_secondary_melee") && w & HITTYPE_SECONDARY))
 381                                 {
 382                                         msgtype = MSG_KILL_MELEE;
 383                                         deathtype = KILL_FRAG_SHOTGUN_MELEE;
 384                                 }
 385
 386                                 Send_KillNotification(s, a, msg, deathtype, MSG_KILL);
 387
 388                                 if(g_ctf && targ.flagcarried)
 389                                 {
 390                                         UpdateFrags(attacker, ctf_score_value("score_kill"));
 391                                         PlayerScore_Add(attacker, SP_CTF_FCKILLS, 1);
 392                                         GiveFrags(attacker, targ, 0); // for logging
 393                                 }
 394                                 else
 395                                         GiveFrags(attacker, targ, 1);
 396
 397                                 if (targ.killcount > 2) {
 398                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 399                                 }
 400
 401                                 attacker.killcount = attacker.killcount + 1;
 402
 403                                 if (attacker.killcount > 2) {
 404                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 405                                 }
 406                                 else if (attacker.killcount == 3)
 407                                 {
 408                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 409                                         AnnounceTo(attacker, "03kills");
 410                                 }
 411                                 else if (attacker.killcount == 5)
 412                                 {
 413                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 414                                         AnnounceTo(attacker, "05kills");
 415                                 }
 416                                 else if (attacker.killcount == 10)
 417                                 {
 418                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 419                                         AnnounceTo(attacker, "10kills");
 420                                 }
 421                                 else if (attacker.killcount == 15)
 422                                 {
 423                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 424                                         AnnounceTo(attacker, "15kills");
 425                                 }
 426                                 else if (attacker.killcount == 20)
 427                                 {
 428                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 429                                         AnnounceTo(attacker, "20kills");
 430                                 }
 431                                 else if (attacker.killcount == 25)
 432                                 {
 433                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 434                                         AnnounceTo(attacker, "25kills");
 435                                 }
 436                                 else if (attacker.killcount == 30)
 437                                 {
 438                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 439                                         AnnounceTo(attacker, "30kills");
 440                                 }
 441                                 LogDeath("frag", deathtype, attacker, targ);
 442                         }
 443                 }
 444                 else
 445                 {
 446                         Send_CSQC_Centerprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 447                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 448                                 msg = inflictor.message;
 449                         else if (deathtype == DEATH_CUSTOM)
 450                                 msg = deathmessage;
 451
 452                         GiveFrags(targ, targ, -1);
 453                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 454                                 AnnounceTo(targ, "botlike");
 455                         }
 456                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 457
 458                         if (targ.killcount > 2)
 459                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 460
 461                         LogDeath("accident", deathtype, targ, targ);
 462                 }
 463
 464                 targ.death_origin = targ.origin;
 465                 if(targ != attacker)
 466                         targ.killer_origin = attacker.origin;
 467
 468                 // FIXME: this should go in PutClientInServer
 469                 if (targ.killcount)
 470                         targ.killcount = 0;
 471         }
 472 }
 473
 474 // these are updated by each Damage call for use in button triggering and such
 475 entity damage_targ;
 476 entity damage_inflictor;
 477 entity damage_attacker;
 478 .float prevhitsound;
 479
 480 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 481 {
 482         float mirrordamage;
 483         float mirrorforce;
 484         float teamdamage0;
 485         entity attacker_save;
 486         mirrordamage = 0;
 487         mirrorforce = 0;
 488
 489         if (gameover || targ.killcount == -666)
 490                 return;
 491
 492         local entity oldself;
 493         oldself = self;
 494         self = targ;
 495         damage_targ = targ;
 496         damage_inflictor = inflictor;
 497         damage_attacker = attacker;
 498                 attacker_save = attacker;
 499
 500         if(targ.classname == "player")
 501                 if(targ.hook)
 502                         if(targ.hook.aiment)
 503                                 if(targ.hook.aiment == attacker)
 504                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 505
 506         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 507         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 508         {
 509                 if(targ.classname == "player")
 510                         if not(IsDifferentTeam(targ, attacker))
 511                         {
 512                                 self = oldself;
 513                                 return;
 514                         }
 515         }
 516
 517         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 518         {
 519                 // These are ALWAYS lethal
 520                 // No damage modification here
 521                 // Instead, prepare the victim for his death...
 522                 targ.armorvalue = 0;
 523                 targ.spawnshieldtime = 0;
 524                 targ.health = 0.9; // this is < 1
 525                 targ.flags -= targ.flags & FL_GODMODE;
 526                 damage = 100000;
 527         }
 528         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 529         {
 530                 // no processing
 531         }
 532         else
 533         {
 534                 if (targ.classname == "player")
 535                 if (attacker.classname == "player")
 536                 if (!targ.isbot)
 537                 if (attacker.isbot)
 538                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 539
 540                 // nullify damage if teamplay is on
 541                 if(deathtype != DEATH_TELEFRAG)
 542                 if(attacker.classname == "player")
 543                 {
 544                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 545                         {
 546                                 damage = 0;
 547                                 force = '0 0 0';
 548                         }
 549                         else if(attacker.team == targ.team)
 550                         {
 551                                 if(teamplay == 1)
 552                                         damage = 0;
 553                                 else if(attacker != targ)
 554                                 {
 555                                         if(teamplay == 3)
 556                                                 damage = 0;
 557                                         else if(teamplay == 4)
 558                                         {
 559                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 560                                                 {
 561                                                         teamdamage0 = max(attacker.dmg_team, cvar("g_teamdamage_threshold"));
 562                                                         attacker.dmg_team = attacker.dmg_team + damage;
 563                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 564                                                                 mirrordamage = cvar("g_mirrordamage") * (attacker.dmg_team - teamdamage0);
 565                                                         mirrorforce = cvar("g_mirrordamage") * vlen(force);
 566                                                         if(g_minstagib)
 567                                                         {
 568                                                                 if(cvar("g_friendlyfire") == 0)
 569                                                                         damage = 0;
 570                                                         }
 571                                                         else if(g_ca)
 572                                                                 damage = 0;
 573                                                         else
 574                                                                 damage = cvar("g_friendlyfire") * damage;
 575                                                         // mirrordamage will be used LATER
 576                                                 }
 577                                                 else
 578                                                         damage = 0;
 579                                         }
 580                                 }
 581                         }
 582                 }
 583
 584                 if(targ.classname == "player")
 585                 if(attacker.classname == "player")
 586                 if(attacker != targ)
 587                 {
 588                         targ.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 589                         attacker.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 590                 }
 591
 592                 if(targ.classname == "player")
 593                 if (g_minstagib)
 594                 {
 595                         if ((deathtype == DEATH_FALL)  ||
 596                                 (deathtype == DEATH_DROWN) ||
 597                                 (deathtype == DEATH_SLIME) ||
 598                                 (deathtype == DEATH_LAVA)  ||
 599                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 600                         {
 601                                 self = oldself;
 602                                 return;
 603                         }
 604                         if(damage > 0)
 605                             damage = 10000;
 606                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 607                         {
 608                                 targ.armorvalue -= 1;
 609                                 centerprint(targ, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(targ.armorvalue)));
 610                                 damage = 0;
 611                                 targ.hitsound += 1;
 612                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 613                         }
 614                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 615                         {
 616                                 damage = 0;
 617                                 if (targ != attacker)
 618                                 {
 619                                         if ((targ.health >= 1) && (targ.classname == "player"))
 620                                                 centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "Secondary fire inflicts no damage!"));
 621                                         damage = 0;
 622                                         mirrordamage = 0;
 623                                         force = '0 0 0';
 624                                         // keep mirrorforce
 625                                         attacker = targ;
 626                                 }
 627                         }
 628                 }
 629
 630                 if not(DEATH_ISSPECIAL(deathtype))
 631                 {
 632                         damage *= g_weapondamagefactor;
 633                         mirrordamage *= g_weapondamagefactor;
 634                         force = force * g_weaponforcefactor;
 635                         mirrorforce *= g_weaponforcefactor;
 636                 }
 637
 638                 // apply strength multiplier
 639                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 640                 {
 641                         if(targ == attacker)
 642                         {
 643                                 damage = damage * cvar("g_balance_powerup_strength_selfdamage");
 644                                 force = force * cvar("g_balance_powerup_strength_selfforce");
 645                         }
 646                         else
 647                         {
 648                                 damage = damage * cvar("g_balance_powerup_strength_damage");
 649                                 force = force * cvar("g_balance_powerup_strength_force");
 650                         }
 651                 }
 652
 653                 // apply invincibility multiplier
 654                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 655                         damage = damage * cvar("g_balance_powerup_invincible_takedamage");
 656
 657                 if (targ == attacker)
 658                 {
 659                         if(g_ca || (g_cts && !cvar("g_cts_selfdamage")))
 660                                 damage = 0;
 661                         else
 662                                 damage = damage * cvar("g_balance_selfdamagepercent");  // Partial damage if the attacker hits himself
 663                 }
 664
 665                 // CTF: reduce damage/force
 666                 if(g_ctf)
 667                 if(targ == attacker)
 668                 if(targ.flagcarried)
 669                 {
 670                         damage = damage * cvar("g_ctf_flagcarrier_selfdamage");
 671                         force = force * cvar("g_ctf_flagcarrier_selfforce");
 672                 }
 673
 674                 if(g_runematch)
 675                 {
 676                         // apply strength rune
 677                         if (attacker.runes & RUNE_STRENGTH)
 678                         {
 679                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 680                                 {
 681                                         damage = damage * cvar("g_balance_rune_strength_combo_damage");
 682                                         force = force * cvar("g_balance_rune_strength_combo_force");
 683                                 }
 684                                 else
 685                                 {
 686                                         damage = damage * cvar("g_balance_rune_strength_damage");
 687                                         force = force * cvar("g_balance_rune_strength_force");
 688                                 }
 689                         }
 690                         else if (attacker.runes & CURSE_WEAK)
 691                         {
 692                                 damage = damage * cvar("g_balance_curse_weak_damage");
 693                                 force = force * cvar("g_balance_curse_weak_force");
 694                         }
 695
 696                         // apply defense rune
 697                         if (targ.runes & RUNE_DEFENSE)
 698                         {
 699                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 700                                         damage = damage * cvar("g_balance_rune_defense_combo_takedamage");
 701                                 else
 702                                         damage = damage * cvar("g_balance_rune_defense_takedamage");
 703                         }
 704                         else if (targ.runes & CURSE_VULNER)
 705                                 damage = damage * cvar("g_balance_curse_vulner_takedamage");
 706                 }
 707
 708                 // count the damage
 709                 if(attacker)
 710                 if(!targ.deadflag)
 711                 if(targ.takedamage == DAMAGE_AIM)
 712                 if(targ != attacker)
 713                 {
 714                         if(targ.classname == "player")
 715                         {
 716                                 // HEAD SHOT:
 717                                 // find height of hit on player axis
 718                                 // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 719                                 vector headmins, headmaxs, org;
 720                                 org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 721                                 headmins = org + GetHeadshotMins(targ);
 722                                 headmaxs = org + GetHeadshotMaxs(targ);
 723                                 if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 724                                 {
 725                                         deathtype |= HITTYPE_HEADSHOT;
 726                                 }
 727                         }
 728                         else if(targ.classname == "turret_head")
 729                         {
 730                                 deathtype |= HITTYPE_HEADSHOT;
 731                         }
 732                         if(deathtype & HITTYPE_HEADSHOT)
 733                                 damage *= 1 + damage_headshotbonus;
 734
 735                         if(targ.classname == "player")
 736                         {
 737                                 if(IsDifferentTeam(targ, attacker))
 738                                 {
 739                                         if(damage > 0)
 740                                         {
 741                                                 if(attacker.weapon != WEP_ELECTRO && attacker.weapon != WEP_LASER || ((attacker.weapon == WEP_ELECTRO && cvar("g_balance_electro_lightning") || attacker.weapon == WEP_LASER) && attacker.prevhitsound + cvar("sv_hitsound_antispam_time") < time))
 742                                                 {
 743                                                         if(targ.BUTTON_CHAT)
 744                                                                 attacker.typehitsound += 1;
 745                                                         else
 746                                                                 attacker.hitsound += 1;
 747                                                         attacker.prevhitsound = time;
 748                                                 }
 749
 750                                                 damage_goodhits += 1;
 751                                                 damage_gooddamage += damage;
 752
 753                                                 if not(DEATH_ISSPECIAL(deathtype))
 754                                                 {
 755                                                         if(!g_minstagib)
 756                                                         if(IsFlying(targ))
 757                                                                 yoda = 1;
 758
 759                                                         if(g_minstagib)
 760                                                         if(targ.items & IT_STRENGTH)
 761                                                                 yoda = 1;
 762
 763                                                         if(deathtype & HITTYPE_HEADSHOT)
 764                                                                 headshot = 1;
 765                                                 }
 766                                         }
 767                                 }
 768                                 else
 769                                 {
 770                                         if(deathtype != DEATH_FIRE)
 771                                                 attacker.typehitsound += 1;
 772                                         if(mirrordamage > 0)
 773                                                 if(time > attacker.teamkill_complain)
 774                                                 {
 775                                                         attacker.teamkill_complain = time + 5;
 776                                                         attacker.teamkill_soundtime = time + 0.4;
 777                                                         attacker.teamkill_soundsource = targ;
 778                                                 }
 779                                 }
 780                         }
 781                 }
 782         }
 783
 784         // apply push
 785         if (self.damageforcescale)
 786         if (vlen(force))
 787         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 788         {
 789                 self.velocity = self.velocity + self.damageforcescale * force;
 790                 self.flags &~= FL_ONGROUND;
 791                 UpdateCSQCProjectile(self);
 792         }
 793         // apply damage
 794         if (damage != 0 || (self.damageforcescale && vlen(force)))
 795         if (self.event_damage)
 796                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 797         self = oldself;
 798
 799         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 800         {
 801                 // Savage: vampire mode
 802                 if (g_vampire)
 803                 if (!g_minstagib)
 804                 if (time >= self.spawnshieldtime)
 805                 {
 806                         attacker.health += damage;
 807                 }
 808                 if(g_runematch)
 809                 {
 810                         if (attacker.runes & RUNE_VAMPIRE)
 811                         {
 812                         // apply vampire rune
 813                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 814                                 {
 815                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb");
 816                                         attacker.health = bound(
 817                                                 cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 40
 818                                                 attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb"),
 819                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 820                                 }
 821                                 else
 822                                 {
 823                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_absorb");
 824                                         attacker.health = bound(
 825                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 826                                                                                         // empathy won't let you gain health in the same way...
 827                                                 attacker.health + damage * cvar("g_balance_rune_vampire_absorb"),
 828                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 829                                         }
 830                         }
 831                         // apply empathy curse
 832                         else if (attacker.runes & CURSE_EMPATHY)
 833                         {
 834                                 attacker.health = bound(
 835                                         cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 20
 836                                         attacker.health + damage * cvar("g_balance_curse_empathy_takedamage"),
 837                                         attacker.health);
 838                         }
 839                 }
 840         }
 841
 842         // apply mirror damage if any
 843         if(mirrordamage > 0 || mirrorforce > 0)
 844         {
 845                 attacker = attacker_save;
 846                 if(g_minstagib)
 847                         if(mirrordamage > 0)
 848                         {
 849                                 // just lose extra LIVES, don't kill the player for mirror damage
 850                                 if(attacker.armorvalue > 0)
 851                                 {
 852                                         attacker.armorvalue = attacker.armorvalue - 1;
 853                                         centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 854                                         attacker.hitsound += 1;
 855                                 }
 856                                 mirrordamage = 0;
 857                         }
 858                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 859                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 860         }
 861 }
 862
 863 vector NearestPointOnBox(entity box, vector org)
 864 {
 865         vector m1, m2, nearest;
 866
 867         m1 = box.mins + box.origin;
 868         m2 = box.maxs + box.origin;
 869
 870         nearest_x = bound(m1_x, org_x, m2_x);
 871         nearest_y = bound(m1_y, org_y, m2_y);
 872         nearest_z = bound(m1_z, org_z, m2_z);
 873
 874         return nearest;
 875 }
 876
 877 void Damage_RecordDamage(entity attacker, float deathtype, float damage)
 878 {
 879         float weaponid;
 880         weaponid = DEATH_WEAPONOF(deathtype);
 881
 882         if not(inWarmupStage)
 883         if (weaponid)
 884         if ((clienttype(attacker) == CLIENTTYPE_REAL) | (clienttype(attacker) == CLIENTTYPE_BOT)) {
 885                 attacker.stats_hit[weaponid - 1] += damage;
 886                 attacker.stat_hit = weaponid + 64 * floor(attacker.stats_hit[weaponid - 1]);
 887         }
 888 }
 889
 890 float RadiusDamage_running;
 891 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 892 // Returns total damage applies to creatures
 893 {
 894         entity  targ;
 895         float   finaldmg;
 896         float   power;
 897         vector  blastorigin;
 898         vector  force;
 899         vector  diff;
 900         vector  center;
 901         vector  nearest;
 902         float   total_damage_to_creatures;
 903         entity  next;
 904         float   tfloordmg;
 905         float   tfloorforce;
 906
 907         float stat_damagedone;
 908         float stat_maxdamage;
 909
 910         if(RadiusDamage_running)
 911         {
 912                 string save;
 913                 print("RadiusDamage called recursively!\n");
 914                 print("Expect stuff to go HORRIBLY wrong.\n");
 915                 print("Causing a stack trace...\n");
 916                 save = cvar_string("prvm_backtraceforwarnings");
 917                 cvar_set("prvm_backtraceforwarnings", "1");
 918                 fclose(-1); // calls VM_Warning
 919                 cvar_set("prvm_backtraceforwarnings", save);
 920                 return 0;
 921         }
 922
 923         RadiusDamage_running = 1;
 924
 925         tfloordmg = cvar("g_throughfloor_damage");
 926         tfloorforce = cvar("g_throughfloor_force");
 927
 928         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 929         total_damage_to_creatures = 0;
 930
 931         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 932         if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 933         {
 934                 force = inflictor.velocity;
 935                 if(vlen(force) == 0)
 936                         force = '0 0 -1';
 937                 else
 938                         force = normalize(force);
 939                 if(forceintensity >= 0)
 940                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, attacker);
 941                 else
 942                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, attacker);
 943         }
 944
 945         stat_damagedone = 0;
 946         stat_maxdamage = 0;
 947
 948         targ = WarpZone_FindRadius (blastorigin, rad, FALSE);
 949         while (targ)
 950         {
 951                 next = targ.chain;
 952                 if (targ != inflictor)
 953                         if (ignore != targ) if(targ.takedamage)
 954                         {
 955                                 // LordHavoc: measure distance to nearest point on target (not origin)
 956                                 // (this guarentees 100% damage on a touch impact)
 957                                 nearest = targ.WarpZone_findradius_nearest;
 958                                 diff = targ.WarpZone_findradius_dist;
 959                                 // round up a little on the damage to ensure full damage on impacts
 960                                 // and turn the distance into a fraction of the radius
 961                                 power = 1 - ((vlen (diff) - 2) / rad);
 962                                 //bprint(" ");
 963                                 //bprint(ftos(power));
 964                                 //if (targ == attacker)
 965                                 //      print(ftos(power), "\n");
 966                                 if (power > 0)
 967                                 {
 968                                         if (power > 1)
 969                                                 power = 1;
 970                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 971                                         if (finaldmg > 0)
 972                                         {
 973                                                 local float a;
 974                                                 local float c;
 975                                                 local float hits;
 976                                                 local float total;
 977                                                 local float hitratio;
 978                                                 local vector hitloc;
 979                                                 local vector myblastorigin;
 980                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 981                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
 982                                                 // if it's a player, use the view origin as reference
 983                                                 if (targ.classname == "player")
 984                                                         center = targ.origin + targ.view_ofs;
 985                                                 force = normalize(center - myblastorigin);
 986                                                 force = force * (finaldmg / coredamage) * forceintensity;
 987                                                 // test line of sight to multiple positions on box,
 988                                                 // and do damage if any of them hit
 989                                                 hits = 0;
 990                                                 if (targ.classname == "player")
 991                                                         total = ceil(bound(1, finaldmg, 50));
 992                                                 else
 993                                                         total = ceil(bound(1, finaldmg/10, 5));
 994                                                 hitloc = nearest;
 995                                                 c = 0;
 996                                                 while (c < total)
 997                                                 {
 998                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 999                                                         WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1000                                                         if (trace_fraction == 1 || trace_ent == targ)
1001                                                         {
1002                                                                 hits = hits + 1;
1003                                                                 if (hits > 1)
1004                                                                         hitloc = hitloc + nearest;
1005                                                                 else
1006                                                                         hitloc = nearest;
1007                                                         }
1008                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1009                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1010                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1011                                                         c = c + 1;
1012                                                 }
1013                                                 nearest = hitloc * (1 / max(1, hits));
1014                                                 hitratio = (hits / total);
1015                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1016                                                 finaldmg = finaldmg * a;
1017                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1018                                                 force = force * a;
1019                                                 //if (targ == attacker)
1020                                                 //{
1021                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1022                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1023                                                 //      print(" (", ftos(a), ")\n");
1024                                                 //}
1025                                                 if(hits || tfloordmg || tfloorforce)
1026                                                 {
1027                                                         if(targ.iscreature)
1028                                                         {
1029                                                                 total_damage_to_creatures += finaldmg;
1030
1031                                                                 if(targ.flags & FL_CLIENT)
1032                                                                 if(targ.deadflag == DEAD_NO)
1033                                                                 if(targ != attacker)
1034                                                                 if(!teamplay || targ.team != attacker.team)
1035                                                                 {
1036                                                                         stat_damagedone += finaldmg;
1037                                                                         stat_maxdamage += coredamage;
1038                                                                 }
1039                                                         }
1040
1041                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1042                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1043                                                         else
1044                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1045                                                 }
1046                                         }
1047                                 }
1048                         }
1049                 targ = next;
1050         }
1051
1052         RadiusDamage_running = 0;
1053
1054         Damage_RecordDamage(attacker, deathtype, min(stat_maxdamage, stat_damagedone));
1055
1056         return total_damage_to_creatures;
1057 }
1058
1059 .float fire_damagepersec;
1060 .float fire_endtime;
1061 .float fire_deathtype;
1062 .entity fire_owner;
1063 .float fire_hitsound;
1064 .entity fire_burner;
1065
1066 void fireburner_think();
1067
1068 float Fire_IsBurning(entity e)
1069 {
1070         return (time < e.fire_endtime);
1071 }
1072
1073 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1074 {
1075         float dps;
1076         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1077
1078         if(e.classname == "player")
1079         {
1080                 if(e.deadflag)
1081                         return -1;
1082         }
1083         else
1084         {
1085                 if(!e.fire_burner)
1086                 {
1087                         // print("adding a fire burner to ", e.classname, "\n");
1088                         e.fire_burner = spawn();
1089                         e.fire_burner.classname = "fireburner";
1090                         e.fire_burner.think = fireburner_think;
1091                         e.fire_burner.nextthink = time;
1092                         e.fire_burner.owner = e;
1093                 }
1094         }
1095
1096         t = max(t, 0.1);
1097         dps = d / t;
1098         if(Fire_IsBurning(e))
1099         {
1100                 mintime = e.fire_endtime - time;
1101                 maxtime = max(mintime, t);
1102
1103                 mindps = e.fire_damagepersec;
1104                 maxdps = max(mindps, dps);
1105
1106                 if(maxtime > mintime || maxdps > mindps)
1107                 {
1108                         mindamage = mindps * mintime;
1109                         maxdamage = mindamage + d;
1110
1111                         // interval [mintime, maxtime] * [mindps, maxdps]
1112                         // intersected with
1113                         // [mindamage, maxdamage]
1114                         // maximum of this!
1115
1116                         if(maxdamage >= maxtime * maxdps)
1117                         {
1118                                 totaltime = maxtime;
1119                                 totaldamage = maxtime * maxdps;
1120
1121                                 // this branch increases totaldamage if either t > mintime, or dps > mindps
1122                         }
1123                         else
1124                         {
1125                                 // maxdamage is inside the interval!
1126                                 // first, try to use mindps; only if this fails, increase dps as needed
1127                                 totaltime = min(maxdamage / mindps, maxtime); // maxdamage / mindps >= mindamage / mindps = mintime
1128                                 totaldamage = maxdamage;
1129                                 // can totaldamage / totaltime be >= maxdps?
1130                                 // max(mindps, maxdamage / maxtime) >= maxdps?
1131                                 // we know maxdamage < maxtime * maxdps
1132                                 // so it cannot be
1133
1134                                 // this branch ALWAYS increases totaldamage, but requires maxdamage < maxtime * maxdps
1135                         }
1136
1137                         // total conditions for increasing:
1138                         //     maxtime > mintime OR maxdps > mindps OR maxtime * maxdps > maxdamage
1139                         // however:
1140                         //     if maxtime = mintime, maxdps = mindps
1141                         // then:
1142                         //     maxdamage = mindamage + d
1143                         //     mindamage = mindps * mintime = maxdps * maxtime < maxdamage!
1144                         // so the last condition is not needed
1145
1146                         e.fire_damagepersec = totaldamage / totaltime;
1147                         e.fire_endtime = time + totaltime;
1148                         if(totaldamage > 1.2 * mindamage)
1149                         {
1150                                 e.fire_deathtype = dt;
1151                                 if(e.fire_owner != o)
1152                                 {
1153                                         e.fire_owner = o;
1154                                         e.fire_hitsound = FALSE;
1155                                 }
1156                         }
1157                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1158                 }
1159                 else
1160                         return 0;
1161         }
1162         else
1163         {
1164                 e.fire_damagepersec = dps;
1165                 e.fire_endtime = time + t;
1166                 e.fire_deathtype = dt;
1167                 e.fire_owner = o;
1168                 e.fire_hitsound = FALSE;
1169                 return d;
1170         }
1171 }
1172
1173 void Fire_ApplyDamage(entity e)
1174 {
1175         float t, d, hi, ty;
1176         entity o;
1177
1178         if not(Fire_IsBurning(e))
1179                 return;
1180
1181         o = e.owner;
1182         while(o.owner)
1183                 o = o.owner;
1184         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1185                 o = e.fire_owner;
1186
1187         // water and slime stop fire
1188         if(e.waterlevel)
1189         if(e.watertype != CONTENT_LAVA)
1190                 e.fire_endtime = 0;
1191
1192         t = min(frametime, e.fire_endtime - time);
1193         d = e.fire_damagepersec * t;
1194
1195         hi = e.fire_owner.hitsound;
1196         ty = e.fire_owner.typehitsound;
1197         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1198         if(e.fire_hitsound && e.fire_owner)
1199         {
1200                 e.fire_owner.hitsound = hi;
1201                 e.fire_owner.typehitsound = ty;
1202         }
1203         e.fire_hitsound = TRUE;
1204
1205         Damage_RecordDamage(e.fire_owner, e.fire_deathtype, d);
1206
1207         if not(IS_INDEPENDENT_PLAYER(e))
1208         FOR_EACH_PLAYER(other) if(e != other)
1209         {
1210                 if(other.classname == "player")
1211                 if(other.deadflag == DEAD_NO)
1212                 if not(IS_INDEPENDENT_PLAYER(other))
1213                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1214                 {
1215                         t = cvar("g_balance_firetransfer_time") * (e.fire_endtime - time);
1216                         d = cvar("g_balance_firetransfer_damage") * e.fire_damagepersec * t;
1217                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1218                 }
1219         }
1220 }
1221
1222 void Fire_ApplyEffect(entity e)
1223 {
1224         if(Fire_IsBurning(e))
1225                 e.effects |= EF_FLAME;
1226         else
1227                 e.effects &~= EF_FLAME;
1228 }
1229
1230 void fireburner_think()
1231 {
1232         // for players, this is done in the regular loop
1233         if(wasfreed(self.owner))
1234         {
1235                 remove(self);
1236                 return;
1237         }
1238         Fire_ApplyEffect(self.owner);
1239         if(!Fire_IsBurning(self.owner))
1240         {
1241                 self.owner.fire_burner = world;
1242                 remove(self);
1243                 return;
1244         }
1245         Fire_ApplyDamage(self.owner);
1246         self.nextthink = time;
1247 }