Merge branch 'master' into samual/weapons
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_damage.qc
1 .float dmg;
2 .float dmg_edge;
3 .float dmg_force;
4 .float dmg_radius;
5
6 float Damage_DamageInfo_SendEntity(entity to, float sf)
7 {
8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
16         WriteShort(MSG_ENTITY, self.oldorigin_x);
17         WriteByte(MSG_ENTITY, self.species);
18         return TRUE;
19 }
20
21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
22 {
23         // TODO maybe call this from non-edgedamage too?
24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
25
26         entity e;
27
28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
29                 deathtype |= 0x8000;
30
31         e = spawn();
32         setorigin(e, org);
33         e.projectiledeathtype = deathtype;
34         e.dmg = coredamage;
35         e.dmg_edge = edgedamage;
36         e.dmg_radius = rad;
37         e.dmg_force = vlen(force);
38         e.velocity = force;
39         e.oldorigin_x = compressShortVector(e.velocity);
40         e.species = bloodtype;
41
42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
43 }
44
45 float checkrules_firstblood;
46
47 float yoda;
48 float damage_goodhits;
49 float damage_gooddamage;
50
51 .float dmg_team;
52 .float teamkill_complain;
53 .float teamkill_soundtime;
54 .entity teamkill_soundsource;
55 .entity pusher;
56 .float istypefrag;
57 .float taunt_soundtime;
58
59 float IsFlying(entity a)
60 {
61         if(a.flags & FL_ONGROUND)
62                 return 0;
63         if(a.waterlevel >= WATERLEVEL_SWIMMING)
64                 return 0;
65         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
66         if(trace_fraction < 1)
67                 return 0;
68         return 1;
69 }
70
71 void UpdateFrags(entity player, float f)
72 {
73         PlayerTeamScore_AddScore(player, f);
74 }
75
76 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
77 void W_SwitchWeapon_Force(entity e, float w);
78 entity GiveFrags_randomweapons;
79 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
80 {
81         // TODO route through PlayerScores instead
82         if(gameover) return;
83
84         if(f < 0)
85         {
86                 if(targ == attacker)
87                 {
88                         // suicide
89                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
90                 }
91                 else
92                 {
93                         // teamkill
94                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
95                 }
96         }
97         else
98         {
99                 // regular frag
100                 PlayerScore_Add(attacker, SP_KILLS, 1);
101                 if(targ.playerid)
102                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
103         }
104
105         PlayerScore_Add(targ, SP_DEATHS, 1);
106
107         if(targ != attacker) // not for suicides
108         if(g_weaponarena_random)
109         {
110                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
111                 float culprit;
112                 culprit = DEATH_WEAPONOF(deathtype);
113                 if(!culprit)
114                         culprit = attacker.weapon;
115                 else if(!(attacker.weapons & WepSet_FromWeapon(culprit)))
116                         culprit = attacker.weapon;
117
118                 if(g_weaponarena_random_with_laser && culprit == WEP_BLASTER) // WEAPONTODO: Shouldn't this be in a mutator?
119                 {
120                         // no exchange
121                 }
122                 else
123                 {
124                         if(!GiveFrags_randomweapons)
125                         {
126                                 GiveFrags_randomweapons = spawn();
127                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
128                         }
129
130                         if(warmup_stage)
131                                 GiveFrags_randomweapons.weapons = WARMUP_START_WEAPONS;
132                         else
133                                 GiveFrags_randomweapons.weapons = start_weapons;
134
135                         // all others (including the culprit): remove
136                         GiveFrags_randomweapons.weapons &= ~attacker.weapons;
137                         GiveFrags_randomweapons.weapons &= ~WepSet_FromWeapon(culprit);
138
139                         // among the remaining ones, choose one by random
140                         W_RandomWeapons(GiveFrags_randomweapons, 1);
141
142                         if(GiveFrags_randomweapons.weapons)
143                         {
144                                 attacker.weapons |= GiveFrags_randomweapons.weapons;
145                                 attacker.weapons &= ~WepSet_FromWeapon(culprit);
146                         }
147                 }
148
149                 // after a frag, choose another random weapon set
150                 if (!(attacker.weapons & WepSet_FromWeapon(attacker.weapon)))
151                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
152         }
153
154         // FIXME fix the mess this is (we have REAL points now!)
155         entity oldself;
156         oldself = self;
157         self = attacker;
158         frag_attacker = attacker;
159         frag_target = targ;
160         frag_score = f;
161         if(MUTATOR_CALLHOOK(GiveFragsForKill))
162         {
163                 f = frag_score;
164                 self = oldself;
165         }
166         else
167         {
168                 self = oldself;
169         }
170
171         attacker.totalfrags += f;
172
173         if(f)
174                 UpdateFrags(attacker, f);
175 }
176
177 string AppendItemcodes(string s, entity player)
178 {
179         float w;
180         w = player.weapon;
181         //if(w == 0)
182         //      w = player.switchweapon;
183         if(w == 0)
184                 w = player.cnt; // previous weapon!
185         s = strcat(s, ftos(w));
186         if(time < player.strength_finished)
187                 s = strcat(s, "S");
188         if(time < player.invincible_finished)
189                 s = strcat(s, "I");
190         if(player.flagcarried != world)
191                 s = strcat(s, "F");
192         if(player.BUTTON_CHAT)
193                 s = strcat(s, "T");
194         if(player.kh_next)
195                 s = strcat(s, "K");
196         return s;
197 }
198
199 void LogDeath(string mode, float deathtype, entity killer, entity killed)
200 {
201         string s;
202         if(!autocvar_sv_eventlog)
203                 return;
204         s = strcat(":kill:", mode);
205         s = strcat(s, ":", ftos(killer.playerid));
206         s = strcat(s, ":", ftos(killed.playerid));
207         s = strcat(s, ":type=", Deathtype_Name(deathtype));
208         s = strcat(s, ":items=");
209         s = AppendItemcodes(s, killer);
210         if(killed != killer)
211         {
212                 s = strcat(s, ":victimitems=");
213                 s = AppendItemcodes(s, killed);
214         }
215         GameLogEcho(s);
216 }
217
218 void Obituary_SpecialDeath(
219         entity notif_target,
220         float murder,
221         float deathtype,
222         string s1, string s2, string s3,
223         float f1, float f2, float f3)
224 {
225         if(DEATH_ISSPECIAL(deathtype))
226         {
227                 entity deathent = deathtypes[(deathtype - DT_FIRST)];
228                 if (!deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
229
230                 if(murder)
231                 {
232                         if(deathent.death_msgmurder)
233                         {
234                                 Send_Notification_WOCOVA(
235                                         NOTIF_ONE,
236                                         notif_target,
237                                         MSG_MULTI,
238                                         deathent.death_msgmurder.nent_id,
239                                         s1, s2, s3, "",
240                                         f1, f2, f3, 0
241                                 );
242                                 Send_Notification_WOCOVA(
243                                         NOTIF_ALL_EXCEPT,
244                                         notif_target,
245                                         MSG_INFO,
246                                         deathent.death_msgmurder.nent_msginfo.nent_id,
247                                         s1, s2, s3, "",
248                                         f1, f2, f3, 0
249                                 );
250                         }
251                 }
252                 else
253                 {
254                         if(deathent.death_msgself)
255                         {
256                                 Send_Notification_WOCOVA(
257                                         NOTIF_ONE,
258                                         notif_target,
259                                         MSG_MULTI,
260                                         deathent.death_msgself.nent_id,
261                                         s1, s2, s3, "",
262                                         f1, f2, f3, 0
263                                 );
264                                 Send_Notification_WOCOVA(
265                                         NOTIF_ALL_EXCEPT,
266                                         notif_target,
267                                         MSG_INFO,
268                                         deathent.death_msgself.nent_msginfo.nent_id,
269                                         s1, s2, s3, "",
270                                         f1, f2, f3, 0
271                                 );
272                         }
273                 }
274         }
275         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
276 }
277
278 float w_deathtype;
279 float Obituary_WeaponDeath(
280         entity notif_target,
281         float murder,
282         float deathtype,
283         string s1, string s2, string s3,
284         float f1, float f2)
285 {
286         float death_weapon = DEATH_WEAPONOF(deathtype);
287         if(death_weapon)
288         {
289                 w_deathtype = deathtype;
290                 float death_message = WEP_ACTION(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
291                 w_deathtype = FALSE;
292
293                 if(death_message)
294                 {
295                         Send_Notification_WOCOVA(
296                                 NOTIF_ONE,
297                                 notif_target,
298                                 MSG_MULTI,
299                                 death_message,
300                                 s1, s2, s3, "",
301                                 f1, f2, 0, 0
302                         );
303                         Send_Notification_WOCOVA(
304                                 NOTIF_ALL_EXCEPT,
305                                 notif_target,
306                                 MSG_INFO,
307                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
308                                 s1, s2, s3, "",
309                                 f1, f2, 0, 0
310                         );
311                 }
312                 else
313                 {
314                         dprintf(
315                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
316                                 deathtype,
317                                 death_weapon
318                         );
319                 }
320
321                 return TRUE;
322         }
323         return FALSE;
324 }
325
326 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
327 {
328         // Sanity check
329         if (!IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
330
331         // Declarations
332         float notif_firstblood = FALSE;
333         float kill_count_to_attacker, kill_count_to_target;
334
335         // Set final information for the death
336         targ.death_origin = targ.origin;
337         if(targ != attacker) { targ.killer_origin = attacker.origin; }
338         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
339
340         #ifdef NOTIFICATIONS_DEBUG
341         Debug_Notification(
342                 sprintf(
343                         "Obituary(%s, %s, %s, %s = %d);\n",
344                         attacker.netname,
345                         inflictor.netname,
346                         targ.netname,
347                         Deathtype_Name(deathtype),
348                         deathtype
349                 )
350         );
351         #endif
352
353         // =======
354         // SUICIDE
355         // =======
356         if(targ == attacker)
357         {
358                 if(DEATH_ISSPECIAL(deathtype))
359                 {
360                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
361                         {
362                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
363                         }
364                         else
365                         {
366                                 switch(deathtype)
367                                 {
368                                         case DEATH_MIRRORDAMAGE:
369                                         {
370                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
371                                                 break;
372                                         }
373
374                                         default:
375                                         {
376                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
377                                                 break;
378                                         }
379                                 }
380                         }
381                 }
382                 else if (!Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
383                 {
384                         backtrace("SUICIDE: what the hell happened here?\n");
385                         return;
386                 }
387                 LogDeath("suicide", deathtype, targ, targ);
388                 GiveFrags(attacker, targ, -1, deathtype);
389         }
390
391         // ======
392         // MURDER
393         // ======
394         else if(IS_PLAYER(attacker))
395         {
396                 if(SAME_TEAM(attacker, targ))
397                 {
398                         LogDeath("tk", deathtype, attacker, targ);
399                         GiveFrags(attacker, targ, -1, deathtype);
400
401                         attacker.killcount = 0;
402
403                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
404                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
405                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
406
407                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
408                         // No need for specific death/weapon messages...
409                 }
410                 else
411                 {
412                         LogDeath("frag", deathtype, attacker, targ);
413                         GiveFrags(attacker, targ, 1, deathtype);
414
415                         attacker.taunt_soundtime = time + 1;
416                         attacker.killcount = attacker.killcount + 1;
417
418                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
419                                 case counta: \
420                                 { \
421                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
422                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
423                                         break; \
424                                 }
425                         switch(attacker.killcount)
426                         {
427                                 KILL_SPREE_LIST
428                                 default: break;
429                         }
430                         #undef SPREE_ITEM
431
432                         if(!checkrules_firstblood)
433                         {
434                                 checkrules_firstblood = TRUE;
435                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
436                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
437                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
438
439                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
440                                 kill_count_to_attacker = -1;
441                                 kill_count_to_target = -2;
442                         }
443                         else
444                         {
445                                 kill_count_to_attacker = attacker.killcount;
446                                 kill_count_to_target = 0;
447                         }
448
449                         if(targ.istypefrag)
450                         {
451                                 Send_Notification(
452                                         NOTIF_ONE,
453                                         attacker,
454                                         MSG_CHOICE,
455                                         CHOICE_TYPEFRAG,
456                                         targ.netname,
457                                         kill_count_to_attacker,
458                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
459                                 );
460                                 Send_Notification(
461                                         NOTIF_ONE,
462                                         targ,
463                                         MSG_CHOICE,
464                                         CHOICE_TYPEFRAGGED,
465                                         attacker.netname,
466                                         kill_count_to_target,
467                                         attacker.health,
468                                         attacker.armorvalue,
469                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
470                                 );
471                         }
472                         else
473                         {
474                                 Send_Notification(
475                                         NOTIF_ONE,
476                                         attacker,
477                                         MSG_CHOICE,
478                                         CHOICE_FRAG,
479                                         targ.netname,
480                                         kill_count_to_attacker,
481                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
482                                 );
483                                 Send_Notification(
484                                         NOTIF_ONE,
485                                         targ,
486                                         MSG_CHOICE,
487                                         CHOICE_FRAGGED,
488                                         attacker.netname,
489                                         kill_count_to_target,
490                                         attacker.health,
491                                         attacker.armorvalue,
492                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
493                                 );
494                         }
495
496                         if (!Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
497                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
498                 }
499         }
500
501         // =============
502         // ACCIDENT/TRAP
503         // =============
504         else
505         {
506                 switch(deathtype)
507                 {
508                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
509                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
510                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
511                         /*case DEATH_HURTTRIGGER:
512                         {
513                                 s1 = targ.netname;
514                                 s2 = inflictor.message;
515                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
516                                 break;
517                         }*/
518
519                         case DEATH_CUSTOM:
520                         {
521                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
522                                         targ.netname,
523                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
524                                         deathlocation,
525                                         targ.killcount,
526                                         0,
527                                         0);
528                                 break;
529                         }
530
531                         default:
532                         {
533                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
534                                 break;
535                         }
536                 }
537
538                 LogDeath("accident", deathtype, targ, targ);
539                 GiveFrags(targ, targ, -1, deathtype);
540
541                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
542                 {
543                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
544                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
545                 }
546         }
547
548         // reset target kill count
549         if(targ.killcount) { targ.killcount = 0; }
550 }
551
552 // these are updated by each Damage call for use in button triggering and such
553 entity damage_targ;
554 entity damage_inflictor;
555 entity damage_attacker;
556
557 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
558 {
559         float mirrordamage;
560         float mirrorforce;
561         float complainteamdamage = 0;
562         entity attacker_save;
563         mirrordamage = 0;
564         mirrorforce = 0;
565
566         if (gameover || targ.killcount == -666)
567                 return;
568
569         entity oldself;
570         oldself = self;
571         self = targ;
572         damage_targ = targ;
573         damage_inflictor = inflictor;
574         damage_attacker = attacker;
575                 attacker_save = attacker;
576
577         if(IS_PLAYER(targ))
578                 if(targ.hook)
579                         if(targ.hook.aiment)
580                                 if(targ.hook.aiment == attacker)
581                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
582
583         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
584         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
585         {
586                 if(IS_PLAYER(targ))
587                         if(SAME_TEAM(targ, attacker))
588                         {
589                                 self = oldself;
590                                 return;
591                         }
592         }
593
594         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
595         {
596                 // exit the vehicle before killing (fixes a crash)
597                 if(IS_PLAYER(targ) && targ.vehicle)
598                         vehicles_exit(VHEF_RELESE);
599
600                 // These are ALWAYS lethal
601                 // No damage modification here
602                 // Instead, prepare the victim for his death...
603                 targ.armorvalue = 0;
604                 targ.spawnshieldtime = 0;
605                 targ.health = 0.9; // this is < 1
606                 targ.flags -= targ.flags & FL_GODMODE;
607                 damage = 100000;
608         }
609         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
610         {
611                 // no processing
612         }
613         else
614         {
615                 // nullify damage if teamplay is on
616                 if(deathtype != DEATH_TELEFRAG)
617                 if(IS_PLAYER(attacker))
618                 {
619                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
620                         {
621                                 damage = 0;
622                                 force = '0 0 0';
623                         }
624                         else if(SAME_TEAM(attacker, targ))
625                         {
626                                 if(autocvar_teamplay_mode == 1)
627                                         damage = 0;
628                                 else if(attacker != targ)
629                                 {
630                                         if(autocvar_teamplay_mode == 3)
631                                                 damage = 0;
632                                         else if(autocvar_teamplay_mode == 4)
633                                         {
634                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
635                                                 {
636                                                         attacker.dmg_team = attacker.dmg_team + damage;
637                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
638                                                         if(complainteamdamage > 0)
639                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
640                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
641                                                         damage = autocvar_g_friendlyfire * damage;
642                                                         // mirrordamage will be used LATER
643
644                                                         if(autocvar_g_mirrordamage_virtual)
645                                                         {
646                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, mirrordamage);
647                                                                 attacker.dmg_take += v_x;
648                                                                 attacker.dmg_save += v_y;
649                                                                 attacker.dmg_inflictor = inflictor;
650                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
651                                                                 mirrorforce = 0;
652                                                         }
653
654                                                         if(autocvar_g_friendlyfire_virtual)
655                                                         {
656                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
657                                                                 targ.dmg_take += v_x;
658                                                                 targ.dmg_save += v_y;
659                                                                 targ.dmg_inflictor = inflictor;
660                                                                 damage = 0;
661                                                                 if(!autocvar_g_friendlyfire_virtual_force)
662                                                                         force = '0 0 0';
663                                                         }
664                                                 }
665                                                 else
666                                                         damage = 0;
667                                         }
668                                 }
669                         }
670                 }
671
672                 if (!DEATH_ISSPECIAL(deathtype))
673                 {
674                         damage *= g_weapondamagefactor;
675                         mirrordamage *= g_weapondamagefactor;
676                         complainteamdamage *= g_weapondamagefactor;
677                         force = force * g_weaponforcefactor;
678                         mirrorforce *= g_weaponforcefactor;
679                 }
680
681                 // should this be changed at all? If so, in what way?
682                 frag_attacker = attacker;
683                 frag_target = targ;
684                 frag_damage = damage;
685                 frag_force = force;
686                 frag_deathtype = deathtype;
687                 frag_mirrordamage = mirrordamage;
688                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
689                 damage = frag_damage;
690                 mirrordamage = frag_mirrordamage;
691                 force = frag_force;
692
693                 if (!g_minstagib)
694                 {
695                         // apply strength multiplier
696                         if (attacker.items & IT_STRENGTH)
697                         {
698                                 if(targ == attacker)
699                                 {
700                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
701                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
702                                 }
703                                 else
704                                 {
705                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
706                                         force = force * autocvar_g_balance_powerup_strength_force;
707                                 }
708                         }
709
710                         // apply invincibility multiplier
711                         if (targ.items & IT_INVINCIBLE)
712                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
713                 }
714
715                 if (targ == attacker)
716                 {
717                         if(g_cts && !autocvar_g_cts_selfdamage)
718                                 damage = 0;
719                         else
720                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
721                 }
722
723                 // count the damage
724                 if(attacker)
725                 if(!targ.deadflag)
726                 if(targ.takedamage == DAMAGE_AIM)
727                 if(targ != attacker)
728                 {
729                         entity victim;
730                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
731                                 victim = targ.owner;
732                         else
733                                 victim = targ;
734
735                         if(IS_PLAYER(victim) || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET || victim.flags & FL_MONSTER)
736                         {
737                                 if(DIFF_TEAM(victim, attacker))
738                                 {
739                                         if(damage > 0)
740                                         {
741                                                 if(deathtype != DEATH_FIRE)
742                                                 {
743                                                         if(victim.BUTTON_CHAT)
744                                                                 attacker.typehitsound += 1;
745                                                         else
746                                                                 attacker.hitsound += 1;
747                                                 }
748
749                                                 damage_goodhits += 1;
750                                                 damage_gooddamage += damage;
751
752                                                 if (!DEATH_ISSPECIAL(deathtype))
753                                                 {
754                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
755                                                         if(IsFlying(victim))
756                                                                 yoda = 1;
757                                                 }
758                                         }
759                                 }
760                                 else
761                                 {
762                                         if(deathtype != DEATH_FIRE)
763                                         {
764                                                 attacker.typehitsound += 1;
765                                         }
766                                         if(complainteamdamage > 0)
767                                                 if(time > attacker.teamkill_complain)
768                                                 {
769                                                         attacker.teamkill_complain = time + 5;
770                                                         attacker.teamkill_soundtime = time + 0.4;
771                                                         attacker.teamkill_soundsource = targ;
772                                                 }
773                                 }
774                         }
775                 }
776         }
777
778         // apply push
779         if (self.damageforcescale)
780         if (vlen(force))
781         if (!IS_PLAYER(self) || time >= self.spawnshieldtime)
782         {
783                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
784                 if(self.movetype == MOVETYPE_PHYSICS)
785                 {
786                         entity farcent;
787                         farcent = spawn();
788                         farcent.classname = "farce";
789                         farcent.enemy = self;
790                         farcent.movedir = farce * 10;
791                         if(self.mass)
792                                 farcent.movedir = farcent.movedir * self.mass;
793                         farcent.origin = hitloc;
794                         farcent.forcetype = FORCETYPE_FORCEATPOS;
795                         farcent.nextthink = time + 0.1;
796                         farcent.think = SUB_Remove;
797                 }
798                 else
799                         self.velocity = self.velocity + farce;
800                 self.flags &= ~FL_ONGROUND;
801                 UpdateCSQCProjectile(self);
802         }
803         // apply damage
804         if (damage != 0 || (self.damageforcescale && vlen(force)))
805         if (self.event_damage)
806                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
807         self = oldself;
808
809         // apply mirror damage if any
810         if(mirrordamage > 0 || mirrorforce > 0)
811         {
812                 attacker = attacker_save;
813
814                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
815                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
816         }
817 }
818
819 float RadiusDamage_running;
820 float RadiusDamageForSource (entity inflictor, vector inflictororigin, vector inflictorvelocity, entity attacker, float coredamage, float edgedamage, float rad, entity cantbe, entity mustbe, float inflictorselfdamage, float forceintensity, float deathtype, entity directhitentity)
821         // Returns total damage applies to creatures
822 {
823         entity  targ;
824         vector  force;
825         float   total_damage_to_creatures;
826         entity  next;
827         float   tfloordmg;
828         float   tfloorforce;
829
830         float stat_damagedone;
831
832         if(RadiusDamage_running)
833         {
834                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
835                 return 0;
836         }
837
838         RadiusDamage_running = 1;
839
840         tfloordmg = autocvar_g_throughfloor_damage;
841         tfloorforce = autocvar_g_throughfloor_force;
842
843         total_damage_to_creatures = 0;
844
845         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
846                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
847                 {
848                         force = inflictorvelocity;
849                         if(vlen(force) == 0)
850                                 force = '0 0 -1';
851                         else
852                                 force = normalize(force);
853                         if(forceintensity >= 0)
854                                 Damage_DamageInfo(inflictororigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
855                         else
856                                 Damage_DamageInfo(inflictororigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
857                 }
858
859         stat_damagedone = 0;
860
861         targ = WarpZone_FindRadius (inflictororigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
862         while (targ)
863         {
864                 next = targ.chain;
865                 if ((targ != inflictor) || inflictorselfdamage)
866                 if (((cantbe != targ) && !mustbe) || (mustbe == targ))
867                 if (targ.takedamage)
868                 {
869                         vector nearest;
870                         vector diff;
871                         float power;
872
873                         // LordHavoc: measure distance to nearest point on target (not origin)
874                         // (this guarentees 100% damage on a touch impact)
875                         nearest = targ.WarpZone_findradius_nearest;
876                         diff = targ.WarpZone_findradius_dist;
877                         // round up a little on the damage to ensure full damage on impacts
878                         // and turn the distance into a fraction of the radius
879                         power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
880                         //bprint(" ");
881                         //bprint(ftos(power));
882                         //if (targ == attacker)
883                         //      print(ftos(power), "\n");
884                         if (power > 0)
885                         {
886                                 float finaldmg;
887                                 if (power > 1)
888                                         power = 1;
889                                 finaldmg = coredamage * power + edgedamage * (1 - power);
890                                 if (finaldmg > 0)
891                                 {
892                                         float a;
893                                         float c;
894                                         vector hitloc;
895                                         vector myblastorigin;
896                                         vector center;
897
898                                         myblastorigin = WarpZone_TransformOrigin(targ, inflictororigin);
899
900                                         // if it's a player, use the view origin as reference
901                                         center = CENTER_OR_VIEWOFS(targ);
902
903                                         force = normalize(center - myblastorigin);
904                                         force = force * (finaldmg / coredamage) * forceintensity;
905                                         hitloc = nearest;
906
907                                         if(targ != directhitentity)
908                                         {
909                                                 float hits;
910                                                 float total;
911                                                 float hitratio;
912                                                 float mininv_f, mininv_d;
913
914                                                 // test line of sight to multiple positions on box,
915                                                 // and do damage if any of them hit
916                                                 hits = 0;
917
918                                                 // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
919                                                 // so for a given max stddev:
920                                                 // n = (1 / (2 * max stddev of hitratio))^2
921
922                                                 mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
923                                                 mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
924
925                                                 if(autocvar_g_throughfloor_debug)
926                                                         printf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f);
927
928
929                                                 total = 0.25 * pow(max(mininv_f, mininv_d), 2);
930
931                                                 if(autocvar_g_throughfloor_debug)
932                                                         printf(" steps=%f", total);
933
934
935                                                 if (IS_PLAYER(targ))
936                                                         total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
937                                                 else
938                                                         total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
939
940                                                 if(autocvar_g_throughfloor_debug)
941                                                         printf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total)));
942
943                                                 for(c = 0; c < total; ++c)
944                                                 {
945                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
946                                                         WarpZone_TraceLine(inflictororigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
947                                                         if (trace_fraction == 1 || trace_ent == targ)
948                                                         {
949                                                                 ++hits;
950                                                                 if (hits > 1)
951                                                                         hitloc = hitloc + nearest;
952                                                                 else
953                                                                         hitloc = nearest;
954                                                         }
955                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
956                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
957                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
958                                                 }
959
960                                                 nearest = hitloc * (1 / max(1, hits));
961                                                 hitratio = (hits / total);
962                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
963                                                 finaldmg = finaldmg * a;
964                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
965                                                 force = force * a;
966
967                                                 if(autocvar_g_throughfloor_debug)
968                                                         printf(" D=%f F=%f\n", finaldmg, vlen(force));
969                                         }
970
971                                         //if (targ == attacker)
972                                         //{
973                                         //      print("hits ", ftos(hits), " / ", ftos(total));
974                                         //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
975                                         //      print(" (", ftos(a), ")\n");
976                                         //}
977                                         if(finaldmg || vlen(force))
978                                         {
979                                                 if(targ.iscreature)
980                                                 {
981                                                         total_damage_to_creatures += finaldmg;
982
983                                                         if(accuracy_isgooddamage(attacker, targ))
984                                                                 stat_damagedone += finaldmg;
985                                                 }
986
987                                                 if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
988                                                         Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
989                                                 else
990                                                         Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
991                                         }
992                                 }
993                         }
994                 }
995                 targ = next;
996         }
997
998         RadiusDamage_running = 0;
999
1000         if(!DEATH_ISSPECIAL(deathtype))
1001                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1002
1003         return total_damage_to_creatures;
1004 }
1005
1006 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity cantbe, entity mustbe, float forceintensity, float deathtype, entity directhitentity)
1007 {
1008         return RadiusDamageForSource (inflictor, (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5), inflictor.velocity, attacker, coredamage, edgedamage, rad, cantbe, mustbe, FALSE, forceintensity, deathtype, directhitentity);
1009 }
1010
1011 .float fire_damagepersec;
1012 .float fire_endtime;
1013 .float fire_deathtype;
1014 .entity fire_owner;
1015 .float fire_hitsound;
1016 .entity fire_burner;
1017
1018 void fireburner_think();
1019
1020 float Fire_IsBurning(entity e)
1021 {
1022         return (time < e.fire_endtime);
1023 }
1024
1025 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1026 {
1027         float dps;
1028         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1029
1030         if(IS_PLAYER(e))
1031         {
1032                 if(e.deadflag)
1033                         return -1;
1034         }
1035         else
1036         {
1037                 if(!e.fire_burner)
1038                 {
1039                         // print("adding a fire burner to ", e.classname, "\n");
1040                         e.fire_burner = spawn();
1041                         e.fire_burner.classname = "fireburner";
1042                         e.fire_burner.think = fireburner_think;
1043                         e.fire_burner.nextthink = time;
1044                         e.fire_burner.owner = e;
1045                 }
1046         }
1047
1048         t = max(t, 0.1);
1049         dps = d / t;
1050         if(Fire_IsBurning(e))
1051         {
1052                 mintime = e.fire_endtime - time;
1053                 maxtime = max(mintime, t);
1054
1055                 mindps = e.fire_damagepersec;
1056                 maxdps = max(mindps, dps);
1057
1058                 if(maxtime > mintime || maxdps > mindps)
1059                 {
1060                         // Constraints:
1061
1062                         // damage we have right now
1063                         mindamage = mindps * mintime;
1064
1065                         // damage we want to get
1066                         maxdamage = mindamage + d;
1067
1068                         // but we can't exceed maxtime * maxdps!
1069                         totaldamage = min(maxdamage, maxtime * maxdps);
1070
1071                         // LEMMA:
1072                         // Look at:
1073                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1074                         // We see:
1075                         // totaldamage <= maxtime * maxdps
1076                         // ==> totaldamage / maxdps <= maxtime.
1077                         // We also see:
1078                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1079                         //                     >= min(mintime, maxtime)
1080                         // ==> totaldamage / maxdps >= mintime.
1081
1082                         /*
1083                         // how long do we damage then?
1084                         // at least as long as before
1085                         // but, never exceed maxdps
1086                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1087                         */
1088
1089                         // alternate:
1090                         // at most as long as maximum allowed
1091                         // but, never below mindps
1092                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1093
1094                         // assuming t > mintime, dps > mindps:
1095                         // we get d = t * dps = maxtime * maxdps
1096                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1097                         // totaldamage / maxdps = maxtime
1098                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1099                         // FROM THIS:
1100                         // a) totaltime = max(mintime, maxtime) = maxtime
1101                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1102
1103                         // assuming t <= mintime:
1104                         // we get maxtime = mintime
1105                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1106                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1107
1108                         // assuming dps <= mindps:
1109                         // we get mindps = maxdps.
1110                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1111                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1112                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1113
1114                         e.fire_damagepersec = totaldamage / totaltime;
1115                         e.fire_endtime = time + totaltime;
1116                         if(totaldamage > 1.2 * mindamage)
1117                         {
1118                                 e.fire_deathtype = dt;
1119                                 if(e.fire_owner != o)
1120                                 {
1121                                         e.fire_owner = o;
1122                                         e.fire_hitsound = FALSE;
1123                                 }
1124                         }
1125                         if(accuracy_isgooddamage(o, e))
1126                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1127                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1128                 }
1129                 else
1130                         return 0;
1131         }
1132         else
1133         {
1134                 e.fire_damagepersec = dps;
1135                 e.fire_endtime = time + t;
1136                 e.fire_deathtype = dt;
1137                 e.fire_owner = o;
1138                 e.fire_hitsound = FALSE;
1139                 if(accuracy_isgooddamage(o, e))
1140                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1141                 return d;
1142         }
1143 }
1144
1145 void Fire_ApplyDamage(entity e)
1146 {
1147         float t, d, hi, ty;
1148         entity o;
1149
1150         if (!Fire_IsBurning(e))
1151                 return;
1152
1153         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1154         if(IS_NOT_A_CLIENT(o))
1155                 o = e.fire_owner;
1156
1157         // water and slime stop fire
1158         if(e.waterlevel)
1159         if(e.watertype != CONTENT_LAVA)
1160                 e.fire_endtime = 0;
1161
1162         // ice stops fire
1163         if(e.freezetag_frozen)
1164                 e.fire_endtime = 0;
1165
1166         t = min(frametime, e.fire_endtime - time);
1167         d = e.fire_damagepersec * t;
1168
1169         hi = e.fire_owner.hitsound;
1170         ty = e.fire_owner.typehitsound;
1171         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1172         if(e.fire_hitsound && e.fire_owner)
1173         {
1174                 e.fire_owner.hitsound = hi;
1175                 e.fire_owner.typehitsound = ty;
1176         }
1177         e.fire_hitsound = TRUE;
1178
1179         if (!IS_INDEPENDENT_PLAYER(e))
1180         if(!e.freezetag_frozen)
1181         FOR_EACH_PLAYER(other) if(e != other)
1182         {
1183                 if(IS_PLAYER(other))
1184                 if(other.deadflag == DEAD_NO)
1185                 if (!IS_INDEPENDENT_PLAYER(other))
1186                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1187                 {
1188                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1189                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1190                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1191                 }
1192         }
1193 }
1194
1195 void Fire_ApplyEffect(entity e)
1196 {
1197         if(Fire_IsBurning(e))
1198                 e.effects |= EF_FLAME;
1199         else
1200                 e.effects &= ~EF_FLAME;
1201 }
1202
1203 void fireburner_think()
1204 {
1205         // for players, this is done in the regular loop
1206         if(wasfreed(self.owner))
1207         {
1208                 remove(self);
1209                 return;
1210         }
1211         Fire_ApplyEffect(self.owner);
1212         if(!Fire_IsBurning(self.owner))
1213         {
1214                 self.owner.fire_burner = world;
1215                 remove(self);
1216                 return;
1217         }
1218         Fire_ApplyDamage(self.owner);
1219         self.nextthink = time;
1220 }