qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_lms)
 190                 {
 191                         // remove a life
 192                         float tl;
 193                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 194                         if(tl < lms_lowest_lives)
 195                                 lms_lowest_lives = tl;
 196                         if(tl <= 0)
 197                         {
 198                                 if(!lms_next_place)
 199                                         lms_next_place = player_count;
 200                                 else
 201                                         lms_next_place = min(lms_next_place, player_count);
 202                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 203                                 --lms_next_place;
 204                         }
 205                         f = 0;
 206                 }
 207         }
 208
 209         attacker.totalfrags += f;
 210
 211         if(f)
 212                 UpdateFrags(attacker, f);
 213 }
 214
 215 string AppendItemcodes(string s, entity player)
 216 {
 217         float w;
 218         w = player.weapon;
 219         //if(w == 0)
 220         //      w = player.switchweapon;
 221         if(w == 0)
 222                 w = player.cnt; // previous weapon!
 223         s = strcat(s, ftos(w));
 224         if(time < player.strength_finished)
 225                 s = strcat(s, "S");
 226         if(time < player.invincible_finished)
 227                 s = strcat(s, "I");
 228         if(player.flagcarried != world)
 229                 s = strcat(s, "F");
 230         if(player.BUTTON_CHAT)
 231                 s = strcat(s, "T");
 232         if(player.kh_next)
 233                 s = strcat(s, "K");
 234         return s;
 235 }
 236
 237 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 238 {
 239         string s;
 240         if(!autocvar_sv_eventlog)
 241                 return;
 242         s = strcat(":kill:", mode);
 243         s = strcat(s, ":", ftos(killer.playerid));
 244         s = strcat(s, ":", ftos(killed.playerid));
 245         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 246         s = strcat(s, ":items=");
 247         s = AppendItemcodes(s, killer);
 248         if(killed != killer)
 249         {
 250                 s = strcat(s, ":victimitems=");
 251                 s = AppendItemcodes(s, killed);
 252         }
 253         GameLogEcho(s);
 254 }
 255
 256 void Obituary_SpecialDeath(
 257         entity notif_target,
 258         float murder,
 259         float deathtype,
 260         string s1, string s2, string s3,
 261         float f1, float f2, float f3)
 262 {
 263         if(DEATH_ISSPECIAL(deathtype))
 264         {
 265                 entity deathent = deathtypes[(deathtype - DT_FIRST) - 1];
 266                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 267
 268                 if(murder)
 269                 {
 270                         if(deathent.death_msgmurder)
 271                         {
 272                                 Send_Notification_WOVA(
 273                                         NOTIF_ONE,
 274                                         notif_target,
 275                                         MSG_MULTI,
 276                                         deathent.death_msgmurder.nent_id,
 277                                         s1, s2, s3, "",
 278                                         f1, f2, f3, 0
 279                                 );
 280                                 Send_Notification_WOVA(
 281                                         NOTIF_ALL_EXCEPT,
 282                                         notif_target,
 283                                         MSG_INFO,
 284                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 285                                         s1, s2, s3, "",
 286                                         f1, f2, f3, 0
 287                                 );
 288                         }
 289                 }
 290                 else
 291                 {
 292                         if(deathent.death_msgself)
 293                         {
 294                                 Send_Notification_WOVA(
 295                                         NOTIF_ONE,
 296                                         notif_target,
 297                                         MSG_MULTI,
 298                                         deathent.death_msgself.nent_id,
 299                                         s1, s2, s3, "",
 300                                         f1, f2, f3, 0
 301                                 );
 302                                 Send_Notification_WOVA(
 303                                         NOTIF_ALL_EXCEPT,
 304                                         notif_target,
 305                                         MSG_INFO,
 306                                         deathent.death_msgself.nent_msginfo.nent_id,
 307                                         s1, s2, s3, "",
 308                                         f1, f2, f3, 0
 309                                 );
 310                         }
 311                 }
 312         }
 313         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 314 }
 315
 316 float w_deathtype;
 317 float Obituary_WeaponDeath(
 318         entity notif_target,
 319         float murder,
 320         float deathtype,
 321         string s1, string s2, string s3,
 322         float f1, float f2)
 323 {
 324         float death_weapon = DEATH_WEAPONOF(deathtype);
 325         if(death_weapon)
 326         {
 327                 w_deathtype = deathtype;
 328                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 329                 w_deathtype = FALSE;
 330
 331                 if(death_message)
 332                 {
 333                         Send_Notification_WOVA(
 334                                 NOTIF_ONE,
 335                                 notif_target,
 336                                 MSG_MULTI,
 337                                 death_message,
 338                                 s1, s2, s3, "",
 339                                 f1, f2, 0, 0
 340                         );
 341                         Send_Notification_WOVA(
 342                                 NOTIF_ALL_EXCEPT,
 343                                 notif_target,
 344                                 MSG_INFO,
 345                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 346                                 s1, s2, s3, "",
 347                                 f1, f2, 0, 0
 348                         );
 349                 }
 350                 else
 351                 {
 352                         dprint(sprintf(
 353                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 354                                 deathtype,
 355                                 death_weapon
 356                         ));
 357                 }
 358
 359                 return TRUE;
 360         }
 361         return FALSE;
 362 }
 363
 364 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 365 {
 366         // Sanity check
 367         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 368
 369         // Declarations
 370         float notif_firstblood = FALSE;
 371         float kill_count_to_attacker, kill_count_to_target;
 372
 373         // Set final information for the death
 374         targ.death_origin = targ.origin;
 375         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 376         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 377
 378         #ifdef NOTIFICATIONS_DEBUG
 379         Debug_Notification(
 380                 sprintf(
 381                         "Obituary(%s, %s, %s, %s = %d);\n",
 382                         attacker.netname,
 383                         inflictor.netname,
 384                         targ.netname,
 385                         Deathtype_Name(deathtype),
 386                         deathtype
 387                 )
 388         );
 389         #endif
 390
 391         // =======
 392         // SUICIDE
 393         // =======
 394         if(targ == attacker)
 395         {
 396                 if(DEATH_ISSPECIAL(deathtype))
 397                 {
 398                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 399                         {
 400                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 401                         }
 402                         else
 403                         {
 404                                 switch(deathtype)
 405                                 {
 406                                         case DEATH_MIRRORDAMAGE:
 407                                         {
 408                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 409                                                 break;
 410                                         }
 411
 412                                         default:
 413                                         {
 414                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 415                                                 break;
 416                                         }
 417                                 }
 418                         }
 419                 }
 420                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 421                 {
 422                         backtrace("SUICIDE: what the hell happened here?\n");
 423                         return;
 424                 }
 425                 LogDeath("suicide", deathtype, targ, targ);
 426                 GiveFrags(attacker, targ, -1, deathtype);
 427         }
 428
 429         // ======
 430         // MURDER
 431         // ======
 432         else if(IS_PLAYER(attacker))
 433         {
 434                 if(!IsDifferentTeam(attacker, targ))
 435                 {
 436                         LogDeath("tk", deathtype, attacker, targ);
 437                         GiveFrags(attacker, targ, -1, deathtype);
 438
 439                         attacker.killcount = 0;
 440
 441                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 442                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 443                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 444
 445                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 446                         // No need for specific death/weapon messages...
 447                 }
 448                 else
 449                 {
 450                         LogDeath("frag", deathtype, attacker, targ);
 451                         GiveFrags(attacker, targ, 1, deathtype);
 452
 453                         attacker.taunt_soundtime = time + 1;
 454                         attacker.killcount = attacker.killcount + 1;
 455
 456                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 457                                 case counta: \
 458                                 { \
 459                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 460                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 461                                         break; \
 462                                 }
 463                         switch(attacker.killcount)
 464                         {
 465                                 KILL_SPREE_LIST
 466                                 default: break;
 467                         }
 468                         #undef SPREE_ITEM
 469
 470                         if(!checkrules_firstblood)
 471                         {
 472                                 checkrules_firstblood = TRUE;
 473                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 474                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 475                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 476
 477                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 478                                 kill_count_to_attacker = -1;
 479                                 kill_count_to_target = -2;
 480                         }
 481                         else
 482                         {
 483                                 kill_count_to_attacker = attacker.killcount;
 484                                 kill_count_to_target = 0;
 485                         }
 486
 487                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
 488                         if(targ.istypefrag)
 489                         {
 490                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 491                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 492                                 else
 493                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 494
 495                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 496                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 497                                 else
 498                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 499                         }
 500                         else
 501                         {
 502                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 503                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 504                                 else
 505                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 506
 507                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 508                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 509                                 else
 510                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 511                         }
 512
 513                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 514                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 515                 }
 516         }
 517
 518         // =============
 519         // ACCIDENT/TRAP
 520         // =============
 521         else
 522         {
 523                 switch(deathtype)
 524                 {
 525                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 526                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 527                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 528                         /*case DEATH_HURTTRIGGER:
 529                         {
 530                                 s1 = targ.netname;
 531                                 s2 = inflictor.message;
 532                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 533                                 break;
 534                         }*/
 535
 536                         case DEATH_CUSTOM:
 537                         {
 538                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 539                                         targ.netname,
 540                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 541                                         deathlocation,
 542                                         targ.killcount,
 543                                         0,
 544                                         0);
 545                                 break;
 546                         }
 547
 548                         default:
 549                         {
 550                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 551                                 break;
 552                         }
 553                 }
 554
 555                 LogDeath("accident", deathtype, targ, targ);
 556                 GiveFrags(targ, targ, -1, deathtype);
 557
 558                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 559                 {
 560                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 561                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 562                 }
 563         }
 564
 565         // reset target kill count
 566         if(targ.killcount) { targ.killcount = 0; }
 567 }
 568
 569 void Ice_Think()
 570 {
 571         setorigin(self, self.owner.origin - '0 0 16');
 572         self.nextthink = time;
 573 }
 574
 575 void Freeze (entity targ, float freeze_time, float frozen_type, float show_waypoint)
 576 {
 577         float monster = (targ.flags & FL_MONSTER);
 578         float player = (targ.flags & FL_CLIENT);
 579
 580         if(!player && !monster) // only specified entities can be freezed
 581                 return;
 582
 583         if(targ.frozen)
 584                 return;
 585
 586         targ.frozen = frozen_type;
 587         targ.revive_progress = 0;
 588         targ.health = 1;
 589         targ.revive_speed = freeze_time;
 590
 591         entity ice;
 592         ice = spawn();
 593         ice.owner = targ;
 594         ice.classname = "ice";
 595         ice.scale = targ.scale;
 596         ice.think = Ice_Think;
 597         ice.nextthink = time;
 598         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 599         setmodel(ice, "models/ice/ice.md3");
 600
 601         entity oldself;
 602         oldself = self;
 603         self = ice;
 604         Ice_Think();
 605         self = oldself;
 606
 607         RemoveGrapplingHook(targ);
 608
 609         // add waypoint
 610         if(show_waypoint)
 611                 WaypointSprite_Spawn("frozen", 0, 0, targ, '0 0 64', world, targ.team, targ, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 612 }
 613
 614 void Unfreeze (entity targ)
 615 {
 616         targ.frozen = 0;
 617         targ.revive_progress = 0;
 618         targ.health = ((targ.classname == STR_PLAYER) ? autocvar_g_balance_health_start : targ.max_health);
 619
 620         WaypointSprite_Kill(targ.waypointsprite_attached);
 621
 622         // remove the ice block
 623         entity ice;
 624         for(ice = world; (ice = find(ice, classname, "ice")); ) if(ice.owner == targ)
 625         {
 626                 remove(ice);
 627                 break;
 628         }
 629 }
 630
 631 // these are updated by each Damage call for use in button triggering and such
 632 entity damage_targ;
 633 entity damage_inflictor;
 634 entity damage_attacker;
 635
 636 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 637 {
 638         float mirrordamage;
 639         float mirrorforce;
 640         float complainteamdamage = 0;
 641         entity attacker_save;
 642         mirrordamage = 0;
 643         mirrorforce = 0;
 644
 645         if (gameover || targ.killcount == -666)
 646                 return;
 647
 648         entity oldself;
 649         oldself = self;
 650         self = targ;
 651         damage_targ = targ;
 652         damage_inflictor = inflictor;
 653         damage_attacker = attacker;
 654                 attacker_save = attacker;
 655
 656         if(targ.classname == "player")
 657                 if(targ.hook)
 658                         if(targ.hook.aiment)
 659                                 if(targ.hook.aiment == attacker)
 660                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 661
 662         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 663         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 664         {
 665                 if(targ.classname == "player")
 666                         if not(IsDifferentTeam(targ, attacker))
 667                         {
 668                                 self = oldself;
 669                                 return;
 670                         }
 671         }
 672
 673         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 674         {
 675                 // These are ALWAYS lethal
 676                 // No damage modification here
 677                 // Instead, prepare the victim for his death...
 678                 targ.armorvalue = 0;
 679                 targ.spawnshieldtime = 0;
 680                 targ.health = 0.9; // this is < 1
 681                 targ.flags -= targ.flags & FL_GODMODE;
 682                 damage = 100000;
 683         }
 684         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 685         {
 686                 // no processing
 687         }
 688         else
 689         {
 690                 /*
 691                 skill based bot damage? gtfo. (tZork)
 692                 if (targ.classname == "player")
 693                 if (attacker.classname == "player")
 694                 if (!targ.isbot)
 695                 if (attacker.isbot)
 696                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 697         */
 698
 699                 // nullify damage if teamplay is on
 700                 if(deathtype != DEATH_TELEFRAG)
 701                 if(attacker.classname == "player")
 702                 {
 703                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 704                         {
 705                                 damage = 0;
 706                                 force = '0 0 0';
 707                         }
 708                         else if(!IsDifferentTeam(attacker, targ))
 709                         {
 710                                 if(autocvar_teamplay_mode == 1)
 711                                         damage = 0;
 712                                 else if(attacker != targ)
 713                                 {
 714                                         if(autocvar_teamplay_mode == 3)
 715                                                 damage = 0;
 716                                         else if(autocvar_teamplay_mode == 4)
 717                                         {
 718                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 719                                                 {
 720                                                         attacker.dmg_team = attacker.dmg_team + damage;
 721                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 722                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 723                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 724                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 725                                                         if(g_minstagib)
 726                                                         {
 727                                                                 if(autocvar_g_friendlyfire == 0)
 728                                                                         damage = 0;
 729                                                         }
 730                                                         else if(g_ca)
 731                                                                 damage = 0;
 732                                                         else
 733                                                                 damage = autocvar_g_friendlyfire * damage;
 734                                                         // mirrordamage will be used LATER
 735
 736                                                         if(autocvar_g_mirrordamage_virtual)
 737                                                         {
 738                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 739                                                                 attacker.dmg_take += v_x;
 740                                                                 attacker.dmg_save += v_y;
 741                                                                 attacker.dmg_inflictor = inflictor;
 742                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 743                                                                 mirrorforce = 0;
 744                                                         }
 745
 746                                                         if(autocvar_g_friendlyfire_virtual)
 747                                                         {
 748                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 749                                                                 targ.dmg_take += v_x;
 750                                                                 targ.dmg_save += v_y;
 751                                                                 targ.dmg_inflictor = inflictor;
 752                                                                 damage = 0;
 753                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 754                                                                         force = '0 0 0';
 755                                                         }
 756                                                 }
 757                                                 else
 758                                                         damage = 0;
 759                                         }
 760                                 }
 761                         }
 762                 }
 763
 764                 if(targ.classname == "player")
 765                 if(attacker.classname == "player")
 766                 if(attacker != targ)
 767                 {
 768                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 769                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 770                 }
 771
 772                 if(targ.classname == "player")
 773                 if (g_minstagib)
 774                 {
 775                         if ((deathtype == DEATH_FALL)  ||
 776                                 (deathtype == DEATH_DROWN) ||
 777                                 (deathtype == DEATH_SLIME) ||
 778                                 (deathtype == DEATH_LAVA)  ||
 779                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 780                         {
 781                                 self = oldself;
 782                                 return;
 783                         }
 784                         if(damage > 0)
 785                             damage = 10000;
 786                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 787                         {
 788                                 targ.armorvalue -= 1;
 789                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 790                                 damage = 0;
 791                                 targ.hitsound += 1;
 792                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 793                         }
 794                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 795                         {
 796                                 damage = 0;
 797                                 mirrordamage = 0;
 798                                 complainteamdamage = 0;
 799                                 if (targ != attacker)
 800                                 {
 801                                         if ((targ.health >= 1) && (targ.classname == "player"))
 802                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 803                                         force = '0 0 0';
 804                                         // keep mirrorforce
 805                                         attacker = targ;
 806                                 }
 807                         }
 808                 }
 809
 810                 if not(DEATH_ISSPECIAL(deathtype))
 811                 {
 812                         damage *= g_weapondamagefactor;
 813                         mirrordamage *= g_weapondamagefactor;
 814                         complainteamdamage *= g_weapondamagefactor;
 815                         force = force * g_weaponforcefactor;
 816                         mirrorforce *= g_weaponforcefactor;
 817                 }
 818
 819                 if(((targ.frozen == 2 && attacker.monsterid != MONSTER_SPIDER) || (targ.frozen == 1)) && deathtype != DEATH_HURTTRIGGER)
 820                 {
 821                         damage = 0;
 822                         force *= 0.2;
 823                 }
 824
 825                 // should this be changed at all? If so, in what way?
 826                 frag_attacker = attacker;
 827                 frag_target = targ;
 828                 frag_damage = damage;
 829                 frag_force = force;
 830         frag_deathtype = deathtype;
 831                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 832                 damage = frag_damage;
 833                 force = frag_force;
 834
 835                 // apply strength multiplier
 836                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 837                 {
 838                         if(targ == attacker)
 839                         {
 840                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 841                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 842                         }
 843                         else
 844                         {
 845                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 846                                 force = force * autocvar_g_balance_powerup_strength_force;
 847                         }
 848                 }
 849
 850                 // apply invincibility multiplier
 851                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 852                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 853
 854                 if (targ == attacker)
 855                 {
 856                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 857                                 damage = 0;
 858                         else
 859                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 860                 }
 861
 862                 // count the damage
 863                 if(attacker)
 864                 if(!targ.deadflag)
 865                 if(targ.takedamage == DAMAGE_AIM)
 866                 if(targ != attacker)
 867                 {
 868                         entity victim;
 869                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 870                                 victim = targ.owner;
 871                         else
 872                                 victim = targ;
 873
 874                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET || victim.flags & FL_MONSTER)
 875                         {
 876                                 if(IsDifferentTeam(victim, attacker))
 877                                 {
 878                                         if(damage > 0)
 879                                         {
 880                                                 if(deathtype != DEATH_FIRE)
 881                                                 {
 882                                                         if(victim.BUTTON_CHAT)
 883                                                                 attacker.typehitsound += 1;
 884                                                         else
 885                                                                 attacker.hitsound += 1;
 886                                                 }
 887
 888                                                 damage_goodhits += 1;
 889                                                 damage_gooddamage += damage;
 890
 891                                                 if not(DEATH_ISSPECIAL(deathtype))
 892                                                 {
 893                                                         if(targ.classname == "player") // don't do this for vehicles
 894                                                         if(!g_minstagib)
 895                                                         if(IsFlying(victim))
 896                                                                 yoda = 1;
 897
 898                                                         if(g_minstagib)
 899                                                         if(victim.items & IT_STRENGTH)
 900                                                                 yoda = 1;
 901                                                 }
 902                                         }
 903                                 }
 904                                 else
 905                                 {
 906                                         if(deathtype != DEATH_FIRE)
 907                                         {
 908                                                 attacker.typehitsound += 1;
 909                                         }
 910                                         if(complainteamdamage > 0)
 911                                                 if(time > attacker.teamkill_complain)
 912                                                 {
 913                                                         attacker.teamkill_complain = time + 5;
 914                                                         attacker.teamkill_soundtime = time + 0.4;
 915                                                         attacker.teamkill_soundsource = targ;
 916                                                 }
 917                                 }
 918                         }
 919                 }
 920         }
 921
 922         // apply push
 923         if (self.damageforcescale)
 924         if (vlen(force))
 925         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 926         {
 927                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 928                 if(self.movetype == MOVETYPE_PHYSICS)
 929                 {
 930                         entity farcent;
 931                         farcent = spawn();
 932                         farcent.classname = "farce";
 933                         farcent.enemy = self;
 934                         farcent.movedir = farce * 10;
 935                         if(self.mass)
 936                                 farcent.movedir = farcent.movedir * self.mass;
 937                         farcent.origin = hitloc;
 938                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 939                         farcent.nextthink = time + 0.1;
 940                         farcent.think = SUB_Remove;
 941                 }
 942                 else
 943                         self.velocity = self.velocity + farce;
 944                 self.flags &~= FL_ONGROUND;
 945                 UpdateCSQCProjectile(self);
 946         }
 947         // apply damage
 948         if (damage != 0 || (self.damageforcescale && vlen(force)))
 949         if (self.event_damage)
 950                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 951         self = oldself;
 952
 953         // apply mirror damage if any
 954         if(mirrordamage > 0 || mirrorforce > 0)
 955         {
 956                 attacker = attacker_save;
 957                 if(g_minstagib)
 958                 if(mirrordamage > 0)
 959                 {
 960                         // just lose extra LIVES, don't kill the player for mirror damage
 961                         if(attacker.armorvalue > 0)
 962                         {
 963                                 attacker.armorvalue = attacker.armorvalue - 1;
 964                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 965                                 attacker.hitsound += 1;
 966                         }
 967                         mirrordamage = 0;
 968                 }
 969
 970                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 971                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 972         }
 973 }
 974
 975 float RadiusDamage_running;
 976 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 977         // Returns total damage applies to creatures
 978 {
 979         entity  targ;
 980         vector  blastorigin;
 981         vector  force;
 982         float   total_damage_to_creatures;
 983         entity  next;
 984         float   tfloordmg;
 985         float   tfloorforce;
 986
 987         float stat_damagedone;
 988
 989         if(RadiusDamage_running)
 990         {
 991                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 992                 return 0;
 993         }
 994
 995         RadiusDamage_running = 1;
 996
 997         tfloordmg = autocvar_g_throughfloor_damage;
 998         tfloorforce = autocvar_g_throughfloor_force;
 999
1000         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1001         total_damage_to_creatures = 0;
1002
1003         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1004                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1005                 {
1006                         force = inflictor.velocity;
1007                         if(vlen(force) == 0)
1008                                 force = '0 0 -1';
1009                         else
1010                                 force = normalize(force);
1011                         if(forceintensity >= 0)
1012                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1013                         else
1014                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1015                 }
1016
1017         stat_damagedone = 0;
1018
1019         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1020         while (targ)
1021         {
1022                 next = targ.chain;
1023                 if (targ != inflictor)
1024                         if (ignore != targ) if(targ.takedamage)
1025                         {
1026                                 vector nearest;
1027                                 vector diff;
1028                                 float power;
1029
1030                                 // LordHavoc: measure distance to nearest point on target (not origin)
1031                                 // (this guarentees 100% damage on a touch impact)
1032                                 nearest = targ.WarpZone_findradius_nearest;
1033                                 diff = targ.WarpZone_findradius_dist;
1034                                 // round up a little on the damage to ensure full damage on impacts
1035                                 // and turn the distance into a fraction of the radius
1036                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1037                                 //bprint(" ");
1038                                 //bprint(ftos(power));
1039                                 //if (targ == attacker)
1040                                 //      print(ftos(power), "\n");
1041                                 if (power > 0)
1042                                 {
1043                                         float finaldmg;
1044                                         if (power > 1)
1045                                                 power = 1;
1046                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1047                                         if (finaldmg > 0)
1048                                         {
1049                                                 float a;
1050                                                 float c;
1051                                                 vector hitloc;
1052                                                 vector myblastorigin;
1053                                                 vector center;
1054
1055                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1056
1057                                                 // if it's a player, use the view origin as reference
1058                                                 center = CENTER_OR_VIEWOFS(targ);
1059
1060                                                 force = normalize(center - myblastorigin);
1061                                                 force = force * (finaldmg / coredamage) * forceintensity;
1062                                                 hitloc = nearest;
1063
1064                                                 if(targ != directhitentity)
1065                                                 {
1066                                                         float hits;
1067                                                         float total;
1068                                                         float hitratio;
1069                                                         float mininv_f, mininv_d;
1070
1071                                                         // test line of sight to multiple positions on box,
1072                                                         // and do damage if any of them hit
1073                                                         hits = 0;
1074
1075                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1076                                                         // so for a given max stddev:
1077                                                         // n = (1 / (2 * max stddev of hitratio))^2
1078
1079                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1080                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1081
1082                                                         if(autocvar_g_throughfloor_debug)
1083                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1084
1085                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1086
1087                                                         if(autocvar_g_throughfloor_debug)
1088                                                                 print(sprintf(" steps=%f", total));
1089
1090                                                         if (targ.classname == "player")
1091                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1092                                                         else
1093                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1094
1095                                                         if(autocvar_g_throughfloor_debug)
1096                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1097
1098                                                         for(c = 0; c < total; ++c)
1099                                                         {
1100                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1101                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1102                                                                 if (trace_fraction == 1 || trace_ent == targ)
1103                                                                 {
1104                                                                         ++hits;
1105                                                                         if (hits > 1)
1106                                                                                 hitloc = hitloc + nearest;
1107                                                                         else
1108                                                                                 hitloc = nearest;
1109                                                                 }
1110                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1111                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1112                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1113                                                         }
1114
1115                                                         nearest = hitloc * (1 / max(1, hits));
1116                                                         hitratio = (hits / total);
1117                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1118                                                         finaldmg = finaldmg * a;
1119                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1120                                                         force = force * a;
1121
1122                                                         if(autocvar_g_throughfloor_debug)
1123                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1124                                                 }
1125
1126                                                 // laser force adjustments :P
1127                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1128                                                 {
1129                                                         if (targ == attacker)
1130                                                         {
1131                                                                 vector vel;
1132
1133                                                                 float force_zscale;
1134                                                                 float force_velocitybiasramp;
1135                                                                 float force_velocitybias;
1136
1137                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1138                                                                 if(deathtype & HITTYPE_SECONDARY)
1139                                                                 {
1140                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1141                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1142                                                                 }
1143                                                                 else
1144                                                                 {
1145                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1146                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1147                                                                 }
1148
1149                                                                 vel = targ.velocity;
1150                                                                 vel_z = 0;
1151                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1152                                                                 force =
1153                                                                         vlen(force)
1154                                                                         *
1155                                                                         normalize(normalize(force) + vel);
1156
1157                                                                 force_z *= force_zscale;
1158                                                         }
1159                                                         else
1160                                                         {
1161                                                                 if(deathtype & HITTYPE_SECONDARY)
1162                                                                 {
1163                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1164                                                                 }
1165                                                                 else
1166                                                                 {
1167                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1168                                                                 }
1169                                                         }
1170                                                 }
1171
1172                                                 //if (targ == attacker)
1173                                                 //{
1174                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1175                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1176                                                 //      print(" (", ftos(a), ")\n");
1177                                                 //}
1178                                                 if(finaldmg || vlen(force))
1179                                                 {
1180                                                         if(targ.iscreature)
1181                                                         {
1182                                                                 total_damage_to_creatures += finaldmg;
1183
1184                                                                 if(accuracy_isgooddamage(attacker, targ))
1185                                                                         stat_damagedone += finaldmg;
1186                                                         }
1187
1188                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1189                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1190                                                         else
1191                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1192                                                 }
1193                                         }
1194                                 }
1195                         }
1196                 targ = next;
1197         }
1198
1199         RadiusDamage_running = 0;
1200
1201         if(!DEATH_ISSPECIAL(deathtype))
1202                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1203
1204         return total_damage_to_creatures;
1205 }
1206
1207 .float fire_damagepersec;
1208 .float fire_endtime;
1209 .float fire_deathtype;
1210 .entity fire_owner;
1211 .float fire_hitsound;
1212 .entity fire_burner;
1213
1214 void fireburner_think();
1215
1216 float Fire_IsBurning(entity e)
1217 {
1218         return (time < e.fire_endtime);
1219 }
1220
1221 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1222 {
1223         float dps;
1224         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1225
1226         if(e.classname == "player")
1227         {
1228                 if(e.deadflag)
1229                         return -1;
1230         }
1231         else
1232         {
1233                 if(!e.fire_burner)
1234                 {
1235                         // print("adding a fire burner to ", e.classname, "\n");
1236                         e.fire_burner = spawn();
1237                         e.fire_burner.classname = "fireburner";
1238                         e.fire_burner.think = fireburner_think;
1239                         e.fire_burner.nextthink = time;
1240                         e.fire_burner.owner = e;
1241                 }
1242         }
1243
1244         t = max(t, 0.1);
1245         dps = d / t;
1246         if(Fire_IsBurning(e))
1247         {
1248                 mintime = e.fire_endtime - time;
1249                 maxtime = max(mintime, t);
1250
1251                 mindps = e.fire_damagepersec;
1252                 maxdps = max(mindps, dps);
1253
1254                 if(maxtime > mintime || maxdps > mindps)
1255                 {
1256                         // Constraints:
1257
1258                         // damage we have right now
1259                         mindamage = mindps * mintime;
1260
1261                         // damage we want to get
1262                         maxdamage = mindamage + d;
1263
1264                         // but we can't exceed maxtime * maxdps!
1265                         totaldamage = min(maxdamage, maxtime * maxdps);
1266
1267                         // LEMMA:
1268                         // Look at:
1269                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1270                         // We see:
1271                         // totaldamage <= maxtime * maxdps
1272                         // ==> totaldamage / maxdps <= maxtime.
1273                         // We also see:
1274                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1275                         //                     >= min(mintime, maxtime)
1276                         // ==> totaldamage / maxdps >= mintime.
1277
1278                         /*
1279                         // how long do we damage then?
1280                         // at least as long as before
1281                         // but, never exceed maxdps
1282                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1283                         */
1284
1285                         // alternate:
1286                         // at most as long as maximum allowed
1287                         // but, never below mindps
1288                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1289
1290                         // assuming t > mintime, dps > mindps:
1291                         // we get d = t * dps = maxtime * maxdps
1292                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1293                         // totaldamage / maxdps = maxtime
1294                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1295                         // FROM THIS:
1296                         // a) totaltime = max(mintime, maxtime) = maxtime
1297                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1298
1299                         // assuming t <= mintime:
1300                         // we get maxtime = mintime
1301                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1302                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1303
1304                         // assuming dps <= mindps:
1305                         // we get mindps = maxdps.
1306                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1307                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1308                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1309
1310                         e.fire_damagepersec = totaldamage / totaltime;
1311                         e.fire_endtime = time + totaltime;
1312                         if(totaldamage > 1.2 * mindamage)
1313                         {
1314                                 e.fire_deathtype = dt;
1315                                 if(e.fire_owner != o)
1316                                 {
1317                                         e.fire_owner = o;
1318                                         e.fire_hitsound = FALSE;
1319                                 }
1320                         }
1321                         if(accuracy_isgooddamage(o, e))
1322                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1323                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1324                 }
1325                 else
1326                         return 0;
1327         }
1328         else
1329         {
1330                 e.fire_damagepersec = dps;
1331                 e.fire_endtime = time + t;
1332                 e.fire_deathtype = dt;
1333                 e.fire_owner = o;
1334                 e.fire_hitsound = FALSE;
1335                 if(accuracy_isgooddamage(o, e))
1336                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1337                 return d;
1338         }
1339 }
1340
1341 void Fire_ApplyDamage(entity e)
1342 {
1343         float t, d, hi, ty;
1344         entity o;
1345
1346         if not(Fire_IsBurning(e))
1347                 return;
1348
1349         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1350         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1351                 o = e.fire_owner;
1352
1353         // water and slime stop fire
1354         if(e.waterlevel)
1355         if(e.watertype != CONTENT_LAVA)
1356                 e.fire_endtime = 0;
1357
1358         // ice stops fire
1359         if(e.frozen)
1360                 e.fire_endtime = 0;
1361
1362         t = min(frametime, e.fire_endtime - time);
1363         d = e.fire_damagepersec * t;
1364
1365         hi = e.fire_owner.hitsound;
1366         ty = e.fire_owner.typehitsound;
1367         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1368         if(e.fire_hitsound && e.fire_owner)
1369         {
1370                 e.fire_owner.hitsound = hi;
1371                 e.fire_owner.typehitsound = ty;
1372         }
1373         e.fire_hitsound = TRUE;
1374
1375         if not(IS_INDEPENDENT_PLAYER(e))
1376         FOR_EACH_PLAYER(other) if(e != other)
1377         {
1378                 if(other.classname == "player")
1379                 if(other.deadflag == DEAD_NO)
1380                 if not(IS_INDEPENDENT_PLAYER(other))
1381                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1382                 {
1383                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1384                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1385                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1386                 }
1387         }
1388 }
1389
1390 void Fire_ApplyEffect(entity e)
1391 {
1392         if(Fire_IsBurning(e))
1393                 e.effects |= EF_FLAME;
1394         else
1395                 e.effects &~= EF_FLAME;
1396 }
1397
1398 void fireburner_think()
1399 {
1400         // for players, this is done in the regular loop
1401         if(wasfreed(self.owner))
1402         {
1403                 remove(self);
1404                 return;
1405         }
1406         Fire_ApplyEffect(self.owner);
1407         if(!Fire_IsBurning(self.owner))
1408         {
1409                 self.owner.fire_burner = world;
1410                 remove(self);
1411                 return;
1412         }
1413         Fire_ApplyDamage(self.owner);
1414         self.nextthink = time;
1415 }