Merge remote-tracking branch 'origin/master' into Mario/lms_updates
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_damage.qc
1 .float dmg;
2 .float dmg_edge;
3 .float dmg_force;
4 .float dmg_radius;
5
6 float Damage_DamageInfo_SendEntity(entity to, float sf)
7 {
8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
16         WriteShort(MSG_ENTITY, self.oldorigin_x);
17         WriteByte(MSG_ENTITY, self.species);
18         return TRUE;
19 }
20
21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
22 {
23         // TODO maybe call this from non-edgedamage too?
24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
25
26         entity e;
27
28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
29                 deathtype |= 0x8000;
30
31         e = spawn();
32         setorigin(e, org);
33         e.projectiledeathtype = deathtype;
34         e.dmg = coredamage;
35         e.dmg_edge = edgedamage;
36         e.dmg_radius = rad;
37         e.dmg_force = vlen(force);
38         e.velocity = force;
39         e.oldorigin_x = compressShortVector(e.velocity);
40         e.species = bloodtype;
41
42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
43 }
44
45 float checkrules_firstblood;
46
47 float yoda;
48 float damage_goodhits;
49 float damage_gooddamage;
50
51 .float dmg_team;
52 .float teamkill_complain;
53 .float teamkill_soundtime;
54 .entity teamkill_soundsource;
55 .entity pusher;
56 .float istypefrag;
57 .float taunt_soundtime;
58
59
60 float IsDifferentTeam(entity a, entity b)
61 {
62         if(teamplay)
63         {
64                 if(a.team == b.team)
65                         return 0;
66         }
67         else
68         {
69                 if(a == b)
70                         return 0;
71         }
72         return 1;
73 }
74
75 float IsFlying(entity a)
76 {
77         if(a.flags & FL_ONGROUND)
78                 return 0;
79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
80                 return 0;
81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
82         if(trace_fraction < 1)
83                 return 0;
84         return 1;
85 }
86
87 void UpdateFrags(entity player, float f)
88 {
89         PlayerTeamScore_AddScore(player, f);
90 }
91
92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
93 void W_SwitchWeapon_Force(entity e, float w);
94 entity GiveFrags_randomweapons;
95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
96 {
97         // TODO route through PlayerScores instead
98         if(gameover) return;
99
100         if(f < 0)
101         {
102                 if(targ == attacker)
103                 {
104                         // suicide
105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
106                 }
107                 else
108                 {
109                         // teamkill
110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
111                 }
112         }
113         else
114         {
115                 // regular frag
116                 PlayerScore_Add(attacker, SP_KILLS, 1);
117                 if(targ.playerid)
118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
119         }
120
121         PlayerScore_Add(targ, SP_DEATHS, 1);
122
123         if(targ != attacker) // not for suicides
124         if(g_weaponarena_random)
125         {
126                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
127                 float culprit;
128                 culprit = DEATH_WEAPONOF(deathtype);
129                 if(!culprit)
130                         culprit = attacker.weapon;
131                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
132                         culprit = attacker.weapon;
133
134                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
135                 {
136                         // no exchange
137                 }
138                 else
139                 {
140                         if(!GiveFrags_randomweapons)
141                         {
142                                 GiveFrags_randomweapons = spawn();
143                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
144                         }
145
146                         if(inWarmupStage)
147                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
148                         else
149                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
150
151                         // all others (including the culprit): remove
152                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
153                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
154
155                         // among the remaining ones, choose one by random
156                         W_RandomWeapons(GiveFrags_randomweapons, 1);
157
158                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
159                         {
160                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
161                                 WEPSET_ANDNOT_EW(attacker, culprit);
162                         }
163                 }
164
165                 // after a frag, choose another random weapon set
166                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
167                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
168         }
169
170         // FIXME fix the mess this is (we have REAL points now!)
171         entity oldself;
172         oldself = self;
173         self = attacker;
174         frag_attacker = attacker;
175         frag_target = targ;
176         frag_score = f;
177         if(MUTATOR_CALLHOOK(GiveFragsForKill))
178         {
179                 f = frag_score;
180                 self = oldself;
181         }
182         else
183         {
184                 self = oldself;
185         }
186
187         attacker.totalfrags += f;
188
189         if(f)
190                 UpdateFrags(attacker, f);
191 }
192
193 string AppendItemcodes(string s, entity player)
194 {
195         float w;
196         w = player.weapon;
197         //if(w == 0)
198         //      w = player.switchweapon;
199         if(w == 0)
200                 w = player.cnt; // previous weapon!
201         s = strcat(s, ftos(w));
202         if(time < player.strength_finished)
203                 s = strcat(s, "S");
204         if(time < player.invincible_finished)
205                 s = strcat(s, "I");
206         if(player.flagcarried != world)
207                 s = strcat(s, "F");
208         if(player.BUTTON_CHAT)
209                 s = strcat(s, "T");
210         if(player.kh_next)
211                 s = strcat(s, "K");
212         return s;
213 }
214
215 void LogDeath(string mode, float deathtype, entity killer, entity killed)
216 {
217         string s;
218         if(!autocvar_sv_eventlog)
219                 return;
220         s = strcat(":kill:", mode);
221         s = strcat(s, ":", ftos(killer.playerid));
222         s = strcat(s, ":", ftos(killed.playerid));
223         s = strcat(s, ":type=", Deathtype_Name(deathtype));
224         s = strcat(s, ":items=");
225         s = AppendItemcodes(s, killer);
226         if(killed != killer)
227         {
228                 s = strcat(s, ":victimitems=");
229                 s = AppendItemcodes(s, killed);
230         }
231         GameLogEcho(s);
232 }
233
234 void Obituary_SpecialDeath(
235         entity notif_target,
236         float murder,
237         float deathtype,
238         string s1, string s2, string s3,
239         float f1, float f2, float f3)
240 {
241         if(DEATH_ISSPECIAL(deathtype))
242         {
243                 entity deathent = deathtypes[(deathtype - DT_FIRST) - 1];
244                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
245
246                 if(murder)
247                 {
248                         if(deathent.death_msgmurder)
249                         {
250                                 Send_Notification_WOVA(
251                                         NOTIF_ONE,
252                                         notif_target,
253                                         MSG_MULTI,
254                                         deathent.death_msgmurder.nent_id,
255                                         s1, s2, s3, "",
256                                         f1, f2, f3, 0
257                                 );
258                                 Send_Notification_WOVA(
259                                         NOTIF_ALL_EXCEPT,
260                                         notif_target,
261                                         MSG_INFO,
262                                         deathent.death_msgmurder.nent_msginfo.nent_id,
263                                         s1, s2, s3, "",
264                                         f1, f2, f3, 0
265                                 );
266                         }
267                 }
268                 else
269                 {
270                         if(deathent.death_msgself)
271                         {
272                                 Send_Notification_WOVA(
273                                         NOTIF_ONE,
274                                         notif_target,
275                                         MSG_MULTI,
276                                         deathent.death_msgself.nent_id,
277                                         s1, s2, s3, "",
278                                         f1, f2, f3, 0
279                                 );
280                                 Send_Notification_WOVA(
281                                         NOTIF_ALL_EXCEPT,
282                                         notif_target,
283                                         MSG_INFO,
284                                         deathent.death_msgself.nent_msginfo.nent_id,
285                                         s1, s2, s3, "",
286                                         f1, f2, f3, 0
287                                 );
288                         }
289                 }
290         }
291         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
292 }
293
294 float w_deathtype;
295 float Obituary_WeaponDeath(
296         entity notif_target,
297         float murder,
298         float deathtype,
299         string s1, string s2, string s3,
300         float f1, float f2)
301 {
302         float death_weapon = DEATH_WEAPONOF(deathtype);
303         if(death_weapon)
304         {
305                 w_deathtype = deathtype;
306                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
307                 w_deathtype = FALSE;
308
309                 if(death_message)
310                 {
311                         Send_Notification_WOVA(
312                                 NOTIF_ONE,
313                                 notif_target,
314                                 MSG_MULTI,
315                                 death_message,
316                                 s1, s2, s3, "",
317                                 f1, f2, 0, 0
318                         );
319                         Send_Notification_WOVA(
320                                 NOTIF_ALL_EXCEPT,
321                                 notif_target,
322                                 MSG_INFO,
323                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
324                                 s1, s2, s3, "",
325                                 f1, f2, 0, 0
326                         );
327                 }
328                 else
329                 {
330                         dprint(sprintf(
331                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
332                                 deathtype,
333                                 death_weapon
334                         ));
335                 }
336
337                 return TRUE;
338         }
339         return FALSE;
340 }
341
342 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
343 {
344         // Sanity check
345         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
346
347         // Declarations
348         float notif_firstblood = FALSE;
349         float kill_count_to_attacker, kill_count_to_target;
350
351         // Set final information for the death
352         targ.death_origin = targ.origin;
353         if(targ != attacker) { targ.killer_origin = attacker.origin; }
354         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
355
356         #ifdef NOTIFICATIONS_DEBUG
357         Debug_Notification(
358                 sprintf(
359                         "Obituary(%s, %s, %s, %s = %d);\n",
360                         attacker.netname,
361                         inflictor.netname,
362                         targ.netname,
363                         Deathtype_Name(deathtype),
364                         deathtype
365                 )
366         );
367         #endif
368         
369         // =======
370         // SUICIDE
371         // =======
372         if(targ == attacker)
373         {
374                 if(DEATH_ISSPECIAL(deathtype))
375                 {
376                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
377                         {
378                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
379                         }
380                         else
381                         {
382                                 switch(deathtype)
383                                 {
384                                         case DEATH_MIRRORDAMAGE:
385                                         {
386                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
387                                                 break;
388                                         }
389                                         
390                                         default:
391                                         {
392                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
393                                                 break;
394                                         }
395                                 }
396                         }
397                 }
398                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
399                 {
400                         backtrace("SUICIDE: what the hell happened here?\n");
401                         return;
402                 }
403                 LogDeath("suicide", deathtype, targ, targ);
404                 GiveFrags(attacker, targ, -1, deathtype);
405         }
406
407         // ======
408         // MURDER
409         // ======
410         else if(IS_PLAYER(attacker))
411         {
412                 if(!IsDifferentTeam(attacker, targ))
413                 {
414                         LogDeath("tk", deathtype, attacker, targ);
415                         GiveFrags(attacker, targ, -1, deathtype);
416
417                         attacker.killcount = 0;
418                         
419                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
420                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
421                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
422
423                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
424                         // No need for specific death/weapon messages...
425                 }
426                 else
427                 {
428                         LogDeath("frag", deathtype, attacker, targ);
429                         GiveFrags(attacker, targ, 1, deathtype);
430
431                         attacker.taunt_soundtime = time + 1;
432                         attacker.killcount = attacker.killcount + 1;
433
434                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
435                                 case counta: \
436                                 { \
437                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
438                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
439                                         break; \
440                                 }
441                         switch(attacker.killcount)
442                         {
443                                 KILL_SPREE_LIST
444                                 default: break;
445                         }
446                         #undef SPREE_ITEM
447
448                         if(!checkrules_firstblood)
449                         {
450                                 checkrules_firstblood = TRUE;
451                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
452                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
453                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
454
455                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
456                                 kill_count_to_attacker = -1;
457                                 kill_count_to_target = -2;
458                         }
459                         else
460                         {
461                                 kill_count_to_attacker = attacker.killcount;
462                                 kill_count_to_target = 0;
463                         }
464
465                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
466                         if(targ.istypefrag)
467                         {
468                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
469                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
470                                 else
471                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
472
473                                 if(targ.FRAG_VERBOSE && verbose_allowed)
474                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
475                                 else
476                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
477                         }
478                         else
479                         {
480                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
481                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
482                                 else
483                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
484
485                                 if(targ.FRAG_VERBOSE && verbose_allowed)
486                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
487                                 else
488                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
489                         }
490
491                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
492                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
493                 }
494         }
495
496         // =============
497         // ACCIDENT/TRAP
498         // =============
499         else
500         {
501                 switch(deathtype)
502                 {
503                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
504                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
505                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
506                         /*case DEATH_HURTTRIGGER:
507                         {
508                                 s1 = targ.netname;
509                                 s2 = inflictor.message;
510                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
511                                 break;
512                         }*/
513
514                         case DEATH_CUSTOM:
515                         {
516                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
517                                         targ.netname,
518                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
519                                         deathlocation,
520                                         targ.killcount,
521                                         0,
522                                         0);
523                                 break;
524                         }
525                         
526                         default:
527                         {
528                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
529                                 break;
530                         }
531                 }
532
533                 LogDeath("accident", deathtype, targ, targ);
534                 GiveFrags(targ, targ, -1, deathtype);
535
536                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
537                 {
538                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
539                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
540                 }
541         }
542
543         // reset target kill count
544         if(targ.killcount) { targ.killcount = 0; }
545 }
546
547 // these are updated by each Damage call for use in button triggering and such
548 entity damage_targ;
549 entity damage_inflictor;
550 entity damage_attacker;
551
552 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
553 {
554         float mirrordamage;
555         float mirrorforce;
556         float complainteamdamage = 0; 
557         entity attacker_save;
558         mirrordamage = 0;
559         mirrorforce = 0;
560
561         if (gameover || targ.killcount == -666)
562                 return;
563
564         entity oldself;
565         oldself = self;
566         self = targ;
567         damage_targ = targ;
568         damage_inflictor = inflictor;
569         damage_attacker = attacker;
570                 attacker_save = attacker;
571
572         if(targ.classname == "player")
573                 if(targ.hook)
574                         if(targ.hook.aiment)
575                                 if(targ.hook.aiment == attacker)
576                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
577
578         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
579         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
580         {
581                 if(targ.classname == "player")
582                         if not(IsDifferentTeam(targ, attacker))
583                         {
584                                 self = oldself;
585                                 return;
586                         }
587         }
588
589         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
590         {
591                 // These are ALWAYS lethal
592                 // No damage modification here
593                 // Instead, prepare the victim for his death...
594                 targ.armorvalue = 0;
595                 targ.spawnshieldtime = 0;
596                 targ.health = 0.9; // this is < 1
597                 targ.flags -= targ.flags & FL_GODMODE;
598                 damage = 100000;
599         }
600         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
601         {
602                 // no processing
603         }
604         else
605         {
606                 /*
607                 skill based bot damage? gtfo. (tZork)
608                 if (targ.classname == "player")
609                 if (attacker.classname == "player")
610                 if (!targ.isbot)
611                 if (attacker.isbot)
612                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
613         */
614         
615                 // nullify damage if teamplay is on
616                 if(deathtype != DEATH_TELEFRAG)
617                 if(attacker.classname == "player")
618                 {
619                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
620                         {
621                                 damage = 0;
622                                 force = '0 0 0';
623                         }
624                         else if(!IsDifferentTeam(attacker, targ))
625                         {
626                                 if(autocvar_teamplay_mode == 1)
627                                         damage = 0;
628                                 else if(attacker != targ)
629                                 {
630                                         if(autocvar_teamplay_mode == 3)
631                                                 damage = 0;
632                                         else if(autocvar_teamplay_mode == 4)
633                                         {
634                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
635                                                 {
636                                                         attacker.dmg_team = attacker.dmg_team + damage;
637                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
638                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
639                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
640                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
641                                                         if(g_minstagib)
642                                                         {
643                                                                 if(autocvar_g_friendlyfire == 0)
644                                                                         damage = 0;
645                                                         }
646                                                         else if(g_ca)
647                                                                 damage = 0;
648                                                         else
649                                                                 damage = autocvar_g_friendlyfire * damage;
650                                                         // mirrordamage will be used LATER
651
652                                                         if(autocvar_g_mirrordamage_virtual)
653                                                         {
654                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
655                                                                 attacker.dmg_take += v_x;
656                                                                 attacker.dmg_save += v_y;
657                                                                 attacker.dmg_inflictor = inflictor;
658                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
659                                                                 mirrorforce = 0;
660                                                         }
661
662                                                         if(autocvar_g_friendlyfire_virtual)
663                                                         {
664                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
665                                                                 targ.dmg_take += v_x;
666                                                                 targ.dmg_save += v_y;
667                                                                 targ.dmg_inflictor = inflictor;
668                                                                 damage = 0;
669                                                                 if(!autocvar_g_friendlyfire_virtual_force)
670                                                                         force = '0 0 0';
671                                                         }
672                                                 }
673                                                 else
674                                                         damage = 0;
675                                         }
676                                 }
677                         }
678                 }
679
680                 if(targ.classname == "player")
681                 if (g_minstagib)
682                 {
683                         if ((deathtype == DEATH_FALL)  ||
684                                 (deathtype == DEATH_DROWN) ||
685                                 (deathtype == DEATH_SLIME) ||
686                                 (deathtype == DEATH_LAVA)  ||
687                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
688                         {
689                                 self = oldself;
690                                 return;
691                         }
692                         if(damage > 0)
693                             damage = 10000;
694                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
695                         {
696                                 targ.armorvalue -= 1;
697                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
698                                 damage = 0;
699                                 targ.hitsound += 1;
700                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
701                         }
702                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
703                         {
704                                 damage = 0;
705                                 mirrordamage = 0;
706                                 complainteamdamage = 0;
707                                 if (targ != attacker)
708                                 {
709                                         if ((targ.health >= 1) && (targ.classname == "player"))
710                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
711                                         force = '0 0 0';
712                                         // keep mirrorforce
713                                         attacker = targ;
714                                 }
715                         }
716                 }
717
718                 if not(DEATH_ISSPECIAL(deathtype))
719                 {
720                         damage *= g_weapondamagefactor;
721                         mirrordamage *= g_weapondamagefactor;
722                         complainteamdamage *= g_weapondamagefactor;
723                         force = force * g_weaponforcefactor;
724                         mirrorforce *= g_weaponforcefactor;
725                 }
726                 
727                 // should this be changed at all? If so, in what way?
728                 frag_attacker = attacker;
729                 frag_target = targ;
730                 frag_damage = damage;
731                 frag_force = force;
732         frag_deathtype = deathtype;
733                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
734                 damage = frag_damage;
735                 force = frag_force;
736                 
737                 // apply strength multiplier
738                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
739                 {
740                         if(targ == attacker)
741                         {
742                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
743                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
744                         }
745                         else
746                         {
747                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
748                                 force = force * autocvar_g_balance_powerup_strength_force;
749                         }
750                 }
751
752                 // apply invincibility multiplier
753                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
754                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
755
756                 if (targ == attacker)
757                 {
758                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
759                                 damage = 0;
760                         else
761                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
762                 }
763
764                 // count the damage
765                 if(attacker)
766                 if(!targ.deadflag)
767                 if(targ.takedamage == DAMAGE_AIM)
768                 if(targ != attacker)
769                 {
770                         entity victim;
771                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
772                                 victim = targ.owner;
773                         else
774                                 victim = targ;
775
776                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
777                         {
778                                 if(IsDifferentTeam(victim, attacker))
779                                 {
780                                         if(damage > 0)
781                                         {
782                                                 if(deathtype != DEATH_FIRE)
783                                                 {
784                                                         if(victim.BUTTON_CHAT)
785                                                                 attacker.typehitsound += 1;
786                                                         else
787                                                                 attacker.hitsound += 1;
788                                                 }
789
790                                                 damage_goodhits += 1;
791                                                 damage_gooddamage += damage;
792
793                                                 if not(DEATH_ISSPECIAL(deathtype))
794                                                 {
795                                                         if(targ.classname == "player") // don't do this for vehicles
796                                                         if(!g_minstagib)
797                                                         if(IsFlying(victim))
798                                                                 yoda = 1;
799
800                                                         if(g_minstagib)
801                                                         if(victim.items & IT_STRENGTH)
802                                                                 yoda = 1;
803                                                 }
804                                         }
805                                 }
806                                 else
807                                 {
808                                         if(deathtype != DEATH_FIRE)
809                                         {
810                                                 attacker.typehitsound += 1;
811                                         }
812                                         if(complainteamdamage > 0)
813                                                 if(time > attacker.teamkill_complain)
814                                                 {
815                                                         attacker.teamkill_complain = time + 5;
816                                                         attacker.teamkill_soundtime = time + 0.4;
817                                                         attacker.teamkill_soundsource = targ;
818                                                 }
819                                 }
820                         }
821                 }
822         }
823
824         // apply push
825         if (self.damageforcescale)
826         if (vlen(force))
827         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
828         {
829                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
830                 if(self.movetype == MOVETYPE_PHYSICS)
831                 {
832                         entity farcent;
833                         farcent = spawn();
834                         farcent.classname = "farce";
835                         farcent.enemy = self;
836                         farcent.movedir = farce * 10;
837                         if(self.mass)
838                                 farcent.movedir = farcent.movedir * self.mass;
839                         farcent.origin = hitloc;
840                         farcent.forcetype = FORCETYPE_FORCEATPOS;
841                         farcent.nextthink = time + 0.1;
842                         farcent.think = SUB_Remove;
843                 }
844                 else
845                         self.velocity = self.velocity + farce;
846                 self.flags &~= FL_ONGROUND;
847                 UpdateCSQCProjectile(self);
848         }
849         // apply damage
850         if (damage != 0 || (self.damageforcescale && vlen(force)))
851         if (self.event_damage)
852                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
853         self = oldself;
854
855         // apply mirror damage if any
856         if(mirrordamage > 0 || mirrorforce > 0)
857         {
858                 attacker = attacker_save;
859                 if(g_minstagib)
860                 if(mirrordamage > 0)
861                 {
862                         // just lose extra LIVES, don't kill the player for mirror damage
863                         if(attacker.armorvalue > 0)
864                         {
865                                 attacker.armorvalue = attacker.armorvalue - 1;
866                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
867                                 attacker.hitsound += 1;
868                         }
869                         mirrordamage = 0;
870                 }
871
872                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
873                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
874         }
875 }
876
877 float RadiusDamage_running;
878 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
879         // Returns total damage applies to creatures
880 {
881         entity  targ;
882         vector  blastorigin;
883         vector  force;
884         float   total_damage_to_creatures;
885         entity  next;
886         float   tfloordmg;
887         float   tfloorforce;
888
889         float stat_damagedone;
890
891         if(RadiusDamage_running)
892         {
893                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
894                 return 0;
895         }
896
897         RadiusDamage_running = 1;
898
899         tfloordmg = autocvar_g_throughfloor_damage;
900         tfloorforce = autocvar_g_throughfloor_force;
901
902         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
903         total_damage_to_creatures = 0;
904
905         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
906                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
907                 {
908                         force = inflictor.velocity;
909                         if(vlen(force) == 0)
910                                 force = '0 0 -1';
911                         else
912                                 force = normalize(force);
913                         if(forceintensity >= 0)
914                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
915                         else
916                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
917                 }
918
919         stat_damagedone = 0;
920
921         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
922         while (targ)
923         {
924                 next = targ.chain;
925                 if (targ != inflictor)
926                         if (ignore != targ) if(targ.takedamage)
927                         {
928                                 vector nearest;
929                                 vector diff;
930                                 float power;
931
932                                 // LordHavoc: measure distance to nearest point on target (not origin)
933                                 // (this guarentees 100% damage on a touch impact)
934                                 nearest = targ.WarpZone_findradius_nearest;
935                                 diff = targ.WarpZone_findradius_dist;
936                                 // round up a little on the damage to ensure full damage on impacts
937                                 // and turn the distance into a fraction of the radius
938                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
939                                 //bprint(" ");
940                                 //bprint(ftos(power));
941                                 //if (targ == attacker)
942                                 //      print(ftos(power), "\n");
943                                 if (power > 0)
944                                 {
945                                         float finaldmg;
946                                         if (power > 1)
947                                                 power = 1;
948                                         finaldmg = coredamage * power + edgedamage * (1 - power);
949                                         if (finaldmg > 0)
950                                         {
951                                                 float a;
952                                                 float c;
953                                                 vector hitloc;
954                                                 vector myblastorigin;
955                                                 vector center;
956
957                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
958
959                                                 // if it's a player, use the view origin as reference
960                                                 center = CENTER_OR_VIEWOFS(targ);
961
962                                                 force = normalize(center - myblastorigin);
963                                                 force = force * (finaldmg / coredamage) * forceintensity;
964                                                 hitloc = nearest;
965
966                                                 if(targ != directhitentity)
967                                                 {
968                                                         float hits;
969                                                         float total;
970                                                         float hitratio;
971                                                         float mininv_f, mininv_d;
972
973                                                         // test line of sight to multiple positions on box,
974                                                         // and do damage if any of them hit
975                                                         hits = 0;
976
977                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
978                                                         // so for a given max stddev:
979                                                         // n = (1 / (2 * max stddev of hitratio))^2
980
981                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
982                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
983
984                                                         if(autocvar_g_throughfloor_debug)
985                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
986
987                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
988
989                                                         if(autocvar_g_throughfloor_debug)
990                                                                 print(sprintf(" steps=%f", total));
991
992                                                         if (targ.classname == "player")
993                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
994                                                         else
995                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
996
997                                                         if(autocvar_g_throughfloor_debug)
998                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
999
1000                                                         for(c = 0; c < total; ++c)
1001                                                         {
1002                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1003                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1004                                                                 if (trace_fraction == 1 || trace_ent == targ)
1005                                                                 {
1006                                                                         ++hits;
1007                                                                         if (hits > 1)
1008                                                                                 hitloc = hitloc + nearest;
1009                                                                         else
1010                                                                                 hitloc = nearest;
1011                                                                 }
1012                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1013                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1014                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1015                                                         }
1016
1017                                                         nearest = hitloc * (1 / max(1, hits));
1018                                                         hitratio = (hits / total);
1019                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1020                                                         finaldmg = finaldmg * a;
1021                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1022                                                         force = force * a;
1023
1024                                                         if(autocvar_g_throughfloor_debug)
1025                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1026                                                 }
1027
1028                                                 // laser force adjustments :P
1029                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1030                                                 {
1031                                                         if (targ == attacker)
1032                                                         {
1033                                                                 vector vel;
1034
1035                                                                 float force_zscale;
1036                                                                 float force_velocitybiasramp;
1037                                                                 float force_velocitybias;
1038
1039                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1040                                                                 if(deathtype & HITTYPE_SECONDARY)
1041                                                                 {
1042                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1043                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1044                                                                 }
1045                                                                 else
1046                                                                 {
1047                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1048                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1049                                                                 }
1050
1051                                                                 vel = targ.velocity;
1052                                                                 vel_z = 0;
1053                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1054                                                                 force =
1055                                                                         vlen(force)
1056                                                                         *
1057                                                                         normalize(normalize(force) + vel);
1058
1059                                                                 force_z *= force_zscale;
1060                                                         }
1061                                                         else
1062                                                         {
1063                                                                 if(deathtype & HITTYPE_SECONDARY)
1064                                                                 {
1065                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1066                                                                 }
1067                                                                 else
1068                                                                 {
1069                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1070                                                                 }
1071                                                         }
1072                                                 }
1073
1074                                                 //if (targ == attacker)
1075                                                 //{
1076                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1077                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1078                                                 //      print(" (", ftos(a), ")\n");
1079                                                 //}
1080                                                 if(finaldmg || vlen(force))
1081                                                 {
1082                                                         if(targ.iscreature)
1083                                                         {
1084                                                                 total_damage_to_creatures += finaldmg;
1085
1086                                                                 if(accuracy_isgooddamage(attacker, targ))
1087                                                                         stat_damagedone += finaldmg;
1088                                                         }
1089
1090                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1091                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1092                                                         else
1093                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1094                                                 }
1095                                         }
1096                                 }
1097                         }
1098                 targ = next;
1099         }
1100
1101         RadiusDamage_running = 0;
1102
1103         if(!DEATH_ISSPECIAL(deathtype))
1104                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1105
1106         return total_damage_to_creatures;
1107 }
1108
1109 .float fire_damagepersec;
1110 .float fire_endtime;
1111 .float fire_deathtype;
1112 .entity fire_owner;
1113 .float fire_hitsound;
1114 .entity fire_burner;
1115
1116 void fireburner_think();
1117
1118 float Fire_IsBurning(entity e)
1119 {
1120         return (time < e.fire_endtime);
1121 }
1122
1123 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1124 {
1125         float dps;
1126         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1127
1128         if(e.classname == "player")
1129         {
1130                 if(e.deadflag)
1131                         return -1;
1132         }
1133         else
1134         {
1135                 if(!e.fire_burner)
1136                 {
1137                         // print("adding a fire burner to ", e.classname, "\n");
1138                         e.fire_burner = spawn();
1139                         e.fire_burner.classname = "fireburner";
1140                         e.fire_burner.think = fireburner_think;
1141                         e.fire_burner.nextthink = time;
1142                         e.fire_burner.owner = e;
1143                 }
1144         }
1145
1146         t = max(t, 0.1);
1147         dps = d / t;
1148         if(Fire_IsBurning(e))
1149         {
1150                 mintime = e.fire_endtime - time;
1151                 maxtime = max(mintime, t);
1152
1153                 mindps = e.fire_damagepersec;
1154                 maxdps = max(mindps, dps);
1155
1156                 if(maxtime > mintime || maxdps > mindps)
1157                 {
1158                         // Constraints:
1159                         
1160                         // damage we have right now
1161                         mindamage = mindps * mintime;
1162
1163                         // damage we want to get
1164                         maxdamage = mindamage + d;
1165
1166                         // but we can't exceed maxtime * maxdps!
1167                         totaldamage = min(maxdamage, maxtime * maxdps);
1168
1169                         // LEMMA:
1170                         // Look at:
1171                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1172                         // We see:
1173                         // totaldamage <= maxtime * maxdps
1174                         // ==> totaldamage / maxdps <= maxtime.
1175                         // We also see:
1176                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1177                         //                     >= min(mintime, maxtime)
1178                         // ==> totaldamage / maxdps >= mintime.
1179
1180                         /*
1181                         // how long do we damage then?
1182                         // at least as long as before
1183                         // but, never exceed maxdps
1184                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1185                         */
1186
1187                         // alternate:
1188                         // at most as long as maximum allowed
1189                         // but, never below mindps
1190                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1191
1192                         // assuming t > mintime, dps > mindps:
1193                         // we get d = t * dps = maxtime * maxdps
1194                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1195                         // totaldamage / maxdps = maxtime
1196                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1197                         // FROM THIS:
1198                         // a) totaltime = max(mintime, maxtime) = maxtime
1199                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1200
1201                         // assuming t <= mintime:
1202                         // we get maxtime = mintime
1203                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1204                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1205
1206                         // assuming dps <= mindps:
1207                         // we get mindps = maxdps.
1208                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1209                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1210                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1211
1212                         e.fire_damagepersec = totaldamage / totaltime;
1213                         e.fire_endtime = time + totaltime;
1214                         if(totaldamage > 1.2 * mindamage)
1215                         {
1216                                 e.fire_deathtype = dt;
1217                                 if(e.fire_owner != o)
1218                                 {
1219                                         e.fire_owner = o;
1220                                         e.fire_hitsound = FALSE;
1221                                 }
1222                         }
1223                         if(accuracy_isgooddamage(o, e))
1224                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1225                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1226                 }
1227                 else
1228                         return 0;
1229         }
1230         else
1231         {
1232                 e.fire_damagepersec = dps;
1233                 e.fire_endtime = time + t;
1234                 e.fire_deathtype = dt;
1235                 e.fire_owner = o;
1236                 e.fire_hitsound = FALSE;
1237                 if(accuracy_isgooddamage(o, e))
1238                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1239                 return d;
1240         }
1241 }
1242
1243 void Fire_ApplyDamage(entity e)
1244 {
1245         float t, d, hi, ty;
1246         entity o;
1247
1248         if not(Fire_IsBurning(e))
1249                 return;
1250
1251         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1252         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1253                 o = e.fire_owner;
1254
1255         // water and slime stop fire
1256         if(e.waterlevel)
1257         if(e.watertype != CONTENT_LAVA)
1258                 e.fire_endtime = 0;
1259
1260         // ice stops fire
1261         if(e.freezetag_frozen)
1262                 e.fire_endtime = 0;
1263
1264         t = min(frametime, e.fire_endtime - time);
1265         d = e.fire_damagepersec * t;
1266
1267         hi = e.fire_owner.hitsound;
1268         ty = e.fire_owner.typehitsound;
1269         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1270         if(e.fire_hitsound && e.fire_owner)
1271         {
1272                 e.fire_owner.hitsound = hi;
1273                 e.fire_owner.typehitsound = ty;
1274         }
1275         e.fire_hitsound = TRUE;
1276
1277         if not(IS_INDEPENDENT_PLAYER(e))
1278         FOR_EACH_PLAYER(other) if(e != other)
1279         {
1280                 if(other.classname == "player")
1281                 if(other.deadflag == DEAD_NO)
1282                 if not(IS_INDEPENDENT_PLAYER(other))
1283                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1284                 {
1285                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1286                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1287                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1288                 }
1289         }
1290 }
1291
1292 void Fire_ApplyEffect(entity e)
1293 {
1294         if(Fire_IsBurning(e))
1295                 e.effects |= EF_FLAME;
1296         else
1297                 e.effects &~= EF_FLAME;
1298 }
1299
1300 void fireburner_think()
1301 {
1302         // for players, this is done in the regular loop
1303         if(wasfreed(self.owner))
1304         {
1305                 remove(self);
1306                 return;
1307         }
1308         Fire_ApplyEffect(self.owner);
1309         if(!Fire_IsBurning(self.owner))
1310         {
1311                 self.owner.fire_burner = world;
1312                 remove(self);
1313                 return;
1314         }
1315         Fire_ApplyDamage(self.owner);
1316         self.nextthink = time;
1317 }