qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 /*string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 220 {
 221         string health_output = string_null;
 222         string ping_output = string_null;
 223         string handicap_output = string_null;
 224         string output = string_null;
 225
 226         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 227         {
 228                 // health/armor of attacker (person who killed you)
 229                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 230                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 231
 232                 // ping display
 233                 if(autocvar_sv_fraginfo_ping)
 234                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 235
 236                 // handicap display
 237                 if(autocvar_sv_fraginfo_handicap)
 238                 {
 239                         if(autocvar_sv_fraginfo_handicap == 2)
 240                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 241                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 242                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 243                 }
 244
 245                 // format the string
 246                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 247                         ping_output, (handicap_output ? "^7 / " : ""),
 248                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 249
 250                 // add new line to the beginning if there is a message
 251                 if(output) { output = strcat("\n", output); }
 252         }
 253
 254         return output;
 255 }*/
 256
 257 string AppendItemcodes(string s, entity player)
 258 {
 259         float w;
 260         w = player.weapon;
 261         //if(w == 0)
 262         //      w = player.switchweapon;
 263         if(w == 0)
 264                 w = player.cnt; // previous weapon!
 265         s = strcat(s, ftos(w));
 266         if(time < player.strength_finished)
 267                 s = strcat(s, "S");
 268         if(time < player.invincible_finished)
 269                 s = strcat(s, "I");
 270         if(player.flagcarried != world)
 271                 s = strcat(s, "F");
 272         if(player.BUTTON_CHAT)
 273                 s = strcat(s, "T");
 274         if(player.kh_next)
 275                 s = strcat(s, "K");
 276         if(player.runes)
 277                 s = strcat(s, "|", ftos(player.runes));
 278         return s;
 279 }
 280
 281 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 282 {
 283         string s;
 284         if(!autocvar_sv_eventlog)
 285                 return;
 286         s = strcat(":kill:", mode);
 287         s = strcat(s, ":", ftos(killer.playerid));
 288         s = strcat(s, ":", ftos(killed.playerid));
 289         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 290         s = strcat(s, ":items=");
 291         s = AppendItemcodes(s, killer);
 292         if(killed != killer)
 293         {
 294                 s = strcat(s, ":victimitems=");
 295                 s = AppendItemcodes(s, killed);
 296         }
 297         GameLogEcho(s);
 298 }
 299
 300 #define INFO_NO_MSG 0
 301
 302 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 303 {
 304         float handled = 0, hits = 0;
 305         if(DEATH_ISSPECIAL(deathtype))
 306         {
 307                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 308                         { if(deathtype == max(0, name)) \
 309                         { \
 310                                 #if msg_death != NO_MSG \
 311                                         if not(murder) \
 312                                         { \
 313                                                 Send_Notification_Legacy_Wrapper(NOTIF_ONE, notif_target, MSG_DEATH, msg_death, s1, s2, f1, f2, f3); \
 314                                                 Send_Notification_Legacy_Wrapper(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, f1, f2, f3); \
 315                                                 ++handled; \
 316                                         } \
 317                                 #endif \
 318                                 #if msg_death_by != NO_MSG \
 319                                         if(murder) \
 320                                         { \
 321                                                 Send_Notification_Legacy_Wrapper(NOTIF_ONE, notif_target, MSG_DEATH, msg_death_by, s1, s2, f1, f2, f3); \
 322                                                 Send_Notification_Legacy_Wrapper(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, f1, f2, f3); \
 323                                                 ++handled; \
 324                                         } \
 325                                 #endif \
 326                                 ++hits; \
 327                         } }
 328
 329                 DEATHTYPES
 330                 #undef DEATHTYPE
 331
 332                 if not(hits)
 333                 {
 334                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 335                 }
 336                 if not(handled)
 337                 {
 338                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 339                         return;
 340                 }
 341         }
 342 }
 343
 344 float w_deathtype;
 345 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1)
 346 {
 347         float death_weapon = DEATH_WEAPONOF(deathtype);
 348
 349         if(death_weapon)
 350         {
 351                 w_deathtype = deathtype;
 352                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 353                 w_deathtype = FALSE;
 354
 355                 if(death_message)
 356                 {
 357                         Send_Notification_Legacy_Wrapper(NOTIF_ONE, notif_target, MSG_WEAPON, death_message, s1, s2, f1, 0, 0);
 358                         Send_Notification_Legacy_Wrapper(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, msg_weapon_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, f1, 0, 0);
 359                         //print(Get_Field_Value(F_INFVAL, MSG_WEAPON, death_message), "\n");
 360                 }
 361                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 362
 363                 return TRUE;
 364         }
 365         return FALSE;
 366 }
 367
 368 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 369 {
 370         // Sanity check
 371         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 372
 373         // Declarations
 374         string s1 = "", s2 = "";
 375         float f1 = 0, f2 = 0, f3 = 0;
 376         float notif_firstblood = FALSE;
 377
 378         //dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 379
 380         // =======
 381         // SUICIDE
 382         // =======
 383         if(targ == attacker)
 384         {
 385                 if(DEATH_ISSPECIAL(deathtype))
 386                 {
 387                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 388                         {
 389                                 s1 = targ.netname;
 390                                 f1 = targ.team;
 391                         }
 392                         else
 393                         {
 394                                 switch(deathtype)
 395                                 {
 396                                         case DEATH_MIRRORDAMAGE:
 397                                         {
 398                                                 s1 = targ.netname;
 399                                                 f1 = targ.killcount;
 400                                                 break;
 401                                         }
 402
 403                                         default:
 404                                         {
 405                                                 s1 = targ.netname;
 406                                                 f1 = targ.killcount;
 407                                                 s2 = "";
 408                                                 f2 = f3 = 0;
 409                                                 break;
 410                                         }
 411                                 }
 412                                 LogDeath("suicide", deathtype, targ, targ);
 413                                 GiveFrags(attacker, targ, -1, deathtype);
 414                         }
 415
 416                         Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, 0);
 417                 }
 418                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, "", targ.killcount))
 419                 {
 420                         backtrace("SUICIDE: what the hell happened here?\n");
 421                 }
 422         }
 423
 424         // ======
 425         // MURDER
 426         // ======
 427         else if(attacker.classname == "player")
 428         {
 429                 s1 = attacker.netname;
 430                 s2 = targ.netname;
 431
 432                 if(!IsDifferentTeam(attacker, targ))
 433                 {
 434                         LogDeath("tk", deathtype, attacker, targ);
 435                         GiveFrags(attacker, targ, -1, deathtype);
 436
 437                         attacker.killcount = 0;
 438
 439                         Send_Notification(NOTIF_ONE, attacker, MSG_DEATH, DEATH_TEAMKILL_FRAG, s2);
 440                         Send_Notification(NOTIF_ONE, targ, MSG_DEATH, DEATH_TEAMKILL_FRAGGED, s1);
 441                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), s2, s1, targ.killcount);
 442
 443                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 444                         // No need for specific death/weapon messages...
 445                 }
 446                 else
 447                 {
 448                         LogDeath("frag", deathtype, attacker, targ);
 449                         GiveFrags(attacker, targ, 1, deathtype);
 450
 451                         attacker.taunt_soundtime = time + 1;
 452                         attacker.killcount = attacker.killcount + 1;
 453
 454                         #define ADD_ACHIEVEMENT_CASE(numa,numb) \
 455                                 case numa: \
 456                                 { \
 457                                         AnnounceTo(attacker, strcat(#numb, "kills")); \
 458                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##numa, 1); \
 459                                         break; \
 460                                 }
 461                         switch(attacker.killcount)
 462                         {
 463                                 ADD_ACHIEVEMENT_CASE(3, 03)
 464                                 ADD_ACHIEVEMENT_CASE(5, 05)
 465                                 ADD_ACHIEVEMENT_CASE(10, 10)
 466                                 ADD_ACHIEVEMENT_CASE(15, 15)
 467                                 ADD_ACHIEVEMENT_CASE(20, 20)
 468                                 ADD_ACHIEVEMENT_CASE(25, 25)
 469                                 ADD_ACHIEVEMENT_CASE(30, 30)
 470                                 default: break;
 471                         }
 472                         #undef ADD_ACHIEVEMENT_CASE
 473
 474                         if(!checkrules_firstblood)
 475                         {
 476                                 checkrules_firstblood = TRUE;
 477                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 478                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 479                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 480                         }
 481
 482                         if(notif_firstblood) // first blood, no kill sprees yet
 483                         {
 484                                 if(targ.istypefrag)
 485                                 {
 486                                         if(attacker.FRAG_VERBOSE)
 487                                                 Send_Notification(NOTIF_ONE, attacker, MSG_DEATH, DEATH_MURDER_TYPEFRAG_FIRST_VERBOSE, s2, s1, ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping));
 488                                         else
 489                                                 Send_Notification(NOTIF_ONE, attacker, MSG_DEATH, DEATH_MURDER_TYPEFRAG_FIRST, s2, s1);
 490
 491                                         if(targ.FRAG_VERBOSE)
 492                                                 Send_Notification(NOTIF_ONE, targ, MSG_DEATH, DEATH_MURDER_TYPEFRAGGED_FIRST_VERBOSE, s1, attacker.health, attacker.armorvalue, ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping));
 493                                         else
 494                                                 Send_Notification(NOTIF_ONE, targ, MSG_DEATH, DEATH_MURDER_TYPEFRAGGED_FIRST, s1);
 495                                 }
 496                                 else
 497                                 {
 498                                         if(attacker.FRAG_VERBOSE)
 499                                                 Send_Notification(NOTIF_ONE, attacker, MSG_DEATH, DEATH_MURDER_FRAG_FIRST_VERBOSE, s2, s1, ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping));
 500                                         else
 501                                                 Send_Notification(NOTIF_ONE, attacker, MSG_DEATH, DEATH_MURDER_FRAG_FIRST, s2, s1);
 502
 503                                         if(targ.FRAG_VERBOSE)
 504                                                 Send_Notification(NOTIF_ONE, targ, MSG_DEATH, DEATH_MURDER_FRAGGED_FIRST_VERBOSE, s1, attacker.health, attacker.armorvalue, ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping));
 505                                         else
 506                                                 Send_Notification(NOTIF_ONE, targ, MSG_DEATH, DEATH_MURDER_FRAGGED_FIRST, s1);
 507                                 }
 508                         }
 509                         else // normal frags, kill sprees listed
 510                         {
 511                                 if(targ.istypefrag)
 512                                 {
 513                                         if(attacker.FRAG_VERBOSE)
 514                                                 Send_Notification(NOTIF_ONE, attacker, MSG_DEATH, DEATH_MURDER_TYPEFRAG_VERBOSE, s2, attacker.killcount, ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping));
 515                                         else
 516                                                 Send_Notification(NOTIF_ONE, attacker, MSG_DEATH, DEATH_MURDER_TYPEFRAG, s2, attacker.killcount);
 517
 518                                         if(targ.FRAG_VERBOSE)
 519                                                 Send_Notification(NOTIF_ONE, targ, MSG_DEATH, DEATH_MURDER_TYPEFRAGGED_VERBOSE, s1, attacker.health, attacker.armorvalue, ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping));
 520                                         else
 521                                                 Send_Notification(NOTIF_ONE, targ, MSG_DEATH, DEATH_MURDER_TYPEFRAGGED, s1);
 522                                 }
 523                                 else
 524                                 {
 525                                         if(attacker.FRAG_VERBOSE)
 526                                                 Send_Notification(NOTIF_ONE, attacker, MSG_DEATH, DEATH_MURDER_FRAG_VERBOSE, s2, attacker.killcount, ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping));
 527                                         else
 528                                                 Send_Notification(NOTIF_ONE, attacker, MSG_DEATH, DEATH_MURDER_FRAG, s2, attacker.killcount);
 529
 530                                         if(targ.FRAG_VERBOSE)
 531                                                 Send_Notification(NOTIF_ONE, targ, MSG_DEATH, DEATH_MURDER_FRAGGED_VERBOSE, s1, attacker.health, attacker.armorvalue, ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping));
 532                                         else
 533                                                 Send_Notification(NOTIF_ONE, targ, MSG_DEATH, DEATH_MURDER_FRAGGED, s1);
 534                                 }
 535                         }
 536
 537                         //print("targ_killcount = ", ftos(targ.killcount), ", attacker_killcount = ", ftos(attacker.killcount), ".\n");
 538                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, targ.killcount))
 539                                 Obituary_SpecialDeath(targ, TRUE, deathtype, s2, s1, targ.killcount, 0, 0);
 540                 }
 541         }
 542
 543         // =============
 544         // ACCIDENT/TRAP
 545         // =============
 546         else
 547         {
 548                 switch(deathtype)
 549                 {
 550                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 551                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 552                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 553                         /*case DEATH_HURTTRIGGER:
 554                         {
 555                                 s1 = targ.netname;
 556                                 s2 = inflictor.message;
 557                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 558                                 break;
 559                         }*/
 560
 561                         case DEATH_CUSTOM:
 562                         {
 563                                 s1 = targ.netname;
 564                                 s2 = deathmessage;
 565                                 f1 = targ.killcount;
 566                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 567                                 f2 = f3 = 0;
 568                                 break;
 569                         }
 570
 571                         default:
 572                         {
 573                                 s1 = targ.netname;
 574                                 f1 = targ.killcount;
 575                                 s2 = "";
 576                                 f2 = f3 = 0;
 577                                 break;
 578                         }
 579                 }
 580
 581                 LogDeath("accident", deathtype, targ, targ);
 582                 GiveFrags(targ, targ, -1, deathtype);
 583
 584                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 585                 {
 586                         AnnounceTo(targ, "botlike");
 587                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 588                 }
 589
 590                 Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, f3);
 591         }
 592
 593         // Set final information for the death
 594         targ.death_origin = targ.origin;
 595         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 596         if(targ.killcount) { targ.killcount = 0; }
 597 }
 598
 599 // these are updated by each Damage call for use in button triggering and such
 600 entity damage_targ;
 601 entity damage_inflictor;
 602 entity damage_attacker;
 603
 604 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 605 {
 606         float mirrordamage;
 607         float mirrorforce;
 608         float teamdamage0;
 609         entity attacker_save;
 610         mirrordamage = 0;
 611         mirrorforce = 0;
 612
 613         if (gameover || targ.killcount == -666)
 614                 return;
 615
 616         entity oldself;
 617         oldself = self;
 618         self = targ;
 619         damage_targ = targ;
 620         damage_inflictor = inflictor;
 621         damage_attacker = attacker;
 622                 attacker_save = attacker;
 623
 624         if(targ.classname == "player")
 625                 if(targ.hook)
 626                         if(targ.hook.aiment)
 627                                 if(targ.hook.aiment == attacker)
 628                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 629
 630         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 631         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 632         {
 633                 if(targ.classname == "player")
 634                         if not(IsDifferentTeam(targ, attacker))
 635                         {
 636                                 self = oldself;
 637                                 return;
 638                         }
 639         }
 640
 641         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 642         {
 643                 // These are ALWAYS lethal
 644                 // No damage modification here
 645                 // Instead, prepare the victim for his death...
 646                 targ.armorvalue = 0;
 647                 targ.spawnshieldtime = 0;
 648                 targ.health = 0.9; // this is < 1
 649                 targ.flags -= targ.flags & FL_GODMODE;
 650                 damage = 100000;
 651         }
 652         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 653         {
 654                 // no processing
 655         }
 656         else
 657         {
 658                 /*
 659                 skill based bot damage? gtfo. (tZork)
 660                 if (targ.classname == "player")
 661                 if (attacker.classname == "player")
 662                 if (!targ.isbot)
 663                 if (attacker.isbot)
 664                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 665         */
 666
 667                 // nullify damage if teamplay is on
 668                 if(deathtype != DEATH_TELEFRAG)
 669                 if(attacker.classname == "player")
 670                 {
 671                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 672                         {
 673                                 damage = 0;
 674                                 force = '0 0 0';
 675                         }
 676                         else if(!IsDifferentTeam(attacker, targ))
 677                         {
 678                                 if(autocvar_teamplay_mode == 1)
 679                                         damage = 0;
 680                                 else if(attacker != targ)
 681                                 {
 682                                         if(autocvar_teamplay_mode == 3)
 683                                                 damage = 0;
 684                                         else if(autocvar_teamplay_mode == 4)
 685                                         {
 686                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 687                                                 {
 688                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 689                                                         attacker.dmg_team = attacker.dmg_team + damage;
 690                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 691                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 692                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 693                                                         if(g_minstagib)
 694                                                         {
 695                                                                 if(autocvar_g_friendlyfire == 0)
 696                                                                         damage = 0;
 697                                                         }
 698                                                         else if(g_ca)
 699                                                                 damage = 0;
 700                                                         else
 701                                                                 damage = autocvar_g_friendlyfire * damage;
 702                                                         // mirrordamage will be used LATER
 703
 704                                                         if(autocvar_g_mirrordamage_virtual)
 705                                                         {
 706                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 707                                                                 attacker.dmg_take += v_x;
 708                                                                 attacker.dmg_save += v_y;
 709                                                                 attacker.dmg_inflictor = inflictor;
 710                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 711                                                                 mirrorforce = 0;
 712                                                         }
 713
 714                                                         if(autocvar_g_friendlyfire_virtual)
 715                                                         {
 716                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 717                                                                 targ.dmg_take += v_x;
 718                                                                 targ.dmg_save += v_y;
 719                                                                 targ.dmg_inflictor = inflictor;
 720                                                                 damage = 0;
 721                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 722                                                                         force = '0 0 0';
 723                                                         }
 724                                                 }
 725                                                 else
 726                                                         damage = 0;
 727                                         }
 728                                 }
 729                         }
 730                 }
 731
 732                 if(targ.classname == "player")
 733                 if(attacker.classname == "player")
 734                 if(attacker != targ)
 735                 {
 736                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 737                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 738                 }
 739
 740                 if(targ.classname == "player")
 741                 if (g_minstagib)
 742                 {
 743                         if ((deathtype == DEATH_FALL)  ||
 744                                 (deathtype == DEATH_DROWN) ||
 745                                 (deathtype == DEATH_SLIME) ||
 746                                 (deathtype == DEATH_LAVA)  ||
 747                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 748                         {
 749                                 self = oldself;
 750                                 return;
 751                         }
 752                         if(damage > 0)
 753                             damage = 10000;
 754                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 755                         {
 756                                 targ.armorvalue -= 1;
 757                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 758                                 damage = 0;
 759                                 targ.hitsound += 1;
 760                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 761                         }
 762                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 763                         {
 764                                 damage = 0;
 765                                 mirrordamage = 0;
 766                                 if (targ != attacker)
 767                                 {
 768                                         if ((targ.health >= 1) && (targ.classname == "player"))
 769                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 770                                         force = '0 0 0';
 771                                         // keep mirrorforce
 772                                         attacker = targ;
 773                                 }
 774                         }
 775                 }
 776
 777                 if not(DEATH_ISSPECIAL(deathtype))
 778                 {
 779                         damage *= g_weapondamagefactor;
 780                         mirrordamage *= g_weapondamagefactor;
 781                         force = force * g_weaponforcefactor;
 782                         mirrorforce *= g_weaponforcefactor;
 783                 }
 784
 785                 // should this be changed at all? If so, in what way?
 786                 frag_attacker = attacker;
 787                 frag_target = targ;
 788                 frag_damage = damage;
 789                 frag_force = force;
 790         frag_deathtype = deathtype;
 791                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 792                 damage = frag_damage;
 793                 force = frag_force;
 794
 795                 // apply strength multiplier
 796                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 797                 {
 798                         if(targ == attacker)
 799                         {
 800                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 801                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 802                         }
 803                         else
 804                         {
 805                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 806                                 force = force * autocvar_g_balance_powerup_strength_force;
 807                         }
 808                 }
 809
 810                 // apply invincibility multiplier
 811                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 812                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 813
 814                 if (targ == attacker)
 815                 {
 816                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 817                                 damage = 0;
 818                         else
 819                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 820                 }
 821
 822                 if(g_runematch)
 823                 {
 824                         // apply strength rune
 825                         if (attacker.runes & RUNE_STRENGTH)
 826                         {
 827                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 828                                 {
 829                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 830                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 831                                 }
 832                                 else
 833                                 {
 834                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 835                                         force = force * autocvar_g_balance_rune_strength_force;
 836                                 }
 837                         }
 838                         else if (attacker.runes & CURSE_WEAK)
 839                         {
 840                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 841                                 force = force * autocvar_g_balance_curse_weak_force;
 842                         }
 843
 844                         // apply defense rune
 845                         if (targ.runes & RUNE_DEFENSE)
 846                         {
 847                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 848                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 849                                 else
 850                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 851                         }
 852                         else if (targ.runes & CURSE_VULNER)
 853                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 854                 }
 855
 856                 // count the damage
 857                 if(attacker)
 858                 if(!targ.deadflag)
 859                 if(targ.takedamage == DAMAGE_AIM)
 860                 if(targ != attacker)
 861                 {
 862                         entity victim;
 863                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 864                                 victim = targ.owner;
 865                         else
 866                                 victim = targ;
 867
 868                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 869                         {
 870                                 if(IsDifferentTeam(victim, attacker))
 871                                 {
 872                                         if(damage > 0)
 873                                         {
 874                                                 if(deathtype != DEATH_FIRE)
 875                                                 {
 876                                                         if(victim.BUTTON_CHAT)
 877                                                                 attacker.typehitsound += 1;
 878                                                         else
 879                                                                 attacker.hitsound += 1;
 880                                                 }
 881
 882                                                 damage_goodhits += 1;
 883                                                 damage_gooddamage += damage;
 884
 885                                                 if not(DEATH_ISSPECIAL(deathtype))
 886                                                 {
 887                                                         if(targ.classname == "player") // don't do this for vehicles
 888                                                         if(!g_minstagib)
 889                                                         if(IsFlying(victim))
 890                                                                 yoda = 1;
 891
 892                                                         if(g_minstagib)
 893                                                         if(victim.items & IT_STRENGTH)
 894                                                                 yoda = 1;
 895                                                 }
 896                                         }
 897                                 }
 898                                 else
 899                                 {
 900                                         if(deathtype != DEATH_FIRE)
 901                                         {
 902                                                 attacker.typehitsound += 1;
 903                                         }
 904                                         if(mirrordamage > 0)
 905                                                 if(time > attacker.teamkill_complain)
 906                                                 {
 907                                                         attacker.teamkill_complain = time + 5;
 908                                                         attacker.teamkill_soundtime = time + 0.4;
 909                                                         attacker.teamkill_soundsource = targ;
 910                                                 }
 911                                 }
 912                         }
 913                 }
 914         }
 915
 916         // apply push
 917         if (self.damageforcescale)
 918         if (vlen(force))
 919         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 920         {
 921                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 922                 if(self.movetype == MOVETYPE_PHYSICS)
 923                 {
 924                         entity farcent;
 925                         farcent = spawn();
 926                         farcent.classname = "farce";
 927                         farcent.enemy = self;
 928                         farcent.movedir = farce * 10;
 929                         if(self.mass)
 930                                 farcent.movedir = farcent.movedir * self.mass;
 931                         farcent.origin = hitloc;
 932                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 933                         farcent.nextthink = time + 0.1;
 934                         farcent.think = SUB_Remove;
 935                 }
 936                 else
 937                         self.velocity = self.velocity + farce;
 938                 self.flags &~= FL_ONGROUND;
 939                 UpdateCSQCProjectile(self);
 940         }
 941         // apply damage
 942         if (damage != 0 || (self.damageforcescale && vlen(force)))
 943         if (self.event_damage)
 944                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 945         self = oldself;
 946
 947         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 948         {
 949                 if(g_runematch)
 950                 {
 951                         if (attacker.runes & RUNE_VAMPIRE)
 952                         {
 953                         // apply vampire rune
 954                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 955                                 {
 956                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 957                                         attacker.health = bound(
 958                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 959                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 960                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 961                                 }
 962                                 else
 963                                 {
 964                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 965                                         attacker.health = bound(
 966                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 967                                                                                         // empathy won't let you gain health in the same way...
 968                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 969                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 970                                         }
 971                         }
 972                         // apply empathy curse
 973                         else if (attacker.runes & CURSE_EMPATHY)
 974                         {
 975                                 attacker.health = bound(
 976                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 977                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 978                                         attacker.health);
 979                         }
 980                 }
 981         }
 982
 983         // apply mirror damage if any
 984         if(mirrordamage > 0 || mirrorforce > 0)
 985         {
 986                 attacker = attacker_save;
 987                 if(g_minstagib)
 988                 if(mirrordamage > 0)
 989                 {
 990                         // just lose extra LIVES, don't kill the player for mirror damage
 991                         if(attacker.armorvalue > 0)
 992                         {
 993                                 attacker.armorvalue = attacker.armorvalue - 1;
 994                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 995                                 attacker.hitsound += 1;
 996                         }
 997                         mirrordamage = 0;
 998                 }
 999
1000                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
1001                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
1002         }
1003 }
1004
1005 float RadiusDamage_running;
1006 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
1007         // Returns total damage applies to creatures
1008 {
1009         entity  targ;
1010         vector  blastorigin;
1011         vector  force;
1012         float   total_damage_to_creatures;
1013         entity  next;
1014         float   tfloordmg;
1015         float   tfloorforce;
1016
1017         float stat_damagedone;
1018
1019         if(RadiusDamage_running)
1020         {
1021                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1022                 return 0;
1023         }
1024
1025         RadiusDamage_running = 1;
1026
1027         tfloordmg = autocvar_g_throughfloor_damage;
1028         tfloorforce = autocvar_g_throughfloor_force;
1029
1030         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1031         total_damage_to_creatures = 0;
1032
1033         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1034                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1035                 {
1036                         force = inflictor.velocity;
1037                         if(vlen(force) == 0)
1038                                 force = '0 0 -1';
1039                         else
1040                                 force = normalize(force);
1041                         if(forceintensity >= 0)
1042                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1043                         else
1044                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1045                 }
1046
1047         stat_damagedone = 0;
1048
1049         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1050         while (targ)
1051         {
1052                 next = targ.chain;
1053                 if (targ != inflictor)
1054                         if (ignore != targ) if(targ.takedamage)
1055                         {
1056                                 vector nearest;
1057                                 vector diff;
1058                                 float power;
1059
1060                                 // LordHavoc: measure distance to nearest point on target (not origin)
1061                                 // (this guarentees 100% damage on a touch impact)
1062                                 nearest = targ.WarpZone_findradius_nearest;
1063                                 diff = targ.WarpZone_findradius_dist;
1064                                 // round up a little on the damage to ensure full damage on impacts
1065                                 // and turn the distance into a fraction of the radius
1066                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1067                                 //bprint(" ");
1068                                 //bprint(ftos(power));
1069                                 //if (targ == attacker)
1070                                 //      print(ftos(power), "\n");
1071                                 if (power > 0)
1072                                 {
1073                                         float finaldmg;
1074                                         if (power > 1)
1075                                                 power = 1;
1076                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1077                                         if (finaldmg > 0)
1078                                         {
1079                                                 float a;
1080                                                 float c;
1081                                                 vector hitloc;
1082                                                 vector myblastorigin;
1083                                                 vector center;
1084
1085                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1086
1087                                                 // if it's a player, use the view origin as reference
1088                                                 center = CENTER_OR_VIEWOFS(targ);
1089
1090                                                 force = normalize(center - myblastorigin);
1091                                                 force = force * (finaldmg / coredamage) * forceintensity;
1092                                                 hitloc = nearest;
1093
1094                                                 if(targ != directhitentity)
1095                                                 {
1096                                                         float hits;
1097                                                         float total;
1098                                                         float hitratio;
1099                                                         float mininv_f, mininv_d;
1100
1101                                                         // test line of sight to multiple positions on box,
1102                                                         // and do damage if any of them hit
1103                                                         hits = 0;
1104
1105                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1106                                                         // so for a given max stddev:
1107                                                         // n = (1 / (2 * max stddev of hitratio))^2
1108
1109                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1110                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1111
1112                                                         if(autocvar_g_throughfloor_debug)
1113                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1114
1115                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1116
1117                                                         if(autocvar_g_throughfloor_debug)
1118                                                                 print(sprintf(" steps=%f", total));
1119
1120                                                         if (targ.classname == "player")
1121                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1122                                                         else
1123                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1124
1125                                                         if(autocvar_g_throughfloor_debug)
1126                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1127
1128                                                         for(c = 0; c < total; ++c)
1129                                                         {
1130                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1131                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1132                                                                 if (trace_fraction == 1 || trace_ent == targ)
1133                                                                 {
1134                                                                         ++hits;
1135                                                                         if (hits > 1)
1136                                                                                 hitloc = hitloc + nearest;
1137                                                                         else
1138                                                                                 hitloc = nearest;
1139                                                                 }
1140                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1141                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1142                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1143                                                         }
1144
1145                                                         nearest = hitloc * (1 / max(1, hits));
1146                                                         hitratio = (hits / total);
1147                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1148                                                         finaldmg = finaldmg * a;
1149                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1150                                                         force = force * a;
1151
1152                                                         if(autocvar_g_throughfloor_debug)
1153                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1154                                                 }
1155
1156                                                 // laser force adjustments :P
1157                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1158                                                 {
1159                                                         if (targ == attacker)
1160                                                         {
1161                                                                 vector vel;
1162
1163                                                                 float force_zscale;
1164                                                                 float force_velocitybiasramp;
1165                                                                 float force_velocitybias;
1166
1167                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1168                                                                 if(deathtype & HITTYPE_SECONDARY)
1169                                                                 {
1170                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1171                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1172                                                                 }
1173                                                                 else
1174                                                                 {
1175                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1176                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1177                                                                 }
1178
1179                                                                 vel = targ.velocity;
1180                                                                 vel_z = 0;
1181                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1182                                                                 force =
1183                                                                         vlen(force)
1184                                                                         *
1185                                                                         normalize(normalize(force) + vel);
1186
1187                                                                 force_z *= force_zscale;
1188                                                         }
1189                                                         else
1190                                                         {
1191                                                                 if(deathtype & HITTYPE_SECONDARY)
1192                                                                 {
1193                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1194                                                                 }
1195                                                                 else
1196                                                                 {
1197                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1198                                                                 }
1199                                                         }
1200                                                 }
1201
1202                                                 //if (targ == attacker)
1203                                                 //{
1204                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1205                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1206                                                 //      print(" (", ftos(a), ")\n");
1207                                                 //}
1208                                                 if(finaldmg || vlen(force))
1209                                                 {
1210                                                         if(targ.iscreature)
1211                                                         {
1212                                                                 total_damage_to_creatures += finaldmg;
1213
1214                                                                 if(accuracy_isgooddamage(attacker, targ))
1215                                                                         stat_damagedone += finaldmg;
1216                                                         }
1217
1218                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1219                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1220                                                         else
1221                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1222                                                 }
1223                                         }
1224                                 }
1225                         }
1226                 targ = next;
1227         }
1228
1229         RadiusDamage_running = 0;
1230
1231         if(!DEATH_ISSPECIAL(deathtype))
1232                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1233
1234         return total_damage_to_creatures;
1235 }
1236
1237 .float fire_damagepersec;
1238 .float fire_endtime;
1239 .float fire_deathtype;
1240 .entity fire_owner;
1241 .float fire_hitsound;
1242 .entity fire_burner;
1243
1244 void fireburner_think();
1245
1246 float Fire_IsBurning(entity e)
1247 {
1248         return (time < e.fire_endtime);
1249 }
1250
1251 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1252 {
1253         float dps;
1254         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1255
1256         if(e.classname == "player")
1257         {
1258                 if(e.deadflag)
1259                         return -1;
1260         }
1261         else
1262         {
1263                 if(!e.fire_burner)
1264                 {
1265                         // print("adding a fire burner to ", e.classname, "\n");
1266                         e.fire_burner = spawn();
1267                         e.fire_burner.classname = "fireburner";
1268                         e.fire_burner.think = fireburner_think;
1269                         e.fire_burner.nextthink = time;
1270                         e.fire_burner.owner = e;
1271                 }
1272         }
1273
1274         t = max(t, 0.1);
1275         dps = d / t;
1276         if(Fire_IsBurning(e))
1277         {
1278                 mintime = e.fire_endtime - time;
1279                 maxtime = max(mintime, t);
1280
1281                 mindps = e.fire_damagepersec;
1282                 maxdps = max(mindps, dps);
1283
1284                 if(maxtime > mintime || maxdps > mindps)
1285                 {
1286                         // Constraints:
1287
1288                         // damage we have right now
1289                         mindamage = mindps * mintime;
1290
1291                         // damage we want to get
1292                         maxdamage = mindamage + d;
1293
1294                         // but we can't exceed maxtime * maxdps!
1295                         totaldamage = min(maxdamage, maxtime * maxdps);
1296
1297                         // LEMMA:
1298                         // Look at:
1299                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1300                         // We see:
1301                         // totaldamage <= maxtime * maxdps
1302                         // ==> totaldamage / maxdps <= maxtime.
1303                         // We also see:
1304                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1305                         //                     >= min(mintime, maxtime)
1306                         // ==> totaldamage / maxdps >= mintime.
1307
1308                         /*
1309                         // how long do we damage then?
1310                         // at least as long as before
1311                         // but, never exceed maxdps
1312                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1313                         */
1314
1315                         // alternate:
1316                         // at most as long as maximum allowed
1317                         // but, never below mindps
1318                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1319
1320                         // assuming t > mintime, dps > mindps:
1321                         // we get d = t * dps = maxtime * maxdps
1322                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1323                         // totaldamage / maxdps = maxtime
1324                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1325                         // FROM THIS:
1326                         // a) totaltime = max(mintime, maxtime) = maxtime
1327                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1328
1329                         // assuming t <= mintime:
1330                         // we get maxtime = mintime
1331                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1332                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1333
1334                         // assuming dps <= mindps:
1335                         // we get mindps = maxdps.
1336                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1337                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1338                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1339
1340                         e.fire_damagepersec = totaldamage / totaltime;
1341                         e.fire_endtime = time + totaltime;
1342                         if(totaldamage > 1.2 * mindamage)
1343                         {
1344                                 e.fire_deathtype = dt;
1345                                 if(e.fire_owner != o)
1346                                 {
1347                                         e.fire_owner = o;
1348                                         e.fire_hitsound = FALSE;
1349                                 }
1350                         }
1351                         if(accuracy_isgooddamage(o, e))
1352                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1353                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1354                 }
1355                 else
1356                         return 0;
1357         }
1358         else
1359         {
1360                 e.fire_damagepersec = dps;
1361                 e.fire_endtime = time + t;
1362                 e.fire_deathtype = dt;
1363                 e.fire_owner = o;
1364                 e.fire_hitsound = FALSE;
1365                 if(accuracy_isgooddamage(o, e))
1366                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1367                 return d;
1368         }
1369 }
1370
1371 void Fire_ApplyDamage(entity e)
1372 {
1373         float t, d, hi, ty;
1374         entity o;
1375
1376         if not(Fire_IsBurning(e))
1377                 return;
1378
1379         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1380         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1381                 o = e.fire_owner;
1382
1383         // water and slime stop fire
1384         if(e.waterlevel)
1385         if(e.watertype != CONTENT_LAVA)
1386                 e.fire_endtime = 0;
1387
1388         // ice stops fire
1389         if(e.freezetag_frozen)
1390                 e.fire_endtime = 0;
1391
1392         t = min(frametime, e.fire_endtime - time);
1393         d = e.fire_damagepersec * t;
1394
1395         hi = e.fire_owner.hitsound;
1396         ty = e.fire_owner.typehitsound;
1397         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1398         if(e.fire_hitsound && e.fire_owner)
1399         {
1400                 e.fire_owner.hitsound = hi;
1401                 e.fire_owner.typehitsound = ty;
1402         }
1403         e.fire_hitsound = TRUE;
1404
1405         if not(IS_INDEPENDENT_PLAYER(e))
1406         FOR_EACH_PLAYER(other) if(e != other)
1407         {
1408                 if(other.classname == "player")
1409                 if(other.deadflag == DEAD_NO)
1410                 if not(IS_INDEPENDENT_PLAYER(other))
1411                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1412                 {
1413                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1414                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1415                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1416                 }
1417         }
1418 }
1419
1420 void Fire_ApplyEffect(entity e)
1421 {
1422         if(Fire_IsBurning(e))
1423                 e.effects |= EF_FLAME;
1424         else
1425                 e.effects &~= EF_FLAME;
1426 }
1427
1428 void fireburner_think()
1429 {
1430         // for players, this is done in the regular loop
1431         if(wasfreed(self.owner))
1432         {
1433                 remove(self);
1434                 return;
1435         }
1436         Fire_ApplyEffect(self.owner);
1437         if(!Fire_IsBurning(self.owner))
1438         {
1439                 self.owner.fire_burner = world;
1440                 remove(self);
1441                 return;
1442         }
1443         Fire_ApplyDamage(self.owner);
1444         self.nextthink = time;
1445 }