qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         return TRUE;
  18 }
  19
  20 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, entity dmgowner)
  21 {
  22         // TODO maybe call this from non-edgedamage too?
  23         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  24
  25         entity e;
  26
  27         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  28                 deathtype |= 0x8000;
  29
  30         e = spawn();
  31         setorigin(e, org);
  32         e.projectiledeathtype = deathtype;
  33         e.dmg = coredamage;
  34         e.dmg_edge = edgedamage;
  35         e.dmg_radius = rad;
  36         e.dmg_force = vlen(force);
  37         e.velocity = force;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  42 }
  43
  44 #define DAMAGE_CENTERPRINT_SPACER NEWLINES
  45
  46 float checkrules_firstblood;
  47
  48 float yoda;
  49 float damage_goodhits;
  50 float damage_gooddamage;
  51 float headshot;
  52 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  53
  54 .float dmg_team;
  55 .float teamkill_complain;
  56 .float teamkill_soundtime;
  57 .entity teamkill_soundsource;
  58 .entity pusher;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teams_matter)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '0.6 0 0' * targ.mins_x + '0 0.6 0' * targ.mins_y + '0 0 1' * (1.3 * targ.view_ofs_z - 0.3 * targ.maxs_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.6 0 0' * targ.maxs_x + '0 0.6 0' * targ.maxs_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 void GiveFrags (entity attacker, entity targ, float f)
 106 {
 107         float w;
 108
 109         // TODO route through PlayerScores instead
 110         if(gameover) return;
 111
 112         if(f < 0)
 113         {
 114                 if(targ == attacker)
 115                 {
 116                         // suicide
 117                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 118                 }
 119                 else
 120                 {
 121                         // teamkill
 122                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 123                 }
 124         }
 125         else
 126         {
 127                 // regular frag
 128                 PlayerScore_Add(attacker, SP_KILLS, 1);
 129         }
 130
 131         PlayerScore_Add(targ, SP_DEATHS, 1);
 132
 133         if(g_arena || g_ca)
 134                 if(cvar("g_arena_roundbased"))
 135                         return;
 136
 137         if(targ != attacker) // not for suicides
 138         if(g_weaponarena_random)
 139         {
 140                 // after a frag, choose another random weapon set
 141                 if(inWarmupStage)
 142                         w = warmup_start_weapons;
 143                 else
 144                         w = start_weapons;
 145
 146                 attacker.weapons = randombits(w - (w & W_WeaponBit(attacker.weapon)), g_weaponarena_random, TRUE);
 147                 if(attacker.weapons < 0)
 148                 {
 149                         // error from randombits: no weapon available
 150                         // this means we can just give ALL weapons
 151                         attacker.weapons = w;
 152                 }
 153                 if not(attacker.weapons & W_WeaponBit(attacker.weapon))
 154                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 155         }
 156
 157         // FIXME fix the mess this is (we have REAL points now!)
 158         entity oldself;
 159         oldself = self;
 160         self = attacker;
 161         frag_attacker = attacker;
 162         frag_target = targ;
 163         frag_score = f;
 164         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 165         {
 166                 f = frag_score;
 167                 self = oldself;
 168         }
 169         else
 170         {
 171                 self = oldself;
 172                 if(g_runematch)
 173                 {
 174                         f = RunematchHandleFrags(attacker, targ, f);
 175                 }
 176                 else if(g_lms)
 177                 {
 178                         // remove a life
 179                         float tl;
 180                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 181                         if(tl < lms_lowest_lives)
 182                                 lms_lowest_lives = tl;
 183                         if(tl <= 0)
 184                         {
 185                                 if(!lms_next_place)
 186                                         lms_next_place = player_count;
 187                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 188                                 --lms_next_place;
 189                         }
 190                         f = 0;
 191                 }
 192                 else if(g_ctf)
 193                 {
 194                         if(g_ctf_ignore_frags)
 195                                 f = 0;
 196                 }
 197         }
 198
 199         attacker.totalfrags += f;
 200
 201         if(f)
 202                 UpdateFrags(attacker, f);
 203 }
 204
 205 string AppendItemcodes(string s, entity player)
 206 {
 207         float w;
 208         w = player.weapon;
 209         //if(w == 0)
 210         //      w = player.switchweapon;
 211         if(w == 0)
 212                 w = player.cnt; // previous weapon!
 213         s = strcat(s, ftos(w));
 214         if(time < player.strength_finished)
 215                 s = strcat(s, "S");
 216         if(time < player.invincible_finished)
 217                 s = strcat(s, "I");
 218         if(player.flagcarried != world)
 219                 s = strcat(s, "F");
 220         if(player.BUTTON_CHAT)
 221                 s = strcat(s, "T");
 222         if(player.kh_next)
 223                 s = strcat(s, "K");
 224         if(player.runes)
 225                 s = strcat(s, "|", ftos(player.runes));
 226         return s;
 227 }
 228
 229 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 230 {
 231         string s;
 232         if(!cvar("sv_eventlog"))
 233                 return;
 234         s = strcat(":kill:", mode);
 235         s = strcat(s, ":", ftos(killer.playerid));
 236         s = strcat(s, ":", ftos(killed.playerid));
 237         s = strcat(s, ":type=", ftos(deathtype));
 238         s = strcat(s, ":items=");
 239         s = AppendItemcodes(s, killer);
 240         if(killed != killer)
 241         {
 242                 s = strcat(s, ":victimitems=");
 243                 s = AppendItemcodes(s, killed);
 244         }
 245         GameLogEcho(s);
 246 }
 247
 248 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 249 {
 250         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 251         WriteByte(MSG_ALL, TE_CSQC_NOTIFY);
 252         WriteByte(MSG_ALL, CSQC_KILLNOTIFY);
 253         WriteString(MSG_ALL, s1);
 254         WriteString(MSG_ALL, s2);
 255         WriteString(MSG_ALL, s3);
 256         WriteShort(MSG_ALL, msg);
 257         WriteByte(MSG_ALL, type);
 258 }
 259
 260 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 261 void Send_CSQC_Centerprint(entity e, string s1, string s2, float msg, float type)
 262 {
 263         if (clienttype(e) == CLIENTTYPE_REAL)
 264         {
 265                 msg_entity = e;
 266                 WRITESPECTATABLE_MSG_ONE({
 267                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 268                         WriteByte(MSG_ONE, TE_CSQC_NOTIFY);
 269                         WriteByte(MSG_ONE, CSQC_CENTERPRINT);
 270                         WriteString(MSG_ONE, s1);
 271                         WriteString(MSG_ONE, s2);
 272                         WriteShort(MSG_ONE, msg);
 273                         WriteByte(MSG_ONE, type);
 274                 });
 275         }
 276 }
 277
 278 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 279 {
 280         string  s, a, msg;
 281         float p, w, type;
 282
 283         if (targ.classname == "player" || targ.classname == "corpse")
 284         {
 285                 if (targ.classname == "corpse")
 286                         s = "A corpse";
 287                 else
 288                         s = targ.netname;
 289
 290                 a = attacker.netname;
 291
 292                 if (targ == attacker) // suicides
 293                 {
 294                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 295                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 296                         Send_CSQC_Centerprint(targ, msg, "", deathtype, MSG_SUICIDE);
 297
 298                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 299                         {
 300                                 LogDeath("suicide", deathtype, targ, targ);
 301                                 GiveFrags(attacker, targ, -1);
 302                         }
 303
 304                         if (targ.killcount > 2)
 305                                 msg = ftos(targ.killcount);
 306                         if(teams_matter && deathtype == DEATH_MIRRORDAMAGE)
 307                         {
 308                                 if(attacker.team == COLOR_TEAM1)
 309                                         deathtype = KILL_TEAM_RED;
 310                                 else
 311                                         deathtype = KILL_TEAM_BLUE;
 312                         }
 313
 314                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 315                 }
 316                 else if (attacker.classname == "player" || attacker.classname == "gib")
 317                 {
 318                         if(teams_matter && attacker.team == targ.team)
 319                         {
 320                                 if(attacker.team == COLOR_TEAM1)
 321                                         type = KILL_TEAM_RED;
 322                                 else
 323                                         type = KILL_TEAM_BLUE;
 324
 325                                 GiveFrags(attacker, targ, -1);
 326
 327                                 Send_CSQC_Centerprint(attacker, s, "", type, MSG_KILL);
 328
 329                                 if (targ.killcount > 2) {
 330                                         msg = ftos(targ.killcount);
 331                                 }
 332
 333                                 if (attacker.killcount > 2) {
 334                                         msg = ftos(attacker.killcount);
 335                                         type = KILL_TEAM_SPREE;
 336                                 }
 337                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 338
 339                                 attacker.killcount = 0;
 340
 341                                 LogDeath("tk", deathtype, attacker, targ);
 342                         }
 343                         else
 344                         {
 345                                 string blood_message, victim_message;
 346                                 if (!checkrules_firstblood)
 347                                 {
 348                                         checkrules_firstblood = TRUE;
 349                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 350                                         // TODO: make these print a newline if they dont
 351                                         Send_CSQC_Centerprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 352                                         Send_CSQC_Centerprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 353                                 }
 354
 355                                 if((cvar("sv_fragmessage_information_typefrag")) && (targ.BUTTON_CHAT)) {
 356                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_TYPEFRAG, MSG_KILL);
 357                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 358                                 } else {
 359                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_FRAG, MSG_KILL);
 360                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_FRAGGED, MSG_KILL);
 361                                 }
 362
 363                                 attacker.taunt_soundtime = time + 1;
 364
 365                                 // TODO: fix this?
 366                                 if (deathtype == DEATH_CUSTOM)
 367                                         msg = deathmessage;
 368                                 else
 369                                         msg = inflictor.message2;
 370
 371                                 if(strstrofs(msg, "%", 0) < 0)
 372                                         msg = strcat("%s ", msg, " by %s");
 373
 374                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 375
 376                                 if(g_ctf && targ.flagcarried)
 377                                 {
 378                                         UpdateFrags(attacker, ctf_score_value("score_kill"));
 379                                         PlayerScore_Add(attacker, SP_CTF_FCKILLS, 1);
 380                                         GiveFrags(attacker, targ, 0); // for logging
 381                                 }
 382                                 else
 383                                         GiveFrags(attacker, targ, 1);
 384
 385                                 if (targ.killcount > 2) {
 386                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 387                                 }
 388
 389                                 attacker.killcount = attacker.killcount + 1;
 390
 391                                 if (attacker.killcount > 2) {
 392                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 393                                 }
 394                                 else if (attacker.killcount == 3)
 395                                 {
 396                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 397                                         AnnounceTo(attacker, "03kills");
 398                                 }
 399                                 else if (attacker.killcount == 5)
 400                                 {
 401                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 402                                         AnnounceTo(attacker, "05kills");
 403                                 }
 404                                 else if (attacker.killcount == 10)
 405                                 {
 406                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 407                                         AnnounceTo(attacker, "10kills");
 408                                 }
 409                                 else if (attacker.killcount == 15)
 410                                 {
 411                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 412                                         AnnounceTo(attacker, "15kills");
 413                                 }
 414                                 else if (attacker.killcount == 20)
 415                                 {
 416                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 417                                         AnnounceTo(attacker, "20kills");
 418                                 }
 419                                 else if (attacker.killcount == 25)
 420                                 {
 421                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 422                                         AnnounceTo(attacker, "25kills");
 423                                 }
 424                                 else if (attacker.killcount == 30)
 425                                 {
 426                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 427                                         AnnounceTo(attacker, "30kills");
 428                                 }
 429                                 LogDeath("frag", deathtype, attacker, targ);
 430                         }
 431                 }
 432                 else
 433                 {
 434                         Send_CSQC_Centerprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 435                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 436                                 msg = inflictor.message;
 437                         else if (deathtype == DEATH_CUSTOM)
 438                                 msg = deathmessage;
 439                         if(strstrofs(msg, "%", 0) < 0)
 440                                 msg = strcat("%s ", msg);
 441
 442                         GiveFrags(targ, targ, -1);
 443                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 444                                 AnnounceTo(targ, "botlike");
 445                         }
 446                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 447
 448                         if (targ.killcount > 2)
 449                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 450
 451                         LogDeath("accident", deathtype, targ, targ);
 452                 }
 453
 454                 targ.death_origin = targ.origin;
 455                 if(targ != attacker)
 456                         targ.killer_origin = attacker.origin;
 457
 458                 // FIXME: this should go in PutClientInServer
 459                 if (targ.killcount)
 460                         targ.killcount = 0;
 461         }
 462 }
 463
 464 // these are updated by each Damage call for use in button triggering and such
 465 entity damage_targ;
 466 entity damage_inflictor;
 467 entity damage_attacker;
 468 .float prevhitsound;
 469
 470 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 471 {
 472         float mirrordamage;
 473         float mirrorforce;
 474         float teamdamage0;
 475         entity attacker_save;
 476         mirrordamage = 0;
 477         mirrorforce = 0;
 478
 479         if (gameover || targ.killcount == -666)
 480                 return;
 481
 482         local entity oldself;
 483         oldself = self;
 484         self = targ;
 485         damage_targ = targ;
 486         damage_inflictor = inflictor;
 487         damage_attacker = attacker;
 488                 attacker_save = attacker;
 489
 490         if(targ.classname == "player")
 491                 if(targ.hook)
 492                         if(targ.hook.aiment)
 493                                 if(targ.hook.aiment == attacker)
 494                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 495
 496         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 497         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 498         {
 499                 if(targ.classname == "player")
 500                         if not(IsDifferentTeam(targ, attacker))
 501                         {
 502                                 self = oldself;
 503                                 return;
 504                         }
 505         }
 506
 507         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 508         {
 509                 // These are ALWAYS lethal
 510                 // No damage modification here
 511                 // Instead, prepare the victim for his death...
 512                 targ.armorvalue = 0;
 513                 targ.spawnshieldtime = 0;
 514                 targ.health = 0.9; // this is < 1
 515                 targ.flags -= targ.flags & FL_GODMODE;
 516                 damage = 100000;
 517         }
 518         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 519         {
 520                 // no processing
 521         }
 522         else
 523         {
 524                 if (targ.classname == "player")
 525                 if (attacker.classname == "player")
 526                 if (!targ.isbot)
 527                 if (attacker.isbot)
 528                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 529
 530                 // nullify damage if teamplay is on
 531                 if(deathtype != DEATH_TELEFRAG)
 532                 if(attacker.classname == "player")
 533                 {
 534                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 535                         {
 536                                 damage = 0;
 537                                 force = '0 0 0';
 538                         }
 539                         else if(attacker.team == targ.team)
 540                         {
 541                                 if(teamplay == 1)
 542                                         damage = 0;
 543                                 else if(attacker != targ)
 544                                 {
 545                                         if(teamplay == 3)
 546                                                 damage = 0;
 547                                         else if(teamplay == 4)
 548                                         {
 549                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 550                                                 {
 551                                                         teamdamage0 = max(attacker.dmg_team, cvar("g_teamdamage_threshold"));
 552                                                         attacker.dmg_team = attacker.dmg_team + damage;
 553                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 554                                                                 mirrordamage = cvar("g_mirrordamage") * (attacker.dmg_team - teamdamage0);
 555                                                         mirrorforce = cvar("g_mirrordamage") * vlen(force);
 556                                                         if(g_minstagib)
 557                                                         {
 558                                                                 if(cvar("g_friendlyfire") == 0)
 559                                                                         damage = 0;
 560                                                         }
 561                                                         else if(g_ca)
 562                                                                 damage = 0;
 563                                                         else
 564                                                                 damage = cvar("g_friendlyfire") * damage;
 565                                                         // mirrordamage will be used LATER
 566                                                 }
 567                                                 else
 568                                                         damage = 0;
 569                                         }
 570                                 }
 571                         }
 572                 }
 573
 574                 if(targ.classname == "player")
 575                 if(attacker.classname == "player")
 576                 if(attacker != targ)
 577                 {
 578                         targ.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 579                         attacker.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 580                 }
 581
 582                 if(targ.classname == "player")
 583                 if (g_minstagib)
 584                 {
 585                         if ((deathtype == DEATH_FALL)  ||
 586                                 (deathtype == DEATH_DROWN) ||
 587                                 (deathtype == DEATH_SLIME) ||
 588                                 (deathtype == DEATH_LAVA)  ||
 589                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 590                         {
 591                                 self = oldself;
 592                                 return;
 593                         }
 594                         if(damage > 0)
 595                             damage = 10000;
 596                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 597                         {
 598                                 targ.armorvalue -= 1;
 599                                 centerprint(targ, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(targ.armorvalue)));
 600                                 damage = 0;
 601                                 targ.hitsound += 1;
 602                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 603                         }
 604                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 605                         {
 606                                 damage = 0;
 607                                 if (targ != attacker)
 608                                 {
 609                                         if ((targ.health >= 1) && (targ.classname == "player"))
 610                                                 centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "Secondary fire inflicts no damage!"));
 611                                         damage = 0;
 612                                         mirrordamage = 0;
 613                                         force = '0 0 0';
 614                                         // keep mirrorforce
 615                                         attacker = targ;
 616                                 }
 617                         }
 618                 }
 619
 620                 if not(DEATH_ISSPECIAL(deathtype))
 621                 {
 622                         damage *= g_weapondamagefactor;
 623                         mirrordamage *= g_weapondamagefactor;
 624                         force = force * g_weaponforcefactor;
 625                         mirrorforce *= g_weaponforcefactor;
 626                 }
 627
 628                 // apply strength multiplier
 629                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 630                 {
 631                         if(targ == attacker)
 632                         {
 633                                 damage = damage * cvar("g_balance_powerup_strength_selfdamage");
 634                                 force = force * cvar("g_balance_powerup_strength_selfforce");
 635                         }
 636                         else
 637                         {
 638                                 damage = damage * cvar("g_balance_powerup_strength_damage");
 639                                 force = force * cvar("g_balance_powerup_strength_force");
 640                         }
 641                 }
 642
 643                 // apply invincibility multiplier
 644                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 645                         damage = damage * cvar("g_balance_powerup_invincible_takedamage");
 646
 647                 if (targ == attacker)
 648                 {
 649                         if(g_ca || (g_cts && !cvar("g_cts_selfdamage")))
 650                                 damage = 0;
 651                         else
 652                                 damage = damage * cvar("g_balance_selfdamagepercent");  // Partial damage if the attacker hits himself
 653                 }
 654
 655                 // CTF: reduce damage/force
 656                 if(g_ctf)
 657                 if(targ == attacker)
 658                 if(targ.flagcarried)
 659                 {
 660                         damage = damage * cvar("g_ctf_flagcarrier_selfdamage");
 661                         force = force * cvar("g_ctf_flagcarrier_selfforce");
 662                 }
 663
 664                 if(g_runematch)
 665                 {
 666                         // apply strength rune
 667                         if (attacker.runes & RUNE_STRENGTH)
 668                         {
 669                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 670                                 {
 671                                         damage = damage * cvar("g_balance_rune_strength_combo_damage");
 672                                         force = force * cvar("g_balance_rune_strength_combo_force");
 673                                 }
 674                                 else
 675                                 {
 676                                         damage = damage * cvar("g_balance_rune_strength_damage");
 677                                         force = force * cvar("g_balance_rune_strength_force");
 678                                 }
 679                         }
 680                         else if (attacker.runes & CURSE_WEAK)
 681                         {
 682                                 damage = damage * cvar("g_balance_curse_weak_damage");
 683                                 force = force * cvar("g_balance_curse_weak_force");
 684                         }
 685
 686                         // apply defense rune
 687                         if (targ.runes & RUNE_DEFENSE)
 688                         {
 689                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 690                                         damage = damage * cvar("g_balance_rune_defense_combo_takedamage");
 691                                 else
 692                                         damage = damage * cvar("g_balance_rune_defense_takedamage");
 693                         }
 694                         else if (targ.runes & CURSE_VULNER)
 695                                 damage = damage * cvar("g_balance_curse_vulner_takedamage");
 696                 }
 697
 698                 // count the damage
 699                 if(attacker)
 700                 if(!targ.deadflag)
 701                 if(targ.takedamage == DAMAGE_AIM)
 702                 if(targ != attacker)
 703                 {
 704                         if(targ.classname == "player")
 705                         {
 706                                 // HEAD SHOT:
 707                                 // find height of hit on player axis
 708                                 // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 709                                 vector headmins, headmaxs, org;
 710                                 org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 711                                 headmins = org + GetHeadshotMins(targ);
 712                                 headmaxs = org + GetHeadshotMaxs(targ);
 713                                 if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 714                                 {
 715                                         deathtype |= HITTYPE_HEADSHOT;
 716                                 }
 717                         }
 718                         else if(targ.classname == "turret_head")
 719                         {
 720                                 deathtype |= HITTYPE_HEADSHOT;
 721                         }
 722                         if(deathtype & HITTYPE_HEADSHOT)
 723                                 damage *= 1 + damage_headshotbonus;
 724
 725                         if(targ.classname == "player")
 726                         {
 727                                 if(IsDifferentTeam(targ, attacker))
 728                                 {
 729                                         if(damage > 0)
 730                                         {
 731                                                 if(attacker.weapon != WEP_ELECTRO && attacker.weapon != WEP_LASER || ((attacker.weapon == WEP_ELECTRO && cvar("g_balance_electro_lightning") || attacker.weapon == WEP_LASER) && attacker.prevhitsound + cvar("sv_hitsound_antispam_time") < time))
 732                                                 {
 733                                                         if(targ.BUTTON_CHAT)
 734                                                                 attacker.typehitsound += 1;
 735                                                         else
 736                                                                 attacker.hitsound += 1;
 737                                                         attacker.prevhitsound = time;
 738                                                 }
 739
 740                                                 damage_goodhits += 1;
 741                                                 damage_gooddamage += damage;
 742
 743                                                 if not(DEATH_ISSPECIAL(deathtype))
 744                                                 {
 745                                                         if(!g_minstagib)
 746                                                         if(IsFlying(targ))
 747                                                                 yoda = 1;
 748
 749                                                         if(g_minstagib)
 750                                                         if(targ.items & IT_STRENGTH)
 751                                                                 yoda = 1;
 752
 753                                                         if(deathtype & HITTYPE_HEADSHOT)
 754                                                                 headshot = 1;
 755                                                 }
 756                                                 if(g_ca)
 757                                                         PlayerScore_Add(attacker, SP_SCORE, damage * cvar("g_ca_damage2score_multiplier"));
 758                                         }
 759                                 }
 760                                 else
 761                                 {
 762                                         if(deathtype != DEATH_FIRE)
 763                                                 attacker.typehitsound += 1;
 764                                         if(mirrordamage > 0)
 765                                                 if(time > attacker.teamkill_complain)
 766                                                 {
 767                                                         attacker.teamkill_complain = time + 5;
 768                                                         attacker.teamkill_soundtime = time + 0.4;
 769                                                         attacker.teamkill_soundsource = targ;
 770                                                 }
 771                                 }
 772                         }
 773                 }
 774         }
 775
 776         // apply push
 777         if (self.damageforcescale)
 778         if (vlen(force))
 779         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 780         {
 781                 self.velocity = self.velocity + self.damageforcescale * force;
 782                 self.flags &~= FL_ONGROUND;
 783                 UpdateCSQCProjectile(self);
 784         }
 785         // apply damage
 786         if (damage != 0 || (self.damageforcescale && vlen(force)))
 787         if (self.event_damage)
 788                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 789         self = oldself;
 790
 791         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 792         {
 793                 // Savage: vampire mode
 794                 if (g_vampire)
 795                 if (!g_minstagib)
 796                 if (time >= self.spawnshieldtime)
 797                 {
 798                         attacker.health += damage;
 799                 }
 800                 if(g_runematch)
 801                 {
 802                         if (attacker.runes & RUNE_VAMPIRE)
 803                         {
 804                         // apply vampire rune
 805                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 806                                 {
 807                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb");
 808                                         attacker.health = bound(
 809                                                 cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 40
 810                                                 attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb"),
 811                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 812                                 }
 813                                 else
 814                                 {
 815                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_absorb");
 816                                         attacker.health = bound(
 817                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 818                                                                                         // empathy won't let you gain health in the same way...
 819                                                 attacker.health + damage * cvar("g_balance_rune_vampire_absorb"),
 820                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 821                                         }
 822                         }
 823                         // apply empathy curse
 824                         else if (attacker.runes & CURSE_EMPATHY)
 825                         {
 826                                 attacker.health = bound(
 827                                         cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 20
 828                                         attacker.health + damage * cvar("g_balance_curse_empathy_takedamage"),
 829                                         attacker.health);
 830                         }
 831                 }
 832         }
 833
 834         // apply mirror damage if any
 835         if(mirrordamage > 0 || mirrorforce > 0)
 836         {
 837                 attacker = attacker_save;
 838                 if(g_minstagib)
 839                         if(mirrordamage > 0)
 840                         {
 841                                 // just lose extra LIVES, don't kill the player for mirror damage
 842                                 if(attacker.armorvalue > 0)
 843                                 {
 844                                         attacker.armorvalue = attacker.armorvalue - 1;
 845                                         centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 846                                         attacker.hitsound += 1;
 847                                 }
 848                                 mirrordamage = 0;
 849                         }
 850                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 851                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 852         }
 853 }
 854
 855 void Damage_RecordDamage(entity attacker, float deathtype, float damage)
 856 {
 857         float weaponid;
 858         weaponid = DEATH_WEAPONOF(deathtype);
 859
 860         if not(inWarmupStage)
 861         if (weaponid)
 862         if ((clienttype(attacker) == CLIENTTYPE_REAL) | (clienttype(attacker) == CLIENTTYPE_BOT)) {
 863                 attacker.stats_hit[weaponid - 1] += damage;
 864                 attacker.stat_hit = weaponid + 64 * floor(attacker.stats_hit[weaponid - 1]);
 865         }
 866 }
 867
 868 float RadiusDamage_running;
 869 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 870 // Returns total damage applies to creatures
 871 {
 872         entity  targ;
 873         float   finaldmg;
 874         float   power;
 875         vector  blastorigin;
 876         vector  force;
 877         vector  diff;
 878         vector  center;
 879         vector  nearest;
 880         float   total_damage_to_creatures;
 881         entity  next;
 882         float   tfloordmg;
 883         float   tfloorforce;
 884
 885         float stat_damagedone;
 886         float stat_maxdamage;
 887
 888         if(RadiusDamage_running)
 889         {
 890                 string save;
 891                 print("RadiusDamage called recursively!\n");
 892                 print("Expect stuff to go HORRIBLY wrong.\n");
 893                 print("Causing a stack trace...\n");
 894                 save = cvar_string("prvm_backtraceforwarnings");
 895                 cvar_set("prvm_backtraceforwarnings", "1");
 896                 fclose(-1); // calls VM_Warning
 897                 cvar_set("prvm_backtraceforwarnings", save);
 898                 return 0;
 899         }
 900
 901         RadiusDamage_running = 1;
 902
 903         tfloordmg = cvar("g_throughfloor_damage");
 904         tfloorforce = cvar("g_throughfloor_force");
 905
 906         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 907         total_damage_to_creatures = 0;
 908
 909         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 910         if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 911         {
 912                 force = inflictor.velocity;
 913                 if(vlen(force) == 0)
 914                         force = '0 0 -1';
 915                 else
 916                         force = normalize(force);
 917                 if(forceintensity >= 0)
 918                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, attacker);
 919                 else
 920                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, attacker);
 921         }
 922
 923         stat_damagedone = 0;
 924         stat_maxdamage = 0;
 925
 926         targ = WarpZone_FindRadius (blastorigin, rad, FALSE);
 927         while (targ)
 928         {
 929                 next = targ.chain;
 930                 if (targ != inflictor)
 931                         if (ignore != targ) if(targ.takedamage)
 932                         {
 933                                 // LordHavoc: measure distance to nearest point on target (not origin)
 934                                 // (this guarentees 100% damage on a touch impact)
 935                                 nearest = targ.WarpZone_findradius_nearest;
 936                                 diff = targ.WarpZone_findradius_dist;
 937                                 // round up a little on the damage to ensure full damage on impacts
 938                                 // and turn the distance into a fraction of the radius
 939                                 power = 1 - ((vlen (diff) - 2) / rad);
 940                                 //bprint(" ");
 941                                 //bprint(ftos(power));
 942                                 //if (targ == attacker)
 943                                 //      print(ftos(power), "\n");
 944                                 if (power > 0)
 945                                 {
 946                                         if (power > 1)
 947                                                 power = 1;
 948                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 949                                         if (finaldmg > 0)
 950                                         {
 951                                                 local float a;
 952                                                 local float c;
 953                                                 local float hits;
 954                                                 local float total;
 955                                                 local float hitratio;
 956                                                 local vector hitloc;
 957                                                 local vector myblastorigin;
 958                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 959                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
 960                                                 // if it's a player, use the view origin as reference
 961                                                 if (targ.classname == "player")
 962                                                         center = targ.origin + targ.view_ofs;
 963                                                 force = normalize(center - myblastorigin);
 964                                                 force = force * (finaldmg / coredamage) * forceintensity;
 965                                                 // test line of sight to multiple positions on box,
 966                                                 // and do damage if any of them hit
 967                                                 hits = 0;
 968                                                 if (targ.classname == "player")
 969                                                         total = ceil(bound(1, finaldmg, 50));
 970                                                 else
 971                                                         total = ceil(bound(1, finaldmg/10, 5));
 972                                                 hitloc = nearest;
 973                                                 c = 0;
 974                                                 while (c < total)
 975                                                 {
 976                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 977                                                         WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 978                                                         if (trace_fraction == 1 || trace_ent == targ)
 979                                                         {
 980                                                                 hits = hits + 1;
 981                                                                 if (hits > 1)
 982                                                                         hitloc = hitloc + nearest;
 983                                                                 else
 984                                                                         hitloc = nearest;
 985                                                         }
 986                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 987                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 988                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 989                                                         c = c + 1;
 990                                                 }
 991                                                 nearest = hitloc * (1 / max(1, hits));
 992                                                 hitratio = (hits / total);
 993                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 994                                                 finaldmg = finaldmg * a;
 995                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
 996                                                 force = force * a;
 997                                                 //if (targ == attacker)
 998                                                 //{
 999                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1000                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1001                                                 //      print(" (", ftos(a), ")\n");
1002                                                 //}
1003                                                 if(hits || tfloordmg || tfloorforce)
1004                                                 {
1005                                                         if(targ.iscreature)
1006                                                         {
1007                                                                 total_damage_to_creatures += finaldmg;
1008
1009                                                                 if(targ.flags & FL_CLIENT)
1010                                                                 if(targ.deadflag == DEAD_NO)
1011                                                                 if(targ != attacker)
1012                                                                 if(!teamplay || targ.team != attacker.team)
1013                                                                 {
1014                                                                         stat_damagedone += finaldmg;
1015                                                                         stat_maxdamage += coredamage;
1016                                                                 }
1017                                                         }
1018
1019                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1020                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1021                                                         else
1022                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1023                                                 }
1024                                         }
1025                                 }
1026                         }
1027                 targ = next;
1028         }
1029
1030         RadiusDamage_running = 0;
1031
1032         Damage_RecordDamage(attacker, deathtype, min(stat_maxdamage, stat_damagedone));
1033
1034         return total_damage_to_creatures;
1035 }
1036
1037 .float fire_damagepersec;
1038 .float fire_endtime;
1039 .float fire_deathtype;
1040 .entity fire_owner;
1041 .float fire_hitsound;
1042 .entity fire_burner;
1043
1044 void fireburner_think();
1045
1046 float Fire_IsBurning(entity e)
1047 {
1048         return (time < e.fire_endtime);
1049 }
1050
1051 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1052 {
1053         float dps;
1054         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1055
1056         if(e.classname == "player")
1057         {
1058                 if(e.deadflag)
1059                         return -1;
1060         }
1061         else
1062         {
1063                 if(!e.fire_burner)
1064                 {
1065                         // print("adding a fire burner to ", e.classname, "\n");
1066                         e.fire_burner = spawn();
1067                         e.fire_burner.classname = "fireburner";
1068                         e.fire_burner.think = fireburner_think;
1069                         e.fire_burner.nextthink = time;
1070                         e.fire_burner.owner = e;
1071                 }
1072         }
1073
1074         t = max(t, 0.1);
1075         dps = d / t;
1076         if(Fire_IsBurning(e))
1077         {
1078                 mintime = e.fire_endtime - time;
1079                 maxtime = max(mintime, t);
1080
1081                 mindps = e.fire_damagepersec;
1082                 maxdps = max(mindps, dps);
1083
1084                 if(maxtime > mintime || maxdps > mindps)
1085                 {
1086                         mindamage = mindps * mintime;
1087                         maxdamage = mindamage + d;
1088
1089                         // interval [mintime, maxtime] * [mindps, maxdps]
1090                         // intersected with
1091                         // [mindamage, maxdamage]
1092                         // maximum of this!
1093
1094                         if(maxdamage >= maxtime * maxdps)
1095                         {
1096                                 totaltime = maxtime;
1097                                 totaldamage = maxtime * maxdps;
1098
1099                                 // this branch increases totaldamage if either t > mintime, or dps > mindps
1100                         }
1101                         else
1102                         {
1103                                 // maxdamage is inside the interval!
1104                                 // first, try to use mindps; only if this fails, increase dps as needed
1105                                 totaltime = min(maxdamage / mindps, maxtime); // maxdamage / mindps >= mindamage / mindps = mintime
1106                                 totaldamage = maxdamage;
1107                                 // can totaldamage / totaltime be >= maxdps?
1108                                 // max(mindps, maxdamage / maxtime) >= maxdps?
1109                                 // we know maxdamage < maxtime * maxdps
1110                                 // so it cannot be
1111
1112                                 // this branch ALWAYS increases totaldamage, but requires maxdamage < maxtime * maxdps
1113                         }
1114
1115                         // total conditions for increasing:
1116                         //     maxtime > mintime OR maxdps > mindps OR maxtime * maxdps > maxdamage
1117                         // however:
1118                         //     if maxtime = mintime, maxdps = mindps
1119                         // then:
1120                         //     maxdamage = mindamage + d
1121                         //     mindamage = mindps * mintime = maxdps * maxtime < maxdamage!
1122                         // so the last condition is not needed
1123
1124                         e.fire_damagepersec = totaldamage / totaltime;
1125                         e.fire_endtime = time + totaltime;
1126                         if(totaldamage > 1.2 * mindamage)
1127                         {
1128                                 e.fire_deathtype = dt;
1129                                 if(e.fire_owner != o)
1130                                 {
1131                                         e.fire_owner = o;
1132                                         e.fire_hitsound = FALSE;
1133                                 }
1134                         }
1135                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1136                 }
1137                 else
1138                         return 0;
1139         }
1140         else
1141         {
1142                 e.fire_damagepersec = dps;
1143                 e.fire_endtime = time + t;
1144                 e.fire_deathtype = dt;
1145                 e.fire_owner = o;
1146                 e.fire_hitsound = FALSE;
1147                 return d;
1148         }
1149 }
1150
1151 void Fire_ApplyDamage(entity e)
1152 {
1153         float t, d, hi, ty;
1154         entity o;
1155
1156         if not(Fire_IsBurning(e))
1157                 return;
1158
1159         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1160         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1161                 o = e.fire_owner;
1162
1163         // water and slime stop fire
1164         if(e.waterlevel)
1165         if(e.watertype != CONTENT_LAVA)
1166                 e.fire_endtime = 0;
1167
1168         t = min(frametime, e.fire_endtime - time);
1169         d = e.fire_damagepersec * t;
1170
1171         hi = e.fire_owner.hitsound;
1172         ty = e.fire_owner.typehitsound;
1173         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1174         if(e.fire_hitsound && e.fire_owner)
1175         {
1176                 e.fire_owner.hitsound = hi;
1177                 e.fire_owner.typehitsound = ty;
1178         }
1179         e.fire_hitsound = TRUE;
1180
1181         Damage_RecordDamage(e.fire_owner, e.fire_deathtype, d);
1182
1183         if not(IS_INDEPENDENT_PLAYER(e))
1184         FOR_EACH_PLAYER(other) if(e != other)
1185         {
1186                 if(other.classname == "player")
1187                 if(other.deadflag == DEAD_NO)
1188                 if not(IS_INDEPENDENT_PLAYER(other))
1189                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1190                 {
1191                         t = cvar("g_balance_firetransfer_time") * (e.fire_endtime - time);
1192                         d = cvar("g_balance_firetransfer_damage") * e.fire_damagepersec * t;
1193                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1194                 }
1195         }
1196 }
1197
1198 void Fire_ApplyEffect(entity e)
1199 {
1200         if(Fire_IsBurning(e))
1201                 e.effects |= EF_FLAME;
1202         else
1203                 e.effects &~= EF_FLAME;
1204 }
1205
1206 void fireburner_think()
1207 {
1208         // for players, this is done in the regular loop
1209         if(wasfreed(self.owner))
1210         {
1211                 remove(self);
1212                 return;
1213         }
1214         Fire_ApplyEffect(self.owner);
1215         if(!Fire_IsBurning(self.owner))
1216         {
1217                 self.owner.fire_burner = world;
1218                 remove(self);
1219                 return;
1220         }
1221         Fire_ApplyDamage(self.owner);
1222         self.nextthink = time;
1223 }