qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189         }
 190
 191         attacker.totalfrags += f;
 192
 193         if(f)
 194                 UpdateFrags(attacker, f);
 195 }
 196
 197 string AppendItemcodes(string s, entity player)
 198 {
 199         float w;
 200         w = player.weapon;
 201         //if(w == 0)
 202         //      w = player.switchweapon;
 203         if(w == 0)
 204                 w = player.cnt; // previous weapon!
 205         s = strcat(s, ftos(w));
 206         if(time < player.strength_finished)
 207                 s = strcat(s, "S");
 208         if(time < player.invincible_finished)
 209                 s = strcat(s, "I");
 210         if(player.flagcarried != world)
 211                 s = strcat(s, "F");
 212         if(player.BUTTON_CHAT)
 213                 s = strcat(s, "T");
 214         if(player.kh_next)
 215                 s = strcat(s, "K");
 216         return s;
 217 }
 218
 219 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 220 {
 221         string s;
 222         if(!autocvar_sv_eventlog)
 223                 return;
 224         s = strcat(":kill:", mode);
 225         s = strcat(s, ":", ftos(killer.playerid));
 226         s = strcat(s, ":", ftos(killed.playerid));
 227         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 228         s = strcat(s, ":items=");
 229         s = AppendItemcodes(s, killer);
 230         if(killed != killer)
 231         {
 232                 s = strcat(s, ":victimitems=");
 233                 s = AppendItemcodes(s, killed);
 234         }
 235         GameLogEcho(s);
 236 }
 237
 238 void Obituary_SpecialDeath(
 239         entity notif_target,
 240         float murder,
 241         float deathtype,
 242         string s1, string s2, string s3,
 243         float f1, float f2, float f3)
 244 {
 245         if(DEATH_ISSPECIAL(deathtype))
 246         {
 247                 entity deathent = deathtypes[(deathtype - DT_FIRST) - 1];
 248                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 249
 250                 if(murder)
 251                 {
 252                         if(deathent.death_msgmurder)
 253                         {
 254                                 Send_Notification_WOVA(
 255                                         NOTIF_ONE,
 256                                         notif_target,
 257                                         MSG_MULTI,
 258                                         deathent.death_msgmurder.nent_id,
 259                                         s1, s2, s3, "",
 260                                         f1, f2, f3, 0
 261                                 );
 262                                 Send_Notification_WOVA(
 263                                         NOTIF_ALL_EXCEPT,
 264                                         notif_target,
 265                                         MSG_INFO,
 266                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 267                                         s1, s2, s3, "",
 268                                         f1, f2, f3, 0
 269                                 );
 270                         }
 271                 }
 272                 else
 273                 {
 274                         if(deathent.death_msgself)
 275                         {
 276                                 Send_Notification_WOVA(
 277                                         NOTIF_ONE,
 278                                         notif_target,
 279                                         MSG_MULTI,
 280                                         deathent.death_msgself.nent_id,
 281                                         s1, s2, s3, "",
 282                                         f1, f2, f3, 0
 283                                 );
 284                                 Send_Notification_WOVA(
 285                                         NOTIF_ALL_EXCEPT,
 286                                         notif_target,
 287                                         MSG_INFO,
 288                                         deathent.death_msgself.nent_msginfo.nent_id,
 289                                         s1, s2, s3, "",
 290                                         f1, f2, f3, 0
 291                                 );
 292                         }
 293                 }
 294         }
 295         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 296 }
 297
 298 float w_deathtype;
 299 float Obituary_WeaponDeath(
 300         entity notif_target,
 301         float murder,
 302         float deathtype,
 303         string s1, string s2, string s3,
 304         float f1, float f2)
 305 {
 306         float death_weapon = DEATH_WEAPONOF(deathtype);
 307         if(death_weapon)
 308         {
 309                 w_deathtype = deathtype;
 310                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 311                 w_deathtype = FALSE;
 312
 313                 if(death_message)
 314                 {
 315                         Send_Notification_WOVA(
 316                                 NOTIF_ONE,
 317                                 notif_target,
 318                                 MSG_MULTI,
 319                                 death_message,
 320                                 s1, s2, s3, "",
 321                                 f1, f2, 0, 0
 322                         );
 323                         Send_Notification_WOVA(
 324                                 NOTIF_ALL_EXCEPT,
 325                                 notif_target,
 326                                 MSG_INFO,
 327                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 328                                 s1, s2, s3, "",
 329                                 f1, f2, 0, 0
 330                         );
 331                 }
 332                 else
 333                 {
 334                         dprint(sprintf(
 335                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 336                                 deathtype,
 337                                 death_weapon
 338                         ));
 339                 }
 340
 341                 return TRUE;
 342         }
 343         return FALSE;
 344 }
 345
 346 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 347 {
 348         // Sanity check
 349         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 350
 351         // Declarations
 352         float notif_firstblood = FALSE;
 353         float kill_count_to_attacker, kill_count_to_target;
 354
 355         // Set final information for the death
 356         targ.death_origin = targ.origin;
 357         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 358         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 359
 360         #ifdef NOTIFICATIONS_DEBUG
 361         Debug_Notification(
 362                 sprintf(
 363                         "Obituary(%s, %s, %s, %s = %d);\n",
 364                         attacker.netname,
 365                         inflictor.netname,
 366                         targ.netname,
 367                         Deathtype_Name(deathtype),
 368                         deathtype
 369                 )
 370         );
 371         #endif
 372
 373         // =======
 374         // SUICIDE
 375         // =======
 376         if(targ == attacker)
 377         {
 378                 if(DEATH_ISSPECIAL(deathtype))
 379                 {
 380                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 381                         {
 382                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 383                         }
 384                         else
 385                         {
 386                                 switch(deathtype)
 387                                 {
 388                                         case DEATH_MIRRORDAMAGE:
 389                                         {
 390                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 391                                                 break;
 392                                         }
 393
 394                                         default:
 395                                         {
 396                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 397                                                 break;
 398                                         }
 399                                 }
 400                         }
 401                 }
 402                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 403                 {
 404                         backtrace("SUICIDE: what the hell happened here?\n");
 405                         return;
 406                 }
 407                 LogDeath("suicide", deathtype, targ, targ);
 408                 GiveFrags(attacker, targ, -1, deathtype);
 409         }
 410
 411         // ======
 412         // MURDER
 413         // ======
 414         else if(IS_PLAYER(attacker))
 415         {
 416                 if(!IsDifferentTeam(attacker, targ))
 417                 {
 418                         LogDeath("tk", deathtype, attacker, targ);
 419                         GiveFrags(attacker, targ, -1, deathtype);
 420
 421                         attacker.killcount = 0;
 422
 423                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 424                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 425                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 426
 427                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 428                         // No need for specific death/weapon messages...
 429                 }
 430                 else
 431                 {
 432                         LogDeath("frag", deathtype, attacker, targ);
 433                         GiveFrags(attacker, targ, 1, deathtype);
 434
 435                         attacker.taunt_soundtime = time + 1;
 436                         attacker.killcount = attacker.killcount + 1;
 437
 438                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 439                                 case counta: \
 440                                 { \
 441                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 442                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 443                                         break; \
 444                                 }
 445                         switch(attacker.killcount)
 446                         {
 447                                 KILL_SPREE_LIST
 448                                 default: break;
 449                         }
 450                         #undef SPREE_ITEM
 451
 452                         if(!checkrules_firstblood)
 453                         {
 454                                 checkrules_firstblood = TRUE;
 455                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 456                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 457                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 458
 459                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 460                                 kill_count_to_attacker = -1;
 461                                 kill_count_to_target = -2;
 462                         }
 463                         else
 464                         {
 465                                 kill_count_to_attacker = attacker.killcount;
 466                                 kill_count_to_target = 0;
 467                         }
 468
 469                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
 470                         if(targ.istypefrag)
 471                         {
 472                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 473                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 474                                 else
 475                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 476
 477                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 478                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 479                                 else
 480                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 481                         }
 482                         else
 483                         {
 484                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 485                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 486                                 else
 487                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 488
 489                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 490                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 491                                 else
 492                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 493                         }
 494
 495                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 496                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 497                 }
 498         }
 499
 500         // =============
 501         // ACCIDENT/TRAP
 502         // =============
 503         else
 504         {
 505                 switch(deathtype)
 506                 {
 507                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 508                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 509                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 510                         /*case DEATH_HURTTRIGGER:
 511                         {
 512                                 s1 = targ.netname;
 513                                 s2 = inflictor.message;
 514                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 515                                 break;
 516                         }*/
 517
 518                         case DEATH_CUSTOM:
 519                         {
 520                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 521                                         targ.netname,
 522                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 523                                         deathlocation,
 524                                         targ.killcount,
 525                                         0,
 526                                         0);
 527                                 break;
 528                         }
 529
 530                         default:
 531                         {
 532                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 533                                 break;
 534                         }
 535                 }
 536
 537                 LogDeath("accident", deathtype, targ, targ);
 538                 GiveFrags(targ, targ, -1, deathtype);
 539
 540                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 541                 {
 542                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 543                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 544                 }
 545         }
 546
 547         // reset target kill count
 548         if(targ.killcount) { targ.killcount = 0; }
 549 }
 550
 551 // these are updated by each Damage call for use in button triggering and such
 552 entity damage_targ;
 553 entity damage_inflictor;
 554 entity damage_attacker;
 555
 556 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 557 {
 558         float mirrordamage;
 559         float mirrorforce;
 560         float complainteamdamage = 0;
 561         entity attacker_save;
 562         mirrordamage = 0;
 563         mirrorforce = 0;
 564
 565         if (gameover || targ.killcount == -666)
 566                 return;
 567
 568         entity oldself;
 569         oldself = self;
 570         self = targ;
 571         damage_targ = targ;
 572         damage_inflictor = inflictor;
 573         damage_attacker = attacker;
 574                 attacker_save = attacker;
 575
 576         if(targ.classname == "player")
 577                 if(targ.hook)
 578                         if(targ.hook.aiment)
 579                                 if(targ.hook.aiment == attacker)
 580                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 581
 582         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 583         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 584         {
 585                 if(targ.classname == "player")
 586                         if not(IsDifferentTeam(targ, attacker))
 587                         {
 588                                 self = oldself;
 589                                 return;
 590                         }
 591         }
 592
 593         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 594         {
 595                 // These are ALWAYS lethal
 596                 // No damage modification here
 597                 // Instead, prepare the victim for his death...
 598                 targ.armorvalue = 0;
 599                 targ.spawnshieldtime = 0;
 600                 targ.health = 0.9; // this is < 1
 601                 targ.flags -= targ.flags & FL_GODMODE;
 602                 damage = 100000;
 603         }
 604         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 605         {
 606                 // no processing
 607         }
 608         else
 609         {
 610                 /*
 611                 skill based bot damage? gtfo. (tZork)
 612                 if (targ.classname == "player")
 613                 if (attacker.classname == "player")
 614                 if (!targ.isbot)
 615                 if (attacker.isbot)
 616                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 617         */
 618
 619                 // nullify damage if teamplay is on
 620                 if(deathtype != DEATH_TELEFRAG)
 621                 if(attacker.classname == "player")
 622                 {
 623                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 624                         {
 625                                 damage = 0;
 626                                 force = '0 0 0';
 627                         }
 628                         else if(!IsDifferentTeam(attacker, targ))
 629                         {
 630                                 if(autocvar_teamplay_mode == 1)
 631                                         damage = 0;
 632                                 else if(attacker != targ)
 633                                 {
 634                                         if(autocvar_teamplay_mode == 3)
 635                                                 damage = 0;
 636                                         else if(autocvar_teamplay_mode == 4)
 637                                         {
 638                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 639                                                 {
 640                                                         attacker.dmg_team = attacker.dmg_team + damage;
 641                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 642                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 643                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 644                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 645                                                         if(g_minstagib)
 646                                                         {
 647                                                                 if(autocvar_g_friendlyfire == 0)
 648                                                                         damage = 0;
 649                                                         }
 650                                                         else if(g_ca)
 651                                                                 damage = 0;
 652                                                         else
 653                                                                 damage = autocvar_g_friendlyfire * damage;
 654                                                         // mirrordamage will be used LATER
 655
 656                                                         if(autocvar_g_mirrordamage_virtual)
 657                                                         {
 658                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 659                                                                 attacker.dmg_take += v_x;
 660                                                                 attacker.dmg_save += v_y;
 661                                                                 attacker.dmg_inflictor = inflictor;
 662                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 663                                                                 mirrorforce = 0;
 664                                                         }
 665
 666                                                         if(autocvar_g_friendlyfire_virtual)
 667                                                         {
 668                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 669                                                                 targ.dmg_take += v_x;
 670                                                                 targ.dmg_save += v_y;
 671                                                                 targ.dmg_inflictor = inflictor;
 672                                                                 damage = 0;
 673                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 674                                                                         force = '0 0 0';
 675                                                         }
 676                                                 }
 677                                                 else
 678                                                         damage = 0;
 679                                         }
 680                                 }
 681                         }
 682                 }
 683
 684                 if(targ.classname == "player")
 685                 if(attacker.classname == "player")
 686                 if(attacker != targ)
 687                 {
 688                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 689                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 690                 }
 691
 692                 if(targ.classname == "player")
 693                 if (g_minstagib)
 694                 {
 695                         if ((deathtype == DEATH_FALL)  ||
 696                                 (deathtype == DEATH_DROWN) ||
 697                                 (deathtype == DEATH_SLIME) ||
 698                                 (deathtype == DEATH_LAVA)  ||
 699                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 700                         {
 701                                 self = oldself;
 702                                 return;
 703                         }
 704                         if(damage > 0)
 705                             damage = 10000;
 706                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 707                         {
 708                                 targ.armorvalue -= 1;
 709                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 710                                 damage = 0;
 711                                 targ.hitsound += 1;
 712                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 713                         }
 714                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 715                         {
 716                                 damage = 0;
 717                                 mirrordamage = 0;
 718                                 complainteamdamage = 0;
 719                                 if (targ != attacker)
 720                                 {
 721                                         if ((targ.health >= 1) && (targ.classname == "player"))
 722                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 723                                         force = '0 0 0';
 724                                         // keep mirrorforce
 725                                         attacker = targ;
 726                                 }
 727                         }
 728                 }
 729
 730                 if not(DEATH_ISSPECIAL(deathtype))
 731                 {
 732                         damage *= g_weapondamagefactor;
 733                         mirrordamage *= g_weapondamagefactor;
 734                         complainteamdamage *= g_weapondamagefactor;
 735                         force = force * g_weaponforcefactor;
 736                         mirrorforce *= g_weaponforcefactor;
 737                 }
 738
 739                 // should this be changed at all? If so, in what way?
 740                 frag_attacker = attacker;
 741                 frag_target = targ;
 742                 frag_damage = damage;
 743                 frag_force = force;
 744         frag_deathtype = deathtype;
 745                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 746                 damage = frag_damage;
 747                 force = frag_force;
 748
 749                 // apply strength multiplier
 750                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 751                 {
 752                         if(targ == attacker)
 753                         {
 754                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 755                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 756                         }
 757                         else
 758                         {
 759                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 760                                 force = force * autocvar_g_balance_powerup_strength_force;
 761                         }
 762                 }
 763
 764                 // apply invincibility multiplier
 765                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 766                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 767
 768                 if (targ == attacker)
 769                 {
 770                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 771                                 damage = 0;
 772                         else
 773                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 774                 }
 775
 776                 // count the damage
 777                 if(attacker)
 778                 if(!targ.deadflag)
 779                 if(targ.takedamage == DAMAGE_AIM)
 780                 if(targ != attacker)
 781                 {
 782                         entity victim;
 783                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 784                                 victim = targ.owner;
 785                         else
 786                                 victim = targ;
 787
 788                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 789                         {
 790                                 if(IsDifferentTeam(victim, attacker))
 791                                 {
 792                                         if(damage > 0)
 793                                         {
 794                                                 if(deathtype != DEATH_FIRE)
 795                                                 {
 796                                                         if(victim.BUTTON_CHAT)
 797                                                                 attacker.typehitsound += 1;
 798                                                         else
 799                                                                 attacker.hitsound += 1;
 800                                                 }
 801
 802                                                 damage_goodhits += 1;
 803                                                 damage_gooddamage += damage;
 804
 805                                                 if not(DEATH_ISSPECIAL(deathtype))
 806                                                 {
 807                                                         if(targ.classname == "player") // don't do this for vehicles
 808                                                         if(!g_minstagib)
 809                                                         if(IsFlying(victim))
 810                                                                 yoda = 1;
 811
 812                                                         if(g_minstagib)
 813                                                         if(victim.items & IT_STRENGTH)
 814                                                                 yoda = 1;
 815                                                 }
 816                                         }
 817                                 }
 818                                 else
 819                                 {
 820                                         if(deathtype != DEATH_FIRE)
 821                                         {
 822                                                 attacker.typehitsound += 1;
 823                                         }
 824                                         if(complainteamdamage > 0)
 825                                                 if(time > attacker.teamkill_complain)
 826                                                 {
 827                                                         attacker.teamkill_complain = time + 5;
 828                                                         attacker.teamkill_soundtime = time + 0.4;
 829                                                         attacker.teamkill_soundsource = targ;
 830                                                 }
 831                                 }
 832                         }
 833                 }
 834         }
 835
 836         // apply push
 837         if (self.damageforcescale)
 838         if (vlen(force))
 839         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 840         {
 841                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 842                 if(self.movetype == MOVETYPE_PHYSICS)
 843                 {
 844                         entity farcent;
 845                         farcent = spawn();
 846                         farcent.classname = "farce";
 847                         farcent.enemy = self;
 848                         farcent.movedir = farce * 10;
 849                         if(self.mass)
 850                                 farcent.movedir = farcent.movedir * self.mass;
 851                         farcent.origin = hitloc;
 852                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 853                         farcent.nextthink = time + 0.1;
 854                         farcent.think = SUB_Remove;
 855                 }
 856                 else
 857                         self.velocity = self.velocity + farce;
 858                 self.flags &~= FL_ONGROUND;
 859                 UpdateCSQCProjectile(self);
 860         }
 861         // apply damage
 862         if (damage != 0 || (self.damageforcescale && vlen(force)))
 863         if (self.event_damage)
 864                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 865         self = oldself;
 866
 867         // apply mirror damage if any
 868         if(mirrordamage > 0 || mirrorforce > 0)
 869         {
 870                 attacker = attacker_save;
 871                 if(g_minstagib)
 872                 if(mirrordamage > 0)
 873                 {
 874                         // just lose extra LIVES, don't kill the player for mirror damage
 875                         if(attacker.armorvalue > 0)
 876                         {
 877                                 attacker.armorvalue = attacker.armorvalue - 1;
 878                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 879                                 attacker.hitsound += 1;
 880                         }
 881                         mirrordamage = 0;
 882                 }
 883
 884                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 885                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 886         }
 887 }
 888
 889 float RadiusDamage_running;
 890 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 891         // Returns total damage applies to creatures
 892 {
 893         entity  targ;
 894         vector  blastorigin;
 895         vector  force;
 896         float   total_damage_to_creatures;
 897         entity  next;
 898         float   tfloordmg;
 899         float   tfloorforce;
 900
 901         float stat_damagedone;
 902
 903         if(RadiusDamage_running)
 904         {
 905                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 906                 return 0;
 907         }
 908
 909         RadiusDamage_running = 1;
 910
 911         tfloordmg = autocvar_g_throughfloor_damage;
 912         tfloorforce = autocvar_g_throughfloor_force;
 913
 914         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 915         total_damage_to_creatures = 0;
 916
 917         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 918                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 919                 {
 920                         force = inflictor.velocity;
 921                         if(vlen(force) == 0)
 922                                 force = '0 0 -1';
 923                         else
 924                                 force = normalize(force);
 925                         if(forceintensity >= 0)
 926                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 927                         else
 928                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 929                 }
 930
 931         stat_damagedone = 0;
 932
 933         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 934         while (targ)
 935         {
 936                 next = targ.chain;
 937                 if (targ != inflictor)
 938                         if (ignore != targ) if(targ.takedamage)
 939                         {
 940                                 vector nearest;
 941                                 vector diff;
 942                                 float power;
 943
 944                                 // LordHavoc: measure distance to nearest point on target (not origin)
 945                                 // (this guarentees 100% damage on a touch impact)
 946                                 nearest = targ.WarpZone_findradius_nearest;
 947                                 diff = targ.WarpZone_findradius_dist;
 948                                 // round up a little on the damage to ensure full damage on impacts
 949                                 // and turn the distance into a fraction of the radius
 950                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 951                                 //bprint(" ");
 952                                 //bprint(ftos(power));
 953                                 //if (targ == attacker)
 954                                 //      print(ftos(power), "\n");
 955                                 if (power > 0)
 956                                 {
 957                                         float finaldmg;
 958                                         if (power > 1)
 959                                                 power = 1;
 960                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 961                                         if (finaldmg > 0)
 962                                         {
 963                                                 float a;
 964                                                 float c;
 965                                                 vector hitloc;
 966                                                 vector myblastorigin;
 967                                                 vector center;
 968
 969                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 970
 971                                                 // if it's a player, use the view origin as reference
 972                                                 center = CENTER_OR_VIEWOFS(targ);
 973
 974                                                 force = normalize(center - myblastorigin);
 975                                                 force = force * (finaldmg / coredamage) * forceintensity;
 976                                                 hitloc = nearest;
 977
 978                                                 if(targ != directhitentity)
 979                                                 {
 980                                                         float hits;
 981                                                         float total;
 982                                                         float hitratio;
 983                                                         float mininv_f, mininv_d;
 984
 985                                                         // test line of sight to multiple positions on box,
 986                                                         // and do damage if any of them hit
 987                                                         hits = 0;
 988
 989                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
 990                                                         // so for a given max stddev:
 991                                                         // n = (1 / (2 * max stddev of hitratio))^2
 992
 993                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
 994                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
 995
 996                                                         if(autocvar_g_throughfloor_debug)
 997                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
 998
 999                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1000
1001                                                         if(autocvar_g_throughfloor_debug)
1002                                                                 print(sprintf(" steps=%f", total));
1003
1004                                                         if (targ.classname == "player")
1005                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1006                                                         else
1007                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1008
1009                                                         if(autocvar_g_throughfloor_debug)
1010                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1011
1012                                                         for(c = 0; c < total; ++c)
1013                                                         {
1014                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1015                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1016                                                                 if (trace_fraction == 1 || trace_ent == targ)
1017                                                                 {
1018                                                                         ++hits;
1019                                                                         if (hits > 1)
1020                                                                                 hitloc = hitloc + nearest;
1021                                                                         else
1022                                                                                 hitloc = nearest;
1023                                                                 }
1024                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1025                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1026                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1027                                                         }
1028
1029                                                         nearest = hitloc * (1 / max(1, hits));
1030                                                         hitratio = (hits / total);
1031                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1032                                                         finaldmg = finaldmg * a;
1033                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1034                                                         force = force * a;
1035
1036                                                         if(autocvar_g_throughfloor_debug)
1037                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1038                                                 }
1039
1040                                                 // laser force adjustments :P
1041                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1042                                                 {
1043                                                         if (targ == attacker)
1044                                                         {
1045                                                                 vector vel;
1046
1047                                                                 float force_zscale;
1048                                                                 float force_velocitybiasramp;
1049                                                                 float force_velocitybias;
1050
1051                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1052                                                                 if(deathtype & HITTYPE_SECONDARY)
1053                                                                 {
1054                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1055                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1056                                                                 }
1057                                                                 else
1058                                                                 {
1059                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1060                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1061                                                                 }
1062
1063                                                                 vel = targ.velocity;
1064                                                                 vel_z = 0;
1065                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1066                                                                 force =
1067                                                                         vlen(force)
1068                                                                         *
1069                                                                         normalize(normalize(force) + vel);
1070
1071                                                                 force_z *= force_zscale;
1072                                                         }
1073                                                         else
1074                                                         {
1075                                                                 if(deathtype & HITTYPE_SECONDARY)
1076                                                                 {
1077                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1078                                                                 }
1079                                                                 else
1080                                                                 {
1081                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1082                                                                 }
1083                                                         }
1084                                                 }
1085
1086                                                 //if (targ == attacker)
1087                                                 //{
1088                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1089                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1090                                                 //      print(" (", ftos(a), ")\n");
1091                                                 //}
1092                                                 if(finaldmg || vlen(force))
1093                                                 {
1094                                                         if(targ.iscreature)
1095                                                         {
1096                                                                 total_damage_to_creatures += finaldmg;
1097
1098                                                                 if(accuracy_isgooddamage(attacker, targ))
1099                                                                         stat_damagedone += finaldmg;
1100                                                         }
1101
1102                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1103                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1104                                                         else
1105                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1106                                                 }
1107                                         }
1108                                 }
1109                         }
1110                 targ = next;
1111         }
1112
1113         RadiusDamage_running = 0;
1114
1115         if(!DEATH_ISSPECIAL(deathtype))
1116                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1117
1118         return total_damage_to_creatures;
1119 }
1120
1121 .float fire_damagepersec;
1122 .float fire_endtime;
1123 .float fire_deathtype;
1124 .entity fire_owner;
1125 .float fire_hitsound;
1126 .entity fire_burner;
1127
1128 void fireburner_think();
1129
1130 float Fire_IsBurning(entity e)
1131 {
1132         return (time < e.fire_endtime);
1133 }
1134
1135 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1136 {
1137         float dps;
1138         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1139
1140         if(e.classname == "player")
1141         {
1142                 if(e.deadflag)
1143                         return -1;
1144         }
1145         else
1146         {
1147                 if(!e.fire_burner)
1148                 {
1149                         // print("adding a fire burner to ", e.classname, "\n");
1150                         e.fire_burner = spawn();
1151                         e.fire_burner.classname = "fireburner";
1152                         e.fire_burner.think = fireburner_think;
1153                         e.fire_burner.nextthink = time;
1154                         e.fire_burner.owner = e;
1155                 }
1156         }
1157
1158         t = max(t, 0.1);
1159         dps = d / t;
1160         if(Fire_IsBurning(e))
1161         {
1162                 mintime = e.fire_endtime - time;
1163                 maxtime = max(mintime, t);
1164
1165                 mindps = e.fire_damagepersec;
1166                 maxdps = max(mindps, dps);
1167
1168                 if(maxtime > mintime || maxdps > mindps)
1169                 {
1170                         // Constraints:
1171
1172                         // damage we have right now
1173                         mindamage = mindps * mintime;
1174
1175                         // damage we want to get
1176                         maxdamage = mindamage + d;
1177
1178                         // but we can't exceed maxtime * maxdps!
1179                         totaldamage = min(maxdamage, maxtime * maxdps);
1180
1181                         // LEMMA:
1182                         // Look at:
1183                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1184                         // We see:
1185                         // totaldamage <= maxtime * maxdps
1186                         // ==> totaldamage / maxdps <= maxtime.
1187                         // We also see:
1188                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1189                         //                     >= min(mintime, maxtime)
1190                         // ==> totaldamage / maxdps >= mintime.
1191
1192                         /*
1193                         // how long do we damage then?
1194                         // at least as long as before
1195                         // but, never exceed maxdps
1196                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1197                         */
1198
1199                         // alternate:
1200                         // at most as long as maximum allowed
1201                         // but, never below mindps
1202                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1203
1204                         // assuming t > mintime, dps > mindps:
1205                         // we get d = t * dps = maxtime * maxdps
1206                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1207                         // totaldamage / maxdps = maxtime
1208                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1209                         // FROM THIS:
1210                         // a) totaltime = max(mintime, maxtime) = maxtime
1211                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1212
1213                         // assuming t <= mintime:
1214                         // we get maxtime = mintime
1215                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1216                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1217
1218                         // assuming dps <= mindps:
1219                         // we get mindps = maxdps.
1220                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1221                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1222                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1223
1224                         e.fire_damagepersec = totaldamage / totaltime;
1225                         e.fire_endtime = time + totaltime;
1226                         if(totaldamage > 1.2 * mindamage)
1227                         {
1228                                 e.fire_deathtype = dt;
1229                                 if(e.fire_owner != o)
1230                                 {
1231                                         e.fire_owner = o;
1232                                         e.fire_hitsound = FALSE;
1233                                 }
1234                         }
1235                         if(accuracy_isgooddamage(o, e))
1236                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1237                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1238                 }
1239                 else
1240                         return 0;
1241         }
1242         else
1243         {
1244                 e.fire_damagepersec = dps;
1245                 e.fire_endtime = time + t;
1246                 e.fire_deathtype = dt;
1247                 e.fire_owner = o;
1248                 e.fire_hitsound = FALSE;
1249                 if(accuracy_isgooddamage(o, e))
1250                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1251                 return d;
1252         }
1253 }
1254
1255 void Fire_ApplyDamage(entity e)
1256 {
1257         float t, d, hi, ty;
1258         entity o;
1259
1260         if not(Fire_IsBurning(e))
1261                 return;
1262
1263         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1264         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1265                 o = e.fire_owner;
1266
1267         // water and slime stop fire
1268         if(e.waterlevel)
1269         if(e.watertype != CONTENT_LAVA)
1270                 e.fire_endtime = 0;
1271
1272         // ice stops fire
1273         if(e.freezetag_frozen)
1274                 e.fire_endtime = 0;
1275
1276         t = min(frametime, e.fire_endtime - time);
1277         d = e.fire_damagepersec * t;
1278
1279         hi = e.fire_owner.hitsound;
1280         ty = e.fire_owner.typehitsound;
1281         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1282         if(e.fire_hitsound && e.fire_owner)
1283         {
1284                 e.fire_owner.hitsound = hi;
1285                 e.fire_owner.typehitsound = ty;
1286         }
1287         e.fire_hitsound = TRUE;
1288
1289         if not(IS_INDEPENDENT_PLAYER(e))
1290         FOR_EACH_PLAYER(other) if(e != other)
1291         {
1292                 if(other.classname == "player")
1293                 if(other.deadflag == DEAD_NO)
1294                 if not(IS_INDEPENDENT_PLAYER(other))
1295                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1296                 {
1297                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1298                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1299                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1300                 }
1301         }
1302 }
1303
1304 void Fire_ApplyEffect(entity e)
1305 {
1306         if(Fire_IsBurning(e))
1307                 e.effects |= EF_FLAME;
1308         else
1309                 e.effects &~= EF_FLAME;
1310 }
1311
1312 void fireburner_think()
1313 {
1314         // for players, this is done in the regular loop
1315         if(wasfreed(self.owner))
1316         {
1317                 remove(self);
1318                 return;
1319         }
1320         Fire_ApplyEffect(self.owner);
1321         if(!Fire_IsBurning(self.owner))
1322         {
1323                 self.owner.fire_burner = world;
1324                 remove(self);
1325                 return;
1326         }
1327         Fire_ApplyDamage(self.owner);
1328         self.nextthink = time;
1329 }