qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(targ != attacker) // not for suicides
 124         if(g_weaponarena_random)
 125         {
 126                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 127                 float culprit;
 128                 culprit = DEATH_WEAPONOF(deathtype);
 129                 if(!culprit)
 130                         culprit = attacker.weapon;
 131                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 132                         culprit = attacker.weapon;
 133
 134                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 135                 {
 136                         // no exchange
 137                 }
 138                 else
 139                 {
 140                         if(!GiveFrags_randomweapons)
 141                         {
 142                                 GiveFrags_randomweapons = spawn();
 143                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 144                         }
 145
 146                         if(inWarmupStage)
 147                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 148                         else
 149                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 150
 151                         // all others (including the culprit): remove
 152                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 153                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 154
 155                         // among the remaining ones, choose one by random
 156                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 157
 158                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 159                         {
 160                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 161                                 WEPSET_ANDNOT_EW(attacker, culprit);
 162                         }
 163                 }
 164
 165                 // after a frag, choose another random weapon set
 166                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 167                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 168         }
 169
 170         // FIXME fix the mess this is (we have REAL points now!)
 171         entity oldself;
 172         oldself = self;
 173         self = attacker;
 174         frag_attacker = attacker;
 175         frag_target = targ;
 176         frag_score = f;
 177         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 178         {
 179                 f = frag_score;
 180                 self = oldself;
 181         }
 182         else
 183         {
 184                 self = oldself;
 185         }
 186
 187         attacker.totalfrags += f;
 188
 189         if(f)
 190                 UpdateFrags(attacker, f);
 191 }
 192
 193 string AppendItemcodes(string s, entity player)
 194 {
 195         float w;
 196         w = player.weapon;
 197         //if(w == 0)
 198         //      w = player.switchweapon;
 199         if(w == 0)
 200                 w = player.cnt; // previous weapon!
 201         s = strcat(s, ftos(w));
 202         if(time < player.strength_finished)
 203                 s = strcat(s, "S");
 204         if(time < player.invincible_finished)
 205                 s = strcat(s, "I");
 206         if(player.flagcarried != world)
 207                 s = strcat(s, "F");
 208         if(player.BUTTON_CHAT)
 209                 s = strcat(s, "T");
 210         if(player.kh_next)
 211                 s = strcat(s, "K");
 212         return s;
 213 }
 214
 215 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 216 {
 217         string s;
 218         if(!autocvar_sv_eventlog)
 219                 return;
 220         s = strcat(":kill:", mode);
 221         s = strcat(s, ":", ftos(killer.playerid));
 222         s = strcat(s, ":", ftos(killed.playerid));
 223         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 224         s = strcat(s, ":items=");
 225         s = AppendItemcodes(s, killer);
 226         if(killed != killer)
 227         {
 228                 s = strcat(s, ":victimitems=");
 229                 s = AppendItemcodes(s, killed);
 230         }
 231         GameLogEcho(s);
 232 }
 233
 234 void Obituary_SpecialDeath(
 235         entity notif_target,
 236         float murder,
 237         float deathtype,
 238         string s1, string s2, string s3,
 239         float f1, float f2, float f3)
 240 {
 241         if(DEATH_ISSPECIAL(deathtype))
 242         {
 243                 entity deathent = deathtypes[(deathtype - DT_FIRST) - 1];
 244                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 245
 246                 if(murder)
 247                 {
 248                         if(deathent.death_msgmurder)
 249                         {
 250                                 Send_Notification_WOVA(
 251                                         NOTIF_ONE,
 252                                         notif_target,
 253                                         MSG_MULTI,
 254                                         deathent.death_msgmurder.nent_id,
 255                                         s1, s2, s3, "",
 256                                         f1, f2, f3, 0
 257                                 );
 258                                 Send_Notification_WOVA(
 259                                         NOTIF_ALL_EXCEPT,
 260                                         notif_target,
 261                                         MSG_INFO,
 262                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 263                                         s1, s2, s3, "",
 264                                         f1, f2, f3, 0
 265                                 );
 266                         }
 267                 }
 268                 else
 269                 {
 270                         if(deathent.death_msgself)
 271                         {
 272                                 Send_Notification_WOVA(
 273                                         NOTIF_ONE,
 274                                         notif_target,
 275                                         MSG_MULTI,
 276                                         deathent.death_msgself.nent_id,
 277                                         s1, s2, s3, "",
 278                                         f1, f2, f3, 0
 279                                 );
 280                                 Send_Notification_WOVA(
 281                                         NOTIF_ALL_EXCEPT,
 282                                         notif_target,
 283                                         MSG_INFO,
 284                                         deathent.death_msgself.nent_msginfo.nent_id,
 285                                         s1, s2, s3, "",
 286                                         f1, f2, f3, 0
 287                                 );
 288                         }
 289                 }
 290         }
 291         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 292 }
 293
 294 float w_deathtype;
 295 float Obituary_WeaponDeath(
 296         entity notif_target,
 297         float murder,
 298         float deathtype,
 299         string s1, string s2, string s3,
 300         float f1, float f2)
 301 {
 302         float death_weapon = DEATH_WEAPONOF(deathtype);
 303         if(death_weapon)
 304         {
 305                 w_deathtype = deathtype;
 306                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 307                 w_deathtype = FALSE;
 308
 309                 if(death_message)
 310                 {
 311                         Send_Notification_WOVA(
 312                                 NOTIF_ONE,
 313                                 notif_target,
 314                                 MSG_MULTI,
 315                                 death_message,
 316                                 s1, s2, s3, "",
 317                                 f1, f2, 0, 0
 318                         );
 319                         Send_Notification_WOVA(
 320                                 NOTIF_ALL_EXCEPT,
 321                                 notif_target,
 322                                 MSG_INFO,
 323                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 324                                 s1, s2, s3, "",
 325                                 f1, f2, 0, 0
 326                         );
 327                 }
 328                 else
 329                 {
 330                         dprint(sprintf(
 331                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 332                                 deathtype,
 333                                 death_weapon
 334                         ));
 335                 }
 336
 337                 return TRUE;
 338         }
 339         return FALSE;
 340 }
 341
 342 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 343 {
 344         // Sanity check
 345         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 346
 347         // Declarations
 348         float notif_firstblood = FALSE;
 349         float kill_count_to_attacker, kill_count_to_target;
 350
 351         // Set final information for the death
 352         targ.death_origin = targ.origin;
 353         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 354         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 355
 356         #ifdef NOTIFICATIONS_DEBUG
 357         Debug_Notification(
 358                 sprintf(
 359                         "Obituary(%s, %s, %s, %s = %d);\n",
 360                         attacker.netname,
 361                         inflictor.netname,
 362                         targ.netname,
 363                         Deathtype_Name(deathtype),
 364                         deathtype
 365                 )
 366         );
 367         #endif
 368
 369         // =======
 370         // SUICIDE
 371         // =======
 372         if(targ == attacker)
 373         {
 374                 if(DEATH_ISSPECIAL(deathtype))
 375                 {
 376                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 377                         {
 378                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 379                         }
 380                         else
 381                         {
 382                                 switch(deathtype)
 383                                 {
 384                                         case DEATH_MIRRORDAMAGE:
 385                                         {
 386                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 387                                                 break;
 388                                         }
 389
 390                                         default:
 391                                         {
 392                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 393                                                 break;
 394                                         }
 395                                 }
 396                         }
 397                 }
 398                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 399                 {
 400                         backtrace("SUICIDE: what the hell happened here?\n");
 401                         return;
 402                 }
 403                 LogDeath("suicide", deathtype, targ, targ);
 404                 GiveFrags(attacker, targ, -1, deathtype);
 405         }
 406
 407         // ======
 408         // MURDER
 409         // ======
 410         else if(IS_PLAYER(attacker))
 411         {
 412                 if(!IsDifferentTeam(attacker, targ))
 413                 {
 414                         LogDeath("tk", deathtype, attacker, targ);
 415                         GiveFrags(attacker, targ, -1, deathtype);
 416
 417                         attacker.killcount = 0;
 418
 419                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 420                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 421                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 422
 423                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 424                         // No need for specific death/weapon messages...
 425                 }
 426                 else
 427                 {
 428                         LogDeath("frag", deathtype, attacker, targ);
 429                         GiveFrags(attacker, targ, 1, deathtype);
 430
 431                         attacker.taunt_soundtime = time + 1;
 432                         attacker.killcount = attacker.killcount + 1;
 433
 434                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 435                                 case counta: \
 436                                 { \
 437                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 438                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 439                                         break; \
 440                                 }
 441                         switch(attacker.killcount)
 442                         {
 443                                 KILL_SPREE_LIST
 444                                 default: break;
 445                         }
 446                         #undef SPREE_ITEM
 447
 448                         if(!checkrules_firstblood)
 449                         {
 450                                 checkrules_firstblood = TRUE;
 451                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 452                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 453                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 454
 455                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 456                                 kill_count_to_attacker = -1;
 457                                 kill_count_to_target = -2;
 458                         }
 459                         else
 460                         {
 461                                 kill_count_to_attacker = attacker.killcount;
 462                                 kill_count_to_target = 0;
 463                         }
 464
 465                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
 466                         if(targ.istypefrag)
 467                         {
 468                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 469                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 470                                 else
 471                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 472
 473                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 474                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 475                                 else
 476                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 477                         }
 478                         else
 479                         {
 480                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 481                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 482                                 else
 483                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 484
 485                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 486                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 487                                 else
 488                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 489                         }
 490
 491                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 492                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 493                 }
 494         }
 495
 496         // =============
 497         // ACCIDENT/TRAP
 498         // =============
 499         else
 500         {
 501                 switch(deathtype)
 502                 {
 503                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 504                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 505                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 506                         /*case DEATH_HURTTRIGGER:
 507                         {
 508                                 s1 = targ.netname;
 509                                 s2 = inflictor.message;
 510                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 511                                 break;
 512                         }*/
 513
 514                         case DEATH_CUSTOM:
 515                         {
 516                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 517                                         targ.netname,
 518                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 519                                         deathlocation,
 520                                         targ.killcount,
 521                                         0,
 522                                         0);
 523                                 break;
 524                         }
 525
 526                         default:
 527                         {
 528                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 529                                 break;
 530                         }
 531                 }
 532
 533                 LogDeath("accident", deathtype, targ, targ);
 534                 GiveFrags(targ, targ, -1, deathtype);
 535
 536                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 537                 {
 538                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 539                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 540                 }
 541         }
 542
 543         // reset target kill count
 544         if(targ.killcount) { targ.killcount = 0; }
 545 }
 546
 547 void Ice_Think()
 548 {
 549         setorigin(self, self.owner.origin - '0 0 16');
 550         self.nextthink = time;
 551 }
 552
 553 void Freeze (entity targ, float freeze_time, float frozen_type, float show_waypoint)
 554 {
 555         float monster = (targ.flags & FL_MONSTER);
 556         float player = (targ.flags & FL_CLIENT);
 557
 558         if(!player && !monster) // only specified entities can be freezed
 559                 return;
 560
 561         if(targ.frozen)
 562                 return;
 563
 564         targ.frozen = frozen_type;
 565         targ.revive_progress = 0;
 566         targ.health = 1;
 567         targ.revive_speed = freeze_time;
 568
 569         entity ice;
 570         ice = spawn();
 571         ice.owner = targ;
 572         ice.classname = "ice";
 573         ice.scale = targ.scale;
 574         ice.think = Ice_Think;
 575         ice.nextthink = time;
 576         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 577         setmodel(ice, "models/ice/ice.md3");
 578         ice.alpha = 1;
 579         ice.colormod = Team_ColorRGB(self.team);
 580         ice.glowmod = ice.colormod;
 581         targ.iceblock = ice;
 582
 583         entity oldself;
 584         oldself = self;
 585         self = ice;
 586         Ice_Think();
 587         self = oldself;
 588
 589         RemoveGrapplingHook(targ);
 590
 591         // add waypoint
 592         if(show_waypoint)
 593                 WaypointSprite_Spawn("frozen", 0, 0, targ, '0 0 64', world, targ.team, targ, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 594 }
 595
 596 void Unfreeze (entity targ)
 597 {
 598         targ.frozen = 0;
 599         targ.revive_progress = 0;
 600         targ.health = ((targ.classname == STR_PLAYER) ? autocvar_g_balance_health_start : targ.max_health);
 601
 602         WaypointSprite_Kill(targ.waypointsprite_attached);
 603
 604         // remove the ice block
 605         remove(targ.iceblock);
 606         targ.iceblock = world;
 607 }
 608
 609 // these are updated by each Damage call for use in button triggering and such
 610 entity damage_targ;
 611 entity damage_inflictor;
 612 entity damage_attacker;
 613
 614 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 615 {
 616         float mirrordamage;
 617         float mirrorforce;
 618         float complainteamdamage = 0;
 619         entity attacker_save;
 620         mirrordamage = 0;
 621         mirrorforce = 0;
 622
 623         if (gameover || targ.killcount == -666)
 624                 return;
 625
 626         entity oldself;
 627         oldself = self;
 628         self = targ;
 629         damage_targ = targ;
 630         damage_inflictor = inflictor;
 631         damage_attacker = attacker;
 632                 attacker_save = attacker;
 633
 634         if(targ.classname == "player")
 635                 if(targ.hook)
 636                         if(targ.hook.aiment)
 637                                 if(targ.hook.aiment == attacker)
 638                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 639
 640         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 641         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 642         {
 643                 if(targ.classname == "player")
 644                         if not(IsDifferentTeam(targ, attacker))
 645                         {
 646                                 self = oldself;
 647                                 return;
 648                         }
 649         }
 650
 651         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 652         {
 653                 // These are ALWAYS lethal
 654                 // No damage modification here
 655                 // Instead, prepare the victim for his death...
 656                 targ.armorvalue = 0;
 657                 targ.spawnshieldtime = 0;
 658                 targ.health = 0.9; // this is < 1
 659                 targ.flags -= targ.flags & FL_GODMODE;
 660                 damage = 100000;
 661         }
 662         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 663         {
 664                 // no processing
 665         }
 666         else
 667         {
 668                 /*
 669                 skill based bot damage? gtfo. (tZork)
 670                 if (targ.classname == "player")
 671                 if (attacker.classname == "player")
 672                 if (!targ.isbot)
 673                 if (attacker.isbot)
 674                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 675         */
 676
 677                 // nullify damage if teamplay is on
 678                 if(deathtype != DEATH_TELEFRAG)
 679                 if(attacker.classname == "player")
 680                 {
 681                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 682                         {
 683                                 damage = 0;
 684                                 force = '0 0 0';
 685                         }
 686                         else if(!IsDifferentTeam(attacker, targ))
 687                         {
 688                                 if(autocvar_teamplay_mode == 1)
 689                                         damage = 0;
 690                                 else if(attacker != targ)
 691                                 {
 692                                         if(autocvar_teamplay_mode == 3)
 693                                                 damage = 0;
 694                                         else if(autocvar_teamplay_mode == 4)
 695                                         {
 696                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 697                                                 {
 698                                                         attacker.dmg_team = attacker.dmg_team + damage;
 699                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 700                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 701                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 702                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 703                                                         if(g_minstagib)
 704                                                         {
 705                                                                 if(autocvar_g_friendlyfire == 0)
 706                                                                         damage = 0;
 707                                                         }
 708                                                         else if(g_ca)
 709                                                                 damage = 0;
 710                                                         else
 711                                                                 damage = autocvar_g_friendlyfire * damage;
 712                                                         // mirrordamage will be used LATER
 713
 714                                                         if(autocvar_g_mirrordamage_virtual)
 715                                                         {
 716                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 717                                                                 attacker.dmg_take += v_x;
 718                                                                 attacker.dmg_save += v_y;
 719                                                                 attacker.dmg_inflictor = inflictor;
 720                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 721                                                                 mirrorforce = 0;
 722                                                         }
 723
 724                                                         if(autocvar_g_friendlyfire_virtual)
 725                                                         {
 726                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 727                                                                 targ.dmg_take += v_x;
 728                                                                 targ.dmg_save += v_y;
 729                                                                 targ.dmg_inflictor = inflictor;
 730                                                                 damage = 0;
 731                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 732                                                                         force = '0 0 0';
 733                                                         }
 734                                                 }
 735                                                 else
 736                                                         damage = 0;
 737                                         }
 738                                 }
 739                         }
 740                 }
 741
 742                 if(targ.classname == "player")
 743                 if (g_minstagib)
 744                 {
 745                         if ((deathtype == DEATH_FALL)  ||
 746                                 (deathtype == DEATH_DROWN) ||
 747                                 (deathtype == DEATH_SLIME) ||
 748                                 (deathtype == DEATH_LAVA)  ||
 749                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 750                         {
 751                                 self = oldself;
 752                                 return;
 753                         }
 754                         if(damage > 0)
 755                             damage = 10000;
 756                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 757                         {
 758                                 targ.armorvalue -= 1;
 759                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 760                                 damage = 0;
 761                                 targ.hitsound += 1;
 762                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 763                         }
 764                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 765                         {
 766                                 damage = 0;
 767                                 mirrordamage = 0;
 768                                 complainteamdamage = 0;
 769                                 if (targ != attacker)
 770                                 {
 771                                         if ((targ.health >= 1) && (targ.classname == "player"))
 772                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 773                                         force = '0 0 0';
 774                                         // keep mirrorforce
 775                                         attacker = targ;
 776                                 }
 777                         }
 778                 }
 779
 780                 if not(DEATH_ISSPECIAL(deathtype))
 781                 {
 782                         damage *= g_weapondamagefactor;
 783                         mirrordamage *= g_weapondamagefactor;
 784                         complainteamdamage *= g_weapondamagefactor;
 785                         force = force * g_weaponforcefactor;
 786                         mirrorforce *= g_weaponforcefactor;
 787                 }
 788
 789                 if(((targ.frozen == 2 && attacker.monsterid != MONSTER_SPIDER) || (targ.frozen == 1)) && deathtype != DEATH_HURTTRIGGER)
 790                 {
 791                         damage = 0;
 792                         force *= 0.2;
 793                 }
 794
 795                 // should this be changed at all? If so, in what way?
 796                 frag_attacker = attacker;
 797                 frag_target = targ;
 798                 frag_damage = damage;
 799                 frag_force = force;
 800         frag_deathtype = deathtype;
 801                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 802                 damage = frag_damage;
 803                 force = frag_force;
 804
 805                 // apply strength multiplier
 806                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 807                 {
 808                         if(targ == attacker)
 809                         {
 810                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 811                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 812                         }
 813                         else
 814                         {
 815                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 816                                 force = force * autocvar_g_balance_powerup_strength_force;
 817                         }
 818                 }
 819
 820                 // apply invincibility multiplier
 821                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 822                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 823
 824                 if (targ == attacker)
 825                 {
 826                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 827                                 damage = 0;
 828                         else
 829                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 830                 }
 831
 832                 // count the damage
 833                 if(attacker)
 834                 if(!targ.deadflag)
 835                 if(targ.takedamage == DAMAGE_AIM)
 836                 if(targ != attacker)
 837                 {
 838                         entity victim;
 839                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 840                                 victim = targ.owner;
 841                         else
 842                                 victim = targ;
 843
 844                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET || victim.flags & FL_MONSTER)
 845                         {
 846                                 if(IsDifferentTeam(victim, attacker))
 847                                 {
 848                                         if(damage > 0)
 849                                         {
 850                                                 if(deathtype != DEATH_FIRE)
 851                                                 {
 852                                                         if(victim.BUTTON_CHAT)
 853                                                                 attacker.typehitsound += 1;
 854                                                         else
 855                                                                 attacker.hitsound += 1;
 856                                                 }
 857
 858                                                 damage_goodhits += 1;
 859                                                 damage_gooddamage += damage;
 860
 861                                                 if not(DEATH_ISSPECIAL(deathtype))
 862                                                 {
 863                                                         if(targ.classname == "player") // don't do this for vehicles
 864                                                         if(!g_minstagib)
 865                                                         if(IsFlying(victim))
 866                                                                 yoda = 1;
 867
 868                                                         if(g_minstagib)
 869                                                         if(victim.items & IT_STRENGTH)
 870                                                                 yoda = 1;
 871                                                 }
 872                                         }
 873                                 }
 874                                 else
 875                                 {
 876                                         if(deathtype != DEATH_FIRE)
 877                                         {
 878                                                 attacker.typehitsound += 1;
 879                                         }
 880                                         if(complainteamdamage > 0)
 881                                                 if(time > attacker.teamkill_complain)
 882                                                 {
 883                                                         attacker.teamkill_complain = time + 5;
 884                                                         attacker.teamkill_soundtime = time + 0.4;
 885                                                         attacker.teamkill_soundsource = targ;
 886                                                 }
 887                                 }
 888                         }
 889                 }
 890         }
 891
 892         // apply push
 893         if (self.damageforcescale)
 894         if (vlen(force))
 895         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 896         {
 897                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 898                 if(self.movetype == MOVETYPE_PHYSICS)
 899                 {
 900                         entity farcent;
 901                         farcent = spawn();
 902                         farcent.classname = "farce";
 903                         farcent.enemy = self;
 904                         farcent.movedir = farce * 10;
 905                         if(self.mass)
 906                                 farcent.movedir = farcent.movedir * self.mass;
 907                         farcent.origin = hitloc;
 908                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 909                         farcent.nextthink = time + 0.1;
 910                         farcent.think = SUB_Remove;
 911                 }
 912                 else
 913                         self.velocity = self.velocity + farce;
 914                 self.flags &~= FL_ONGROUND;
 915                 UpdateCSQCProjectile(self);
 916         }
 917         // apply damage
 918         if (damage != 0 || (self.damageforcescale && vlen(force)))
 919         if (self.event_damage)
 920                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 921         self = oldself;
 922
 923         // apply mirror damage if any
 924         if(mirrordamage > 0 || mirrorforce > 0)
 925         {
 926                 attacker = attacker_save;
 927                 if(g_minstagib)
 928                 if(mirrordamage > 0)
 929                 {
 930                         // just lose extra LIVES, don't kill the player for mirror damage
 931                         if(attacker.armorvalue > 0)
 932                         {
 933                                 attacker.armorvalue = attacker.armorvalue - 1;
 934                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 935                                 attacker.hitsound += 1;
 936                         }
 937                         mirrordamage = 0;
 938                 }
 939
 940                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 941                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 942         }
 943 }
 944
 945 float RadiusDamage_running;
 946 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 947         // Returns total damage applies to creatures
 948 {
 949         entity  targ;
 950         vector  blastorigin;
 951         vector  force;
 952         float   total_damage_to_creatures;
 953         entity  next;
 954         float   tfloordmg;
 955         float   tfloorforce;
 956
 957         float stat_damagedone;
 958
 959         if(RadiusDamage_running)
 960         {
 961                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 962                 return 0;
 963         }
 964
 965         RadiusDamage_running = 1;
 966
 967         tfloordmg = autocvar_g_throughfloor_damage;
 968         tfloorforce = autocvar_g_throughfloor_force;
 969
 970         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 971         total_damage_to_creatures = 0;
 972
 973         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 974                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 975                 {
 976                         force = inflictor.velocity;
 977                         if(vlen(force) == 0)
 978                                 force = '0 0 -1';
 979                         else
 980                                 force = normalize(force);
 981                         if(forceintensity >= 0)
 982                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 983                         else
 984                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 985                 }
 986
 987         stat_damagedone = 0;
 988
 989         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 990         while (targ)
 991         {
 992                 next = targ.chain;
 993                 if (targ != inflictor)
 994                         if (ignore != targ) if(targ.takedamage)
 995                         {
 996                                 vector nearest;
 997                                 vector diff;
 998                                 float power;
 999
1000                                 // LordHavoc: measure distance to nearest point on target (not origin)
1001                                 // (this guarentees 100% damage on a touch impact)
1002                                 nearest = targ.WarpZone_findradius_nearest;
1003                                 diff = targ.WarpZone_findradius_dist;
1004                                 // round up a little on the damage to ensure full damage on impacts
1005                                 // and turn the distance into a fraction of the radius
1006                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1007                                 //bprint(" ");
1008                                 //bprint(ftos(power));
1009                                 //if (targ == attacker)
1010                                 //      print(ftos(power), "\n");
1011                                 if (power > 0)
1012                                 {
1013                                         float finaldmg;
1014                                         if (power > 1)
1015                                                 power = 1;
1016                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1017                                         if (finaldmg > 0)
1018                                         {
1019                                                 float a;
1020                                                 float c;
1021                                                 vector hitloc;
1022                                                 vector myblastorigin;
1023                                                 vector center;
1024
1025                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1026
1027                                                 // if it's a player, use the view origin as reference
1028                                                 center = CENTER_OR_VIEWOFS(targ);
1029
1030                                                 force = normalize(center - myblastorigin);
1031                                                 force = force * (finaldmg / coredamage) * forceintensity;
1032                                                 hitloc = nearest;
1033
1034                                                 if(targ != directhitentity)
1035                                                 {
1036                                                         float hits;
1037                                                         float total;
1038                                                         float hitratio;
1039                                                         float mininv_f, mininv_d;
1040
1041                                                         // test line of sight to multiple positions on box,
1042                                                         // and do damage if any of them hit
1043                                                         hits = 0;
1044
1045                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1046                                                         // so for a given max stddev:
1047                                                         // n = (1 / (2 * max stddev of hitratio))^2
1048
1049                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1050                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1051
1052                                                         if(autocvar_g_throughfloor_debug)
1053                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1054
1055                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1056
1057                                                         if(autocvar_g_throughfloor_debug)
1058                                                                 print(sprintf(" steps=%f", total));
1059
1060                                                         if (targ.classname == "player")
1061                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1062                                                         else
1063                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1064
1065                                                         if(autocvar_g_throughfloor_debug)
1066                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1067
1068                                                         for(c = 0; c < total; ++c)
1069                                                         {
1070                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1071                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1072                                                                 if (trace_fraction == 1 || trace_ent == targ)
1073                                                                 {
1074                                                                         ++hits;
1075                                                                         if (hits > 1)
1076                                                                                 hitloc = hitloc + nearest;
1077                                                                         else
1078                                                                                 hitloc = nearest;
1079                                                                 }
1080                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1081                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1082                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1083                                                         }
1084
1085                                                         nearest = hitloc * (1 / max(1, hits));
1086                                                         hitratio = (hits / total);
1087                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1088                                                         finaldmg = finaldmg * a;
1089                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1090                                                         force = force * a;
1091
1092                                                         if(autocvar_g_throughfloor_debug)
1093                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1094                                                 }
1095
1096                                                 // laser force adjustments :P
1097                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1098                                                 {
1099                                                         if (targ == attacker)
1100                                                         {
1101                                                                 vector vel;
1102
1103                                                                 float force_zscale;
1104                                                                 float force_velocitybiasramp;
1105                                                                 float force_velocitybias;
1106
1107                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1108                                                                 if(deathtype & HITTYPE_SECONDARY)
1109                                                                 {
1110                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1111                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1112                                                                 }
1113                                                                 else
1114                                                                 {
1115                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1116                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1117                                                                 }
1118
1119                                                                 vel = targ.velocity;
1120                                                                 vel_z = 0;
1121                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1122                                                                 force =
1123                                                                         vlen(force)
1124                                                                         *
1125                                                                         normalize(normalize(force) + vel);
1126
1127                                                                 force_z *= force_zscale;
1128                                                         }
1129                                                         else
1130                                                         {
1131                                                                 if(deathtype & HITTYPE_SECONDARY)
1132                                                                 {
1133                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1134                                                                 }
1135                                                                 else
1136                                                                 {
1137                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1138                                                                 }
1139                                                         }
1140                                                 }
1141
1142                                                 //if (targ == attacker)
1143                                                 //{
1144                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1145                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1146                                                 //      print(" (", ftos(a), ")\n");
1147                                                 //}
1148                                                 if(finaldmg || vlen(force))
1149                                                 {
1150                                                         if(targ.iscreature)
1151                                                         {
1152                                                                 total_damage_to_creatures += finaldmg;
1153
1154                                                                 if(accuracy_isgooddamage(attacker, targ))
1155                                                                         stat_damagedone += finaldmg;
1156                                                         }
1157
1158                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1159                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1160                                                         else
1161                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1162                                                 }
1163                                         }
1164                                 }
1165                         }
1166                 targ = next;
1167         }
1168
1169         RadiusDamage_running = 0;
1170
1171         if(!DEATH_ISSPECIAL(deathtype))
1172                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1173
1174         return total_damage_to_creatures;
1175 }
1176
1177 .float fire_damagepersec;
1178 .float fire_endtime;
1179 .float fire_deathtype;
1180 .entity fire_owner;
1181 .float fire_hitsound;
1182 .entity fire_burner;
1183
1184 void fireburner_think();
1185
1186 float Fire_IsBurning(entity e)
1187 {
1188         return (time < e.fire_endtime);
1189 }
1190
1191 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1192 {
1193         float dps;
1194         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1195
1196         if(e.classname == "player")
1197         {
1198                 if(e.deadflag)
1199                         return -1;
1200         }
1201         else
1202         {
1203                 if(!e.fire_burner)
1204                 {
1205                         // print("adding a fire burner to ", e.classname, "\n");
1206                         e.fire_burner = spawn();
1207                         e.fire_burner.classname = "fireburner";
1208                         e.fire_burner.think = fireburner_think;
1209                         e.fire_burner.nextthink = time;
1210                         e.fire_burner.owner = e;
1211                 }
1212         }
1213
1214         t = max(t, 0.1);
1215         dps = d / t;
1216         if(Fire_IsBurning(e))
1217         {
1218                 mintime = e.fire_endtime - time;
1219                 maxtime = max(mintime, t);
1220
1221                 mindps = e.fire_damagepersec;
1222                 maxdps = max(mindps, dps);
1223
1224                 if(maxtime > mintime || maxdps > mindps)
1225                 {
1226                         // Constraints:
1227
1228                         // damage we have right now
1229                         mindamage = mindps * mintime;
1230
1231                         // damage we want to get
1232                         maxdamage = mindamage + d;
1233
1234                         // but we can't exceed maxtime * maxdps!
1235                         totaldamage = min(maxdamage, maxtime * maxdps);
1236
1237                         // LEMMA:
1238                         // Look at:
1239                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1240                         // We see:
1241                         // totaldamage <= maxtime * maxdps
1242                         // ==> totaldamage / maxdps <= maxtime.
1243                         // We also see:
1244                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1245                         //                     >= min(mintime, maxtime)
1246                         // ==> totaldamage / maxdps >= mintime.
1247
1248                         /*
1249                         // how long do we damage then?
1250                         // at least as long as before
1251                         // but, never exceed maxdps
1252                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1253                         */
1254
1255                         // alternate:
1256                         // at most as long as maximum allowed
1257                         // but, never below mindps
1258                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1259
1260                         // assuming t > mintime, dps > mindps:
1261                         // we get d = t * dps = maxtime * maxdps
1262                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1263                         // totaldamage / maxdps = maxtime
1264                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1265                         // FROM THIS:
1266                         // a) totaltime = max(mintime, maxtime) = maxtime
1267                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1268
1269                         // assuming t <= mintime:
1270                         // we get maxtime = mintime
1271                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1272                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1273
1274                         // assuming dps <= mindps:
1275                         // we get mindps = maxdps.
1276                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1277                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1278                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1279
1280                         e.fire_damagepersec = totaldamage / totaltime;
1281                         e.fire_endtime = time + totaltime;
1282                         if(totaldamage > 1.2 * mindamage)
1283                         {
1284                                 e.fire_deathtype = dt;
1285                                 if(e.fire_owner != o)
1286                                 {
1287                                         e.fire_owner = o;
1288                                         e.fire_hitsound = FALSE;
1289                                 }
1290                         }
1291                         if(accuracy_isgooddamage(o, e))
1292                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1293                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1294                 }
1295                 else
1296                         return 0;
1297         }
1298         else
1299         {
1300                 e.fire_damagepersec = dps;
1301                 e.fire_endtime = time + t;
1302                 e.fire_deathtype = dt;
1303                 e.fire_owner = o;
1304                 e.fire_hitsound = FALSE;
1305                 if(accuracy_isgooddamage(o, e))
1306                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1307                 return d;
1308         }
1309 }
1310
1311 void Fire_ApplyDamage(entity e)
1312 {
1313         float t, d, hi, ty;
1314         entity o;
1315
1316         if not(Fire_IsBurning(e))
1317                 return;
1318
1319         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1320         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1321                 o = e.fire_owner;
1322
1323         // water and slime stop fire
1324         if(e.waterlevel)
1325         if(e.watertype != CONTENT_LAVA)
1326                 e.fire_endtime = 0;
1327
1328         // ice stops fire
1329         if(e.frozen)
1330                 e.fire_endtime = 0;
1331
1332         t = min(frametime, e.fire_endtime - time);
1333         d = e.fire_damagepersec * t;
1334
1335         hi = e.fire_owner.hitsound;
1336         ty = e.fire_owner.typehitsound;
1337         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1338         if(e.fire_hitsound && e.fire_owner)
1339         {
1340                 e.fire_owner.hitsound = hi;
1341                 e.fire_owner.typehitsound = ty;
1342         }
1343         e.fire_hitsound = TRUE;
1344
1345         if not(IS_INDEPENDENT_PLAYER(e))
1346         FOR_EACH_PLAYER(other) if(e != other)
1347         {
1348                 if(other.classname == "player")
1349                 if(other.deadflag == DEAD_NO)
1350                 if not(IS_INDEPENDENT_PLAYER(other))
1351                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1352                 {
1353                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1354                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1355                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1356                 }
1357         }
1358 }
1359
1360 void Fire_ApplyEffect(entity e)
1361 {
1362         if(Fire_IsBurning(e))
1363                 e.effects |= EF_FLAME;
1364         else
1365                 e.effects &~= EF_FLAME;
1366 }
1367
1368 void fireburner_think()
1369 {
1370         // for players, this is done in the regular loop
1371         if(wasfreed(self.owner))
1372         {
1373                 remove(self);
1374                 return;
1375         }
1376         Fire_ApplyEffect(self.owner);
1377         if(!Fire_IsBurning(self.owner))
1378         {
1379                 self.owner.fire_burner = world;
1380                 remove(self);
1381                 return;
1382         }
1383         Fire_ApplyDamage(self.owner);
1384         self.nextthink = time;
1385 }