Merge remote-tracking branch 'origin/Mario/extralife_fix'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / g_damage.qc
1 .float dmg;
2 .float dmg_edge;
3 .float dmg_force;
4 .float dmg_radius;
5
6 float Damage_DamageInfo_SendEntity(entity to, float sf)
7 {
8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
16         WriteShort(MSG_ENTITY, self.oldorigin_x);
17         WriteByte(MSG_ENTITY, self.species);
18         return TRUE;
19 }
20
21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
22 {
23         // TODO maybe call this from non-edgedamage too?
24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
25
26         entity e;
27
28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
29                 deathtype |= 0x8000;
30
31         e = spawn();
32         setorigin(e, org);
33         e.projectiledeathtype = deathtype;
34         e.dmg = coredamage;
35         e.dmg_edge = edgedamage;
36         e.dmg_radius = rad;
37         e.dmg_force = vlen(force);
38         e.velocity = force;
39         e.oldorigin_x = compressShortVector(e.velocity);
40         e.species = bloodtype;
41
42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
43 }
44
45 float checkrules_firstblood;
46
47 float yoda;
48 float damage_goodhits;
49 float damage_gooddamage;
50
51 .float dmg_team;
52 .float teamkill_complain;
53 .float teamkill_soundtime;
54 .entity teamkill_soundsource;
55 .entity pusher;
56 .float istypefrag;
57 .float taunt_soundtime;
58
59
60 float IsDifferentTeam(entity a, entity b)
61 {
62         if(teamplay)
63         {
64                 if(a.team == b.team)
65                         return 0;
66         }
67         else
68         {
69                 if(a == b)
70                         return 0;
71         }
72         return 1;
73 }
74
75 float IsFlying(entity a)
76 {
77         if(a.flags & FL_ONGROUND)
78                 return 0;
79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
80                 return 0;
81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
82         if(trace_fraction < 1)
83                 return 0;
84         return 1;
85 }
86
87 void UpdateFrags(entity player, float f)
88 {
89         PlayerTeamScore_AddScore(player, f);
90 }
91
92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
93 void W_SwitchWeapon_Force(entity e, float w);
94 entity GiveFrags_randomweapons;
95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
96 {
97         // TODO route through PlayerScores instead
98         if(gameover) return;
99
100         if(f < 0)
101         {
102                 if(targ == attacker)
103                 {
104                         // suicide
105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
106                 }
107                 else
108                 {
109                         // teamkill
110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
111                 }
112         }
113         else
114         {
115                 // regular frag
116                 PlayerScore_Add(attacker, SP_KILLS, 1);
117                 if(targ.playerid)
118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
119         }
120
121         PlayerScore_Add(targ, SP_DEATHS, 1);
122
123         if(targ != attacker) // not for suicides
124         if(g_weaponarena_random)
125         {
126                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
127                 float culprit;
128                 culprit = DEATH_WEAPONOF(deathtype);
129                 if(!culprit)
130                         culprit = attacker.weapon;
131                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
132                         culprit = attacker.weapon;
133
134                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
135                 {
136                         // no exchange
137                 }
138                 else
139                 {
140                         if(!GiveFrags_randomweapons)
141                         {
142                                 GiveFrags_randomweapons = spawn();
143                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
144                         }
145
146                         if(inWarmupStage)
147                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
148                         else
149                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
150
151                         // all others (including the culprit): remove
152                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
153                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
154
155                         // among the remaining ones, choose one by random
156                         W_RandomWeapons(GiveFrags_randomweapons, 1);
157
158                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
159                         {
160                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
161                                 WEPSET_ANDNOT_EW(attacker, culprit);
162                         }
163                 }
164
165                 // after a frag, choose another random weapon set
166                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
167                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
168         }
169
170         // FIXME fix the mess this is (we have REAL points now!)
171         entity oldself;
172         oldself = self;
173         self = attacker;
174         frag_attacker = attacker;
175         frag_target = targ;
176         frag_score = f;
177         if(MUTATOR_CALLHOOK(GiveFragsForKill))
178         {
179                 f = frag_score;
180                 self = oldself;
181         }
182         else
183         {
184                 self = oldself;
185         }
186
187         attacker.totalfrags += f;
188
189         if(f)
190                 UpdateFrags(attacker, f);
191 }
192
193 string AppendItemcodes(string s, entity player)
194 {
195         float w;
196         w = player.weapon;
197         //if(w == 0)
198         //      w = player.switchweapon;
199         if(w == 0)
200                 w = player.cnt; // previous weapon!
201         s = strcat(s, ftos(w));
202         if(time < player.strength_finished)
203                 s = strcat(s, "S");
204         if(time < player.invincible_finished)
205                 s = strcat(s, "I");
206         if(player.flagcarried != world)
207                 s = strcat(s, "F");
208         if(player.BUTTON_CHAT)
209                 s = strcat(s, "T");
210         if(player.kh_next)
211                 s = strcat(s, "K");
212         return s;
213 }
214
215 void LogDeath(string mode, float deathtype, entity killer, entity killed)
216 {
217         string s;
218         if(!autocvar_sv_eventlog)
219                 return;
220         s = strcat(":kill:", mode);
221         s = strcat(s, ":", ftos(killer.playerid));
222         s = strcat(s, ":", ftos(killed.playerid));
223         s = strcat(s, ":type=", Deathtype_Name(deathtype));
224         s = strcat(s, ":items=");
225         s = AppendItemcodes(s, killer);
226         if(killed != killer)
227         {
228                 s = strcat(s, ":victimitems=");
229                 s = AppendItemcodes(s, killed);
230         }
231         GameLogEcho(s);
232 }
233
234 void Obituary_SpecialDeath(
235         entity notif_target,
236         float murder,
237         float deathtype,
238         string s1, string s2, string s3,
239         float f1, float f2, float f3)
240 {
241         if(DEATH_ISSPECIAL(deathtype))
242         {
243                 entity deathent = deathtypes[(deathtype - DT_FIRST)];
244                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
245
246                 if(murder)
247                 {
248                         if(deathent.death_msgmurder)
249                         {
250                                 Send_Notification_WOVA(
251                                         NOTIF_ONE,
252                                         notif_target,
253                                         MSG_MULTI,
254                                         deathent.death_msgmurder.nent_id,
255                                         s1, s2, s3, "",
256                                         f1, f2, f3, 0
257                                 );
258                                 Send_Notification_WOVA(
259                                         NOTIF_ALL_EXCEPT,
260                                         notif_target,
261                                         MSG_INFO,
262                                         deathent.death_msgmurder.nent_msginfo.nent_id,
263                                         s1, s2, s3, "",
264                                         f1, f2, f3, 0
265                                 );
266                         }
267                 }
268                 else
269                 {
270                         if(deathent.death_msgself)
271                         {
272                                 Send_Notification_WOVA(
273                                         NOTIF_ONE,
274                                         notif_target,
275                                         MSG_MULTI,
276                                         deathent.death_msgself.nent_id,
277                                         s1, s2, s3, "",
278                                         f1, f2, f3, 0
279                                 );
280                                 Send_Notification_WOVA(
281                                         NOTIF_ALL_EXCEPT,
282                                         notif_target,
283                                         MSG_INFO,
284                                         deathent.death_msgself.nent_msginfo.nent_id,
285                                         s1, s2, s3, "",
286                                         f1, f2, f3, 0
287                                 );
288                         }
289                 }
290         }
291         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
292 }
293
294 float w_deathtype;
295 float Obituary_WeaponDeath(
296         entity notif_target,
297         float murder,
298         float deathtype,
299         string s1, string s2, string s3,
300         float f1, float f2)
301 {
302         float death_weapon = DEATH_WEAPONOF(deathtype);
303         if(death_weapon)
304         {
305                 w_deathtype = deathtype;
306                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
307                 w_deathtype = FALSE;
308
309                 if(death_message)
310                 {
311                         Send_Notification_WOVA(
312                                 NOTIF_ONE,
313                                 notif_target,
314                                 MSG_MULTI,
315                                 death_message,
316                                 s1, s2, s3, "",
317                                 f1, f2, 0, 0
318                         );
319                         Send_Notification_WOVA(
320                                 NOTIF_ALL_EXCEPT,
321                                 notif_target,
322                                 MSG_INFO,
323                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
324                                 s1, s2, s3, "",
325                                 f1, f2, 0, 0
326                         );
327                 }
328                 else
329                 {
330                         dprint(sprintf(
331                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
332                                 deathtype,
333                                 death_weapon
334                         ));
335                 }
336
337                 return TRUE;
338         }
339         return FALSE;
340 }
341
342 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
343 {
344         // Sanity check
345         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
346
347         // Declarations
348         float notif_firstblood = FALSE;
349         float kill_count_to_attacker, kill_count_to_target;
350
351         // Set final information for the death
352         targ.death_origin = targ.origin;
353         if(targ != attacker) { targ.killer_origin = attacker.origin; }
354         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
355
356         #ifdef NOTIFICATIONS_DEBUG
357         Debug_Notification(
358                 sprintf(
359                         "Obituary(%s, %s, %s, %s = %d);\n",
360                         attacker.netname,
361                         inflictor.netname,
362                         targ.netname,
363                         Deathtype_Name(deathtype),
364                         deathtype
365                 )
366         );
367         #endif
368         
369         // =======
370         // SUICIDE
371         // =======
372         if(targ == attacker)
373         {
374                 if(DEATH_ISSPECIAL(deathtype))
375                 {
376                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
377                         {
378                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
379                         }
380                         else
381                         {
382                                 switch(deathtype)
383                                 {
384                                         case DEATH_MIRRORDAMAGE:
385                                         {
386                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
387                                                 break;
388                                         }
389                                         
390                                         default:
391                                         {
392                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
393                                                 break;
394                                         }
395                                 }
396                         }
397                 }
398                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
399                 {
400                         backtrace("SUICIDE: what the hell happened here?\n");
401                         return;
402                 }
403                 LogDeath("suicide", deathtype, targ, targ);
404                 GiveFrags(attacker, targ, -1, deathtype);
405         }
406
407         // ======
408         // MURDER
409         // ======
410         else if(IS_PLAYER(attacker))
411         {
412                 if(!IsDifferentTeam(attacker, targ))
413                 {
414                         LogDeath("tk", deathtype, attacker, targ);
415                         GiveFrags(attacker, targ, -1, deathtype);
416
417                         attacker.killcount = 0;
418                         
419                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
420                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
421                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
422
423                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
424                         // No need for specific death/weapon messages...
425                 }
426                 else
427                 {
428                         LogDeath("frag", deathtype, attacker, targ);
429                         GiveFrags(attacker, targ, 1, deathtype);
430
431                         attacker.taunt_soundtime = time + 1;
432                         attacker.killcount = attacker.killcount + 1;
433
434                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
435                                 case counta: \
436                                 { \
437                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
438                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
439                                         break; \
440                                 }
441                         switch(attacker.killcount)
442                         {
443                                 KILL_SPREE_LIST
444                                 default: break;
445                         }
446                         #undef SPREE_ITEM
447
448                         if(!checkrules_firstblood)
449                         {
450                                 checkrules_firstblood = TRUE;
451                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
452                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
453                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
454
455                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
456                                 kill_count_to_attacker = -1;
457                                 kill_count_to_target = -2;
458                         }
459                         else
460                         {
461                                 kill_count_to_attacker = attacker.killcount;
462                                 kill_count_to_target = 0;
463                         }
464
465                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
466                         if(targ.istypefrag)
467                         {
468                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
469                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
470                                 else
471                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
472
473                                 if(targ.FRAG_VERBOSE && verbose_allowed)
474                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
475                                 else
476                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
477                         }
478                         else
479                         {
480                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
481                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
482                                 else
483                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
484
485                                 if(targ.FRAG_VERBOSE && verbose_allowed)
486                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
487                                 else
488                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
489                         }
490
491                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
492                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
493                 }
494         }
495
496         // =============
497         // ACCIDENT/TRAP
498         // =============
499         else
500         {
501                 switch(deathtype)
502                 {
503                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
504                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
505                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
506                         /*case DEATH_HURTTRIGGER:
507                         {
508                                 s1 = targ.netname;
509                                 s2 = inflictor.message;
510                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
511                                 break;
512                         }*/
513
514                         case DEATH_CUSTOM:
515                         {
516                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
517                                         targ.netname,
518                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
519                                         deathlocation,
520                                         targ.killcount,
521                                         0,
522                                         0);
523                                 break;
524                         }
525                         
526                         default:
527                         {
528                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
529                                 break;
530                         }
531                 }
532
533                 LogDeath("accident", deathtype, targ, targ);
534                 GiveFrags(targ, targ, -1, deathtype);
535
536                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
537                 {
538                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
539                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
540                 }
541         }
542
543         // reset target kill count
544         if(targ.killcount) { targ.killcount = 0; }
545 }
546
547 // these are updated by each Damage call for use in button triggering and such
548 entity damage_targ;
549 entity damage_inflictor;
550 entity damage_attacker;
551
552 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
553 {
554         float mirrordamage;
555         float mirrorforce;
556         float complainteamdamage = 0; 
557         entity attacker_save;
558         mirrordamage = 0;
559         mirrorforce = 0;
560
561         if (gameover || targ.killcount == -666)
562                 return;
563
564         entity oldself;
565         oldself = self;
566         self = targ;
567         damage_targ = targ;
568         damage_inflictor = inflictor;
569         damage_attacker = attacker;
570                 attacker_save = attacker;
571
572         if(IS_PLAYER(targ))
573                 if(targ.hook)
574                         if(targ.hook.aiment)
575                                 if(targ.hook.aiment == attacker)
576                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
577
578         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
579         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
580         {
581                 if(IS_PLAYER(targ))
582                         if not(IsDifferentTeam(targ, attacker))
583                         {
584                                 self = oldself;
585                                 return;
586                         }
587         }
588
589         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
590         {
591                 // These are ALWAYS lethal
592                 // No damage modification here
593                 // Instead, prepare the victim for his death...
594                 targ.armorvalue = 0;
595                 targ.spawnshieldtime = 0;
596                 targ.health = 0.9; // this is < 1
597                 targ.flags -= targ.flags & FL_GODMODE;
598                 damage = 100000;
599         }
600         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
601         {
602                 // no processing
603         }
604         else
605         {
606                 // nullify damage if teamplay is on
607                 if(deathtype != DEATH_TELEFRAG)
608                 if(IS_PLAYER(attacker))
609                 {
610                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
611                         {
612                                 damage = 0;
613                                 force = '0 0 0';
614                         }
615                         else if(!IsDifferentTeam(attacker, targ))
616                         {
617                                 if(autocvar_teamplay_mode == 1)
618                                         damage = 0;
619                                 else if(attacker != targ)
620                                 {
621                                         if(autocvar_teamplay_mode == 3)
622                                                 damage = 0;
623                                         else if(autocvar_teamplay_mode == 4)
624                                         {
625                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
626                                                 {
627                                                         attacker.dmg_team = attacker.dmg_team + damage;
628                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
629                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
630                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
631                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
632                                                         if(g_ca)
633                                                                 damage = 0;
634                                                         else
635                                                                 damage = autocvar_g_friendlyfire * damage;
636                                                         // mirrordamage will be used LATER
637
638                                                         if(autocvar_g_mirrordamage_virtual)
639                                                         {
640                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
641                                                                 attacker.dmg_take += v_x;
642                                                                 attacker.dmg_save += v_y;
643                                                                 attacker.dmg_inflictor = inflictor;
644                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
645                                                                 mirrorforce = 0;
646                                                         }
647
648                                                         if(autocvar_g_friendlyfire_virtual)
649                                                         {
650                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
651                                                                 targ.dmg_take += v_x;
652                                                                 targ.dmg_save += v_y;
653                                                                 targ.dmg_inflictor = inflictor;
654                                                                 damage = 0;
655                                                                 if(!autocvar_g_friendlyfire_virtual_force)
656                                                                         force = '0 0 0';
657                                                         }
658                                                 }
659                                                 else
660                                                         damage = 0;
661                                         }
662                                 }
663                         }
664                 }
665
666                 if not(DEATH_ISSPECIAL(deathtype))
667                 {
668                         damage *= g_weapondamagefactor;
669                         mirrordamage *= g_weapondamagefactor;
670                         complainteamdamage *= g_weapondamagefactor;
671                         force = force * g_weaponforcefactor;
672                         mirrorforce *= g_weaponforcefactor;
673                 }
674                 
675                 // should this be changed at all? If so, in what way?
676                 frag_attacker = attacker;
677                 frag_target = targ;
678                 frag_damage = damage;
679                 frag_force = force;
680         frag_deathtype = deathtype;
681                 frag_mirrordamage = mirrordamage;
682                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
683                 damage = frag_damage;
684                 mirrordamage = frag_mirrordamage;
685                 force = frag_force;
686                 
687                 if not(g_minstagib)
688                 {
689                         // apply strength multiplier
690                         if (attacker.items & IT_STRENGTH)
691                         {
692                                 if(targ == attacker)
693                                 {
694                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
695                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
696                                 }
697                                 else
698                                 {
699                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
700                                         force = force * autocvar_g_balance_powerup_strength_force;
701                                 }
702                         }
703
704                         // apply invincibility multiplier
705                         if (targ.items & IT_INVINCIBLE)
706                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
707                 }
708
709                 if (targ == attacker)
710                 {
711                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
712                                 damage = 0;
713                         else
714                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
715                 }
716
717                 // count the damage
718                 if(attacker)
719                 if(!targ.deadflag)
720                 if(targ.takedamage == DAMAGE_AIM)
721                 if(targ != attacker)
722                 {
723                         entity victim;
724                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
725                                 victim = targ.owner;
726                         else
727                                 victim = targ;
728
729                         if(IS_PLAYER(victim) || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
730                         {
731                                 if(IsDifferentTeam(victim, attacker))
732                                 {
733                                         if(damage > 0)
734                                         {
735                                                 if(deathtype != DEATH_FIRE)
736                                                 {
737                                                         if(victim.BUTTON_CHAT)
738                                                                 attacker.typehitsound += 1;
739                                                         else
740                                                                 attacker.hitsound += 1;
741                                                 }
742
743                                                 damage_goodhits += 1;
744                                                 damage_gooddamage += damage;
745
746                                                 if not(DEATH_ISSPECIAL(deathtype))
747                                                 {
748                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
749                                                         if(IsFlying(victim))
750                                                                 yoda = 1;
751                                                 }
752                                         }
753                                 }
754                                 else
755                                 {
756                                         if(deathtype != DEATH_FIRE)
757                                         {
758                                                 attacker.typehitsound += 1;
759                                         }
760                                         if(complainteamdamage > 0)
761                                                 if(time > attacker.teamkill_complain)
762                                                 {
763                                                         attacker.teamkill_complain = time + 5;
764                                                         attacker.teamkill_soundtime = time + 0.4;
765                                                         attacker.teamkill_soundsource = targ;
766                                                 }
767                                 }
768                         }
769                 }
770         }
771
772         // apply push
773         if (self.damageforcescale)
774         if (vlen(force))
775         if (!IS_PLAYER(self) || time >= self.spawnshieldtime || g_midair)
776         {
777                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
778                 if(self.movetype == MOVETYPE_PHYSICS)
779                 {
780                         entity farcent;
781                         farcent = spawn();
782                         farcent.classname = "farce";
783                         farcent.enemy = self;
784                         farcent.movedir = farce * 10;
785                         if(self.mass)
786                                 farcent.movedir = farcent.movedir * self.mass;
787                         farcent.origin = hitloc;
788                         farcent.forcetype = FORCETYPE_FORCEATPOS;
789                         farcent.nextthink = time + 0.1;
790                         farcent.think = SUB_Remove;
791                 }
792                 else
793                         self.velocity = self.velocity + farce;
794                 self.flags &~= FL_ONGROUND;
795                 UpdateCSQCProjectile(self);
796         }
797         // apply damage
798         if (damage != 0 || (self.damageforcescale && vlen(force)))
799         if (self.event_damage)
800                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
801         self = oldself;
802
803         // apply mirror damage if any
804         if(mirrordamage > 0 || mirrorforce > 0)
805         {
806                 attacker = attacker_save;
807
808                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
809                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
810         }
811 }
812
813 float RadiusDamage_running;
814 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
815         // Returns total damage applies to creatures
816 {
817         entity  targ;
818         vector  blastorigin;
819         vector  force;
820         float   total_damage_to_creatures;
821         entity  next;
822         float   tfloordmg;
823         float   tfloorforce;
824
825         float stat_damagedone;
826
827         if(RadiusDamage_running)
828         {
829                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
830                 return 0;
831         }
832
833         RadiusDamage_running = 1;
834
835         tfloordmg = autocvar_g_throughfloor_damage;
836         tfloorforce = autocvar_g_throughfloor_force;
837
838         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
839         total_damage_to_creatures = 0;
840
841         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
842                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
843                 {
844                         force = inflictor.velocity;
845                         if(vlen(force) == 0)
846                                 force = '0 0 -1';
847                         else
848                                 force = normalize(force);
849                         if(forceintensity >= 0)
850                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
851                         else
852                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
853                 }
854
855         stat_damagedone = 0;
856
857         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
858         while (targ)
859         {
860                 next = targ.chain;
861                 if (targ != inflictor)
862                         if (ignore != targ) if(targ.takedamage)
863                         {
864                                 vector nearest;
865                                 vector diff;
866                                 float power;
867
868                                 // LordHavoc: measure distance to nearest point on target (not origin)
869                                 // (this guarentees 100% damage on a touch impact)
870                                 nearest = targ.WarpZone_findradius_nearest;
871                                 diff = targ.WarpZone_findradius_dist;
872                                 // round up a little on the damage to ensure full damage on impacts
873                                 // and turn the distance into a fraction of the radius
874                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
875                                 //bprint(" ");
876                                 //bprint(ftos(power));
877                                 //if (targ == attacker)
878                                 //      print(ftos(power), "\n");
879                                 if (power > 0)
880                                 {
881                                         float finaldmg;
882                                         if (power > 1)
883                                                 power = 1;
884                                         finaldmg = coredamage * power + edgedamage * (1 - power);
885                                         if (finaldmg > 0)
886                                         {
887                                                 float a;
888                                                 float c;
889                                                 vector hitloc;
890                                                 vector myblastorigin;
891                                                 vector center;
892
893                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
894
895                                                 // if it's a player, use the view origin as reference
896                                                 center = CENTER_OR_VIEWOFS(targ);
897
898                                                 force = normalize(center - myblastorigin);
899                                                 force = force * (finaldmg / coredamage) * forceintensity;
900                                                 hitloc = nearest;
901
902                                                 if(targ != directhitentity)
903                                                 {
904                                                         float hits;
905                                                         float total;
906                                                         float hitratio;
907                                                         float mininv_f, mininv_d;
908
909                                                         // test line of sight to multiple positions on box,
910                                                         // and do damage if any of them hit
911                                                         hits = 0;
912
913                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
914                                                         // so for a given max stddev:
915                                                         // n = (1 / (2 * max stddev of hitratio))^2
916
917                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
918                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
919
920                                                         if(autocvar_g_throughfloor_debug)
921                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
922
923                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
924
925                                                         if(autocvar_g_throughfloor_debug)
926                                                                 print(sprintf(" steps=%f", total));
927
928                                                         if (IS_PLAYER(targ))
929                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
930                                                         else
931                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
932
933                                                         if(autocvar_g_throughfloor_debug)
934                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
935
936                                                         for(c = 0; c < total; ++c)
937                                                         {
938                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
939                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
940                                                                 if (trace_fraction == 1 || trace_ent == targ)
941                                                                 {
942                                                                         ++hits;
943                                                                         if (hits > 1)
944                                                                                 hitloc = hitloc + nearest;
945                                                                         else
946                                                                                 hitloc = nearest;
947                                                                 }
948                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
949                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
950                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
951                                                         }
952
953                                                         nearest = hitloc * (1 / max(1, hits));
954                                                         hitratio = (hits / total);
955                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
956                                                         finaldmg = finaldmg * a;
957                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
958                                                         force = force * a;
959
960                                                         if(autocvar_g_throughfloor_debug)
961                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
962                                                 }
963
964                                                 // laser force adjustments :P
965                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
966                                                 {
967                                                         if (targ == attacker)
968                                                         {
969                                                                 vector vel;
970
971                                                                 float force_zscale;
972                                                                 float force_velocitybiasramp;
973                                                                 float force_velocitybias;
974
975                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
976                                                                 if(deathtype & HITTYPE_SECONDARY)
977                                                                 {
978                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
979                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
980                                                                 }
981                                                                 else
982                                                                 {
983                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
984                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
985                                                                 }
986
987                                                                 vel = targ.velocity;
988                                                                 vel_z = 0;
989                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
990                                                                 force =
991                                                                         vlen(force)
992                                                                         *
993                                                                         normalize(normalize(force) + vel);
994
995                                                                 force_z *= force_zscale;
996                                                         }
997                                                         else
998                                                         {
999                                                                 if(deathtype & HITTYPE_SECONDARY)
1000                                                                 {
1001                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1002                                                                 }
1003                                                                 else
1004                                                                 {
1005                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1006                                                                 }
1007                                                         }
1008                                                 }
1009
1010                                                 //if (targ == attacker)
1011                                                 //{
1012                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1013                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1014                                                 //      print(" (", ftos(a), ")\n");
1015                                                 //}
1016                                                 if(finaldmg || vlen(force))
1017                                                 {
1018                                                         if(targ.iscreature)
1019                                                         {
1020                                                                 total_damage_to_creatures += finaldmg;
1021
1022                                                                 if(accuracy_isgooddamage(attacker, targ))
1023                                                                         stat_damagedone += finaldmg;
1024                                                         }
1025
1026                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1027                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1028                                                         else
1029                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1030                                                 }
1031                                         }
1032                                 }
1033                         }
1034                 targ = next;
1035         }
1036
1037         RadiusDamage_running = 0;
1038
1039         if(!DEATH_ISSPECIAL(deathtype))
1040                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1041
1042         return total_damage_to_creatures;
1043 }
1044
1045 .float fire_damagepersec;
1046 .float fire_endtime;
1047 .float fire_deathtype;
1048 .entity fire_owner;
1049 .float fire_hitsound;
1050 .entity fire_burner;
1051
1052 void fireburner_think();
1053
1054 float Fire_IsBurning(entity e)
1055 {
1056         return (time < e.fire_endtime);
1057 }
1058
1059 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1060 {
1061         float dps;
1062         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1063
1064         if(IS_PLAYER(e))
1065         {
1066                 if(e.deadflag)
1067                         return -1;
1068         }
1069         else
1070         {
1071                 if(!e.fire_burner)
1072                 {
1073                         // print("adding a fire burner to ", e.classname, "\n");
1074                         e.fire_burner = spawn();
1075                         e.fire_burner.classname = "fireburner";
1076                         e.fire_burner.think = fireburner_think;
1077                         e.fire_burner.nextthink = time;
1078                         e.fire_burner.owner = e;
1079                 }
1080         }
1081
1082         t = max(t, 0.1);
1083         dps = d / t;
1084         if(Fire_IsBurning(e))
1085         {
1086                 mintime = e.fire_endtime - time;
1087                 maxtime = max(mintime, t);
1088
1089                 mindps = e.fire_damagepersec;
1090                 maxdps = max(mindps, dps);
1091
1092                 if(maxtime > mintime || maxdps > mindps)
1093                 {
1094                         // Constraints:
1095                         
1096                         // damage we have right now
1097                         mindamage = mindps * mintime;
1098
1099                         // damage we want to get
1100                         maxdamage = mindamage + d;
1101
1102                         // but we can't exceed maxtime * maxdps!
1103                         totaldamage = min(maxdamage, maxtime * maxdps);
1104
1105                         // LEMMA:
1106                         // Look at:
1107                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1108                         // We see:
1109                         // totaldamage <= maxtime * maxdps
1110                         // ==> totaldamage / maxdps <= maxtime.
1111                         // We also see:
1112                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1113                         //                     >= min(mintime, maxtime)
1114                         // ==> totaldamage / maxdps >= mintime.
1115
1116                         /*
1117                         // how long do we damage then?
1118                         // at least as long as before
1119                         // but, never exceed maxdps
1120                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1121                         */
1122
1123                         // alternate:
1124                         // at most as long as maximum allowed
1125                         // but, never below mindps
1126                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1127
1128                         // assuming t > mintime, dps > mindps:
1129                         // we get d = t * dps = maxtime * maxdps
1130                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1131                         // totaldamage / maxdps = maxtime
1132                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1133                         // FROM THIS:
1134                         // a) totaltime = max(mintime, maxtime) = maxtime
1135                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1136
1137                         // assuming t <= mintime:
1138                         // we get maxtime = mintime
1139                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1140                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1141
1142                         // assuming dps <= mindps:
1143                         // we get mindps = maxdps.
1144                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1145                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1146                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1147
1148                         e.fire_damagepersec = totaldamage / totaltime;
1149                         e.fire_endtime = time + totaltime;
1150                         if(totaldamage > 1.2 * mindamage)
1151                         {
1152                                 e.fire_deathtype = dt;
1153                                 if(e.fire_owner != o)
1154                                 {
1155                                         e.fire_owner = o;
1156                                         e.fire_hitsound = FALSE;
1157                                 }
1158                         }
1159                         if(accuracy_isgooddamage(o, e))
1160                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1161                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1162                 }
1163                 else
1164                         return 0;
1165         }
1166         else
1167         {
1168                 e.fire_damagepersec = dps;
1169                 e.fire_endtime = time + t;
1170                 e.fire_deathtype = dt;
1171                 e.fire_owner = o;
1172                 e.fire_hitsound = FALSE;
1173                 if(accuracy_isgooddamage(o, e))
1174                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1175                 return d;
1176         }
1177 }
1178
1179 void Fire_ApplyDamage(entity e)
1180 {
1181         float t, d, hi, ty;
1182         entity o;
1183
1184         if not(Fire_IsBurning(e))
1185                 return;
1186
1187         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1188         if(IS_NOT_A_CLIENT(o))
1189                 o = e.fire_owner;
1190
1191         // water and slime stop fire
1192         if(e.waterlevel)
1193         if(e.watertype != CONTENT_LAVA)
1194                 e.fire_endtime = 0;
1195
1196         // ice stops fire
1197         if(e.freezetag_frozen)
1198                 e.fire_endtime = 0;
1199
1200         t = min(frametime, e.fire_endtime - time);
1201         d = e.fire_damagepersec * t;
1202
1203         hi = e.fire_owner.hitsound;
1204         ty = e.fire_owner.typehitsound;
1205         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1206         if(e.fire_hitsound && e.fire_owner)
1207         {
1208                 e.fire_owner.hitsound = hi;
1209                 e.fire_owner.typehitsound = ty;
1210         }
1211         e.fire_hitsound = TRUE;
1212
1213         if not(IS_INDEPENDENT_PLAYER(e))
1214         FOR_EACH_PLAYER(other) if(e != other)
1215         {
1216                 if(IS_PLAYER(other))
1217                 if(other.deadflag == DEAD_NO)
1218                 if not(IS_INDEPENDENT_PLAYER(other))
1219                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1220                 {
1221                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1222                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1223                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1224                 }
1225         }
1226 }
1227
1228 void Fire_ApplyEffect(entity e)
1229 {
1230         if(Fire_IsBurning(e))
1231                 e.effects |= EF_FLAME;
1232         else
1233                 e.effects &~= EF_FLAME;
1234 }
1235
1236 void fireburner_think()
1237 {
1238         // for players, this is done in the regular loop
1239         if(wasfreed(self.owner))
1240         {
1241                 remove(self);
1242                 return;
1243         }
1244         Fire_ApplyEffect(self.owner);
1245         if(!Fire_IsBurning(self.owner))
1246         {
1247                 self.owner.fire_burner = world;
1248                 remove(self);
1249                 return;
1250         }
1251         Fire_ApplyDamage(self.owner);
1252         self.nextthink = time;
1253 }