qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 /*string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }*/
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 #define INFO_NO_MSG 0
 312
 313 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 314 {
 315         float handled = 0, hits = 0;
 316         if(DEATH_ISSPECIAL(deathtype))
 317         {
 318                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 319                         { if(deathtype == max(0, name)) \
 320                         { \
 321                                 #if msg_death != NO_MSG \
 322                                         if not(murder) \
 323                                         { \
 324                                                 Send_Notification_Legacy_Wrapper(notif_target, MSG_ONE, MSG_DEATH, msg_death, s1, s2, f1, f2, f3); \
 325                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death, s1, s2, f1, f2, f3); \
 326                                                 ++handled; \
 327                                         } \
 328                                 #endif \
 329                                 #if msg_death_by != NO_MSG \
 330                                         if(murder) \
 331                                         { \
 332                                                 Send_Notification_Legacy_Wrapper(notif_target, MSG_ONE, MSG_DEATH, msg_death_by, s1, s2, f1, f2, f3); \
 333                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death_by, s1, s2, f1, f2, f3); \
 334                                                 ++handled; \
 335                                         } \
 336                                 #endif \
 337                                 ++hits; \
 338                         } }
 339
 340                 DEATHTYPES
 341                 #undef DEATHTYPE
 342
 343                 if not(hits)
 344                 {
 345                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 346                 }
 347                 if not(handled)
 348                 {
 349                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 350                         return;
 351                 }
 352         }
 353 }
 354
 355 float w_deathtype;
 356 float Obituary_WeaponDeath(float murder, float deathtype, string s1, string s2)
 357 {
 358         float death_weapon = DEATH_WEAPONOF(deathtype);
 359
 360         if(death_weapon)
 361         {
 362                 w_deathtype = deathtype;
 363                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 364                 w_deathtype = FALSE;
 365
 366                 if(death_message) { Send_Notification_Legacy_Wrapper(world, MSG_BROADCAST, MSG_WEAPON, death_message, s1, s2, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG); }
 367                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 368
 369                 return TRUE;
 370         }
 371         return FALSE;
 372 }
 373
 374 .float FRAG_VERBOSE;
 375 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 376 {
 377         // Sanity check
 378         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 379
 380         // Declarations
 381         string s1 = NO_STR_ARG, s2 = NO_STR_ARG;
 382         float f1 = NO_FL_ARG, f2 = NO_FL_ARG, f3 = NO_FL_ARG;
 383         float notif_firstblood = FALSE;
 384
 385         //dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 386
 387         // =======
 388         // SUICIDE
 389         // =======
 390         if(targ == attacker)
 391         {
 392                 if(DEATH_ISSPECIAL(deathtype))
 393                 {
 394                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 395                         {
 396                                 s1 = targ.netname;
 397                                 f1 = targ.team;
 398                         }
 399                         else
 400                         {
 401                                 switch(deathtype)
 402                                 {
 403                                         case DEATH_MIRRORDAMAGE:
 404                                         {
 405                                                 s1 = targ.netname;
 406                                                 f1 = targ.killcount;
 407                                                 break;
 408                                         }
 409
 410                                         default:
 411                                         {
 412                                                 s1 = targ.netname;
 413                                                 f1 = targ.killcount;
 414                                                 s2 = NO_STR_ARG;
 415                                                 f2 = f3 = NO_FL_ARG;
 416                                                 break;
 417                                         }
 418                                 }
 419                                 LogDeath("suicide", deathtype, targ, targ);
 420                                 GiveFrags(attacker, targ, -1, deathtype);
 421                         }
 422
 423                         Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, NO_FL_ARG);
 424                 }
 425                 else if not(Obituary_WeaponDeath(FALSE, deathtype, targ.netname, NO_STR_ARG))
 426                 {
 427                         backtrace("SUICIDE: what the hell happened here?\n");
 428                 }
 429         }
 430
 431         // ======
 432         // MURDER
 433         // ======
 434         else if(attacker.classname == "player")
 435         {
 436                 s1 = attacker.netname;
 437                 s2 = targ.netname;
 438
 439                 // TODO: ADD REAL CHECK HERE!
 440                 attacker.FRAG_VERBOSE = TRUE;
 441                 targ.FRAG_VERBOSE = TRUE;
 442
 443                 if(!IsDifferentTeam(attacker, targ))
 444                 {
 445                         LogDeath("tk", deathtype, attacker, targ);
 446                         GiveFrags(attacker, targ, -1, deathtype);
 447
 448                         attacker.killcount = 0;
 449
 450                         Send_Notification_Legacy_Wrapper(attacker, MSG_ONE, MSG_DEATH, DEATH_TEAMKILL_FRAG, s2, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 451                         Send_Notification_Legacy_Wrapper(targ, MSG_ONE, MSG_DEATH, DEATH_TEAMKILL_FRAGGED, s1, NO_STR_ARG, NO_FL_ARG, NO_FL_ARG, NO_FL_ARG);
 452                         Send_Notification_Legacy_Wrapper(world, MSG_BROADCAST, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG);
 453
 454                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 455                         // No need for specific death/weapon messages...
 456                 }
 457                 else
 458                 {
 459                         LogDeath("frag", deathtype, attacker, targ);
 460                         GiveFrags(attacker, targ, 1, deathtype);
 461
 462                         attacker.taunt_soundtime = time + 1;
 463                         attacker.killcount = attacker.killcount + 1;
 464
 465                         #define ADD_ACHIEVEMENT_CASE(numa,numb) \
 466                                 case numa: \
 467                                 { \
 468                                         AnnounceTo(attacker, strcat(#numb, "kills")); \
 469                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##numa, 1); \
 470                                         break; \
 471                                 }
 472                         switch(attacker.killcount)
 473                         {
 474                                 ADD_ACHIEVEMENT_CASE(3, 03)
 475                                 ADD_ACHIEVEMENT_CASE(5, 05)
 476                                 ADD_ACHIEVEMENT_CASE(10, 10)
 477                                 ADD_ACHIEVEMENT_CASE(15, 15)
 478                                 ADD_ACHIEVEMENT_CASE(20, 20)
 479                                 ADD_ACHIEVEMENT_CASE(25, 25)
 480                                 ADD_ACHIEVEMENT_CASE(30, 30)
 481                                 default: break;
 482                         }
 483                         #undef ADD_ACHIEVEMENT_CASE
 484
 485                         if(!checkrules_firstblood)
 486                         {
 487                                 checkrules_firstblood = TRUE;
 488                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 489                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 490                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 491                         }
 492
 493                         if(notif_firstblood) // first blood, no kill sprees yet
 494                         {
 495                                 if(targ.istypefrag)
 496                                 {
 497                                         Send_Notification_Legacy_Wrapper(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAG_FIRST),
 498                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 499
 500                                         Send_Notification_Legacy_Wrapper(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAGGED_FIRST),
 501                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 502                                 }
 503                                 else
 504                                 {
 505                                         Send_Notification_Legacy_Wrapper(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_FIRST_VERBOSE : DEATH_MURDER_FRAG_FIRST),
 506                                                 s2, s1, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 507
 508                                         Send_Notification_Legacy_Wrapper(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_FIRST_VERBOSE : DEATH_MURDER_FRAGGED_FIRST),
 509                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 510                                 }
 511                         }
 512                         else // normal frags, kill sprees listed
 513                         {
 514                                 if(targ.istypefrag)
 515                                 {
 516                                         Send_Notification_Legacy_Wrapper(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_VERBOSE : DEATH_MURDER_TYPEFRAG),
 517                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 518
 519                                         Send_Notification_Legacy_Wrapper(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_VERBOSE : DEATH_MURDER_TYPEFRAGGED),
 520                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 521                                 }
 522                                 else
 523                                 {
 524                                         Send_Notification_Legacy_Wrapper(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_VERBOSE : DEATH_MURDER_FRAG),
 525                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 526
 527                                         Send_Notification_Legacy_Wrapper(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_VERBOSE : DEATH_MURDER_FRAGGED),
 528                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 529                                 }
 530                         }
 531
 532                         if not(Obituary_WeaponDeath(TRUE, deathtype, targ.netname, attacker.netname))
 533                                 Obituary_SpecialDeath(targ, TRUE, deathtype, s2, s1, targ.killcount, NO_FL_ARG, NO_FL_ARG);
 534                 }
 535         }
 536
 537         // =============
 538         // ACCIDENT/TRAP
 539         // =============
 540         else
 541         {
 542                 switch(deathtype)
 543                 {
 544                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 545                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 546                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 547                         /*case DEATH_HURTTRIGGER:
 548                         {
 549                                 s1 = targ.netname;
 550                                 s2 = inflictor.message;
 551                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 552                                 break;
 553                         }*/
 554
 555                         case DEATH_CUSTOM:
 556                         {
 557                                 s1 = targ.netname;
 558                                 s2 = deathmessage;
 559                                 f1 = targ.killcount;
 560                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 561                                 f2 = f3 = NO_FL_ARG;
 562                                 break;
 563                         }
 564
 565                         default:
 566                         {
 567                                 s1 = targ.netname;
 568                                 f1 = targ.killcount;
 569                                 s2 = NO_STR_ARG;
 570                                 f2 = f3 = NO_FL_ARG;
 571                                 break;
 572                         }
 573                 }
 574
 575                 LogDeath("accident", deathtype, targ, targ);
 576                 GiveFrags(targ, targ, -1, deathtype);
 577
 578                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 579                 {
 580                         AnnounceTo(targ, "botlike");
 581                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 582                 }
 583
 584                 Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, f3);
 585         }
 586
 587         // Set final information for the death
 588         targ.death_origin = targ.origin;
 589         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 590         if(targ.killcount) { targ.killcount = 0; }
 591 }
 592
 593 // these are updated by each Damage call for use in button triggering and such
 594 entity damage_targ;
 595 entity damage_inflictor;
 596 entity damage_attacker;
 597
 598 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 599 {
 600         float mirrordamage;
 601         float mirrorforce;
 602         float teamdamage0;
 603         entity attacker_save;
 604         mirrordamage = 0;
 605         mirrorforce = 0;
 606
 607         if (gameover || targ.killcount == -666)
 608                 return;
 609
 610         entity oldself;
 611         oldself = self;
 612         self = targ;
 613         damage_targ = targ;
 614         damage_inflictor = inflictor;
 615         damage_attacker = attacker;
 616                 attacker_save = attacker;
 617
 618         if(targ.classname == "player")
 619                 if(targ.hook)
 620                         if(targ.hook.aiment)
 621                                 if(targ.hook.aiment == attacker)
 622                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 623
 624         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 625         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 626         {
 627                 if(targ.classname == "player")
 628                         if not(IsDifferentTeam(targ, attacker))
 629                         {
 630                                 self = oldself;
 631                                 return;
 632                         }
 633         }
 634
 635         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 636         {
 637                 // These are ALWAYS lethal
 638                 // No damage modification here
 639                 // Instead, prepare the victim for his death...
 640                 targ.armorvalue = 0;
 641                 targ.spawnshieldtime = 0;
 642                 targ.health = 0.9; // this is < 1
 643                 targ.flags -= targ.flags & FL_GODMODE;
 644                 damage = 100000;
 645         }
 646         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 647         {
 648                 // no processing
 649         }
 650         else
 651         {
 652                 /*
 653                 skill based bot damage? gtfo. (tZork)
 654                 if (targ.classname == "player")
 655                 if (attacker.classname == "player")
 656                 if (!targ.isbot)
 657                 if (attacker.isbot)
 658                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 659         */
 660
 661                 // nullify damage if teamplay is on
 662                 if(deathtype != DEATH_TELEFRAG)
 663                 if(attacker.classname == "player")
 664                 {
 665                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 666                         {
 667                                 damage = 0;
 668                                 force = '0 0 0';
 669                         }
 670                         else if(!IsDifferentTeam(attacker, targ))
 671                         {
 672                                 if(autocvar_teamplay_mode == 1)
 673                                         damage = 0;
 674                                 else if(attacker != targ)
 675                                 {
 676                                         if(autocvar_teamplay_mode == 3)
 677                                                 damage = 0;
 678                                         else if(autocvar_teamplay_mode == 4)
 679                                         {
 680                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 681                                                 {
 682                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 683                                                         attacker.dmg_team = attacker.dmg_team + damage;
 684                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 685                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 686                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 687                                                         if(g_minstagib)
 688                                                         {
 689                                                                 if(autocvar_g_friendlyfire == 0)
 690                                                                         damage = 0;
 691                                                         }
 692                                                         else if(g_ca)
 693                                                                 damage = 0;
 694                                                         else
 695                                                                 damage = autocvar_g_friendlyfire * damage;
 696                                                         // mirrordamage will be used LATER
 697
 698                                                         if(autocvar_g_mirrordamage_virtual)
 699                                                         {
 700                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 701                                                                 attacker.dmg_take += v_x;
 702                                                                 attacker.dmg_save += v_y;
 703                                                                 attacker.dmg_inflictor = inflictor;
 704                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 705                                                                 mirrorforce = 0;
 706                                                         }
 707
 708                                                         if(autocvar_g_friendlyfire_virtual)
 709                                                         {
 710                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 711                                                                 targ.dmg_take += v_x;
 712                                                                 targ.dmg_save += v_y;
 713                                                                 targ.dmg_inflictor = inflictor;
 714                                                                 damage = 0;
 715                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 716                                                                         force = '0 0 0';
 717                                                         }
 718                                                 }
 719                                                 else
 720                                                         damage = 0;
 721                                         }
 722                                 }
 723                         }
 724                 }
 725
 726                 if(targ.classname == "player")
 727                 if(attacker.classname == "player")
 728                 if(attacker != targ)
 729                 {
 730                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 731                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 732                 }
 733
 734                 if(targ.classname == "player")
 735                 if (g_minstagib)
 736                 {
 737                         if ((deathtype == DEATH_FALL)  ||
 738                                 (deathtype == DEATH_DROWN) ||
 739                                 (deathtype == DEATH_SLIME) ||
 740                                 (deathtype == DEATH_LAVA)  ||
 741                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 742                         {
 743                                 self = oldself;
 744                                 return;
 745                         }
 746                         if(damage > 0)
 747                             damage = 10000;
 748                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 749                         {
 750                                 targ.armorvalue -= 1;
 751                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 752                                 damage = 0;
 753                                 targ.hitsound += 1;
 754                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 755                         }
 756                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 757                         {
 758                                 damage = 0;
 759                                 mirrordamage = 0;
 760                                 if (targ != attacker)
 761                                 {
 762                                         if ((targ.health >= 1) && (targ.classname == "player"))
 763                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 764                                         force = '0 0 0';
 765                                         // keep mirrorforce
 766                                         attacker = targ;
 767                                 }
 768                         }
 769                 }
 770
 771                 if not(DEATH_ISSPECIAL(deathtype))
 772                 {
 773                         damage *= g_weapondamagefactor;
 774                         mirrordamage *= g_weapondamagefactor;
 775                         force = force * g_weaponforcefactor;
 776                         mirrorforce *= g_weaponforcefactor;
 777                 }
 778
 779                 // should this be changed at all? If so, in what way?
 780                 frag_attacker = attacker;
 781                 frag_target = targ;
 782                 frag_damage = damage;
 783                 frag_force = force;
 784         frag_deathtype = deathtype;
 785                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 786                 damage = frag_damage;
 787                 force = frag_force;
 788
 789                 // apply strength multiplier
 790                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 791                 {
 792                         if(targ == attacker)
 793                         {
 794                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 795                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 796                         }
 797                         else
 798                         {
 799                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 800                                 force = force * autocvar_g_balance_powerup_strength_force;
 801                         }
 802                 }
 803
 804                 // apply invincibility multiplier
 805                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 806                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 807
 808                 if (targ == attacker)
 809                 {
 810                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 811                                 damage = 0;
 812                         else
 813                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 814                 }
 815
 816                 if(g_runematch)
 817                 {
 818                         // apply strength rune
 819                         if (attacker.runes & RUNE_STRENGTH)
 820                         {
 821                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 822                                 {
 823                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 824                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 825                                 }
 826                                 else
 827                                 {
 828                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 829                                         force = force * autocvar_g_balance_rune_strength_force;
 830                                 }
 831                         }
 832                         else if (attacker.runes & CURSE_WEAK)
 833                         {
 834                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 835                                 force = force * autocvar_g_balance_curse_weak_force;
 836                         }
 837
 838                         // apply defense rune
 839                         if (targ.runes & RUNE_DEFENSE)
 840                         {
 841                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 842                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 843                                 else
 844                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 845                         }
 846                         else if (targ.runes & CURSE_VULNER)
 847                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 848                 }
 849
 850                 // count the damage
 851                 if(attacker)
 852                 if(!targ.deadflag)
 853                 if(targ.takedamage == DAMAGE_AIM)
 854                 if(targ != attacker)
 855                 {
 856                         if(damage_headshotbonus)
 857                         {
 858                                 if(targ.classname == "player")
 859                                 {
 860                                         // HEAD SHOT:
 861                                         // find height of hit on player axis
 862                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 863                                         vector headmins, headmaxs, org;
 864                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 865                                         headmins = org + GetHeadshotMins(targ);
 866                                         headmaxs = org + GetHeadshotMaxs(targ);
 867                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 868                                         {
 869                                                 deathtype |= HITTYPE_HEADSHOT;
 870                                         }
 871                                 }
 872                                 else if(targ.classname == "turret_head")
 873                                 {
 874                                         deathtype |= HITTYPE_HEADSHOT;
 875                                 }
 876                                 if(deathtype & HITTYPE_HEADSHOT)
 877                                         if(damage_headshotbonus > 0)
 878                                                 damage *= 1 + damage_headshotbonus;
 879                         }
 880
 881                         entity victim;
 882                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 883                                 victim = targ.owner;
 884                         else
 885                                 victim = targ;
 886
 887                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 888                         {
 889                                 if(IsDifferentTeam(victim, attacker))
 890                                 {
 891                                         if(damage > 0)
 892                                         {
 893                                                 if(deathtype != DEATH_FIRE)
 894                                                 {
 895                                                         if(victim.BUTTON_CHAT)
 896                                                                 attacker.typehitsound += 1;
 897                                                         else
 898                                                                 attacker.hitsound += 1;
 899                                                 }
 900
 901                                                 damage_goodhits += 1;
 902                                                 damage_gooddamage += damage;
 903
 904                                                 if not(DEATH_ISSPECIAL(deathtype))
 905                                                 {
 906                                                         if(targ.classname == "player") // don't do this for vehicles
 907                                                         if(!g_minstagib)
 908                                                         if(IsFlying(victim))
 909                                                                 yoda = 1;
 910
 911                                                         if(g_minstagib)
 912                                                         if(victim.items & IT_STRENGTH)
 913                                                                 yoda = 1;
 914
 915                                                         if(deathtype & HITTYPE_HEADSHOT)
 916                                                                 headshot = 1;
 917                                                 }
 918                                         }
 919                                 }
 920                                 else
 921                                 {
 922                                         if(deathtype != DEATH_FIRE)
 923                                         {
 924                                                 attacker.typehitsound += 1;
 925                                         }
 926                                         if(mirrordamage > 0)
 927                                                 if(time > attacker.teamkill_complain)
 928                                                 {
 929                                                         attacker.teamkill_complain = time + 5;
 930                                                         attacker.teamkill_soundtime = time + 0.4;
 931                                                         attacker.teamkill_soundsource = targ;
 932                                                 }
 933                                 }
 934                         }
 935                 }
 936         }
 937
 938         // apply push
 939         if (self.damageforcescale)
 940         if (vlen(force))
 941         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 942         {
 943                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 944                 if(self.movetype == MOVETYPE_PHYSICS)
 945                 {
 946                         entity farcent;
 947                         farcent = spawn();
 948                         farcent.classname = "farce";
 949                         farcent.enemy = self;
 950                         farcent.movedir = farce * 10;
 951                         if(self.mass)
 952                                 farcent.movedir = farcent.movedir * self.mass;
 953                         farcent.origin = hitloc;
 954                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 955                         farcent.nextthink = time + 0.1;
 956                         farcent.think = SUB_Remove;
 957                 }
 958                 else
 959                         self.velocity = self.velocity + farce;
 960                 self.flags &~= FL_ONGROUND;
 961                 UpdateCSQCProjectile(self);
 962         }
 963         // apply damage
 964         if (damage != 0 || (self.damageforcescale && vlen(force)))
 965         if (self.event_damage)
 966                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 967         self = oldself;
 968
 969         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 970         {
 971                 if(g_runematch)
 972                 {
 973                         if (attacker.runes & RUNE_VAMPIRE)
 974                         {
 975                         // apply vampire rune
 976                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 977                                 {
 978                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 979                                         attacker.health = bound(
 980                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 981                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 982                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 983                                 }
 984                                 else
 985                                 {
 986                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 987                                         attacker.health = bound(
 988                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 989                                                                                         // empathy won't let you gain health in the same way...
 990                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 991                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 992                                         }
 993                         }
 994                         // apply empathy curse
 995                         else if (attacker.runes & CURSE_EMPATHY)
 996                         {
 997                                 attacker.health = bound(
 998                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 999                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
1000                                         attacker.health);
1001                         }
1002                 }
1003         }
1004
1005         // apply mirror damage if any
1006         if(mirrordamage > 0 || mirrorforce > 0)
1007         {
1008                 attacker = attacker_save;
1009                 if(g_minstagib)
1010                 if(mirrordamage > 0)
1011                 {
1012                         // just lose extra LIVES, don't kill the player for mirror damage
1013                         if(attacker.armorvalue > 0)
1014                         {
1015                                 attacker.armorvalue = attacker.armorvalue - 1;
1016                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
1017                                 attacker.hitsound += 1;
1018                         }
1019                         mirrordamage = 0;
1020                 }
1021
1022                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
1023                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
1024         }
1025 }
1026
1027 float RadiusDamage_running;
1028 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
1029         // Returns total damage applies to creatures
1030 {
1031         entity  targ;
1032         vector  blastorigin;
1033         vector  force;
1034         float   total_damage_to_creatures;
1035         entity  next;
1036         float   tfloordmg;
1037         float   tfloorforce;
1038
1039         float stat_damagedone;
1040
1041         if(RadiusDamage_running)
1042         {
1043                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1044                 return 0;
1045         }
1046
1047         RadiusDamage_running = 1;
1048
1049         tfloordmg = autocvar_g_throughfloor_damage;
1050         tfloorforce = autocvar_g_throughfloor_force;
1051
1052         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1053         total_damage_to_creatures = 0;
1054
1055         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1056                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1057                 {
1058                         force = inflictor.velocity;
1059                         if(vlen(force) == 0)
1060                                 force = '0 0 -1';
1061                         else
1062                                 force = normalize(force);
1063                         if(forceintensity >= 0)
1064                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1065                         else
1066                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1067                 }
1068
1069         stat_damagedone = 0;
1070
1071         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1072         while (targ)
1073         {
1074                 next = targ.chain;
1075                 if (targ != inflictor)
1076                         if (ignore != targ) if(targ.takedamage)
1077                         {
1078                                 vector nearest;
1079                                 vector diff;
1080                                 float power;
1081
1082                                 // LordHavoc: measure distance to nearest point on target (not origin)
1083                                 // (this guarentees 100% damage on a touch impact)
1084                                 nearest = targ.WarpZone_findradius_nearest;
1085                                 diff = targ.WarpZone_findradius_dist;
1086                                 // round up a little on the damage to ensure full damage on impacts
1087                                 // and turn the distance into a fraction of the radius
1088                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1089                                 //bprint(" ");
1090                                 //bprint(ftos(power));
1091                                 //if (targ == attacker)
1092                                 //      print(ftos(power), "\n");
1093                                 if (power > 0)
1094                                 {
1095                                         float finaldmg;
1096                                         if (power > 1)
1097                                                 power = 1;
1098                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1099                                         if (finaldmg > 0)
1100                                         {
1101                                                 float a;
1102                                                 float c;
1103                                                 vector hitloc;
1104                                                 vector myblastorigin;
1105                                                 vector center;
1106
1107                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1108
1109                                                 // if it's a player, use the view origin as reference
1110                                                 center = CENTER_OR_VIEWOFS(targ);
1111
1112                                                 force = normalize(center - myblastorigin);
1113                                                 force = force * (finaldmg / coredamage) * forceintensity;
1114                                                 hitloc = nearest;
1115
1116                                                 if(targ != directhitentity)
1117                                                 {
1118                                                         float hits;
1119                                                         float total;
1120                                                         float hitratio;
1121                                                         float mininv_f, mininv_d;
1122
1123                                                         // test line of sight to multiple positions on box,
1124                                                         // and do damage if any of them hit
1125                                                         hits = 0;
1126
1127                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1128                                                         // so for a given max stddev:
1129                                                         // n = (1 / (2 * max stddev of hitratio))^2
1130
1131                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1132                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1133
1134                                                         if(autocvar_g_throughfloor_debug)
1135                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1136
1137                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1138
1139                                                         if(autocvar_g_throughfloor_debug)
1140                                                                 print(sprintf(" steps=%f", total));
1141
1142                                                         if (targ.classname == "player")
1143                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1144                                                         else
1145                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1146
1147                                                         if(autocvar_g_throughfloor_debug)
1148                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1149
1150                                                         for(c = 0; c < total; ++c)
1151                                                         {
1152                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1153                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1154                                                                 if (trace_fraction == 1 || trace_ent == targ)
1155                                                                 {
1156                                                                         ++hits;
1157                                                                         if (hits > 1)
1158                                                                                 hitloc = hitloc + nearest;
1159                                                                         else
1160                                                                                 hitloc = nearest;
1161                                                                 }
1162                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1163                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1164                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1165                                                         }
1166
1167                                                         nearest = hitloc * (1 / max(1, hits));
1168                                                         hitratio = (hits / total);
1169                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1170                                                         finaldmg = finaldmg * a;
1171                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1172                                                         force = force * a;
1173
1174                                                         if(autocvar_g_throughfloor_debug)
1175                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1176                                                 }
1177
1178                                                 // laser force adjustments :P
1179                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1180                                                 {
1181                                                         if (targ == attacker)
1182                                                         {
1183                                                                 vector vel;
1184
1185                                                                 float force_zscale;
1186                                                                 float force_velocitybiasramp;
1187                                                                 float force_velocitybias;
1188
1189                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1190                                                                 if(deathtype & HITTYPE_SECONDARY)
1191                                                                 {
1192                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1193                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1194                                                                 }
1195                                                                 else
1196                                                                 {
1197                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1198                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1199                                                                 }
1200
1201                                                                 vel = targ.velocity;
1202                                                                 vel_z = 0;
1203                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1204                                                                 force =
1205                                                                         vlen(force)
1206                                                                         *
1207                                                                         normalize(normalize(force) + vel);
1208
1209                                                                 force_z *= force_zscale;
1210                                                         }
1211                                                         else
1212                                                         {
1213                                                                 if(deathtype & HITTYPE_SECONDARY)
1214                                                                 {
1215                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1216                                                                 }
1217                                                                 else
1218                                                                 {
1219                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1220                                                                 }
1221                                                         }
1222                                                 }
1223
1224                                                 //if (targ == attacker)
1225                                                 //{
1226                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1227                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1228                                                 //      print(" (", ftos(a), ")\n");
1229                                                 //}
1230                                                 if(finaldmg || vlen(force))
1231                                                 {
1232                                                         if(targ.iscreature)
1233                                                         {
1234                                                                 total_damage_to_creatures += finaldmg;
1235
1236                                                                 if(accuracy_isgooddamage(attacker, targ))
1237                                                                         stat_damagedone += finaldmg;
1238                                                         }
1239
1240                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1241                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1242                                                         else
1243                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1244                                                 }
1245                                         }
1246                                 }
1247                         }
1248                 targ = next;
1249         }
1250
1251         RadiusDamage_running = 0;
1252
1253         if(!DEATH_ISSPECIAL(deathtype))
1254                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1255
1256         return total_damage_to_creatures;
1257 }
1258
1259 .float fire_damagepersec;
1260 .float fire_endtime;
1261 .float fire_deathtype;
1262 .entity fire_owner;
1263 .float fire_hitsound;
1264 .entity fire_burner;
1265
1266 void fireburner_think();
1267
1268 float Fire_IsBurning(entity e)
1269 {
1270         return (time < e.fire_endtime);
1271 }
1272
1273 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1274 {
1275         float dps;
1276         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1277
1278         if(e.classname == "player")
1279         {
1280                 if(e.deadflag)
1281                         return -1;
1282         }
1283         else
1284         {
1285                 if(!e.fire_burner)
1286                 {
1287                         // print("adding a fire burner to ", e.classname, "\n");
1288                         e.fire_burner = spawn();
1289                         e.fire_burner.classname = "fireburner";
1290                         e.fire_burner.think = fireburner_think;
1291                         e.fire_burner.nextthink = time;
1292                         e.fire_burner.owner = e;
1293                 }
1294         }
1295
1296         t = max(t, 0.1);
1297         dps = d / t;
1298         if(Fire_IsBurning(e))
1299         {
1300                 mintime = e.fire_endtime - time;
1301                 maxtime = max(mintime, t);
1302
1303                 mindps = e.fire_damagepersec;
1304                 maxdps = max(mindps, dps);
1305
1306                 if(maxtime > mintime || maxdps > mindps)
1307                 {
1308                         // Constraints:
1309
1310                         // damage we have right now
1311                         mindamage = mindps * mintime;
1312
1313                         // damage we want to get
1314                         maxdamage = mindamage + d;
1315
1316                         // but we can't exceed maxtime * maxdps!
1317                         totaldamage = min(maxdamage, maxtime * maxdps);
1318
1319                         // LEMMA:
1320                         // Look at:
1321                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1322                         // We see:
1323                         // totaldamage <= maxtime * maxdps
1324                         // ==> totaldamage / maxdps <= maxtime.
1325                         // We also see:
1326                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1327                         //                     >= min(mintime, maxtime)
1328                         // ==> totaldamage / maxdps >= mintime.
1329
1330                         /*
1331                         // how long do we damage then?
1332                         // at least as long as before
1333                         // but, never exceed maxdps
1334                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1335                         */
1336
1337                         // alternate:
1338                         // at most as long as maximum allowed
1339                         // but, never below mindps
1340                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1341
1342                         // assuming t > mintime, dps > mindps:
1343                         // we get d = t * dps = maxtime * maxdps
1344                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1345                         // totaldamage / maxdps = maxtime
1346                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1347                         // FROM THIS:
1348                         // a) totaltime = max(mintime, maxtime) = maxtime
1349                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1350
1351                         // assuming t <= mintime:
1352                         // we get maxtime = mintime
1353                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1354                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1355
1356                         // assuming dps <= mindps:
1357                         // we get mindps = maxdps.
1358                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1359                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1360                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1361
1362                         e.fire_damagepersec = totaldamage / totaltime;
1363                         e.fire_endtime = time + totaltime;
1364                         if(totaldamage > 1.2 * mindamage)
1365                         {
1366                                 e.fire_deathtype = dt;
1367                                 if(e.fire_owner != o)
1368                                 {
1369                                         e.fire_owner = o;
1370                                         e.fire_hitsound = FALSE;
1371                                 }
1372                         }
1373                         if(accuracy_isgooddamage(o, e))
1374                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1375                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1376                 }
1377                 else
1378                         return 0;
1379         }
1380         else
1381         {
1382                 e.fire_damagepersec = dps;
1383                 e.fire_endtime = time + t;
1384                 e.fire_deathtype = dt;
1385                 e.fire_owner = o;
1386                 e.fire_hitsound = FALSE;
1387                 if(accuracy_isgooddamage(o, e))
1388                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1389                 return d;
1390         }
1391 }
1392
1393 void Fire_ApplyDamage(entity e)
1394 {
1395         float t, d, hi, ty;
1396         entity o;
1397
1398         if not(Fire_IsBurning(e))
1399                 return;
1400
1401         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1402         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1403                 o = e.fire_owner;
1404
1405         // water and slime stop fire
1406         if(e.waterlevel)
1407         if(e.watertype != CONTENT_LAVA)
1408                 e.fire_endtime = 0;
1409
1410         // ice stops fire
1411         if(e.freezetag_frozen)
1412                 e.fire_endtime = 0;
1413
1414         t = min(frametime, e.fire_endtime - time);
1415         d = e.fire_damagepersec * t;
1416
1417         hi = e.fire_owner.hitsound;
1418         ty = e.fire_owner.typehitsound;
1419         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1420         if(e.fire_hitsound && e.fire_owner)
1421         {
1422                 e.fire_owner.hitsound = hi;
1423                 e.fire_owner.typehitsound = ty;
1424         }
1425         e.fire_hitsound = TRUE;
1426
1427         if not(IS_INDEPENDENT_PLAYER(e))
1428         FOR_EACH_PLAYER(other) if(e != other)
1429         {
1430                 if(other.classname == "player")
1431                 if(other.deadflag == DEAD_NO)
1432                 if not(IS_INDEPENDENT_PLAYER(other))
1433                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1434                 {
1435                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1436                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1437                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1438                 }
1439         }
1440 }
1441
1442 void Fire_ApplyEffect(entity e)
1443 {
1444         if(Fire_IsBurning(e))
1445                 e.effects |= EF_FLAME;
1446         else
1447                 e.effects &~= EF_FLAME;
1448 }
1449
1450 void fireburner_think()
1451 {
1452         // for players, this is done in the regular loop
1453         if(wasfreed(self.owner))
1454         {
1455                 remove(self);
1456                 return;
1457         }
1458         Fire_ApplyEffect(self.owner);
1459         if(!Fire_IsBurning(self.owner))
1460         {
1461                 self.owner.fire_burner = world;
1462                 remove(self);
1463                 return;
1464         }
1465         Fire_ApplyDamage(self.owner);
1466         self.nextthink = time;
1467 }